git.oblomov.eu Git - ikiwiki/blob - ikiwiki

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3
   4 use warnings;
   5 use strict;
   6 use Memoize;
   7 use File::Spec;
   8 use HTML::Template;
   9 use Getopt::Long;
  10
  11 my (%links, %oldlinks, %oldpagemtime, %renderedfiles, %pagesources);
  12
  13 my %config=( #{{{
  14         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$)},
  15         wiki_link_regexp => qr/\[\[([^\s]+)\]\]/,
  16         wiki_file_regexp => qr/(^[-A-Za-z0-9_.:\/+]+$)/,
  17         verbose => 0,
  18         wikiname => "wiki",
  19         default_pageext => ".mdwn",
  20         cgi => 0,
  21         svn => 1,
  22         url => '',
  23         cgiurl => '',
  24         historyurl => '',
  25         anonok => 0,
  26         rebuild => 0,
  27         wrapper => undef,
  28         wrappermode => undef,
  29         srcdir => undef,
  30         destdir => undef,
  31         templatedir => undef,
  32         setup => undef,
  33 ); #}}}
  34
  35 GetOptions( #{{{
  36         "setup=s" => \$config{setup},
  37         "wikiname=s" => \$config{wikiname},
  38         "verbose|v!" => \$config{verbose},
  39         "rebuild!" => \$config{rebuild},
  40         "wrapper=s" => sub { $config{wrapper}=$_[1] ? $_[1] : "ikiwiki-wrap" },
  41         "wrappermode=i" => \$config{wrappermode},
  42         "svn!" => \$config{svn},
  43         "anonok!" => \$config{anonok},
  44         "cgi!" => \$config{cgi},
  45         "url=s" => \$config{url},
  46         "cgiurl=s" => \$config{cgiurl},
  47         "historyurl=s" => \$config{historyurl},
  48         "exclude=s@" => sub {
  49                 $config{wiki_file_prune_regexp}=qr/$config{wiki_file_prune_regexp}|$_[1]/;
  50         },
  51 ) || usage();
  52
  53 if (! $config{setup}) {
  54         usage() unless @ARGV == 3;
  55         $config{srcdir} = possibly_foolish_untaint(shift);
  56         $config{templatedir} = possibly_foolish_untaint(shift);
  57         $config{destdir} = possibly_foolish_untaint(shift);
  58         if ($config{cgi} && ! length $config{url}) {
  59                 error("Must specify url to wiki with --url when using --cgi");
  60         }
  61 }
  62 #}}}
  63
  64 sub usage { #{{{
  65         die "usage: ikiwiki [options] source templates dest\n";
  66 } #}}}
  67
  68 sub error { #{{{
  69         if ($config{cgi}) {
  70                 print "Content-type: text/html\n\n";
  71                 print misctemplate("Error", "<p>Error: @_</p>");
  72         }
  73         die @_;
  74 } #}}}
  75
  76 sub debug ($) { #{{{
  77         return unless $config{verbose};
  78         if (! $config{cgi}) {
  79                 print "@_\n";
  80         }
  81         else {
  82                 print STDERR "@_\n";
  83         }
  84 } #}}}
  85
  86 sub mtime ($) { #{{{
  87         my $page=shift;
  88
  89         return (stat($page))[9];
  90 } #}}}
  91
  92 sub possibly_foolish_untaint { #{{{
  93         my $tainted=shift;
  94         my ($untainted)=$tainted=~/(.*)/;
  95         return $untainted;
  96 } #}}}
  97
  98 sub basename ($) { #{{{
  99         my $file=shift;
 100
 101         $file=~s!.*/!!;
 102         return $file;
 103 } #}}}
 104
 105 sub dirname ($) { #{{{
 106         my $file=shift;
 107
 108         $file=~s!/?[^/]+$!!;
 109         return $file;
 110 } #}}}
 111
 112 sub pagetype ($) { #{{{
 113         my $page=shift;
 114
 115         if ($page =~ /\.mdwn$/) {
 116                 return ".mdwn";
 117         }
 118         else {
 119                 return "unknown";
 120         }
 121 } #}}}
 122
 123 sub pagename ($) { #{{{
 124         my $file=shift;
 125
 126         my $type=pagetype($file);
 127         my $page=$file;
 128         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 129         return $page;
 130 } #}}}
 131
 132 sub htmlpage ($) { #{{{
 133         my $page=shift;
 134
 135         return $page.".html";
 136 } #}}}
 137
 138 sub readfile ($) { #{{{
 139         my $file=shift;
 140
 141         local $/=undef;
 142         open (IN, "$file") || error("failed to read $file: $!");
 143         my $ret=<IN>;
 144         close IN;
 145         return $ret;
 146 } #}}}
 147
 148 sub writefile ($$) { #{{{
 149         my $file=shift;
 150         my $content=shift;
 151
 152         my $dir=dirname($file);
 153         if (! -d $dir) {
 154                 my $d="";
 155                 foreach my $s (split(m!/+!, $dir)) {
 156                         $d.="$s/";
 157                         if (! -d $d) {
 158                                 mkdir($d) || error("failed to create directory $d: $!");
 159                         }
 160                 }
 161         }
 162
 163         open (OUT, ">$file") || error("failed to write $file: $!");
 164         print OUT $content;
 165         close OUT;
 166 } #}}}
 167
 168 sub findlinks ($$) { #{{{
 169         my $content=shift;
 170         my $page=shift;
 171
 172         my @links;
 173         while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 174                 push @links, lc($1);
 175         }
 176         # Discussion links are a special case since they're not in the text
 177         # of the page, but on its template.
 178         return @links, "$page/discussion";
 179 } #}}}
 180
 181 sub bestlink ($$) { #{{{
 182         # Given a page and the text of a link on the page, determine which
 183         # existing page that link best points to. Prefers pages under a
 184         # subdirectory with the same name as the source page, failing that
 185         # goes down the directory tree to the base looking for matching
 186         # pages.
 187         my $page=shift;
 188         my $link=lc(shift);
 189
 190         my $cwd=$page;
 191         do {
 192                 my $l=$cwd;
 193                 $l.="/" if length $l;
 194                 $l.=$link;
 195
 196                 if (exists $links{$l}) {
 197                         #debug("for $page, \"$link\", use $l");
 198                         return $l;
 199                 }
 200         } while $cwd=~s!/?[^/]+$!!;
 201
 202         #print STDERR "warning: page $page, broken link: $link\n";
 203         return "";
 204 } #}}}
 205
 206 sub isinlinableimage ($) { #{{{
 207         my $file=shift;
 208
 209         $file=~/\.(png|gif|jpg|jpeg)$/;
 210 } #}}}
 211
 212 sub htmllink { #{{{
 213         my $page=shift;
 214         my $link=shift;
 215         my $noimageinline=shift; # don't turn links into inline html images
 216         my $forcesubpage=shift; # force a link to a subpage
 217
 218         my $bestlink;
 219         if (! $forcesubpage) {
 220                 $bestlink=bestlink($page, $link);
 221         }
 222         else {
 223                 $bestlink="$page/".lc($link);
 224         }
 225
 226         return $link if length $bestlink && $page eq $bestlink;
 227
 228         # TODO BUG: %renderedfiles may not have it, if the linked to page
 229         # was also added and isn't yet rendered! Note that this bug is
 230         # masked by the bug mentioned below that makes all new files
 231         # be rendered twice.
 232         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 233                 $bestlink=htmlpage($bestlink);
 234         }
 235         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 236                 return "<a href=\"$config{cgiurl}?do=create&page=$link&from=$page\">?</a>$link"
 237         }
 238
 239         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 240
 241         if (! $noimageinline && isinlinableimage($bestlink)) {
 242                 return "<img src=\"$bestlink\">";
 243         }
 244         return "<a href=\"$bestlink\">$link</a>";
 245 } #}}}
 246
 247 sub linkify ($$) { #{{{
 248         my $content=shift;
 249         my $file=shift;
 250
 251         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 252                 $1 ? "[[$2]]" : htmllink(pagename($file), $2)
 253         }eg;
 254
 255         return $content;
 256 } #}}}
 257
 258 sub htmlize ($$) { #{{{
 259         my $type=shift;
 260         my $content=shift;
 261
 262         if (! $INC{"/usr/bin/markdown"}) {
 263                 no warnings 'once';
 264                 $blosxom::version="is a proper perl module too much to ask?";
 265                 use warnings 'all';
 266                 do "/usr/bin/markdown";
 267         }
 268
 269         if ($type eq '.mdwn') {
 270                 return Markdown::Markdown($content);
 271         }
 272         else {
 273                 error("htmlization of $type not supported");
 274         }
 275 } #}}}
 276
 277 sub backlinks ($) { #{{{
 278         my $page=shift;
 279
 280         my @links;
 281         foreach my $p (keys %links) {
 282                 next if bestlink($page, $p) eq $page;
 283                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 284                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 285
 286                         # Trim common dir prefixes from both pages.
 287                         my $p_trimmed=$p;
 288                         my $page_trimmed=$page;
 289                         my $dir;
 290                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
 291                                 defined $dir &&
 292                                 $p_trimmed=~s/^\Q$dir\E// &&
 293                                 $page_trimmed=~s/^\Q$dir\E//;
 294
 295                         push @links, { url => $href, page => $p_trimmed };
 296                 }
 297         }
 298
 299         return sort { $a->{page} cmp $b->{page} } @links;
 300 } #}}}
 301
 302 sub parentlinks ($) { #{{{
 303         my $page=shift;
 304
 305         my @ret;
 306         my $pagelink="";
 307         my $path="";
 308         my $skip=1;
 309         foreach my $dir (reverse split("/", $page)) {
 310                 if (! $skip) {
 311                         $path.="../";
 312                         unshift @ret, { url => "$path$dir.html", page => $dir };
 313                 }
 314                 else {
 315                         $skip=0;
 316                 }
 317         }
 318         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
 319         return @ret;
 320 } #}}}
 321
 322 sub indexlink () { #{{{
 323         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 324 } #}}}
 325
 326 sub finalize ($$) { #{{{
 327         my $content=shift;
 328         my $page=shift;
 329
 330         my $title=basename($page);
 331         $title=~s/_/ /g;
 332
 333         my $template=HTML::Template->new(blind_cache => 1,
 334                 filename => "$config{templatedir}/page.tmpl");
 335
 336         if (length $config{cgiurl}) {
 337                 $template->param(editurl => "$config{cgiurl}?do=edit&page=$page");
 338                 if ($config{svn}) {
 339                         $template->param(recentchangesurl => "$config{cgiurl}?do=recentchanges");
 340                 }
 341         }
 342
 343         if (length $config{historyurl}) {
 344                 my $u=$config{historyurl};
 345                 $u=~s/\[\[\]\]/$pagesources{$page}/g;
 346                 $template->param(historyurl => $u);
 347         }
 348
 349         $template->param(
 350                 title => $title,
 351                 wikiname => $config{wikiname},
 352                 parentlinks => [parentlinks($page)],
 353                 content => $content,
 354                 backlinks => [backlinks($page)],
 355                 discussionlink => htmllink($page, "Discussion", 1, 1),
 356         );
 357
 358         return $template->output;
 359 } #}}}
 360
 361 sub check_overwrite ($$) { #{{{
 362         # Important security check. Make sure to call this before saving
 363         # any files to the source directory.
 364         my $dest=shift;
 365         my $src=shift;
 366
 367         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 368                 error("$dest already exists and was rendered from ".
 369                         join(" ",(grep { $renderedfiles{$_} eq $dest } keys
 370                                 %renderedfiles)).
 371                         ", before, so not rendering from $src");
 372         }
 373 } #}}}
 374
 375 sub render ($) { #{{{
 376         my $file=shift;
 377
 378         my $type=pagetype($file);
 379         my $content=readfile("$config{srcdir}/$file");
 380         if ($type ne 'unknown') {
 381                 my $page=pagename($file);
 382
 383                 $links{$page}=[findlinks($content, $page)];
 384
 385                 $content=linkify($content, $file);
 386                 $content=htmlize($type, $content);
 387                 $content=finalize($content, $page);
 388
 389                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 390                 writefile("$config{destdir}/".htmlpage($page), $content);
 391                 $oldpagemtime{$page}=time;
 392                 $renderedfiles{$page}=htmlpage($page);
 393         }
 394         else {
 395                 $links{$file}=[];
 396                 check_overwrite("$config{destdir}/$file", $file);
 397                 writefile("$config{destdir}/$file", $content);
 398                 $oldpagemtime{$file}=time;
 399                 $renderedfiles{$file}=$file;
 400         }
 401 } #}}}
 402
 403 sub loadindex () { #{{{
 404         open (IN, "$config{srcdir}/.ikiwiki/index") || return;
 405         while (<IN>) {
 406                 $_=possibly_foolish_untaint($_);
 407                 chomp;
 408                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 409                 my $page=pagename($file);
 410                 $pagesources{$page}=$file;
 411                 $oldpagemtime{$page}=$mtime;
 412                 $oldlinks{$page}=[@links];
 413                 $links{$page}=[@links];
 414                 $renderedfiles{$page}=$rendered;
 415         }
 416         close IN;
 417 } #}}}
 418
 419 sub saveindex () { #{{{
 420         if (! -d "$config{srcdir}/.ikiwiki") {
 421                 mkdir("$config{srcdir}/.ikiwiki");
 422         }
 423         open (OUT, ">$config{srcdir}/.ikiwiki/index") || error("cannot write to index: $!");
 424         foreach my $page (keys %oldpagemtime) {
 425                 print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 426                         join(" ", @{$links{$page}})."\n"
 427                                 if $oldpagemtime{$page};
 428         }
 429         close OUT;
 430 } #}}}
 431
 432 sub rcs_update () { #{{{
 433         if (-d "$config{srcdir}/.svn") {
 434                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
 435                         warn("svn update failed\n");
 436                 }
 437         }
 438 } #}}}
 439
 440 sub rcs_commit ($) { #{{{
 441         my $message=shift;
 442
 443         if (-d "$config{srcdir}/.svn") {
 444                 if (system("svn", "commit", "--quiet", "-m",
 445                            possibly_foolish_untaint($message),
 446                            $config{srcdir}) != 0) {
 447                         warn("svn commit failed\n");
 448                 }
 449         }
 450 } #}}}
 451
 452 sub rcs_add ($) { #{{{
 453         my $file=shift;
 454
 455         if (-d "$config{srcdir}/.svn") {
 456                 my $parent=dirname($file);
 457                 while (! -d "$config{srcdir}/$parent/.svn") {
 458                         $file=$parent;
 459                         $parent=dirname($file);
 460                 }
 461
 462                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
 463                         warn("svn add failed\n");
 464                 }
 465         }
 466 } #}}}
 467
 468 sub rcs_recentchanges ($) { #{{{
 469         my $num=shift;
 470         my @ret;
 471
 472         eval q{use Date::Parse};
 473         eval q{use Time::Duration};
 474
 475         if (-d "$config{srcdir}/.svn") {
 476                 my $info=`LANG=C svn info $config{srcdir}`;
 477                 my ($svn_url)=$info=~/^URL: (.*)$/m;
 478
 479                 # FIXME: currently assumes that the wiki is somewhere
 480                 # under trunk in svn, doesn't support other layouts.
 481                 my ($svn_base)=$svn_url=~m!(/trunk(?:/.*)?)$!;
 482
 483                 my $div=qr/^--------------------+$/;
 484                 my $infoline=qr/^r(\d+)\s+\|\s+([^\s]+)\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 485                 my $state='start';
 486                 my ($rev, $user, $when, @pages, @message);
 487                 foreach (`LANG=C svn log -v '$svn_url'`) {
 488                         chomp;
 489                         if ($state eq 'start' && /$div/) {
 490                                 $state='header';
 491                         }
 492                         elsif ($state eq 'header' && /$infoline/) {
 493                                 $rev=$1;
 494                                 $user=$2;
 495                                 $when=concise(ago(time - str2time($3)));
 496                         }
 497                         elsif ($state eq 'header' && /^\s+[A-Z]\s+\Q$svn_base\E\/(.+)$/) {
 498                                 push @pages, { link => htmllink("", pagename($1), 1) }
 499                                         if length $1;
 500                         }
 501                         elsif ($state eq 'header' && /^$/) {
 502                                 $state='body';
 503                         }
 504                         elsif ($state eq 'body' && /$div/) {
 505                                 my $committype="web";
 506                                 if (defined $message[0] &&
 507                                     $message[0]->{line}=~/^web commit by (\w+):?(.*)/) {
 508                                         $user="$1";
 509                                         $message[0]->{line}=$2;
 510                                 }
 511                                 else {
 512                                         $committype="svn";
 513                                 }
 514
 515                                 push @ret, { rev => $rev,
 516                                         user => htmllink("", $user, 1),
 517                                         committype => $committype,
 518                                         when => $when, message => [@message],
 519                                         pages => [@pages] } if @pages;
 520                                 return @ret if @ret >= $num;
 521
 522                                 $state='header';
 523                                 $rev=$user=$when=undef;
 524                                 @pages=@message=();
 525                         }
 526                         elsif ($state eq 'body') {
 527                                 push @message, {line => $_},
 528                         }
 529                 }
 530         }
 531
 532         return @ret;
 533 } #}}}
 534
 535 sub prune ($) { #{{{
 536         my $file=shift;
 537
 538         unlink($file);
 539         my $dir=dirname($file);
 540         while (rmdir($dir)) {
 541                 $dir=dirname($dir);
 542         }
 543 } #}}}
 544
 545 sub refresh () { #{{{
 546         # Find existing pages.
 547         my %exists;
 548         my @files;
 549
 550         eval q{use File::Find};
 551         find({
 552                 no_chdir => 1,
 553                 wanted => sub {
 554                         if (/$config{wiki_file_prune_regexp}/) {
 555                                 no warnings 'once';
 556                                 $File::Find::prune=1;
 557                                 use warnings "all";
 558                         }
 559                         elsif (! -d $_) {
 560                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 561                                 if (! defined $f) {
 562                                         warn("skipping bad filename $_\n");
 563                                 }
 564                                 else {
 565                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 566                                         push @files, $f;
 567                                         $exists{pagename($f)}=1;
 568                                 }
 569                         }
 570                 },
 571         }, $config{srcdir});
 572
 573         my %rendered;
 574
 575         # check for added or removed pages
 576         my @add;
 577         foreach my $file (@files) {
 578                 my $page=pagename($file);
 579                 if (! $oldpagemtime{$page}) {
 580                         debug("new page $page");
 581                         push @add, $file;
 582                         $links{$page}=[];
 583                         $pagesources{$page}=$file;
 584                 }
 585         }
 586         my @del;
 587         foreach my $page (keys %oldpagemtime) {
 588                 if (! $exists{$page}) {
 589                         debug("removing old page $page");
 590                         push @del, $renderedfiles{$page};
 591                         prune($config{destdir}."/".$renderedfiles{$page});
 592                         delete $renderedfiles{$page};
 593                         $oldpagemtime{$page}=0;
 594                         delete $pagesources{$page};
 595                 }
 596         }
 597
 598         # render any updated files
 599         foreach my $file (@files) {
 600                 my $page=pagename($file);
 601
 602                 if (! exists $oldpagemtime{$page} ||
 603                     mtime("$config{srcdir}/$file") > $oldpagemtime{$page}) {
 604                         debug("rendering changed file $file");
 605                         render($file);
 606                         $rendered{$file}=1;
 607                 }
 608         }
 609
 610         # if any files were added or removed, check to see if each page
 611         # needs an update due to linking to them
 612         # TODO: inefficient; pages may get rendered above and again here;
 613         # problem is the bestlink may have changed and we won't know until
 614         # now
 615         if (@add || @del) {
 616 FILE:           foreach my $file (@files) {
 617                         my $page=pagename($file);
 618                         foreach my $f (@add, @del) {
 619                                 my $p=pagename($f);
 620                                 foreach my $link (@{$links{$page}}) {
 621                                         if (bestlink($page, $link) eq $p) {
 622                                                 debug("rendering $file, which links to $p");
 623                                                 render($file);
 624                                                 $rendered{$file}=1;
 625                                                 next FILE;
 626                                         }
 627                                 }
 628                         }
 629                 }
 630         }
 631
 632         # handle backlinks; if a page has added/removed links, update the
 633         # pages it links to
 634         # TODO: inefficient; pages may get rendered above and again here;
 635         # problem is the backlinks could be wrong in the first pass render
 636         # above
 637         if (%rendered) {
 638                 my %linkchanged;
 639                 foreach my $file (keys %rendered, @del) {
 640                         my $page=pagename($file);
 641                         if (exists $links{$page}) {
 642                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 643                                         if (length $link &&
 644                                             ! exists $oldlinks{$page} ||
 645                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 646                                                 $linkchanged{$link}=1;
 647                                         }
 648                                 }
 649                         }
 650                         if (exists $oldlinks{$page}) {
 651                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 652                                         if (length $link &&
 653                                             ! exists $links{$page} ||
 654                                             ! grep { $_ eq $link } @{$links{$page}}) {
 655                                                 $linkchanged{$link}=1;
 656                                         }
 657                                 }
 658                         }
 659                 }
 660                 foreach my $link (keys %linkchanged) {
 661                         my $linkfile=$pagesources{$link};
 662                         if (defined $linkfile) {
 663                                 debug("rendering $linkfile, to update its backlinks");
 664                                 render($linkfile);
 665                         }
 666                 }
 667         }
 668 } #}}}
 669
 670 sub gen_wrapper (@) { #{{{
 671         my %config=(@_);
 672         eval q{use Cwd 'abs_path'};
 673         $config{srcdir}=abs_path($config{srcdir});
 674         $config{destdir}=abs_path($config{destdir});
 675         my $this=abs_path($0);
 676         if (! -x $this) {
 677                 error("$this doesn't seem to be executable");
 678         }
 679
 680         if ($config{setup}) {
 681                 error("cannot create a wrapper that uses a setup file");
 682         }
 683
 684         my @params=($config{srcdir}, $config{templatedir}, $config{destdir},
 685                 "--wikiname=$config{wikiname}");
 686         push @params, "--verbose" if $config{verbose};
 687         push @params, "--rebuild" if $config{rebuild};
 688         push @params, "--nosvn" if !$config{svn};
 689         push @params, "--cgi" if $config{cgi};
 690         push @params, "--url=$config{url}" if length $config{url};
 691         push @params, "--cgiurl=$config{cgiurl}" if length $config{cgiurl};
 692         push @params, "--historyurl=$config{historyurl}" if length $config{historyurl};
 693         push @params, "--anonok" if $config{anonok};
 694         my $params=join(" ", @params);
 695         my $call='';
 696         foreach my $p ($this, $this, @params) {
 697                 $call.=qq{"$p", };
 698         }
 699         $call.="NULL";
 700
 701         my @envsave;
 702         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
 703                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
 704                        HTTP_COOKIE} if $config{cgi};
 705         my $envsave="";
 706         foreach my $var (@envsave) {
 707                 $envsave.=<<"EOF"
 708         if ((s=getenv("$var")))
 709                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
 710 EOF
 711         }
 712
 713         open(OUT, ">ikiwiki-wrap.c") || error("failed to write ikiwiki-wrap.c: $!");;
 714         print OUT <<"EOF";
 715 /* A wrapper for ikiwiki, can be safely made suid. */
 716 #define _GNU_SOURCE
 717 #include <stdio.h>
 718 #include <unistd.h>
 719 #include <stdlib.h>
 720 #include <string.h>
 721
 722 extern char **environ;
 723
 724 int main (int argc, char **argv) {
 725         /* Sanitize environment. */
 726         char *s;
 727         char *newenviron[$#envsave+3];
 728         int i=0;
 729 $envsave
 730         newenviron[i++]="HOME=$ENV{HOME}";
 731         newenviron[i]=NULL;
 732         environ=newenviron;
 733
 734         if (argc == 2 && strcmp(argv[1], "--params") == 0) {
 735                 printf("$params\\n");
 736                 exit(0);
 737         }
 738
 739         execl($call);
 740         perror("failed to run $this");
 741         exit(1);
 742 }
 743 EOF
 744         close OUT;
 745         if (system("gcc", "ikiwiki-wrap.c", "-o", possibly_foolish_untaint($config{wrapper})) != 0) {
 746                 error("failed to compile ikiwiki-wrap.c");
 747         }
 748         unlink("ikiwiki-wrap.c");
 749         if (defined $config{wrappermode} &&
 750             ! chmod(oct($config{wrappermode}), possibly_foolish_untaint($config{wrapper}))) {
 751                 error("chmod $config{wrapper}: $!");
 752         }
 753         print "successfully generated $config{wrapper}\n";
 754 } #}}}
 755
 756 sub misctemplate ($$) { #{{{
 757         my $title=shift;
 758         my $pagebody=shift;
 759
 760         my $template=HTML::Template->new(
 761                 filename => "$config{templatedir}/misc.tmpl"
 762         );
 763         $template->param(
 764                 title => $title,
 765                 indexlink => indexlink(),
 766                 wikiname => $config{wikiname},
 767                 pagebody => $pagebody,
 768         );
 769         return $template->output;
 770 }#}}}
 771
 772 sub cgi_recentchanges ($) { #{{{
 773         my $q=shift;
 774
 775         my $template=HTML::Template->new(
 776                 filename => "$config{templatedir}/recentchanges.tmpl"
 777         );
 778         $template->param(
 779                 title => "RecentChanges",
 780                 indexlink => indexlink(),
 781                 wikiname => $config{wikiname},
 782                 changelog => [rcs_recentchanges(100)],
 783         );
 784         print $q->header, $template->output;
 785 } #}}}
 786
 787 sub userinfo_get ($$) { #{{{
 788         my $user=shift;
 789         my $field=shift;
 790
 791         eval q{use Storable};
 792         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 793         if (! defined $userdata || ! ref $userdata ||
 794             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 795                 return "";
 796         }
 797         return $userdata->{$user}->{$field};
 798 } #}}}
 799
 800 sub userinfo_set ($$) { #{{{
 801         my $user=shift;
 802         my $info=shift;
 803
 804         eval q{use Storable};
 805         my $userdata=eval{ Storable::lock_retrieve("$config{srcdir}/.ikiwiki/userdb") };
 806         if (! defined $userdata || ! ref $userdata) {
 807                 $userdata={};
 808         }
 809         $userdata->{$user}=$info;
 810         my $oldmask=umask(077);
 811         my $ret=Storable::lock_store($userdata, "$config{srcdir}/.ikiwiki/userdb");
 812         umask($oldmask);
 813         return $ret;
 814 } #}}}
 815
 816 sub cgi_signin ($$) { #{{{
 817         my $q=shift;
 818         my $session=shift;
 819
 820         eval q{use CGI::FormBuilder};
 821         my $form = CGI::FormBuilder->new(
 822                 title => "$config{wikiname} signin",
 823                 fields => [qw(do page from name password confirm_password email)],
 824                 header => 1,
 825                 method => 'POST',
 826                 validate => {
 827                         confirm_password => {
 828                                 perl => q{eq $form->field("password")},
 829                         },
 830                         email => 'EMAIL',
 831                 },
 832                 required => 'NONE',
 833                 javascript => 0,
 834                 params => $q,
 835                 action => $q->request_uri,
 836                 header => 0,
 837                 template => (-e "$config{templatedir}/signin.tmpl" ?
 838                               "$config{templatedir}/signin.tmpl" : "")
 839         );
 840
 841         $form->field(name => "name", required => 0);
 842         $form->field(name => "do", type => "hidden");
 843         $form->field(name => "page", type => "hidden");
 844         $form->field(name => "from", type => "hidden");
 845         $form->field(name => "password", type => "password", required => 0);
 846         $form->field(name => "confirm_password", type => "password", required => 0);
 847         $form->field(name => "email", required => 0);
 848         if ($q->param("do") ne "signin") {
 849                 $form->text("You need to log in before you can edit pages.");
 850         }
 851
 852         if ($form->submitted) {
 853                 # Set required fields based on how form was submitted.
 854                 my %required=(
 855                         "Login" => [qw(name password)],
 856                         "Register" => [qw(name password confirm_password email)],
 857                         "Mail Password" => [qw(name)],
 858                 );
 859                 foreach my $opt (@{$required{$form->submitted}}) {
 860                         $form->field(name => $opt, required => 1);
 861                 }
 862
 863                 # Validate password differently depending on how
 864                 # form was submitted.
 865                 if ($form->submitted eq 'Login') {
 866                         $form->field(
 867                                 name => "password",
 868                                 validate => sub {
 869                                         length $form->field("name") &&
 870                                         shift eq userinfo_get($form->field("name"), 'password');
 871                                 },
 872                         );
 873                         $form->field(name => "name", validate => '/^\w+$/');
 874                 }
 875                 else {
 876                         $form->field(name => "password", validate => 'VALUE');
 877                 }
 878                 # And make sure the entered name exists when logging
 879                 # in or sending email, and does not when registering.
 880                 if ($form->submitted eq 'Register') {
 881                         $form->field(
 882                                 name => "name",
 883                                 validate => sub {
 884                                         my $name=shift;
 885                                         length $name &&
 886                                         ! userinfo_get($name, "regdate");
 887                                 },
 888                         );
 889                 }
 890                 else {
 891                         $form->field(
 892                                 name => "name",
 893                                 validate => sub {
 894                                         my $name=shift;
 895                                         length $name &&
 896                                         userinfo_get($name, "regdate");
 897                                 },
 898                         );
 899                 }
 900         }
 901         else {
 902                 # First time settings.
 903                 $form->field(name => "name", comment => "use FirstnameLastName");
 904                 $form->field(name => "confirm_password", comment => "(only needed");
 905                 $form->field(name => "email",            comment => "for registration)");
 906                 if ($session->param("name")) {
 907                         $form->field(name => "name", value => $session->param("name"));
 908                 }
 909         }
 910
 911         if ($form->submitted && $form->validate) {
 912                 if ($form->submitted eq 'Login') {
 913                         $session->param("name", $form->field("name"));
 914                         if (defined $form->field("do") &&
 915                             $form->field("do") ne 'signin') {
 916                                 print $q->redirect(
 917                                         "$config{cgiurl}?do=".$form->field("do").
 918                                         "&page=".$form->field("page").
 919                                         "&from=".$form->field("from"));;
 920                         }
 921                         else {
 922                                 print $q->redirect($config{url});
 923                         }
 924                 }
 925                 elsif ($form->submitted eq 'Register') {
 926                         my $user_name=$form->field('name');
 927                         if (userinfo_set($user_name, {
 928                                            'email' => $form->field('email'),
 929                                            'password' => $form->field('password'),
 930                                            'regdate' => time
 931                                          })) {
 932                                 $form->field(name => "confirm_password", type => "hidden");
 933                                 $form->field(name => "email", type => "hidden");
 934                                 $form->text("Registration successful. Now you can Login.");
 935                                 print $session->header();
 936                                 print misctemplate($form->title, $form->render(submit => ["Login"]));
 937                         }
 938                         else {
 939                                 error("Error saving registration.");
 940                         }
 941                 }
 942                 elsif ($form->submitted eq 'Mail Password') {
 943                         my $user_name=$form->field("name");
 944                         my $template=HTML::Template->new(
 945                                 filename => "$config{templatedir}/passwordmail.tmpl"
 946                         );
 947                         $template->param(
 948                                 user_name => $user_name,
 949                                 user_password => userinfo_get($user_name, "password"),
 950                                 wikiurl => $config{url},
 951                                 wikiname => $config{wikiname},
 952                                 REMOTE_ADDR => $ENV{REMOTE_ADDR},
 953                         );
 954
 955                         eval q{use Mail::Sendmail};
 956                         my ($fromhost) = $config{cgiurl} =~ m!/([^/]+)!;
 957                         sendmail(
 958                                 To => userinfo_get($user_name, "email"),
 959                                 From => "$config{wikiname} admin <".(getpwuid($>))[0]."@".$fromhost.">",
 960                                 Subject => "$config{wikiname} information",
 961                                 Message => $template->output,
 962                         ) or error("Failed to send mail");
 963
 964                         $form->text("Your password has been emailed to you.");
 965                         $form->field(name => "name", required => 0);
 966                         print $session->header();
 967                         print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 968                 }
 969         }
 970         else {
 971                 print $session->header();
 972                 print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 973         }
 974 } #}}}
 975
 976 sub cgi_editpage ($$) { #{{{
 977         my $q=shift;
 978         my $session=shift;
 979
 980         eval q{use CGI::FormBuilder};
 981         my $form = CGI::FormBuilder->new(
 982                 fields => [qw(do from page content comments)],
 983                 header => 1,
 984                 method => 'POST',
 985                 validate => {
 986                         content => '/.+/',
 987                 },
 988                 required => [qw{content}],
 989                 javascript => 0,
 990                 params => $q,
 991                 action => $q->request_uri,
 992                 table => 0,
 993                 template => "$config{templatedir}/editpage.tmpl"
 994         );
 995
 996         my ($page)=$form->param('page')=~/$config{wiki_file_regexp}/;
 997         if (! defined $page || ! length $page || $page ne $q->param('page') ||
 998             $page=~/$config{wiki_file_prune_regexp}/ || $page=~/^\//) {
 999                 error("bad page name");
1000         }
1001         $page=lc($page);
1002
1003         $form->field(name => "do", type => 'hidden');
1004         $form->field(name => "from", type => 'hidden');
1005         $form->field(name => "page", value => "$page", force => 1);
1006         $form->field(name => "comments", type => "text", size => 80);
1007         $form->field(name => "content", type => "textarea", rows => 20,
1008                 cols => 80);
1009
1010         if ($form->submitted eq "Cancel") {
1011                 print $q->redirect("$config{url}/".htmlpage($page));
1012                 return;
1013         }
1014         if (! $form->submitted || ! $form->validate) {
1015                 if ($form->field("do") eq "create") {
1016                         if (exists $pagesources{lc($page)}) {
1017                                 # hmm, someone else made the page in the
1018                                 # meantime?
1019                                 print $q->redirect("$config{url}/".htmlpage($page));
1020                                 return;
1021                         }
1022
1023                         my @page_locs;
1024                         my $best_loc;
1025                         my ($from)=$form->param('from')=~/$config{wiki_file_regexp}/;
1026                         if (! defined $from || ! length $from ||
1027                             $from ne $form->param('from') ||
1028                             $from=~/$config{wiki_file_prune_regexp}/ || $from=~/^\//) {
1029                                 @page_locs=$best_loc=$page;
1030                         }
1031                         else {
1032                                 my $dir=$from."/";
1033                                 $dir=~s![^/]+/$!!;
1034                                 push @page_locs, $dir.$page;
1035                                 push @page_locs, "$from/$page";
1036                                 $best_loc="$from/$page";
1037                                 while (length $dir) {
1038                                         $dir=~s![^/]+/$!!;
1039                                         push @page_locs, $dir.$page;
1040                                 }
1041
1042                                 @page_locs = grep { ! exists
1043                                         $pagesources{lc($_)} } @page_locs;
1044                         }
1045
1046                         $form->tmpl_param("page_select", 1);
1047                         $form->field(name => "page", type => 'select',
1048                                 options => \@page_locs, value => $best_loc);
1049                         $form->title("creating $page");
1050                 }
1051                 elsif ($form->field("do") eq "edit") {
1052                         my $content="";
1053                         if (exists $pagesources{lc($page)}) {
1054                                 $content=readfile("$config{srcdir}/$pagesources{lc($page)}");
1055                                 $content=~s/\n/\r\n/g;
1056                         }
1057                         $form->tmpl_param("page_select", 0);
1058                         $form->field(name => "content", value => $content,
1059                                 force => 1);
1060                         $form->field(name => "page", type => 'hidden');
1061                         $form->title("editing $page");
1062                 }
1063
1064                 $form->tmpl_param("can_commit", $config{svn});
1065                 $form->tmpl_param("indexlink", indexlink());
1066                 print $form->render(submit => ["Save Page", "Cancel"]);
1067         }
1068         else {
1069                 # save page
1070                 my $file=$page.$config{default_pageext};
1071                 my $newfile=1;
1072                 if (exists $pagesources{lc($page)}) {
1073                         $file=$pagesources{lc($page)};
1074                         $newfile=0;
1075                 }
1076
1077                 my $content=$form->field('content');
1078                 $content=~s/\r\n/\n/g;
1079                 $content=~s/\r/\n/g;
1080                 writefile("$config{srcdir}/$file", $content);
1081
1082                 my $message="web commit ";
1083                 if ($session->param("name")) {
1084                         $message.="by ".$session->param("name");
1085                 }
1086                 else {
1087                         $message.="from $ENV{REMOTE_ADDR}";
1088                 }
1089                 if (defined $form->field('comments') &&
1090                     length $form->field('comments')) {
1091                         $message.=": ".$form->field('comments');
1092                 }
1093
1094                 if ($config{svn}) {
1095                         if ($newfile) {
1096                                 rcs_add($file);
1097                         }
1098                         # presumably the commit will trigger an update
1099                         # of the wiki
1100                         rcs_commit($message);
1101                 }
1102                 else {
1103                         loadindex();
1104                         refresh();
1105                         saveindex();
1106                 }
1107
1108                 # The trailing question mark tries to avoid broken
1109                 # caches and get the most recent version of the page.
1110                 print $q->redirect("$config{url}/".htmlpage($page)."?updated");
1111         }
1112 } #}}}
1113
1114 sub cgi () { #{{{
1115         eval q{use CGI};
1116         eval q{use CGI::Session};
1117
1118         my $q=CGI->new;
1119
1120         my $do=$q->param('do');
1121         if (! defined $do || ! length $do) {
1122                 error("\"do\" parameter missing");
1123         }
1124
1125         # This does not need a session.
1126         if ($do eq 'recentchanges') {
1127                 cgi_recentchanges($q);
1128                 return;
1129         }
1130
1131         CGI::Session->name("ikiwiki_session");
1132
1133         my $oldmask=umask(077);
1134         my $session = CGI::Session->new("driver:db_file", $q,
1135                 { FileName => "$config{srcdir}/.ikiwiki/sessions.db" });
1136         umask($oldmask);
1137
1138         # Everything below this point needs the user to be signed in.
1139         if ((! $config{anonok} && ! defined $session->param("name") ||
1140                 ! userinfo_get($session->param("name"), "regdate")) || $do eq 'signin') {
1141                 cgi_signin($q, $session);
1142
1143                 # Force session flush with safe umask.
1144                 my $oldmask=umask(077);
1145                 $session->flush;
1146                 umask($oldmask);
1147
1148                 return;
1149         }
1150
1151         if ($do eq 'create' || $do eq 'edit') {
1152                 cgi_editpage($q, $session);
1153         }
1154         else {
1155                 error("unknown do parameter");
1156         }
1157 } #}}}
1158
1159 sub setup () { # {{{
1160         my $setup=possibly_foolish_untaint($config{setup});
1161         delete $config{setup};
1162         open (IN, $setup) || error("read $setup: $!\n");
1163         local $/=undef;
1164         my $code=<IN>;
1165         ($code)=$code=~/(.*)/s;
1166         close IN;
1167
1168         my (%setup);
1169         eval $code;
1170         error($@) if $@;
1171
1172         gen_wrapper(%config, %setup, %{$setup{cgiwrapper}}) if $setup{cgiwrapper};
1173         gen_wrapper(%config, %setup, %{$setup{svnwrapper}}) if $setup{svnwrapper};
1174
1175         print "$setup{wikiname} setup complete, now forcing a rebuild\n";
1176         foreach my $c (keys %setup) {
1177                 $config{$c}=possibly_foolish_untaint($setup{$c})
1178                         if defined $setup{$c} && ! ref $setup{$c};
1179         }
1180         $config{rebuild}=1;
1181         refresh();
1182         saveindex();
1183         exit;
1184 } #}}}
1185
1186 # main {{{
1187 setup() if $config{setup};
1188 if ($config{wrapper}) {
1189         gen_wrapper(%config);
1190         exit;
1191 }
1192 memoize('pagename');
1193 memoize('bestlink');
1194 loadindex() unless $config{rebuild};
1195 if ($config{cgi}) {
1196         cgi();
1197 }
1198 else {
1199         rcs_update() if $config{svn};
1200         refresh();
1201         saveindex();
1202 }
1203 #}}}