git.oblomov.eu Git - ikiwiki/blob - IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use IkiWiki::UserInfo;
   9 use open qw{:utf8 :std};
  10 use Encode;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub showform ($$$$;@) { #{{{
  25         my $form=shift;
  26         my $buttons=shift;
  27         my $session=shift;
  28         my $cgi=shift;
  29
  30         if (exists $hooks{formbuilder}) {
  31                 run_hooks(formbuilder => sub {
  32                         shift->(form => $form, cgi => $cgi, session => $session,
  33                                 buttons => $buttons);
  34                 });
  35         }
  36
  37         printheader($session);
  38         print misctemplate($form->title, $form->render(submit => $buttons), @_);
  39 }
  40
  41 sub redirect ($$) { #{{{
  42         my $q=shift;
  43         my $url=shift;
  44         if (! $config{w3mmode}) {
  45                 print $q->redirect($url);
  46         }
  47         else {
  48                 print "Content-type: text/plain\n";
  49                 print "W3m-control: GOTO $url\n\n";
  50         }
  51 } #}}}
  52
  53 sub check_canedit ($$$;$) { #{{{
  54         my $page=shift;
  55         my $q=shift;
  56         my $session=shift;
  57         my $nonfatal=shift;
  58
  59         my $canedit;
  60         run_hooks(canedit => sub {
  61                 return if defined $canedit;
  62                 my $ret=shift->($page, $q, $session);
  63                 if (defined $ret) {
  64                         if ($ret eq "") {
  65                                 $canedit=1;
  66                         }
  67                         elsif (ref $ret eq 'CODE') {
  68                                 $ret->() unless $nonfatal;
  69                                 $canedit=0;
  70                         }
  71                         elsif (defined $ret) {
  72                                 error($ret) unless $nonfatal;
  73                                 $canedit=0;
  74                         }
  75                 }
  76         });
  77         return $canedit;
  78 } #}}}
  79
  80 sub decode_cgi_utf8 ($) { #{{{
  81         # decode_form_utf8 method is needed for 5.10
  82         if ($] < 5.01) {
  83                 my $cgi = shift;
  84                 foreach my $f ($cgi->param) {
  85                         $cgi->param($f, map { decode_utf8 $_ } $cgi->param($f));
  86                 }
  87         }
  88 } #}}}
  89
  90 sub decode_form_utf8 ($) { #{{{
  91         if ($] >= 5.01) {
  92                 my $form = shift;
  93                 foreach my $f ($form->field) {
  94                         $form->field(name  => $f,
  95                                      value => decode_utf8($form->field($f)),
  96                                      force => 1,
  97                         );
  98                 }
  99         }
 100 } #}}}
 101
 102 # Check if the user is signed in. If not, redirect to the signin form and
 103 # save their place to return to later.
 104 sub needsignin ($$) { #{{{
 105         my $q=shift;
 106         my $session=shift;
 107
 108         if (! defined $session->param("name") ||
 109             ! userinfo_get($session->param("name"), "regdate")) {
 110                 $session->param(postsignin => $ENV{QUERY_STRING});
 111                 cgi_signin($q, $session);
 112                 cgi_savesession($session);
 113                 exit;
 114         }
 115 } #}}}
 116
 117 sub cgi_signin ($$) { #{{{
 118         my $q=shift;
 119         my $session=shift;
 120
 121         decode_cgi_utf8($q);
 122         eval q{use CGI::FormBuilder};
 123         error($@) if $@;
 124         my $form = CGI::FormBuilder->new(
 125                 title => "signin",
 126                 name => "signin",
 127                 charset => "utf-8",
 128                 method => 'POST',
 129                 required => 'NONE',
 130                 javascript => 0,
 131                 params => $q,
 132                 action => $config{cgiurl},
 133                 header => 0,
 134                 template => {type => 'div'},
 135                 stylesheet => baseurl()."style.css",
 136         );
 137         my $buttons=["Login"];
 138
 139         if ($q->param("do") ne "signin" && !$form->submitted) {
 140                 $form->text(gettext("You need to log in first."));
 141         }
 142         $form->field(name => "do", type => "hidden", value => "signin",
 143                 force => 1);
 144
 145         decode_form_utf8($form);
 146         run_hooks(formbuilder_setup => sub {
 147                 shift->(form => $form, cgi => $q, session => $session,
 148                         buttons => $buttons);
 149         });
 150         decode_form_utf8($form);
 151
 152         if ($form->submitted) {
 153                 $form->validate;
 154         }
 155
 156         showform($form, $buttons, $session, $q);
 157 } #}}}
 158
 159 sub cgi_postsignin ($$) { #{{{
 160         my $q=shift;
 161         my $session=shift;
 162
 163         # Continue with whatever was being done before the signin process.
 164         if (defined $session->param("postsignin")) {
 165                 my $postsignin=CGI->new($session->param("postsignin"));
 166                 $session->clear("postsignin");
 167                 cgi($postsignin, $session);
 168                 cgi_savesession($session);
 169                 exit;
 170         }
 171         else {
 172                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 173         }
 174 } #}}}
 175
 176 sub cgi_prefs ($$) { #{{{
 177         my $q=shift;
 178         my $session=shift;
 179
 180         needsignin($q, $session);
 181         decode_cgi_utf8($q);
 182
 183         # The session id is stored on the form and checked to
 184         # guard against CSRF.
 185         my $sid=$q->param('sid');
 186         if (! defined $sid) {
 187                 $q->delete_all;
 188         }
 189         elsif ($sid ne $session->id) {
 190                 error(gettext("Your login session has expired."));
 191         }
 192
 193         eval q{use CGI::FormBuilder};
 194         error($@) if $@;
 195         my $form = CGI::FormBuilder->new(
 196                 title => "preferences",
 197                 name => "preferences",
 198                 header => 0,
 199                 charset => "utf-8",
 200                 method => 'POST',
 201                 validate => {
 202                         email => 'EMAIL',
 203                 },
 204                 required => 'NONE',
 205                 javascript => 0,
 206                 params => $q,
 207                 action => $config{cgiurl},
 208                 template => {type => 'div'},
 209                 stylesheet => baseurl()."style.css",
 210                 fieldsets => [
 211                         [login => gettext("Login")],
 212                         [preferences => gettext("Preferences")],
 213                         [admin => gettext("Admin")]
 214                 ],
 215         );
 216         my $buttons=["Save Preferences", "Logout", "Cancel"];
 217
 218         decode_form_utf8($form);
 219         run_hooks(formbuilder_setup => sub {
 220                 shift->(form => $form, cgi => $q, session => $session,
 221                         buttons => $buttons);
 222         });
 223         decode_form_utf8($form);
 224
 225         $form->field(name => "do", type => "hidden", value => "prefs",
 226                 force => 1);
 227         $form->field(name => "sid", type => "hidden", value => $session->id,
 228                 force => 1);
 229         $form->field(name => "email", size => 50, fieldset => "preferences");
 230         $form->field(name => "banned_users", size => 50,
 231                 fieldset => "admin");
 232
 233         my $user_name=$session->param("name");
 234         if (! is_admin($user_name)) {
 235                 $form->field(name => "banned_users", type => "hidden");
 236         }
 237
 238         if (! $form->submitted) {
 239                 $form->field(name => "email", force => 1,
 240                         value => userinfo_get($user_name, "email"));
 241                 if (is_admin($user_name)) {
 242                         $form->field(name => "banned_users", force => 1,
 243                                 value => join(" ", get_banned_users()));
 244                 }
 245         }
 246
 247         if ($form->submitted eq 'Logout') {
 248                 $session->delete();
 249                 redirect($q, $config{url});
 250                 return;
 251         }
 252         elsif ($form->submitted eq 'Cancel') {
 253                 redirect($q, $config{url});
 254                 return;
 255         }
 256         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 257                 if (defined $form->field('email')) {
 258                         userinfo_set($user_name, 'email', $form->field('email')) ||
 259                                 error("failed to set email");
 260                 }
 261                 if (is_admin($user_name)) {
 262                         set_banned_users(grep { ! is_admin($_) }
 263                                         split(' ',
 264                                                 $form->field("banned_users"))) ||
 265                                 error("failed saving changes");
 266                 }
 267                 $form->text(gettext("Preferences saved."));
 268         }
 269
 270         showform($form, $buttons, $session, $q);
 271 } #}}}
 272
 273 sub cgi_editpage ($$) { #{{{
 274         my $q=shift;
 275         my $session=shift;
 276
 277         decode_cgi_utf8($q);
 278
 279         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 280         my @buttons=("Save Page", "Preview", "Cancel");
 281         eval q{use CGI::FormBuilder};
 282         error($@) if $@;
 283         my $form = CGI::FormBuilder->new(
 284                 fields => \@fields,
 285                 charset => "utf-8",
 286                 method => 'POST',
 287                 required => [qw{editcontent}],
 288                 javascript => 0,
 289                 params => $q,
 290                 action => $config{cgiurl},
 291                 header => 0,
 292                 table => 0,
 293                 template => scalar template_params("editpage.tmpl"),
 294                 wikiname => $config{wikiname},
 295         );
 296
 297         decode_form_utf8($form);
 298         run_hooks(formbuilder_setup => sub {
 299                 shift->(form => $form, cgi => $q, session => $session,
 300                         buttons => \@buttons);
 301         });
 302         decode_form_utf8($form);
 303
 304         # This untaint is safe because we check file_pruned.
 305         my $page=$form->field('page');
 306         $page=possibly_foolish_untaint($page);
 307         my $absolute=($page =~ s#^/+##);
 308         if (! defined $page || ! length $page ||
 309             file_pruned($page, $config{srcdir})) {
 310                 error("bad page name");
 311         }
 312
 313         my $baseurl=$config{url}."/".htmlpage($page);
 314
 315         my $from;
 316         if (defined $form->field('from')) {
 317                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 318         }
 319
 320         my $file;
 321         my $type;
 322         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 323                 $file=$pagesources{$page};
 324                 $type=pagetype($file);
 325                 if (! defined $type || $type=~/^_/) {
 326                         error(sprintf(gettext("%s is not an editable page"), $page));
 327                 }
 328                 if (! $form->submitted) {
 329                         $form->field(name => "rcsinfo",
 330                                 value => rcs_prepedit($file), force => 1);
 331                 }
 332                 $form->field(name => "editcontent", validate => '/.*/');
 333         }
 334         else {
 335                 $type=$form->param('type');
 336                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 337                         $type=possibly_foolish_untaint($type);
 338                 }
 339                 elsif (defined $from && exists $pagesources{$from}) {
 340                         # favor the type of linking page
 341                         $type=pagetype($pagesources{$from});
 342                 }
 343                 $type=$config{default_pageext} unless defined $type;
 344                 $file=$page.".".$type;
 345                 if (! $form->submitted) {
 346                         $form->field(name => "rcsinfo", value => "", force => 1);
 347                 }
 348                 $form->field(name => "editcontent", validate => '/.+/');
 349         }
 350
 351         $form->field(name => "do", type => 'hidden');
 352         $form->field(name => "sid", type => "hidden", value => $session->id,
 353                 force => 1);
 354         $form->field(name => "from", type => 'hidden');
 355         $form->field(name => "rcsinfo", type => 'hidden');
 356         $form->field(name => "subpage", type => 'hidden');
 357         $form->field(name => "page", value => $page, force => 1);
 358         $form->field(name => "type", value => $type, force => 1);
 359         $form->field(name => "comments", type => "text", size => 80);
 360         $form->field(name => "editcontent", type => "textarea", rows => 20,
 361                 cols => 80);
 362         $form->tmpl_param("can_commit", $config{rcs});
 363         $form->tmpl_param("indexlink", indexlink());
 364         $form->tmpl_param("helponformattinglink",
 365                 htmllink($page, $page, "ikiwiki/formatting",
 366                         noimageinline => 1,
 367                         linktext => "FormattingHelp"));
 368         $form->tmpl_param("message", "");
 369
 370         if ($form->submitted eq "Cancel") {
 371                 if ($form->field("do") eq "create" && defined $from) {
 372                         redirect($q, "$config{url}/".htmlpage($from));
 373                 }
 374                 elsif ($form->field("do") eq "create") {
 375                         redirect($q, $config{url});
 376                 }
 377                 else {
 378                         redirect($q, "$config{url}/".htmlpage($page));
 379                 }
 380                 return;
 381         }
 382         elsif ($form->submitted eq "Preview") {
 383                 my $new=not exists $pagesources{$page};
 384                 if ($new) {
 385                         # temporarily record its type
 386                         $pagesources{$page}=$page.".".$type;
 387                 }
 388
 389                 my $content=$form->field('editcontent');
 390
 391                 run_hooks(editcontent => sub {
 392                         $content=shift->(
 393                                 content => $content,
 394                                 page => $page,
 395                                 cgi => $q,
 396                                 session => $session,
 397                         );
 398                 });
 399                 my $preview=htmlize($page, $page, $type,
 400                         linkify($page, $page,
 401                         preprocess($page, $page,
 402                         filter($page, $page, $content), 0, 1)));
 403                 run_hooks(format => sub {
 404                         $preview=shift->(
 405                                 page => $page,
 406                                 content => $preview,
 407                         );
 408                 });
 409                 $form->tmpl_param("page_preview", $preview);
 410
 411                 if ($new) {
 412                         delete $pagesources{$page};
 413                 }
 414                 # previewing may have created files on disk
 415                 saveindex();
 416         }
 417         elsif ($form->submitted eq "Save Page") {
 418                 $form->tmpl_param("page_preview", "");
 419         }
 420
 421         if ($form->submitted ne "Save Page" || ! $form->validate) {
 422                 if ($form->field("do") eq "create") {
 423                         my @page_locs;
 424                         my $best_loc;
 425                         if (! defined $from || ! length $from ||
 426                             $from ne $form->field('from') ||
 427                             file_pruned($from, $config{srcdir}) ||
 428                             $from=~/^\// ||
 429                             $absolute ||
 430                             $form->submitted eq "Preview") {
 431                                 @page_locs=$best_loc=$page;
 432                         }
 433                         else {
 434                                 my $dir=$from."/";
 435                                 $dir=~s![^/]+/+$!!;
 436
 437                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 438                                     $page eq gettext('discussion')) {
 439                                         $best_loc="$from/$page";
 440                                 }
 441                                 else {
 442                                         $best_loc=$dir.$page;
 443                                 }
 444
 445                                 push @page_locs, $dir.$page;
 446                                 push @page_locs, "$from/$page";
 447                                 while (length $dir) {
 448                                         $dir=~s![^/]+/+$!!;
 449                                         push @page_locs, $dir.$page;
 450                                 }
 451
 452                                 push @page_locs, "$config{userdir}/$page"
 453                                         if length $config{userdir};
 454                         }
 455
 456                         @page_locs = grep {
 457                                 ! exists $pagecase{lc $_}
 458                         } @page_locs;
 459                         if (! @page_locs) {
 460                                 # hmm, someone else made the page in the
 461                                 # meantime?
 462                                 if ($form->submitted eq "Preview") {
 463                                         # let them go ahead with the edit
 464                                         # and resolve the conflict at save
 465                                         # time
 466                                         @page_locs=$page;
 467                                 }
 468                                 else {
 469                                         redirect($q, "$config{url}/".htmlpage($page));
 470                                         return;
 471                                 }
 472                         }
 473
 474                         my @editable_locs = grep {
 475                                 check_canedit($_, $q, $session, 1)
 476                         } @page_locs;
 477                         if (! @editable_locs) {
 478                                 # let it throw an error this time
 479                                 map { check_canedit($_, $q, $session) } @page_locs;
 480                         }
 481
 482                         my @page_types;
 483                         if (exists $hooks{htmlize}) {
 484                                 @page_types=grep { !/^_/ }
 485                                         keys %{$hooks{htmlize}};
 486                         }
 487
 488                         $form->tmpl_param("page_select", 1);
 489                         $form->field(name => "page", type => 'select',
 490                                 options => [ map { [ $_, pagetitle($_, 1) ] } @editable_locs ],
 491                                 value => $best_loc);
 492                         $form->field(name => "type", type => 'select',
 493                                 options => \@page_types);
 494                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 495
 496                 }
 497                 elsif ($form->field("do") eq "edit") {
 498                         check_canedit($page, $q, $session);
 499                         if (! defined $form->field('editcontent') ||
 500                             ! length $form->field('editcontent')) {
 501                                 my $content="";
 502                                 if (exists $pagesources{$page}) {
 503                                         $content=readfile(srcfile($pagesources{$page}));
 504                                         $content=~s/\n/\r\n/g;
 505                                 }
 506                                 $form->field(name => "editcontent", value => $content,
 507                                         force => 1);
 508                         }
 509                         $form->tmpl_param("page_select", 0);
 510                         $form->field(name => "page", type => 'hidden');
 511                         $form->field(name => "type", type => 'hidden');
 512                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 513                 }
 514
 515                 showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 516         }
 517         else {
 518                 # save page
 519                 check_canedit($page, $q, $session);
 520
 521                 # The session id is stored on the form and checked to
 522                 # guard against CSRF. But only if the user is logged in,
 523                 # as anonok can allow anonymous edits.
 524                 if (defined $session->param("name")) {
 525                         my $sid=$q->param('sid');
 526                         if (! defined $sid || $sid ne $session->id) {
 527                                 error(gettext("Your login session has expired."));
 528                         }
 529                 }
 530
 531                 my $exists=-e "$config{srcdir}/$file";
 532
 533                 if ($form->field("do") ne "create" && ! $exists &&
 534                     ! defined srcfile($file, 1)) {
 535                         $form->tmpl_param("message", template("editpagegone.tmpl")->output);
 536                         $form->field(name => "do", value => "create", force => 1);
 537                         $form->tmpl_param("page_select", 0);
 538                         $form->field(name => "page", type => 'hidden');
 539                         $form->field(name => "type", type => 'hidden');
 540                         $form->title(sprintf(gettext("editing %s"), $page));
 541                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 542                         return;
 543                 }
 544                 elsif ($form->field("do") eq "create" && $exists) {
 545                         $form->tmpl_param("message", template("editcreationconflict.tmpl")->output);
 546                         $form->field(name => "do", value => "edit", force => 1);
 547                         $form->tmpl_param("page_select", 0);
 548                         $form->field(name => "page", type => 'hidden');
 549                         $form->field(name => "type", type => 'hidden');
 550                         $form->title(sprintf(gettext("editing %s"), $page));
 551                         $form->field("editcontent",
 552                                 value => readfile("$config{srcdir}/$file").
 553                                          "\n\n\n".$form->field("editcontent"),
 554                                 force => 1);
 555                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 556                         return;
 557                 }
 558
 559                 my $content=$form->field('editcontent');
 560                 run_hooks(editcontent => sub {
 561                         $content=shift->(
 562                                 content => $content,
 563                                 page => $page,
 564                                 cgi => $q,
 565                                 session => $session,
 566                         );
 567                 });
 568                 $content=~s/\r\n/\n/g;
 569                 $content=~s/\r/\n/g;
 570                 $content.="\n" if $content !~ /\n$/;
 571
 572                 $config{cgi}=0; # avoid cgi error message
 573                 eval { writefile($file, $config{srcdir}, $content) };
 574                 $config{cgi}=1;
 575                 if ($@) {
 576                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 577                                 force => 1);
 578                         my $mtemplate=template("editfailedsave.tmpl");
 579                         $mtemplate->param(error_message => $@);
 580                         $form->tmpl_param("message", $mtemplate->output);
 581                         $form->field("editcontent", value => $content, force => 1);
 582                         $form->tmpl_param("page_select", 0);
 583                         $form->field(name => "page", type => 'hidden');
 584                         $form->field(name => "type", type => 'hidden');
 585                         $form->title(sprintf(gettext("editing %s"), $page));
 586                         showform($form, \@buttons, $session, $q,
 587                                 forcebaseurl => $baseurl);
 588                         return;
 589                 }
 590
 591                 my $conflict;
 592                 if ($config{rcs}) {
 593                         my $message="";
 594                         if (defined $form->field('comments') &&
 595                             length $form->field('comments')) {
 596                                 $message=$form->field('comments');
 597                         }
 598
 599                         if (! $exists) {
 600                                 rcs_add($file);
 601                         }
 602
 603                         # Prevent deadlock with post-commit hook by
 604                         # signaling to it that it should not try to
 605                         # do anything.
 606                         disable_commit_hook();
 607                         $conflict=rcs_commit($file, $message,
 608                                 $form->field("rcsinfo"),
 609                                 $session->param("name"), $ENV{REMOTE_ADDR});
 610                         enable_commit_hook();
 611                         rcs_update();
 612                 }
 613
 614                 # Refresh even if there was a conflict, since other changes
 615                 # may have been committed while the post-commit hook was
 616                 # disabled.
 617                 require IkiWiki::Render;
 618                 refresh();
 619                 saveindex();
 620
 621                 if (defined $conflict) {
 622                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 623                                 force => 1);
 624                         $form->tmpl_param("message", template("editconflict.tmpl")->output);
 625                         $form->field("editcontent", value => $conflict, force => 1);
 626                         $form->field("do", "edit", force => 1);
 627                         $form->tmpl_param("page_select", 0);
 628                         $form->field(name => "page", type => 'hidden');
 629                         $form->field(name => "type", type => 'hidden');
 630                         $form->title(sprintf(gettext("editing %s"), $page));
 631                         showform($form, \@buttons, $session, $q,
 632                                 forcebaseurl => $baseurl);
 633                         return;
 634                 }
 635                 else {
 636                         # The trailing question mark tries to avoid broken
 637                         # caches and get the most recent version of the page.
 638                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 639                 }
 640         }
 641 } #}}}
 642
 643 sub cgi_getsession ($) { #{{{
 644         my $q=shift;
 645
 646         eval q{use CGI::Session};
 647         error($@) if $@;
 648         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 649
 650         my $oldmask=umask(077);
 651         my $session = eval {
 652                 CGI::Session->new("driver:DB_File", $q,
 653                         { FileName => "$config{wikistatedir}/sessions.db" })
 654         };
 655         if (! $session || $@) {
 656                 error($@." ".CGI::Session->errstr());
 657         }
 658
 659         umask($oldmask);
 660
 661         return $session;
 662 } #}}}
 663
 664 sub cgi_savesession ($) { #{{{
 665         my $session=shift;
 666
 667         # Force session flush with safe umask.
 668         my $oldmask=umask(077);
 669         $session->flush;
 670         umask($oldmask);
 671 } #}}}
 672
 673 sub cgi (;$$) { #{{{
 674         my $q=shift;
 675         my $session=shift;
 676
 677         eval q{use CGI};
 678         error($@) if $@;
 679         $CGI::DISABLE_UPLOADS=$config{cgi_disable_uploads};
 680
 681         if (! $q) {
 682                 binmode(STDIN);
 683                 $q=CGI->new;
 684                 binmode(STDIN, ":utf8");
 685
 686                 run_hooks(cgi => sub { shift->($q) });
 687         }
 688
 689         my $do=$q->param('do');
 690         if (! defined $do || ! length $do) {
 691                 my $error = $q->cgi_error;
 692                 if ($error) {
 693                         error("Request not processed: $error");
 694                 }
 695                 else {
 696                         error("\"do\" parameter missing");
 697                 }
 698         }
 699
 700         # Need to lock the wiki before getting a session.
 701         lockwiki();
 702         loadindex();
 703
 704         if (! $session) {
 705                 $session=cgi_getsession($q);
 706         }
 707
 708         # Auth hooks can sign a user in.
 709         if ($do ne 'signin' && ! defined $session->param("name")) {
 710                 run_hooks(auth => sub {
 711                         shift->($q, $session)
 712                 });
 713                 if (defined $session->param("name")) {
 714                         # Make sure whatever user was authed is in the
 715                         # userinfo db.
 716                         if (! userinfo_get($session->param("name"), "regdate")) {
 717                                 userinfo_setall($session->param("name"), {
 718                                         email => "",
 719                                         password => "",
 720                                         regdate => time,
 721                                 }) || error("failed adding user");
 722                         }
 723                 }
 724         }
 725
 726         if (defined $session->param("name") &&
 727             userinfo_get($session->param("name"), "banned")) {
 728                 print $q->header(-status => "403 Forbidden");
 729                 $session->delete();
 730                 print gettext("You are banned.");
 731                 cgi_savesession($session);
 732         }
 733
 734         run_hooks(sessioncgi => sub { shift->($q, $session) });
 735
 736         if ($do eq 'signin') {
 737                 cgi_signin($q, $session);
 738                 cgi_savesession($session);
 739         }
 740         elsif ($do eq 'prefs') {
 741                 cgi_prefs($q, $session);
 742         }
 743         elsif ($do eq 'create' || $do eq 'edit') {
 744                 cgi_editpage($q, $session);
 745         }
 746         elsif (defined $session->param("postsignin") || $do eq 'postsignin') {
 747                 cgi_postsignin($q, $session);
 748         }
 749         else {
 750                 error("unknown do parameter");
 751         }
 752 } #}}}
 753
 754 # Does not need tobe called directly; all errors will go through here.
 755 sub cgierror ($) { #{{{
 756         my $message=shift;
 757
 758         print "Content-type: text/html\n\n";
 759         print misctemplate(gettext("Error"),
 760                 "<p class=\"error\">".gettext("Error").": $message</p>");
 761         die $@;
 762 } #}}}
 763
 764 1