git.oblomov.eu Git - xorg/xkeyboard-config/blob - configure.in

   1 AC_INIT(xkeyboard-config, 2.6)
   2 AC_CONFIG_SRCDIR(rules/base.xml.in)
   3 AM_INIT_AUTOMAKE([foreign dist-bzip2])
   4 AM_MAINTAINER_MODE
   5
   6 # Require X.Org macros 1.12 or later for XORG_WITH_XSLTPROC
   7 m4_ifndef([XORG_MACROS_VERSION],
   8           [m4_fatal([must install xorg-macros 1.12 or later before
   9           running autoconf/autogen])])
  10 XORG_MACROS_VERSION(1.12)
  11 XORG_MANPAGE_SECTIONS
  12 XORG_WITH_XSLTPROC
  13 AC_PROG_SED
  14
  15 AC_SUBST(VERSION)
  16
  17 AC_ARG_WITH( xkb_base,
  18              [AS_HELP_STRING([--with-xkb-base=DIR],[XKB base path @<:@DATADIR/X11/xkb@:>@])],
  19              xkb_base="$withval",
  20              xkb_base="${datadir}/X11/xkb" )
  21
  22 AC_ARG_WITH( xkb_rules_symlink,
  23              [  --with-xkb-rules-symlink=NAME1(,NAME2)*        create symlink(s) to "old style" rules files (xfree86 and/or xorg)],
  24              xkb_rules_symlink="$withval" )
  25
  26 AC_ARG_ENABLE( compat_rules,
  27                [  --enable-compat-rules      create compatibility rules],
  28                enable_compat_rules="$enableval",
  29                enable_compat_rules="yes" )
  30
  31 # xkeyboard-config does not have build-time dependencies. However, it does
  32 # have run-time dependencies and keyboard layouts may not work without the
  33 # right libX11 or xproto installed.
  34 # By default, we enable these run-time dependencies as build-time
  35 # dependencies so that those building on their local machines are warned
  36 # that the resulting build may not work.
  37 AC_ARG_ENABLE( runtime-deps,
  38                [ --enable-runtime-deps    use run-time dependencies as build-time dependencies],
  39                enable_runtime_deps="$enableval",
  40                enable_runtime_deps="yes")
  41
  42 if test "x$enable_runtime_deps" = "xyes"; then
  43     PKG_CHECK_MODULES(DEPS, [xproto >= 7.0.20] [x11 >= 1.4.3], [have_deps=yes], [have_deps=no])
  44     if test "x$have_deps" = "xno" ; then
  45         AC_MSG_WARN([
  46                  Required dependencies not found. These dependencies are
  47                  run-time dependencies only and not required for building.
  48                  Skip this check with --disable-runtime-deps.
  49
  50                  Installing this version of xkeyboard-config on a host
  51                  without the required dependencies may result in unusable
  52                  keyboard layouts.
  53                  ])
  54
  55         AC_MSG_ERROR([$DEPS_PKG_ERRORS])
  56     fi
  57 fi
  58
  59 AM_CONDITIONAL(CREATE_RULES_SYMLINK, test "x$xkb_rules_symlink" != "x")
  60
  61 AM_CONDITIONAL(USE_COMPAT_RULES, test "x$enable_compat_rules" = "xyes")
  62
  63 # ****
  64 # i18n
  65 # ****
  66 AC_PROG_INTLTOOL(0.30)
  67
  68 AM_GNU_GETTEXT_VERSION([0.18.1])
  69 AM_GNU_GETTEXT([external])
  70
  71 GETTEXT_PACKAGE=xkeyboard-config
  72 AC_SUBST(GETTEXT_PACKAGE)
  73 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
  74
  75 ALL_LINGUAS="af az bg ca crh cs da de el en_GB eo es fi fr gl hu id it ja ka ko ky lt nb nl pl ro ru rw sk sl sq sr sv tr uk vi zh_CN zh_TW"
  76
  77 AC_SUBST(xkb_base)
  78 AC_SUBST(xkb_rules_symlink)
  79
  80 AC_OUTPUT([ po/Makefile.in
  81 Makefile
  82 compat/Makefile
  83 geometry/Makefile
  84 geometry/digital_vndr/Makefile
  85 geometry/sgi_vndr/Makefile
  86 keycodes/Makefile
  87 keycodes/digital_vndr/Makefile
  88 keycodes/sgi_vndr/Makefile
  89 rules/Makefile
  90 rules/bin/Makefile
  91 rules/compat/Makefile
  92 symbols/Makefile
  93 symbols/digital_vndr/Makefile
  94 symbols/fujitsu_vndr/Makefile
  95 symbols/hp_vndr/Makefile
  96 symbols/macintosh_vndr/Makefile
  97 symbols/nec_vndr/Makefile
  98 symbols/nokia_vndr/Makefile
  99 symbols/sgi_vndr/Makefile
 100 symbols/sony_vndr/Makefile
 101 symbols/sun_vndr/Makefile
 102 symbols/xfree68_vndr/Makefile
 103 types/Makefile
 104 xkeyboard-config.pc
 105 docs/Makefile
 106 man/Makefile
 107 ])
 108
 109 echo '***********************************************************'
 110 echo "  $PACKAGE_NAME is configured with the following parameters:"
 111 echo "    XKB base directory: $xkb_base"
 112 if test -z "$xkb_rules_symlink" ; then
 113   echo "    Symbolic link(s) to legacy rules are not created"
 114 else
 115   echo "    Symbolic link(s) to legacy rules: $xkb_rules_symlink"
 116 fi
 117
 118 if test "$enable_compat_rules" = "yes" ; then
 119   echo "    Compatibility rules are included"
 120 else
 121   echo "    Compatibility rules are not included"
 122 fi
 123 echo '***********************************************************'
 124