Pre-release PO sync
[xorg/xkeyboard-config] / configure.in
1 AC_INIT(xkeyboard-config, 2.4.1)
2 AC_CONFIG_SRCDIR(rules/base.xml.in)
3 AM_INIT_AUTOMAKE([foreign dist-bzip2])
4 AM_MAINTAINER_MODE
5
6 # Require X.Org macros 1.12 or later for XORG_WITH_XSLTPROC
7 m4_ifndef([XORG_MACROS_VERSION],
8           [m4_fatal([must install xorg-macros 1.12 or later before
9           running autoconf/autogen])])
10 XORG_MACROS_VERSION(1.12)
11 XORG_MANPAGE_SECTIONS
12 XORG_WITH_XSLTPROC
13 AC_PROG_SED
14
15 AC_SUBST(VERSION)
16
17 AC_PATH_PROG([XKBCOMP], [xkbcomp], [not_found])
18 if test x$XKBCOMP = xnot_found ; then
19         AC_ERROR([xkbcomp is required to install the xkb data files])
20 fi
21
22 AC_ARG_WITH( xkb_base,
23              [AS_HELP_STRING([--with-xkb-base=DIR],[XKB base path @<:@DATADIR/X11/xkb@:>@])],
24              xkb_base="$withval", 
25              xkb_base="${datadir}/X11/xkb" )
26
27 AC_ARG_WITH( xkb_rules_symlink,
28              [  --with-xkb-rules-symlink=NAME1(,NAME2)*        create symlink(s) to "old style" rules files (xfree86 and/or xorg)],
29              xkb_rules_symlink="$withval" )
30
31 AC_ARG_ENABLE( compat_rules,
32                [  --enable-compat-rules      create compatibility rules],
33                enable_compat_rules="$enableval",
34                enable_compat_rules="yes" )
35
36 # xkeyboard-config does not have build-time dependencies. However, it does
37 # have run-time dependencies and keyboard layouts may not work without the
38 # right libX11 or xproto installed.
39 # By default, we enable these run-time dependencies as build-time
40 # dependencies so that those building on their local machines are warned
41 # that the resulting build may not work.
42 AC_ARG_ENABLE( runtime-deps,
43                [ --enable-runtime-deps    use run-time dependencies as build-time dependencies],
44                enable_runtime_deps="$enableval",
45                enable_runtime_deps="yes")
46
47 if test "x$enable_runtime_deps" = "xyes"; then
48     PKG_CHECK_MODULES(DEPS, [xproto >= 7.0.20] [x11 >= 1.4.3], [have_deps=yes], [have_deps=no])
49     if test "x$have_deps" = "xno" ; then
50         AC_MSG_WARN([
51                  Required dependencies not found. These dependencies are
52                  run-time dependencies only and not required for building.
53                  Skip this check with --disable-runtime-deps.
54
55                  Installing this version of xkeyboard-config on a host
56                  without the required dependencies may result in unusable
57                  keyboard layouts.
58                  ])
59
60         AC_MSG_ERROR([$DEPS_PKG_ERRORS])
61     fi
62 fi
63
64 AM_CONDITIONAL(CREATE_RULES_SYMLINK, test "x$xkb_rules_symlink" != "x")
65
66 AM_CONDITIONAL(USE_COMPAT_RULES, test "x$enable_compat_rules" = "xyes")
67
68 # ****
69 # i18n
70 # ****
71 AC_PROG_INTLTOOL(0.30)
72
73 GETTEXT_PACKAGE=xkeyboard-config
74 AC_SUBST(GETTEXT_PACKAGE)
75 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
76
77 AM_GLIB_GNU_GETTEXT
78
79 ALL_LINGUAS="af az bg ca crh cs da de el en_GB eo es fi fr gl hu id it ja ka ko ky lt nb nl pl ro ru rw sk sl sq sr sv tr uk vi zh_CN zh_TW"
80
81 AC_SUBST(xkb_base)
82 AC_SUBST(xkb_rules_symlink)
83
84 AC_OUTPUT([ po/Makefile.in
85 Makefile
86 compat/Makefile
87 geometry/Makefile
88 geometry/digital_vndr/Makefile
89 geometry/sgi_vndr/Makefile
90 keycodes/Makefile
91 keycodes/digital_vndr/Makefile
92 keycodes/sgi_vndr/Makefile
93 keymap/Makefile
94 keymap/digital_vndr/Makefile
95 keymap/sgi_vndr/Makefile
96 keymap/sun_vndr/Makefile
97 semantics/Makefile
98 rules/Makefile
99 rules/bin/Makefile
100 rules/compat/Makefile
101 symbols/Makefile
102 symbols/digital_vndr/Makefile
103 symbols/fujitsu_vndr/Makefile
104 symbols/hp_vndr/Makefile
105 symbols/macintosh_vndr/Makefile
106 symbols/nec_vndr/Makefile
107 symbols/nokia_vndr/Makefile
108 symbols/sgi_vndr/Makefile
109 symbols/sony_vndr/Makefile
110 symbols/sun_vndr/Makefile
111 symbols/xfree68_vndr/Makefile
112 types/Makefile
113 xkeyboard-config.pc
114 docs/Makefile
115 man/Makefile
116 ])
117
118 echo '***********************************************************'
119 echo "  $PACKAGE_NAME is configured with the following parameters:"
120 echo "    XKB base directory: $xkb_base"
121 if test -z "$xkb_rules_symlink" ; then
122   echo "    Symbolic link(s) to legacy rules are not created"
123 else
124   echo "    Symbolic link(s) to legacy rules: $xkb_rules_symlink"
125 fi
126
127 if test "$enable_compat_rules" = "yes" ; then
128   echo "    Compatibility rules are included"
129 else
130   echo "    Compatibility rules are not included"
131 fi
132 echo '***********************************************************'
133