git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89                 feed_desc_fmt => {
  90                         type => "string",
  91                         example => '%1$s\'s %2$s',
  92                         description => "format string for the default feed description, using the wiki name and page title as parameters",
  93                         safe => 0,
  94                         rebuild => 1,
  95                 }
  96 }
  97
  98 sub checkconfig () {
  99         if (($config{rss} || $config{atom}) && ! length $config{url}) {
 100                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
 101         }
 102         if ($config{rss}) {
 103                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
 104         }
 105         if ($config{atom}) {
 106                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 107         }
 108         if (! exists $config{pingurl}) {
 109                 $config{pingurl}=[];
 110         }
 111 }
 112
 113 sub format (@) {
 114         my %params=@_;
 115
 116         # Fill in the inline content generated earlier. This is actually an
 117         # optimisation.
 118         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 119                 delete @inline[$1,]
 120         }eg;
 121         return $params{content};
 122 }
 123
 124 sub sessioncgi ($$) {
 125         my $q=shift;
 126         my $session=shift;
 127
 128         if ($q->param('do') eq 'blog') {
 129                 my $page=titlepage(decode_utf8($q->param('title')));
 130                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 131                 # if the page already exists, munge it to be unique
 132                 my $from=$q->param('from');
 133                 my $add="";
 134                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 135                         $add=1 unless length $add;
 136                         $add++;
 137                 }
 138                 $q->param('page', "/$from/$page$add");
 139                 # now go create the page
 140                 $q->param('do', 'create');
 141                 # make sure the editpage plugin is loaded
 142                 if (IkiWiki->can("cgi_editpage")) {
 143                         IkiWiki::cgi_editpage($q, $session);
 144                 }
 145                 else {
 146                         error(gettext("page editing not allowed"));
 147                 }
 148                 exit;
 149         }
 150 }
 151
 152 # Back to ikiwiki namespace for the rest, this code is very much
 153 # internal to ikiwiki even though it's separated into a plugin.
 154 package IkiWiki;
 155
 156 my %toping;
 157 my %feedlinks;
 158
 159 sub preprocess_inline (@) {
 160         my %params=@_;
 161
 162         if (! exists $params{pages} && ! exists $params{pagenames}) {
 163                 error gettext("missing pages parameter");
 164         }
 165         my $raw=yesno($params{raw});
 166         my $archive=yesno($params{archive});
 167         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 168         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 169         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 170         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw;
 171         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 172         my $feedonly=yesno($params{feedonly});
 173         if (! exists $params{show} && ! $archive) {
 174                 $params{show}=10;
 175         }
 176         if (! exists $params{feedshow} && exists $params{show}) {
 177                 $params{feedshow}=$params{show};
 178         }
 179
 180         my ($page, $desc, $feedtitle);
 181         $page = $params{page};
 182         if ($pagestate{$page}{meta} && $pagestate{$page}{meta}{title}) {
 183                 $feedtitle = $pagestate{$page}{meta}{title};
 184         } else {
 185                 $feedtitle = pagetitle(basename($page));
 186         }
 187         if (exists $params{description}) {
 188                 $desc = $params{description}
 189         } elsif ($pagestate{$page}{meta} && $pagestate{$page}{meta}{description}) {
 190                 $desc = $pagestate{$page}{meta}{description};
 191         } else {
 192                 if ($page =~ m!^/?index(?:$|\.)!) {
 193                         $desc = $config{wikiname};
 194                 } else {
 195                         my $descfmt = defined $config{feed_desc_fmt} ? $config{feed_desc_fmt} : '%1$s\'s %2$s';
 196                         $desc = sprintf($descfmt, $config{wikiname}, $feedtitle);
 197                 }
 198         }
 199         my $actions=yesno($params{actions});
 200         if (exists $params{template}) {
 201                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 202         }
 203         else {
 204                 $params{template} = $archive ? "archivepage" : "inlinepage";
 205         }
 206
 207         my @list;
 208
 209         if (exists $params{pagenames}) {
 210                 foreach my $p (qw(sort pages)) {
 211                         if (exists $params{$p}) {
 212                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 213                                         "pagenames", $p);
 214                         }
 215                 }
 216
 217                 @list = map { bestlink($params{page}, $_) }
 218                         split ' ', $params{pagenames};
 219
 220                 if (yesno($params{reverse})) {
 221                         @list=reverse(@list);
 222                 }
 223
 224                 foreach my $p (@list) {
 225                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 226                 }
 227         }
 228         else {
 229                 my $num=0;
 230                 if ($params{show}) {
 231                         $num=$params{show};
 232                 }
 233                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 234                         $num=$params{feedshow};
 235                 }
 236                 if ($params{skip} && $num) {
 237                         $num+=$params{skip};
 238                 }
 239
 240                 @list = pagespec_match_list($params{page}, $params{pages},
 241                         deptype => deptype($quick ? "presence" : "content"),
 242                         filter => sub { $_[0] eq $params{page} },
 243                         sort => exists $params{sort} ? $params{sort} : "age",
 244                         reverse => yesno($params{reverse}),
 245                         ($num ? (num => $num) : ()),
 246                 );
 247         }
 248
 249         if (exists $params{skip}) {
 250                 @list=@list[$params{skip} .. $#list];
 251         }
 252
 253         my @feedlist;
 254         if ($feeds) {
 255                 if (exists $params{feedshow} &&
 256                     $params{feedshow} && @list > $params{feedshow}) {
 257                         @feedlist=@list[0..$params{feedshow} - 1];
 258                 }
 259                 else {
 260                         @feedlist=@list;
 261                 }
 262         }
 263
 264         if ($params{show} && @list > $params{show}) {
 265                 @list=@list[0..$params{show} - 1];
 266         }
 267
 268         if ($feeds && exists $params{feedpages}) {
 269                 @feedlist = pagespec_match_list(
 270                         $params{page}, "($params{pages}) and ($params{feedpages})",
 271                         deptype => deptype($quick ? "presence" : "content"),
 272                         list => \@feedlist,
 273                 );
 274         }
 275
 276         my ($feedbase, $feednum);
 277         if ($feeds) {
 278                 # Ensure that multiple feeds on a page go to unique files.
 279
 280                 # Feedfile can lead to conflicts if usedirs is not enabled,
 281                 # so avoid supporting it in that case.
 282                 delete $params{feedfile} if ! $config{usedirs};
 283                 # Tight limits on legal feedfiles, to avoid security issues
 284                 # and conflicts.
 285                 if (defined $params{feedfile}) {
 286                         if ($params{feedfile} =~ /\// ||
 287                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 288                                 error("illegal feedfile");
 289                         }
 290                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 291                 }
 292                 $feedbase=targetpage($params{page}, "", $params{feedfile});
 293
 294                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 295                 if (exists $knownfeeds{$feedid}) {
 296                         $feednum=$knownfeeds{$feedid};
 297                 }
 298                 else {
 299                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 300                                 if ($feeds) {
 301                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 302                                 }
 303                         }
 304                         else {
 305                                 $feednum=$knownfeeds{$feedid}="";
 306                                 if ($feeds) {
 307                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 308                                 }
 309                         }
 310                 }
 311         }
 312
 313         my ($rssurl, $atomurl, $rssdesc, $atomdesc);
 314         if ($feeds) {
 315                 if ($rss) {
 316                         $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage})));
 317                         $rssdesc = gettext("%s (RSS feed)", $desc);
 318                 }
 319                 if ($atom) {
 320                         $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage})));
 321                         $atomdesc = gettext("%s (Atom feed)", $desc);
 322                 }
 323         }
 324
 325         my $ret="";
 326
 327         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 328             (exists $params{postform} && yesno($params{postform}))) &&
 329             IkiWiki->can("cgi_editpage")) {
 330                 # Add a blog post form, with feed buttons.
 331                 my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
 332                 $formtemplate->param(cgiurl => IkiWiki::cgiurl());
 333                 $formtemplate->param(rootpage => rootpage(%params));
 334                 if ($feeds) {
 335                         if ($rss) {
 336                                 $formtemplate->param(rssurl => $rssurl);
 337                                 $formtemplate->param(rssdesc => $rssdesc);
 338                         }
 339                         if ($atom) {
 340                                 $formtemplate->param(atomurl => $atomurl);
 341                                 $formtemplate->param(atomdesc => $atomdesc);
 342                         }
 343                 }
 344                 if (exists $params{postformtext}) {
 345                         $formtemplate->param(postformtext =>
 346                                 $params{postformtext});
 347                 }
 348                 else {
 349                         $formtemplate->param(postformtext =>
 350                                 gettext("Add a new post titled:"));
 351                 }
 352                 $ret.=$formtemplate->output;
 353
 354                 # The post form includes the feed buttons, so
 355                 # emptyfeeds cannot be hidden.
 356                 $emptyfeeds=1;
 357         }
 358         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 359                 # Add feed buttons.
 360                 my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
 361                 if ($rss) {
 362                         $linktemplate->param(rssurl => $rssurl);
 363                         $linktemplate->param(rssdesc => $rssdesc);
 364                 }
 365                 if ($atom) {
 366                         $linktemplate->param(atomurl => $atomurl);
 367                         $linktemplate->param(atomdesc => $atomdesc);
 368                 }
 369                 $ret.=$linktemplate->output;
 370         }
 371
 372         if (! $feedonly) {
 373                 my $template;
 374                 if (! $raw) {
 375                         # cannot use wiki pages as templates; template not sanitized due to
 376                         # format hook hack
 377                         eval {
 378                                 $template=template_depends($params{template}.".tmpl", $params{page},
 379                                         blind_cache => 1);
 380                         };
 381                         if ($@) {
 382                                 error sprintf(gettext("failed to process template %s"), $params{template}.".tmpl").": $@";
 383                         }
 384                 }
 385                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 386
 387                 foreach my $page (@list) {
 388                         my $file = $pagesources{$page};
 389                         my $type = pagetype($file);
 390                         if (! $raw) {
 391                                 if ($needcontent) {
 392                                         # Get the content before populating the
 393                                         # template, since getting the content uses
 394                                         # the same template if inlines are nested.
 395                                         my $content=get_inline_content($page, $params{destpage});
 396                                         $template->param(content => $content);
 397                                 }
 398                                 $template->param(pageurl => urlto($page, $params{destpage}));
 399                                 $template->param(inlinepage => $page);
 400                                 $template->param(title => pagetitle(basename($page)));
 401                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}, 1));
 402                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 403                                 $template->param(first => 1) if $page eq $list[0];
 404                                 $template->param(last => 1) if $page eq $list[$#list];
 405                                 $template->param(html5 => $config{html5});
 406
 407                                 if ($actions) {
 408                                         my $file = $pagesources{$page};
 409                                         my $type = pagetype($file);
 410                                         if ($config{discussion}) {
 411                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 412                                                     (length $config{cgiurl} ||
 413                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 414                                                         $template->param(have_actions => 1);
 415                                                         $template->param(discussionlink =>
 416                                                                 htmllink($page,
 417                                                                         $params{destpage},
 418                                                                         $config{discussionpage},
 419                                                                         noimageinline => 1,
 420                                                                         forcesubpage => 1));
 421                                                 }
 422                                         }
 423                                         if (length $config{cgiurl} &&
 424                                             defined $type &&
 425                                             IkiWiki->can("cgi_editpage")) {
 426                                                 $template->param(have_actions => 1);
 427                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 428
 429                                         }
 430                                 }
 431
 432                                 run_hooks(pagetemplate => sub {
 433                                         shift->(page => $page, destpage => $params{destpage},
 434                                                 template => $template,);
 435                                 });
 436
 437                                 $ret.=$template->output;
 438                                 $template->clear_params;
 439                         }
 440                         else {
 441                                 if (defined $type) {
 442                                         $ret.="\n".
 443                                               linkify($page, $params{destpage},
 444                                               preprocess($page, $params{destpage},
 445                                               filter($page, $params{destpage},
 446                                               readfile(srcfile($file)))));
 447                                 }
 448                                 else {
 449                                         $ret.="\n".
 450                                               readfile(srcfile($file));
 451                                 }
 452                         }
 453                 }
 454         }
 455
 456         if ($feeds && ($emptyfeeds || @feedlist)) {
 457                 if ($rss) {
 458                         my $rssp=$feedbase."rss".$feednum;
 459                         will_render($params{destpage}, $rssp);
 460                         if (! $params{preview}) {
 461                                 writefile($rssp, $config{destdir},
 462                                         genfeed("rss",
 463                                                 $config{url}."/".$rssp, $feedtitle, $desc, $params{guid}, $params{destpage}, @feedlist));
 464                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 465                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$rssdesc" href="$rssurl" />};
 466                         }
 467                 }
 468                 if ($atom) {
 469                         my $atomp=$feedbase."atom".$feednum;
 470                         will_render($params{destpage}, $atomp);
 471                         if (! $params{preview}) {
 472                                 writefile($atomp, $config{destdir},
 473                                         genfeed("atom", $config{url}."/".$atomp, $feedtitle, $desc, $params{guid}, $params{destpage}, @feedlist));
 474                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 475                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$atomdesc" href="$atomurl" />};
 476                         }
 477                 }
 478         }
 479
 480         clear_inline_content_cache();
 481
 482         return $ret if $raw || $nested;
 483         push @inline, $ret;
 484         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 485 }
 486
 487 sub pagetemplate_inline (@) {
 488         my %params=@_;
 489         my $page=$params{page};
 490         my $template=$params{template};
 491
 492         $template->param(feedlinks => $feedlinks{$page})
 493                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 494 }
 495
 496 {
 497 my %inline_content;
 498 my $cached_destpage="";
 499
 500 sub get_inline_content ($$) {
 501         my $page=shift;
 502         my $destpage=shift;
 503
 504         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 505                 return $inline_content{$page};
 506         }
 507
 508         my $file=$pagesources{$page};
 509         my $type=pagetype($file);
 510         my $ret="";
 511         if (defined $type) {
 512                 $nested++;
 513                 $ret=htmlize($page, $destpage, $type,
 514                        linkify($page, $destpage,
 515                        preprocess($page, $destpage,
 516                        filter($page, $destpage,
 517                        readfile(srcfile($file))))));
 518                 $nested--;
 519                 if (isinternal($page)) {
 520                         # make inlined text of internal pages searchable
 521                         run_hooks(indexhtml => sub {
 522                                 shift->(page => $page, destpage => $page,
 523                                         content => $ret);
 524                         });
 525                 }
 526         }
 527
 528         if ($cached_destpage ne $destpage) {
 529                 clear_inline_content_cache();
 530                 $cached_destpage=$destpage;
 531         }
 532         return $inline_content{$page}=$ret;
 533 }
 534
 535 sub clear_inline_content_cache () {
 536         %inline_content=();
 537 }
 538
 539 }
 540
 541 sub date_822 ($) {
 542         my $time=shift;
 543
 544         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 545         POSIX::setlocale(&POSIX::LC_TIME, "C");
 546         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 547         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 548         return $ret;
 549 }
 550
 551 sub absolute_urls ($$) {
 552         # needed because rss sucks
 553         my $html=shift;
 554         my $baseurl=shift;
 555
 556         my $url=$baseurl;
 557         $url=~s/[^\/]+$//;
 558         my $urltop; # calculated if needed
 559
 560         my $ret="";
 561
 562         eval q{use HTML::Parser; use HTML::Tagset};
 563         die $@ if $@;
 564         my $p = HTML::Parser->new(api_version => 3);
 565         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 566         $p->handler(start => sub {
 567                 my ($tagname, $pos, $text) = @_;
 568                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 569                         while (4 <= @$pos) {
 570                                 # use attribute sets from right to left
 571                                 # to avoid invalidating the offsets
 572                                 # when replacing the values
 573                                 my ($k_offset, $k_len, $v_offset, $v_len) =
 574                                         splice(@$pos, -4);
 575                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 576                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 577                                 next unless $v_offset; # 0 v_offset means no value
 578                                 my $v = substr($text, $v_offset, $v_len);
 579                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 580                                 if ($v=~/^#/) {
 581                                         $v=$baseurl.$v; # anchor
 582                                 }
 583                                 elsif ($v=~/^(?!\w+:)[^\/]/) {
 584                                         $v=$url.$v; # relative url
 585                                 }
 586                                 elsif ($v=~/^\//) {
 587                                         if (! defined $urltop) {
 588                                                 # what is the non path part of the url?
 589                                                 my $top_uri = URI->new($url);
 590                                                 $top_uri->path_query(""); # reset the path
 591                                                 $urltop = $top_uri->as_string;
 592                                         }
 593                                         $v=$urltop.$v; # url relative to top of site
 594                                 }
 595                                 $v =~ s/\"/&quot;/g; # since we quote with ""
 596                                 substr($text, $v_offset, $v_len) = qq("$v");
 597                         }
 598                 }
 599                 $ret.=$text;
 600         }, "tagname, tokenpos, text");
 601         $p->parse($html);
 602         $p->eof;
 603
 604         return $ret;
 605 }
 606
 607 sub genfeed ($$$$$@) {
 608         my $feedtype=shift;
 609         my $feedurl=shift;
 610         my $feedtitle=shift;
 611         my $feeddesc=shift;
 612         my $guid=shift;
 613         my $page=shift;
 614         my @pages=@_;
 615
 616         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 617
 618         my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
 619         my $content="";
 620         my $lasttime = 0;
 621         foreach my $p (@pages) {
 622                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 623                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 624
 625                 $itemtemplate->param(
 626                         title => pagetitle(basename($p)),
 627                         url => $u,
 628                         permalink => $u,
 629                         cdate_822 => date_822($pagectime{$p}),
 630                         mdate_822 => date_822($pagemtime{$p}),
 631                         cdate_3339 => date_3339($pagectime{$p}),
 632                         mdate_3339 => date_3339($pagemtime{$p}),
 633                 );
 634
 635                 if (exists $pagestate{$p}) {
 636                         if (exists $pagestate{$p}{meta}{guid}) {
 637                                 eval q{use HTML::Entities};
 638                                 $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
 639                         }
 640
 641                         if (exists $pagestate{$p}{meta}{updated}) {
 642                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 643                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 644                         }
 645                 }
 646
 647                 if ($itemtemplate->query(name => "enclosure")) {
 648                         my $file=$pagesources{$p};
 649                         my $type=pagetype($file);
 650                         if (defined $type) {
 651                                 $itemtemplate->param(content => $pcontent);
 652                         }
 653                         else {
 654                                 my $size=(srcfile_stat($file))[8];
 655                                 my $mime="unknown";
 656                                 eval q{use File::MimeInfo};
 657                                 if (! $@) {
 658                                         $mime = mimetype($file);
 659                                 }
 660                                 $itemtemplate->param(
 661                                         enclosure => $u,
 662                                         type => $mime,
 663                                         length => $size,
 664                                 );
 665                         }
 666                 }
 667                 else {
 668                         $itemtemplate->param(content => $pcontent);
 669                 }
 670
 671                 run_hooks(pagetemplate => sub {
 672                         shift->(page => $p, destpage => $page,
 673                                 template => $itemtemplate);
 674                 });
 675
 676                 $content.=$itemtemplate->output;
 677                 $itemtemplate->clear_params;
 678
 679                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 680         }
 681
 682         my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
 683         $template->param(
 684                 title => $feedtitle,
 685                 wikiname => $config{wikiname},
 686                 pageurl => $url,
 687                 content => $content,
 688                 feeddesc => $feeddesc,
 689                 guid => $guid,
 690                 feeddate => date_3339($lasttime),
 691                 feedurl => $feedurl,
 692                 version => $IkiWiki::version,
 693         );
 694         run_hooks(pagetemplate => sub {
 695                 shift->(page => $page, destpage => $page,
 696                         template => $template);
 697         });
 698
 699         return $template->output;
 700 }
 701
 702 sub pingurl (@) {
 703         return unless @{$config{pingurl}} && %toping;
 704
 705         eval q{require RPC::XML::Client};
 706         if ($@) {
 707                 debug(gettext("RPC::XML::Client not found, not pinging"));
 708                 return;
 709         }
 710
 711         # daemonize here so slow pings don't slow down wiki updates
 712         defined(my $pid = fork) or error("Can't fork: $!");
 713         return if $pid;
 714         chdir '/';
 715         POSIX::setsid() or error("Can't start a new session: $!");
 716         open STDIN, '/dev/null';
 717         open STDOUT, '>/dev/null';
 718         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 719
 720         # Don't need to keep a lock on the wiki as a daemon.
 721         IkiWiki::unlockwiki();
 722
 723         foreach my $page (keys %toping) {
 724                 my $title=pagetitle(basename($page), 0);
 725                 my $url=urlto($page, "", 1);
 726                 foreach my $pingurl (@{$config{pingurl}}) {
 727                         debug("Pinging $pingurl for $page");
 728                         eval {
 729                                 my $client = RPC::XML::Client->new($pingurl);
 730                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 731                                         $title, $url);
 732                                 my $res = $client->send_request($req);
 733                                 if (! ref $res) {
 734                                         error("Did not receive response to ping");
 735                                 }
 736                                 my $r=$res->value;
 737                                 if (! exists $r->{flerror} || $r->{flerror}) {
 738                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 739                                 }
 740                         };
 741                         if ($@) {
 742                                 error "Ping failed: $@";
 743                         }
 744                 }
 745         }
 746
 747         exit 0; # daemon done
 748 }
 749
 750
 751 sub rootpage (@) {
 752         my %params=@_;
 753
 754         my $rootpage;
 755         if (exists $params{rootpage}) {
 756                 $rootpage=bestlink($params{page}, $params{rootpage});
 757                 if (!length $rootpage) {
 758                         $rootpage=$params{rootpage};
 759                 }
 760         }
 761         else {
 762                 $rootpage=$params{page};
 763         }
 764         return $rootpage;
 765 }
 766
 767 1