git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         run_hooks(indexhtml => sub {
  66                 shift->(page => $page, destpage => $page, content => $content);
  67         });
  68
  69         my $templatefile;
  70         run_hooks(templatefile => sub {
  71                 return if defined $templatefile;
  72                 my $file=shift->(page => $page);
  73                 if (defined $file && defined template_file($file)) {
  74                         $templatefile=$file;
  75                 }
  76         });
  77         my $template;
  78         if (defined $templatefile) {
  79                 $template=template_depends($templatefile, $page,
  80                         blind_cache => 1);
  81         }
  82         else {
  83                 # no explicit depends as special case
  84                 $template=template('page.tmpl',
  85                         blind_cache => 1);
  86         }
  87
  88         my $actions=0;
  89         if (length $config{cgiurl}) {
  90                 if (IkiWiki->can("cgi_editpage")) {
  91                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  92                         $actions++;
  93                 }
  94         }
  95         if (defined $config{historyurl} && length $config{historyurl}) {
  96                 my $u=$config{historyurl};
  97                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  98                 $template->param(historyurl => $u);
  99                 $actions++;
 100         }
 101         if ($config{discussion}) {
 102                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 103                    (length $config{cgiurl} ||
 104                     exists $links{$page."/".$config{discussionpage}})) {
 105                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 106                         $actions++;
 107                 }
 108         }
 109         if ($actions) {
 110                 $template->param(have_actions => 1);
 111         }
 112         templateactions($template, $page);
 113
 114         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 115         my ($backlinks, $more_backlinks);
 116         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 117                 $backlinks=\@backlinks;
 118                 $more_backlinks=[];
 119         }
 120         else {
 121                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 122                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 123         }
 124
 125         $template->param(
 126                 title => $page eq 'index'
 127                         ? $config{wikiname}
 128                         : pagetitle(basename($page)),
 129                 wikiname => $config{wikiname},
 130                 content => $content,
 131                 backlinks => $backlinks,
 132                 more_backlinks => $more_backlinks,
 133                 mtime => displaytime($pagemtime{$page}),
 134                 ctime => displaytime($pagectime{$page}, undef, 1),
 135                 baseurl => baseurl($page),
 136                 html5 => $config{html5},
 137         );
 138
 139         run_hooks(pagetemplate => sub {
 140                 shift->(page => $page, destpage => $page, template => $template);
 141         });
 142
 143         $content=$template->output;
 144
 145         run_hooks(format => sub {
 146                 $content=shift->(
 147                         page => $page,
 148                         content => $content,
 149                 );
 150         });
 151
 152         return $content;
 153 }
 154
 155 sub scan ($) {
 156         my $file=shift;
 157
 158         debug(sprintf(gettext("scanning %s"), $file));
 159
 160         my $type=pagetype($file);
 161         if (defined $type) {
 162                 my $srcfile=srcfile($file);
 163                 my $content=readfile($srcfile);
 164                 my $page=pagename($file);
 165                 will_render($page, htmlpage($page), 1);
 166
 167                 if ($config{discussion}) {
 168                         # Discussion links are a special case since they're
 169                         # not in the text of the page, but on its template.
 170                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 171                 }
 172                 else {
 173                         $links{$page}=[];
 174                 }
 175                 delete $typedlinks{$page};
 176
 177                 run_hooks(scan => sub {
 178                         shift->(
 179                                 page => $page,
 180                                 content => $content,
 181                         );
 182                 });
 183
 184                 # Preprocess in scan-only mode.
 185                 preprocess($page, $page, $content, 1);
 186
 187                 run_hooks(rescan => sub {
 188                         shift->(
 189                                 page => $page,
 190                                 content => $content,
 191                         );
 192                 });
 193
 194         }
 195         else {
 196                 will_render($file, $file, 1);
 197         }
 198 }
 199
 200 sub fast_file_copy (@) {
 201         my $srcfile=shift;
 202         my $destfile=shift;
 203         my $srcfd=shift;
 204         my $destfd=shift;
 205         my $cleanup=shift;
 206
 207         my $blksize = 16384;
 208         my ($len, $buf, $written);
 209         while ($len = sysread $srcfd, $buf, $blksize) {
 210                 if (! defined $len) {
 211                         next if $! =~ /^Interrupted/;
 212                         error("failed to read $srcfile: $!", $cleanup);
 213                 }
 214                 my $offset = 0;
 215                 while ($len) {
 216                         defined($written = syswrite $destfd, $buf, $len, $offset)
 217                                 or error("failed to write $destfile: $!", $cleanup);
 218                         $len -= $written;
 219                         $offset += $written;
 220                 }
 221         }
 222 }
 223
 224 sub render ($$) {
 225         my $file=shift;
 226         return if $rendered{$file};
 227         debug(shift);
 228         $rendered{$file}=1;
 229
 230         my $type=pagetype($file);
 231         my $srcfile=srcfile($file);
 232         if (defined $type) {
 233                 my $page=pagename($file);
 234                 delete $depends{$page};
 235                 delete $depends_simple{$page};
 236                 will_render($page, htmlpage($page), 1);
 237                 return if $type=~/^_/;
 238
 239                 my $content=htmlize($page, $page, $type,
 240                         linkify($page, $page,
 241                         preprocess($page, $page,
 242                         filter($page, $page,
 243                         readfile($srcfile)))));
 244
 245                 my $output=htmlpage($page);
 246                 writefile($output, $config{destdir}, genpage($page, $content));
 247         }
 248         else {
 249                 delete $depends{$file};
 250                 delete $depends_simple{$file};
 251                 will_render($file, $file, 1);
 252
 253                 if ($config{hardlink}) {
 254                         # only hardlink if owned by same user
 255                         my @stat=stat($srcfile);
 256                         if ($stat[4] == $>) {
 257                                 prep_writefile($file, $config{destdir});
 258                                 unlink($config{destdir}."/".$file);
 259                                 if (link($srcfile, $config{destdir}."/".$file)) {
 260                                         return;
 261                                 }
 262                         }
 263                         # if hardlink fails, fall back to copying
 264                 }
 265
 266                 my $srcfd=readfile($srcfile, 1, 1);
 267                 writefile($file, $config{destdir}, undef, 1, sub {
 268                         fast_file_copy($srcfile, $file, $srcfd, @_);
 269                 });
 270         }
 271 }
 272
 273 sub prune ($) {
 274         my $file=shift;
 275
 276         unlink($file);
 277         my $dir=dirname($file);
 278         while (rmdir($dir)) {
 279                 $dir=dirname($dir);
 280         }
 281 }
 282
 283 sub srcdir_check () {
 284         # security check, avoid following symlinks in the srcdir path by default
 285         my $test=$config{srcdir};
 286         while (length $test) {
 287                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 288                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 289                 }
 290                 unless ($test=~s/\/+$//) {
 291                         $test=dirname($test);
 292                 }
 293         }
 294
 295 }
 296
 297 sub find_src_files () {
 298         my @files;
 299         my %pages;
 300         eval q{use File::Find};
 301         error($@) if $@;
 302
 303         eval q{use Cwd};
 304         die $@ if $@;
 305         my $origdir=getcwd();
 306         my $abssrcdir=Cwd::abs_path($config{srcdir});
 307
 308         my ($page, $underlay);
 309         my $helper=sub {
 310                 my $file=decode_utf8($_);
 311
 312                 return if -l $file || -d _;
 313                 $file=~s/^\.\///;
 314                 return if ! length $file;
 315                 $page = pagename($file);
 316                 if (! exists $pagesources{$page} &&
 317                     file_pruned($file)) {
 318                         $File::Find::prune=1;
 319                         return;
 320                 }
 321
 322                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 323                 if (! defined $f) {
 324                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 325                         return;
 326                 }
 327
 328                 if ($underlay) {
 329                         # avoid underlaydir override attacks; see security.mdwn
 330                         if (! -l "$abssrcdir/$f" && ! -e _) {
 331                                 if (! $pages{$page}) {
 332                                         push @files, $f;
 333                                         $pages{$page}=1;
 334                                 }
 335                         }
 336                 }
 337                 else {
 338                         push @files, $f;
 339                         if ($pages{$page}) {
 340                                 debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 341                         }
 342                         $pages{$page}=1;
 343                 }
 344         };
 345
 346         chdir($config{srcdir}) || die "chdir $config{srcdir}: $!";
 347         find({
 348                 no_chdir => 1,
 349                 wanted => $helper,
 350         }, '.');
 351         chdir($origdir) || die "chdir $origdir: $!";
 352
 353         $underlay=1;
 354         foreach (@{$config{underlaydirs}}, $config{underlaydir}) {
 355                 if (chdir($_)) {
 356                         find({
 357                                 no_chdir => 1,
 358                                 wanted => $helper,
 359                         }, '.');
 360                         chdir($origdir) || die "chdir: $!";
 361                 }
 362         };
 363
 364         return \@files, \%pages;
 365 }
 366
 367 sub find_new_files ($) {
 368         my $files=shift;
 369         my @new;
 370         my @internal_new;
 371
 372         my $times_noted;
 373
 374         foreach my $file (@$files) {
 375                 my $page=pagename($file);
 376
 377                 if ($config{rcs} && $config{gettime} &&
 378                     -e "$config{srcdir}/$file") {
 379                         if (! $times_noted) {
 380                                 debug(sprintf(gettext("querying %s for file creation and modification times.."), $config{rcs}));
 381                                 $times_noted=1;
 382                         }
 383
 384                         eval {
 385                                 my $ctime=rcs_getctime($file);
 386                                 if ($ctime > 0) {
 387                                         $pagectime{$page}=$ctime;
 388                                 }
 389                         };
 390                         if ($@) {
 391                                 print STDERR $@;
 392                         }
 393                         my $mtime;
 394                         eval {
 395                                 $mtime=rcs_getmtime($file);
 396                         };
 397                         if ($@) {
 398                                 print STDERR $@;
 399                         }
 400                         elsif ($mtime > 0) {
 401                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 402                         }
 403                 }
 404
 405                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 406                         # the page has changed its type
 407                         $forcerebuild{$page}=1;
 408                 }
 409                 $pagesources{$page}=$file;
 410                 if (! $pagemtime{$page}) {
 411                         if (isinternal($page)) {
 412                                 push @internal_new, $file;
 413                         }
 414                         else {
 415                                 push @new, $file;
 416                         }
 417                         $pagecase{lc $page}=$page;
 418                         if (! exists $pagectime{$page}) {
 419                                 $pagectime{$page}=(srcfile_stat($file))[10];
 420                         }
 421                 }
 422         }
 423
 424         return \@new, \@internal_new;
 425 }
 426
 427 sub find_del_files ($) {
 428         my $pages=shift;
 429         my @del;
 430         my @internal_del;
 431
 432         foreach my $page (keys %pagesources) {
 433                 if (! $pages->{$page}) {
 434                         if (isinternal($page)) {
 435                                 push @internal_del, $pagesources{$page};
 436                         }
 437                         else {
 438                                 push @del, $pagesources{$page};
 439                         }
 440                         $links{$page}=[];
 441                         delete $typedlinks{$page};
 442                         $renderedfiles{$page}=[];
 443                         $pagemtime{$page}=0;
 444                 }
 445         }
 446
 447         return \@del, \@internal_del;
 448 }
 449
 450 sub remove_del (@) {
 451         foreach my $file (@_) {
 452                 my $page=pagename($file);
 453                 if (! isinternal($page)) {
 454                         debug(sprintf(gettext("removing obsolete %s"), $page));
 455                 }
 456
 457                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 458                         prune($config{destdir}."/".$old);
 459                 }
 460
 461                 foreach my $source (keys %destsources) {
 462                         if ($destsources{$source} eq $page) {
 463                                 delete $destsources{$source};
 464                         }
 465                 }
 466
 467                 delete $pagecase{lc $page};
 468                 $delpagesources{$page}=$pagesources{$page};
 469                 delete $pagesources{$page};
 470         }
 471 }
 472
 473 sub find_changed ($) {
 474         my $files=shift;
 475         my @changed;
 476         my @internal_changed;
 477         foreach my $file (@$files) {
 478                 my $page=pagename($file);
 479                 my ($srcfile, @stat)=srcfile_stat($file);
 480                 if (! exists $pagemtime{$page} ||
 481                     $stat[9] > $pagemtime{$page} ||
 482                     $forcerebuild{$page}) {
 483                         $pagemtime{$page}=$stat[9];
 484
 485                         if (isinternal($page)) {
 486                                 # Preprocess internal page in scan-only mode.
 487                                 preprocess($page, $page, readfile($srcfile), 1);
 488                                 push @internal_changed, $file;
 489                         }
 490                         else {
 491                                 push @changed, $file;
 492                         }
 493                 }
 494         }
 495         return \@changed, \@internal_changed;
 496 }
 497
 498 sub calculate_old_links ($$) {
 499         my ($changed, $del)=@_;
 500         my %oldlink_targets;
 501         foreach my $file (@$changed, @$del) {
 502                 my $page=pagename($file);
 503                 if (exists $oldlinks{$page}) {
 504                         foreach my $l (@{$oldlinks{$page}}) {
 505                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 506                         }
 507                 }
 508         }
 509         return \%oldlink_targets;
 510 }
 511
 512 sub derender_internal ($) {
 513         my $file=shift;
 514         my $page=pagename($file);
 515         delete $depends{$page};
 516         delete $depends_simple{$page};
 517         foreach my $old (@{$renderedfiles{$page}}) {
 518                 delete $destsources{$old};
 519         }
 520         $renderedfiles{$page}=[];
 521 }
 522
 523 sub render_linkers ($) {
 524         my $f=shift;
 525         my $p=pagename($f);
 526         foreach my $page (keys %{$backlinks{$p}}) {
 527                 my $file=$pagesources{$page};
 528                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 529         }
 530 }
 531
 532 sub remove_unrendered () {
 533         foreach my $src (keys %rendered) {
 534                 my $page=pagename($src);
 535                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 536                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 537                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 538                                 prune($config{destdir}."/".$file);
 539                         }
 540                 }
 541         }
 542 }
 543
 544 sub link_types_changed ($$) {
 545         # each is of the form { type => { link => 1 } }
 546         my $new = shift;
 547         my $old = shift;
 548
 549         return 0 if !defined $new && !defined $old;
 550         return 1 if (!defined $new && %$old) || (!defined $old && %$new);
 551
 552         while (my ($type, $links) = each %$new) {
 553                 foreach my $link (keys %$links) {
 554                         return 1 unless exists $old->{$type}{$link};
 555                 }
 556         }
 557
 558         while (my ($type, $links) = each %$old) {
 559                 foreach my $link (keys %$links) {
 560                         return 1 unless exists $new->{$type}{$link};
 561                 }
 562         }
 563
 564         return 0;
 565 }
 566
 567 sub calculate_changed_links ($$$) {
 568         my ($changed, $del, $oldlink_targets)=@_;
 569
 570         my (%backlinkchanged, %linkchangers);
 571
 572         foreach my $file (@$changed, @$del) {
 573                 my $page=pagename($file);
 574
 575                 if (exists $links{$page}) {
 576                         foreach my $l (@{$links{$page}}) {
 577                                 my $target=bestlink($page, $l);
 578                                 if (! exists $oldlink_targets->{$page}{$l} ||
 579                                     $target ne $oldlink_targets->{$page}{$l}) {
 580                                         $backlinkchanged{$target}=1;
 581                                         $linkchangers{lc($page)}=1;
 582                                 }
 583                                 delete $oldlink_targets->{$page}{$l};
 584                         }
 585                 }
 586                 if (exists $oldlink_targets->{$page} &&
 587                     %{$oldlink_targets->{$page}}) {
 588                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 589                                 $backlinkchanged{$target}=1;
 590                         }
 591                         $linkchangers{lc($page)}=1;
 592                 }
 593
 594                 # we currently assume that changing the type of a link doesn't
 595                 # change backlinks
 596                 if (!exists $linkchangers{lc($page)}) {
 597                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 598                                 $linkchangers{lc($page)}=1;
 599                         }
 600                 }
 601         }
 602
 603         return \%backlinkchanged, \%linkchangers;
 604 }
 605
 606 sub render_dependent ($$$$$$$) {
 607         my ($files, $new, $internal_new, $del, $internal_del,
 608                 $internal_changed, $linkchangers)=@_;
 609
 610         my @changed=(keys %rendered, @$del);
 611         my @exists_changed=(@$new, @$del);
 612
 613         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 614         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 615
 616         foreach my $p ("templates/page.tmpl", keys %{$depends_simple{""}}) {
 617                 if ($rendered{$p} || grep { $_ eq $p } @$del) {
 618                         foreach my $f (@$files) {
 619                                 next if $rendered{$f};
 620                                 render($f, sprintf(gettext("building %s, which depends on %s"), $f, $p));
 621                         }
 622                         return 0;
 623                 }
 624         }
 625
 626         foreach my $f (@$files) {
 627                 next if $rendered{$f};
 628                 my $p=pagename($f);
 629                 my $reason = undef;
 630
 631                 if (exists $depends_simple{$p} && ! defined $reason) {
 632                         foreach my $d (keys %{$depends_simple{$p}}) {
 633                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 634                                      $lc_changed{$d})
 635                                     ||
 636                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 637                                      $lc_exists_changed{$d})
 638                                     ||
 639                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 640                                      $linkchangers->{$d})
 641                                 ) {
 642                                         $reason = $d;
 643                                         last;
 644                                 }
 645                         }
 646                 }
 647
 648                 if (exists $depends{$p} && ! defined $reason) {
 649                         foreach my $dep (keys %{$depends{$p}}) {
 650                                 my $sub=pagespec_translate($dep);
 651                                 next unless defined $sub;
 652
 653                                 # only consider internal files
 654                                 # if the page explicitly depends
 655                                 # on such files
 656                                 my $internal_dep=$dep =~ /(?:internal|comment|comment_pending)\(/;
 657
 658                                 my $in=sub {
 659                                         my $list=shift;
 660                                         my $type=shift;
 661                                         foreach my $file (@$list) {
 662                                                 next if $file eq $f;
 663                                                 my $page=pagename($file);
 664                                                 if ($sub->($page, location => $p)) {
 665                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 666                                                                 next unless $linkchangers->{lc($page)};
 667                                                         }
 668                                                         $reason=$page;
 669                                                         return 1;
 670                                                 }
 671                                         }
 672                                         return undef;
 673                                 };
 674
 675                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 676                                         last if $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 677                                         last if $internal_dep && (
 678                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 679                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 680                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT)
 681                                         );
 682                                 }
 683                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 684                                         last if $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 685                                         last if $internal_dep && (
 686                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 687                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE)
 688                                         );
 689                                 }
 690                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 691                                         last if $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 692                                         last if $internal_dep && (
 693                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 694                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 695                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS)
 696                                         );
 697                                 }
 698                         }
 699                 }
 700
 701                 if (defined $reason) {
 702                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 703                         return 1;
 704                 }
 705         }
 706
 707         return 0;
 708 }
 709
 710 sub render_backlinks ($) {
 711         my $backlinkchanged=shift;
 712         foreach my $link (keys %$backlinkchanged) {
 713                 my $linkfile=$pagesources{$link};
 714                 if (defined $linkfile) {
 715                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 716                 }
 717         }
 718 }
 719
 720 sub gen_autofile ($$$) {
 721         my $autofile=shift;
 722         my $pages=shift;
 723         my $del=shift;
 724
 725         if (file_pruned($autofile)) {
 726                 return;
 727         }
 728
 729         my ($file)="$config{srcdir}/$autofile" =~ /$config{wiki_file_regexp}/; # untaint
 730         if (! defined $file) {
 731                 return;
 732         }
 733
 734         # Remember autofiles that were tried, and never try them again later.
 735         if (exists $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}) {
 736                 return;
 737         }
 738         $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}=1;
 739
 740         if (srcfile($autofile, 1) || file_pruned($autofile)) {
 741                 return;
 742         }
 743
 744         if (-l $file || -d _ || -e _) {
 745                 return;
 746         }
 747
 748         my $page = pagename($file);
 749         if ($pages->{$page}) {
 750                 return;
 751         }
 752
 753         if (grep { $_ eq $autofile } @$del) {
 754                 return;
 755         }
 756
 757         $autofiles{$autofile}{generator}->();
 758         $pages->{$page}=1;
 759         return 1;
 760 }
 761
 762
 763 sub refresh () {
 764         srcdir_check();
 765         run_hooks(refresh => sub { shift->() });
 766         my ($files, $pages)=find_src_files();
 767         my ($new, $internal_new)=find_new_files($files);
 768         my ($del, $internal_del)=find_del_files($pages);
 769         my ($changed, $internal_changed)=find_changed($files);
 770         run_hooks(needsbuild => sub { shift->($changed) });
 771         my $oldlink_targets=calculate_old_links($changed, $del);
 772
 773         foreach my $file (@$changed) {
 774                 scan($file);
 775         }
 776
 777         foreach my $autofile (keys %autofiles) {
 778                 if (gen_autofile($autofile, $pages, $del)) {
 779                         push @{$files}, $autofile;
 780                         push @{$new}, $autofile if find_new_files([$autofile]);
 781                         push @{$changed}, $autofile if find_changed([$autofile]);
 782
 783                         scan($autofile);
 784                 }
 785         }
 786
 787         calculate_links();
 788
 789         remove_del(@$del, @$internal_del);
 790
 791         foreach my $file (@$changed) {
 792                 render($file, sprintf(gettext("building %s"), $file));
 793         }
 794         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 795                 derender_internal($file);
 796         }
 797
 798         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 799                 $del, $oldlink_targets);
 800
 801         foreach my $file (@$new, @$del) {
 802                 render_linkers($file);
 803         }
 804
 805         if (@$changed || @$internal_changed ||
 806             @$del || @$internal_del || @$internal_new) {
 807                 1 while render_dependent($files, $new, $internal_new,
 808                         $del, $internal_del, $internal_changed,
 809                         $linkchangers);
 810         }
 811
 812         render_backlinks($backlinkchanged);
 813         remove_unrendered();
 814
 815         if (@$del || @$internal_del) {
 816                 run_hooks(delete => sub { shift->(@$del, @$internal_del) });
 817         }
 818         if (%rendered) {
 819                 run_hooks(change => sub { shift->(keys %rendered) });
 820         }
 821 }
 822
 823 sub clean_rendered {
 824         lockwiki();
 825         loadindex();
 826         remove_unrendered();
 827         foreach my $page (keys %oldrenderedfiles) {
 828                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 829                         prune($config{destdir}."/".$file);
 830                 }
 831         }
 832 }
 833
 834 sub commandline_render () {
 835         lockwiki();
 836         loadindex();
 837         unlockwiki();
 838
 839         my $srcfile=possibly_foolish_untaint($config{render});
 840         my $file=$srcfile;
 841         $file=~s/\Q$config{srcdir}\E\/?//;
 842
 843         my $type=pagetype($file);
 844         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 845         my $content=readfile($srcfile);
 846         my $page=pagename($file);
 847         $pagesources{$page}=$file;
 848         $content=filter($page, $page, $content);
 849         $content=preprocess($page, $page, $content);
 850         $content=linkify($page, $page, $content);
 851         $content=htmlize($page, $page, $type, $content);
 852         $pagemtime{$page}=(stat($srcfile))[9];
 853         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 854
 855         print genpage($page, $content);
 856         exit 0;
 857 }
 858
 859 1