git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use File::Spec;
   7 use HTML::Template;
   8
   9 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime
  10             %renderedfiles %pagesources %depends %hooks};
  11
  12 sub defaultconfig () { #{{{
  13         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$|\.rss$)},
  14         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  15         wiki_processor_regexp => qr/\[\[(\w+)\s+([^\]]*)\]\]/,
  16         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  17         verbose => 0,
  18         wikiname => "wiki",
  19         default_pageext => ".mdwn",
  20         cgi => 0,
  21         rcs => 'svn',
  22         notify => 0,
  23         url => '',
  24         cgiurl => '',
  25         historyurl => '',
  26         diffurl => '',
  27         anonok => 0,
  28         rss => 0,
  29         discussion => 1,
  30         rebuild => 0,
  31         refresh => 0,
  32         getctime => 0,
  33         wrapper => undef,
  34         wrappermode => undef,
  35         svnrepo => undef,
  36         svnpath => "trunk",
  37         srcdir => undef,
  38         destdir => undef,
  39         templatedir => "/usr/share/ikiwiki/templates",
  40         underlaydir => "/usr/share/ikiwiki/basewiki",
  41         setup => undef,
  42         adminuser => undef,
  43         adminemail => undef,
  44         plugin => [qw{inline htmlscrubber}],
  45         timeformat => '%c',
  46 } #}}}
  47
  48 sub checkconfig () { #{{{
  49         if ($config{cgi} && ! length $config{url}) {
  50                 error("Must specify url to wiki with --url when using --cgi\n");
  51         }
  52         if ($config{rss} && ! length $config{url}) {
  53                 error("Must specify url to wiki with --url when using --rss\n");
  54         }
  55
  56         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
  57                 unless exists $config{wikistatedir};
  58
  59         if ($config{rcs}) {
  60                 eval qq{require IkiWiki::Rcs::$config{rcs}};
  61                 if ($@) {
  62                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
  63                 }
  64         }
  65         else {
  66                 require IkiWiki::Rcs::Stub;
  67         }
  68
  69         foreach my $plugin (@{$config{plugin}}) {
  70                 my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
  71                 eval qq{use $mod};
  72                 if ($@) {
  73                         error("Failed to load plugin $mod: $@");
  74                 }
  75         }
  76
  77         if (exists $hooks{checkconfig}) {
  78                 foreach my $id (keys %{$hooks{checkconfig}}) {
  79                         $hooks{checkconfig}{$id}{call}->();
  80                 }
  81         }
  82 } #}}}
  83
  84 sub error ($) { #{{{
  85         if ($config{cgi}) {
  86                 print "Content-type: text/html\n\n";
  87                 print misctemplate("Error", "<p>Error: @_</p>");
  88         }
  89         die @_;
  90 } #}}}
  91
  92 sub debug ($) { #{{{
  93         return unless $config{verbose};
  94         if (! $config{cgi}) {
  95                 print "@_\n";
  96         }
  97         else {
  98                 print STDERR "@_\n";
  99         }
 100 } #}}}
 101
 102 sub possibly_foolish_untaint ($) { #{{{
 103         my $tainted=shift;
 104         my ($untainted)=$tainted=~/(.*)/;
 105         return $untainted;
 106 } #}}}
 107
 108 sub basename ($) { #{{{
 109         my $file=shift;
 110
 111         $file=~s!.*/+!!;
 112         return $file;
 113 } #}}}
 114
 115 sub dirname ($) { #{{{
 116         my $file=shift;
 117
 118         $file=~s!/*[^/]+$!!;
 119         return $file;
 120 } #}}}
 121
 122 sub pagetype ($) { #{{{
 123         my $page=shift;
 124
 125         if ($page =~ /\.mdwn$/) {
 126                 return ".mdwn";
 127         }
 128         else {
 129                 return "unknown";
 130         }
 131 } #}}}
 132
 133 sub pagename ($) { #{{{
 134         my $file=shift;
 135
 136         my $type=pagetype($file);
 137         my $page=$file;
 138         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 139         return $page;
 140 } #}}}
 141
 142 sub htmlpage ($) { #{{{
 143         my $page=shift;
 144
 145         return $page.".html";
 146 } #}}}
 147
 148 sub srcfile ($) { #{{{
 149         my $file=shift;
 150
 151         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 152         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 153         error("internal error: $file cannot be found");
 154 } #}}}
 155
 156 sub readfile ($;$) { #{{{
 157         my $file=shift;
 158         my $binary=shift;
 159
 160         if (-l $file) {
 161                 error("cannot read a symlink ($file)");
 162         }
 163
 164         local $/=undef;
 165         open (IN, $file) || error("failed to read $file: $!");
 166         if (! $binary) {
 167                 binmode(IN, ":utf8");
 168         }
 169         else {
 170                 binmode(IN);
 171         }
 172         my $ret=<IN>;
 173         close IN;
 174         return $ret;
 175 } #}}}
 176
 177 sub writefile ($$$;$) { #{{{
 178         my $file=shift; # can include subdirs
 179         my $destdir=shift; # directory to put file in
 180         my $content=shift;
 181         my $binary=shift;
 182
 183         my $test=$file;
 184         while (length $test) {
 185                 if (-l "$destdir/$test") {
 186                         error("cannot write to a symlink ($test)");
 187                 }
 188                 $test=dirname($test);
 189         }
 190
 191         my $dir=dirname("$destdir/$file");
 192         if (! -d $dir) {
 193                 my $d="";
 194                 foreach my $s (split(m!/+!, $dir)) {
 195                         $d.="$s/";
 196                         if (! -d $d) {
 197                                 mkdir($d) || error("failed to create directory $d: $!");
 198                         }
 199                 }
 200         }
 201
 202         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 203         if (! $binary) {
 204                 binmode(OUT, ":utf8");
 205         }
 206         else {
 207                 binmode(OUT);
 208         }
 209         print OUT $content;
 210         close OUT;
 211 } #}}}
 212
 213 sub bestlink ($$) { #{{{
 214         # Given a page and the text of a link on the page, determine which
 215         # existing page that link best points to. Prefers pages under a
 216         # subdirectory with the same name as the source page, failing that
 217         # goes down the directory tree to the base looking for matching
 218         # pages.
 219         my $page=shift;
 220         my $link=lc(shift);
 221
 222         my $cwd=$page;
 223         do {
 224                 my $l=$cwd;
 225                 $l.="/" if length $l;
 226                 $l.=$link;
 227
 228                 if (exists $links{$l}) {
 229                         #debug("for $page, \"$link\", use $l");
 230                         return $l;
 231                 }
 232         } while $cwd=~s!/?[^/]+$!!;
 233
 234         #print STDERR "warning: page $page, broken link: $link\n";
 235         return "";
 236 } #}}}
 237
 238 sub isinlinableimage ($) { #{{{
 239         my $file=shift;
 240
 241         $file=~/\.(png|gif|jpg|jpeg)$/i;
 242 } #}}}
 243
 244 sub pagetitle ($) { #{{{
 245         my $page=shift;
 246         $page=~s/__(\d+)__/&#$1;/g;
 247         $page=~y/_/ /;
 248         return $page;
 249 } #}}}
 250
 251 sub titlepage ($) { #{{{
 252         my $title=shift;
 253         $title=~y/ /_/;
 254         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 255         return $title;
 256 } #}}}
 257
 258 sub cgiurl (@) { #{{{
 259         my %params=@_;
 260
 261         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 262 } #}}}
 263
 264 sub styleurl (;$) { #{{{
 265         my $page=shift;
 266
 267         return "$config{url}/style.css" if ! defined $page;
 268
 269         $page=~s/[^\/]+$//;
 270         $page=~s/[^\/]+\//..\//g;
 271         return $page."style.css";
 272 } #}}}
 273
 274 sub htmllink ($$$;$$$) { #{{{
 275         my $lpage=shift; # the page doing the linking
 276         my $page=shift; # the page that will contain the link (different for inline)
 277         my $link=shift;
 278         my $noimageinline=shift; # don't turn links into inline html images
 279         my $forcesubpage=shift; # force a link to a subpage
 280         my $linktext=shift; # set to force the link text to something
 281
 282         my $bestlink;
 283         if (! $forcesubpage) {
 284                 $bestlink=bestlink($lpage, $link);
 285         }
 286         else {
 287                 $bestlink="$lpage/".lc($link);
 288         }
 289
 290         $linktext=pagetitle(basename($link)) unless defined $linktext;
 291
 292         return $linktext if length $bestlink && $page eq $bestlink;
 293
 294         # TODO BUG: %renderedfiles may not have it, if the linked to page
 295         # was also added and isn't yet rendered! Note that this bug is
 296         # masked by the bug that makes all new files be rendered twice.
 297         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 298                 $bestlink=htmlpage($bestlink);
 299         }
 300         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 301                 return "<span><a href=\"".
 302                         cgiurl(do => "create", page => $link, from => $page).
 303                         "\">?</a>$linktext</span>"
 304         }
 305
 306         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 307
 308         if (! $noimageinline && isinlinableimage($bestlink)) {
 309                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 310         }
 311         return "<a href=\"$bestlink\">$linktext</a>";
 312 } #}}}
 313
 314 sub indexlink () { #{{{
 315         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 316 } #}}}
 317
 318 sub lockwiki () { #{{{
 319         # Take an exclusive lock on the wiki to prevent multiple concurrent
 320         # run issues. The lock will be dropped on program exit.
 321         if (! -d $config{wikistatedir}) {
 322                 mkdir($config{wikistatedir});
 323         }
 324         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 325                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 326         if (! flock(WIKILOCK, 2 | 4)) {
 327                 debug("wiki seems to be locked, waiting for lock");
 328                 my $wait=600; # arbitrary, but don't hang forever to
 329                               # prevent process pileup
 330                 for (1..600) {
 331                         return if flock(WIKILOCK, 2 | 4);
 332                         sleep 1;
 333                 }
 334                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 335         }
 336 } #}}}
 337
 338 sub unlockwiki () { #{{{
 339         close WIKILOCK;
 340 } #}}}
 341
 342 sub loadindex () { #{{{
 343         open (IN, "$config{wikistatedir}/index") || return;
 344         while (<IN>) {
 345                 $_=possibly_foolish_untaint($_);
 346                 chomp;
 347                 my %items;
 348                 $items{link}=[];
 349                 foreach my $i (split(/ /, $_)) {
 350                         my ($item, $val)=split(/=/, $i, 2);
 351                         push @{$items{$item}}, $val;
 352                 }
 353
 354                 next unless exists $items{src}; # skip bad lines for now
 355
 356                 my $page=pagename($items{src}[0]);
 357                 if (! $config{rebuild}) {
 358                         $pagesources{$page}=$items{src}[0];
 359                         $oldpagemtime{$page}=$items{mtime}[0];
 360                         $oldlinks{$page}=[@{$items{link}}];
 361                         $links{$page}=[@{$items{link}}];
 362                         $depends{$page}=join(" ", @{$items{depends}})
 363                                 if exists $items{depends};
 364                         $renderedfiles{$page}=$items{dest}[0];
 365                 }
 366                 $pagectime{$page}=$items{ctime}[0];
 367         }
 368         close IN;
 369 } #}}}
 370
 371 sub saveindex () { #{{{
 372         if (! -d $config{wikistatedir}) {
 373                 mkdir($config{wikistatedir});
 374         }
 375         open (OUT, ">$config{wikistatedir}/index") ||
 376                 error("cannot write to $config{wikistatedir}/index: $!");
 377         foreach my $page (keys %oldpagemtime) {
 378                 next unless $oldpagemtime{$page};
 379                 my $line="mtime=$oldpagemtime{$page} ".
 380                         "ctime=$pagectime{$page} ".
 381                         "src=$pagesources{$page} ".
 382                         "dest=$renderedfiles{$page}";
 383                 $line.=" link=$_" foreach @{$links{$page}};
 384                 if (exists $depends{$page}) {
 385                         $line.=" depends=$_" foreach split " ", $depends{$page};
 386                 }
 387                 print OUT $line."\n";
 388         }
 389         close OUT;
 390 } #}}}
 391
 392 sub misctemplate ($$) { #{{{
 393         my $title=shift;
 394         my $pagebody=shift;
 395
 396         my $template=HTML::Template->new(
 397                 filename => "$config{templatedir}/misc.tmpl"
 398         );
 399         $template->param(
 400                 title => $title,
 401                 indexlink => indexlink(),
 402                 wikiname => $config{wikiname},
 403                 pagebody => $pagebody,
 404                 styleurl => styleurl(),
 405                 baseurl => "$config{url}/",
 406         );
 407         return $template->output;
 408 }#}}}
 409
 410 sub glob_match ($$) { #{{{
 411         my $page=shift;
 412         my $glob=shift;
 413
 414         if ($glob =~ /^link\((.+)\)$/) {
 415                 my $rev = $links{$page} or return undef;
 416                 foreach my $p (@$rev) {
 417                         return 1 if lc $p eq $1;
 418                 }
 419                 return 0;
 420         } elsif ($glob =~ /^backlink\((.+)\)$/) {
 421                 my $rev = $links{$1} or return undef;
 422                 foreach my $p (@$rev) {
 423                         return 1 if lc $p eq $page;
 424                 }
 425                 return 0;
 426         } else {
 427                 # turn glob into safe regexp
 428                 $glob=quotemeta($glob);
 429                 $glob=~s/\\\*/.*/g;
 430                 $glob=~s/\\\?/./g;
 431                 $glob=~s!\\/!/!g;
 432
 433                 return $page=~/^$glob$/i;
 434         }
 435 } #}}}
 436
 437 sub globlist_match ($$) { #{{{
 438         my $page=shift;
 439         my @globlist=split(" ", shift);
 440
 441         # check any negated globs first
 442         foreach my $glob (@globlist) {
 443                 return 0 if $glob=~/^!(.*)/ && glob_match($page, $1);
 444         }
 445
 446         foreach my $glob (@globlist) {
 447                 return 1 if glob_match($page, $glob);
 448         }
 449
 450         return 0;
 451 } #}}}
 452
 453 sub hook (@) { # {{{
 454         my %param=@_;
 455
 456         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 457                 error "hook requires type, call, and id parameters";
 458         }
 459
 460         $hooks{$param{type}}{$param{id}}=\%param;
 461 } # }}}
 462
 463 1