git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31
  32 memoize("istranslatable");
  33 memoize("_istranslation");
  34 memoize("percenttranslated");
  35
  36 sub import {
  37         hook(type => "getsetup", id => "po", call => \&getsetup);
  38         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  39         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  40         hook(type => "scan", id => "po", call => \&scan, last => 1);
  41         hook(type => "filter", id => "po", call => \&filter);
  42         hook(type => "htmlize", id => "po", call => \&htmlize);
  43         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  44         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  45         hook(type => "delete", id => "po", call => \&mydelete);
  46         hook(type => "change", id => "po", call => \&change);
  47         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  48         hook(type => "canremove", id => "po", call => \&canremove);
  49         hook(type => "canrename", id => "po", call => \&canrename);
  50         hook(type => "editcontent", id => "po", call => \&editcontent);
  51         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  52         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  53
  54         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  55         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  56         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  57         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  58         $origsubs{'urlto'}=\&IkiWiki::urlto;
  59         inject(name => "IkiWiki::urlto", call => \&myurlto);
  60         $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  61         inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  62 }
  63
  64
  65 # ,----
  66 # | Table of contents
  67 # `----
  68
  69 # 1. Hooks
  70 # 2. Injected functions
  71 # 3. Blackboxes for private data
  72 # 4. Helper functions
  73 # 5. PageSpecs
  74
  75
  76 # ,----
  77 # | Hooks
  78 # `----
  79
  80 sub getsetup () {
  81         return
  82                 plugin => {
  83                         safe => 0,
  84                         rebuild => 1,
  85                 },
  86                 po_master_language => {
  87                         type => "string",
  88                         example => {
  89                                 'code' => 'en',
  90                                 'name' => 'English'
  91                         },
  92                         description => "master language (non-PO files)",
  93                         safe => 1,
  94                         rebuild => 1,
  95                 },
  96                 po_slave_languages => {
  97                         type => "string",
  98                         example => {
  99                                 'fr' => 'Français',
 100                                 'es' => 'Español',
 101                                 'de' => 'Deutsch'
 102                         },
 103                         description => "slave languages (PO files)",
 104                         safe => 1,
 105                         rebuild => 1,
 106                 },
 107                 po_translatable_pages => {
 108                         type => "pagespec",
 109                         example => "* and !*/Discussion",
 110                         description => "PageSpec controlling which pages are translatable",
 111                         link => "ikiwiki/PageSpec",
 112                         safe => 1,
 113                         rebuild => 1,
 114                 },
 115                 po_link_to => {
 116                         type => "string",
 117                         example => "current",
 118                         description => "internal linking behavior (default/current/negotiated)",
 119                         safe => 1,
 120                         rebuild => 1,
 121                 },
 122 }
 123
 124 sub checkconfig () {
 125         foreach my $field (qw{po_master_language}) {
 126                 if (! exists $config{$field} || ! defined $config{$field}) {
 127                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 128                                       $field, 'po'));
 129                 }
 130         }
 131
 132         map {
 133                 islanguagecode($_)
 134                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 135         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 136
 137         if (! exists $config{po_translatable_pages} ||
 138             ! defined $config{po_translatable_pages}) {
 139                 $config{po_translatable_pages}="";
 140         }
 141         if (! exists $config{po_link_to} ||
 142             ! defined $config{po_link_to}) {
 143                 $config{po_link_to}='default';
 144         }
 145         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 146                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 147                              $config{po_link_to}));
 148                 $config{po_link_to}='default';
 149         }
 150         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 151                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 152                 $config{po_link_to}='default';
 153         }
 154         unless ($config{po_link_to} eq 'default') {
 155                 $origsubs{'bestlink'}=\&IkiWiki::bestlink;
 156                 inject(name => "IkiWiki::bestlink", call => \&mybestlink);
 157         }
 158
 159         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 160
 161         # Translated versions of the underlays are added if available.
 162         foreach my $underlay ("basewiki",
 163                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 164                                   reverse @{$config{underlaydirs}}) {
 165                 next if $underlay=~/^locale\//;
 166
 167                 # Underlays containing the po files for slave languages.
 168                 foreach my $ll (keys %{$config{po_slave_languages}}) {
 169                         add_underlay("po/$ll/$underlay")
 170                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 171                 }
 172
 173                 if ($config{po_master_language}{code} ne 'en') {
 174                         # Add underlay containing translated source files
 175                         # for the master language.
 176                         add_underlay("locale/$config{po_master_language}{code}/$underlay");
 177                 }
 178         }
 179 }
 180
 181 sub needsbuild () {
 182         my $needsbuild=shift;
 183
 184         # backup @needsbuild content so that change() can know whether
 185         # a given master page was rendered because its source file was changed
 186         @origneedsbuild=(@$needsbuild);
 187
 188         flushmemoizecache();
 189         buildtranslationscache();
 190
 191         # make existing translations depend on the corresponding master page
 192         foreach my $master (keys %translations) {
 193                 map add_depends($_, $master), values %{otherlanguages($master)};
 194         }
 195 }
 196
 197 # Massage the recorded state of internal links so that:
 198 # - it matches the actually generated links, rather than the links as written
 199 #   in the pages' source
 200 # - backlinks are consistent in all cases
 201 sub scan (@) {
 202         my %params=@_;
 203         my $page=$params{page};
 204         my $content=$params{content};
 205
 206         if (istranslation($page)) {
 207                 foreach my $destpage (@{$links{$page}}) {
 208                         if (istranslatable($destpage)) {
 209                                 # replace the occurence of $destpage in $links{$page}
 210                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 211                                         if (@{$links{$page}}[$i] eq $destpage) {
 212                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 213                                                 last;
 214                                         }
 215                                 }
 216                         }
 217                 }
 218         }
 219         elsif (! istranslatable($page) && ! istranslation($page)) {
 220                 foreach my $destpage (@{$links{$page}}) {
 221                         if (istranslatable($destpage)) {
 222                                 # make sure any destpage's translations has
 223                                 # $page in its backlinks
 224                                 push @{$links{$page}},
 225                                         values %{otherlanguages($destpage)};
 226                         }
 227                 }
 228         }
 229 }
 230
 231 # We use filter to convert PO to the master page's format,
 232 # since the rest of ikiwiki should not work on PO files.
 233 sub filter (@) {
 234         my %params = @_;
 235
 236         my $page = $params{page};
 237         my $destpage = $params{destpage};
 238         my $content = $params{content};
 239         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 240                 $content = po_to_markup($page, $content);
 241                 setalreadyfiltered($page, $destpage);
 242         }
 243         return $content;
 244 }
 245
 246 sub htmlize (@) {
 247         my %params=@_;
 248
 249         my $page = $params{page};
 250         my $content = $params{content};
 251
 252         # ignore PO files this plugin did not create
 253         return $content unless istranslation($page);
 254
 255         # force content to be htmlize'd as if it was the same type as the master page
 256         return IkiWiki::htmlize($page, $page,
 257                 pagetype(srcfile($pagesources{masterpage($page)})),
 258                 $content);
 259 }
 260
 261 sub pagetemplate (@) {
 262         my %params=@_;
 263         my $page=$params{page};
 264         my $destpage=$params{destpage};
 265         my $template=$params{template};
 266
 267         my ($masterpage, $lang) = istranslation($page);
 268
 269         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 270                 $template->param(percenttranslated => percenttranslated($page));
 271         }
 272         if ($template->query(name => "istranslation")) {
 273                 $template->param(istranslation => scalar istranslation($page));
 274         }
 275         if ($template->query(name => "istranslatable")) {
 276                 $template->param(istranslatable => istranslatable($page));
 277         }
 278         if ($template->query(name => "HOMEPAGEURL")) {
 279                 $template->param(homepageurl => homepageurl($page));
 280         }
 281         if ($template->query(name => "otherlanguages")) {
 282                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 283                 map add_depends($page, $_), (values %{otherlanguages($page)});
 284         }
 285         if ($config{discussion} && istranslation($page)) {
 286                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 287                    (length $config{cgiurl} ||
 288                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 289                         $template->param('discussionlink' => htmllink(
 290                                 $page,
 291                                 $destpage,
 292                                 $masterpage . '/' . $config{discussionpage},
 293                                 noimageinline => 1,
 294                                 forcesubpage => 0,
 295                                 linktext => $config{discussionpage},
 296                 ));
 297                 }
 298         }
 299         # Remove broken parentlink to ./index.html on home page's translations.
 300         # It works because this hook has the "last" parameter set, to ensure it
 301         # runs after parentlinks' own pagetemplate hook.
 302         if ($template->param('parentlinks')
 303             && istranslation($page)
 304             && $masterpage eq "index") {
 305                 $template->param('parentlinks' => []);
 306         }
 307         if (ishomepage($page) && $template->query(name => "title")) {
 308                 $template->param(title => $config{wikiname});
 309         }
 310 } # }}}
 311
 312 # Add the renamed page translations to the list of to-be-renamed pages.
 313 sub renamepages (@) {
 314         my %params = @_;
 315
 316         my %torename = %{$params{torename}};
 317         my $session = $params{session};
 318
 319         # Save the page(s) the user asked to rename, so that our
 320         # canrename hook can tell the difference between:
 321         #  - a translation being renamed as a consequence of its master page
 322         #    being renamed
 323         #  - a user trying to directly rename a translation
 324         # This is why this hook has to be run first, before the list of pages
 325         # to rename is modified by other plugins.
 326         my @orig_torename;
 327         @orig_torename=@{$session->param("po_orig_torename")}
 328                 if defined $session->param("po_orig_torename");
 329         push @orig_torename, $torename{src};
 330         $session->param(po_orig_torename => \@orig_torename);
 331         IkiWiki::cgi_savesession($session);
 332
 333         return () unless istranslatable($torename{src});
 334
 335         my @ret;
 336         my %otherpages=%{otherlanguages($torename{src})};
 337         while (my ($lang, $otherpage) = each %otherpages) {
 338                 push @ret, {
 339                         src => $otherpage,
 340                         srcfile => $pagesources{$otherpage},
 341                         dest => otherlanguage($torename{dest}, $lang),
 342                         destfile => $torename{dest}.".".$lang.".po",
 343                         required => 0,
 344                 };
 345         }
 346         return @ret;
 347 }
 348
 349 sub mydelete (@) {
 350         my @deleted=@_;
 351
 352         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 353 }
 354
 355 sub change (@) {
 356         my @rendered=@_;
 357
 358         # All meta titles are first extracted at scan time, i.e. before we turn
 359         # PO files back into translated markdown; escaping of double-quotes in
 360         # PO files breaks the meta plugin's parsing enough to save ugly titles
 361         # to %pagestate at this time.
 362         #
 363         # Then, at render time, every page passes in turn through the Great
 364         # Rendering Chain (filter->preprocess->linkify->htmlize), and the meta
 365         # plugin's preprocess hook is this time in a position to correctly
 366         # extract the titles from slave pages.
 367         #
 368         # This is, unfortunately, too late: if the page A, linking to the page
 369         # B, is rendered before B, it will display the wrongly-extracted meta
 370         # title as the link text to B.
 371         #
 372         # On the one hand, such a corner case only happens on rebuild: on
 373         # refresh, every rendered page is fixed to contain correct meta titles.
 374         # On the other hand, it can take some time to get every page fixed.
 375         # We therefore re-render every rendered page after a rebuild to fix them
 376         # at once. As this more or less doubles the time needed to rebuild the
 377         # wiki, we do so only when really needed.
 378
 379         if (@rendered
 380             && exists $config{rebuild} && defined $config{rebuild} && $config{rebuild}
 381             && UNIVERSAL::can("IkiWiki::Plugin::meta", "getsetup")
 382             && exists $config{meta_overrides_page_title}
 383             && defined $config{meta_overrides_page_title}
 384             && $config{meta_overrides_page_title}) {
 385                 debug(sprintf(gettext("rebuilding all pages to fix meta titles")));
 386                 resetalreadyfiltered();
 387                 require IkiWiki::Render;
 388                 foreach my $file (@rendered) {
 389                         debug(sprintf(gettext("building %s"), $file));
 390                         IkiWiki::render($file);
 391                 }
 392         }
 393
 394         my $updated_po_files=0;
 395
 396         # Refresh/create POT and PO files as needed.
 397         # (But avoid doing so if they are in an underlay directory.)
 398         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 399                 my $masterfile=srcfile($file);
 400                 my $page=pagename($file);
 401                 my $updated_pot_file=0;
 402                 # Only refresh POT file if it does not exist, or if
 403                 # $pagesources{$page} was changed: don't if only the HTML was
 404                 # refreshed, e.g. because of a dependency.
 405                 if ($masterfile eq "$config{srcdir}/$file" &&
 406                    ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 407                     || ! -e potfile($masterfile))) {
 408                         refreshpot($masterfile);
 409                         $updated_pot_file=1;
 410                 }
 411                 my @pofiles;
 412                 foreach my $po (pofiles($masterfile)) {
 413                         next if ! $updated_pot_file && ! -e $po;
 414                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 415                         push @pofiles, $po;
 416                 }
 417                 if (@pofiles) {
 418                         refreshpofiles($masterfile, @pofiles);
 419                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 420                         $updated_po_files=1;
 421                 }
 422         }
 423
 424         if ($updated_po_files) {
 425                 commit_and_refresh(
 426                         gettext("updated PO files"),
 427                         "IkiWiki::Plugin::po::change");
 428         }
 429 }
 430
 431 sub checkcontent (@) {
 432         my %params=@_;
 433
 434         if (istranslation($params{page})) {
 435                 my $res = isvalidpo($params{content});
 436                 if ($res) {
 437                         return undef;
 438                 }
 439                 else {
 440                         return "$res";
 441                 }
 442         }
 443         return undef;
 444 }
 445
 446 sub canremove (@) {
 447         my %params = @_;
 448
 449         if (istranslation($params{page})) {
 450                 return gettext("Can not remove a translation. If the master page is removed, ".
 451                                "however, its translations will be removed as well.");
 452         }
 453         return undef;
 454 }
 455
 456 sub canrename (@) {
 457         my %params = @_;
 458         my $session = $params{session};
 459
 460         if (istranslation($params{src})) {
 461                 my $masterpage = masterpage($params{src});
 462                 # Tell the difference between:
 463                 #  - a translation being renamed as a consequence of its master page
 464                 #    being renamed, which is allowed
 465                 #  - a user trying to directly rename a translation, which is forbidden
 466                 # by looking for the master page in the list of to-be-renamed pages we
 467                 # saved early in the renaming process.
 468                 my $orig_torename = $session->param("po_orig_torename");
 469                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 470                         return gettext("Can not rename a translation. If the master page is renamed, ".
 471                                        "however, its translations will be renamed as well.");
 472                 }
 473         }
 474         return undef;
 475 }
 476
 477 # As we're previewing or saving a page, the content may have
 478 # changed, so tell the next filter() invocation it must not be lazy.
 479 sub editcontent () {
 480         my %params=@_;
 481
 482         unsetalreadyfiltered($params{page}, $params{page});
 483         return $params{content};
 484 }
 485
 486 sub formbuilder_setup (@) {
 487         my %params=@_;
 488         my $form=$params{form};
 489         my $q=$params{cgi};
 490
 491         return unless defined $form->field("do");
 492
 493         if ($form->field("do") eq "create") {
 494                 # Warn the user: new pages must be written in master language.
 495                 my $template=template("pocreatepage.tmpl");
 496                 $template->param(LANG => $config{po_master_language}{name});
 497                 $form->tmpl_param(message => $template->output);
 498         }
 499         elsif ($form->field("do") eq "edit") {
 500                 # Remove the rename/remove buttons on slave pages.
 501                 # This has to be done after the rename/remove plugins have added
 502                 # their buttons, which is why this hook must be run last.
 503                 # The canrename/canremove hooks already ensure this is forbidden
 504                 # at the backend level, so this is only UI sugar.
 505                 if (istranslation($form->field("page"))) {
 506                         map {
 507                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 508                                         if (@{$params{buttons}}[$i] eq $_) {
 509                                                 delete  @{$params{buttons}}[$i];
 510                                                 last;
 511                                         }
 512                                 }
 513                         } qw(Rename Remove);
 514                 }
 515         }
 516 }
 517
 518 sub formbuilder (@) {
 519         my %params=@_;
 520         my $form=$params{form};
 521         my $q=$params{cgi};
 522
 523         return unless defined $form->field("do");
 524
 525         # Do not allow to create pages of type po: they are automatically created.
 526         # The main reason to do so is to bypass the "favor the type of linking page
 527         # on page creation" logic, which is unsuitable when a broken link is clicked
 528         # on a slave (PO) page.
 529         # This cannot be done in the formbuilder_setup hook as the list of types is
 530         # computed later.
 531         if ($form->field("do") eq "create") {
 532                 foreach my $field ($form->field) {
 533                         next unless "$field" eq "type";
 534                         if ($field->type eq 'select') {
 535                                 # remove po from the list of types
 536                                 my @types = grep { $_->[0] ne 'po' } $field->options;
 537                                 $field->options(\@types) if @types;
 538                         }
 539                 }
 540         }
 541 }
 542
 543 # ,----
 544 # | Injected functions
 545 # `----
 546
 547 # Implement po_link_to 'current' and 'negotiated' settings.
 548 # Not injected otherwise.
 549 sub mybestlink ($$) {
 550         my $page=shift;
 551         my $link=shift;
 552
 553         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 554         if (length $res
 555             && istranslatable($res)
 556             && istranslation($page)) {
 557                 return $res . "." . lang($page);
 558         }
 559         return $res;
 560 }
 561
 562 sub mybeautify_urlpath ($) {
 563         my $url=shift;
 564
 565         my $res=$origsubs{'beautify_urlpath'}->($url);
 566         if ($config{po_link_to} eq "negotiated") {
 567                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 568                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 569                 map {
 570                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 571                 } (keys %{$config{po_slave_languages}});
 572         }
 573         return $res;
 574 }
 575
 576 sub mytargetpage ($$) {
 577         my $page=shift;
 578         my $ext=shift;
 579
 580         if (istranslation($page) || istranslatable($page)) {
 581                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 582                 if (! $config{usedirs} || $masterpage eq 'index') {
 583                         return $masterpage . "." . $lang . "." . $ext;
 584                 }
 585                 else {
 586                         return $masterpage . "/index." . $lang . "." . $ext;
 587                 }
 588         }
 589         return $origsubs{'targetpage'}->($page, $ext);
 590 }
 591
 592 sub myurlto ($$;$) {
 593         my $to=shift;
 594         my $from=shift;
 595         my $absolute=shift;
 596
 597         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 598         if (! length $to
 599             && $config{po_link_to} eq "current"
 600             && istranslatable('index')) {
 601                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 602         }
 603         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 604         # so that one is redirected to the just-edited page rather than to the
 605         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 606         # we only do so when our beautify_urlpath would actually do what we want to
 607         # avoid, i.e. when po_link_to = negotiated.
 608         # also avoid doing so when run by cgi_goto, so that the links on recentchanges
 609         # page actually lead to the exact page they pretend to.
 610         if ($config{po_link_to} eq "negotiated") {
 611                 my @caller = caller(1);
 612                 my $use_orig = 0;
 613                 $use_orig = 1 if (exists $caller[3] && defined $caller[3]
 614                                  && ($caller[3] eq "IkiWiki::cgi_editpage" ||
 615                                      $caller[3] eq "IkiWiki::Plugin::goto::cgi_goto")
 616                                  );
 617                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 618                         if $use_orig;
 619                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 620                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 621                         if $use_orig;
 622                 return $res;
 623         }
 624         else {
 625                 return $origsubs{'urlto'}->($to,$from,$absolute)
 626         }
 627 }
 628
 629 sub mycgiurl (@) {
 630         my %params=@_;
 631
 632         # slave pages have no subpages
 633         if (istranslation($params{'from'})) {
 634                 $params{'from'} = masterpage($params{'from'});
 635         }
 636         return $origsubs{'cgiurl'}->(%params);
 637 }
 638
 639 # ,----
 640 # | Blackboxes for private data
 641 # `----
 642
 643 {
 644         my %filtered;
 645
 646         sub alreadyfiltered($$) {
 647                 my $page=shift;
 648                 my $destpage=shift;
 649
 650                 return exists $filtered{$page}{$destpage}
 651                          && $filtered{$page}{$destpage} eq 1;
 652         }
 653
 654         sub setalreadyfiltered($$) {
 655                 my $page=shift;
 656                 my $destpage=shift;
 657
 658                 $filtered{$page}{$destpage}=1;
 659         }
 660
 661         sub unsetalreadyfiltered($$) {
 662                 my $page=shift;
 663                 my $destpage=shift;
 664
 665                 if (exists $filtered{$page}{$destpage}) {
 666                         delete $filtered{$page}{$destpage};
 667                 }
 668         }
 669
 670         sub resetalreadyfiltered() {
 671                 undef %filtered;
 672         }
 673 }
 674
 675 # ,----
 676 # | Helper functions
 677 # `----
 678
 679 sub maybe_add_leading_slash ($;$) {
 680         my $str=shift;
 681         my $add=shift;
 682         $add=1 unless defined $add;
 683         return '/' . $str if $add;
 684         return $str;
 685 }
 686
 687 sub istranslatablefile ($) {
 688         my $file=shift;
 689
 690         return 0 unless defined $file;
 691         my $type=pagetype($file);
 692         return 0 if ! defined $type || $type eq 'po';
 693         return 0 if $file =~ /\.pot$/;
 694         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 695         return;
 696 }
 697
 698 sub istranslatable ($) {
 699         my $page=shift;
 700
 701         $page=~s#^/##;
 702         return 1 if istranslatablefile($pagesources{$page});
 703         return;
 704 }
 705
 706 sub _istranslation ($) {
 707         my $page=shift;
 708
 709         $page='' unless defined $page && length $page;
 710         my $hasleadingslash = ($page=~s#^/##);
 711         my $file=$pagesources{$page};
 712         return 0 unless defined $file
 713                          && defined pagetype($file)
 714                          && pagetype($file) eq 'po';
 715         return 0 if $file =~ /\.pot$/;
 716
 717         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 718         return 0 unless defined $masterpage && defined $lang
 719                          && length $masterpage && length $lang
 720                          && defined $pagesources{$masterpage}
 721                          && defined $config{po_slave_languages}{$lang};
 722
 723         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 724                 if istranslatable($masterpage);
 725 }
 726
 727 sub istranslation ($) {
 728         my $page=shift;
 729
 730         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 731                 my $hasleadingslash = ($masterpage=~s#^/##);
 732                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 733                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 734         }
 735         return "";
 736 }
 737
 738 sub masterpage ($) {
 739         my $page=shift;
 740
 741         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 742                 return $masterpage;
 743         }
 744         return $page;
 745 }
 746
 747 sub lang ($) {
 748         my $page=shift;
 749
 750         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 751                 return $lang;
 752         }
 753         return $config{po_master_language}{code};
 754 }
 755
 756 sub islanguagecode ($) {
 757         my $code=shift;
 758
 759         return $code =~ /^[a-z]{2}$/;
 760 }
 761
 762 sub otherlanguage ($$) {
 763         my $page=shift;
 764         my $code=shift;
 765
 766         return masterpage($page) if $code eq $config{po_master_language}{code};
 767         return masterpage($page) . '.' . $code;
 768 }
 769
 770 sub otherlanguages ($) {
 771         my $page=shift;
 772
 773         my %ret;
 774         return \%ret unless istranslation($page) || istranslatable($page);
 775         my $curlang=lang($page);
 776         foreach my $lang
 777                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 778                 next if $lang eq $curlang;
 779                 $ret{$lang}=otherlanguage($page, $lang);
 780         }
 781         return \%ret;
 782 }
 783
 784 sub potfile ($) {
 785         my $masterfile=shift;
 786
 787         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 788         $dir='' if $dir eq './';
 789         return File::Spec->catpath('', $dir, $name . ".pot");
 790 }
 791
 792 sub pofile ($$) {
 793         my $masterfile=shift;
 794         my $lang=shift;
 795
 796         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 797         $dir='' if $dir eq './';
 798         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 799 }
 800
 801 sub pofiles ($) {
 802         my $masterfile=shift;
 803
 804         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 805 }
 806
 807 sub refreshpot ($) {
 808         my $masterfile=shift;
 809
 810         my $potfile=potfile($masterfile);
 811         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 812         my $doc=Locale::Po4a::Chooser::new('text',%options);
 813         $doc->{TT}{utf_mode} = 1;
 814         $doc->{TT}{file_in_charset} = 'utf-8';
 815         $doc->{TT}{file_out_charset} = 'utf-8';
 816         $doc->read($masterfile);
 817         # let's cheat a bit to force porefs option to be passed to
 818         # Locale::Po4a::Po; this is undocument use of internal
 819         # Locale::Po4a::TransTractor's data, compulsory since this module
 820         # prevents us from using the porefs option.
 821         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 822         $doc->{TT}{po_out}->set_charset('utf-8');
 823         # do the actual work
 824         $doc->parse;
 825         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 826         $doc->writepo($potfile);
 827 }
 828
 829 sub refreshpofiles ($@) {
 830         my $masterfile=shift;
 831         my @pofiles=@_;
 832
 833         my $potfile=potfile($masterfile);
 834         if (! -e $potfile) {
 835                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 836         }
 837
 838         foreach my $pofile (@pofiles) {
 839                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 840
 841                 if (! -e $pofile) {
 842                         # If the po file exists in an underlay, copy it
 843                         # from there.
 844                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 845                         foreach my $dir (@{$config{underlaydirs}}) {
 846                                 if (-e "$dir/$pobase") {
 847                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 848                                                 or error("po(refreshpofiles) ".
 849                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 850                                                                  $pofile));
 851                                 }
 852                         }
 853                 }
 854
 855                 if (-e $pofile) {
 856                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 857                                 or error("po(refreshpofiles) ".
 858                                          sprintf(gettext("failed to update %s"),
 859                                                  $pofile));
 860                 }
 861                 else {
 862                         File::Copy::syscopy($potfile,$pofile)
 863                                 or error("po(refreshpofiles) ".
 864                                          sprintf(gettext("failed to copy the POT file to %s"),
 865                                                  $pofile));
 866                 }
 867         }
 868 }
 869
 870 sub buildtranslationscache() {
 871         # use istranslation's side-effect
 872         map istranslation($_), (keys %pagesources);
 873 }
 874
 875 sub resettranslationscache() {
 876         undef %translations;
 877 }
 878
 879 sub flushmemoizecache() {
 880         Memoize::flush_cache("istranslatable");
 881         Memoize::flush_cache("_istranslation");
 882         Memoize::flush_cache("percenttranslated");
 883 }
 884
 885 sub urlto_with_orig_beautiful_urlpath($$) {
 886         my $to=shift;
 887         my $from=shift;
 888
 889         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 890         my $res=urlto($to, $from);
 891         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 892
 893         return $res;
 894 }
 895
 896 sub percenttranslated ($) {
 897         my $page=shift;
 898
 899         $page=~s/^\///;
 900         return gettext("N/A") unless istranslation($page);
 901         my $file=srcfile($pagesources{$page});
 902         my $masterfile = srcfile($pagesources{masterpage($page)});
 903         my %options = (
 904                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 905         );
 906         my $doc=Locale::Po4a::Chooser::new('text',%options);
 907         $doc->process(
 908                 'po_in_name'    => [ $file ],
 909                 'file_in_name'  => [ $masterfile ],
 910                 'file_in_charset'  => 'utf-8',
 911                 'file_out_charset' => 'utf-8',
 912         ) or error("po(percenttranslated) ".
 913                    sprintf(gettext("failed to translate %s"), $page));
 914         my ($percent,$hit,$queries) = $doc->stats();
 915         $percent =~ s/\.[0-9]+$//;
 916         return $percent;
 917 }
 918
 919 sub languagename ($) {
 920         my $code=shift;
 921
 922         return $config{po_master_language}{name}
 923                 if $code eq $config{po_master_language}{code};
 924         return $config{po_slave_languages}{$code}
 925                 if defined $config{po_slave_languages}{$code};
 926         return;
 927 }
 928
 929 sub otherlanguagesloop ($) {
 930         my $page=shift;
 931
 932         my @ret;
 933         my %otherpages=%{otherlanguages($page)};
 934         while (my ($lang, $otherpage) = each %otherpages) {
 935                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 936                         push @ret, {
 937                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 938                                 code => $lang,
 939                                 language => languagename($lang),
 940                                 master => 1,
 941                         };
 942                 }
 943                 elsif (istranslation($otherpage)) {
 944                         push @ret, {
 945                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 946                                 code => $lang,
 947                                 language => languagename($lang),
 948                                 percent => percenttranslated($otherpage),
 949                         }
 950                 }
 951         }
 952         return sort {
 953                 return -1 if $a->{code} eq $config{po_master_language}{code};
 954                 return 1 if $b->{code} eq $config{po_master_language}{code};
 955                 return $a->{language} cmp $b->{language};
 956         } @ret;
 957 }
 958
 959 sub homepageurl (;$) {
 960         my $page=shift;
 961
 962         return urlto('', $page);
 963 }
 964
 965 sub ishomepage ($) {
 966         my $page = shift;
 967
 968         return 1 if $page eq 'index';
 969         map { return 1 if $page eq 'index.'.$_ } keys %{$config{po_slave_languages}};
 970         return undef;
 971 }
 972
 973 sub deletetranslations ($) {
 974         my $deletedmasterfile=shift;
 975
 976         my $deletedmasterpage=pagename($deletedmasterfile);
 977         my @todelete;
 978         map {
 979                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 980                 my $absfile = "$config{srcdir}/$file";
 981                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 982                         push @todelete, $file;
 983                 }
 984         } keys %{$config{po_slave_languages}};
 985
 986         map {
 987                 if ($config{rcs}) {
 988                         IkiWiki::rcs_remove($_);
 989                 }
 990                 else {
 991                         IkiWiki::prune("$config{srcdir}/$_");
 992                 }
 993         } @todelete;
 994
 995         if (@todelete) {
 996                 commit_and_refresh(
 997                         gettext("removed obsolete PO files"),
 998                         "IkiWiki::Plugin::po::deletetranslations");
 999         }
