git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use open qw{:utf8 :std};
   8
   9 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime
  10             %renderedfiles %pagesources %depends %hooks};
  11
  12 sub defaultconfig () { #{{{
  13         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$|\.rss$)},
  14         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  15         wiki_processor_regexp => qr/\[\[(\w+)\s+([^\]]*)\]\]/,
  16         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  17         verbose => 0,
  18         wikiname => "wiki",
  19         default_pageext => "mdwn",
  20         cgi => 0,
  21         rcs => 'svn',
  22         notify => 0,
  23         url => '',
  24         cgiurl => '',
  25         historyurl => '',
  26         diffurl => '',
  27         anonok => 0,
  28         rss => 0,
  29         discussion => 1,
  30         rebuild => 0,
  31         refresh => 0,
  32         getctime => 0,
  33         wrapper => undef,
  34         wrappermode => undef,
  35         svnrepo => undef,
  36         svnpath => "trunk",
  37         srcdir => undef,
  38         destdir => undef,
  39         pingurl => [],
  40         templatedir => "/usr/share/ikiwiki/templates",
  41         underlaydir => "/usr/share/ikiwiki/basewiki",
  42         setup => undef,
  43         adminuser => undef,
  44         adminemail => undef,
  45         plugin => [qw{mdwn inline htmlscrubber}],
  46         timeformat => '%c',
  47 } #}}}
  48
  49 sub checkconfig () { #{{{
  50         if ($config{cgi} && ! length $config{url}) {
  51                 error("Must specify url to wiki with --url when using --cgi\n");
  52         }
  53         if ($config{rss} && ! length $config{url}) {
  54                 error("Must specify url to wiki with --url when using --rss\n");
  55         }
  56
  57         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
  58                 unless exists $config{wikistatedir};
  59
  60         if ($config{rcs}) {
  61                 eval qq{require IkiWiki::Rcs::$config{rcs}};
  62                 if ($@) {
  63                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
  64                 }
  65         }
  66         else {
  67                 require IkiWiki::Rcs::Stub;
  68         }
  69
  70         foreach my $plugin (@{$config{plugin}}) {
  71                 my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
  72                 eval qq{use $mod};
  73                 if ($@) {
  74                         error("Failed to load plugin $mod: $@");
  75                 }
  76         }
  77
  78         if (exists $hooks{checkconfig}) {
  79                 foreach my $id (keys %{$hooks{checkconfig}}) {
  80                         $hooks{checkconfig}{$id}{call}->();
  81                 }
  82         }
  83 } #}}}
  84
  85 sub error ($) { #{{{
  86         if ($config{cgi}) {
  87                 print "Content-type: text/html\n\n";
  88                 print misctemplate("Error", "<p>Error: @_</p>");
  89         }
  90         die @_;
  91 } #}}}
  92
  93 sub debug ($) { #{{{
  94         return unless $config{verbose};
  95         if (! $config{cgi}) {
  96                 print "@_\n";
  97         }
  98         else {
  99                 print STDERR "@_\n";
 100         }
 101 } #}}}
 102
 103 sub possibly_foolish_untaint ($) { #{{{
 104         my $tainted=shift;
 105         my ($untainted)=$tainted=~/(.*)/;
 106         return $untainted;
 107 } #}}}
 108
 109 sub basename ($) { #{{{
 110         my $file=shift;
 111
 112         $file=~s!.*/+!!;
 113         return $file;
 114 } #}}}
 115
 116 sub dirname ($) { #{{{
 117         my $file=shift;
 118
 119         $file=~s!/*[^/]+$!!;
 120         return $file;
 121 } #}}}
 122
 123 sub pagetype ($) { #{{{
 124         my $page=shift;
 125
 126         if ($page =~ /\.([^.]+)$/) {
 127                 return $1 if exists $hooks{htmlize}{$1};
 128         }
 129         return undef;
 130 } #}}}
 131
 132 sub pagename ($) { #{{{
 133         my $file=shift;
 134
 135         my $type=pagetype($file);
 136         my $page=$file;
 137         $page=~s/\Q.$type\E*$// if defined $type;
 138         return $page;
 139 } #}}}
 140
 141 sub htmlpage ($) { #{{{
 142         my $page=shift;
 143
 144         return $page.".html";
 145 } #}}}
 146
 147 sub srcfile ($) { #{{{
 148         my $file=shift;
 149
 150         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 151         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 152         error("internal error: $file cannot be found");
 153 } #}}}
 154
 155 sub readfile ($;$) { #{{{
 156         my $file=shift;
 157         my $binary=shift;
 158
 159         if (-l $file) {
 160                 error("cannot read a symlink ($file)");
 161         }
 162
 163         local $/=undef;
 164         open (IN, $file) || error("failed to read $file: $!");
 165         binmode(IN) if ($binary);
 166         my $ret=<IN>;
 167         close IN;
 168         return $ret;
 169 } #}}}
 170
 171 sub writefile ($$$;$) { #{{{
 172         my $file=shift; # can include subdirs
 173         my $destdir=shift; # directory to put file in
 174         my $content=shift;
 175         my $binary=shift;
 176
 177         my $test=$file;
 178         while (length $test) {
 179                 if (-l "$destdir/$test") {
 180                         error("cannot write to a symlink ($test)");
 181                 }
 182                 $test=dirname($test);
 183         }
 184
 185         my $dir=dirname("$destdir/$file");
 186         if (! -d $dir) {
 187                 my $d="";
 188                 foreach my $s (split(m!/+!, $dir)) {
 189                         $d.="$s/";
 190                         if (! -d $d) {
 191                                 mkdir($d) || error("failed to create directory $d: $!");
 192                         }
 193                 }
 194         }
 195
 196         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 197         binmode(OUT) if ($binary);
 198         print OUT $content;
 199         close OUT;
 200 } #}}}
 201
 202 sub bestlink ($$) { #{{{
 203         # Given a page and the text of a link on the page, determine which
 204         # existing page that link best points to. Prefers pages under a
 205         # subdirectory with the same name as the source page, failing that
 206         # goes down the directory tree to the base looking for matching
 207         # pages.
 208         my $page=shift;
 209         my $link=lc(shift);
 210
 211         my $cwd=$page;
 212         do {
 213                 my $l=$cwd;
 214                 $l.="/" if length $l;
 215                 $l.=$link;
 216
 217                 if (exists $links{$l}) {
 218                         #debug("for $page, \"$link\", use $l");
 219                         return $l;
 220                 }
 221         } while $cwd=~s!/?[^/]+$!!;
 222
 223         #print STDERR "warning: page $page, broken link: $link\n";
 224         return "";
 225 } #}}}
 226
 227 sub isinlinableimage ($) { #{{{
 228         my $file=shift;
 229
 230         $file=~/\.(png|gif|jpg|jpeg)$/i;
 231 } #}}}
 232
 233 sub pagetitle ($) { #{{{
 234         my $page=shift;
 235         $page=~s/__(\d+)__/&#$1;/g;
 236         $page=~y/_/ /;
 237         return $page;
 238 } #}}}
 239
 240 sub titlepage ($) { #{{{
 241         my $title=shift;
 242         $title=~y/ /_/;
 243         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 244         return $title;
 245 } #}}}
 246
 247 sub cgiurl (@) { #{{{
 248         my %params=@_;
 249
 250         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 251 } #}}}
 252
 253 sub styleurl (;$) { #{{{
 254         my $page=shift;
 255
 256         return "$config{url}/style.css" if ! defined $page;
 257
 258         $page=~s/[^\/]+$//;
 259         $page=~s/[^\/]+\//..\//g;
 260         return $page."style.css";
 261 } #}}}
 262
 263 sub abs2rel ($$) {
 264         # Work around very innefficient behavior in File::Spec if abs2rel
 265         # is passed two relative paths. It's much faster if paths are
 266         # absolute!
 267         my $path="/".shift;
 268         my $base="/".shift;
 269
 270         require File::Spec;
 271         my $ret=File::Spec->abs2rel($path, $base);
 272         $ret=~s/^// if defined $ret;
 273         return $ret;
 274 }
 275
 276 sub htmllink ($$$;$$$) { #{{{
 277         my $lpage=shift; # the page doing the linking
 278         my $page=shift; # the page that will contain the link (different for inline)
 279         my $link=shift;
 280         my $noimageinline=shift; # don't turn links into inline html images
 281         my $forcesubpage=shift; # force a link to a subpage
 282         my $linktext=shift; # set to force the link text to something
 283
 284         my $bestlink;
 285         if (! $forcesubpage) {
 286                 $bestlink=bestlink($lpage, $link);
 287         }
 288         else {
 289                 $bestlink="$lpage/".lc($link);
 290         }
 291
 292         $linktext=pagetitle(basename($link)) unless defined $linktext;
 293
 294         return $linktext if length $bestlink && $page eq $bestlink;
 295
 296         # TODO BUG: %renderedfiles may not have it, if the linked to page
 297         # was also added and isn't yet rendered! Note that this bug is
 298         # masked by the bug that makes all new files be rendered twice.
 299         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 300                 $bestlink=htmlpage($bestlink);
 301         }
 302         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 303                 return "<span><a href=\"".
 304                         cgiurl(do => "create", page => $link, from => $page).
 305                         "\">?</a>$linktext</span>"
 306         }
 307
 308         $bestlink=abs2rel($bestlink, dirname($page));
 309
 310         if (! $noimageinline && isinlinableimage($bestlink)) {
 311                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 312         }
 313         return "<a href=\"$bestlink\">$linktext</a>";
 314 } #}}}
 315
 316 sub indexlink () { #{{{
 317         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 318 } #}}}
 319
 320 sub lockwiki () { #{{{
 321         # Take an exclusive lock on the wiki to prevent multiple concurrent
 322         # run issues. The lock will be dropped on program exit.
 323         if (! -d $config{wikistatedir}) {
 324                 mkdir($config{wikistatedir});
 325         }
 326         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 327                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 328         if (! flock(WIKILOCK, 2 | 4)) {
 329                 debug("wiki seems to be locked, waiting for lock");
 330                 my $wait=600; # arbitrary, but don't hang forever to
 331                               # prevent process pileup
 332                 for (1..600) {
 333                         return if flock(WIKILOCK, 2 | 4);
 334                         sleep 1;
 335                 }
 336                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 337         }
 338 } #}}}
 339
 340 sub unlockwiki () { #{{{
 341         close WIKILOCK;
 342 } #}}}
 343
 344 sub loadindex () { #{{{
 345         open (IN, "$config{wikistatedir}/index") || return;
 346         while (<IN>) {
 347                 $_=possibly_foolish_untaint($_);
 348                 chomp;
 349                 my %items;
 350                 $items{link}=[];
 351                 foreach my $i (split(/ /, $_)) {
 352                         my ($item, $val)=split(/=/, $i, 2);
 353                         push @{$items{$item}}, $val;
 354                 }
 355
 356                 next unless exists $items{src}; # skip bad lines for now
 357
 358                 my $page=pagename($items{src}[0]);
 359                 if (! $config{rebuild}) {
 360                         $pagesources{$page}=$items{src}[0];
 361                         $oldpagemtime{$page}=$items{mtime}[0];
 362                         $oldlinks{$page}=[@{$items{link}}];
 363                         $links{$page}=[@{$items{link}}];
 364                         $depends{$page}=join(" ", @{$items{depends}})
 365                                 if exists $items{depends};
 366                         $renderedfiles{$page}=$items{dest}[0];
 367                 }
 368                 $pagectime{$page}=$items{ctime}[0];
 369         }
 370         close IN;
 371 } #}}}
 372
 373 sub saveindex () { #{{{
 374         if (! -d $config{wikistatedir}) {
 375                 mkdir($config{wikistatedir});
 376         }
 377         open (OUT, ">$config{wikistatedir}/index") ||
 378                 error("cannot write to $config{wikistatedir}/index: $!");
 379         foreach my $page (keys %oldpagemtime) {
 380                 next unless $oldpagemtime{$page};
 381                 my $line="mtime=$oldpagemtime{$page} ".
 382                         "ctime=$pagectime{$page} ".
 383                         "src=$pagesources{$page} ".
 384                         "dest=$renderedfiles{$page}";
 385                 $line.=" link=$_" foreach @{$links{$page}};
 386                 if (exists $depends{$page}) {
 387                         $line.=" depends=$_" foreach split " ", $depends{$page};
 388                 }
 389                 print OUT $line."\n";
 390         }
 391         close OUT;
 392 } #}}}
 393
 394 sub template_params (@) { #{{{
 395         my $filename=shift;
 396
 397         require HTML::Template;
 398         return filter => sub {
 399                         my $text_ref = shift;
 400                         $$text_ref=&Encode::decode_utf8($$text_ref);
 401                 },
 402                 filename => "$config{templatedir}/$filename", @_;
 403 } #}}}
 404
 405 sub template ($;@) { #{{{
 406         HTML::Template->new(template_params(@_));
 407 } #}}}
 408
 409 sub misctemplate ($$) { #{{{
 410         my $title=shift;
 411         my $pagebody=shift;
 412
 413         my $template=template("misc.tmpl");
 414         $template->param(
 415                 title => $title,
 416                 indexlink => indexlink(),
 417                 wikiname => $config{wikiname},
 418                 pagebody => $pagebody,
 419                 styleurl => styleurl(),
 420                 baseurl => "$config{url}/",
 421         );
 422         return $template->output;
 423 }#}}}
 424
 425 sub glob_match ($$) { #{{{
 426         my $page=shift;
 427         my $glob=shift;
 428
 429         if ($glob =~ /^link\((.+)\)$/) {
 430                 my $rev = $links{$page} or return undef;
 431                 foreach my $p (@$rev) {
 432                         return 1 if lc $p eq $1;
 433                 }
 434                 return 0;
 435         } elsif ($glob =~ /^backlink\((.+)\)$/) {
 436                 my $rev = $links{$1} or return undef;
 437                 foreach my $p (@$rev) {
 438                         return 1 if lc $p eq $page;
 439                 }
 440                 return 0;
 441         } else {
 442                 # turn glob into safe regexp
 443                 $glob=quotemeta($glob);
 444                 $glob=~s/\\\*/.*/g;
 445                 $glob=~s/\\\?/./g;
 446                 $glob=~s!\\/!/!g;
 447
 448                 return $page=~/^$glob$/i;
 449         }
 450 } #}}}
 451
 452 sub globlist_match ($$) { #{{{
 453         my $page=shift;
 454         my @globlist=split(" ", shift);
 455
 456         # check any negated globs first
 457         foreach my $glob (@globlist) {
 458                 return 0 if $glob=~/^!(.*)/ && glob_match($page, $1);
 459         }
 460
 461         foreach my $glob (@globlist) {
 462                 return 1 if glob_match($page, $glob);
 463         }
 464
 465         return 0;
 466 } #}}}
 467
 468 sub hook (@) { # {{{
 469         my %param=@_;
 470
 471         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 472                 error "hook requires type, call, and id parameters";
 473         }
 474
 475         $hooks{$param{type}}{$param{id}}=\%param;
 476 } # }}}
 477
 478 1