git.oblomov.eu Git - ikiwiki/blob - ikiwiki

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3
   4 use warnings;
   5 use strict;
   6 use Memoize;
   7 use File::Spec;
   8 use HTML::Template;
   9 use Getopt::Long;
  10
  11 my (%links, %oldlinks, %oldpagemtime, %renderedfiles, %pagesources);
  12
  13 my %config=( #{{{
  14         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$)},
  15         wiki_link_regexp => qr/\[\[([^\s]+)\]\]/,
  16         wiki_file_regexp => qr/(^[-A-Za-z0-9_.:\/+]+$)/,
  17         verbose => 0,
  18         wikiname => "wiki",
  19         default_pageext => ".mdwn",
  20         cgi => 0,
  21         svn => 1,
  22         url => '',
  23         cgiurl => '',
  24         historyurl => '',
  25         anonok => 0,
  26         rebuild => 0,
  27         wrapper => undef,
  28         wrappermode => undef,
  29         srcdir => undef,
  30         destdir => undef,
  31         templatedir => undef,
  32         setup => undef,
  33 ); #}}}
  34
  35 GetOptions( #{{{
  36         "setup=s" => \$config{setup},
  37         "wikiname=s" => \$config{wikiname},
  38         "verbose|v!" => \$config{verbose},
  39         "rebuild!" => \$config{rebuild},
  40         "wrapper=s" => sub { $config{wrapper}=$_[1] ? $_[1] : "ikiwiki-wrap" },
  41         "wrappermode=i" => \$config{wrappermode},
  42         "svn!" => \$config{svn},
  43         "anonok!" => \$config{anonok},
  44         "cgi!" => \$config{cgi},
  45         "url=s" => \$config{url},
  46         "cgiurl=s" => \$config{cgiurl},
  47         "historyurl=s" => \$config{historyurl},
  48         "exclude=s@" => sub {
  49                 $config{wiki_file_prune_regexp}=qr/$config{wiki_file_prune_regexp}|$_[1]/;
  50         },
  51 ) || usage();
  52
  53 if (! $config{setup}) {
  54         usage() unless @ARGV == 3;
  55         $config{srcdir} = possibly_foolish_untaint(shift);
  56         $config{templatedir} = possibly_foolish_untaint(shift);
  57         $config{destdir} = possibly_foolish_untaint(shift);
  58         if ($config{cgi} && ! length $config{url}) {
  59                 error("Must specify url to wiki with --url when using --cgi");
  60         }
  61 }
  62 #}}}
  63
  64 sub usage { #{{{
  65         die "usage: ikiwiki [options] source templates dest\n";
  66 } #}}}
  67
  68 sub error { #{{{
  69         if ($config{cgi}) {
  70                 print "Content-type: text/html\n\n";
  71                 print misctemplate("Error", "<p>Error: @_</p>");
  72         }
  73         die @_;
  74 } #}}}
  75
  76 sub debug ($) { #{{{
  77         return unless $config{verbose};
  78         if (! $config{cgi}) {
  79                 print "@_\n";
  80         }
  81         else {
  82                 print STDERR "@_\n";
  83         }
  84 } #}}}
  85
  86 sub mtime ($) { #{{{
  87         my $page=shift;
  88
  89         return (stat($page))[9];
  90 } #}}}
  91
  92 sub possibly_foolish_untaint { #{{{
  93         my $tainted=shift;
  94         my ($untainted)=$tainted=~/(.*)/;
  95         return $untainted;
  96 } #}}}
  97
  98 sub basename ($) { #{{{
  99         my $file=shift;
 100
 101         $file=~s!.*/!!;
 102         return $file;
 103 } #}}}
 104
 105 sub dirname ($) { #{{{
 106         my $file=shift;
 107
 108         $file=~s!/?[^/]+$!!;
 109         return $file;
 110 } #}}}
 111
 112 sub pagetype ($) { #{{{
 113         my $page=shift;
 114
 115         if ($page =~ /\.mdwn$/) {
 116                 return ".mdwn";
 117         }
 118         else {
 119                 return "unknown";
 120         }
 121 } #}}}
 122
 123 sub pagename ($) { #{{{
 124         my $file=shift;
 125
 126         my $type=pagetype($file);
 127         my $page=$file;
 128         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 129         return $page;
 130 } #}}}
 131
 132 sub htmlpage ($) { #{{{
 133         my $page=shift;
 134
 135         return $page.".html";
 136 } #}}}
 137
 138 sub readfile ($) { #{{{
 139         my $file=shift;
 140
 141         local $/=undef;
 142         open (IN, "$file") || error("failed to read $file: $!");
 143         my $ret=<IN>;
 144         close IN;
 145         return $ret;
 146 } #}}}
 147
 148 sub writefile ($$) { #{{{
 149         my $file=shift;
 150         my $content=shift;
 151
 152         my $dir=dirname($file);
 153         if (! -d $dir) {
 154                 my $d="";
 155                 foreach my $s (split(m!/+!, $dir)) {
 156                         $d.="$s/";
 157                         if (! -d $d) {
 158                                 mkdir($d) || error("failed to create directory $d: $!");
 159                         }
 160                 }
 161         }
 162
 163         open (OUT, ">$file") || error("failed to write $file: $!");
 164         print OUT $content;
 165         close OUT;
 166 } #}}}
 167
 168 sub findlinks ($) { #{{{
 169         my $content=shift;
 170
 171         my @links;
 172         while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 173                 push @links, lc($1);
 174         }
 175         return @links;
 176 } #}}}
 177
 178 sub bestlink ($$) { #{{{
 179         # Given a page and the text of a link on the page, determine which
 180         # existing page that link best points to. Prefers pages under a
 181         # subdirectory with the same name as the source page, failing that
 182         # goes down the directory tree to the base looking for matching
 183         # pages.
 184         my $page=shift;
 185         my $link=lc(shift);
 186
 187         my $cwd=$page;
 188         do {
 189                 my $l=$cwd;
 190                 $l.="/" if length $l;
 191                 $l.=$link;
 192
 193                 if (exists $links{$l}) {
 194                         #debug("for $page, \"$link\", use $l");
 195                         return $l;
 196                 }
 197         } while $cwd=~s!/?[^/]+$!!;
 198
 199         #print STDERR "warning: page $page, broken link: $link\n";
 200         return "";
 201 } #}}}
 202
 203 sub isinlinableimage ($) { #{{{
 204         my $file=shift;
 205
 206         $file=~/\.(png|gif|jpg|jpeg)$/;
 207 } #}}}
 208
 209 sub htmllink { #{{{
 210         my $page=shift;
 211         my $link=shift;
 212         my $noimageinline=shift; # don't turn links into inline html images
 213         my $createsubpage=shift; # force creation of a subpage if page DNE
 214
 215         my $bestlink=bestlink($page, $link);
 216
 217         return $link if length $bestlink && $page eq $bestlink;
 218
 219         # TODO BUG: %renderedfiles may not have it, if the linked to page
 220         # was also added and isn't yet rendered! Note that this bug is
 221         # masked by the bug mentioned below that makes all new files
 222         # be rendered twice.
 223         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 224                 $bestlink=htmlpage($bestlink);
 225         }
 226         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 227                 if (! $createsubpage) {
 228                         return "<a href=\"$config{cgiurl}?do=create&page=$link&from=$page\">?</a>$link"
 229                 }
 230                 else {
 231                         return "<a href=\"$config{cgiurl}?do=create&page=$page/$link\">?</a>$link"
 232                 }
 233         }
 234
 235         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 236
 237         if (! $noimageinline && isinlinableimage($bestlink)) {
 238                 return "<img src=\"$bestlink\">";
 239         }
 240         return "<a href=\"$bestlink\">$link</a>";
 241 } #}}}
 242
 243 sub linkify ($$) { #{{{
 244         my $content=shift;
 245         my $file=shift;
 246
 247         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 248                 $1 ? "[[$2]]" : htmllink(pagename($file), $2)
 249         }eg;
 250
 251         return $content;
 252 } #}}}
 253
 254 sub htmlize ($$) { #{{{
 255         my $type=shift;
 256         my $content=shift;
 257
 258         if (! $INC{"/usr/bin/markdown"}) {
 259                 no warnings 'once';
 260                 $blosxom::version="is a proper perl module too much to ask?";
 261                 use warnings 'all';
 262                 do "/usr/bin/markdown";
 263         }
 264
 265         if ($type eq '.mdwn') {
 266                 return Markdown::Markdown($content);
 267         }
 268         else {
 269                 error("htmlization of $type not supported");
 270         }
 271 } #}}}
 272
 273 sub backlinks ($) { #{{{
 274         my $page=shift;
 275
 276         my @links;
 277         foreach my $p (keys %links) {
 278                 next if bestlink($page, $p) eq $page;
 279                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 280                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 281
 282                         # Trim common dir prefixes from both pages.
 283                         my $p_trimmed=$p;
 284                         my $page_trimmed=$page;
 285                         my $dir;
 286                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
 287                                 defined $dir &&
 288                                 $p_trimmed=~s/^\Q$dir\E// &&
 289                                 $page_trimmed=~s/^\Q$dir\E//;
 290
 291                         push @links, { url => $href, page => $p_trimmed };
 292                 }
 293         }
 294
 295         return sort { $a->{page} cmp $b->{page} } @links;
 296 } #}}}
 297
 298 sub parentlinks ($) { #{{{
 299         my $page=shift;
 300
 301         my @ret;
 302         my $pagelink="";
 303         my $path="";
 304         my $skip=1;
 305         foreach my $dir (reverse split("/", $page)) {
 306                 if (! $skip) {
 307                         $path.="../";
 308                         unshift @ret, { url => "$path$dir.html", page => $dir };
 309                 }
 310                 else {
 311                         $skip=0;
 312                 }
 313         }
 314         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
 315         return @ret;
 316 } #}}}
 317
 318 sub indexlink () { #{{{
 319         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 320 } #}}}
 321
 322 sub finalize ($$) { #{{{
 323         my $content=shift;
 324         my $page=shift;
 325
 326         my $title=basename($page);
 327         $title=~s/_/ /g;
 328
 329         my $template=HTML::Template->new(blind_cache => 1,
 330                 filename => "$config{templatedir}/page.tmpl");
 331
 332         if (length $config{cgiurl}) {
 333                 $template->param(editurl => "$config{cgiurl}?do=edit&page=$page");
 334                 if ($config{svn}) {
 335                         $template->param(recentchangesurl => "$config{cgiurl}?do=recentchanges");
 336                 }
 337         }
 338
 339         if (length $config{historyurl}) {
 340                 my $u=$config{historyurl};
 341                 $u=~s/\[\[\]\]/$pagesources{$page}/g;
 342                 $template->param(historyurl => $u);
 343         }
 344
 345         $template->param(
 346                 title => $title,
 347                 wikiname => $config{wikiname},
 348                 parentlinks => [parentlinks($page)],
 349                 content => $content,
 350                 backlinks => [backlinks($page)],
 351                 discussionlink => htmllink($page, "Discussion", 1, 1),
 352         );
 353
 354         return $template->output;
 355 } #}}}
 356
 357 sub check_overwrite ($$) { #{{{
 358         # Important security check. Make sure to call this before saving
 359         # any files to the source directory.
 360         my $dest=shift;
 361         my $src=shift;
 362
 363         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 364                 error("$dest already exists and was rendered from ".
 365                         join(" ",(grep { $renderedfiles{$_} eq $dest } keys
 366                                 %renderedfiles)).
 367                         ", before, so not rendering from $src");
 368         }
 369 } #}}}
 370
 371 sub render ($) { #{{{
 372         my $file=shift;
 373
 374         my $type=pagetype($file);
 375         my $content=readfile("$config{srcdir}/$file");
 376         if ($type ne 'unknown') {
 377                 my $page=pagename($file);
 378
 379                 $links{$page}=[findlinks($content)];
 380
 381                 $content=linkify($content, $file);
 382                 $content=htmlize($type, $content);
 383                 $content=finalize($content, $page);
 384
 385                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 386                 writefile("$config{destdir}/".htmlpage($page), $content);
 387                 $oldpagemtime{$page}=time;
 388                 $renderedfiles{$page}=htmlpage($page);
 389         }
 390         else {
 391                 $links{$file}=[];
 392                 check_overwrite("$config{destdir}/$file", $file);
 393                 writefile("$config{destdir}/$file", $content);
 394                 $oldpagemtime{$file}=time;
 395                 $renderedfiles{$file}=$file;
 396         }
 397 } #}}}
 398
 399 sub loadindex () { #{{{
 400         open (IN, "$config{srcdir}/.ikiwiki/index") || return;
 401         while (<IN>) {
 402                 $_=possibly_foolish_untaint($_);
 403                 chomp;
 404                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 405                 my $page=pagename($file);
 406                 $pagesources{$page}=$file;
 407                 $oldpagemtime{$page}=$mtime;
 408                 $oldlinks{$page}=[@links];
 409                 $links{$page}=[@links];
 410                 $renderedfiles{$page}=$rendered;
 411         }
 412         close IN;
 413 } #}}}
 414
 415 sub saveindex () { #{{{
 416         if (! -d "$config{srcdir}/.ikiwiki") {
 417                 mkdir("$config{srcdir}/.ikiwiki");
 418         }
 419         open (OUT, ">$config{srcdir}/.ikiwiki/index") || error("cannot write to index: $!");
 420         foreach my $page (keys %oldpagemtime) {
 421                 print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 422                         join(" ", @{$links{$page}})."\n"
 423                                 if $oldpagemtime{$page};
 424         }
 425         close OUT;
 426 } #}}}
 427
 428 sub rcs_update () { #{{{
 429         if (-d "$config{srcdir}/.svn") {
 430                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
 431                         warn("svn update failed\n");
 432                 }
 433         }
 434 } #}}}
 435
 436 sub rcs_commit ($) { #{{{
 437         my $message=shift;
 438
 439         if (-d "$config{srcdir}/.svn") {
 440                 if (system("svn", "commit", "--quiet", "-m",
 441                            possibly_foolish_untaint($message),
 442                            $config{srcdir}) != 0) {
 443                         warn("svn commit failed\n");
 444                 }
 445         }
 446 } #}}}
 447
 448 sub rcs_add ($) { #{{{
 449         my $file=shift;
 450
 451         if (-d "$config{srcdir}/.svn") {
 452                 my $parent=dirname($file);
 453                 while (! -d "$config{srcdir}/$parent/.svn") {
 454                         $file=$parent;
 455                         $parent=dirname($file);
 456                 }
 457
 458                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
 459                         warn("svn add failed\n");
 460                 }
 461         }
 462 } #}}}
 463
 464 sub rcs_recentchanges ($) { #{{{
 465         my $num=shift;
 466         my @ret;
 467
 468         eval q{use Date::Parse};
 469         eval q{use Time::Duration};
 470
 471         if (-d "$config{srcdir}/.svn") {
 472                 my $info=`LANG=C svn info $config{srcdir}`;
 473                 my ($svn_url)=$info=~/^URL: (.*)$/m;
 474
 475                 # FIXME: currently assumes that the wiki is somewhere
 476                 # under trunk in svn, doesn't support other layouts.
 477                 my ($svn_base)=$svn_url=~m!(/trunk(?:/.*)?)$!;
 478
 479                 my $div=qr/^--------------------+$/;
 480                 my $infoline=qr/^r(\d+)\s+\|\s+([^\s]+)\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 481                 my $state='start';
 482                 my ($rev, $user, $when, @pages, @message);
 483                 foreach (`LANG=C svn log -v '$svn_url'`) {
 484                         chomp;
 485                         if ($state eq 'start' && /$div/) {
 486                                 $state='header';
 487                         }
 488                         elsif ($state eq 'header' && /$infoline/) {
 489                                 $rev=$1;
 490                                 $user=$2;
 491                                 $when=concise(ago(time - str2time($3)));
 492                         }
 493                         elsif ($state eq 'header' && /^\s+[A-Z]\s+\Q$svn_base\E\/(.+)$/) {
 494                                 push @pages, { link => htmllink("", pagename($1), 1) }
 495                                         if length $1;
 496                         }
 497                         elsif ($state eq 'header' && /^$/) {
 498                                 $state='body';
 499                         }
 500                         elsif ($state eq 'body' && /$div/) {
 501                                 my $committype="web";
 502                                 if (defined $message[0] &&
 503                                     $message[0]->{line}=~/^web commit by (\w+):?(.*)/) {
 504                                         $user="$1";
 505                                         $message[0]->{line}=$2;
 506                                 }
 507                                 else {
 508                                         $committype="svn";
 509                                 }
 510
 511                                 push @ret, { rev => $rev,
 512                                         user => htmllink("", $user, 1),
 513                                         committype => $committype,
 514                                         when => $when, message => [@message],
 515                                         pages => [@pages] } if @pages;
 516                                 return @ret if @ret >= $num;
 517
 518                                 $state='header';
 519                                 $rev=$user=$when=undef;
 520                                 @pages=@message=();
 521                         }
 522                         elsif ($state eq 'body') {
 523                                 push @message, {line => $_},
 524                         }
 525                 }
 526         }
 527
 528         return @ret;
 529 } #}}}
 530
 531 sub prune ($) { #{{{
 532         my $file=shift;
 533
 534         unlink($file);
 535         my $dir=dirname($file);
 536         while (rmdir($dir)) {
 537                 $dir=dirname($dir);
 538         }
 539 } #}}}
 540
 541 sub refresh () { #{{{
 542         # Find existing pages.
 543         my %exists;
 544         my @files;
 545
 546         eval q{use File::Find};
 547         find({
 548                 no_chdir => 1,
 549                 wanted => sub {
 550                         if (/$config{wiki_file_prune_regexp}/) {
 551                                 no warnings 'once';
 552                                 $File::Find::prune=1;
 553                                 use warnings "all";
 554                         }
 555                         elsif (! -d $_) {
 556                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 557                                 if (! defined $f) {
 558                                         warn("skipping bad filename $_\n");
 559                                 }
 560                                 else {
 561                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 562                                         push @files, $f;
 563                                         $exists{pagename($f)}=1;
 564                                 }
 565                         }
 566                 },
 567         }, $config{srcdir});
 568
 569         my %rendered;
 570
 571         # check for added or removed pages
 572         my @add;
 573         foreach my $file (@files) {
 574                 my $page=pagename($file);
 575                 if (! $oldpagemtime{$page}) {
 576                         debug("new page $page");
 577                         push @add, $file;
 578                         $links{$page}=[];
 579                         $pagesources{$page}=$file;
 580                 }
 581         }
 582         my @del;
 583         foreach my $page (keys %oldpagemtime) {
 584                 if (! $exists{$page}) {
 585                         debug("removing old page $page");
 586                         push @del, $renderedfiles{$page};
 587                         prune($config{destdir}."/".$renderedfiles{$page});
 588                         delete $renderedfiles{$page};
 589                         $oldpagemtime{$page}=0;
 590                         delete $pagesources{$page};
 591                 }
 592         }
 593
 594         # render any updated files
 595         foreach my $file (@files) {
 596                 my $page=pagename($file);
 597
 598                 if (! exists $oldpagemtime{$page} ||
 599                     mtime("$config{srcdir}/$file") > $oldpagemtime{$page}) {
 600                         debug("rendering changed file $file");
 601                         render($file);
 602                         $rendered{$file}=1;
 603                 }
 604         }
 605
 606         # if any files were added or removed, check to see if each page
 607         # needs an update due to linking to them
 608         # TODO: inefficient; pages may get rendered above and again here;
 609         # problem is the bestlink may have changed and we won't know until
 610         # now
 611         if (@add || @del) {
 612 FILE:           foreach my $file (@files) {
 613                         my $page=pagename($file);
 614                         foreach my $f (@add, @del) {
 615                                 my $p=pagename($f);
 616                                 foreach my $link (@{$links{$page}}) {
 617                                         if (bestlink($page, $link) eq $p) {
 618                                                 debug("rendering $file, which links to $p");
 619                                                 render($file);
 620                                                 $rendered{$file}=1;
 621                                                 next FILE;
 622                                         }
 623                                 }
 624                         }
 625                 }
 626         }
 627
 628         # handle backlinks; if a page has added/removed links, update the
 629         # pages it links to
 630         # TODO: inefficient; pages may get rendered above and again here;
 631         # problem is the backlinks could be wrong in the first pass render
 632         # above
 633         if (%rendered) {
 634                 my %linkchanged;
 635                 foreach my $file (keys %rendered, @del) {
 636                         my $page=pagename($file);
 637                         if (exists $links{$page}) {
 638                                 foreach my $link (@{$links{$page}}) {
 639                                         $link=bestlink($page, $link);
 640                                         if (length $link &&
 641                                             ! exists $oldlinks{$page} ||
 642                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 643                                                 $linkchanged{$link}=1;
 644                                         }
 645                                 }
 646                         }
 647                         if (exists $oldlinks{$page}) {
 648                                 foreach my $link (@{$oldlinks{$page}}) {
 649                                         $link=bestlink($page, $link);
 650                                         if (length $link &&
 651                                             ! exists $links{$page} ||
 652                                             ! grep { $_ eq $link } @{$links{$page}}) {
 653                                                 $linkchanged{$link}=1;
 654                                         }
 655                                 }
 656                         }
 657                 }
 658                 foreach my $link (keys %linkchanged) {
 659                         my $linkfile=$pagesources{$link};
 660                         if (defined $linkfile) {
 661                                 debug("rendering $linkfile, to update its backlinks");
 662                                 render($linkfile);
 663                         }
 664                 }
 665         }
 666 } #}}}
 667
 668 sub gen_wrapper (@) { #{{{
 669         my %config=(@_);
 670         eval q{use Cwd 'abs_path'};
 671         $config{srcdir}=abs_path($config{srcdir});
 672         $config{destdir}=abs_path($config{destdir});
 673         my $this=abs_path($0);
 674         if (! -x $this) {
 675                 error("$this doesn't seem to be executable");
 676         }
 677
 678         if ($config{setup}) {
 679                 error("cannot create a wrapper that uses a setup file");
 680         }
 681
 682         my @params=($config{srcdir}, $config{templatedir}, $config{destdir},
 683                 "--wikiname=$config{wikiname}");
 684         push @params, "--verbose" if $config{verbose};
 685         push @params, "--rebuild" if $config{rebuild};
 686         push @params, "--nosvn" if !$config{svn};
 687         push @params, "--cgi" if $config{cgi};
 688         push @params, "--url=$config{url}" if length $config{url};
 689         push @params, "--cgiurl=$config{cgiurl}" if length $config{cgiurl};
 690         push @params, "--historyurl=$config{historyurl}" if length $config{historyurl};
 691         push @params, "--anonok" if $config{anonok};
 692         my $params=join(" ", @params);
 693         my $call='';
 694         foreach my $p ($this, $this, @params) {
 695                 $call.=qq{"$p", };
 696         }
 697         $call.="NULL";
 698
 699         my @envsave;
 700         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
 701                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
 702                        HTTP_COOKIE} if $config{cgi};
 703         my $envsave="";
 704         foreach my $var (@envsave) {
 705                 $envsave.=<<"EOF"
 706         if ((s=getenv("$var")))
 707                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
 708 EOF
 709         }
 710
 711         open(OUT, ">ikiwiki-wrap.c") || error("failed to write ikiwiki-wrap.c: $!");;
 712         print OUT <<"EOF";
 713 /* A wrapper for ikiwiki, can be safely made suid. */
 714 #define _GNU_SOURCE
 715 #include <stdio.h>
 716 #include <unistd.h>
 717 #include <stdlib.h>
 718 #include <string.h>
 719
 720 extern char **environ;
 721
 722 int main (int argc, char **argv) {
 723         /* Sanitize environment. */
 724         char *s;
 725         char *newenviron[$#envsave+3];
 726         int i=0;
 727 $envsave
 728         newenviron[i++]="HOME=$ENV{HOME}";
 729         newenviron[i]=NULL;
 730         environ=newenviron;
 731
 732         if (argc == 2 && strcmp(argv[1], "--params") == 0) {
 733                 printf("$params\\n");
 734                 exit(0);
 735         }
 736
 737         execl($call);
 738         perror("failed to run $this");
 739         exit(1);
 740 }
 741 EOF
 742         close OUT;
 743         if (system("gcc", "ikiwiki-wrap.c", "-o", possibly_foolish_untaint($config{wrapper})) != 0) {
 744                 error("failed to compile ikiwiki-wrap.c");
 745         }
 746         unlink("ikiwiki-wrap.c");
 747         if (defined $config{wrappermode} &&
 748             ! chmod(oct($config{wrappermode}), possibly_foolish_untaint($config{wrapper}))) {
 749                 error("chmod $config{wrapper}: $!");
 750         }
 751         print "successfully generated $config{wrapper}\n";
 752 } #}}}
 753
 754 sub misctemplate ($$) { #{{{
 755         my $title=shift;
 756         my $pagebody=shift;
 757
 758         my $template=HTML::Template->new(
 759                 filename => "$config{templatedir}/misc.tmpl"
 760         );
 761         $template->param(
 762                 title => $title,
 763                 indexlink => indexlink(),
 764                 wikiname => $config{wikiname},
 765                 pagebody => $pagebody,
 766         );
 767         return $template->output;
 768 }#}}}
 769
 770 sub cgi_recentchanges ($) { #{{{
 771         my $q=shift;
 772
 773         my $template=HTML::Template->new(
 774                 filename => "$config{templatedir}/recentchanges.tmpl"
 775         );
 776         $template->param(
 777                 title => "RecentChanges",
 778                 indexlink => indexlink(),
 779                 wikiname => $config{wikiname},
 780                 changelog => [rcs_recentchanges(100)],
 781         );
 782         print $q->header, $template->output;
 783 } #}}}
 784
 785 sub userinfo_get ($$) { #{{{
 786         my $user=shift;
 787         my $field=shift;
 788
 789         eval q{use Storable};
 790         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 791         if (! defined $userdata || ! ref $userdata ||
 792             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 793                 return "";
 794         }
 795         return $userdata->{$user}->{$field};
 796 } #}}}
 797
 798 sub userinfo_set ($$) { #{{{
 799         my $user=shift;
 800         my $info=shift;
 801
 802         eval q{use Storable};
 803         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 804         if (! defined $userdata || ! ref $userdata) {
 805                 $userdata={};
 806         }
 807         $userdata->{$user}=$info;
 808         my $oldmask=umask(077);
 809         my $ret=Storable::lock_store($userdata, "$config{srcdir}/.ikiwiki/userdb");
 810         umask($oldmask);
 811         return $ret;
 812 } #}}}
 813
 814 sub cgi_signin ($$) { #{{{
 815         my $q=shift;
 816         my $session=shift;
 817
 818         eval q{use CGI::FormBuilder};
 819         my $form = CGI::FormBuilder->new(
 820                 title => "$config{wikiname} signin",
 821                 fields => [qw(do page from name password confirm_password email)],
 822                 header => 1,
 823                 method => 'POST',
 824                 validate => {
 825                         confirm_password => {
 826                                 perl => q{eq $form->field("password")},
 827                         },
 828                         email => 'EMAIL',
 829                 },
 830                 required => 'NONE',
 831                 javascript => 0,
 832                 params => $q,
 833                 action => $q->request_uri,
 834                 header => 0,
 835                 template => (-e "$config{templatedir}/signin.tmpl" ?
 836                               "$config{templatedir}/signin.tmpl" : "")
 837         );
 838
 839         $form->field(name => "name", required => 0);
 840         $form->field(name => "do", type => "hidden");
 841         $form->field(name => "page", type => "hidden");
 842         $form->field(name => "from", type => "hidden");
 843         $form->field(name => "password", type => "password", required => 0);
 844         $form->field(name => "confirm_password", type => "password", required => 0);
 845         $form->field(name => "email", required => 0);
 846         if ($q->param("do") ne "signin") {
 847                 $form->text("You need to log in before you can edit pages.");
 848         }
 849
 850         if ($form->submitted) {
 851                 # Set required fields based on how form was submitted.
 852                 my %required=(
 853                         "Login" => [qw(name password)],
 854                         "Register" => [qw(name password confirm_password email)],
 855                         "Mail Password" => [qw(name)],
 856                 );
 857                 foreach my $opt (@{$required{$form->submitted}}) {
 858                         $form->field(name => $opt, required => 1);
 859                 }
 860
 861                 # Validate password differently depending on how
 862                 # form was submitted.
 863                 if ($form->submitted eq 'Login') {
 864                         $form->field(
 865                                 name => "password",
 866                                 validate => sub {
 867                                         length $form->field("name") &&
 868                                         shift eq userinfo_get($form->field("name"), 'password');
 869                                 },
 870                         );
 871                         $form->field(name => "name", validate => '/^\w+$/');
 872                 }
 873                 else {
 874                         $form->field(name => "password", validate => 'VALUE');
 875                 }
 876                 # And make sure the entered name exists when logging
 877                 # in or sending email, and does not when registering.
 878                 if ($form->submitted eq 'Register') {
 879                         $form->field(
 880                                 name => "name",
 881                                 validate => sub {
 882                                         my $name=shift;
 883                                         length $name &&
 884                                         ! userinfo_get($name, "regdate");
 885                                 },
 886                         );
 887                 }
 888                 else {
 889                         $form->field(
 890                                 name => "name",
 891                                 validate => sub {
 892                                         my $name=shift;
 893                                         length $name &&
 894                                         userinfo_get($name, "regdate");
 895                                 },
 896                         );
 897                 }
 898         }
 899         else {
 900                 # First time settings.
 901                 $form->field(name => "name", comment => "use FirstnameLastName");
 902                 $form->field(name => "confirm_password", comment => "(only needed");
 903                 $form->field(name => "email",            comment => "for registration)");
 904                 if ($session->param("name")) {
 905                         $form->field(name => "name", value => $session->param("name"));
 906                 }
 907         }
 908
 909         if ($form->submitted && $form->validate) {
 910                 if ($form->submitted eq 'Login') {
 911                         $session->param("name", $form->field("name"));
 912                         if (defined $form->field("do") &&
 913                             $form->field("do") ne 'signin') {
 914                                 print $q->redirect(
 915                                         "$config{cgiurl}?do=".$form->field("do").
 916                                         "&page=".$form->field("page").
 917                                         "&from=".$form->field("from"));;
 918                         }
 919                         else {
 920                                 print $q->redirect($config{url});
 921                         }
 922                 }
 923                 elsif ($form->submitted eq 'Register') {
 924                         my $user_name=$form->field('name');
 925                         if (userinfo_set($user_name, {
 926                                            'email' => $form->field('email'),
 927                                            'password' => $form->field('password'),
 928                                            'regdate' => time
 929                                          })) {
 930                                 $form->field(name => "confirm_password", type => "hidden");
 931                                 $form->field(name => "email", type => "hidden");
 932                                 $form->text("Registration successful. Now you can Login.");
 933                                 print $session->header();
 934                                 print misctemplate($form->title, $form->render(submit => ["Login"]));
 935                         }
 936                         else {
 937                                 error("Error saving registration.");
 938                         }
 939                 }
 940                 elsif ($form->submitted eq 'Mail Password') {
 941                         my $user_name=$form->field("name");
 942                         my $template=HTML::Template->new(
 943                                 filename => "$config{templatedir}/passwordmail.tmpl"
 944                         );
 945                         $template->param(
 946                                 user_name => $user_name,
 947                                 user_password => userinfo_get($user_name, "password"),
 948                                 wikiurl => $config{url},
 949                                 wikiname => $config{wikiname},
 950                                 REMOTE_ADDR => $ENV{REMOTE_ADDR},
 951                         );
 952
 953                         eval q{use Mail::Sendmail};
 954                         my ($fromhost) = $config{cgiurl} =~ m!/([^/]+)!;
 955                         sendmail(
 956                                 To => userinfo_get($user_name, "email"),
 957                                 From => "$config{wikiname} admin <".(getpwuid($>))[0]."@".$fromhost.">",
 958                                 Subject => "$config{wikiname} information",
 959                                 Message => $template->output,
 960                         ) or error("Failed to send mail");
 961
 962                         $form->text("Your password has been emailed to you.");
 963                         $form->field(name => "name", required => 0);
 964                         print $session->header();
 965                         print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 966                 }
 967         }
 968         else {
 969                 print $session->header();
 970                 print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 971         }
 972 } #}}}
 973
 974 sub cgi_editpage ($$) { #{{{
 975         my $q=shift;
 976         my $session=shift;
 977
 978         eval q{use CGI::FormBuilder};
 979         my $form = CGI::FormBuilder->new(
 980                 fields => [qw(do from page content comments)],
 981                 header => 1,
 982                 method => 'POST',
 983                 validate => {
 984                         content => '/.+/',
 985                 },
 986                 required => [qw{content}],
 987                 javascript => 0,
 988                 params => $q,
 989                 action => $q->request_uri,
 990                 table => 0,
 991                 template => "$config{templatedir}/editpage.tmpl"
 992         );
 993
 994         my ($page)=$form->param('page')=~/$config{wiki_file_regexp}/;
 995         if (! defined $page || ! length $page || $page ne $q->param('page') ||
 996             $page=~/$config{wiki_file_prune_regexp}/ || $page=~/^\//) {
 997                 error("bad page name");
 998         }
 999         $page=lc($page);
1000
1001         $form->field(name => "do", type => 'hidden');
1002         $form->field(name => "from", type => 'hidden');
1003         $form->field(name => "page", value => "$page", force => 1);
1004         $form->field(name => "comments", type => "text", size => 80);
1005         $form->field(name => "content", type => "textarea", rows => 20,
1006                 cols => 80);
1007
1008         if ($form->submitted eq "Cancel") {
1009                 print $q->redirect("$config{url}/".htmlpage($page));
1010                 return;
1011         }
1012         if (! $form->submitted || ! $form->validate) {
1013                 if ($form->field("do") eq "create") {
1014                         if (exists $pagesources{lc($page)}) {
1015                                 # hmm, someone else made the page in the
1016                                 # meantime?
1017                                 print $q->redirect("$config{url}/".htmlpage($page));
1018                                 return;
1019                         }
1020
1021                         my @page_locs;
1022                         my ($from)=$form->param('from')=~/$config{wiki_file_regexp}/;
1023                         if (! defined $from || ! length $from ||
1024                             $from ne $form->param('from') ||
1025                             $from=~/$config{wiki_file_prune_regexp}/ || $from=~/^\//) {
1026                                 @page_locs=$page;
1027                         }
1028                         else {
1029                                 my $dir=$from."/";
1030                                 $dir=~s![^/]+/$!!;
1031                                 push @page_locs, $dir.$page;
1032                                 push @page_locs, "$from/$page";
1033                                 while (length $dir) {
1034                                         $dir=~s![^/]+/$!!;
1035                                         push @page_locs, $dir.$page;
1036                                 }
1037                         }
1038
1039                         $form->tmpl_param("page_select", 1);
1040                         $form->field(name => "page", type => 'select',
1041                                 options => \@page_locs);
1042                         $form->title("creating $page");
1043                 }
1044                 elsif ($form->field("do") eq "edit") {
1045                         my $content="";
1046                         if (exists $pagesources{lc($page)}) {
1047                                 $content=readfile("$config{srcdir}/$pagesources{lc($page)}");
1048                                 $content=~s/\n/\r\n/g;
1049                         }
1050                         $form->tmpl_param("page_select", 0);
1051                         $form->field(name => "content", value => $content,
1052                                 force => 1);
1053                         $form->field(name => "page", type => 'hidden');
1054                         $form->title("editing $page");
1055                 }
1056
1057                 $form->tmpl_param("can_commit", $config{svn});
1058                 $form->tmpl_param("indexlink", indexlink());
1059                 print $form->render(submit => ["Save Page", "Cancel"]);
1060         }
1061         else {
1062                 # save page
1063                 my $file=$page.$config{default_pageext};
1064                 my $newfile=1;
1065                 if (exists $pagesources{lc($page)}) {
1066                         $file=$pagesources{lc($page)};
1067                         $newfile=0;
1068                 }
1069
1070                 my $content=$form->field('content');
1071                 $content=~s/\r\n/\n/g;
1072                 $content=~s/\r/\n/g;
1073                 writefile("$config{srcdir}/$file", $content);
1074
1075                 my $message="web commit ";
1076                 if ($session->param("name")) {
1077                         $message.="by ".$session->param("name");
1078                 }
1079                 else {
1080                         $message.="from $ENV{REMOTE_ADDR}";
1081                 }
1082                 if (defined $form->field('comments') &&
1083                     length $form->field('comments')) {
1084                         $message.=": ".$form->field('comments');
1085                 }
1086
1087                 if ($config{svn}) {
1088                         if ($newfile) {
1089                                 rcs_add($file);
1090                         }
1091                         # presumably the commit will trigger an update
1092                         # of the wiki
1093                         rcs_commit($message);
1094                 }
1095                 else {
1096                         loadindex();
1097                         refresh();
1098                         saveindex();
1099                 }
1100
1101                 # The trailing question mark tries to avoid broken
1102                 # caches and get the most recent version of the page.
1103                 print $q->redirect("$config{url}/".htmlpage($page)."?updated");
1104         }
1105 } #}}}
1106
1107 sub cgi () { #{{{
1108         eval q{use CGI};
1109         eval q{use CGI::Session};
1110
1111         my $q=CGI->new;
1112
1113         my $do=$q->param('do');
1114         if (! defined $do || ! length $do) {
1115                 error("\"do\" parameter missing");
1116         }
1117
1118         # This does not need a session.
1119         if ($do eq 'recentchanges') {
1120                 cgi_recentchanges($q);
1121                 return;
1122         }
1123
1124         CGI::Session->name("ikiwiki_session");
1125
1126         my $oldmask=umask(077);
1127         my $session = CGI::Session->new("driver:db_file", $q,
1128                 { FileName => "$config{srcdir}/.ikiwiki/sessions.db" });
1129         umask($oldmask);
1130
1131         # Everything below this point needs the user to be signed in.
1132         if ((! $config{anonok} && ! defined $session->param("name") ||
1133                 ! userinfo_get($session->param("name"), "regdate")) || $do eq 'signin') {
1134                 cgi_signin($q, $session);
1135
1136                 # Force session flush with safe umask.
1137                 my $oldmask=umask(077);
1138                 $session->flush;
1139                 umask($oldmask);
1140
1141                 return;
1142         }
1143
1144         if ($do eq 'create' || $do eq 'edit') {
1145                 cgi_editpage($q, $session);
1146         }
1147         else {
1148                 error("unknown do parameter");
1149         }
1150 } #}}}
1151
1152 sub setup () { # {{{
1153         my $setup=possibly_foolish_untaint($config{setup});
1154         delete $config{setup};
1155         open (IN, $setup) || error("read $setup: $!\n");
1156         local $/=undef;
1157         my $code=<IN>;
1158         ($code)=$code=~/(.*)/s;
1159         close IN;
1160
1161         my (%setup);
1162         eval $code;
1163         error($@) if $@;
1164
1165         gen_wrapper(%config, %setup, %{$setup{cgiwrapper}}) if $setup{cgiwrapper};
1166         gen_wrapper(%config, %setup, %{$setup{svnwrapper}}) if $setup{svnwrapper};
1167
1168         print "$setup{wikiname} setup complete, now forcing a rebuild\n";
1169         foreach my $c (keys %setup) {
1170                 $config{$c}=possibly_foolish_untaint($setup{$c})
1171                         if defined $setup{$c} && ! ref $setup{$c};
1172         }
1173         $config{rebuild}=1;
1174         refresh();
1175         saveindex();
1176         exit;
1177 } #}}}
1178
1179 # main {{{
1180 setup() if $config{setup};
1181 if ($config{wrapper}) {
1182         gen_wrapper(%config);
1183         exit;
1184 }
1185 memoize('pagename');
1186 memoize('bestlink');
1187 loadindex() unless $config{rebuild};
1188 if ($config{cgi}) {
1189         cgi();
1190 }
1191 else {
1192         rcs_update() if $config{svn};
1193         refresh();
1194         saveindex();
1195 }
1196 #}}}