git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Setup.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki setup files can be perl files that 'use IkiWiki::Setup::foo',
   3 # passing it some sort of configuration data. Or, they can contain
   4 # the module name at the top, without the 'use', and the whole file is
   5 # then fed into that module.
   6
   7 package IkiWiki::Setup;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki;
  12 use open qw{:utf8 :std};
  13 use File::Spec;
  14
  15 sub load ($;$) {
  16         my $file=IkiWiki::possibly_foolish_untaint(shift);
  17         my $safemode=shift;
  18
  19         $config{setupfile}=File::Spec->rel2abs($file);
  20
  21         #translators: The first parameter is a filename, and the second
  22         #translators: is a (probably not translated) error message.
  23         open (IN, $file) || error(sprintf(gettext("cannot read %s: %s"), $file, $!));
  24         my $content;
  25         {
  26                 local $/=undef;
  27                 $content=<IN> || error("$file: $!");
  28         }
  29         close IN;
  30
  31         if ($content=~/((?:use|require)\s+)?IkiWiki::Setup::(\w+)/) {
  32                 $config{setuptype}=$2;
  33                 if ($1) {
  34                         error sprintf(gettext("cannot load %s in safe mode"), $file)
  35                                 if $safemode;
  36                         no warnings;
  37                         eval IkiWiki::possibly_foolish_untaint($content);
  38                         error("$file: ".$@) if $@;
  39                 }
  40                 else {
  41                         eval qq{require IkiWiki::Setup::$config{setuptype}};
  42                         error $@ if $@;
  43                         "IkiWiki::Setup::$config{setuptype}"->loaddump(IkiWiki::possibly_foolish_untaint($content));
  44                 }
  45         }
  46         else {
  47                 error sprintf(gettext("failed to parse %s"), $file);
  48         }
  49 }
  50
  51 sub dump ($) {
  52         my $file=IkiWiki::possibly_foolish_untaint(shift);
  53
  54         my @header=(
  55                 "Setup file for ikiwiki.",
  56                 "",
  57                 "Passing this to ikiwiki --setup will make ikiwiki generate",
  58                 "wrappers and build the wiki.",
  59                 "",
  60                 "Remember to re-run ikiwiki --setup any time you edit this file.",
  61         );
  62
  63         # Fork because dumping setup requires loading all plugins.
  64         my $pid=fork();
  65         if ($pid == 0) {
  66                 eval qq{require IkiWiki::Setup::$config{setuptype}};
  67                 error $@ if $@;
  68                 my @dump="IkiWiki::Setup::$config{setuptype}"->gendump(@header);
  69
  70                 open (OUT, ">", $file) || die "$file: $!";
  71                 print OUT "$_\n" foreach @dump;
  72                 close OUT;
  73
  74                 exit 0;
  75         }
  76         else {
  77                 waitpid $pid, 0;
  78                 exit($? >> 8) if $? >> 8;
  79                 exit(1) if $?;
  80         }
  81 }
  82
  83 sub merge ($) {
  84         # Merge setup into existing config and untaint.
  85         my %setup=%{shift()};
  86
  87         if (exists $setup{add_plugins} && exists $config{add_plugins}) {
  88                 push @{$setup{add_plugins}}, @{$config{add_plugins}};
  89         }
  90         if (exists $setup{exclude}) {
  91                 push @{$config{wiki_file_prune_regexps}}, $setup{exclude};
  92         }
  93         foreach my $c (keys %setup) {
  94                 if (defined $setup{$c}) {
  95                         if (! ref $setup{$c} || ref $setup{$c} eq 'Regexp') {
  96                                 $config{$c}=IkiWiki::possibly_foolish_untaint($setup{$c});
  97                         }
  98                         elsif (ref $setup{$c} eq 'ARRAY') {
  99                                 if ($c eq 'wrappers') {
 100                                         # backwards compatability code
 101                                         $config{$c}=$setup{$c};
 102                                 }
 103                                 else {
 104                                         $config{$c}=[map { IkiWiki::possibly_foolish_untaint($_) } @{$setup{$c}}]
 105                                 }
 106                         }
 107                         elsif (ref $setup{$c} eq 'HASH') {
 108                                 foreach my $key (keys %{$setup{$c}}) {
 109                                         $config{$c}{$key}=IkiWiki::possibly_foolish_untaint($setup{$c}{$key});
 110                                 }
 111                         }
 112                 }
 113                 else {
 114                         $config{$c}=undef;
 115                 }
 116         }
 117
 118         if (length $config{cgi_wrapper}) {
 119                 push @{$config{wrappers}}, {
 120                         cgi => 1,
 121                         wrapper => $config{cgi_wrapper},
 122                         wrappermode => (defined $config{cgi_wrappermode} ? $config{cgi_wrappermode} : "06755"),
 123                 };
 124         }
 125 }
 126
 127 sub disabled_plugins (@) {
 128         # Handles running disable hooks of plugins that were enabled
 129         # previously, but got disabled when a new setup file was loaded.
 130         if (exists $config{setupfile} && @_) {
 131                 # Fork a child to load the disabled plugins.
 132                 my $pid=fork();
 133                 if ($pid == 0) {
 134                         foreach my $plugin (@_) {
 135                                 print STDERR "** plugin $plugin disabled\n";
 136                                 eval { IkiWiki::loadplugin($plugin, 1) };
 137                                 if (exists $IkiWiki::hooks{disable}{$plugin}{call}) {
 138                                         eval { $IkiWiki::hooks{disable}{$plugin}{call}->() };
 139                                 }
 140                         }
 141                         exit(0);
 142                 }
 143                 else {
 144                         waitpid $pid, 0;
 145                 }
 146         }
 147 }
 148
 149 sub getsetup () {
 150         # Gets all available setup data from all plugins. Returns an
 151         # ordered list of [plugin, setup] pairs.
 152
 153         # disable logging to syslog while dumping, broken plugins may
 154         # whine when loaded
 155         my $syslog=$config{syslog};
 156         $config{syslog}=undef;
 157
 158         # Load all plugins, so that all setup options are available.
 159         my %original_loaded_plugins=%IkiWiki::loaded_plugins;
 160         my @plugins=IkiWiki::listplugins();
 161         foreach my $plugin (@plugins) {
 162                 eval { IkiWiki::loadplugin($plugin, 1) };
 163                 if (exists $IkiWiki::hooks{checkconfig}{$plugin}{call}) {
 164                         my @s=eval { $IkiWiki::hooks{checkconfig}{$plugin}{call}->() };
 165                 }
 166         }
 167         %IkiWiki::loaded_plugins=%original_loaded_plugins;
 168
 169         my %sections;
 170         foreach my $plugin (@plugins) {
 171                 if (exists $IkiWiki::hooks{getsetup}{$plugin}{call}) {
 172                         # use an array rather than a hash, to preserve order
 173                         my @s=eval { $IkiWiki::hooks{getsetup}{$plugin}{call}->() };
 174                         next unless @s;
 175
 176                         # set default section value (note use of shared
 177                         # hashref between array and hash)
 178                         my %s=@s;
 179                         if (! exists $s{plugin} || ! $s{plugin}->{section}) {
 180                                 $s{plugin}->{section}="other";
 181                         }
 182
 183                         # only the selected rcs plugin is included
 184                         if ($config{rcs} && $plugin eq $config{rcs}) {
 185                                 $s{plugin}->{section}="core";
 186                         }
 187                         elsif ($s{plugin}->{section} eq "rcs") {
 188                                 next;
 189                         }
 190
 191                         push @{$sections{$s{plugin}->{section}}}, [ $plugin, \@s ];
 192                 }
 193         }
 194
 195         $config{syslog}=$syslog;
 196
 197         return map { sort { $a->[0] cmp $b->[0] } @{$sections{$_}} }
 198                 sort { # core first, other last, otherwise alphabetical
 199                         ($b eq "core") <=> ($a eq "core")
 200                            ||
 201                         ($a eq "other") <=> ($b eq "other")
 202                            ||
 203                         $a cmp $b
 204                 } keys %sections;
 205 }
 206
 207 sub commented_dump ($$) {
 208         my $dumpline=shift;
 209         my $indent=shift;
 210
 211         my %setup=(%config);
 212         my @ret;
 213
 214         # disable logging to syslog while dumping
 215         $config{syslog}=undef;
 216
 217         eval q{use Text::Wrap};
 218         die $@ if $@;
 219
 220         my %section_plugins;
 221         push @ret, commented_dumpvalues($dumpline, $indent, \%setup, IkiWiki::getsetup());
 222         foreach my $pair (IkiWiki::Setup::getsetup()) {
 223                 my $plugin=$pair->[0];
 224                 my $setup=$pair->[1];
 225                 my %s=@{$setup};
 226                 my $section=$s{plugin}->{section};
 227                 push @{$section_plugins{$section}}, $plugin;
 228                 if (@{$section_plugins{$section}} == 1) {
 229                         push @ret, "", $indent.("#" x 70), "$indent# $section plugins",
 230                                 sub {
 231                                         wrap("$indent#   (", "$indent#    ",
 232                                                 join(", ", @{$section_plugins{$section}})).")"
 233                                 },
 234                                 $indent.("#" x 70);
 235                 }
 236
 237                 my @values=commented_dumpvalues($dumpline, $indent, \%setup, @{$setup});
 238                 if (@values) {
 239                         push @ret, "", "$indent# $plugin plugin", @values;
 240                 }
 241         }
 242
 243         return map { ref $_ ? $_->() : $_ } @ret;
 244 }
 245
 246 sub commented_dumpvalues ($$$@) {
 247         my $dumpline=shift;
 248         my $indent=shift;
 249         my $setup=shift;
 250         my @ret;
 251         while (@_) {
 252                 my $key=shift;
 253                 my %info=%{shift()};
 254
 255                 next if $key eq "plugin" || $info{type} eq "internal";
 256
 257                 push @ret, "$indent# ".$info{description} if exists $info{description};
 258
 259                 if (exists $setup->{$key} && defined $setup->{$key}) {
 260                         push @ret, $dumpline->($key, $setup->{$key}, $info{type}, "");
 261                         delete $setup->{$key};
 262                 }
 263                 elsif (exists $info{example}) {
 264                         push @ret, $dumpline->($key, $info{example}, $info{type}, "#");
 265                 }
 266                 else {
 267                         push @ret, $dumpline->($key, "", $info{type}, "#");
 268                 }
 269         }
 270         return @ret;
 271 }
 272
 273 1