git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/recentchanges.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::recentchanges;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8 use HTML::Entities;
   9
  10 sub import {
  11         hook(type => "getsetup", id => "recentchanges", call => \&getsetup);
  12         hook(type => "checkconfig", id => "recentchanges", call => \&checkconfig);
  13         hook(type => "refresh", id => "recentchanges", call => \&refresh);
  14         hook(type => "pagetemplate", id => "recentchanges", call => \&pagetemplate);
  15         hook(type => "htmlize", id => "_change", call => \&htmlize);
  16         hook(type => "sessioncgi", id => "recentchanges", call => \&sessioncgi);
  17         # Load goto to fix up links from recentchanges
  18         IkiWiki::loadplugin("goto");
  19 }
  20
  21 sub getsetup () {
  22         return
  23                 plugin => {
  24                         safe => 1,
  25                         rebuild => 1,
  26                 },
  27                 recentchangespage => {
  28                         type => "string",
  29                         example => "recentchanges",
  30                         description => "name of the recentchanges page",
  31                         safe => 1,
  32                         rebuild => 1,
  33                 },
  34                 recentchangesnum => {
  35                         type => "integer",
  36                         example => 100,
  37                         description => "number of changes to track",
  38                         safe => 1,
  39                         rebuild => 0,
  40                 },
  41 }
  42
  43 sub checkconfig () {
  44         $config{recentchangespage}='recentchanges' unless defined $config{recentchangespage};
  45         $config{recentchangesnum}=100 unless defined $config{recentchangesnum};
  46 }
  47
  48 sub refresh ($) {
  49         my %seen;
  50
  51         # add new changes
  52         foreach my $change (IkiWiki::rcs_recentchanges($config{recentchangesnum})) {
  53                 $seen{store($change, $config{recentchangespage})}=1;
  54         }
  55
  56         # delete old and excess changes
  57         foreach my $page (keys %pagesources) {
  58                 if ($pagesources{$page} =~ /\._change$/ && ! $seen{$page}) {
  59                         unlink($config{srcdir}.'/'.$pagesources{$page});
  60                 }
  61         }
  62 }
  63
  64 sub confirmation_form {
  65         my ($q, $session, $rev) = @_;
  66
  67         eval q{use CGI::FormBuilder};
  68         error($@) if $@;
  69         my $f = CGI::FormBuilder->new(
  70                 name => "revert",
  71                 header => 0,
  72                 charset => "utf-8",
  73                 method => 'POST',
  74                 javascript => 0,
  75                 params => $q,
  76                 action => $config{cgiurl},
  77                 stylesheet => 1,
  78                 template => { template('revert.tmpl') },
  79         );
  80
  81         $f->field(name => "sid", type => "hidden", value => $session->id,
  82                 force => 1);
  83         $f->field(name => "do", type => "hidden", value => "revert",
  84                 force => 1);
  85
  86         return $f, ["Revert", "Cancel"];
  87 }
  88
  89 sub sessioncgi ($$) {
  90         my ($q, $session) = @_;
  91         my $do = $q->param('do');
  92         my $rev = $q->param('rev');
  93
  94         return unless $do eq 'revert' && $rev;
  95
  96         IkiWiki::rcs_preprevert(cgi => $q, session => $session, rev => $rev);
  97
  98         my ($form, $buttons) = confirmation_form($q, $session);
  99         IkiWiki::decode_form_utf8($form);
 100
 101         if ($form->submitted eq 'Revert' && $form->validate) {
 102                 IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 103                 IkiWiki::disable_commit_hook();
 104                 my $r = IkiWiki::rcs_revert($rev);
 105                 if (! defined $r) { # success
 106                         rcs_commit_staged(
 107                                 message => sprintf(gettext("This reverts commit %s"), $rev),
 108                                 session => $session,
 109                                 rev => $rev,
 110                         );
 111                 }
 112                 IkiWiki::enable_commit_hook();
 113
 114                 if (defined $r) {
 115                         die "Revert '$rev' failed.";
 116                 }
 117                 else {
 118                         require IkiWiki::Render;
 119                         IkiWiki::refresh();
 120                         IkiWiki::saveindex();
 121                 }
 122         }
 123         elsif ($form->submitted ne 'Cancel') {
 124                 $form->title(sprintf(gettext("confirm reversion of %s"), $rev));
 125                 $form->tmpl_param(diff => encode_entities(scalar IkiWiki::rcs_diff($rev)));
 126                 $form->field(name => "rev", type => "hidden", value => $rev, force => 1);
 127                 IkiWiki::showform($form, $buttons, $session, $q);
 128                 exit 0;
 129         }
 130
 131         IkiWiki::redirect($q, urlto($config{recentchangespage}, ''));
 132         exit 0;
 133 }
 134
 135 # Enable the recentchanges link.
 136 sub pagetemplate (@) {
 137         my %params=@_;
 138         my $template=$params{template};
 139         my $page=$params{page};
 140
 141         if (defined $config{recentchangespage} && $config{rcs} &&
 142             $template->query(name => "recentchangesurl") &&
 143             $page ne $config{recentchangespage}) {
 144                 $template->param(recentchangesurl => urlto($config{recentchangespage}, $page));
 145                 $template->param(have_actions => 1);
 146         }
 147 }
 148
 149 # Pages with extension _change have plain html markup, pass through.
 150 sub htmlize (@) {
 151         my %params=@_;
 152         return $params{content};
 153 }
 154
 155 sub store ($$$) {
 156         my $change=shift;
 157
 158         my $page="$config{recentchangespage}/change_".titlepage($change->{rev});
 159
 160         # Optimisation to avoid re-writing pages. Assumes commits never
 161         # change (or that any changes are not important).
 162         return $page if exists $pagesources{$page} && ! $config{rebuild};
 163
 164         # Limit pages to first 10, and add links to the changed pages.
 165         my $is_excess = exists $change->{pages}[10];
 166         delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
 167         $change->{pages} = [
 168                 map {
 169                         if (length $config{cgiurl}) {
 170                                 $_->{link} = "<a href=\"".
 171                                         IkiWiki::cgiurl(
 172                                                 do => "goto",
 173                                                 page => $_->{page}
 174                                         ).
 175                                         "\" rel=\"nofollow\">".
 176                                         pagetitle($_->{page}).
 177                                         "</a>"
 178                         }
 179                         else {
 180                                 $_->{link} = pagetitle($_->{page});
 181                         }
 182                         $_->{baseurl}="$config{url}/" if length $config{url};
 183
 184                         $_;
 185                 } @{$change->{pages}}
 186         ];
 187         push @{$change->{pages}}, { link => '...' } if $is_excess;
 188
 189         if (length $config{cgiurl}) {
 190                 $change->{reverturl} = IkiWiki::cgiurl(
 191                         do => "revert",
 192                         rev => $change->{rev}
 193                 );
 194         }
 195
 196         $change->{author}=$change->{user};
 197         my $oiduser=eval { IkiWiki::openiduser($change->{user}) };
 198         if (defined $oiduser) {
 199                 $change->{authorurl}=$change->{user};
 200                 $change->{user}=defined $change->{nickname} ? $change->{nickname} : $oiduser;
 201         }
 202         elsif (length $config{cgiurl}) {
 203                 $change->{authorurl} = IkiWiki::cgiurl(
 204                         do => "goto",
 205                         page => IkiWiki::userpage($change->{author}),
 206                 );
 207         }
 208
 209         if (ref $change->{message}) {
 210                 foreach my $field (@{$change->{message}}) {
 211                         if (exists $field->{line}) {
 212                                 # escape html
 213                                 $field->{line} = encode_entities($field->{line});
 214                                 # escape links and preprocessor stuff
 215                                 $field->{line} = encode_entities($field->{line}, '\[\]');
 216                         }
 217                 }
 218         }
 219
 220         # Fill out a template with the change info.
 221         my $template=template("change.tmpl", blind_cache => 1);
 222         $template->param(
 223                 %$change,
 224                 commitdate => displaytime($change->{when}, "%X %x"),
 225                 wikiname => $config{wikiname},
 226         );
 227
 228         $template->param(permalink => "$config{url}/$config{recentchangespage}/#change-".titlepage($change->{rev}))
 229                 if exists $config{url};
 230
 231         IkiWiki::run_hooks(pagetemplate => sub {
 232                 shift->(page => $page, destpage => $page,
 233                         template => $template, rev => $change->{rev});
 234         });
 235
 236         my $file=$page."._change";
 237         writefile($file, $config{srcdir}, $template->output);
 238         utime $change->{when}, $change->{when}, "$config{srcdir}/$file";
 239
 240         return $page;
 241 }
 242
 243 1