git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/autoindex.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::autoindex;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "autoindex", call => \&getsetup);
  11         hook(type => "refresh", id => "autoindex", call => \&refresh);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => 0,
  19                 },
  20 }
  21
  22 sub genindex ($) {
  23         my $page=shift;
  24         my $file=newpagefile($page, $config{default_pageext});
  25         my $template=template("autoindex.tmpl");
  26         $template->param(page => $page);
  27         writefile($file, $config{srcdir}, $template->output);
  28         if ($config{rcs}) {
  29                 IkiWiki::rcs_add($file);
  30         }
  31 }
  32
  33 sub refresh () {
  34         eval q{use File::Find};
  35         error($@) if $@;
  36
  37         my (%pages, %dirs);
  38         foreach my $dir ($config{srcdir}, @{$config{underlaydirs}}, $config{underlaydir}) {
  39                 find({
  40                         no_chdir => 1,
  41                         wanted => sub {
  42                                 $_=decode_utf8($_);
  43                                 if (IkiWiki::file_pruned($_)) {
  44                                         $File::Find::prune=1;
  45                                 }
  46                                 elsif (! -l $_) {
  47                                         my ($f)=/$config{wiki_file_regexp}/; # untaint
  48                                         return unless defined $f;
  49                                         return if $f =~ /\._([^.]+)$/; # skip internal page
  50                                         if (! -d _) {
  51                                                 $pages{pagename($f)}=1;
  52                                         }
  53                                         elsif ($dir eq $config{srcdir}) {
  54                                                 $dirs{$f}=1;
  55                                         }
  56                                 }
  57                         }
  58                 }, $dir);
  59         }
  60
  61         my %deleted;
  62         if (ref $wikistate{autoindex}{deleted}) {
  63                 %deleted=%{$wikistate{autoindex}{deleted}};
  64         }
  65         elsif (ref $pagestate{index}{autoindex}{deleted}) {
  66                 # compatability code
  67                 %deleted=%{$pagestate{index}{autoindex}{deleted}};
  68                 delete $pagestate{index}{autoindex};
  69         }
  70
  71         if (keys %deleted) {
  72                 foreach my $dir (keys %deleted) {
  73                         # remove deleted page state if the deleted page is re-added,
  74                         # or if all its subpages are deleted
  75                         if ($deleted{$dir} && (exists $pages{$dir} ||
  76                                                ! grep /^$dir\/.*/, keys %pages)) {
  77                                 delete $deleted{$dir};
  78                         }
  79                 }
  80                 $wikistate{autoindex}{deleted}=\%deleted;
  81         }
  82
  83         my @needed;
  84         foreach my $dir (keys %dirs) {
  85                 if (! exists $pages{$dir} && ! $deleted{$dir} &&
  86                     grep /^$dir\/.*/, keys %pages) {
  87                         if (exists $IkiWiki::pagemtime{$dir}) {
  88                                 # This page must have just been deleted, so
  89                                 # don't re-add it. And remember it was
  90                                 # deleted.
  91                                 if (! ref $wikistate{autoindex}{deleted}) {
  92                                         $wikistate{autoindex}{deleted}={};
  93                                 }
  94                                 ${$wikistate{autoindex}{deleted}}{$dir}=1;
  95                         }
  96                         else {
  97                                 push @needed, $dir;
  98                         }
  99                 }
 100         }
 101
 102         if (@needed) {
 103                 if ($config{rcs}) {
 104                         IkiWiki::disable_commit_hook();
 105                 }
 106                 foreach my $page (@needed) {
 107                         genindex($page);
 108                 }
 109                 if ($config{rcs}) {
 110                         IkiWiki::rcs_commit_staged(
 111                                 gettext("automatic index generation"),
 112                                 undef, undef);
 113                         IkiWiki::enable_commit_hook();
 114                 }
 115         }
 116 }
 117
 118 1