git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Render.pm

   1 package IkiWiki;
   2
   3 use warnings;
   4 use strict;
   5 use File::Spec;
   6
   7 sub linkify ($$) { #{{{
   8         my $content=shift;
   9         my $page=shift;
  10
  11         $content =~ s{(\\?)$config{wiki_link_regexp}}{
  12                 $1 ? "[[$2]]" : htmllink($page, $2)
  13         }eg;
  14
  15         return $content;
  16 } #}}}
  17
  18 sub htmlize ($$) { #{{{
  19         my $type=shift;
  20         my $content=shift;
  21
  22         if (! $INC{"/usr/bin/markdown"}) {
  23                 no warnings 'once';
  24                 $blosxom::version="is a proper perl module too much to ask?";
  25                 use warnings 'all';
  26                 do "/usr/bin/markdown";
  27         }
  28
  29         if ($type eq '.mdwn') {
  30                 return Markdown::Markdown($content);
  31         }
  32         else {
  33                 error("htmlization of $type not supported");
  34         }
  35 } #}}}
  36
  37 sub backlinks ($) { #{{{
  38         my $page=shift;
  39
  40         my @links;
  41         foreach my $p (keys %links) {
  42                 next if bestlink($page, $p) eq $page;
  43                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
  44                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
  45
  46                         # Trim common dir prefixes from both pages.
  47                         my $p_trimmed=$p;
  48                         my $page_trimmed=$page;
  49                         my $dir;
  50                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  51                                 defined $dir &&
  52                                 $p_trimmed=~s/^\Q$dir\E// &&
  53                                 $page_trimmed=~s/^\Q$dir\E//;
  54
  55                         push @links, { url => $href, page => $p_trimmed };
  56                 }
  57         }
  58
  59         return sort { $a->{page} cmp $b->{page} } @links;
  60 } #}}}
  61
  62 sub parentlinks ($) { #{{{
  63         my $page=shift;
  64
  65         my @ret;
  66         my $pagelink="";
  67         my $path="";
  68         my $skip=1;
  69         foreach my $dir (reverse split("/", $page)) {
  70                 if (! $skip) {
  71                         $path.="../";
  72                         unshift @ret, { url => "$path$dir.html", page => $dir };
  73                 }
  74                 else {
  75                         $skip=0;
  76                 }
  77         }
  78         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
  79         return @ret;
  80 } #}}}
  81
  82 sub rsspage ($) { #{{{
  83         my $page=shift;
  84
  85         return $page.".rss";
  86 } #}}}
  87
  88 sub postprocess { #{{{
  89         # Takes content to postprocess followed by a list of postprocessor
  90         # commands and subroutine references to run for the commands.
  91         my $page=shift;
  92         my $content=shift;
  93         my %commands=@_;
  94
  95         my $handle=sub {
  96                 my $escape=shift;
  97                 my $command=shift;
  98                 my $params=shift;
  99                 if (length $escape) {
 100                         "[[$command $params]]";
 101                 }
 102                 elsif (exists $commands{$command}) {
 103                         my %params;
 104                         while ($params =~ /(\w+)=\"([^"]+)"(\s+|$)/g) {
 105                                 $params{$1}=$2;
 106                         }
 107                         $commands{$command}->($page, %params);
 108                 }
 109                 else {
 110                         "[[bad directive $command]]";
 111                 }
 112         };
 113
 114         $content =~ s{(\\?)$config{wiki_processor_regexp}}{$handle->($1, $2, $3)}eg;
 115         return $content;
 116 } #}}}
 117
 118 sub blog_list ($$) { #{{{
 119         my $globlist=shift;
 120         my $maxitems=shift;
 121
 122         my @list;
 123         foreach my $page (keys %pagesources) {
 124                 if (globlist_match($page, $globlist)) {
 125                         push @list, $page;
 126                 }
 127         }
 128
 129         @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 130         return @list if @list <= $maxitems;
 131         return @list[0..$maxitems - 1];
 132 } #}}}
 133
 134 sub get_inline_content ($$) { #{{{
 135         my $parentpage=shift;
 136         my $page=shift;
 137
 138         my $file=$pagesources{$page};
 139         my $type=pagetype($file);
 140         if ($type ne 'unknown') {
 141                 return htmlize($type, linkify(readfile("$config{srcdir}/$file"), $parentpage));
 142         }
 143         else {
 144                 return "";
 145         }
 146 } #}}}
 147
 148 sub postprocess_html_inline { #{{{
 149         my $parentpage=shift;
 150         my %params=@_;
 151
 152         if (! exists $params{show}) {
 153                 $params{show}=10;
 154         }
 155         if (! exists $params{pages}) {
 156                 return "";
 157         }
 158         $inlinepages{$parentpage}=$params{pages};
 159
 160         my $template=HTML::Template->new(blind_cache => 1,
 161                 filename => "$config{templatedir}/inlinepage.tmpl");
 162
 163         my $ret="";
 164         foreach my $page (blog_list($params{pages}, $params{show})) {
 165                 $template->param(pagelink => htmllink($parentpage, $page));
 166                 $template->param(content => get_inline_content($parentpage, $page));
 167                 $template->param(ctime => scalar(gmtime($pagectime{$page})));
 168                 $ret.=$template->output;
 169         }
 170
 171         return $ret;
 172 } #}}}
 173
 174 sub genpage ($$$) { #{{{
 175         my $content=shift;
 176         my $page=shift;
 177         my $mtime=shift;
 178
 179         $content = postprocess($page, $content, inline => \&postprocess_html_inline);
 180
 181         my $title=pagetitle(basename($page));
 182
 183         my $template=HTML::Template->new(blind_cache => 1,
 184                 filename => "$config{templatedir}/page.tmpl");
 185
 186         if (length $config{cgiurl}) {
 187                 $template->param(editurl => "$config{cgiurl}?do=edit&page=$page");
 188                 $template->param(prefsurl => "$config{cgiurl}?do=prefs");
 189                 if ($config{rcs}) {
 190                         $template->param(recentchangesurl => "$config{cgiurl}?do=recentchanges");
 191                 }
 192         }
 193
 194         if (length $config{historyurl}) {
 195                 my $u=$config{historyurl};
 196                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
 197                 $template->param(historyurl => $u);
 198         }
 199
 200         if ($config{rss}) {
 201                 $template->param(rssurl => rsspage($page));
 202         }
 203
 204         $template->param(
 205                 title => $title,
 206                 wikiname => $config{wikiname},
 207                 parentlinks => [parentlinks($page)],
 208                 content => $content,
 209                 backlinks => [backlinks($page)],
 210                 discussionlink => htmllink($page, "Discussion", 1, 1),
 211                 mtime => scalar(gmtime($mtime)),
 212         );
 213
 214         return $template->output;
 215 } #}}}
 216
 217 sub date_822 ($) { #{{{
 218         my $time=shift;
 219
 220         eval q{use POSIX};
 221         return POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 222 } #}}}
 223
 224 sub absolute_urls ($$) { #{{{
 225         # sucky sub because rss sucks
 226         my $content=shift;
 227         my $url=shift;
 228
 229         $url=~s/[^\/]+$//;
 230
 231         $content=~s/<a\s+href="(?!http:\/\/)([^"]+)"/<a href="$url$1"/ig;
 232         $content=~s/<img\s+src="(?!http:\/\/)([^"]+)"/<img src="$url$1"/ig;
 233         return $content;
 234 } #}}}zo
 235
 236 sub genrss ($$$) { #{{{
 237         my $content=shift;
 238         my $page=shift;
 239         my $mtime=shift;
 240
 241         my $url="$config{url}/".htmlpage($page);
 242
 243         my $template=HTML::Template->new(blind_cache => 1,
 244                 filename => "$config{templatedir}/rsspage.tmpl");
 245
 246         my @items;
 247         my $isblog=0;
 248         my $gen_blog=sub {
 249                 my $parentpage=shift;
 250                 my %params=@_;
 251
 252                 if (! exists $params{show}) {
 253                         $params{show}=10;
 254                 }
 255                 if (! exists $params{pages}) {
 256                         return "";
 257                 }
 258                 $inlinepages{$parentpage}=$params{pages};
 259
 260                 $isblog=1;
 261                 foreach my $page (blog_list($params{pages}, $params{show})) {
 262                         push @items, {
 263                                 itemtitle => pagetitle(basename($page)),
 264                                 itemurl => "$config{url}/$renderedfiles{$page}",
 265                                 itempubdate => date_822($pagectime{$page}),
 266                                 itemcontent => absolute_urls(get_inline_content($parentpage, $page), $url),
 267                         } if exists $renderedfiles{$page};
 268                 }
 269
 270                 return "";
 271         };
 272
 273         $content = postprocess($page, $content, inline => $gen_blog);
 274
 275         # Regular page gets a feed that is updated every time the
 276         # page is changed, so the mtime is encoded in the guid.
 277         push @items, {
 278                 itemtitle => pagetitle(basename($page)),
 279                 itemguid => "$url?mtime=$mtime",
 280                 itemurl => $url,
 281                 itempubdate => date_822($mtime),
 282                 itemcontent => absolute_urls($content, $url),
 283         } unless $isblog;
 284
 285         $template->param(
 286                 title => $config{wikiname},
 287                 pageurl => $url,
 288                 items => \@items,
 289         );
 290
 291         return $template->output;
 292 } #}}}
 293
 294 sub check_overwrite ($$) { #{{{
 295         # Important security check. Make sure to call this before saving
 296         # any files to the source directory.
 297         my $dest=shift;
 298         my $src=shift;
 299
 300         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 301                 error("$dest already exists and was rendered from ".
 302                         join(" ",(grep { $renderedfiles{$_} eq $dest } keys
 303                                 %renderedfiles)).
 304                         ", before, so not rendering from $src");
 305         }
 306 } #}}}
 307
 308 sub mtime ($) { #{{{
 309         my $page=shift;
 310
 311         return (stat($page))[9];
 312 } #}}}
 313
 314 sub findlinks ($$) { #{{{
 315         my $content=shift;
 316         my $page=shift;
 317
 318         my @links;
 319         while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 320                 push @links, lc($1);
 321         }
 322         # Discussion links are a special case since they're not in the text
 323         # of the page, but on its template.
 324         return @links, "$page/discussion";
 325 } #}}}
 326
 327 sub render ($) { #{{{
 328         my $file=shift;
 329
 330         my $type=pagetype($file);
 331         my $content=readfile("$config{srcdir}/$file");
 332         if ($type ne 'unknown') {
 333                 my $page=pagename($file);
 334
 335                 $links{$page}=[findlinks($content, $page)];
 336
 337                 $content=linkify($content, $page);
 338                 $content=htmlize($type, $content);
 339
 340                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 341                 writefile("$config{destdir}/".htmlpage($page),
 342                         genpage($content, $page, mtime("$config{srcdir}/$file")));
 343                 $oldpagemtime{$page}=time;
 344                 $renderedfiles{$page}=htmlpage($page);
 345
 346                 # TODO: should really add this to renderedfiles and call
 347                 # check_overwrite, as above, but currently renderedfiles
 348                 # only supports listing one file per page.
 349                 if ($config{rss}) {
 350                         writefile("$config{destdir}/".rsspage($page),
 351                                 genrss($content, $page, mtime("$config{srcdir}/$file")));
 352                 }
 353         }
 354         else {
 355                 $links{$file}=[];
 356                 check_overwrite("$config{destdir}/$file", $file);
 357                 writefile("$config{destdir}/$file", $content);
 358                 $oldpagemtime{$file}=time;
 359                 $renderedfiles{$file}=$file;
 360         }
 361 } #}}}
 362
 363 sub prune ($) { #{{{
 364         my $file=shift;
 365
 366         unlink($file);
 367         my $dir=dirname($file);
 368         while (rmdir($dir)) {
 369                 $dir=dirname($dir);
 370         }
 371 } #}}}
 372
 373 sub refresh () { #{{{
 374         # find existing pages
 375         my %exists;
 376         my @files;
 377         eval q{use File::Find};
 378         find({
 379                 no_chdir => 1,
 380                 wanted => sub {
 381                         if (/$config{wiki_file_prune_regexp}/) {
 382                                 no warnings 'once';
 383                                 $File::Find::prune=1;
 384                                 use warnings "all";
 385                         }
 386                         elsif (! -d $_ && ! -l $_) {
 387                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 388                                 if (! defined $f) {
 389                                         warn("skipping bad filename $_\n");
 390                                 }
 391                                 else {
 392                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 393                                         push @files, $f;
 394                                         $exists{pagename($f)}=1;
 395                                 }
 396                         }
 397                 },
 398         }, $config{srcdir});
 399
 400         my %rendered;
 401
 402         # check for added or removed pages
 403         my @add;
 404         foreach my $file (@files) {
 405                 my $page=pagename($file);
 406                 if (! $oldpagemtime{$page}) {
 407                         debug("new page $page") unless exists $pagectime{$page};
 408                         push @add, $file;
 409                         $links{$page}=[];
 410                         $pagesources{$page}=$file;
 411                         $pagectime{$page}=time unless exists $pagectime{$page};
 412                 }
 413         }
 414         my @del;
 415         foreach my $page (keys %oldpagemtime) {
 416                 if (! $exists{$page}) {
 417                         debug("removing old page $page");
 418                         push @del, $pagesources{$page};
 419                         prune($config{destdir}."/".$renderedfiles{$page});
 420                         delete $renderedfiles{$page};
 421                         $oldpagemtime{$page}=0;
 422                         delete $pagesources{$page};
 423                 }
 424         }
 425
 426         # render any updated files
 427         foreach my $file (@files) {
 428                 my $page=pagename($file);
 429
 430                 if (! exists $oldpagemtime{$page} ||
 431                     mtime("$config{srcdir}/$file") > $oldpagemtime{$page}) {
 432                         debug("rendering changed file $file");
 433                         render($file);
 434                         $rendered{$file}=1;
 435                 }
 436         }
 437
 438         # if any files were added or removed, check to see if each page
 439         # needs an update due to linking to them or inlining them.
 440         # TODO: inefficient; pages may get rendered above and again here;
 441         # problem is the bestlink may have changed and we won't know until
 442         # now
 443         if (@add || @del) {
 444 FILE:           foreach my $file (@files) {
 445                         my $page=pagename($file);
 446                         foreach my $f (@add, @del) {
 447                                 my $p=pagename($f);
 448                                 foreach my $link (@{$links{$page}}) {
 449                                         if (bestlink($page, $link) eq $p) {
 450                                                 debug("rendering $file, which links to $p");
 451                                                 render($file);
 452                                                 $rendered{$file}=1;
 453                                                 next FILE;
 454                                         }
 455                                 }
 456                                 if (exists $inlinepages{$page} &&
 457                                     globlist_match($p, $inlinepages{$page})) {
 458                                         debug("rendering $file, which inlines $p");
 459                                         render($file);
 460                                         $rendered{$file}=1;
 461                                 }
 462                         }
 463                 }
 464         }
 465
 466         # handle backlinks; if a page has added/removed links, update the
 467         # pages it links to
 468         # TODO: inefficient; pages may get rendered above and again here;
 469         # problem is the backlinks could be wrong in the first pass render
 470         # above
 471         if (%rendered) {
 472                 my %linkchanged;
 473                 foreach my $file (keys %rendered, @del) {
 474                         my $page=pagename($file);
 475                         if (exists $links{$page}) {
 476                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 477                                         if (length $link &&
 478                                             ! exists $oldlinks{$page} ||
 479                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 480                                                 $linkchanged{$link}=1;
 481                                         }
 482                                 }
 483                         }
 484                         if (exists $oldlinks{$page}) {
 485                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 486                                         if (length $link &&
 487                                             ! exists $links{$page} ||
 488                                             ! grep { $_ eq $link } @{$links{$page}}) {
 489                                                 $linkchanged{$link}=1;
 490                                         }
 491                                 }
 492                         }
 493                 }
 494                 foreach my $link (keys %linkchanged) {
 495                         my $linkfile=$pagesources{$link};
 496                         if (defined $linkfile) {
 497                                 debug("rendering $linkfile, to update its backlinks");
 498                                 render($linkfile);
 499                         }
 500                 }
 501         }
 502 } #}}}
 503
 504 1