git.oblomov.eu Git - ikiwiki/blob - ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8
   9 BEGIN {
  10         $blosxom::version="is a proper perl module too much to ask?";
  11         do "/usr/bin/markdown";
  12 }
  13
  14 memoize('pagename');
  15 memoize('bestlink');
  16
  17 sub usage {
  18         die "usage: ikiwiki [options] source dest\n";
  19 }
  20
  21 my $link=qr/\[\[([^\s]+)\]\]/;
  22 my $verbose=0;
  23 my $rebuild=0;
  24 my $wikiname="wiki";
  25 if (grep /^-/, @ARGV) {
  26         eval {use Getopt::Long};
  27         GetOptions(
  28                 "wikiname=s" => \$wikiname,
  29                 "verbose|v" => \$verbose,
  30                 "rebuild" => \$rebuild,
  31         ) || usage();
  32 }
  33 usage() unless @ARGV == 2;
  34 my ($srcdir) = shift =~ /(.*)/; # untaint
  35 my ($destdir) = shift =~ /(.*)/; # untaint
  36
  37 my %links;
  38 my %oldlinks;
  39 my %oldpagemtime;
  40 my %renderedfiles;
  41 my %pagesources;
  42
  43 sub error ($) {
  44         die @_;
  45 }
  46
  47 sub debug ($) {
  48         print "@_\n" if $verbose;
  49 }
  50
  51 sub mtime ($) {
  52         my $page=shift;
  53
  54         return (stat($page))[9];
  55 }
  56
  57 sub basename {
  58         my $file=shift;
  59
  60         $file=~s!.*/!!;
  61         return $file;
  62 }
  63
  64 sub dirname {
  65         my $file=shift;
  66
  67         $file=~s!/?[^/]+$!!;
  68         return $file;
  69 }
  70
  71 sub pagetype ($) {
  72         my $page=shift;
  73
  74         if ($page =~ /\.mdwn$/) {
  75                 return ".mdwn";
  76         }
  77         else {
  78                 return "unknown";
  79         }
  80 }
  81
  82 sub pagename ($) {
  83         my $file=shift;
  84
  85         my $type=pagetype($file);
  86         my $page=$file;
  87         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  88         return $page;
  89 }
  90
  91 sub htmlpage ($) {
  92         my $page=shift;
  93
  94         return $page.".html";
  95 }
  96
  97 sub readpage ($) {
  98         my $page=shift;
  99
 100         local $/=undef;
 101         open (PAGE, "$srcdir/$page") || error("failed to read $page: $!");
 102         my $ret=<PAGE>;
 103         close PAGE;
 104         return $ret;
 105 }
 106
 107 sub writepage ($$) {
 108         my $page=shift;
 109         my $content=shift;
 110
 111         my $dir=dirname("$destdir/$page");
 112         if (! -d $dir) {
 113                 my $d="";
 114                 foreach my $s (split(m!/+!, $dir)) {
 115                         $d.="$s/";
 116                         if (! -d $d) {
 117                                 mkdir($d) || error("failed to create directory $d: $!");
 118                         }
 119                 }
 120         }
 121
 122         open (PAGE, ">$destdir/$page") || error("failed to write $page: $!");
 123         print PAGE $content;
 124         close PAGE;
 125 }
 126
 127 sub findlinks {
 128         my $content=shift;
 129
 130         my @links;
 131         while ($content =~ /$link/g) {
 132                 push @links, lc($1);
 133         }
 134         return @links;
 135 }
 136
 137 # Given a page and the text of a link on the page, determine which existing
 138 # page that link best points to. Prefers pages under a subdirectory with
 139 # the same name as the source page, failing that goes down the directory tree
 140 # to the base looking for matching pages.
 141 sub bestlink ($$) {
 142         my $page=shift;
 143         my $link=lc(shift);
 144
 145         my $cwd=$page;
 146         do {
 147                 my $l=$cwd;
 148                 $l.="/" if length $l;
 149                 $l.=$link;
 150
 151                 if (exists $links{$l}) {
 152                         #debug("for $page, \"$link\", use $l");
 153                         return $l;
 154                 }
 155         } while $cwd=~s!/?[^/]+$!!;
 156
 157         print STDERR "warning: page $page, broken link: $link\n";
 158         return "";
 159 }
 160
 161 sub isinlinableimage ($) {
 162         my $file=shift;
 163
 164         $file=~/\.(png|gif|jpg|jpeg)$/;
 165 }
 166
 167 sub htmllink ($$) {
 168         my $page=shift;
 169         my $link=shift;
 170
 171         my $bestlink=bestlink($page, $link);
 172
 173         return $link if $page eq $bestlink;
 174
 175         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 176                 $bestlink=htmlpage($bestlink);
 177         }
 178         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 179                 return "<a href=\"?\">?</a>$link"
 180         }
 181
 182         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 183
 184         if (isinlinableimage($bestlink)) {
 185                 return "<img src=\"$bestlink\">";
 186         }
 187         return "<a href=\"$bestlink\">$link</a>";
 188 }
 189
 190 sub linkify ($$) {
 191         my $content=shift;
 192         my $file=shift;
 193
 194         $content =~ s/$link/htmllink(pagename($file), $1)/eg;
 195
 196         return $content;
 197 }
 198
 199 sub htmlize ($$) {
 200         my $type=shift;
 201         my $content=shift;
 202
 203         if ($type eq '.mdwn') {
 204                 return Markdown::Markdown($content);
 205         }
 206         else {
 207                 error("htmlization of $type not supported");
 208         }
 209 }
 210
 211 sub linkbacks ($$) {
 212         my $content=shift;
 213         my $page=shift;
 214
 215         my @links;
 216         foreach my $p (keys %links) {
 217                 if (grep { $_ eq $page } @{$links{$p}}) {
 218                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 219                         push @links, "<a href=\"$href\">$p</a>";
 220                 }
 221         }
 222
 223         $content.="<hr><p>Links: ".join(" ", sort @links)."</p>\n" if @links;
 224         return $content;
 225 }
 226
 227 sub finalize ($$) {
 228         my $content=shift;
 229         my $page=shift;
 230
 231         my $title=basename($page);
 232         $title=~s/_/ /g;
 233
 234         my $pagelink="";
 235         my $path="";
 236         foreach my $dir (reverse split("/", $page)) {
 237                 if (length($pagelink)) {
 238                         $pagelink="<a href=\"$path$dir.html\">$dir</a>/ $pagelink";
 239                 }
 240                 else {
 241                         $pagelink=$dir;
 242                 }
 243                 $path.="../";
 244         }
 245         $path=~s/\.\.\/$/index.html/;
 246         $pagelink="<a href=\"$path\">$wikiname</a>/ $pagelink";
 247
 248         $content="<html>\n<head><title>$title</title></head>\n<body>\n".
 249                   "<h1>$pagelink</h1>\n".
 250                   $content.
 251                   "</body>\n</html>\n";
 252
 253         return $content;
 254 }
 255
 256 sub render ($) {
 257         my $file=shift;
 258
 259         my $type=pagetype($file);
 260         my $content=readpage($file);
 261         if ($type ne 'unknown') {
 262                 my $page=pagename($file);
 263
 264                 $links{$page}=[findlinks($content)];
 265
 266                 $content=linkify($content, $file);
 267                 $content=htmlize($type, $content);
 268                 $content=linkbacks($content, $page);
 269                 $content=finalize($content, $page);
 270
 271                 writepage(htmlpage($page), $content);
 272                 $oldpagemtime{$page}=time;
 273                 $renderedfiles{$page}=htmlpage($page);
 274         }
 275         else {
 276                 $links{$file}=[];
 277                 writepage($file, $content);
 278                 $oldpagemtime{$file}=time;
 279                 $renderedfiles{$file}=$file;
 280         }
 281 }
 282
 283 sub loadindex () {
 284         open (IN, "$srcdir/.index") || return;
 285         while (<IN>) {
 286                 ($_)=/(.*)/; # untaint
 287                 chomp;
 288                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 289                 my $page=pagename($file);
 290                 $pagesources{$page}=$file;
 291                 $oldpagemtime{$page}=$mtime;
 292                 $links{$page}=[@links];
 293                 $oldlinks{$page}=[@links];
 294                 $renderedfiles{$page}=$rendered;
 295         }
 296         close IN;
 297 }
 298
 299 sub saveindex () {
 300         open (OUT, ">$srcdir/.index") || error("cannot write to .index: $!");
 301         foreach my $page (keys %oldpagemtime) {
 302         print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 303                   join(" ", @{$links{$page}})."\n"
 304                         if $oldpagemtime{$page};
 305         }
 306         close OUT;
 307 }
 308
 309 sub prune ($) {
 310         my $file=shift;
 311
 312         unlink($file);
 313         my $dir=dirname($file);
 314         while (rmdir($dir)) {
 315                 $dir=dirname($dir);
 316         }
 317 }
 318
 319 sub refresh () {
 320         # Find existing pages.
 321         my %exists;
 322         my @files;
 323         find({
 324                 no_chdir => 1,
 325                 wanted => sub {
 326                         if (/\/\.svn\//) {
 327                                 $File::Find::prune=1;
 328                         }
 329                         elsif (! -d $_ && ! /\.html$/ && ! /\/\./) {
 330                                 my ($f)=/(^[-A-Za-z0-9_.:\/+]+$)/; # untaint
 331                                 if (! defined $f) {
 332                                         warn("skipping bad filename $_\n");
 333                                 }
 334                                 else {
 335                                         $f=~s/^\Q$srcdir\E\/?//;
 336                                         push @files, $f;
 337                                         $exists{pagename($f)}=1;
 338                                 }
 339                         }
 340                 },
 341         }, $srcdir);
 342
 343         my %rendered;
 344
 345         # check for added or removed pages
 346         my @add;
 347         foreach my $file (@files) {
 348                 my $page=pagename($file);
 349                 if (! $oldpagemtime{$page}) {
 350                         debug("new page $page");
 351                         push @add, $file;
 352                         $links{$page}=[];
 353                         $pagesources{$page}=$file;
 354                 }
 355         }
 356         my @del;
 357         foreach my $page (keys %oldpagemtime) {
 358                 if (! $exists{$page}) {
 359                         debug("removing old page $page");
 360                         push @del, $renderedfiles{$page};
 361                         prune($destdir."/".$renderedfiles{$page});
 362                         delete $renderedfiles{$page};
 363                         $oldpagemtime{$page}=0;
 364                 }
 365         }
 366
 367         # render any updated files
 368         foreach my $file (@files) {
 369                 my $page=pagename($file);
 370
 371                 if (! exists $oldpagemtime{$page} ||
 372                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 373                         debug("rendering changed file $file");
 374                         render($file);
 375                         $rendered{$file}=1;
 376                 }
 377                 elsif ($rebuild) {
 378                         debug("rebuilding unchanged file $file");
 379                         render($file);
 380                         $rendered{$file}=1;
 381                 }
 382         }
 383
 384         # if any files were added or removed, check to see if each page
 385         # needs an update due to linking to them
 386         if (@add || @del) {
 387 FILE:           foreach my $file (@files) {
 388                         next if $rendered{$file};
 389                         my $page=pagename($file);
 390                         foreach my $f (@add, @del) {
 391                                 my $p=pagename($f);
 392                                 foreach my $link (@{$links{$page}}) {
 393                                         if (bestlink($page, $link) eq $p) {
 394                                                 debug("rendering $file, which links to $p");
 395                                                 render($file);
 396                                                 next FILE;
 397                                         }
 398                                 }
 399                         }
 400                 }
 401         }
 402
 403         # handle linkbacks; if a page has added/removed links, update the
 404         # pages it links to
 405         # TODO: inefficient; pages may get rendered above and again here;
 406         # problem is the linkbacks could be wrong in the first pass render
 407         # above.
 408         if (%rendered) {
 409                 my %linkchanged;
 410                 foreach my $file (keys %rendered, @del) {
 411                         my $pagename=pagename($file);
 412                         if (exists $links{$pagename}) {
 413                                 foreach my $link (@{$links{$pagename}}) {
 414                                         if (! exists $oldlinks{$pagename} ||
 415                                             ! grep { $_ eq $link } @{$oldlinks{$pagename}}) {
 416                                                 $linkchanged{$link}=1;
 417                                         }
 418                                 }
 419                         }
 420                         if (exists $oldlinks{$pagename}) {
 421                                 foreach my $link (@{$oldlinks{$pagename}}) {
 422                                         if (! exists $links{$pagename} ||
 423                                             ! grep { $_ eq $link } @{$links{$pagename}}) {
 424                                                 $linkchanged{$link}=1;
 425                                         }
 426                                 }
 427                         }
 428                 }
 429                 foreach my $link (keys %linkchanged) {
 430                         my $linkfile=$pagesources{$link};
 431                         if (defined $linkfile) {
 432                                 debug("rendering $linkfile, to update its linkbacks");
 433                                 render($linkfile);
 434                         }
 435                 }
 436         }
 437 }
 438
 439 loadindex();
 440 refresh();
 441 saveindex();