git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use IkiWiki;
   9 use Encode;
  10
  11 sub linkify ($$$) { #{{{
  12         my $lpage=shift;
  13         my $page=shift;
  14         my $content=shift;
  15
  16         $content =~ s{(\\?)$config{wiki_link_regexp}}{
  17                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
  18                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
  19         }eg;
  20
  21         return $content;
  22 } #}}}
  23
  24 sub htmlize ($$) { #{{{
  25         my $type=shift;
  26         my $content=shift;
  27
  28         if (! $INC{"/usr/bin/markdown"}) {
  29                 # Note: a proper perl module is available in Debian
  30                 # for markdown, but not upstream yet.
  31                 no warnings 'once';
  32                 $blosxom::version="is a proper perl module too much to ask?";
  33                 use warnings 'all';
  34                 do "/usr/bin/markdown";
  35         }
  36
  37         if ($type eq '.mdwn') {
  38                 # Workaround for perl bug (#376329)
  39                 $content=Encode::encode_utf8($content);
  40                 $content=Encode::encode_utf8($content);
  41                 $content=Markdown::Markdown($content);
  42                 $content=Encode::decode_utf8($content);
  43                 $content=Encode::decode_utf8($content);
  44         }
  45         else {
  46                 error("htmlization of $type not supported");
  47         }
  48
  49         if (exists $hooks{sanitize}) {
  50                 foreach my $id (keys %{$hooks{sanitize}}) {
  51                         $content=$hooks{sanitize}{$id}{call}->($content);
  52                 }
  53         }
  54
  55         return $content;
  56 } #}}}
  57
  58 sub backlinks ($) { #{{{
  59         my $page=shift;
  60
  61         my @links;
  62         foreach my $p (keys %links) {
  63                 next if bestlink($page, $p) eq $page;
  64                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
  65                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
  66
  67                         # Trim common dir prefixes from both pages.
  68                         my $p_trimmed=$p;
  69                         my $page_trimmed=$page;
  70                         my $dir;
  71                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  72                                 defined $dir &&
  73                                 $p_trimmed=~s/^\Q$dir\E// &&
  74                                 $page_trimmed=~s/^\Q$dir\E//;
  75
  76                         push @links, { url => $href, page => $p_trimmed };
  77                 }
  78         }
  79
  80         return sort { $a->{page} cmp $b->{page} } @links;
  81 } #}}}
  82
  83 sub parentlinks ($) { #{{{
  84         my $page=shift;
  85
  86         my @ret;
  87         my $pagelink="";
  88         my $path="";
  89         my $skip=1;
  90         foreach my $dir (reverse split("/", $page)) {
  91                 if (! $skip) {
  92                         $path.="../";
  93                         unshift @ret, { url => "$path$dir.html", page => $dir };
  94                 }
  95                 else {
  96                         $skip=0;
  97                 }
  98         }
  99         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
 100         return @ret;
 101 } #}}}
 102
 103 sub preprocess ($$;$) { #{{{
 104         my $page=shift;
 105         my $content=shift;
 106         my $onlystrip=shift || 0; # strip directives without processing
 107
 108         my $handle=sub {
 109                 my $escape=shift;
 110                 my $command=shift;
 111                 my $params=shift;
 112                 if (length $escape) {
 113                         return "[[$command $params]]";
 114                 }
 115                 elsif ($onlystrip) {
 116                         return "";
 117                 }
 118                 elsif (exists $hooks{preprocess}{$command}) {
 119                         # Note: preserve order of params, some plugins may
 120                         # consider it significant.
 121                         my @params;
 122                         while ($params =~ /(\w+)=\"?([^"]+)"?(\s+|$)/g) {
 123                                 push @params, $1, $2;
 124                         }
 125                         return $hooks{preprocess}{$command}{call}->(@params, page => $page);
 126                 }
 127                 else {
 128                         return "[[$command not processed]]";
 129                 }
 130         };
 131
 132         $content =~ s{(\\?)$config{wiki_processor_regexp}}{$handle->($1, $2, $3)}eg;
 133         return $content;
 134 } #}}}
 135
 136 sub add_depends ($$) { #{{{
 137         my $page=shift;
 138         my $globlist=shift;
 139
 140         if (! exists $depends{$page}) {
 141                 $depends{$page}=$globlist;
 142         }
 143         else {
 144                 $depends{$page}=globlist_merge($depends{$page}, $globlist);
 145         }
 146 } # }}}
 147
 148 sub globlist_merge ($$) { #{{{
 149         my $a=shift;
 150         my $b=shift;
 151
 152         my $ret="";
 153         # Only add negated globs if they are not matched by the other globlist.
 154         foreach my $i ((map { [ $a, $_ ] } split(" ", $b)),
 155                        (map { [ $b, $_ ] } split(" ", $a))) {
 156                 if ($i->[1]=~/^!(.*)/) {
 157                         if (! globlist_match($1, $i->[0])) {
 158                                 $ret.=" ".$i->[1];
 159                         }
 160                 }
 161                 else {
 162                         $ret.=" ".$i->[1];
 163                 }
 164         }
 165
 166         return $ret;
 167 } #}}}
 168
 169 sub genpage ($$$) { #{{{
 170         my $page=shift;
 171         my $content=shift;
 172         my $mtime=shift;
 173
 174         my $title=pagetitle(basename($page));
 175
 176         my $template=template("page.tmpl", blind_cache => 1);
 177         my $actions=0;
 178
 179         if (length $config{cgiurl}) {
 180                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 181                 $template->param(prefsurl => cgiurl(do => "prefs"));
 182                 if ($config{rcs}) {
 183                         $template->param(recentchangesurl => cgiurl(do => "recentchanges"));
 184                 }
 185                 $actions++;
 186         }
 187
 188         if (length $config{historyurl}) {
 189                 my $u=$config{historyurl};
 190                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
 191                 $template->param(historyurl => $u);
 192                 $actions++;
 193         }
 194         if ($config{discussion}) {
 195                 $template->param(discussionlink => htmllink($page, $page, "Discussion", 1, 1));
 196                 $actions++;
 197         }
 198
 199         if ($actions) {
 200                 $template->param(have_actions => 1);
 201         }
 202
 203         $template->param(
 204                 title => $title,
 205                 wikiname => $config{wikiname},
 206                 parentlinks => [parentlinks($page)],
 207                 content => $content,
 208                 backlinks => [backlinks($page)],
 209                 mtime => displaytime($mtime),
 210                 styleurl => styleurl($page),
 211         );
 212
 213         if (exists $hooks{pagetemplate}) {
 214                 foreach my $id (keys %{$hooks{pagetemplate}}) {
 215                         $hooks{pagetemplate}{$id}{call}->($page, $template);
 216                 }
 217         }
 218
 219         return $template->output;
 220 } #}}}
 221
 222 sub check_overwrite ($$) { #{{{
 223         # Important security check. Make sure to call this before saving
 224         # any files to the source directory.
 225         my $dest=shift;
 226         my $src=shift;
 227
 228         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 229                 error("$dest already exists and was not rendered from $src before");
 230         }
 231 } #}}}
 232
 233 sub displaytime ($) { #{{{
 234         my $time=shift;
 235
 236         eval q{use POSIX};
 237         # strftime doesn't know about encodings, so make sure
 238         # its output is properly treated as utf8
 239         return Encode::decode_utf8(POSIX::strftime(
 240                         $config{timeformat}, localtime($time)));
 241 } #}}}
 242
 243 sub mtime ($) { #{{{
 244         my $file=shift;
 245
 246         return (stat($file))[9];
 247 } #}}}
 248
 249 sub findlinks ($$) { #{{{
 250         my $page=shift;
 251         my $content=shift;
 252
 253         my @links;
 254         while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 255                 push @links, titlepage($2);
 256         }
 257         if ($config{discussion}) {
 258                 # Discussion links are a special case since they're not in the
 259                 # text of the page, but on its template.
 260                 return @links, "$page/discussion";
 261         }
 262         else {
 263                 return @links;
 264         }
 265 } #}}}
 266
 267 sub render ($) { #{{{
 268         my $file=shift;
 269
 270         my $type=pagetype($file);
 271         my $srcfile=srcfile($file);
 272         if ($type ne 'unknown') {
 273                 my $content=readfile($srcfile);
 274                 my $page=pagename($file);
 275                 delete $depends{$page};
 276
 277                 if (exists $hooks{filter}) {
 278                         foreach my $id (keys %{$hooks{filter}}) {
 279                                 $content=$hooks{filter}{$id}{call}->(
 280                                         page => $page,
 281                                         content => $content
 282                                 );
 283                         }
 284                 }
 285
 286                 $links{$page}=[findlinks($page, $content)];
 287
 288                 $content=linkify($page, $page, $content);
 289                 $content=preprocess($page, $content);
 290                 $content=htmlize($type, $content);
 291
 292                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 293                 writefile(htmlpage($page), $config{destdir},
 294                         genpage($page, $content, mtime($srcfile)));
 295                 $oldpagemtime{$page}=time;
 296                 $renderedfiles{$page}=htmlpage($page);
 297         }
 298         else {
 299                 my $content=readfile($srcfile, 1);
 300                 $links{$file}=[];
 301                 delete $depends{$file};
 302                 check_overwrite("$config{destdir}/$file", $file);
 303                 writefile($file, $config{destdir}, $content, 1);
 304                 $oldpagemtime{$file}=time;
 305                 $renderedfiles{$file}=$file;
 306         }
 307 } #}}}
 308
 309 sub prune ($) { #{{{
 310         my $file=shift;
 311
 312         unlink($file);
 313         my $dir=dirname($file);
 314         while (rmdir($dir)) {
 315                 $dir=dirname($dir);
 316         }
 317 } #}}}
 318
 319 sub refresh () { #{{{
 320         # find existing pages
 321         my %exists;
 322         my @files;
 323         eval q{use File::Find};
 324         find({
 325                 no_chdir => 1,
 326                 wanted => sub {
 327                         $_ = Encode::decode_utf8($_);
 328                         if (/$config{wiki_file_prune_regexp}/) {
 329                                 $File::Find::prune=1;
 330                         }
 331                         elsif (! -d $_ && ! -l $_) {
 332                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 333                                 if (! defined $f) {
 334                                         warn("skipping bad filename $_\n");
 335                                 }
 336                                 else {
 337                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 338                                         push @files, $f;
 339                                         $exists{pagename($f)}=1;
 340                                 }
 341                         }
 342                 },
 343         }, $config{srcdir});
 344         find({
 345                 no_chdir => 1,
 346                 wanted => sub {
 347                         $_ = Encode::decode_utf8($_);
 348                         if (/$config{wiki_file_prune_regexp}/) {
 349                                 $File::Find::prune=1;
 350                         }
 351                         elsif (! -d $_ && ! -l $_) {
 352                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 353                                 if (! defined $f) {
 354                                         warn("skipping bad filename $_\n");
 355                                 }
 356                                 else {
 357                                         # Don't add files that are in the
 358                                         # srcdir.
 359                                         $f=~s/^\Q$config{underlaydir}\E\/?//;
 360                                         if (! -e "$config{srcdir}/$f" &&
 361                                             ! -l "$config{srcdir}/$f") {
 362                                                 push @files, $f;
 363                                                 $exists{pagename($f)}=1;
 364                                         }
 365                                 }
 366                         }
 367                 },
 368         }, $config{underlaydir});
 369
 370         my %rendered;
 371
 372         # check for added or removed pages
 373         my @add;
 374         foreach my $file (@files) {
 375                 my $page=pagename($file);
 376                 if (! $oldpagemtime{$page}) {
 377                         debug("new page $page") unless exists $pagectime{$page};
 378                         push @add, $file;
 379                         $links{$page}=[];
 380                         $pagesources{$page}=$file;
 381                         if ($config{getctime} && -e "$config{srcdir}/$file") {
 382                                 $pagectime{$page}=rcs_getctime("$config{srcdir}/$file");
 383                         }
 384                         elsif (! exists $pagectime{$page}) {
 385                                 $pagectime{$page}=mtime(srcfile($file));
 386                         }
 387                 }
 388         }
 389         my @del;
 390         foreach my $page (keys %oldpagemtime) {
 391                 if (! $exists{$page}) {
 392                         debug("removing old page $page");
 393                         push @del, $pagesources{$page};
 394                         prune($config{destdir}."/".$renderedfiles{$page});
 395                         delete $renderedfiles{$page};
 396                         $oldpagemtime{$page}=0;
 397                         delete $pagesources{$page};
 398                 }
 399         }
 400
 401         # render any updated files
 402         foreach my $file (@files) {
 403                 my $page=pagename($file);
 404
 405                 if (! exists $oldpagemtime{$page} ||
 406                     mtime(srcfile($file)) > $oldpagemtime{$page}) {
 407                         debug("rendering $file");
 408                         render($file);
 409                         $rendered{$file}=1;
 410                 }
 411         }
 412
 413         # if any files were added or removed, check to see if each page
 414         # needs an update due to linking to them or inlining them.
 415         # TODO: inefficient; pages may get rendered above and again here;
 416         # problem is the bestlink may have changed and we won't know until
 417         # now
 418         if (@add || @del) {
 419 FILE:           foreach my $file (@files) {
 420                         my $page=pagename($file);
 421                         foreach my $f (@add, @del) {
 422                                 my $p=pagename($f);
 423                                 foreach my $link (@{$links{$page}}) {
 424                                         if (bestlink($page, $link) eq $p) {
 425                                                 debug("rendering $file, which links to $p");
 426                                                 render($file);
 427                                                 $rendered{$file}=1;
 428                                                 next FILE;
 429                                         }
 430                                 }
 431                         }
 432                 }
 433         }
 434
 435         # Handle backlinks; if a page has added/removed links, update the
 436         # pages it links to. Also handles rebuilding dependant pages.
 437         # TODO: inefficient; pages may get rendered above and again here;
 438         # problem is the backlinks could be wrong in the first pass render
 439         # above
 440         if (%rendered || @del) {
 441                 foreach my $f (@files) {
 442                         my $p=pagename($f);
 443                         if (exists $depends{$p}) {
 444                                 foreach my $file (keys %rendered, @del) {
 445                                         next if $f eq $file;
 446                                         my $page=pagename($file);
 447                                         if (globlist_match($page, $depends{$p})) {
 448                                                 debug("rendering $f, which depends on $page");
 449                                                 render($f);
 450                                                 $rendered{$f}=1;
 451                                                 last;
 452                                         }
 453                                 }
 454                         }
 455                 }
 456
 457                 my %linkchanged;
 458                 foreach my $file (keys %rendered, @del) {
 459                         my $page=pagename($file);
 460
 461                         if (exists $links{$page}) {
 462                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 463                                         if (length $link &&
 464                                             (! exists $oldlinks{$page} ||
 465                                              ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
 466                                                 $linkchanged{$link}=1;
 467                                         }
 468                                 }
 469                         }
 470                         if (exists $oldlinks{$page}) {
 471                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 472                                         if (length $link &&
 473                                             (! exists $links{$page} ||
 474                                              ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
 475                                                 $linkchanged{$link}=1;
 476                                         }
 477                                 }
 478                         }
 479                 }
 480                 foreach my $link (keys %linkchanged) {
 481                         my $linkfile=$pagesources{$link};
 482                         if (defined $linkfile) {
 483                                 debug("rendering $linkfile, to update its backlinks");
 484                                 render($linkfile);
 485                                 $rendered{$linkfile}=1;
 486                         }
 487                 }
 488         }
 489
 490         if (@del && exists $hooks{delete}) {
 491                 foreach my $id (keys %{$hooks{delete}}) {
 492                         $hooks{delete}{$id}{call}->(@del);
 493                 }
 494         }
 495         if (%rendered && exists $hooks{change}) {
 496                 foreach my $id (keys %{$hooks{change}}) {
 497                         $hooks{change}{$id}{call}->(keys %rendered);
 498                 }
 499         }
 500 } #}}}
 501
 502 1