1000 }
1001
1002 sub commit_and_refresh ($$) {
1003         my ($msg, $author) = (shift, shift);
1004
1005         if ($config{rcs}) {
1006                 IkiWiki::disable_commit_hook();
1007                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
1008                 IkiWiki::enable_commit_hook();
1009                 IkiWiki::rcs_update();
1010         }
1011         # Reinitialize module's private variables.
1012         resetalreadyfiltered();
1013         resettranslationscache();
1014         flushmemoizecache();
1015         # Trigger a wiki refresh.
1016         require IkiWiki::Render;
1017         # without preliminary saveindex/loadindex, refresh()
1018         # complains about a lot of uninitialized variables
1019         IkiWiki::saveindex();
1020         IkiWiki::loadindex();
1021         IkiWiki::refresh();
1022         IkiWiki::saveindex();
1023 }
1024
1025 # on success, returns the filtered content.
1026 # on error, if $nonfatal, warn and return undef; else, error out.
1027 sub po_to_markup ($$;$) {
1028         my ($page, $content) = (shift, shift);
1029         my $nonfatal = shift;
1030
1031         $content = '' unless defined $content;
1032         $content = decode_utf8(encode_utf8($content));
1033         # CRLF line terminators make poor Locale::Po4a feel bad
1034         $content=~s/\r\n/\n/g;
1035
1036         # There are incompatibilities between some File::Temp versions
1037         # (including 0.18, bundled with Lenny's perl-modules package)
1038         # and others (e.g. 0.20, previously present in the archive as
1039         # a standalone package): under certain circumstances, some
1040         # return a relative filename, whereas others return an absolute one;
1041         # we here use this module in a way that is at least compatible
1042         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1043         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1044                                     DIR => File::Spec->tmpdir,
1045                                     UNLINK => 1)->filename;
1046         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1047                                      DIR => File::Spec->tmpdir,
1048                                      UNLINK => 1)->filename;
1049
1050         my $fail = sub ($) {
1051                 my $msg = "po(po_to_markup) - $page : " . shift;
1052                 if ($nonfatal) {
1053                         warn $msg;
1054                         return undef;
1055                 }
1056                 error($msg, sub { unlink $infile, $outfile});
1057         };
1058
1059         writefile(basename($infile), File::Spec->tmpdir, $content)
1060                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1061
1062         my $masterfile = srcfile($pagesources{masterpage($page)});
1063         my %options = (
1064                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
1065         );
1066         my $doc=Locale::Po4a::Chooser::new('text',%options);
1067         $doc->process(
1068                 'po_in_name'    => [ $infile ],
1069                 'file_in_name'  => [ $masterfile ],
1070                 'file_in_charset'  => 'utf-8',
1071                 'file_out_charset' => 'utf-8',
1072         ) or return $fail->(gettext("failed to translate"));
1073         $doc->write($outfile)
1074                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1075
1076         $content = readfile($outfile)
1077                 or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
1078
1079         # Unlinking should happen automatically, thanks to File::Temp,
1080         # but it does not work here, probably because of the way writefile()
1081         # and Locale::Po4a::write() work.
1082         unlink $infile, $outfile;
1083
1084         return $content;
1085 }
1086
1087 # returns a SuccessReason or FailReason object
1088 sub isvalidpo ($) {
1089         my $content = shift;
1090
1091         # NB: we don't use po_to_markup here, since Po4a parser does
1092         # not mind invalid PO content
1093         $content = '' unless defined $content;
1094         $content = decode_utf8(encode_utf8($content));
1095
1096         # There are incompatibilities between some File::Temp versions
1097         # (including 0.18, bundled with Lenny's perl-modules package)
1098         # and others (e.g. 0.20, previously present in the archive as
1099         # a standalone package): under certain circumstances, some
1100         # return a relative filename, whereas others return an absolute one;
1101         # we here use this module in a way that is at least compatible
1102         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1103         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1104                                     DIR => File::Spec->tmpdir,
1105                                     UNLINK => 1)->filename;
1106
1107         my $fail = sub ($) {
1108                 my $msg = '[po/isvalidpo] ' . shift;
1109                 unlink $infile;
1110                 return IkiWiki::FailReason->new("$msg");
1111         };
1112
1113         writefile(basename($infile), File::Spec->tmpdir, $content)
1114                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1115
1116         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1117
1118         # Unlinking should happen automatically, thanks to File::Temp,
1119         # but it does not work here, probably because of the way writefile()
1120         # and Locale::Po4a::write() work.
1121         unlink $infile;
1122
1123         if ($res) {
1124             return IkiWiki::SuccessReason->new("valid gettext data");
1125         }
1126         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1127                                         "to previous page to continue edit"));
1128 }
1129
1130 # ,----
1131 # | PageSpecs
1132 # `----
1133
1134 package IkiWiki::PageSpec;
1135
1136 sub match_istranslation ($;@) {
1137         my $page=shift;
1138
1139         if (IkiWiki::Plugin::po::istranslation($page)) {
1140                 return IkiWiki::SuccessReason->new("is a translation page");
1141         }
1142         else {
1143                 return IkiWiki::FailReason->new("is not a translation page");
1144         }
1145 }
1146
1147 sub match_istranslatable ($;@) {
1148         my $page=shift;
1149
1150         if (IkiWiki::Plugin::po::istranslatable($page)) {
1151                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1152         }
1153         else {
1154                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1155         }
1156 }
1157
1158 sub match_lang ($$;@) {
1159         my $page=shift;
1160         my $wanted=shift;
1161
1162         my $regexp=IkiWiki::glob2re($wanted);
1163         my $lang=IkiWiki::Plugin::po::lang($page);
1164         if ($lang !~ /^$regexp$/i) {
1165                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1166         }
1167         else {
1168                 return IkiWiki::SuccessReason->new("file language is $wanted");
1169         }
1170 }
1171
1172 sub match_currentlang ($$;@) {
1173         my $page=shift;
1174         shift;
1175         my %params=@_;
1176
1177         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1178
1179         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1180         my $lang=IkiWiki::Plugin::po::lang($page);
1181
1182         if ($lang eq $currentlang) {
1183                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1184         }
1185         else {
1186                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1187         }
1188 }
1189
1190 1