git.oblomov.eu Git - xorg/xkeyboard-config/blob - configure.in

   1 AC_INIT(xkeyboard-config, 2.3.99)
   2 AC_CONFIG_SRCDIR(rules/base.xml.in)
   3 AM_INIT_AUTOMAKE([foreign dist-bzip2])
   4 AM_MAINTAINER_MODE
   5
   6 AC_SUBST(VERSION)
   7
   8 AC_PATH_PROG([XKBCOMP], [xkbcomp], [not_found])
   9 if test x$XKBCOMP = xnot_found ; then
  10         AC_ERROR([xkbcomp is required to install the xkb data files])
  11 fi
  12
  13 AC_ARG_WITH( xkb_base,
  14              [AS_HELP_STRING([--with-xkb-base=DIR],[XKB base path @<:@DATADIR/X11/xkb@:>@])],
  15              xkb_base="$withval",
  16              xkb_base="${datadir}/X11/xkb" )
  17
  18 AC_ARG_WITH( xkb_rules_symlink,
  19              [  --with-xkb-rules-symlink=NAME1(,NAME2)*        create symlink(s) to "old style" rules files (xfree86 and/or xorg)],
  20              xkb_rules_symlink="$withval" )
  21
  22 AC_ARG_ENABLE( compat_rules,
  23                [  --enable-compat-rules      create compatibility rules],
  24                enable_compat_rules="$enableval",
  25                enable_compat_rules="yes" )
  26
  27 # xkeyboard-config does not have build-time dependencies. However, it does
  28 # have run-time dependencies and keyboard layouts may not work without the
  29 # right libX11 or xproto installed.
  30 # By default, we enable these run-time dependencies as build-time
  31 # dependencies so that those building on their local machines are warned
  32 # that the resulting build may not work.
  33 AC_ARG_ENABLE( runtime-deps,
  34                [ --enable-runtime-deps    use run-time dependencies as build-time dependencies],
  35                enable_runtime_deps="$enableval",
  36                enable_runtime_deps="yes")
  37
  38 if test "x$enable_runtime_deps" = "xyes"; then
  39     PKG_CHECK_MODULES(DEPS, [xproto >= 7.0.20] [x11 >= 1.4.3], [have_deps=yes], [have_deps=no])
  40     if test "x$have_deps" = "xno" ; then
  41         AC_MSG_WARN([
  42                  Required dependencies not found. These dependencies are
  43                  run-time dependencies only and not required for building.
  44                  Skip this check with --disable-runtime-deps.
  45
  46                  Installing this version of xkeyboard-config on a host
  47                  without the required dependencies may result in unusable
  48                  keyboard layouts.
  49                  ])
  50
  51         AC_MSG_ERROR([$DEPS_PKG_ERRORS])
  52     fi
  53 fi
  54
  55 AM_CONDITIONAL(CREATE_RULES_SYMLINK, test "x$xkb_rules_symlink" != "x")
  56
  57 AM_CONDITIONAL(USE_COMPAT_RULES, test "x$enable_compat_rules" = "xyes")
  58
  59 # ****
  60 # i18n
  61 # ****
  62 AC_PROG_INTLTOOL(0.30)
  63
  64 GETTEXT_PACKAGE=xkeyboard-config
  65 AC_SUBST(GETTEXT_PACKAGE)
  66 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
  67
  68 AM_GLIB_GNU_GETTEXT
  69
  70 ALL_LINGUAS="af az bg ca crh cs da de el en_GB eo es fi fr gl hu id it ja ka ko ky lt nb nl pl ro ru rw sk sl sq sr sv tr uk vi zh_CN zh_TW"
  71
  72 AC_SUBST(xkb_base)
  73 AC_SUBST(xkb_rules_symlink)
  74
  75 AC_OUTPUT([ po/Makefile.in
  76 Makefile
  77 compat/Makefile
  78 geometry/Makefile
  79 geometry/digital_vndr/Makefile
  80 geometry/sgi_vndr/Makefile
  81 keycodes/Makefile
  82 keycodes/digital_vndr/Makefile
  83 keycodes/sgi_vndr/Makefile
  84 keymap/Makefile
  85 keymap/digital_vndr/Makefile
  86 keymap/sgi_vndr/Makefile
  87 keymap/sun_vndr/Makefile
  88 semantics/Makefile
  89 rules/Makefile
  90 rules/bin/Makefile
  91 rules/compat/Makefile
  92 symbols/Makefile
  93 symbols/digital_vndr/Makefile
  94 symbols/fujitsu_vndr/Makefile
  95 symbols/hp_vndr/Makefile
  96 symbols/macintosh_vndr/Makefile
  97 symbols/nec_vndr/Makefile
  98 symbols/nokia_vndr/Makefile
  99 symbols/sgi_vndr/Makefile
 100 symbols/sony_vndr/Makefile
 101 symbols/sun_vndr/Makefile
 102 symbols/xfree68_vndr/Makefile
 103 types/Makefile
 104 xkeyboard-config.pc
 105 xkeyboard-config.spec
 106 docs/Makefile
 107 ])
 108
 109 echo '***********************************************************'
 110 echo "  $PACKAGE_NAME is configured with the following parameters:"
 111 echo "    XKB base directory: $xkb_base"
 112 if test -z "$xkb_rules_symlink" ; then
 113   echo "    Symbolic link(s) to legacy rules are not created"
 114 else
 115   echo "    Symbolic link(s) to legacy rules: $xkb_rules_symlink"
 116 fi
 117
 118 if test "$enable_compat_rules" = "yes" ; then
 119   echo "    Compatibility rules are included"
 120 else
 121   echo "    Compatibility rules are not included"
 122 fi
 123 echo '***********************************************************'
 124