git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89 }
  90
  91 sub checkconfig () {
  92         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  93                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  94         }
  95         if ($config{rss}) {
  96                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  97         }
  98         if ($config{atom}) {
  99                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 100         }
 101         if (! exists $config{pingurl}) {
 102                 $config{pingurl}=[];
 103         }
 104 }
 105
 106 sub format (@) {
 107         my %params=@_;
 108
 109         # Fill in the inline content generated earlier. This is actually an
 110         # optimisation.
 111         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 112                 delete @inline[$1,]
 113         }eg;
 114         return $params{content};
 115 }
 116
 117 sub sessioncgi ($$) {
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if ($q->param('do') eq 'blog') {
 122                 my $page=titlepage(decode_utf8($q->param('title')));
 123                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 124                 # if the page already exists, munge it to be unique
 125                 my $from=$q->param('from');
 126                 my $add="";
 127                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 128                         $add=1 unless length $add;
 129                         $add++;
 130                 }
 131                 $q->param('page', $page.$add);
 132                 # now go create the page
 133                 $q->param('do', 'create');
 134                 # make sure the editpage plugin in loaded
 135                 if (IkiWiki->can("cgi_editpage")) {
 136                         IkiWiki::cgi_editpage($q, $session);
 137                 }
 138                 else {
 139                         error(gettext("page editing not allowed"));
 140                 }
 141                 exit;
 142         }
 143 }
 144
 145 # Back to ikiwiki namespace for the rest, this code is very much
 146 # internal to ikiwiki even though it's separated into a plugin.
 147 package IkiWiki;
 148
 149 my %toping;
 150 my %feedlinks;
 151
 152 sub preprocess_inline (@) {
 153         my %params=@_;
 154
 155         if (! exists $params{pages} && ! exists $params{pagenames}) {
 156                 error gettext("missing pages parameter");
 157         }
 158         my $raw=yesno($params{raw});
 159         my $archive=yesno($params{archive});
 160         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 161         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 162         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 163         my $feeds=! $nested && (exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw);
 164         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 165         my $feedonly=yesno($params{feedonly});
 166         if (! exists $params{show} && ! $archive) {
 167                 $params{show}=10;
 168         }
 169         if (! exists $params{feedshow} && exists $params{show}) {
 170                 $params{feedshow}=$params{show};
 171         }
 172         my $desc;
 173         if (exists $params{description}) {
 174                 $desc = $params{description}
 175         }
 176         else {
 177                 $desc = $config{wikiname};
 178         }
 179         my $actions=yesno($params{actions});
 180         if (exists $params{template}) {
 181                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 182         }
 183         else {
 184                 $params{template} = $archive ? "archivepage" : "inlinepage";
 185         }
 186
 187         my @list;
 188
 189         if (exists $params{pagenames}) {
 190                 foreach my $p (qw(sort pages)) {
 191                         if (exists $params{$p}) {
 192                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 193                                         "pagenames", $p);
 194                         }
 195                 }
 196
 197                 @list = map { bestlink($params{page}, $_) }
 198                         split ' ', $params{pagenames};
 199
 200                 if (yesno($params{reverse})) {
 201                         @list=reverse(@list);
 202                 }
 203
 204                 foreach my $p (@list) {
 205                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 206                 }
 207         }
 208         else {
 209                 my $num=0;
 210                 if ($params{show}) {
 211                         $num=$params{show};
 212                 }
 213                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 214                         $num=$params{feedshow};
 215                 }
 216                 if ($params{skip} && $num) {
 217                         $num+=$params{skip};
 218                 }
 219
 220                 @list = pagespec_match_list($params{page}, $params{pages},
 221                         deptype => deptype($quick ? "presence" : "content"),
 222                         filter => sub { $_[0] eq $params{page} },
 223                         sort => exists $params{sort} ? $params{sort} : "age",
 224                         reverse => yesno($params{reverse}),
 225                         ($num ? (num => $num) : ()),
 226                 );
 227         }
 228
 229         if (exists $params{skip}) {
 230                 @list=@list[$params{skip} .. $#list];
 231         }
 232
 233         my @feedlist;
 234         if ($feeds) {
 235                 if (exists $params{feedshow} &&
 236                     $params{feedshow} && @list > $params{feedshow}) {
 237                         @feedlist=@list[0..$params{feedshow} - 1];
 238                 }
 239                 else {
 240                         @feedlist=@list;
 241                 }
 242         }
 243
 244         if ($params{show} && @list > $params{show}) {
 245                 @list=@list[0..$params{show} - 1];
 246         }
 247
 248         if ($feeds && exists $params{feedpages}) {
 249                 @feedlist = pagespec_match_list(
 250                         $params{page}, "($params{pages}) and ($params{feedpages})",
 251                         deptype => deptype($quick ? "presence" : "content"),
 252                         list => \@feedlist,
 253                 );
 254         }
 255
 256         my ($feedbase, $feednum);
 257         if ($feeds) {
 258                 # Ensure that multiple feeds on a page go to unique files.
 259
 260                 # Feedfile can lead to conflicts if usedirs is not enabled,
 261                 # so avoid supporting it in that case.
 262                 delete $params{feedfile} if ! $config{usedirs};
 263                 # Tight limits on legal feedfiles, to avoid security issues
 264                 # and conflicts.
 265                 if (defined $params{feedfile}) {
 266                         if ($params{feedfile} =~ /\// ||
 267                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 268                                 error("illegal feedfile");
 269                         }
 270                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 271                 }
 272                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 273
 274                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 275                 if (exists $knownfeeds{$feedid}) {
 276                         $feednum=$knownfeeds{$feedid};
 277                 }
 278                 else {
 279                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 280                                 if ($feeds) {
 281                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 282                                 }
 283                         }
 284                         else {
 285                                 $feednum=$knownfeeds{$feedid}="";
 286                                 if ($feeds) {
 287                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 288                                 }
 289                         }
 290                 }
 291         }
 292
 293         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 294         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 295
 296         my $ret="";
 297
 298         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 299             (exists $params{postform} && yesno($params{postform}))) &&
 300             IkiWiki->can("cgi_editpage")) {
 301                 # Add a blog post form, with feed buttons.
 302                 my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
 303                 $formtemplate->param(cgiurl => $config{cgiurl});
 304                 $formtemplate->param(rootpage => rootpage(%params));
 305                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 306                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 307                 if (exists $params{postformtext}) {
 308                         $formtemplate->param(postformtext =>
 309                                 $params{postformtext});
 310                 }
 311                 else {
 312                         $formtemplate->param(postformtext =>
 313                                 gettext("Add a new post titled:"));
 314                 }
 315                 $ret.=$formtemplate->output;
 316
 317                 # The post form includes the feed buttons, so
 318                 # emptyfeeds cannot be hidden.
 319                 $emptyfeeds=1;
 320         }
 321         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 322                 # Add feed buttons.
 323                 my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
 324                 $linktemplate->param(rssurl => $rssurl) if $rss;
 325                 $linktemplate->param(atomurl => $atomurl) if $atom;
 326                 $ret.=$linktemplate->output;
 327         }
 328
 329         if (! $feedonly) {
 330                 my $template;
 331                 if (! $raw) {
 332                         # cannot use wiki pages as templates; template not sanitized due to
 333                         # format hook hack
 334                         eval {
 335                                 $template=template_depends($params{template}.".tmpl", $params{page},
 336                                         blind_cache => 1);
 337                         };
 338                         if ($@) {
 339                                 error gettext("failed to process template:")." $@";
 340                         }
 341                         if (! $template) {
 342                                 error sprintf(gettext("template %s not found"), $params{template}.".tmpl");
 343                         }
 344                 }
 345                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 346
 347                 foreach my $page (@list) {
 348                         my $file = $pagesources{$page};
 349                         my $type = pagetype($file);
 350                         if (! $raw) {
 351                                 if ($needcontent) {
 352                                         # Get the content before populating the
 353                                         # template, since getting the content uses
 354                                         # the same template if inlines are nested.
 355                                         my $content=get_inline_content($page, $params{destpage});
 356                                         $template->param(content => $content);
 357                                 }
 358                                 $template->param(pageurl => urlto($page, $params{destpage}));
 359                                 $template->param(inlinepage => $page);
 360                                 $template->param(title => pagetitle(basename($page)));
 361                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}, 1));
 362                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 363                                 $template->param(first => 1) if $page eq $list[0];
 364                                 $template->param(last => 1) if $page eq $list[$#list];
 365
 366                                 if ($actions) {
 367                                         my $file = $pagesources{$page};
 368                                         my $type = pagetype($file);
 369                                         if ($config{discussion}) {
 370                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 371                                                     (length $config{cgiurl} ||
 372                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 373                                                         $template->param(have_actions => 1);
 374                                                         $template->param(discussionlink =>
 375                                                                 htmllink($page,
 376                                                                         $params{destpage},
 377                                                                         $config{discussionpage},
 378                                                                         noimageinline => 1,
 379                                                                         forcesubpage => 1));
 380                                                 }
 381                                         }
 382                                         if (length $config{cgiurl} &&
 383                                             defined $type &&
 384                                             IkiWiki->can("cgi_editpage")) {
 385                                                 $template->param(have_actions => 1);
 386                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 387
 388                                         }
 389                                 }
 390
 391                                 run_hooks(pagetemplate => sub {
 392                                         shift->(page => $page, destpage => $params{destpage},
 393                                                 template => $template,);
 394                                 });
 395
 396                                 $ret.=$template->output;
 397                                 $template->clear_params;
 398                         }
 399                         else {
 400                                 if (defined $type) {
 401                                         $ret.="\n".
 402                                               linkify($page, $params{destpage},
 403                                               preprocess($page, $params{destpage},
 404                                               filter($page, $params{destpage},
 405                                               readfile(srcfile($file)))));
 406                                 }
 407                                 else {
 408                                         $ret.="\n".
 409                                               readfile(srcfile($file));
 410                                 }
 411                         }
 412                 }
 413         }
 414
 415         if ($feeds && ($emptyfeeds || @feedlist)) {
 416                 if ($rss) {
 417                         my $rssp=$feedbase."rss".$feednum;
 418                         will_render($params{destpage}, $rssp);
 419                         if (! $params{preview}) {
 420                                 writefile($rssp, $config{destdir},
 421                                         genfeed("rss",
 422                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 423                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 424                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 425                         }
 426                 }
 427                 if ($atom) {
 428                         my $atomp=$feedbase."atom".$feednum;
 429                         will_render($params{destpage}, $atomp);
 430                         if (! $params{preview}) {
 431                                 writefile($atomp, $config{destdir},
 432                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 433                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 434                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 435                         }
 436                 }
 437         }
 438
 439         clear_inline_content_cache();
 440
 441         return $ret if $raw || $nested;
 442         push @inline, $ret;
 443         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 444 }
 445
 446 sub pagetemplate_inline (@) {
 447         my %params=@_;
 448         my $page=$params{page};
 449         my $template=$params{template};
 450
 451         $template->param(feedlinks => $feedlinks{$page})
 452                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 453 }
 454
 455 {
 456 my %inline_content;
 457 my $cached_destpage="";
 458
 459 sub get_inline_content ($$) {
 460         my $page=shift;
 461         my $destpage=shift;
 462
 463         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 464                 return $inline_content{$page};
 465         }
 466
 467         my $file=$pagesources{$page};
 468         my $type=pagetype($file);
 469         my $ret="";
 470         if (defined $type) {
 471                 $nested++;
 472                 $ret=htmlize($page, $destpage, $type,
 473                        linkify($page, $destpage,
 474                        preprocess($page, $destpage,
 475                        filter($page, $destpage,
 476                        readfile(srcfile($file))))));
 477                 $nested--;
 478         }
 479
 480         if ($cached_destpage ne $destpage) {
 481                 clear_inline_content_cache();
 482                 $cached_destpage=$destpage;
 483         }
 484         return $inline_content{$page}=$ret;
 485 }
 486
 487 sub clear_inline_content_cache () {
 488         %inline_content=();
 489 }
 490
 491 }
 492
 493 sub date_822 ($) {
 494         my $time=shift;
 495
 496         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 497         POSIX::setlocale(&POSIX::LC_TIME, "C");
 498         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 499         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 500         return $ret;
 501 }
 502
 503 sub absolute_urls ($$) {
 504         # sucky sub because rss sucks
 505         my $content=shift;
 506         my $baseurl=shift;
 507
 508         my $url=$baseurl;
 509         $url=~s/[^\/]+$//;
 510
 511         # what is the non path part of the url?
 512         my $top_uri = URI->new($url);
 513         $top_uri->path_query(""); # reset the path
 514         my $urltop = $top_uri->as_string;
 515
 516         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 517         # relative to another wiki page
 518         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 519         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 520         # relative to the top of the site
 521         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 522         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 523         return $content;
 524 }
 525
 526 sub genfeed ($$$$$@) {
 527         my $feedtype=shift;
 528         my $feedurl=shift;
 529         my $feeddesc=shift;
 530         my $guid=shift;
 531         my $page=shift;
 532         my @pages=@_;
 533
 534         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 535
 536         my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
 537         my $content="";
 538         my $lasttime = 0;
 539         foreach my $p (@pages) {
 540                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 541                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 542
 543                 $itemtemplate->param(
 544                         title => pagetitle(basename($p)),
 545                         url => $u,
 546                         permalink => $u,
 547                         cdate_822 => date_822($pagectime{$p}),
 548                         mdate_822 => date_822($pagemtime{$p}),
 549                         cdate_3339 => date_3339($pagectime{$p}),
 550                         mdate_3339 => date_3339($pagemtime{$p}),
 551                 );
 552
 553                 if (exists $pagestate{$p}) {
 554                         if (exists $pagestate{$p}{meta}{guid}) {
 555                                 eval q{use HTML::Entities};
 556                                 $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
 557                         }
 558
 559                         if (exists $pagestate{$p}{meta}{updated}) {
 560                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 561                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 562                         }
 563                 }
 564
 565                 if ($itemtemplate->query(name => "enclosure")) {
 566                         my $file=$pagesources{$p};
 567                         my $type=pagetype($file);
 568                         if (defined $type) {
 569                                 $itemtemplate->param(content => $pcontent);
 570                         }
 571                         else {
 572                                 my $size=(srcfile_stat($file))[8];
 573                                 my $mime="unknown";
 574                                 eval q{use File::MimeInfo};
 575                                 if (! $@) {
 576                                         $mime = mimetype($file);
 577                                 }
 578                                 $itemtemplate->param(
 579                                         enclosure => $u,
 580                                         type => $mime,
 581                                         length => $size,
 582                                 );
 583                         }
 584                 }
 585                 else {
 586                         $itemtemplate->param(content => $pcontent);
 587                 }
 588
 589                 run_hooks(pagetemplate => sub {
 590                         shift->(page => $p, destpage => $page,
 591                                 template => $itemtemplate);
 592                 });
 593
 594                 $content.=$itemtemplate->output;
 595                 $itemtemplate->clear_params;
 596
 597                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 598         }
 599
 600         my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
 601         $template->param(
 602                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 603                 wikiname => $config{wikiname},
 604                 pageurl => $url,
 605                 content => $content,
 606                 feeddesc => $feeddesc,
 607                 guid => $guid,
 608                 feeddate => date_3339($lasttime),
 609                 feedurl => $feedurl,
 610                 version => $IkiWiki::version,
 611         );
 612         run_hooks(pagetemplate => sub {
 613                 shift->(page => $page, destpage => $page,
 614                         template => $template);
 615         });
 616
 617         return $template->output;
 618 }
 619
 620 sub pingurl (@) {
 621         return unless @{$config{pingurl}} && %toping;
 622
 623         eval q{require RPC::XML::Client};
 624         if ($@) {
 625                 debug(gettext("RPC::XML::Client not found, not pinging"));
 626                 return;
 627         }
 628
 629         # daemonize here so slow pings don't slow down wiki updates
 630         defined(my $pid = fork) or error("Can't fork: $!");
 631         return if $pid;
 632         chdir '/';
 633         POSIX::setsid() or error("Can't start a new session: $!");
 634         open STDIN, '/dev/null';
 635         open STDOUT, '>/dev/null';
 636         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 637
 638         # Don't need to keep a lock on the wiki as a daemon.
 639         IkiWiki::unlockwiki();
 640
 641         foreach my $page (keys %toping) {
 642                 my $title=pagetitle(basename($page), 0);
 643                 my $url=urlto($page, "", 1);
 644                 foreach my $pingurl (@{$config{pingurl}}) {
 645                         debug("Pinging $pingurl for $page");
 646                         eval {
 647                                 my $client = RPC::XML::Client->new($pingurl);
 648                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 649                                         $title, $url);
 650                                 my $res = $client->send_request($req);
 651                                 if (! ref $res) {
 652                                         error("Did not receive response to ping");
 653                                 }
 654                                 my $r=$res->value;
 655                                 if (! exists $r->{flerror} || $r->{flerror}) {
 656                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 657                                 }
 658                         };
 659                         if ($@) {
 660                                 error "Ping failed: $@";
 661                         }
 662                 }
 663         }
 664
 665         exit 0; # daemon done
 666 }
 667
 668
 669 sub rootpage (@) {
 670         my %params=@_;
 671
 672         my $rootpage;
 673         if (exists $params{rootpage}) {
 674                 $rootpage=bestlink($params{page}, $params{rootpage});
 675                 if (!length $rootpage) {
 676                         $rootpage=$params{rootpage};
 677                 }
 678         }
 679         else {
 680                 $rootpage=$params{page};
 681         }
 682         return $rootpage;
 683 }
 684
 685 1