git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         run_hooks(postscan => sub {
  66                 shift->(page => $page, content => $content);
  67         });
  68
  69         my $templatefile;
  70         run_hooks(templatefile => sub {
  71                 return if defined $templatefile;
  72                 my $file=shift->(page => $page);
  73                 if (defined $file && defined template_file($file)) {
  74                         $templatefile=$file;
  75                 }
  76         });
  77         my $template=template(defined $templatefile ? $templatefile : 'page.tmpl', blind_cache => 1);
  78         my $actions=0;
  79
  80         if (length $config{cgiurl}) {
  81                 if (IkiWiki->can("cgi_editpage")) {
  82                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  83                         $actions++;
  84                 }
  85                 if (exists $hooks{auth}) {
  86                         $template->param(prefsurl => cgiurl(do => "prefs"));
  87                         $actions++;
  88                 }
  89         }
  90
  91         if (defined $config{historyurl} && length $config{historyurl}) {
  92                 my $u=$config{historyurl};
  93                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  94                 $template->param(historyurl => $u);
  95                 $actions++;
  96         }
  97         if ($config{discussion}) {
  98                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
  99                    (length $config{cgiurl} ||
 100                     exists $links{$page."/".$config{discussionpage}})) {
 101                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 102                         $actions++;
 103                 }
 104         }
 105
 106         if ($actions) {
 107                 $template->param(have_actions => 1);
 108         }
 109
 110         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 111         my ($backlinks, $more_backlinks);
 112         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 113                 $backlinks=\@backlinks;
 114                 $more_backlinks=[];
 115         }
 116         else {
 117                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 118                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 119         }
 120
 121         $template->param(
 122                 title => $page eq 'index'
 123                         ? $config{wikiname}
 124                         : pagetitle(basename($page)),
 125                 wikiname => $config{wikiname},
 126                 content => $content,
 127                 backlinks => $backlinks,
 128                 more_backlinks => $more_backlinks,
 129                 mtime => displaytime($pagemtime{$page}),
 130                 ctime => displaytime($pagectime{$page}),
 131                 baseurl => baseurl($page),
 132         );
 133
 134         run_hooks(pagetemplate => sub {
 135                 shift->(page => $page, destpage => $page, template => $template);
 136         });
 137
 138         $content=$template->output;
 139
 140         run_hooks(format => sub {
 141                 $content=shift->(
 142                         page => $page,
 143                         content => $content,
 144                 );
 145         });
 146
 147         return $content;
 148 }
 149
 150 sub scan ($) {
 151         my $file=shift;
 152
 153         debug(sprintf(gettext("scanning %s"), $file));
 154
 155         my $type=pagetype($file);
 156         if (defined $type) {
 157                 my $srcfile=srcfile($file);
 158                 my $content=readfile($srcfile);
 159                 my $page=pagename($file);
 160                 will_render($page, htmlpage($page), 1);
 161
 162                 if ($config{discussion}) {
 163                         # Discussion links are a special case since they're
 164                         # not in the text of the page, but on its template.
 165                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 166                 }
 167                 else {
 168                         $links{$page}=[];
 169                 }
 170                 delete $typedlinks{$page};
 171
 172                 run_hooks(scan => sub {
 173                         shift->(
 174                                 page => $page,
 175                                 content => $content,
 176                         );
 177                 });
 178
 179                 # Preprocess in scan-only mode.
 180                 preprocess($page, $page, $content, 1);
 181         }
 182         else {
 183                 will_render($file, $file, 1);
 184         }
 185 }
 186
 187 sub fast_file_copy (@) {
 188         my $srcfile=shift;
 189         my $destfile=shift;
 190         my $srcfd=shift;
 191         my $destfd=shift;
 192         my $cleanup=shift;
 193
 194         my $blksize = 16384;
 195         my ($len, $buf, $written);
 196         while ($len = sysread $srcfd, $buf, $blksize) {
 197                 if (! defined $len) {
 198                         next if $! =~ /^Interrupted/;
 199                         error("failed to read $srcfile: $!", $cleanup);
 200                 }
 201                 my $offset = 0;
 202                 while ($len) {
 203                         defined($written = syswrite $destfd, $buf, $len, $offset)
 204                                 or error("failed to write $destfile: $!", $cleanup);
 205                         $len -= $written;
 206                         $offset += $written;
 207                 }
 208         }
 209 }
 210
 211 sub render ($$) {
 212         my $file=shift;
 213         return if $rendered{$file};
 214         debug(shift);
 215         $rendered{$file}=1;
 216
 217         my $type=pagetype($file);
 218         my $srcfile=srcfile($file);
 219         if (defined $type) {
 220                 my $page=pagename($file);
 221                 delete $depends{$page};
 222                 delete $depends_simple{$page};
 223                 will_render($page, htmlpage($page), 1);
 224                 return if $type=~/^_/;
 225
 226                 my $content=htmlize($page, $page, $type,
 227                         linkify($page, $page,
 228                         preprocess($page, $page,
 229                         filter($page, $page,
 230                         readfile($srcfile)))));
 231
 232                 my $output=htmlpage($page);
 233                 writefile($output, $config{destdir}, genpage($page, $content));
 234         }
 235         else {
 236                 delete $depends{$file};
 237                 delete $depends_simple{$file};
 238                 will_render($file, $file, 1);
 239
 240                 if ($config{hardlink}) {
 241                         # only hardlink if owned by same user
 242                         my @stat=stat($srcfile);
 243                         if ($stat[4] == $>) {
 244                                 prep_writefile($file, $config{destdir});
 245                                 unlink($config{destdir}."/".$file);
 246                                 if (link($srcfile, $config{destdir}."/".$file)) {
 247                                         return;
 248                                 }
 249                         }
 250                         # if hardlink fails, fall back to copying
 251                 }
 252
 253                 my $srcfd=readfile($srcfile, 1, 1);
 254                 writefile($file, $config{destdir}, undef, 1, sub {
 255                         fast_file_copy($srcfile, $file, $srcfd, @_);
 256                 });
 257         }
 258 }
 259
 260 sub prune ($) {
 261         my $file=shift;
 262
 263         unlink($file);
 264         my $dir=dirname($file);
 265         while (rmdir($dir)) {
 266                 $dir=dirname($dir);
 267         }
 268 }
 269
 270 sub srcdir_check () {
 271         # security check, avoid following symlinks in the srcdir path by default
 272         my $test=$config{srcdir};
 273         while (length $test) {
 274                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 275                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 276                 }
 277                 unless ($test=~s/\/+$//) {
 278                         $test=dirname($test);
 279                 }
 280         }
 281
 282 }
 283
 284 sub find_src_files () {
 285         my @files;
 286         my %pages;
 287         eval q{use File::Find};
 288         error($@) if $@;
 289         find({
 290                 no_chdir => 1,
 291                 wanted => sub {
 292                         my $file=decode_utf8($_);
 293                         $file=~s/^\Q$config{srcdir}\E\/?//;
 294                         return if -l $_ || -d _ || ! length $file;
 295                         my $page = pagename($file);
 296                         if (! exists $pagesources{$page} &&
 297                             file_pruned($file)) {
 298                                 $File::Find::prune=1;
 299                                 return;
 300                         }
 301
 302                         my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 303                         if (! defined $f) {
 304                                 warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 305                         }
 306                         else {
 307                                 push @files, $f;
 308                                 if ($pages{$page}) {
 309                                         debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 310                                 }
 311                                 $pages{$page}=1;
 312                         }
 313                 },
 314         }, $config{srcdir});
 315         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 316                 find({
 317                         no_chdir => 1,
 318                         wanted => sub {
 319                                 my $file=decode_utf8($_);
 320                                 $file=~s/^\Q$dir\E\/?//;
 321                                 return if -l $_ || -d _ || ! length $file;
 322                                 my $page=pagename($file);
 323                                 if (! exists $pagesources{$page} &&
 324                                     file_pruned($file)) {
 325                                         $File::Find::prune=1;
 326                                         return;
 327                                 }
 328
 329                                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 330                                 if (! defined $f) {
 331                                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 332                                 }
 333                                 else {
 334                                         # avoid underlaydir override
 335                                         # attacks; see security.mdwn
 336                                         if (! -l "$config{srcdir}/$f" &&
 337                                             ! -e _) {
 338                                                 if (! $pages{$page}) {
 339                                                         push @files, $f;
 340                                                         $pages{$page}=1;
 341                                                 }
 342                                         }
 343                                 }
 344                         },
 345                 }, $dir);
 346         };
 347         return \@files, \%pages;
 348 }
 349
 350 sub find_new_files ($) {
 351         my $files=shift;
 352         my @new;
 353         my @internal_new;
 354
 355         foreach my $file (@$files) {
 356                 my $page=pagename($file);
 357                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 358                         # the page has changed its type
 359                         $forcerebuild{$page}=1;
 360                 }
 361                 $pagesources{$page}=$file;
 362                 if (! $pagemtime{$page}) {
 363                         if (isinternal($page)) {
 364                                 push @internal_new, $file;
 365                         }
 366                         else {
 367                                 push @new, $file;
 368                                 if ($config{gettime} && -e "$config{srcdir}/$file") {
 369                                         eval {
 370                                                 my $ctime=rcs_getctime("$config{srcdir}/$file");
 371                                                 if ($ctime > 0) {
 372                                                         $pagectime{$page}=$ctime;
 373                                                 }
 374                                         };
 375                                         if ($@) {
 376                                                 print STDERR $@;
 377                                         }
 378                                         my $mtime;
 379                                         eval {
 380                                                 my $mtime=rcs_getmtime("$config{srcdir}/$file");
 381                                         };
 382                                         if ($@) {
 383                                                 print STDERR $@;
 384                                         }
 385                                         elsif ($mtime > 0) {
 386                                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 387                                         }
 388                                 }
 389                         }
 390                         $pagecase{lc $page}=$page;
 391                         if (! exists $pagectime{$page}) {
 392                                 $pagectime{$page}=(srcfile_stat($file))[10];
 393                         }
 394                 }
 395         }
 396
 397         return \@new, \@internal_new;
 398 }
 399
 400 sub find_del_files ($) {
 401         my $pages=shift;
 402         my @del;
 403         my @internal_del;
 404
 405         foreach my $page (keys %pagemtime) {
 406                 if (! $pages->{$page}) {
 407                         if (isinternal($page)) {
 408                                 push @internal_del, $pagesources{$page};
 409                         }
 410                         else {
 411                                 push @del, $pagesources{$page};
 412                         }
 413                         $links{$page}=[];
 414                         delete $typedlinks{$page};
 415                         $renderedfiles{$page}=[];
 416                         $pagemtime{$page}=0;
 417                 }
 418         }
 419
 420         return \@del, \@internal_del;
 421 }
 422
 423 sub remove_del (@) {
 424         foreach my $file (@_) {
 425                 my $page=pagename($file);
 426                 if (! isinternal($page)) {
 427                         debug(sprintf(gettext("removing old page %s"), $page));
 428                 }
 429
 430                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 431                         prune($config{destdir}."/".$old);
 432                 }
 433
 434                 foreach my $source (keys %destsources) {
 435                         if ($destsources{$source} eq $page) {
 436                                 delete $destsources{$source};
 437                         }
 438                 }
 439
 440                 delete $pagecase{lc $page};
 441                 delete $pagesources{$page};
 442         }
 443 }
 444
 445 sub find_changed ($) {
 446         my $files=shift;
 447         my @changed;
 448         my @internal_changed;
 449         foreach my $file (@$files) {
 450                 my $page=pagename($file);
 451                 my ($srcfile, @stat)=srcfile_stat($file);
 452                 if (! exists $pagemtime{$page} ||
 453                     $stat[9] > $pagemtime{$page} ||
 454                     $forcerebuild{$page}) {
 455                         $pagemtime{$page}=$stat[9];
 456
 457                         if (isinternal($page)) {
 458                                 # Preprocess internal page in scan-only mode.
 459                                 preprocess($page, $page, readfile($srcfile), 1);
 460                                 push @internal_changed, $file;
 461                         }
 462                         else {
 463                                 push @changed, $file;
 464                         }
 465                 }
 466         }
 467         return \@changed, \@internal_changed;
 468 }
 469
 470 sub calculate_old_links ($$) {
 471         my ($changed, $del)=@_;
 472         my %oldlink_targets;
 473         foreach my $file (@$changed, @$del) {
 474                 my $page=pagename($file);
 475                 if (exists $oldlinks{$page}) {
 476                         foreach my $l (@{$oldlinks{$page}}) {
 477                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 478                         }
 479                 }
 480         }
 481         return \%oldlink_targets;
 482 }
 483
 484 sub derender_internal ($) {
 485         my $file=shift;
 486         my $page=pagename($file);
 487         delete $depends{$page};
 488         delete $depends_simple{$page};
 489         foreach my $old (@{$renderedfiles{$page}}) {
 490                 delete $destsources{$old};
 491         }
 492         $renderedfiles{$page}=[];
 493 }
 494
 495 sub render_linkers ($) {
 496         my $f=shift;
 497         my $p=pagename($f);
 498         foreach my $page (keys %{$backlinks{$p}}) {
 499                 my $file=$pagesources{$page};
 500                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 501         }
 502 }
 503
 504 sub remove_unrendered () {
 505         foreach my $src (keys %rendered) {
 506                 my $page=pagename($src);
 507                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 508                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 509                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 510                                 prune($config{destdir}."/".$file);
 511                         }
 512                 }
 513         }
 514 }
 515
 516 sub link_types_changed ($$) {
 517         # each is of the form { type => { link => 1 } }
 518         my $new = shift;
 519         my $old = shift;
 520
 521         return 0 if !defined $new && !defined $old;
 522         return 1 if !defined $new || !defined $old;
 523
 524         while (my ($type, $links) = each %$new) {
 525                 foreach my $link (keys %$links) {
 526                         return 1 unless exists $old->{$type}{$link};
 527                 }
 528         }
 529
 530         while (my ($type, $links) = each %$old) {
 531                 foreach my $link (keys %$links) {
 532                         return 1 unless exists $new->{$type}{$link};
 533                 }
 534         }
 535
 536         return 0;
 537 }
 538
 539 sub calculate_changed_links ($$$) {
 540         my ($changed, $del, $oldlink_targets)=@_;
 541
 542         my (%backlinkchanged, %linkchangers);
 543
 544         foreach my $file (@$changed, @$del) {
 545                 my $page=pagename($file);
 546
 547                 if (exists $links{$page}) {
 548                         foreach my $l (@{$links{$page}}) {
 549                                 my $target=bestlink($page, $l);
 550                                 if (! exists $oldlink_targets->{$page}{$l} ||
 551                                     $target ne $oldlink_targets->{$page}{$l}) {
 552                                         $backlinkchanged{$target}=1;
 553                                         $linkchangers{lc($page)}=1;
 554                                 }
 555                                 delete $oldlink_targets->{$page}{$l};
 556                         }
 557                 }
 558                 if (exists $oldlink_targets->{$page} &&
 559                     %{$oldlink_targets->{$page}}) {
 560                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 561                                 $backlinkchanged{$target}=1;
 562                         }
 563                         $linkchangers{lc($page)}=1;
 564                 }
 565
 566                 # we currently assume that changing the type of a link doesn't
 567                 # change backlinks
 568                 if (!exists $linkchangers{lc($page)}) {
 569                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 570                                 $linkchangers{lc($page)}=1;
 571                         }
 572                 }
 573         }
 574
 575         return \%backlinkchanged, \%linkchangers;
 576 }
 577
 578 sub render_dependent ($$$$$$$) {
 579         my ($files, $new, $internal_new, $del, $internal_del,
 580                 $internal_changed, $linkchangers)=@_;
 581
 582         my @changed=(keys %rendered, @$del);
 583         my @exists_changed=(@$new, @$del);
 584
 585         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 586         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 587
 588         foreach my $f (@$files) {
 589                 next if $rendered{$f};
 590                 my $p=pagename($f);
 591                 my $reason = undef;
 592
 593                 if (exists $depends_simple{$p}) {
 594                         foreach my $d (keys %{$depends_simple{$p}}) {
 595                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 596                                      $lc_changed{$d})
 597                                     ||
 598                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 599                                      $lc_exists_changed{$d})
 600                                     ||
 601                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 602                                      $linkchangers->{$d})
 603                                 ) {
 604                                         $reason = $d;
 605                                         last;
 606                                 }
 607                         }
 608                 }
 609
 610                 if (exists $depends{$p} && ! defined $reason) {
 611                         foreach my $dep (keys %{$depends{$p}}) {
 612                                 my $sub=pagespec_translate($dep);
 613                                 next unless defined $sub;
 614
 615                                 # only consider internal files
 616                                 # if the page explicitly depends
 617                                 # on such files
 618                                 my $internal_dep=$dep =~ /internal\(/;
 619
 620                                 my $in=sub {
 621                                         my $list=shift;
 622                                         my $type=shift;
 623                                         foreach my $file (@$list) {
 624                                                 next if $file eq $f;
 625                                                 my $page=pagename($file);
 626                                                 if ($sub->($page, location => $p)) {
 627                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 628                                                                 next unless $linkchangers->{lc($page)};
 629                                                         }
 630                                                         return $page;
 631                                                 }
 632                                         }
 633                                         return undef;
 634                                 };
 635
 636                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 637                                         last if $reason =
 638                                                 $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 639                                         last if $internal_dep && ($reason =
 640                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 641                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 642                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT));
 643                                 }
 644                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 645                                         last if $reason =
 646                                                 $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 647                                         last if $internal_dep && ($reason =
 648                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 649                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE));
 650                                 }
 651                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 652                                         last if $reason =
 653                                                 $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 654                                         last if $internal_dep && ($reason =
 655                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 656                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 657                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS));
 658                                 }
 659                         }
 660                 }
 661
 662                 if (defined $reason) {
 663                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 664                         return 1;
 665                 }
 666         }
 667
 668         return 0;
 669 }
 670
 671 sub render_backlinks ($) {
 672         my $backlinkchanged=shift;
 673         foreach my $link (keys %$backlinkchanged) {
 674                 my $linkfile=$pagesources{$link};
 675                 if (defined $linkfile) {
 676                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 677                 }
 678         }
 679 }
 680
 681 sub refresh () {
 682         srcdir_check();
 683         run_hooks(refresh => sub { shift->() });
 684         my ($files, $pages)=find_src_files();
 685         my ($new, $internal_new)=find_new_files($files);
 686         my ($del, $internal_del)=find_del_files($pages);
 687         my ($changed, $internal_changed)=find_changed($files);
 688         run_hooks(needsbuild => sub { shift->($changed) });
 689         my $oldlink_targets=calculate_old_links($changed, $del);
 690
 691         foreach my $file (@$changed) {
 692                 scan($file);
 693         }
 694
 695         calculate_links();
 696
 697         remove_del(@$del, @$internal_del);
 698
 699         foreach my $file (@$changed) {
 700                 render($file, sprintf(gettext("building %s"), $file));
 701         }
 702         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 703                 derender_internal($file);
 704         }
 705
 706         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 707                 $del, $oldlink_targets);
 708
 709         foreach my $file (@$new, @$del) {
 710                 render_linkers($file);
 711         }
 712
 713         if (@$changed || @$internal_changed ||
 714             @$del || @$internal_del || @$internal_new) {
 715                 1 while render_dependent($files, $new, $internal_new,
 716                         $del, $internal_del, $internal_changed,
 717                         $linkchangers);
 718         }
 719
 720         render_backlinks($backlinkchanged);
 721         remove_unrendered();
 722
 723         if (@$del) {
 724                 run_hooks(delete => sub { shift->(@$del) });
 725         }
 726         if (%rendered) {
 727                 run_hooks(change => sub { shift->(keys %rendered) });
 728         }
 729 }
 730
 731 sub clean_rendered {
 732         lockwiki();
 733         loadindex();
 734         remove_unrendered();
 735         foreach my $page (keys %oldrenderedfiles) {
 736                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 737                         prune($config{destdir}."/".$file);
 738                 }
 739         }
 740 }
 741
 742 sub commandline_render () {
 743         lockwiki();
 744         loadindex();
 745         unlockwiki();
 746
 747         my $srcfile=possibly_foolish_untaint($config{render});
 748         my $file=$srcfile;
 749         $file=~s/\Q$config{srcdir}\E\/?//;
 750
 751         my $type=pagetype($file);
 752         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 753         my $content=readfile($srcfile);
 754         my $page=pagename($file);
 755         $pagesources{$page}=$file;
 756         $content=filter($page, $page, $content);
 757         $content=preprocess($page, $page, $content);
 758         $content=linkify($page, $page, $content);
 759         $content=htmlize($page, $page, $type, $content);
 760         $pagemtime{$page}=(stat($srcfile))[9];
 761         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 762
 763         print genpage($page, $content);
 764         exit 0;
 765 }
 766
 767 1