From 8322b8c9c82941c4052bcc8a0d1824a92d6426a0 Mon Sep 17 00:00:00 2001
From: Simon McVittie <smcv@ http://smcv.pseudorandom.co.uk/>
Date: Sat, 31 Jan 2009 18:07:42 +0000
Subject: [PATCH] CGI: add cgi_page_from_404(), which remaps a path like
 $REDIRECT_URL to an IkiWiki page name

Also add a regression test
---
 IkiWiki/CGI.pm        | 40 ++++++++++++++++++++++++++++++++++++++++
 t/cgi_page_from_404.t | 43 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100755 t/cgi_page_from_404.t

diff --git a/IkiWiki/CGI.pm b/IkiWiki/CGI.pm
index fe8457262..82cad40c8 100644
--- a/IkiWiki/CGI.pm
+++ b/IkiWiki/CGI.pm
@@ -332,6 +332,46 @@ sub cgi_goto ($;$) {
 	exit;
 }
 
+sub cgi_page_from_404 ($$$) {
+	my $path = shift;
+	my $baseurl = shift;
+	my $usedirs = shift;
+
+	# fail if missing from environment or whatever
+	return undef unless defined $path;
+	return undef unless defined $baseurl;
+
+	# with usedirs on, path is like /~fred/foo/bar/ or /~fred/foo/bar or
+	#    /~fred/foo/bar/index.html
+	# with usedirs off, path is like /~fred/foo/bar.html
+	# baseurl is like 'http://people.example.com/~fred'
+
+	# convert baseurl to ~fred
+	unless ($baseurl =~ s{^https?://[^/]+/?}{}) {
+		return undef;
+	}
+
+	# convert path to /~fred/foo/bar
+	if ($usedirs) {
+		$path =~ s/\/*(?:index\.$config{htmlext})?$//;
+	}
+	else {
+		$path =~ s/\.$config{htmlext}$//;
+	}
+
+	# remove /~fred/
+	unless ($path =~ s{^/*\Q$baseurl\E/*}{}) {
+		return undef;
+	}
+
+	# special case for the index
+	unless ($path) {
+		return 'index';
+	}
+
+	return $path;
+}
+
 sub cgi (;$$) {
 	my $q=shift;
 	my $session=shift;
diff --git a/t/cgi_page_from_404.t b/t/cgi_page_from_404.t
new file mode 100755
index 000000000..adbbdf874
--- /dev/null
+++ b/t/cgi_page_from_404.t
@@ -0,0 +1,43 @@
+#!/usr/bin/perl
+use warnings;
+use strict;
+use Test::More tests => 18;
+
+BEGIN { use_ok("IkiWiki"); }
+BEGIN { use_ok("IkiWiki::CGI"); }
+
+sub cgi_page_from_404 { return IkiWiki::cgi_page_from_404(shift, shift, shift); }
+
+$IkiWiki::config{htmlext} = 'html';
+
+is(cgi_page_from_404('/', 'http://example.com', 1), 'index');
+is(cgi_page_from_404('/index.html', 'http://example.com', 0), 'index');
+is(cgi_page_from_404('/', 'http://example.com/', 1), 'index');
+is(cgi_page_from_404('/index.html', 'http://example.com/', 0), 'index');
+
+is(cgi_page_from_404('/~user/foo/bar', 'http://example.com/~user', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar/index.html', 'http://example.com/~user', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar/', 'http://example.com/~user', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar.html', 'http://example.com/~user', 0),
+   'foo/bar');
+
+is(cgi_page_from_404('/~user/foo/bar', 'http://example.com/~user/', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar/index.html', 'http://example.com/~user/', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar/', 'http://example.com/~user/', 1),
+   'foo/bar');
+is(cgi_page_from_404('/~user/foo/bar.html', 'http://example.com/~user/', 0),
+   'foo/bar');
+
+is(cgi_page_from_404('/~user/foo', 'https://example.com/~user', 1),
+   'foo');
+is(cgi_page_from_404('/~user/foo/index.html', 'https://example.com/~user', 1),
+   'foo');
+is(cgi_page_from_404('/~user/foo/', 'https://example.com/~user', 1),
+   'foo');
+is(cgi_page_from_404('/~user/foo.html', 'https://example.com/~user', 0),
+   'foo');
-- 
2.32.0.93.g670b81a890