git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render gettext
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version
  20
  21 # Optimisation.
  22 use Memoize;
  23 memoize("abs2rel");
  24 memoize("pagespec_translate");
  25 memoize("file_pruned");
  26
  27 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29
  30 sub defaultconfig () { #{{{
  31         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./, qr/\.x?html?$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => '',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         anonok => 0,
  48         rss => 0,
  49         atom => 0,
  50         discussion => 1,
  51         rebuild => 0,
  52         refresh => 0,
  53         getctime => 0,
  54         w3mmode => 0,
  55         wrapper => undef,
  56         wrappermode => undef,
  57         svnrepo => undef,
  58         svnpath => "trunk",
  59         srcdir => undef,
  60         destdir => undef,
  61         pingurl => [],
  62         templatedir => "$installdir/share/ikiwiki/templates",
  63         underlaydir => "$installdir/share/ikiwiki/basewiki",
  64         setup => undef,
  65         adminuser => undef,
  66         adminemail => undef,
  67         plugin => [qw{mdwn inline htmlscrubber passwordauth}],
  68         timeformat => '%c',
  69         locale => undef,
  70         sslcookie => 0,
  71         httpauth => 0,
  72         userdir => "",
  73 } #}}}
  74
  75 sub checkconfig () { #{{{
  76         # locale stuff; avoid LC_ALL since it overrides everything
  77         if (defined $ENV{LC_ALL}) {
  78                 $ENV{LANG} = $ENV{LC_ALL};
  79                 delete $ENV{LC_ALL};
  80         }
  81         if (defined $config{locale}) {
  82                 eval q{use POSIX};
  83                 error($@) if $@;
  84                 $ENV{LANG} = $config{locale}
  85                         if POSIX::setlocale(&POSIX::LC_TIME, $config{locale});
  86         }
  87
  88         if ($config{w3mmode}) {
  89                 eval q{use Cwd q{abs_path}};
  90                 error($@) if $@;
  91                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  92                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  93                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  94                         unless $config{cgiurl} =~ m!file:///!;
  95                 $config{url}="file://".$config{destdir};
  96         }
  97
  98         if ($config{cgi} && ! length $config{url}) {
  99                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{rcs}) {
 106                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 107                 if ($@) {
 108                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 109                 }
 110         }
 111         else {
 112                 require IkiWiki::Rcs::Stub;
 113         }
 114
 115         run_hooks(checkconfig => sub { shift->() });
 116 } #}}}
 117
 118 sub loadplugins () { #{{{
 119         loadplugin($_) foreach @{$config{plugin}};
 120
 121         run_hooks(getopt => sub { shift->() });
 122         if (grep /^-/, @ARGV) {
 123                 print STDERR "Unknown option: $_\n"
 124                         foreach grep /^-/, @ARGV;
 125                 usage();
 126         }
 127 } #}}}
 128
 129 sub loadplugin ($) { #{{{
 130         my $plugin=shift;
 131
 132         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 133
 134         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 135         eval qq{use $mod};
 136         if ($@) {
 137                 error("Failed to load plugin $mod: $@");
 138         }
 139 } #}}}
 140
 141 sub error ($) { #{{{
 142         if ($config{cgi}) {
 143                 print "Content-type: text/html\n\n";
 144                 print misctemplate(gettext("Error"),
 145                         "<p>".gettext("Error").": @_</p>");
 146         }
 147         log_message(error => @_);
 148         exit(1);
 149 } #}}}
 150
 151 sub debug ($) { #{{{
 152         return unless $config{verbose};
 153         log_message(debug => @_);
 154 } #}}}
 155
 156 my $log_open=0;
 157 sub log_message ($$) { #{{{
 158         my $type=shift;
 159
 160         if ($config{syslog}) {
 161                 require Sys::Syslog;
 162                 unless ($log_open) {
 163                         Sys::Syslog::setlogsock('unix');
 164                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 165                         $log_open=1;
 166                 }
 167                 eval {
 168                         Sys::Syslog::syslog($type, join(" ", @_));
 169                 }
 170         }
 171         elsif (! $config{cgi}) {
 172                 print "@_\n";
 173         }
 174         else {
 175                 print STDERR "@_\n";
 176         }
 177 } #}}}
 178
 179 sub possibly_foolish_untaint ($) { #{{{
 180         my $tainted=shift;
 181         my ($untainted)=$tainted=~/(.*)/;
 182         return $untainted;
 183 } #}}}
 184
 185 sub basename ($) { #{{{
 186         my $file=shift;
 187
 188         $file=~s!.*/+!!;
 189         return $file;
 190 } #}}}
 191
 192 sub dirname ($) { #{{{
 193         my $file=shift;
 194
 195         $file=~s!/*[^/]+$!!;
 196         return $file;
 197 } #}}}
 198
 199 sub pagetype ($) { #{{{
 200         my $page=shift;
 201
 202         if ($page =~ /\.([^.]+)$/) {
 203                 return $1 if exists $hooks{htmlize}{$1};
 204         }
 205         return undef;
 206 } #}}}
 207
 208 sub pagename ($) { #{{{
 209         my $file=shift;
 210
 211         my $type=pagetype($file);
 212         my $page=$file;
 213         $page=~s/\Q.$type\E*$// if defined $type;
 214         return $page;
 215 } #}}}
 216
 217 sub htmlpage ($) { #{{{
 218         my $page=shift;
 219
 220         return $page.".html";
 221 } #}}}
 222
 223 sub srcfile ($) { #{{{
 224         my $file=shift;
 225
 226         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 227         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 228         error("internal error: $file cannot be found");
 229 } #}}}
 230
 231 sub readfile ($;$) { #{{{
 232         my $file=shift;
 233         my $binary=shift;
 234
 235         if (-l $file) {
 236                 error("cannot read a symlink ($file)");
 237         }
 238
 239         local $/=undef;
 240         open (IN, $file) || error("failed to read $file: $!");
 241         binmode(IN) if ($binary);
 242         my $ret=<IN>;
 243         close IN;
 244         return $ret;
 245 } #}}}
 246
 247 sub writefile ($$$;$) { #{{{
 248         my $file=shift; # can include subdirs
 249         my $destdir=shift; # directory to put file in
 250         my $content=shift;
 251         my $binary=shift;
 252
 253         my $test=$file;
 254         while (length $test) {
 255                 if (-l "$destdir/$test") {
 256                         error("cannot write to a symlink ($test)");
 257                 }
 258                 $test=dirname($test);
 259         }
 260
 261         my $dir=dirname("$destdir/$file");
 262         if (! -d $dir) {
 263                 my $d="";
 264                 foreach my $s (split(m!/+!, $dir)) {
 265                         $d.="$s/";
 266                         if (! -d $d) {
 267                                 mkdir($d) || error("failed to create directory $d: $!");
 268                         }
 269                 }
 270         }
 271
 272         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 273         binmode(OUT) if ($binary);
 274         print OUT $content;
 275         close OUT;
 276 } #}}}
 277
 278 my %cleared;
 279 sub will_render ($$;$) { #{{{
 280         my $page=shift;
 281         my $dest=shift;
 282         my $clear=shift;
 283
 284         # Important security check.
 285         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 286             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 287                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 288         }
 289
 290         if (! $clear || $cleared{$page}) {
 291                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 292         }
 293         else {
 294                 $renderedfiles{$page}=[$dest];
 295                 $cleared{$page}=1;
 296         }
 297 } #}}}
 298
 299 sub bestlink ($$) { #{{{
 300         my $page=shift;
 301         my $link=shift;
 302
 303         my $cwd=$page;
 304         if ($link=~s/^\/+//) {
 305                 # absolute links
 306                 $cwd="";
 307         }
 308
 309         do {
 310                 my $l=$cwd;
 311                 $l.="/" if length $l;
 312                 $l.=$link;
 313
 314                 if (exists $links{$l}) {
 315                         return $l;
 316                 }
 317                 elsif (exists $pagecase{lc $l}) {
 318                         return $pagecase{lc $l};
 319                 }
 320         } while $cwd=~s!/?[^/]+$!!;
 321
 322         if (length $config{userdir} && exists $links{"$config{userdir}/".lc($link)}) {
 323                 return $links{"$config{userdir}/".lc($link)};
 324         }
 325
 326         #print STDERR "warning: page $page, broken link: $link\n";
 327         return "";
 328 } #}}}
 329
 330 sub isinlinableimage ($) { #{{{
 331         my $file=shift;
 332
 333         $file=~/\.(png|gif|jpg|jpeg)$/i;
 334 } #}}}
 335
 336 sub pagetitle ($;$) { #{{{
 337         my $page=shift;
 338         my $unescaped=shift;
 339
 340         if ($unescaped) {
 341                 $page=~s/__(\d+)__/chr($1)/eg;
 342         }
 343         else {
 344                 $page=~s/__(\d+)__/&#$1;/g;
 345         }
 346         $page=~y/_/ /;
 347
 348         return $page;
 349 } #}}}
 350
 351 sub titlepage ($) { #{{{
 352         my $title=shift;
 353         $title=~y/ /_/;
 354         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 355         return $title;
 356 } #}}}
 357
 358 sub cgiurl (@) { #{{{
 359         my %params=@_;
 360
 361         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 362 } #}}}
 363
 364 sub baseurl (;$) { #{{{
 365         my $page=shift;
 366
 367         return "$config{url}/" if ! defined $page;
 368
 369         $page=~s/[^\/]+$//;
 370         $page=~s/[^\/]+\//..\//g;
 371         return $page;
 372 } #}}}
 373
 374 sub abs2rel ($$) { #{{{
 375         # Work around very innefficient behavior in File::Spec if abs2rel
 376         # is passed two relative paths. It's much faster if paths are
 377         # absolute! (Debian bug #376658; fixed in debian unstable now)
 378         my $path="/".shift;
 379         my $base="/".shift;
 380
 381         require File::Spec;
 382         my $ret=File::Spec->abs2rel($path, $base);
 383         $ret=~s/^// if defined $ret;
 384         return $ret;
 385 } #}}}
 386
 387 sub displaytime ($) { #{{{
 388         my $time=shift;
 389
 390         eval q{use POSIX};
 391         error($@) if $@;
 392         # strftime doesn't know about encodings, so make sure
 393         # its output is properly treated as utf8
 394         return decode_utf8(POSIX::strftime(
 395                         $config{timeformat}, localtime($time)));
 396 } #}}}
 397
 398 sub htmllink ($$$;$$$) { #{{{
 399         my $lpage=shift; # the page doing the linking
 400         my $page=shift; # the page that will contain the link (different for inline)
 401         my $link=shift;
 402         my $noimageinline=shift; # don't turn links into inline html images
 403         my $forcesubpage=shift; # force a link to a subpage
 404         my $linktext=shift; # set to force the link text to something
 405
 406         my $bestlink;
 407         if (! $forcesubpage) {
 408                 $bestlink=bestlink($lpage, $link);
 409         }
 410         else {
 411                 $bestlink="$lpage/".lc($link);
 412         }
 413
 414         $linktext=pagetitle(basename($link)) unless defined $linktext;
 415
 416         return "<span class=\"selflink\">$linktext</span>"
 417                 if length $bestlink && $page eq $bestlink;
 418
 419         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 420                 $bestlink=htmlpage($bestlink);
 421         }
 422         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 423                 return $linktext unless length $config{cgiurl};
 424                 return "<span><a href=\"".
 425                         cgiurl(do => "create", page => lc($link), from => $page).
 426                         "\">?</a>$linktext</span>"
 427         }
 428
 429         $bestlink=abs2rel($bestlink, dirname($page));
 430
 431         if (! $noimageinline && isinlinableimage($bestlink)) {
 432                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 433         }
 434         return "<a href=\"$bestlink\">$linktext</a>";
 435 } #}}}
 436
 437 sub htmlize ($$$) { #{{{
 438         my $page=shift;
 439         my $type=shift;
 440         my $content=shift;
 441
 442         if (exists $hooks{htmlize}{$type}) {
 443                 $content=$hooks{htmlize}{$type}{call}->(
 444                         page => $page,
 445                         content => $content,
 446                 );
 447         }
 448         else {
 449                 error("htmlization of $type not supported");
 450         }
 451
 452         run_hooks(sanitize => sub {
 453                 $content=shift->(
 454                         page => $page,
 455                         content => $content,
 456                 );
 457         });
 458
 459         return $content;
 460 } #}}}
 461
 462 sub linkify ($$$) { #{{{
 463         my $lpage=shift; # the page containing the links
 464         my $page=shift; # the page the link will end up on (different for inline)
 465         my $content=shift;
 466
 467         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 468                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 469                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 470         }eg;
 471
 472         return $content;
 473 } #}}}
 474
 475 my %preprocessing;
 476 sub preprocess ($$$;$) { #{{{
 477         my $page=shift; # the page the data comes from
 478         my $destpage=shift; # the page the data will appear in (different for inline)
 479         my $content=shift;
 480         my $scan=shift;
 481
 482         my $handle=sub {
 483                 my $escape=shift;
 484                 my $command=shift;
 485                 my $params=shift;
 486                 if (length $escape) {
 487                         return "[[$command $params]]";
 488                 }
 489                 elsif (exists $hooks{preprocess}{$command}) {
 490                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 491                         # Note: preserve order of params, some plugins may
 492                         # consider it significant.
 493                         my @params;
 494                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 495                                 my $key=$1;
 496                                 my $val;
 497                                 if (defined $2) {
 498                                         $val=$2;
 499                                         $val=~s/\r\n/\n/mg;
 500                                         $val=~s/^\n+//g;
 501                                         $val=~s/\n+$//g;
 502                                 }
 503                                 elsif (defined $3) {
 504                                         $val=$3;
 505                                 }
 506                                 elsif (defined $4) {
 507                                         $val=$4;
 508                                 }
 509
 510                                 if (defined $key) {
 511                                         push @params, $key, $val;
 512                                 }
 513                                 else {
 514                                         push @params, $val, '';
 515                                 }
 516                         }
 517                         if ($preprocessing{$page}++ > 3) {
 518                                 # Avoid loops of preprocessed pages preprocessing
 519                                 # other pages that preprocess them, etc.
 520                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 521                                         $command, $page, $preprocessing{$page}).
 522                                 "]]";
 523                         }
 524                         my $ret=$hooks{preprocess}{$command}{call}->(
 525                                 @params,
 526                                 page => $page,
 527                                 destpage => $destpage,
 528                         );
 529                         $preprocessing{$page}--;
 530                         return $ret;
 531                 }
 532                 else {
 533                         return "[[$command $params]]";
 534                 }
 535         };
 536
 537         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 538         return $content;
 539 } #}}}
 540
 541 sub filter ($$) { #{{{
 542         my $page=shift;
 543         my $content=shift;
 544
 545         run_hooks(filter => sub {
 546                 $content=shift->(page => $page, content => $content);
 547         });
 548
 549         return $content;
 550 } #}}}
 551
 552 sub indexlink () { #{{{
 553         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 554 } #}}}
 555
 556 sub lockwiki () { #{{{
 557         # Take an exclusive lock on the wiki to prevent multiple concurrent
 558         # run issues. The lock will be dropped on program exit.
 559         if (! -d $config{wikistatedir}) {
 560                 mkdir($config{wikistatedir});
 561         }
 562         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 563                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 564         if (! flock(WIKILOCK, 2 | 4)) {
 565                 debug("wiki seems to be locked, waiting for lock");
 566                 my $wait=600; # arbitrary, but don't hang forever to
 567                               # prevent process pileup
 568                 for (1..600) {
 569                         return if flock(WIKILOCK, 2 | 4);
 570                         sleep 1;
 571                 }
 572                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 573         }
 574 } #}}}
 575
 576 sub unlockwiki () { #{{{
 577         close WIKILOCK;
 578 } #}}}
 579
 580 sub loadindex () { #{{{
 581         open (IN, "$config{wikistatedir}/index") || return;
 582         while (<IN>) {
 583                 $_=possibly_foolish_untaint($_);
 584                 chomp;
 585                 my %items;
 586                 $items{link}=[];
 587                 $items{dest}=[];
 588                 foreach my $i (split(/ /, $_)) {
 589                         my ($item, $val)=split(/=/, $i, 2);
 590                         push @{$items{$item}}, decode_entities($val);
 591                 }
 592
 593                 next unless exists $items{src}; # skip bad lines for now
 594
 595                 my $page=pagename($items{src}[0]);
 596                 if (! $config{rebuild}) {
 597                         $pagesources{$page}=$items{src}[0];
 598                         $oldpagemtime{$page}=$items{mtime}[0];
 599                         $oldlinks{$page}=[@{$items{link}}];
 600                         $links{$page}=[@{$items{link}}];
 601                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 602                         $renderedfiles{$page}=[@{$items{dest}}];
 603                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 604                         $pagecase{lc $page}=$page;
 605                 }
 606                 $pagectime{$page}=$items{ctime}[0];
 607         }
 608         close IN;
 609 } #}}}
 610
 611 sub saveindex () { #{{{
 612         run_hooks(savestate => sub { shift->() });
 613
 614         if (! -d $config{wikistatedir}) {
 615                 mkdir($config{wikistatedir});
 616         }
 617         open (OUT, ">$config{wikistatedir}/index") ||
 618                 error("cannot write to $config{wikistatedir}/index: $!");
 619         foreach my $page (keys %oldpagemtime) {
 620                 next unless $oldpagemtime{$page};
 621                 my $line="mtime=$oldpagemtime{$page} ".
 622                         "ctime=$pagectime{$page} ".
 623                         "src=$pagesources{$page}";
 624                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 625                 my %count;
 626                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 627                 if (exists $depends{$page}) {
 628                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 629                 }
 630                 print OUT $line."\n";
 631         }
 632         close OUT;
 633 } #}}}
 634
 635 sub template_params (@) { #{{{
 636         my $filename=shift;
 637
 638         require HTML::Template;
 639         return filter => sub {
 640                         my $text_ref = shift;
 641                         $$text_ref=&Encode::decode_utf8($$text_ref);
 642                 },
 643                 filename => "$config{templatedir}/$filename",
 644                 loop_context_vars => 1,
 645                 die_on_bad_params => 0,
 646                 @_;
 647 } #}}}
 648
 649 sub template ($;@) { #{{{
 650         HTML::Template->new(template_params(@_));
 651 } #}}}
 652
 653 sub misctemplate ($$;@) { #{{{
 654         my $title=shift;
 655         my $pagebody=shift;
 656
 657         my $template=template("misc.tmpl");
 658         $template->param(
 659                 title => $title,
 660                 indexlink => indexlink(),
 661                 wikiname => $config{wikiname},
 662                 pagebody => $pagebody,
 663                 baseurl => baseurl(),
 664                 @_,
 665         );
 666         run_hooks(pagetemplate => sub {
 667                 shift->(page => "", destpage => "", template => $template);
 668         });
 669         return $template->output;
 670 }#}}}
 671
 672 sub hook (@) { # {{{
 673         my %param=@_;
 674
 675         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 676                 error "hook requires type, call, and id parameters";
 677         }
 678
 679         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 680
 681         $hooks{$param{type}}{$param{id}}=\%param;
 682 } # }}}
 683
 684 sub run_hooks ($$) { # {{{
 685         # Calls the given sub for each hook of the given type,
 686         # passing it the hook function to call.
 687         my $type=shift;
 688         my $sub=shift;
 689
 690         if (exists $hooks{$type}) {
 691                 my @deferred;
 692                 foreach my $id (keys %{$hooks{$type}}) {
 693                         if ($hooks{$type}{$id}{last}) {
 694                                 push @deferred, $id;
 695                                 next;
 696                         }
 697                         $sub->($hooks{$type}{$id}{call});
 698                 }
 699                 foreach my $id (@deferred) {
 700                         $sub->($hooks{$type}{$id}{call});
 701                 }
 702         }
 703 } #}}}
 704
 705 sub globlist_to_pagespec ($) { #{{{
 706         my @globlist=split(' ', shift);
 707
 708         my (@spec, @skip);
 709         foreach my $glob (@globlist) {
 710                 if ($glob=~/^!(.*)/) {
 711                         push @skip, $glob;
 712                 }
 713                 else {
 714                         push @spec, $glob;
 715                 }
 716         }
 717
 718         my $spec=join(" or ", @spec);
 719         if (@skip) {
 720                 my $skip=join(" and ", @skip);
 721                 if (length $spec) {
 722                         $spec="$skip and ($spec)";
 723                 }
 724                 else {
 725                         $spec=$skip;
 726                 }
 727         }
 728         return $spec;
 729 } #}}}
 730
 731 sub is_globlist ($) { #{{{
 732         my $s=shift;
 733         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 734 } #}}}
 735
 736 sub safequote ($) { #{{{
 737         my $s=shift;
 738         $s=~s/[{}]//g;
 739         return "q{$s}";
 740 } #}}}
 741
 742 sub pagespec_merge ($$) { #{{{
 743         my $a=shift;
 744         my $b=shift;
 745
 746         return $a if $a eq $b;
 747
 748         # Support for old-style GlobLists.
 749         if (is_globlist($a)) {
 750                 $a=globlist_to_pagespec($a);
 751         }
 752         if (is_globlist($b)) {
 753                 $b=globlist_to_pagespec($b);
 754         }
 755
 756         return "($a) or ($b)";
 757 } #}}}
 758
 759 sub pagespec_translate ($) { #{{{
 760         # This assumes that $page is in scope in the function
 761         # that evalulates the translated pagespec code.
 762         my $spec=shift;
 763
 764         # Support for old-style GlobLists.
 765         if (is_globlist($spec)) {
 766                 $spec=globlist_to_pagespec($spec);
 767         }
 768
 769         # Convert spec to perl code.
 770         my $code="";
 771         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 772                 my $word=$1;
 773                 if (lc $word eq "and") {
 774                         $code.=" &&";
 775                 }
 776                 elsif (lc $word eq "or") {
 777                         $code.=" ||";
 778                 }
 779                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 780                         $code.=" ".$word;
 781                 }
 782                 elsif ($word =~ /^(link|backlink|created_before|created_after|creation_month|creation_year|creation_day)\((.+)\)$/) {
 783                         $code.=" match_$1(\$page, ".safequote($2).")";
 784                 }
 785                 else {
 786                         $code.=" match_glob(\$page, ".safequote($word).")";
 787                 }
 788         }
 789
 790         return $code;
 791 } #}}}
 792
 793 sub add_depends ($$) { #{{{
 794         my $page=shift;
 795         my $pagespec=shift;
 796
 797         if (! exists $depends{$page}) {
 798                 $depends{$page}=$pagespec;
 799         }
 800         else {
 801                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 802         }
 803 } # }}}
 804
 805 sub file_pruned ($$) { #{{{
 806         require File::Spec;
 807         my $file=File::Spec->canonpath(shift);
 808         my $base=File::Spec->canonpath(shift);
 809         $file=~s#^\Q$base\E/*##;
 810
 811         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 812         $file =~ m/$regexp/;
 813 } #}}}
 814
 815 sub gettext { #{{{
 816         # Only use gettext in the rare cases it's needed.
 817         # This overrides future calls of this function.
 818         if (exists $ENV{LANG} || exists $ENV{LC_ALL} || exists $ENV{LC_MESSAGES}) {
 819                 eval q{use Locale::gettext};
 820                 textdomain('ikiwiki');
 821                 return Locale::gettext::gettext(shift);
 822         }
 823         else {
 824                 return shift;
 825         }
 826 } #}}}
 827
 828 sub pagespec_match ($$) { #{{{
 829         my $page=shift;
 830         my $spec=shift;
 831
 832         return eval pagespec_translate($spec);
 833 } #}}}
 834
 835 sub match_glob ($$) { #{{{
 836         my $page=shift;
 837         my $glob=shift;
 838
 839         # turn glob into safe regexp
 840         $glob=quotemeta($glob);
 841         $glob=~s/\\\*/.*/g;
 842         $glob=~s/\\\?/./g;
 843
 844         return $page=~/^$glob$/i;
 845 } #}}}
 846
 847 sub match_link ($$) { #{{{
 848         my $page=shift;
 849         my $link=lc(shift);
 850
 851         my $links = $links{$page} or return undef;
 852         foreach my $p (@$links) {
 853                 return 1 if lc $p eq $link;
 854         }
 855         return 0;
 856 } #}}}
 857
 858 sub match_backlink ($$) { #{{{
 859         match_link(pop, pop);
 860 } #}}}
 861
 862 sub match_created_before ($$) { #{{{
 863         my $page=shift;
 864         my $testpage=shift;
 865
 866         if (exists $pagectime{$testpage}) {
 867                 return $pagectime{$page} < $pagectime{$testpage};
 868         }
 869         else {
 870                 return 0;
 871         }
 872 } #}}}
 873
 874 sub match_created_after ($$) { #{{{
 875         my $page=shift;
 876         my $testpage=shift;
 877
 878         if (exists $pagectime{$testpage}) {
 879                 return $pagectime{$page} > $pagectime{$testpage};
 880         }
 881         else {
 882                 return 0;
 883         }
 884 } #}}}
 885
 886 sub match_creation_day ($$) { #{{{
 887         return ((gmtime($pagectime{shift()}))[3] == shift);
 888 } #}}}
 889
 890 sub match_creation_month ($$) { #{{{
 891         return ((gmtime($pagectime{shift()}))[4] + 1 == shift);
 892 } #}}}
 893
 894 sub match_creation_year ($$) { #{{{
 895         return ((gmtime($pagectime{shift()}))[5] + 1900 == shift);
 896 } #}}}
 897
 898 1