git.oblomov.eu Git - ikiwiki/blob - ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8
   9 BEGIN {
  10         $blosxom::version="is a proper perl module too much to ask?";
  11         do "/usr/bin/markdown";
  12 }
  13
  14 memoize('pagename');
  15 memoize('bestlink');
  16
  17 sub usage {
  18         die "usage: ikiwiki [options] source dest\n";
  19 }
  20
  21 my $link=qr/\[\[([^\s]+)\]\]/;
  22 my $verbose=0;
  23 my $rebuild=0;
  24 my $wikiname="wiki";
  25 if (grep /^-/, @ARGV) {
  26         eval {use Getopt::Long};
  27         GetOptions(
  28                 "wikiname=s" => \$wikiname,
  29                 "verbose|v" => \$verbose,
  30                 "rebuild" => \$rebuild,
  31         ) || usage();
  32 }
  33 usage() unless @ARGV == 2;
  34 my ($srcdir) = shift =~ /(.*)/; # untaint
  35 my ($destdir) = shift =~ /(.*)/; # untaint
  36
  37 my %links;
  38 my %oldlinks;
  39 my %oldpagemtime;
  40 my %renderedfiles;
  41 my %pagesources;
  42
  43 sub error ($) {
  44         die @_;
  45 }
  46
  47 sub debug ($) {
  48         print "@_\n" if $verbose;
  49 }
  50
  51 sub mtime ($) {
  52         my $page=shift;
  53
  54         return (stat($page))[9];
  55 }
  56
  57 sub basename {
  58         my $file=shift;
  59
  60         $file=~s!.*/!!;
  61         return $file;
  62 }
  63
  64 sub dirname {
  65         my $file=shift;
  66
  67         $file=~s!/?[^/]+$!!;
  68         return $file;
  69 }
  70
  71 sub pagetype ($) {
  72         my $page=shift;
  73
  74         if ($page =~ /\.mdwn$/) {
  75                 return ".mdwn";
  76         }
  77         else {
  78                 return "unknown";
  79         }
  80 }
  81
  82 sub pagename ($) {
  83         my $file=shift;
  84
  85         my $type=pagetype($file);
  86         my $page=$file;
  87         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  88         return $page;
  89 }
  90
  91 sub htmlpage ($) {
  92         my $page=shift;
  93
  94         return $page.".html";
  95 }
  96
  97 sub readpage ($) {
  98         my $page=shift;
  99
 100         local $/=undef;
 101         open (PAGE, "$srcdir/$page") || error("failed to read $page: $!");
 102         my $ret=<PAGE>;
 103         close PAGE;
 104         return $ret;
 105 }
 106
 107 sub writepage ($$) {
 108         my $page=shift;
 109         my $content=shift;
 110
 111         my $dir=dirname("$destdir/$page");
 112         if (! -d $dir) {
 113                 my $d="";
 114                 foreach my $s (split(m!/+!, $dir)) {
 115                         $d.="$s/";
 116                         if (! -d $d) {
 117                                 mkdir($d) || error("failed to create directory $d: $!");
 118                         }
 119                 }
 120         }
 121
 122         open (PAGE, ">$destdir/$page") || error("failed to write $page: $!");
 123         print PAGE $content;
 124         close PAGE;
 125 }
 126
 127 sub findlinks {
 128         my $content=shift;
 129
 130         my @links;
 131         while ($content =~ /$link/g) {
 132                 push @links, lc($1);
 133         }
 134         return @links;
 135 }
 136
 137 # Given a page and the text of a link on the page, determine which existing
 138 # page that link best points to. Prefers pages under a subdirectory with
 139 # the same name as the source page, failing that goes down the directory tree
 140 # to the base looking for matching pages.
 141 sub bestlink ($$) {
 142         my $page=shift;
 143         my $link=lc(shift);
 144
 145         my $cwd=$page;
 146         do {
 147                 my $l=$cwd;
 148                 $l.="/" if length $l;
 149                 $l.=$link;
 150
 151                 if (exists $links{$l}) {
 152                         #debug("for $page, \"$link\", use $l");
 153                         return $l;
 154                 }
 155         } while $cwd=~s!/?[^/]+$!!;
 156
 157         #print STDERR "warning: page $page, broken link: $link\n";
 158         return "";
 159 }
 160
 161 sub isinlinableimage ($) {
 162         my $file=shift;
 163
 164         $file=~/\.(png|gif|jpg|jpeg)$/;
 165 }
 166
 167 sub htmllink ($$) {
 168         my $page=shift;
 169         my $link=shift;
 170
 171         my $bestlink=bestlink($page, $link);
 172
 173         return $link if $page eq $bestlink;
 174
 175         # TODO BUG: %renderedfiles may not have it, if the linked to page
 176         # was also added and isn't yet rendered! Note that this bug is
 177         # masked by the bug mentioned below that makes all new files
 178         # be rendered twice.
 179         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 180                 $bestlink=htmlpage($bestlink);
 181         }
 182         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 183                 return "<a href=\"?\">?</a>$link"
 184         }
 185
 186         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 187
 188         if (isinlinableimage($bestlink)) {
 189                 return "<img src=\"$bestlink\">";
 190         }
 191         return "<a href=\"$bestlink\">$link</a>";
 192 }
 193
 194 sub linkify ($$) {
 195         my $content=shift;
 196         my $file=shift;
 197
 198         $content =~ s/$link/htmllink(pagename($file), $1)/eg;
 199
 200         return $content;
 201 }
 202
 203 sub htmlize ($$) {
 204         my $type=shift;
 205         my $content=shift;
 206
 207         if ($type eq '.mdwn') {
 208                 return Markdown::Markdown($content);
 209         }
 210         else {
 211                 error("htmlization of $type not supported");
 212         }
 213 }
 214
 215 sub linkbacks ($$) {
 216         my $content=shift;
 217         my $page=shift;
 218
 219         my @links;
 220         foreach my $p (keys %links) {
 221                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
 222                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 223                         # TODO: if $p is joey/foo/bar and
 224                         # the $page is joey/foo/baz, make the link text
 225                         # just be "bar".
 226                         push @links, "<a href=\"$href\">$p</a>";
 227                 }
 228         }
 229
 230         $content.="<hr><p>Links: ".join(" ", sort @links)."</p>\n" if @links;
 231         return $content;
 232 }
 233
 234 sub finalize ($$) {
 235         my $content=shift;
 236         my $page=shift;
 237
 238         my $title=basename($page);
 239         $title=~s/_/ /g;
 240
 241         my $pagelink="";
 242         my $path="";
 243         foreach my $dir (reverse split("/", $page)) {
 244                 if (length($pagelink)) {
 245                         $pagelink="<a href=\"$path$dir.html\">$dir</a>/ $pagelink";
 246                 }
 247                 else {
 248                         $pagelink=$dir;
 249                 }
 250                 $path.="../";
 251         }
 252         $path=~s/\.\.\/$/index.html/;
 253         $pagelink="<a href=\"$path\">$wikiname</a>/ $pagelink";
 254
 255         $content="<html>\n<head><title>$title</title></head>\n<body>\n".
 256                   "<h1>$pagelink</h1>\n".
 257                   $content.
 258                   "</body>\n</html>\n";
 259
 260         return $content;
 261 }
 262
 263 sub render ($) {
 264         my $file=shift;
 265
 266         my $type=pagetype($file);
 267         my $content=readpage($file);
 268         if ($type ne 'unknown') {
 269                 my $page=pagename($file);
 270
 271                 $links{$page}=[findlinks($content)];
 272
 273                 $content=linkify($content, $file);
 274                 $content=htmlize($type, $content);
 275                 $content=linkbacks($content, $page);
 276                 $content=finalize($content, $page);
 277
 278                 writepage(htmlpage($page), $content);
 279                 $oldpagemtime{$page}=time;
 280                 $renderedfiles{$page}=htmlpage($page);
 281         }
 282         else {
 283                 $links{$file}=[];
 284                 writepage($file, $content);
 285                 $oldpagemtime{$file}=time;
 286                 $renderedfiles{$file}=$file;
 287         }
 288 }
 289
 290 sub loadindex () {
 291         open (IN, "$srcdir/.index") || return;
 292         while (<IN>) {
 293                 ($_)=/(.*)/; # untaint
 294                 chomp;
 295                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 296                 my $page=pagename($file);
 297                 $pagesources{$page}=$file;
 298                 $oldpagemtime{$page}=$mtime;
 299                 $oldlinks{$page}=[@links];
 300                 $links{$page}=[@links];
 301                 $renderedfiles{$page}=$rendered;
 302         }
 303         close IN;
 304 }
 305
 306 sub saveindex () {
 307         open (OUT, ">$srcdir/.index") || error("cannot write to .index: $!");
 308         foreach my $page (keys %oldpagemtime) {
 309         print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 310                   join(" ", @{$links{$page}})."\n"
 311                         if $oldpagemtime{$page};
 312         }
 313         close OUT;
 314 }
 315
 316 sub prune ($) {
 317         my $file=shift;
 318
 319         unlink($file);
 320         my $dir=dirname($file);
 321         while (rmdir($dir)) {
 322                 $dir=dirname($dir);
 323         }
 324 }
 325
 326 sub refresh () {
 327         # Find existing pages.
 328         my %exists;
 329         my @files;
 330         find({
 331                 no_chdir => 1,
 332                 wanted => sub {
 333                         if (/\/\.svn\//) {
 334                                 $File::Find::prune=1;
 335                         }
 336                         elsif (! -d $_ && ! /\.html$/ && ! /\/\./) {
 337                                 my ($f)=/(^[-A-Za-z0-9_.:\/+]+$)/; # untaint
 338                                 if (! defined $f) {
 339                                         warn("skipping bad filename $_\n");
 340                                 }
 341                                 else {
 342                                         $f=~s/^\Q$srcdir\E\/?//;
 343                                         push @files, $f;
 344                                         $exists{pagename($f)}=1;
 345                                 }
 346                         }
 347                 },
 348         }, $srcdir);
 349
 350         my %rendered;
 351
 352         # check for added or removed pages
 353         my @add;
 354         foreach my $file (@files) {
 355                 my $page=pagename($file);
 356                 if (! $oldpagemtime{$page}) {
 357                         debug("new page $page");
 358                         push @add, $file;
 359                         $links{$page}=[];
 360                         $pagesources{$page}=$file;
 361                 }
 362         }
 363         my @del;
 364         foreach my $page (keys %oldpagemtime) {
 365                 if (! $exists{$page}) {
 366                         debug("removing old page $page");
 367                         push @del, $renderedfiles{$page};
 368                         prune($destdir."/".$renderedfiles{$page});
 369                         delete $renderedfiles{$page};
 370                         $oldpagemtime{$page}=0;
 371                         delete $pagesources{$page};
 372                 }
 373         }
 374
 375         # render any updated files
 376         foreach my $file (@files) {
 377                 my $page=pagename($file);
 378
 379                 if (! exists $oldpagemtime{$page} ||
 380                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 381                         debug("rendering changed file $file");
 382                         render($file);
 383                         $rendered{$file}=1;
 384                 }
 385         }
 386
 387         # if any files were added or removed, check to see if each page
 388         # needs an update due to linking to them
 389         # TODO: inefficient; pages may get rendered above and again here;
 390         # problem is the bestlink may have changed and we won't know until
 391         # now
 392         if (@add || @del) {
 393 FILE:           foreach my $file (@files) {
 394                         my $page=pagename($file);
 395                         foreach my $f (@add, @del) {
 396                                 my $p=pagename($f);
 397                                 foreach my $link (@{$links{$page}}) {
 398                                         if (bestlink($page, $link) eq $p) {
 399                                                 debug("rendering $file, which links to $p");
 400                                                 render($file);
 401                                                 $rendered{$file}=1;
 402                                                 next FILE;
 403                                         }
 404                                 }
 405                         }
 406                 }
 407         }
 408
 409         # handle linkbacks; if a page has added/removed links, update the
 410         # pages it links to
 411         # TODO: inefficient; pages may get rendered above and again here;
 412         # problem is the linkbacks could be wrong in the first pass render
 413         # above
 414         if (%rendered) {
 415                 my %linkchanged;
 416                 foreach my $file (keys %rendered, @del) {
 417                         my $page=pagename($file);
 418                         if (exists $links{$page}) {
 419                                 foreach my $link (@{$links{$page}}) {
 420                                         $link=bestlink($page, $link);
 421                                         if (length $link &&
 422                                             ! exists $oldlinks{$page} ||
 423                                             ! grep { $_ eq $link } @{$oldlinks{$page}}) {
 424                                                 $linkchanged{$link}=1;
 425                                         }
 426                                 }
 427                         }
 428                         if (exists $oldlinks{$page}) {
 429                                 foreach my $link (@{$oldlinks{$page}}) {
 430                                         $link=bestlink($page, $link);
 431                                         if (length $link &&
 432                                             ! exists $links{$page} ||
 433                                             ! grep { $_ eq $link } @{$links{$page}}) {
 434                                                 $linkchanged{$link}=1;
 435                                         }
 436                                 }
 437                         }
 438                 }
 439                 foreach my $link (keys %linkchanged) {
 440                         my $linkfile=$pagesources{$link};
 441                         if (defined $linkfile) {
 442                                 debug("rendering $linkfile, to update its linkbacks");
 443                                 render($linkfile);
 444                         }
 445                 }
 446         }
 447 }
 448
 449 loadindex() unless $rebuild;
 450 refresh();
 451 saveindex();