git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import { #{{{
   9         hook(type => "getsetup", id => "rename", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  13
  14 } # }}}
  15
  16 sub getsetup () { #{{{
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 } #}}}
  23
  24 sub check_canrename ($$$$$$$) { #{{{
  25         my $src=shift;
  26         my $srcfile=shift;
  27         my $dest=shift;
  28         my $destfile=shift;
  29         my $q=shift;
  30         my $session=shift;
  31         my $attachment=shift;
  32
  33         # Must be a known source file.
  34         if (! exists $pagesources{$src}) {
  35                 error(sprintf(gettext("%s does not exist"),
  36                         htmllink("", "", $src, noimageinline => 1)));
  37         }
  38
  39         # Must exist on disk, and be a regular file.
  40         if (! -e "$config{srcdir}/$srcfile") {
  41                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  42         }
  43         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  44                 error(sprintf(gettext("%s is not a file"), $srcfile));
  45         }
  46
  47         # Must be editable.
  48         IkiWiki::check_canedit($src, $q, $session);
  49         if ($attachment) {
  50                 IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  51         }
  52
  53         # Dest checks can be omitted by passing undef.
  54         if (defined $dest) {
  55                 if ($srcfile eq $destfile) {
  56                         error(gettext("no change to the file name was specified"));
  57                 }
  58
  59                 # Must be a legal filename, and not absolute.
  60                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  61                     $destfile=~/^\//) {
  62                         error(sprintf(gettext("illegal name")));
  63                 }
  64
  65                 # Must not be a known source file.
  66                 if ($src ne $dest && exists $pagesources{$dest}) {
  67                         error(sprintf(gettext("%s already exists"),
  68                                 htmllink("", "", $dest, noimageinline => 1)));
  69                 }
  70
  71                 # Must not exist on disk already.
  72                 if (-l "$config{srcdir}/$destfile" || -e _) {
  73                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  74                 }
  75
  76                 # Must be editable.
  77                 IkiWiki::check_canedit($dest, $q, $session);
  78                 if ($attachment) {
  79                         # Note that $srcfile is used here, not $destfile,
  80                         # because it wants the current file, to check it.
  81                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  82                 }
  83         }
  84 } #}}}
  85
  86 sub rename_form ($$$) { #{{{
  87         my $q=shift;
  88         my $session=shift;
  89         my $page=shift;
  90
  91         eval q{use CGI::FormBuilder};
  92         error($@) if $@;
  93         my $f = CGI::FormBuilder->new(
  94                 name => "rename",
  95                 title => sprintf(gettext("rename %s"), IkiWiki::pagetitle($page)),
  96                 header => 0,
  97                 charset => "utf-8",
  98                 method => 'POST',
  99                 javascript => 0,
 100                 params => $q,
 101                 action => $config{cgiurl},
 102                 stylesheet => IkiWiki::baseurl()."style.css",
 103                 fields => [qw{do page new_name attachment}],
 104         );
 105
 106         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
 107         $f->field(name => "page", type => "hidden", value => $page, force => 1);
 108         $f->field(name => "new_name", value => IkiWiki::pagetitle($page), size => 60);
 109         if (!$q->param("attachment")) {
 110                 # insert the standard extensions
 111                 my @page_types;
 112                 if (exists $IkiWiki::hooks{htmlize}) {
 113                         @page_types=grep { !/^_/ }
 114                                 keys %{$IkiWiki::hooks{htmlize}};
 115                 }
 116
 117                 # make sure the current extension is in the list
 118                 my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
 119                 if (! $IkiWiki::hooks{htmlize}{$ext}) {
 120                         unshift(@page_types, $ext);
 121                 }
 122
 123                 $f->field(name => "type", type => 'select',
 124                         options => \@page_types,
 125                         value => $ext, force => 1);
 126
 127                 $f->field(name => "subpages",
 128                         label => "",
 129                         type => "checkbox",
 130                         options => [ [ 1 => gettext("Also rename SubPages and attachments") ] ],
 131                         value => 1,
 132                         force => 1);
 133         }
 134         $f->field(name => "attachment", type => "hidden");
 135
 136         return $f, ["Rename", "Cancel"];
 137 } #}}}
 138
 139 sub rename_start ($$$$) { #{{{
 140         my $q=shift;
 141         my $session=shift;
 142         my $attachment=shift;
 143         my $page=shift;
 144
 145         check_canrename($page, $pagesources{$page}, undef, undef,
 146                 $q, $session, $attachment);
 147
 148         # Save current form state to allow returning to it later
 149         # without losing any edits.
 150         # (But don't save what button was submitted, to avoid
 151         # looping back to here.)
 152         # Note: "_submit" is CGI::FormBuilder internals.
 153         $q->param(-name => "_submit", -value => "");
 154         $session->param(postrename => scalar $q->Vars);
 155         IkiWiki::cgi_savesession($session);
 156
 157         my ($f, $buttons)=rename_form($q, $session, $page);
 158         if (defined $attachment) {
 159                 $f->field(name => "attachment", value => $attachment, force => 1);
 160         }
 161
 162         IkiWiki::showform($f, $buttons, $session, $q);
 163         exit 0;
 164 } #}}}
 165
 166 sub postrename ($;$$$) { #{{{
 167         my $session=shift;
 168         my $src=shift;
 169         my $dest=shift;
 170         my $attachment=shift;
 171
 172         # Load saved form state and return to edit page.
 173         my $postrename=CGI->new($session->param("postrename"));
 174         $session->clear("postrename");
 175         IkiWiki::cgi_savesession($session);
 176
 177         if (defined $dest) {
 178                 if (! $attachment) {
 179                         # They renamed the page they were editing. This requires
 180                         # fixups to the edit form state.
 181                         # Tweak the edit form to be editing the new page.
 182                         $postrename->param("page", $dest);
 183                 }
 184
 185                 # Update edit form content to fix any links present
 186                 # on it.
 187                 $postrename->param("editcontent",
 188                         renamepage_hook($dest, $src, $dest,
 189                                  $postrename->param("editcontent")));
 190
 191                 # Get a new edit token; old was likely invalidated.
 192                 $postrename->param("rcsinfo",
 193                         IkiWiki::rcs_prepedit($pagesources{$dest}));
 194         }
 195
 196         IkiWiki::cgi_editpage($postrename, $session);
 197 } #}}}
 198
 199 sub formbuilder (@) { #{{{
 200         my %params=@_;
 201         my $form=$params{form};
 202
 203         if (defined $form->field("do") && $form->field("do") eq "edit") {
 204                 my $q=$params{cgi};
 205                 my $session=$params{session};
 206
 207                 if ($form->submitted eq "Rename") {
 208                         rename_start($q, $session, 0, $form->field("page"));
 209                 }
 210                 elsif ($form->submitted eq "Rename Attachment") {
 211                         my @selected=$q->param("attachment_select");
 212                         if (@selected > 1) {
 213                                 error(gettext("Only one attachment can be renamed at a time."));
 214                         }
 215                         elsif (! @selected) {
 216                                 error(gettext("Please select the attachment to rename."))
 217                         }
 218                         rename_start($q, $session, 1, $selected[0]);
 219                 }
 220         }
 221 } #}}}
 222
 223 my $renamesummary;
 224
 225 sub formbuilder_setup (@) { #{{{
 226         my %params=@_;
 227         my $form=$params{form};
 228         my $q=$params{cgi};
 229
 230         if (defined $form->field("do") && $form->field("do") eq "edit") {
 231                 # Rename button for the page, and also for attachments.
 232                 push @{$params{buttons}}, "Rename";
 233                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 234
 235                 if (defined $renamesummary) {
 236                         $form->tmpl_param(message => $renamesummary);
 237                 }
 238         }
 239 } #}}}
 240
 241 sub sessioncgi ($$) { #{{{
 242         my $q=shift;
 243
 244         if ($q->param("do") eq 'rename') {
 245                 my $session=shift;
 246                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 247                 IkiWiki::decode_form_utf8($form);
 248
 249                 if ($form->submitted eq 'Cancel') {
 250                         postrename($session);
 251                 }
 252                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 253                         # These untaints are safe because of the checks
 254                         # performed in check_canrename below.
 255                         my $src=$q->param("page");
 256                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 257                         my $dest=IkiWiki::possibly_foolish_untaint(IkiWiki::titlepage($q->param("new_name")));
 258
 259                         my $destfile=$dest;
 260                         if (! $q->param("attachment")) {
 261                                 my $type=$q->param('type');
 262                                 if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 263                                         $type=IkiWiki::possibly_foolish_untaint($type);
 264                                 }
 265                                 else {
 266                                         my ($ext)=$srcfile=~/\.([^.]+)$/;
 267                                         $type=$ext;
 268                                 }
 269
 270                                 $destfile.=".".$type;
 271                         }
 272
 273                         check_canrename($src, $srcfile, $dest, $destfile,
 274                                 $q, $session, $q->param("attachment"));
 275
 276                         # See if subpages need to be renamed.
 277                         my @subpages;
 278                         if ($q->param("subpages") && $src ne $dest) {
 279                                 foreach my $p (keys %pagesources) {
 280                                         if ($pagesources{$p}=~m/^\Q$src\E\/$/) {
 281                                                 push @subpages, $p;
 282                                         }
 283                                 }
 284                         }
 285
 286                         # Begin renaming process, which will end with a
 287                         # wiki refresh.
 288                         require IkiWiki::Render;
 289                         IkiWiki::disable_commit_hook() if $config{rcs};
 290
 291                         do_rename($srcfile, $destfile, $session);
 292
 293                         foreach my $subpage (@subpages) {
 294                                 my $subsrc=$pagesources{$subpage};
 295                                 my $subdest=$subsrc;
 296                                 $subdest=~s/^\Q$src\E\//$dest/;
 297                                 eval {
 298                                         do_rename($subsrc, $subdest, $session)
 299                                 };
 300                         }
 301
 302                         my @fixedlinks;
 303                         if ($src ne $dest) {
 304                                 push @fixedlinks, fixlinks($src, $dest, $session);
 305                         }
 306
 307                         # End renaming process and refresh wiki.
 308                         if ($config{rcs}) {
 309                                 IkiWiki::enable_commit_hook();
 310                                 IkiWiki::rcs_update();
 311                         }
 312                         IkiWiki::refresh();
 313                         IkiWiki::saveindex();
 314
 315                         # Scan for any remaining broken links to $src.
 316                         my @brokenlinks;
 317                         if ($src ne $dest) {
 318                                 foreach my $page (keys %links) {
 319                                         my $broken=0;
 320                                         foreach my $link (@{$links{$page}}) {
 321                                                 my $bestlink=bestlink($page, $link);
 322                                                 if ($bestlink eq $src) {
 323                                                         $broken=1;
 324                                                         last;
 325                                                 }
 326                                         }
 327                                         push @brokenlinks, $page if $broken;
 328                                 }
 329                         }
 330
 331                         # Generate a rename summary, that will be shown at the top
 332                         # of the edit template.
 333                         my $template=template("renamesummary.tmpl");
 334                         $template->param(src => $srcfile);
 335                         $template->param(dest => $destfile);
 336                         if ($src ne $dest) {
 337                                 $template->param(brokenlinks_checked => 1);
 338                                 $template->param(brokenlinks => [
 339                                         map {
 340                                                 {
 341                                                         page => htmllink($dest, $dest, $_,
 342                                                                         noimageinline => 1)
 343                                                 }
 344                                         } @brokenlinks
 345                                 ]);
 346                                 $template->param(fixedlinks => [
 347                                         map {
 348                                                 {
 349                                                         page => htmllink($dest, $dest, $_,
 350                                                                         noimageinline => 1)
 351                                                 }
 352                                         } @fixedlinks
 353                                 ]);
 354                         }
 355                         $renamesummary=$template->output;
 356
 357                         postrename($session, $src, $dest, $q->param("attachment"));
 358                 }
 359                 else {
 360                         IkiWiki::showform($form, $buttons, $session, $q);
 361                 }
 362
 363                 exit 0;
 364         }
 365 } #}}}
 366
 367 sub renamepage_hook ($$$$) { #{{{
 368         my ($page, $src, $dest, $content)=@_;
 369
 370         IkiWiki::run_hooks(renamepage => sub {
 371                 $content=shift->(
 372                         page => $page,
 373                         oldpage => $src,
 374                         newpage => $dest,
 375                         content => $content,
 376                 );
 377         });
 378
 379         return $content;
 380 }# }}}
 381
 382 sub do_rename ($$$) { #{{{
 383         my $srcfile=shift;
 384         my $destfile=shift;
 385         my $session=shift;
 386
 387         # Actual file rename happens here.
 388         # First, ensure that the dest directory exists and is ok.
 389         IkiWiki::prep_writefile($destfile, $config{srcdir});
 390         if ($config{rcs}) {
 391                 IkiWiki::rcs_rename($srcfile, $destfile);
 392                 IkiWiki::rcs_commit_staged(
 393                         sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
 394                         $session->param("name"), $ENV{REMOTE_ADDR});
 395         }
 396         else {
 397                 if (! rename("$config{srcdir}/$srcfile", "$config{srcdir}/$destfile")) {
 398                         error("rename: $!");
 399                 }
 400         }
 401 } # }}}
 402
 403 sub fixlinks ($$$) { #{{{
 404         my $src=shift;
 405         my $dest=shift;
 406         my $session=shift;
 407
 408         my @fixedlinks;
 409
 410         foreach my $page (keys %links) {
 411                 my $needfix=0;
 412                 foreach my $link (@{$links{$page}}) {
 413                         my $bestlink=bestlink($page, $link);
 414                         if ($bestlink eq $src) {
 415                                 $needfix=1;
 416                                 last;
 417                         }
 418                 }
 419                 if ($needfix) {
 420                         my $file=$pagesources{$page};
 421                         my $oldcontent=readfile($config{srcdir}."/".$file);
 422                         my $content=renamepage_hook($page, $src, $dest, $oldcontent);
 423                         if ($oldcontent ne $content) {
 424                                 my $token=IkiWiki::rcs_prepedit($file);
 425                                 eval { writefile($file, $config{srcdir}, $content) };
 426                                 next if $@;
 427                                 my $conflict=IkiWiki::rcs_commit(
 428                                         $file,
 429                                         sprintf(gettext("update for rename of %s to %s"), $src, $dest),
 430                                         $token,
 431                                         $session->param("name"),
 432                                         $ENV{REMOTE_ADDR}
 433                                 );
 434                                 push @fixedlinks, $page if ! defined $conflict;
 435                         }
 436                 }
 437         }
 438
 439         return @fixedlinks;
 440 } #}}}
 441
 442 1