git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "rename", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  13         hook(type => "rename", id => "rename", call => \&rename);
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 }
  23
  24 sub check_canrename ($$$$$$) {
  25         my $src=shift;
  26         my $srcfile=shift;
  27         my $dest=shift;
  28         my $destfile=shift;
  29         my $q=shift;
  30         my $session=shift;
  31
  32         my $attachment=! defined pagetype($pagesources{$src});
  33
  34         # Must be a known source file.
  35         if (! exists $pagesources{$src}) {
  36                 error(sprintf(gettext("%s does not exist"),
  37                         htmllink("", "", $src, noimageinline => 1)));
  38         }
  39
  40         # Must exist on disk, and be a regular file.
  41         if (! -e "$config{srcdir}/$srcfile") {
  42                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  43         }
  44         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  45                 error(sprintf(gettext("%s is not a file"), $srcfile));
  46         }
  47
  48         # Must be editable.
  49         IkiWiki::check_canedit($src, $q, $session);
  50         if ($attachment) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  53                 }
  54                 else {
  55                         error("renaming of attachments is not allowed");
  56                 }
  57         }
  58
  59         # Dest checks can be omitted by passing undef.
  60         if (defined $dest) {
  61                 if ($srcfile eq $destfile) {
  62                         error(gettext("no change to the file name was specified"));
  63                 }
  64
  65                 # Must be a legal filename, and not absolute.
  66                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  67                     $destfile=~/^\//) {
  68                         error(sprintf(gettext("illegal name")));
  69                 }
  70
  71                 # Must not be a known source file.
  72                 if ($src ne $dest && exists $pagesources{$dest}) {
  73                         error(sprintf(gettext("%s already exists"),
  74                                 htmllink("", "", $dest, noimageinline => 1)));
  75                 }
  76
  77                 # Must not exist on disk already.
  78                 if (-l "$config{srcdir}/$destfile" || -e _) {
  79                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  80                 }
  81
  82                 # Must be editable.
  83                 IkiWiki::check_canedit($dest, $q, $session);
  84                 if ($attachment) {
  85                         # Note that $srcfile is used here, not $destfile,
  86                         # because it wants the current file, to check it.
  87                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  88                 }
  89         }
  90
  91         my $canrename;
  92         IkiWiki::run_hooks(canrename => sub {
  93                 return if defined $canrename;
  94                 my $ret=shift->(cgi => $q, session => $session,
  95                         src => $src, srcfile => $srcfile,
  96                         dest => $dest, destfile => $destfile);
  97                 if (defined $ret) {
  98                         if ($ret eq "") {
  99                                 $canrename=1;
 100                         }
 101                         elsif (ref $ret eq 'CODE') {
 102                                 $ret->();
 103                                 $canrename=0;
 104                         }
 105                         elsif (defined $ret) {
 106                                 error($ret);
 107                                 $canrename=0;
 108                         }
 109                 }
 110         });
 111 }
 112
 113 sub rename_form ($$$) {
 114         my $q=shift;
 115         my $session=shift;
 116         my $page=shift;
 117
 118         eval q{use CGI::FormBuilder};
 119         error($@) if $@;
 120         my $f = CGI::FormBuilder->new(
 121                 name => "rename",
 122                 title => sprintf(gettext("rename %s"), pagetitle($page)),
 123                 header => 0,
 124                 charset => "utf-8",
 125                 method => 'POST',
 126                 javascript => 0,
 127                 params => $q,
 128                 action => $config{cgiurl},
 129                 stylesheet => IkiWiki::baseurl()."style.css",
 130                 fields => [qw{do page new_name attachment}],
 131         );
 132
 133         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
 134         $f->field(name => "page", type => "hidden", value => $page, force => 1);
 135         $f->field(name => "new_name", value => pagetitle($page, 1), size => 60);
 136         if (!$q->param("attachment")) {
 137                 # insert the standard extensions
 138                 my @page_types;
 139                 if (exists $IkiWiki::hooks{htmlize}) {
 140                         @page_types=grep { !/^_/ }
 141                                 keys %{$IkiWiki::hooks{htmlize}};
 142                 }
 143
 144                 # make sure the current extension is in the list
 145                 my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
 146                 if (! $IkiWiki::hooks{htmlize}{$ext}) {
 147                         unshift(@page_types, $ext);
 148                 }
 149
 150                 $f->field(name => "type", type => 'select',
 151                         options => \@page_types,
 152                         value => $ext, force => 1);
 153
 154                 foreach my $p (keys %pagesources) {
 155                         if ($pagesources{$p}=~m/^\Q$page\E\//) {
 156                                 $f->field(name => "subpages",
 157                                         label => "",
 158                                         type => "checkbox",
 159                                         options => [ [ 1 => gettext("Also rename SubPages and attachments") ] ],
 160                                         value => 1,
 161                                         force => 1);
 162                                 last;
 163                         }
 164                 }
 165         }
 166         $f->field(name => "attachment", type => "hidden");
 167
 168         return $f, ["Rename", "Cancel"];
 169 }
 170
 171 sub rename_start ($$$$) {
 172         my $q=shift;
 173         my $session=shift;
 174         my $attachment=shift;
 175         my $page=shift;
 176
 177         check_canrename($page, $pagesources{$page}, undef, undef,
 178                 $q, $session);
 179
 180         # Save current form state to allow returning to it later
 181         # without losing any edits.
 182         # (But don't save what button was submitted, to avoid
 183         # looping back to here.)
 184         # Note: "_submit" is CGI::FormBuilder internals.
 185         $q->param(-name => "_submit", -value => "");
 186         $session->param(postrename => scalar $q->Vars);
 187         IkiWiki::cgi_savesession($session);
 188
 189         if (defined $attachment) {
 190                 $q->param(-name => "attachment", -value => $attachment);
 191         }
 192         my ($f, $buttons)=rename_form($q, $session, $page);
 193         IkiWiki::showform($f, $buttons, $session, $q);
 194         exit 0;
 195 }
 196
 197 sub postrename ($;$$$) {
 198         my $session=shift;
 199         my $src=shift;
 200         my $dest=shift;
 201         my $attachment=shift;
 202
 203         # Load saved form state and return to edit page.
 204         my $postrename=CGI->new($session->param("postrename"));
 205         $session->clear("postrename");
 206         IkiWiki::cgi_savesession($session);
 207
 208         if (defined $dest) {
 209                 if (! $attachment) {
 210                         # They renamed the page they were editing. This requires
 211                         # fixups to the edit form state.
 212                         # Tweak the edit form to be editing the new page.
 213                         $postrename->param("page", $dest);
 214                 }
 215
 216                 # Update edit form content to fix any links present
 217                 # on it.
 218                 $postrename->param("editcontent",
 219                         renamepage_hook($dest, $src, $dest,
 220                                  $postrename->param("editcontent")));
 221
 222                 # Get a new edit token; old was likely invalidated.
 223                 $postrename->param("rcsinfo",
 224                         IkiWiki::rcs_prepedit($pagesources{$dest}));
 225         }
 226
 227         IkiWiki::cgi_editpage($postrename, $session);
 228 }
 229
 230 sub formbuilder (@) {
 231         my %params=@_;
 232         my $form=$params{form};
 233
 234         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 235             $form->field("do") eq "create")) {
 236                 my $q=$params{cgi};
 237                 my $session=$params{session};
 238
 239                 if ($form->submitted eq "Rename" && $form->field("do") eq "edit") {
 240                         rename_start($q, $session, 0, $form->field("page"));
 241                 }
 242                 elsif ($form->submitted eq "Rename Attachment") {
 243                         my @selected=$q->param("attachment_select");
 244                         if (@selected > 1) {
 245                                 error(gettext("Only one attachment can be renamed at a time."));
 246                         }
 247                         elsif (! @selected) {
 248                                 error(gettext("Please select the attachment to rename."))
 249                         }
 250                         rename_start($q, $session, 1, $selected[0]);
 251                 }
 252         }
 253 }
 254
 255 my $renamesummary;
 256
 257 sub formbuilder_setup (@) {
 258         my %params=@_;
 259         my $form=$params{form};
 260         my $q=$params{cgi};
 261
 262         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 263             $form->field("do") eq "create")) {
 264                 # Rename button for the page, and also for attachments.
 265                 push @{$params{buttons}}, "Rename" if $form->field("do") eq "edit";
 266                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 267
 268                 if (defined $renamesummary) {
 269                         $form->tmpl_param(message => $renamesummary);
 270                 }
 271         }
 272 }
 273
 274 sub sessioncgi ($$) {
 275         my $q=shift;
 276
 277         if ($q->param("do") eq 'rename') {
 278                 my $session=shift;
 279                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 280                 IkiWiki::decode_form_utf8($form);
 281
 282                 if ($form->submitted eq 'Cancel') {
 283                         postrename($session);
 284                 }
 285                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 286                         # Queue of rename actions to perfom.
 287                         my @torename;
 288
 289                         # These untaints are safe because of the checks
 290                         # performed in check_canrename later.
 291                         my $src=$q->param("page");
 292                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 293                         my $dest=IkiWiki::possibly_foolish_untaint(titlepage($q->param("new_name")));
 294                         my $destfile=$dest;
 295                         if (! $q->param("attachment")) {
 296                                 my $type=$q->param('type');
 297                                 if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 298                                         $type=IkiWiki::possibly_foolish_untaint($type);
 299                                 }
 300                                 else {
 301                                         my ($ext)=$srcfile=~/\.([^.]+)$/;
 302                                         $type=$ext;
 303                                 }
 304
 305                                 $destfile=newpagefile($dest, $type);
 306                         }
 307                         push @torename, {
 308                                 src => $src,
 309                                 srcfile => $srcfile,
 310                                 dest => $dest,
 311                                 destfile => $destfile,
 312                                 required => 1,
 313                         };
 314
 315                         @torename=rename_hook(
 316                                 torename => \@torename,
 317                                 done => {},
 318                                 cgi => $q,
 319                                 session => $session,
 320                         );
 321
 322                         # remove duplicates from @torename
 323                         my %seen=();
 324                         my @uniq_torename;
 325                         foreach my $item (@torename) {
 326                                 push(@uniq_torename, $item) unless $seen{$item->{src}}++;
 327                         }
 328                         @torename=@uniq_torename;
 329
 330                         require IkiWiki::Render;
 331                         IkiWiki::disable_commit_hook() if $config{rcs};
 332                         my %origpagesources=%pagesources;
 333
 334                         # First file renaming.
 335                         foreach my $rename (@torename) {
 336                                 if ($rename->{required}) {
 337                                         do_rename($rename, $q, $session);
 338                                 }
 339                                 else {
 340                                         eval {do_rename($rename, $q, $session)};
 341                                         if ($@) {
 342                                                 $rename->{error}=$@;
 343                                                 next;
 344                                         }
 345                                 }
 346
 347                                 # Temporarily tweak pagesources to point to
 348                                 # the renamed file, in case fixlinks needs
 349                                 # to edit it.
 350                                 $pagesources{$rename->{src}}=$rename->{destfile};
 351                         }
 352                         IkiWiki::rcs_commit_staged(
 353                                 sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
 354                                 $session->param("name"), $ENV{REMOTE_ADDR}) if $config{rcs};
 355
 356                         # Then link fixups.
 357                         foreach my $rename (@torename) {
 358                                 next if $rename->{src} eq $rename->{dest};
 359                                 next if $rename->{error};
 360                                 foreach my $p (fixlinks($rename, $session)) {
 361                                         # map old page names to new
 362                                         foreach my $r (@torename) {
 363                                                 next if $rename->{error};
 364                                                 if ($r->{src} eq $p) {
 365                                                         $p=$r->{dest};
 366                                                         last;
 367                                                 }
 368                                         }
 369                                         push @{$rename->{fixedlinks}}, $p;
 370                                 }
 371                         }
 372
 373                         # Then refresh.
 374                         %pagesources=%origpagesources;
 375                         if ($config{rcs}) {
 376                                 IkiWiki::enable_commit_hook();
 377                                 IkiWiki::rcs_update();
 378                         }
 379                         IkiWiki::refresh();
 380                         IkiWiki::saveindex();
 381
 382                         # Find pages with remaining, broken links.
 383                         foreach my $rename (@torename) {
 384                                 next if $rename->{src} eq $rename->{dest};
 385
 386                                 foreach my $page (keys %links) {
 387                                         my $broken=0;
 388                                         foreach my $link (@{$links{$page}}) {
 389                                                 my $bestlink=bestlink($page, $link);
 390                                                 if ($bestlink eq $rename->{src}) {
 391                                                         push @{$rename->{brokenlinks}}, $page;
 392                                                         last;
 393                                                 }
 394                                         }
 395                                 }
 396                         }
 397
 398                         # Generate a summary, that will be shown at the top
 399                         # of the edit template.
 400                         $renamesummary="";
 401                         foreach my $rename (@torename) {
 402                                 my $template=template("renamesummary.tmpl");
 403                                 $template->param(src => $rename->{srcfile});
 404                                 $template->param(dest => $rename->{destfile});
 405                                 $template->param(error => $rename->{error});
 406                                 if ($rename->{src} ne $rename->{dest}) {
 407                                         $template->param(brokenlinks_checked => 1);
 408                                         $template->param(brokenlinks => linklist($rename->{dest}, $rename->{brokenlinks}));
 409                                         $template->param(fixedlinks => linklist($rename->{dest}, $rename->{fixedlinks}));
 410                                 }
 411                                 $renamesummary.=$template->output;
 412                         }
 413
 414                         postrename($session, $src, $dest, $q->param("attachment"));
 415                 }
 416                 else {
 417                         IkiWiki::showform($form, $buttons, $session, $q);
 418                 }
 419
 420                 exit 0;
 421         }
 422 }
 423
 424 # Add subpages to the list of pages to be renamed, if needed.
 425 sub rename(@) {
 426         my %params = @_;
 427
 428         my %torename = %{$params{torename}};
 429         my $q = $params{cgi};
 430         my $src = $torename{src};
 431         my $srcfile = $torename{src};
 432         my $dest = $torename{dest};
 433         my $destfile = $torename{dest};
 434
 435         return () unless ($q->param("subpages") && $src ne $dest);
 436
 437         my @ret;
 438         foreach my $p (keys %pagesources) {
 439                 next unless $pagesources{$p}=~m/^\Q$src\E\//;
 440                 # If indexpages is enabled, the srcfile should not be confused
 441                 # with a subpage.
 442                 next if $pagesources{$p} eq $srcfile;
 443
 444                 my $d=$pagesources{$p};
 445                 $d=~s/^\Q$src\E\//$dest\//;
 446                 push @ret, {
 447                         src => $p,
 448                         srcfile => $pagesources{$p},
 449                         dest => pagename($d),
 450                         destfile => $d,
 451                         required => 0,
 452                 };
 453         }
 454         return @ret;
 455 }
 456
 457 sub linklist {
 458         # generates a list of links in a form suitable for FormBuilder
 459         my $dest=shift;
 460         my $list=shift;
 461         # converts a list of pages into a list of links
 462         # in a form suitable for FormBuilder.
 463
 464         [map {
 465                 {
 466                         page => htmllink($dest, $dest, $_,
 467                                         noimageinline => 1,
 468                                         linktext => pagetitle($_),
 469                                 )
 470                 }
 471         } @{$list}]
 472 }
 473
 474 sub renamepage_hook ($$$$) {
 475         my ($page, $src, $dest, $content)=@_;
 476
 477         IkiWiki::run_hooks(renamepage => sub {
 478                 $content=shift->(
 479                         page => $page,
 480                         oldpage => $src,
 481                         newpage => $dest,
 482                         content => $content,
 483                 );
 484         });
 485
 486         return $content;
 487 }
 488
 489 sub rename_hook (@) {
 490         my %params = @_;
 491
 492         my @torename=@{$params{torename}};
 493         my %done=%{$params{done}};
 494         my $q=$params{cgi};
 495         my $session=$params{session};
 496
 497         my @nextset;
 498         if (@torename) {
 499                 foreach my $torename (@torename) {
 500                         unless (exists $done{$torename->{src}} && $done{$torename->{src}}) {
 501                                 IkiWiki::run_hooks(rename => sub {
 502                                         push @nextset, shift->(
 503                                                 torename => $torename,
 504                                                 cgi => $q,
 505                                                 session => $session,
 506                                         );
 507                                 });
 508                                 $done{$torename->{src}}=1;
 509                         }
 510                 }
 511                 push @torename, rename_hook(
 512                         torename => \@nextset,
 513                         done => \%done,
 514                         cgi => $q,
 515                         session => $session,
 516                 );
 517                 return @torename;
 518         }
 519         else {
 520                 return ();
 521         }
 522 }
 523
 524 sub do_rename ($$$) {
 525         my $rename=shift;
 526         my $q=shift;
 527         my $session=shift;
 528
 529         # First, check if this rename is allowed.
 530         check_canrename($rename->{src},
 531                 $rename->{srcfile},
 532                 $rename->{dest},
 533                 $rename->{destfile},
 534                 $q, $session);
 535
 536         # Ensure that the dest directory exists and is ok.
 537         IkiWiki::prep_writefile($rename->{destfile}, $config{srcdir});
 538
 539         if ($config{rcs}) {
 540                 IkiWiki::rcs_rename($rename->{srcfile}, $rename->{destfile});
 541         }
 542         else {
 543                 if (! CORE::rename($config{srcdir}."/".$rename->{srcfile},
 544                              $config{srcdir}."/".$rename->{destfile})) {
 545                         error("rename: $!");
 546                 }
 547         }
 548
 549 }
 550
 551 sub fixlinks ($$$) {
 552         my $rename=shift;
 553         my $session=shift;
 554
 555         my @fixedlinks;
 556
 557         foreach my $page (keys %links) {
 558                 my $needfix=0;
 559                 foreach my $link (@{$links{$page}}) {
 560                         my $bestlink=bestlink($page, $link);
 561                         if ($bestlink eq $rename->{src}) {
 562                                 $needfix=1;
 563                                 last;
 564                         }
 565                 }
 566                 if ($needfix) {
 567                         my $file=$pagesources{$page};
 568                         my $oldcontent=readfile($config{srcdir}."/".$file);
 569                         my $content=renamepage_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
 570                         if ($oldcontent ne $content) {
 571                                 my $token=IkiWiki::rcs_prepedit($file);
 572                                 eval { writefile($file, $config{srcdir}, $content) };
 573                                 next if $@;
 574                                 my $conflict=IkiWiki::rcs_commit(
 575                                         $file,
 576                                         sprintf(gettext("update for rename of %s to %s"), $rename->{srcfile}, $rename->{destfile}),
 577                                         $token,
 578                                         $session->param("name"),
 579                                         $ENV{REMOTE_ADDR}
 580                                 );
 581                                 push @fixedlinks, $page if ! defined $conflict;
 582                         }
 583                 }
 584         }
 585
 586         return @fixedlinks;
 587 }
 588
 589 1