git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         run_hooks(indexhtml => sub {
  66                 shift->(page => $page, destpage => $page, content => $content);
  67         });
  68
  69         my $templatefile;
  70         run_hooks(templatefile => sub {
  71                 return if defined $templatefile;
  72                 my $file=shift->(page => $page);
  73                 if (defined $file && defined template_file($file)) {
  74                         $templatefile=$file;
  75                 }
  76         });
  77         my $template;
  78         if (defined $templatefile) {
  79                 $template=template_depends($templatefile, $page,
  80                         blind_cache => 1);
  81         }
  82         else {
  83                 # no explicit depends as special case
  84                 $template=template('page.tmpl',
  85                         blind_cache => 1);
  86         }
  87
  88         my $actions=0;
  89         if (length $config{cgiurl}) {
  90                 if (IkiWiki->can("cgi_editpage")) {
  91                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  92                         $actions++;
  93                 }
  94         }
  95         if (defined $config{historyurl} && length $config{historyurl}) {
  96                 my $u=$config{historyurl};
  97                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  98                 $template->param(historyurl => $u);
  99                 $actions++;
 100         }
 101         if ($config{discussion}) {
 102                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 103                    (length $config{cgiurl} ||
 104                     exists $links{$page."/".$config{discussionpage}})) {
 105                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 106                         $actions++;
 107                 }
 108         }
 109         if ($actions) {
 110                 $template->param(have_actions => 1);
 111         }
 112         templateactions($template, $page);
 113
 114         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 115         my ($backlinks, $more_backlinks);
 116         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 117                 $backlinks=\@backlinks;
 118                 $more_backlinks=[];
 119         }
 120         else {
 121                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 122                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 123         }
 124
 125         $template->param(
 126                 title => $page eq 'index'
 127                         ? $config{wikiname}
 128                         : pagetitle(basename($page)),
 129                 wikiname => $config{wikiname},
 130                 content => $content,
 131                 backlinks => $backlinks,
 132                 more_backlinks => $more_backlinks,
 133                 mtime => displaytime($pagemtime{$page}),
 134                 ctime => displaytime($pagectime{$page}, undef, 1),
 135                 baseurl => baseurl($page),
 136                 html5 => $config{html5},
 137         );
 138
 139         run_hooks(pagetemplate => sub {
 140                 shift->(page => $page, destpage => $page, template => $template);
 141         });
 142
 143         $content=$template->output;
 144
 145         run_hooks(format => sub {
 146                 $content=shift->(
 147                         page => $page,
 148                         content => $content,
 149                 );
 150         });
 151
 152         return $content;
 153 }
 154
 155 sub scan ($) {
 156         my $file=shift;
 157
 158         debug(sprintf(gettext("scanning %s"), $file));
 159
 160         my $type=pagetype($file);
 161         if (defined $type) {
 162                 my $srcfile=srcfile($file);
 163                 my $content=readfile($srcfile);
 164                 my $page=pagename($file);
 165                 will_render($page, htmlpage($page), 1);
 166
 167                 if ($config{discussion}) {
 168                         # Discussion links are a special case since they're
 169                         # not in the text of the page, but on its template.
 170                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 171                 }
 172                 else {
 173                         $links{$page}=[];
 174                 }
 175                 delete $typedlinks{$page};
 176
 177                 run_hooks(scan => sub {
 178                         shift->(
 179                                 page => $page,
 180                                 content => $content,
 181                         );
 182                 });
 183
 184                 # Preprocess in scan-only mode.
 185                 preprocess($page, $page, $content, 1);
 186         }
 187         else {
 188                 will_render($file, $file, 1);
 189         }
 190 }
 191
 192 sub fast_file_copy (@) {
 193         my $srcfile=shift;
 194         my $destfile=shift;
 195         my $srcfd=shift;
 196         my $destfd=shift;
 197         my $cleanup=shift;
 198
 199         my $blksize = 16384;
 200         my ($len, $buf, $written);
 201         while ($len = sysread $srcfd, $buf, $blksize) {
 202                 if (! defined $len) {
 203                         next if $! =~ /^Interrupted/;
 204                         error("failed to read $srcfile: $!", $cleanup);
 205                 }
 206                 my $offset = 0;
 207                 while ($len) {
 208                         defined($written = syswrite $destfd, $buf, $len, $offset)
 209                                 or error("failed to write $destfile: $!", $cleanup);
 210                         $len -= $written;
 211                         $offset += $written;
 212                 }
 213         }
 214 }
 215
 216 sub render ($$) {
 217         my $file=shift;
 218         return if $rendered{$file};
 219         debug(shift);
 220         $rendered{$file}=1;
 221
 222         my $type=pagetype($file);
 223         my $srcfile=srcfile($file);
 224         if (defined $type) {
 225                 my $page=pagename($file);
 226                 delete $depends{$page};
 227                 delete $depends_simple{$page};
 228                 will_render($page, htmlpage($page), 1);
 229                 return if $type=~/^_/;
 230
 231                 my $content=htmlize($page, $page, $type,
 232                         linkify($page, $page,
 233                         preprocess($page, $page,
 234                         filter($page, $page,
 235                         readfile($srcfile)))));
 236
 237                 my $output=htmlpage($page);
 238                 writefile($output, $config{destdir}, genpage($page, $content));
 239         }
 240         else {
 241                 delete $depends{$file};
 242                 delete $depends_simple{$file};
 243                 will_render($file, $file, 1);
 244
 245                 if ($config{hardlink}) {
 246                         # only hardlink if owned by same user
 247                         my @stat=stat($srcfile);
 248                         if ($stat[4] == $>) {
 249                                 prep_writefile($file, $config{destdir});
 250                                 unlink($config{destdir}."/".$file);
 251                                 if (link($srcfile, $config{destdir}."/".$file)) {
 252                                         return;
 253                                 }
 254                         }
 255                         # if hardlink fails, fall back to copying
 256                 }
 257
 258                 my $srcfd=readfile($srcfile, 1, 1);
 259                 writefile($file, $config{destdir}, undef, 1, sub {
 260                         fast_file_copy($srcfile, $file, $srcfd, @_);
 261                 });
 262         }
 263 }
 264
 265 sub prune ($) {
 266         my $file=shift;
 267
 268         unlink($file);
 269         my $dir=dirname($file);
 270         while (rmdir($dir)) {
 271                 $dir=dirname($dir);
 272         }
 273 }
 274
 275 sub srcdir_check () {
 276         # security check, avoid following symlinks in the srcdir path by default
 277         my $test=$config{srcdir};
 278         while (length $test) {
 279                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 280                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 281                 }
 282                 unless ($test=~s/\/+$//) {
 283                         $test=dirname($test);
 284                 }
 285         }
 286
 287 }
 288
 289 sub find_src_files () {
 290         my @files;
 291         my %pages;
 292         eval q{use File::Find};
 293         error($@) if $@;
 294
 295         my ($page, $underlay);
 296         my $helper=sub {
 297                 my $file=decode_utf8($_);
 298                 return if -l $file || -d _;
 299                 $file=~s/^\Q.\/\E//;
 300                 return if ! length $file;
 301                 $page = pagename($file);
 302                 if (! exists $pagesources{$page} &&
 303                     file_pruned($file)) {
 304                         $File::Find::prune=1;
 305                         return;
 306                 }
 307
 308                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 309                 if (! defined $f) {
 310                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 311                         return;
 312                 }
 313
 314                 if ($underlay) {
 315                         # avoid underlaydir override attacks; see security.mdwn
 316                         if (! -l "$config{srcdir}/$f" && ! -e _) {
 317                                 if (! $pages{$page}) {
 318                                         push @files, $f;
 319                                         $pages{$page}=1;
 320                                 }
 321                         }
 322                 }
 323                 else {
 324                         push @files, $f;
 325                         if ($pages{$page}) {
 326                                 debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 327                         }
 328                         $pages{$page}=1;
 329                 }
 330         };
 331
 332         eval q{use Cwd};
 333         die $@ if $@;
 334         my $origdir=getcwd();
 335
 336         chdir($config{srcdir}) || die "chdir: $!";
 337         find({
 338                 no_chdir => 1,
 339                 wanted => $helper,
 340         }, '.');
 341         chdir($origdir) || die "chdir: $!";
 342
 343         $underlay=1;
 344         foreach (@{$config{underlaydirs}}, $config{underlaydir}) {
 345                 chdir($_) || die "chdir: $!";
 346                 find({
 347                         no_chdir => 1,
 348                         wanted => $helper,
 349                 }, '.');
 350                 chdir($origdir) || die "chdir: $!";
 351         };
 352
 353         return \@files, \%pages;
 354 }
 355
 356 sub find_new_files ($) {
 357         my $files=shift;
 358         my @new;
 359         my @internal_new;
 360
 361         my $times_noted;
 362
 363         foreach my $file (@$files) {
 364                 my $page=pagename($file);
 365                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 366                         # the page has changed its type
 367                         $forcerebuild{$page}=1;
 368                 }
 369                 $pagesources{$page}=$file;
 370                 if (! $pagemtime{$page}) {
 371                         if (isinternal($page)) {
 372                                 push @internal_new, $file;
 373                         }
 374                         elsif ($config{rcs}) {
 375                                 push @new, $file;
 376                                 if ($config{gettime} && -e "$config{srcdir}/$file") {
 377                                         if (! $times_noted) {
 378                                                 debug(sprintf(gettext("querying %s for file creation and modification times.."), $config{rcs}));
 379                                                 $times_noted=1;
 380                                         }
 381
 382                                         eval {
 383                                                 my $ctime=rcs_getctime("$config{srcdir}/$file");
 384                                                 if ($ctime > 0) {
 385                                                         $pagectime{$page}=$ctime;
 386                                                 }
 387                                         };
 388                                         if ($@) {
 389                                                 print STDERR $@;
 390                                         }
 391                                         my $mtime;
 392                                         eval {
 393                                                 $mtime=rcs_getmtime("$config{srcdir}/$file");
 394                                         };
 395                                         if ($@) {
 396                                                 print STDERR $@;
 397                                         }
 398                                         elsif ($mtime > 0) {
 399                                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 400                                         }
 401                                 }
 402                         }
 403                         $pagecase{lc $page}=$page;
 404                         if (! exists $pagectime{$page}) {
 405                                 $pagectime{$page}=(srcfile_stat($file))[10];
 406                         }
 407                 }
 408         }
 409
 410         return \@new, \@internal_new;
 411 }
 412
 413 sub find_del_files ($) {
 414         my $pages=shift;
 415         my @del;
 416         my @internal_del;
 417
 418         foreach my $page (keys %pagesources) {
 419                 if (! $pages->{$page}) {
 420                         if (isinternal($page)) {
 421                                 push @internal_del, $pagesources{$page};
 422                         }
 423                         else {
 424                                 push @del, $pagesources{$page};
 425                         }
 426                         $links{$page}=[];
 427                         delete $typedlinks{$page};
 428                         $renderedfiles{$page}=[];
 429                         $pagemtime{$page}=0;
 430                 }
 431         }
 432
 433         return \@del, \@internal_del;
 434 }
 435
 436 sub remove_del (@) {
 437         foreach my $file (@_) {
 438                 my $page=pagename($file);
 439                 if (! isinternal($page)) {
 440                         debug(sprintf(gettext("removing obsolete %s"), $page));
 441                 }
 442
 443                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 444                         prune($config{destdir}."/".$old);
 445                 }
 446
 447                 foreach my $source (keys %destsources) {
 448                         if ($destsources{$source} eq $page) {
 449                                 delete $destsources{$source};
 450                         }
 451                 }
 452
 453                 delete $pagecase{lc $page};
 454                 $delpagesources{$page}=$pagesources{$page};
 455                 delete $pagesources{$page};
 456         }
 457 }
 458
 459 sub find_changed ($) {
 460         my $files=shift;
 461         my @changed;
 462         my @internal_changed;
 463         foreach my $file (@$files) {
 464                 my $page=pagename($file);
 465                 my ($srcfile, @stat)=srcfile_stat($file);
 466                 if (! exists $pagemtime{$page} ||
 467                     $stat[9] > $pagemtime{$page} ||
 468                     $forcerebuild{$page}) {
 469                         $pagemtime{$page}=$stat[9];
 470
 471                         if (isinternal($page)) {
 472                                 # Preprocess internal page in scan-only mode.
 473                                 preprocess($page, $page, readfile($srcfile), 1);
 474                                 push @internal_changed, $file;
 475                         }
 476                         else {
 477                                 push @changed, $file;
 478                         }
 479                 }
 480         }
 481         return \@changed, \@internal_changed;
 482 }
 483
 484 sub calculate_old_links ($$) {
 485         my ($changed, $del)=@_;
 486         my %oldlink_targets;
 487         foreach my $file (@$changed, @$del) {
 488                 my $page=pagename($file);
 489                 if (exists $oldlinks{$page}) {
 490                         foreach my $l (@{$oldlinks{$page}}) {
 491                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 492                         }
 493                 }
 494         }
 495         return \%oldlink_targets;
 496 }
 497
 498 sub derender_internal ($) {
 499         my $file=shift;
 500         my $page=pagename($file);
 501         delete $depends{$page};
 502         delete $depends_simple{$page};
 503         foreach my $old (@{$renderedfiles{$page}}) {
 504                 delete $destsources{$old};
 505         }
 506         $renderedfiles{$page}=[];
 507 }
 508
 509 sub render_linkers ($) {
 510         my $f=shift;
 511         my $p=pagename($f);
 512         foreach my $page (keys %{$backlinks{$p}}) {
 513                 my $file=$pagesources{$page};
 514                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 515         }
 516 }
 517
 518 sub remove_unrendered () {
 519         foreach my $src (keys %rendered) {
 520                 my $page=pagename($src);
 521                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 522                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 523                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 524                                 prune($config{destdir}."/".$file);
 525                         }
 526                 }
 527         }
 528 }
 529
 530 sub link_types_changed ($$) {
 531         # each is of the form { type => { link => 1 } }
 532         my $new = shift;
 533         my $old = shift;
 534
 535         return 0 if !defined $new && !defined $old;
 536         return 1 if (!defined $new && %$old) || (!defined $old && %$new);
 537
 538         while (my ($type, $links) = each %$new) {
 539                 foreach my $link (keys %$links) {
 540                         return 1 unless exists $old->{$type}{$link};
 541                 }
 542         }
 543
 544         while (my ($type, $links) = each %$old) {
 545                 foreach my $link (keys %$links) {
 546                         return 1 unless exists $new->{$type}{$link};
 547                 }
 548         }
 549
 550         return 0;
 551 }
 552
 553 sub calculate_changed_links ($$$) {
 554         my ($changed, $del, $oldlink_targets)=@_;
 555
 556         my (%backlinkchanged, %linkchangers);
 557
 558         foreach my $file (@$changed, @$del) {
 559                 my $page=pagename($file);
 560
 561                 if (exists $links{$page}) {
 562                         foreach my $l (@{$links{$page}}) {
 563                                 my $target=bestlink($page, $l);
 564                                 if (! exists $oldlink_targets->{$page}{$l} ||
 565                                     $target ne $oldlink_targets->{$page}{$l}) {
 566                                         $backlinkchanged{$target}=1;
 567                                         $linkchangers{lc($page)}=1;
 568                                 }
 569                                 delete $oldlink_targets->{$page}{$l};
 570                         }
 571                 }
 572                 if (exists $oldlink_targets->{$page} &&
 573                     %{$oldlink_targets->{$page}}) {
 574                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 575                                 $backlinkchanged{$target}=1;
 576                         }
 577                         $linkchangers{lc($page)}=1;
 578                 }
 579
 580                 # we currently assume that changing the type of a link doesn't
 581                 # change backlinks
 582                 if (!exists $linkchangers{lc($page)}) {
 583                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 584                                 $linkchangers{lc($page)}=1;
 585                         }
 586                 }
 587         }
 588
 589         return \%backlinkchanged, \%linkchangers;
 590 }
 591
 592 sub render_dependent ($$$$$$$) {
 593         my ($files, $new, $internal_new, $del, $internal_del,
 594                 $internal_changed, $linkchangers)=@_;
 595
 596         my @changed=(keys %rendered, @$del);
 597         my @exists_changed=(@$new, @$del);
 598
 599         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 600         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 601
 602         foreach my $p ("templates/page.tmpl", keys %{$depends_simple{""}}) {
 603                 if ($rendered{$p} || grep { $_ eq $p } @$del) {
 604                         foreach my $f (@$files) {
 605                                 next if $rendered{$f};
 606                                 render($f, sprintf(gettext("building %s, which depends on %s"), $f, $p));
 607                         }
 608                         return 0;
 609                 }
 610         }
 611
 612         foreach my $f (@$files) {
 613                 next if $rendered{$f};
 614                 my $p=pagename($f);
 615                 my $reason = undef;
 616
 617                 if (exists $depends_simple{$p} && ! defined $reason) {
 618                         foreach my $d (keys %{$depends_simple{$p}}) {
 619                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 620                                      $lc_changed{$d})
 621                                     ||
 622                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 623                                      $lc_exists_changed{$d})
 624                                     ||
 625                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 626                                      $linkchangers->{$d})
 627                                 ) {
 628                                         $reason = $d;
 629                                         last;
 630                                 }
 631                         }
 632                 }
 633
 634                 if (exists $depends{$p} && ! defined $reason) {
 635                         foreach my $dep (keys %{$depends{$p}}) {
 636                                 my $sub=pagespec_translate($dep);
 637                                 next unless defined $sub;
 638
 639                                 # only consider internal files
 640                                 # if the page explicitly depends
 641                                 # on such files
 642                                 my $internal_dep=$dep =~ /(?:internal|comment|comment_pending)\(/;
 643
 644                                 my $in=sub {
 645                                         my $list=shift;
 646                                         my $type=shift;
 647                                         foreach my $file (@$list) {
 648                                                 next if $file eq $f;
 649                                                 my $page=pagename($file);
 650                                                 if ($sub->($page, location => $p)) {
 651                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 652                                                                 next unless $linkchangers->{lc($page)};
 653                                                         }
 654                                                         $reason=$page;
 655                                                         return 1;
 656                                                 }
 657                                         }
 658                                         return undef;
 659                                 };
 660
 661                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 662                                         last if $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 663                                         last if $internal_dep && (
 664                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 665                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 666                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT)
 667                                         );
 668                                 }
 669                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 670                                         last if $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 671                                         last if $internal_dep && (
 672                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 673                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE)
 674                                         );
 675                                 }
 676                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 677                                         last if $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 678                                         last if $internal_dep && (
 679                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 680                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 681                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS)
 682                                         );
 683                                 }
 684                         }
 685                 }
 686
 687                 if (defined $reason) {
 688                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 689                         return 1;
 690                 }
 691         }
 692
 693         return 0;
 694 }
 695
 696 sub render_backlinks ($) {
 697         my $backlinkchanged=shift;
 698         foreach my $link (keys %$backlinkchanged) {
 699                 my $linkfile=$pagesources{$link};
 700                 if (defined $linkfile) {
 701                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 702                 }
 703         }
 704 }
 705
 706 sub gen_autofile ($$$) {
 707         my $autofile=shift;
 708         my $pages=shift;
 709         my $del=shift;
 710
 711         if (file_pruned($autofile)) {
 712                 return;
 713         }
 714
 715         my ($file)="$config{srcdir}/$autofile" =~ /$config{wiki_file_regexp}/; # untaint
 716         if (! defined $file) {
 717                 return;
 718         }
 719
 720         # Remember autofiles that were tried, and never try them again later.
 721         if (exists $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}) {
 722                 return;
 723         }
 724         $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}=1;
 725
 726         if (srcfile($autofile, 1) || file_pruned($autofile)) {
 727                 return;
 728         }
 729
 730         if (-l $file || -d _ || -e _) {
 731                 return;
 732         }
 733
 734         my $page = pagename($file);
 735         if ($pages->{$page}) {
 736                 return;
 737         }
 738
 739         if (grep { $_ eq $autofile } @$del) {
 740                 return;
 741         }
 742
 743         $autofiles{$autofile}{generator}->();
 744         $pages->{$page}=1;
 745         return 1;
 746 }
 747
 748
 749 sub refresh () {
 750         srcdir_check();
 751         run_hooks(refresh => sub { shift->() });
 752         my ($files, $pages)=find_src_files();
 753         my ($new, $internal_new)=find_new_files($files);
 754         my ($del, $internal_del)=find_del_files($pages);
 755         my ($changed, $internal_changed)=find_changed($files);
 756         run_hooks(needsbuild => sub { shift->($changed) });
 757         my $oldlink_targets=calculate_old_links($changed, $del);
 758
 759         foreach my $file (@$changed) {
 760                 scan($file);
 761         }
 762
 763         foreach my $autofile (keys %autofiles) {
 764                 if (gen_autofile($autofile, $pages, $del)) {
 765                         push @{$files}, $autofile;
 766                         push @{$new}, $autofile if find_new_files([$autofile]);
 767                         push @{$changed}, $autofile if find_changed([$autofile]);
 768
 769                         scan($autofile);
 770                 }
 771         }
 772
 773         calculate_links();
 774
 775         remove_del(@$del, @$internal_del);
 776
 777         foreach my $file (@$changed) {
 778                 render($file, sprintf(gettext("building %s"), $file));
 779         }
 780         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 781                 derender_internal($file);
 782         }
 783
 784         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 785                 $del, $oldlink_targets);
 786
 787         foreach my $file (@$new, @$del) {
 788                 render_linkers($file);
 789         }
 790
 791         if (@$changed || @$internal_changed ||
 792             @$del || @$internal_del || @$internal_new) {
 793                 1 while render_dependent($files, $new, $internal_new,
 794                         $del, $internal_del, $internal_changed,
 795                         $linkchangers);
 796         }
 797
 798         render_backlinks($backlinkchanged);
 799         remove_unrendered();
 800
 801         if (@$del || @$internal_del) {
 802                 run_hooks(delete => sub { shift->(@$del, @$internal_del) });
 803         }
 804         if (%rendered) {
 805                 run_hooks(change => sub { shift->(keys %rendered) });
 806         }
 807 }
 808
 809 sub clean_rendered {
 810         lockwiki();
 811         loadindex();
 812         remove_unrendered();
 813         foreach my $page (keys %oldrenderedfiles) {
 814                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 815                         prune($config{destdir}."/".$file);
 816                 }
 817         }
 818 }
 819
 820 sub commandline_render () {
 821         lockwiki();
 822         loadindex();
 823         unlockwiki();
 824
 825         my $srcfile=possibly_foolish_untaint($config{render});
 826         my $file=$srcfile;
 827         $file=~s/\Q$config{srcdir}\E\/?//;
 828
 829         my $type=pagetype($file);
 830         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 831         my $content=readfile($srcfile);
 832         my $page=pagename($file);
 833         $pagesources{$page}=$file;
 834         $content=filter($page, $page, $content);
 835         $content=preprocess($page, $page, $content);
 836         $content=linkify($page, $page, $content);
 837         $content=htmlize($page, $page, $type, $content);
 838         $pagemtime{$page}=(stat($srcfile))[9];
 839         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 840
 841         print genpage($page, $content);
 842         exit 0;
 843 }
 844
 845 1