git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 # Verify the user input
 464
 465 foreach my $entry (@initial_to) {
 466         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 467 }
 468
 469 foreach my $entry (@initial_cc) {
 470         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 471 }
 472
 473 foreach my $entry (@bcclist) {
 474         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 475 }
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return split_addrs($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/^\s|\\$/) {
 496                 print STDERR "warning: sendmail continuation line is not supported: $_\n";
 497         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 498                 my ($alias, $addr) = ($1, $2);
 499                 $aliases{$alias} = [ split_addrs($addr) ];
 500         } else {
 501                 print STDERR "warning: sendmail line is not recognized: $_\n";
 502         }
 503 }
 504
 505 sub parse_sendmail_aliases {
 506         my $fh = shift;
 507         while (<$fh>) {
 508                 next if /^\s*$/ || /^\s*#/;
 509                 parse_sendmail_alias($_);
 510         }
 511 }
 512
 513 my %parse_alias = (
 514         # multiline formats can be supported in the future
 515         mutt => sub { my $fh = shift; while (<$fh>) {
 516                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 517                         my ($alias, $addr) = ($1, $2);
 518                         $addr =~ s/#.*$//; # mutt allows # comments
 519                          # commas delimit multiple addresses
 520                         $aliases{$alias} = [ split_addrs($addr) ];
 521                 }}},
 522         mailrc => sub { my $fh = shift; while (<$fh>) {
 523                 if (/^alias\s+(\S+)\s+(.*)$/) {
 524                         # spaces delimit multiple addresses
 525                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 526                 }}},
 527         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 528                 for (my $x = ''; defined($x); $x = $_) {
 529                         chomp $x;
 530                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 531                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 532                         $aliases{$1} = [ split_addrs($2) ];
 533                 }},
 534         elm => sub  { my $fh = shift;
 535                       while (<$fh>) {
 536                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 537                               my ($alias, $addr) = ($1, $2);
 538                                $aliases{$alias} = [ split_addrs($addr) ];
 539                           }
 540                       } },
 541         sendmail => \&parse_sendmail_aliases,
 542         gnus => sub { my $fh = shift; while (<$fh>) {
 543                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 544                         $aliases{$1} = [ $2 ];
 545                 }}}
 546 );
 547
 548 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 549         foreach my $file (@alias_files) {
 550                 open my $fh, '<', $file or die "opening $file: $!\n";
 551                 $parse_alias{$aliasfiletype}->($fh);
 552                 close $fh;
 553         }
 554 }
 555
 556 ($sender) = expand_aliases($sender) if defined $sender;
 557
 558 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 559 # $f is a revision list specification to be passed to format-patch.
 560 sub is_format_patch_arg {
 561         return unless $repo;
 562         my $f = shift;
 563         try {
 564                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 565                 if (defined($format_patch)) {
 566                         return $format_patch;
 567                 }
 568                 die(<<EOF);
 569 File '$f' exists but it could also be the range of commits
 570 to produce patches for.  Please disambiguate by...
 571
 572     * Saying "./$f" if you mean a file; or
 573     * Giving --format-patch option if you mean a range.
 574 EOF
 575         } catch Git::Error::Command with {
 576                 # Not a valid revision.  Treat it as a filename.
 577                 return 0;
 578         }
 579 }
 580
 581 # Now that all the defaults are set, process the rest of the command line
 582 # arguments and collect up the files that need to be processed.
 583 my @rev_list_opts;
 584 while (defined(my $f = shift @ARGV)) {
 585         if ($f eq "--") {
 586                 push @rev_list_opts, "--", @ARGV;
 587                 @ARGV = ();
 588         } elsif (-d $f and !is_format_patch_arg($f)) {
 589                 opendir my $dh, $f
 590                         or die "Failed to opendir $f: $!";
 591
 592                 push @files, grep { -f $_ } map { catfile($f, $_) }
 593                                 sort readdir $dh;
 594                 closedir $dh;
 595         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 596                 push @files, $f;
 597         } else {
 598                 push @rev_list_opts, $f;
 599         }
 600 }
 601
 602 if (@rev_list_opts) {
 603         die "Cannot run git format-patch from outside a repository\n"
 604                 unless $repo;
 605         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 606 }
 607
 608 if ($validate) {
 609         foreach my $f (@files) {
 610                 unless (-p $f) {
 611                         my $error = validate_patch($f);
 612                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 613                 }
 614         }
 615 }
 616
 617 if (@files) {
 618         unless ($quiet) {
 619                 print $_,"\n" for (@files);
 620         }
 621 } else {
 622         print STDERR "\nNo patch files specified!\n\n";
 623         usage();
 624 }
 625
 626 sub get_patch_subject {
 627         my $fn = shift;
 628         open (my $fh, '<', $fn);
 629         while (my $line = <$fh>) {
 630                 next unless ($line =~ /^Subject: (.*)$/);
 631                 close $fh;
 632                 return "GIT: $1\n";
 633         }
 634         close $fh;
 635         die "No subject line in $fn ?";
 636 }
 637
 638 if ($compose) {
 639         # Note that this does not need to be secure, but we will make a small
 640         # effort to have it be unique
 641         $compose_filename = ($repo ?
 642                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 643                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 644         open my $c, ">", $compose_filename
 645                 or die "Failed to open for writing $compose_filename: $!";
 646
 647
 648         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 649         my $tpl_subject = $initial_subject || '';
 650         my $tpl_reply_to = $initial_reply_to || '';
 651
 652         print $c <<EOT;
 653 From $tpl_sender # This line is ignored.
 654 GIT: Lines beginning in "GIT:" will be removed.
 655 GIT: Consider including an overall diffstat or table of contents
 656 GIT: for the patch you are writing.
 657 GIT:
 658 GIT: Clear the body content if you don't wish to send a summary.
 659 From: $tpl_sender
 660 Subject: $tpl_subject
 661 In-Reply-To: $tpl_reply_to
 662
 663 EOT
 664         for my $f (@files) {
 665                 print $c get_patch_subject($f);
 666         }
 667         close $c;
 668
 669         if ($annotate) {
 670                 do_edit($compose_filename, @files);
 671         } else {
 672                 do_edit($compose_filename);
 673         }
 674
 675         open my $c2, ">", $compose_filename . ".final"
 676                 or die "Failed to open $compose_filename.final : " . $!;
 677
 678         open $c, "<", $compose_filename
 679                 or die "Failed to open $compose_filename : " . $!;
 680
 681         my $need_8bit_cte = file_has_nonascii($compose_filename);
 682         my $in_body = 0;
 683         my $summary_empty = 1;
 684         if (!defined $compose_encoding) {
 685                 $compose_encoding = "UTF-8";
 686         }
 687         while(<$c>) {
 688                 next if m/^GIT:/;
 689                 if ($in_body) {
 690                         $summary_empty = 0 unless (/^\n$/);
 691                 } elsif (/^\n$/) {
 692                         $in_body = 1;
 693                         if ($need_8bit_cte) {
 694                                 print $c2 "MIME-Version: 1.0\n",
 695                                          "Content-Type: text/plain; ",
 696                                            "charset=$compose_encoding\n",
 697                                          "Content-Transfer-Encoding: 8bit\n";
 698                         }
 699                 } elsif (/^MIME-Version:/i) {
 700                         $need_8bit_cte = 0;
 701                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 702                         $initial_subject = $1;
 703                         my $subject = $initial_subject;
 704                         $_ = "Subject: " .
 705                                 quote_subject($subject, $compose_encoding) .
 706                                 "\n";
 707                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 708                         $initial_reply_to = $1;
 709                         next;
 710                 } elsif (/^From:\s*(.+)\s*$/i) {
 711                         $sender = $1;
 712                         next;
 713                 } elsif (/^(?:To|Cc|Bcc):/i) {
 714                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 715                         next;
 716                 }
 717                 print $c2 $_;
 718         }
 719         close $c;
 720         close $c2;
 721
 722         if ($summary_empty) {
 723                 print "Summary email is empty, skipping it\n";
 724                 $compose = -1;
 725         }
 726 } elsif ($annotate) {
 727         do_edit(@files);
 728 }
 729
 730 sub ask {
 731         my ($prompt, %arg) = @_;
 732         my $valid_re = $arg{valid_re};
 733         my $default = $arg{default};
 734         my $confirm_only = $arg{confirm_only};
 735         my $resp;
 736         my $i = 0;
 737         return defined $default ? $default : undef
 738                 unless defined $term->IN and defined fileno($term->IN) and
 739                        defined $term->OUT and defined fileno($term->OUT);
 740         while ($i++ < 10) {
 741                 $resp = $term->readline($prompt);
 742                 if (!defined $resp) { # EOF
 743                         print "\n";
 744                         return defined $default ? $default : undef;
 745                 }
 746                 if ($resp eq '' and defined $default) {
 747                         return $default;
 748                 }
 749                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 750                         return $resp;
 751                 }
 752                 if ($confirm_only) {
 753                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 754                         if (defined $yesno && $yesno =~ /y/i) {
 755                                 return $resp;
 756                         }
 757                 }
 758         }
 759         return;
 760 }
 761
 762 my %broken_encoding;
 763
 764 sub file_declares_8bit_cte {
 765         my $fn = shift;
 766         open (my $fh, '<', $fn);
 767         while (my $line = <$fh>) {
 768                 last if ($line =~ /^$/);
 769                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 770         }
 771         close $fh;
 772         return 0;
 773 }
 774
 775 foreach my $f (@files) {
 776         next unless (body_or_subject_has_nonascii($f)
 777                      && !file_declares_8bit_cte($f));
 778         $broken_encoding{$f} = 1;
 779 }
 780
 781 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 782         print "The following files are 8bit, but do not declare " .
 783                 "a Content-Transfer-Encoding.\n";
 784         foreach my $f (sort keys %broken_encoding) {
 785                 print "    $f\n";
 786         }
 787         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 788                                   valid_re => qr/.{4}/, confirm_only => 1,
 789                                   default => "UTF-8");
 790 }
 791
 792 if (!$force) {
 793         for my $f (@files) {
 794                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 795                         die "Refusing to send because the patch\n\t$f\n"
 796                                 . "has the template subject '*** SUBJECT HERE ***'. "
 797                                 . "Pass --force if you really want to send.\n";
 798                 }
 799         }
 800 }
 801
 802 if (!defined $sender) {
 803         $sender = $repoauthor || $repocommitter || '';
 804 }
 805
 806 # $sender could be an already sanitized address
 807 # (e.g. sendemail.from could be manually sanitized by user).
 808 # But it's a no-op to run sanitize_address on an already sanitized address.
 809 $sender = sanitize_address($sender);
 810
 811 my $prompting = 0;
 812 if (!@initial_to && !defined $to_cmd) {
 813         my $to = ask("Who should the emails be sent to (if any)? ",
 814                      default => "",
 815                      valid_re => qr/\@.*\./, confirm_only => 1);
 816         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 817         $prompting++;
 818 }
 819
 820 sub expand_aliases {
 821         return map { expand_one_alias($_) } @_;
 822 }
 823
 824 my %EXPANDED_ALIASES;
 825 sub expand_one_alias {
 826         my $alias = shift;
 827         if ($EXPANDED_ALIASES{$alias}) {
 828                 die "fatal: alias '$alias' expands to itself\n";
 829         }
 830         local $EXPANDED_ALIASES{$alias} = 1;
 831         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 832 }
 833
 834 @initial_to = expand_aliases(@initial_to);
 835 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 836 @initial_cc = expand_aliases(@initial_cc);
 837 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 838 @bcclist = expand_aliases(@bcclist);
 839 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 840
 841 if ($thread && !defined $initial_reply_to && $prompting) {
 842         $initial_reply_to = ask(
 843                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 844                 default => "",
 845                 valid_re => qr/\@.*\./, confirm_only => 1);
 846 }
 847 if (defined $initial_reply_to) {
 848         $initial_reply_to =~ s/^\s*<?//;
 849         $initial_reply_to =~ s/>?\s*$//;
 850         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 851 }
 852
 853 if (!defined $smtp_server) {
 854         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 855                 if (-x $_) {
 856                         $smtp_server = $_;
 857                         last;
 858                 }
 859         }
 860         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 861 }
 862
 863 if ($compose && $compose > 0) {
 864         @files = ($compose_filename . ".final", @files);
 865 }
 866
 867 # Variables we set as part of the loop over files
 868 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 869         $needs_confirm, $message_num, $ask_default);
 870
 871 sub extract_valid_address {
 872         my $address = shift;
 873         my $local_part_regexp = qr/[^<>"\s@]+/;
 874         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 875
 876         # check for a local address:
 877         return $address if ($address =~ /^($local_part_regexp)$/);
 878
 879         $address =~ s/^\s*<(.*)>\s*$/$1/;
 880         if ($have_email_valid) {
 881                 return scalar Email::Valid->address($address);
 882         }
 883
 884         # less robust/correct than the monster regexp in Email::Valid,
 885         # but still does a 99% job, and one less dependency
 886         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 887         return;
 888 }
 889
 890 sub extract_valid_address_or_die {
 891         my $address = shift;
 892         $address = extract_valid_address($address);
 893         die "error: unable to extract a valid address from: $address\n"
 894                 if !$address;
 895         return $address;
 896 }
 897
 898 sub validate_address {
 899         my $address = shift;
 900         while (!extract_valid_address($address)) {
 901                 print STDERR "error: unable to extract a valid address from: $address\n";
 902                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 903                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 904                         default => 'q');
 905                 if (/^d/i) {
 906                         return undef;
 907                 } elsif (/^q/i) {
 908                         cleanup_compose_files();
 909                         exit(0);
 910                 }
 911                 $address = ask("Who should the email be sent to (if any)? ",
 912                         default => "",
 913                         valid_re => qr/\@.*\./, confirm_only => 1);
 914         }
 915         return $address;
 916 }
 917
 918 sub validate_address_list {
 919         return (grep { defined $_ }
 920                 map { validate_address($_) } @_);
 921 }
 922
 923 # Usually don't need to change anything below here.
 924
 925 # we make a "fake" message id by taking the current number
 926 # of seconds since the beginning of Unix time and tacking on
 927 # a random number to the end, in case we are called quicker than
 928 # 1 second since the last time we were called.
 929
 930 # We'll setup a template for the message id, using the "from" address:
 931
 932 my ($message_id_stamp, $message_id_serial);
 933 sub make_message_id {
 934         my $uniq;
 935         if (!defined $message_id_stamp) {
 936                 $message_id_stamp = sprintf("%s-%s", time, $$);
 937                 $message_id_serial = 0;
 938         }
 939         $message_id_serial++;
 940         $uniq = "$message_id_stamp-$message_id_serial";
 941
 942         my $du_part;
 943         for ($sender, $repocommitter, $repoauthor) {
 944                 $du_part = extract_valid_address(sanitize_address($_));
 945                 last if (defined $du_part and $du_part ne '');
 946         }
 947         if (not defined $du_part or $du_part eq '') {
 948                 require Sys::Hostname;
 949                 $du_part = 'user@' . Sys::Hostname::hostname();
 950         }
 951         my $message_id_template = "<%s-git-send-email-%s>";
 952         $message_id = sprintf($message_id_template, $uniq, $du_part);
 953         #print "new message id = $message_id\n"; # Was useful for debugging
 954 }
 955
 956
 957
 958 $time = time - scalar $#files;
 959
 960 sub unquote_rfc2047 {
 961         local ($_) = @_;
 962         my $charset;
 963         my $sep = qr/[ \t]+/;
 964         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 965                 my @words = split $sep, $&;
 966                 foreach (@words) {
 967                         m/$re_encoded_word/;
 968                         $charset = $1;
 969                         my $encoding = $2;
 970                         my $text = $3;
 971                         if ($encoding eq 'q' || $encoding eq 'Q') {
 972                                 $_ = $text;
 973                                 s/_/ /g;
 974                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 975                         } else {
 976                                 # other encodings not supported yet
 977                         }
 978                 }
 979                 join '', @words;
 980         }eg;
 981         return wantarray ? ($_, $charset) : $_;
 982 }
 983
 984 sub quote_rfc2047 {
 985         local $_ = shift;
 986         my $encoding = shift || 'UTF-8';
 987         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 988         s/(.*)/=\?$encoding\?q\?$1\?=/;
 989         return $_;
 990 }
 991
 992 sub is_rfc2047_quoted {
 993         my $s = shift;
 994         length($s) <= 75 &&
 995         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 996 }
 997
 998 sub subject_needs_rfc2047_quoting {
 999         my $s = shift;
1000
1001         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1002 }
1003
1004 sub quote_subject {
1005         local $subject = shift;
1006         my $encoding = shift || 'UTF-8';
1007
1008         if (subject_needs_rfc2047_quoting($subject)) {
1009                 return quote_rfc2047($subject, $encoding);
1010         }
1011         return $subject;
1012 }
1013
1014 # use the simplest quoting being able to handle the recipient
1015 sub sanitize_address {
1016         my ($recipient) = @_;
1017
1018         # remove garbage after email address
1019         $recipient =~ s/(.*>).*$/$1/;
1020
1021         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1022
1023         if (not $recipient_name) {
1024                 return $recipient;
1025         }
1026
1027         # if recipient_name is already quoted, do nothing
1028         if (is_rfc2047_quoted($recipient_name)) {
1029                 return $recipient;
1030         }
1031
1032         # rfc2047 is needed if a non-ascii char is included
1033         if ($recipient_name =~ /[^[:ascii:]]/) {
1034                 $recipient_name =~ s/^"(.*)"$/$1/;
1035                 $recipient_name = quote_rfc2047($recipient_name);
1036         }
1037
1038         # double quotes are needed if specials or CTLs are included
1039         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1040                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1041                 $recipient_name = qq["$recipient_name"];
1042         }
1043
1044         return "$recipient_name $recipient_addr";
1045
1046 }
1047
1048 sub sanitize_address_list {
1049         return (map { sanitize_address($_) } @_);
1050 }
1051
1052 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1053 #
1054 # Tightly configured MTAa require that a caller sends a real DNS
1055 # domain name that corresponds the IP address in the HELO/EHLO
1056 # handshake. This is used to verify the connection and prevent
1057 # spammers from trying to hide their identity. If the DNS and IP don't
1058 # match, the receiveing MTA may deny the connection.
1059 #
1060 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1061 #
1062 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1063 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1064 #
1065 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1066 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1067
1068 sub valid_fqdn {
1069         my $domain = shift;
1070         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1071 }
1072
1073 sub maildomain_net {
1074         my $maildomain;
1075
1076         if (eval { require Net::Domain; 1 }) {
1077                 my $domain = Net::Domain::domainname();
1078                 $maildomain = $domain if valid_fqdn($domain);
1079         }
1080
1081         return $maildomain;
1082 }
1083
1084 sub maildomain_mta {
1085         my $maildomain;
1086
1087         if (eval { require Net::SMTP; 1 }) {
1088                 for my $host (qw(mailhost localhost)) {
1089                         my $smtp = Net::SMTP->new($host);
1090                         if (defined $smtp) {
1091                                 my $domain = $smtp->domain;
1092                                 $smtp->quit;
1093
1094                                 $maildomain = $domain if valid_fqdn($domain);
1095
1096                                 last if $maildomain;
1097                         }
1098                 }
1099         }
1100
1101         return $maildomain;
1102 }
1103
1104 sub maildomain {
1105         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1106 }
1107
1108 sub smtp_host_string {
1109         if (defined $smtp_server_port) {
1110                 return "$smtp_server:$smtp_server_port";
1111         } else {
1112                 return $smtp_server;
1113         }
1114 }
1115
1116 # Returns 1 if authentication succeeded or was not necessary
1117 # (smtp_user was not specified), and 0 otherwise.
1118
1119 sub smtp_auth_maybe {
1120         if (!defined $smtp_authuser || $auth) {
1121                 return 1;
1122         }
1123
1124         # Workaround AUTH PLAIN/LOGIN interaction defect
1125         # with Authen::SASL::Cyrus
1126         eval {
1127                 require Authen::SASL;
1128                 Authen::SASL->import(qw(Perl));
1129         };
1130
1131         # TODO: Authentication may fail not because credentials were
1132         # invalid but due to other reasons, in which we should not
1133         # reject credentials.
1134         $auth = Git::credential({
1135                 'protocol' => 'smtp',
1136                 'host' => smtp_host_string(),
1137                 'username' => $smtp_authuser,
1138                 # if there's no password, "git credential fill" will
1139                 # give us one, otherwise it'll just pass this one.
1140                 'password' => $smtp_authpass
1141         }, sub {
1142                 my $cred = shift;
1143                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1144         });
1145
1146         return $auth;
1147 }
1148
1149 sub ssl_verify_params {
1150         eval {
1151                 require IO::Socket::SSL;
1152                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1153         };
1154         if ($@) {
1155                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1156                 return;
1157         }
1158
1159         if (!defined $smtp_ssl_cert_path) {
1160                 # use the OpenSSL defaults
1161                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1162         }
1163
1164         if ($smtp_ssl_cert_path eq "") {
1165                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1166         } elsif (-d $smtp_ssl_cert_path) {
1167                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1168                         SSL_ca_path => $smtp_ssl_cert_path);
1169         } elsif (-f $smtp_ssl_cert_path) {
1170                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1171                         SSL_ca_file => $smtp_ssl_cert_path);
1172         } else {
1173                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1174                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1175         }
1176 }
1177
1178 sub file_name_is_absolute {
1179         my ($path) = @_;
1180
1181         # msys does not grok DOS drive-prefixes
1182         if ($^O eq 'msys') {
1183                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1184         }
1185
1186         require File::Spec::Functions;
1187         return File::Spec::Functions::file_name_is_absolute($path);
1188 }
1189
1190 # Returns 1 if the message was sent, and 0 otherwise.
1191 # In actuality, the whole program dies when there
1192 # is an error sending a message.
1193
1194 sub send_message {
1195         my @recipients = unique_email_list(@to);
1196         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1197                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1198                     }
1199                @cc);
1200         my $to = join (",\n\t", @recipients);
1201         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1202         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1203         my $date = format_2822_time($time++);
1204         my $gitversion = '@@GIT_VERSION@@';
1205         if ($gitversion =~ m/..GIT_VERSION../) {
1206             $gitversion = Git::version();
1207         }
1208
1209         my $cc = join(",\n\t", unique_email_list(@cc));
1210         my $ccline = "";
1211         if ($cc ne '') {
1212                 $ccline = "\nCc: $cc";
1213         }
1214         make_message_id() unless defined($message_id);
1215
1216         my $header = "From: $sender
1217 To: $to${ccline}
1218 Subject: $subject
1219 Date: $date
1220 Message-Id: $message_id
1221 ";
1222         if ($use_xmailer) {
1223                 $header .= "X-Mailer: git-send-email $gitversion\n";
1224         }
1225         if ($reply_to) {
1226
1227                 $header .= "In-Reply-To: $reply_to\n";
1228                 $header .= "References: $references\n";
1229         }
1230         if (@xh) {
1231                 $header .= join("\n", @xh) . "\n";
1232         }
1233
1234         my @sendmail_parameters = ('-i', @recipients);
1235         my $raw_from = $sender;
1236         if (defined $envelope_sender && $envelope_sender ne "auto") {
1237                 $raw_from = $envelope_sender;
1238         }
1239         $raw_from = extract_valid_address($raw_from);
1240         unshift (@sendmail_parameters,
1241                         '-f', $raw_from) if(defined $envelope_sender);
1242
1243         if ($needs_confirm && !$dry_run) {
1244                 print "\n$header\n";
1245                 if ($needs_confirm eq "inform") {
1246                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1247                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1248                         print "    The Cc list above has been expanded by additional\n";
1249                         print "    addresses found in the patch commit message. By default\n";
1250                         print "    send-email prompts before sending whenever this occurs.\n";
1251                         print "    This behavior is controlled by the sendemail.confirm\n";
1252                         print "    configuration setting.\n";
1253                         print "\n";
1254                         print "    For additional information, run 'git send-email --help'.\n";
1255                         print "    To retain the current behavior, but squelch this message,\n";
1256                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1257                 }
1258                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1259                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1260                          default => $ask_default);
1261                 die "Send this email reply required" unless defined $_;
1262                 if (/^n/i) {
1263                         return 0;
1264                 } elsif (/^q/i) {
1265                         cleanup_compose_files();
1266                         exit(0);
1267                 } elsif (/^a/i) {
1268                         $confirm = 'never';
1269                 }
1270         }
1271
1272         unshift (@sendmail_parameters, @smtp_server_options);
1273
1274         if ($dry_run) {
1275                 # We don't want to send the email.
1276         } elsif (file_name_is_absolute($smtp_server)) {
1277                 my $pid = open my $sm, '|-';
1278                 defined $pid or die $!;
1279                 if (!$pid) {
1280                         exec($smtp_server, @sendmail_parameters) or die $!;
1281                 }
1282                 print $sm "$header\n$message";
1283                 close $sm or die $!;
1284         } else {
1285
1286                 if (!defined $smtp_server) {
1287                         die "The required SMTP server is not properly defined."
1288                 }
1289
1290                 if ($smtp_encryption eq 'ssl') {
1291                         $smtp_server_port ||= 465; # ssmtp
1292                         require Net::SMTP::SSL;
1293                         $smtp_domain ||= maildomain();
1294                         require IO::Socket::SSL;
1295                         # Net::SMTP::SSL->new() does not forward any SSL options
1296                         IO::Socket::SSL::set_client_defaults(
1297                                 ssl_verify_params());
1298                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1299                                                       Hello => $smtp_domain,
1300                                                       Port => $smtp_server_port,
1301                                                       Debug => $debug_net_smtp);
1302                 }
1303                 else {
1304                         require Net::SMTP;
1305                         $smtp_domain ||= maildomain();
1306                         $smtp_server_port ||= 25;
1307                         $smtp ||= Net::SMTP->new($smtp_server,
1308                                                  Hello => $smtp_domain,
1309                                                  Debug => $debug_net_smtp,
1310                                                  Port => $smtp_server_port);
1311                         if ($smtp_encryption eq 'tls' && $smtp) {
1312                                 require Net::SMTP::SSL;
1313                                 $smtp->command('STARTTLS');
1314                                 $smtp->response();
1315                                 if ($smtp->code == 220) {
1316                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1317                                                                           ssl_verify_params())
1318                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1319                                         $smtp_encryption = '';
1320                                         # Send EHLO again to receive fresh
1321                                         # supported commands
1322                                         $smtp->hello($smtp_domain);
1323                                 } else {
1324                                         die "Server does not support STARTTLS! ".$smtp->message;
1325                                 }
1326                         }
1327                 }
1328
1329                 if (!$smtp) {
1330                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1331                             "VALUES: server=$smtp_server ",
1332                             "encryption=$smtp_encryption ",
1333                             "hello=$smtp_domain",
1334                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1335                 }
1336
1337                 smtp_auth_maybe or die $smtp->message;
1338
1339                 $smtp->mail( $raw_from ) or die $smtp->message;
1340                 $smtp->to( @recipients ) or die $smtp->message;
1341                 $smtp->data or die $smtp->message;
1342                 $smtp->datasend("$header\n$message") or die $smtp->message;
1343                 $smtp->dataend() or die $smtp->message;
1344                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1345         }
1346         if ($quiet) {
1347                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1348         } else {
1349                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1350                 if (!file_name_is_absolute($smtp_server)) {
1351                         print "Server: $smtp_server\n";
1352                         print "MAIL FROM:<$raw_from>\n";
1353                         foreach my $entry (@recipients) {
1354                             print "RCPT TO:<$entry>\n";
1355                         }
1356                 } else {
1357                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1358                 }
1359                 print $header, "\n";
1360                 if ($smtp) {
1361                         print "Result: ", $smtp->code, ' ',
1362                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1363                 } else {
1364                         print "Result: OK\n";
1365                 }
1366         }
1367
1368         return 1;
1369 }
1370
1371 $reply_to = $initial_reply_to;
1372 $references = $initial_reply_to || '';
1373 $subject = $initial_subject;
1374 $message_num = 0;
1375
1376 foreach my $t (@files) {
1377         open my $fh, "<", $t or die "can't open file $t";
1378
1379         my $author = undef;
1380         my $sauthor = undef;
1381         my $author_encoding;
1382         my $has_content_type;
1383         my $body_encoding;
1384         my $xfer_encoding;
1385         my $has_mime_version;
1386         @to = ();
1387         @cc = ();
1388         @xh = ();
1389         my $input_format = undef;
1390         my @header = ();
1391         $message = "";
1392         $message_num++;
1393         # First unfold multiline header fields
1394         while(<$fh>) {
1395                 last if /^\s*$/;
1396                 if (/^\s+\S/ and @header) {
1397                         chomp($header[$#header]);
1398                         s/^\s+/ /;
1399                         $header[$#header] .= $_;
1400             } else {
1401                         push(@header, $_);
1402                 }
1403         }
1404         # Now parse the header
1405         foreach(@header) {
1406                 if (/^From /) {
1407                         $input_format = 'mbox';
1408                         next;
1409                 }
1410                 chomp;
1411                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1412                         $input_format = 'mbox';
1413                 }
1414
1415                 if (defined $input_format && $input_format eq 'mbox') {
1416                         if (/^Subject:\s+(.*)$/i) {
1417                                 $subject = $1;
1418                         }
1419                         elsif (/^From:\s+(.*)$/i) {
1420                                 ($author, $author_encoding) = unquote_rfc2047($1);
1421                                 $sauthor = sanitize_address($author);
1422                                 next if $suppress_cc{'author'};
1423                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1424                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1425                                         $1, $_) unless $quiet;
1426                                 push @cc, $1;
1427                         }
1428                         elsif (/^To:\s+(.*)$/i) {
1429                                 foreach my $addr (parse_address_line($1)) {
1430                                         printf("(mbox) Adding to: %s from line '%s'\n",
1431                                                 $addr, $_) unless $quiet;
1432                                         push @to, $addr;
1433                                 }
1434                         }
1435                         elsif (/^Cc:\s+(.*)$/i) {
1436                                 foreach my $addr (parse_address_line($1)) {
1437                                         my $qaddr = unquote_rfc2047($addr);
1438                                         my $saddr = sanitize_address($qaddr);
1439                                         if ($saddr eq $sender) {
1440                                                 next if ($suppress_cc{'self'});
1441                                         } else {
1442                                                 next if ($suppress_cc{'cc'});
1443                                         }
1444                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1445                                                 $addr, $_) unless $quiet;
1446                                         push @cc, $addr;
1447                                 }
1448                         }
1449                         elsif (/^Content-type:/i) {
1450                                 $has_content_type = 1;
1451                                 if (/charset="?([^ "]+)/) {
1452                                         $body_encoding = $1;
1453                                 }
1454                                 push @xh, $_;
1455                         }
1456                         elsif (/^MIME-Version/i) {
1457                                 $has_mime_version = 1;
1458                                 push @xh, $_;
1459                         }
1460                         elsif (/^Message-Id: (.*)/i) {
1461                                 $message_id = $1;
1462                         }
1463                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1464                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1465                         }
1466                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1467                                 push @xh, $_;
1468                         }
1469
1470                 } else {
1471                         # In the traditional
1472                         # "send lots of email" format,
1473                         # line 1 = cc
1474                         # line 2 = subject
1475                         # So let's support that, too.
1476                         $input_format = 'lots';
1477                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1478                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1479                                         $_, $_) unless $quiet;
1480                                 push @cc, $_;
1481                         } elsif (!defined $subject) {
1482                                 $subject = $_;
1483                         }
1484                 }
1485         }
1486         # Now parse the message body
1487         while(<$fh>) {
1488                 $message .=  $_;
1489                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1490                         chomp;
1491                         my ($what, $c) = ($1, $2);
1492                         chomp $c;
1493                         my $sc = sanitize_address($c);
1494                         if ($sc eq $sender) {
1495                                 next if ($suppress_cc{'self'});
1496                         } else {
1497                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1498                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1499                         }
1500                         push @cc, $c;
1501                         printf("(body) Adding cc: %s from line '%s'\n",
1502                                 $c, $_) unless $quiet;
1503                 }
1504         }
1505         close $fh;
1506
1507         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1508                 if defined $to_cmd;
1509         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1510                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1511
1512         if ($broken_encoding{$t} && !$has_content_type) {
1513                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1514                 $has_content_type = 1;
1515                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1516                 $body_encoding = $auto_8bit_encoding;
1517         }
1518
1519         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1520                 $subject = quote_subject($subject, $auto_8bit_encoding);
1521         }
1522
1523         if (defined $sauthor and $sauthor ne $sender) {
1524                 $message = "From: $author\n\n$message";
1525                 if (defined $author_encoding) {
1526                         if ($has_content_type) {
1527                                 if ($body_encoding eq $author_encoding) {
1528                                         # ok, we already have the right encoding
1529                                 }
1530                                 else {
1531                                         # uh oh, we should re-encode
1532                                 }
1533                         }
1534                         else {
1535                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1536                                 $has_content_type = 1;
1537                                 push @xh,
1538                                   "Content-Type: text/plain; charset=$author_encoding";
1539                         }
1540                 }
1541         }
1542         if (defined $target_xfer_encoding) {
1543                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1544                 $message = apply_transfer_encoding(
1545                         $message, $xfer_encoding, $target_xfer_encoding);
1546                 $xfer_encoding = $target_xfer_encoding;
1547         }
1548         if (defined $xfer_encoding) {
1549                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1550         }
1551         if (defined $xfer_encoding or $has_content_type) {
1552                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1553         }
1554
1555         $needs_confirm = (
1556                 $confirm eq "always" or
1557                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1558                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1559         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1560
1561         @to = validate_address_list(sanitize_address_list(@to));
1562         @cc = validate_address_list(sanitize_address_list(@cc));
1563
1564         @to = (@initial_to, @to);
1565         @cc = (@initial_cc, @cc);
1566
1567         if ($message_num == 1) {
1568                 if (defined $cover_cc and $cover_cc) {
1569                         @initial_cc = @cc;
1570                 }
1571                 if (defined $cover_to and $cover_to) {
1572                         @initial_to = @to;
1573                 }
1574         }
1575
1576         my $message_was_sent = send_message();
1577
1578         # set up for the next message
1579         if ($thread && $message_was_sent &&
1580                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1581                 $message_num == 1)) {
1582                 $reply_to = $message_id;
1583                 if (length $references > 0) {
1584                         $references .= "\n $message_id";
1585                 } else {
1586                         $references = "$message_id";
1587                 }
1588         }
1589         $message_id = undef;
1590 }
1591
1592 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1593 # and return a results array
1594 sub recipients_cmd {
1595         my ($prefix, $what, $cmd, $file) = @_;
1596
1597         my @addresses = ();
1598         open my $fh, "-|", "$cmd \Q$file\E"
1599             or die "($prefix) Could not execute '$cmd'";
1600         while (my $address = <$fh>) {
1601                 $address =~ s/^\s*//g;
1602                 $address =~ s/\s*$//g;
1603                 $address = sanitize_address($address);
1604                 next if ($address eq $sender and $suppress_cc{'self'});
1605                 push @addresses, $address;
1606                 printf("($prefix) Adding %s: %s from: '%s'\n",
1607                        $what, $address, $cmd) unless $quiet;
1608                 }
1609         close $fh
1610             or die "($prefix) failed to close pipe to '$cmd'";
1611         return @addresses;
1612 }
1613
1614 cleanup_compose_files();
1615
1616 sub cleanup_compose_files {
1617         unlink($compose_filename, $compose_filename . ".final") if $compose;
1618 }
1619
1620 $smtp->quit if $smtp;
1621
1622 sub apply_transfer_encoding {
1623         my $message = shift;
1624         my $from = shift;
1625         my $to = shift;
1626
1627         return $message if ($from eq $to and $from ne '7bit');
1628
1629         require MIME::QuotedPrint;
1630         require MIME::Base64;
1631
1632         $message = MIME::QuotedPrint::decode($message)
1633                 if ($from eq 'quoted-printable');
1634         $message = MIME::Base64::decode($message)
1635                 if ($from eq 'base64');
1636
1637         die "cannot send message as 7bit"
1638                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1639         return $message
1640                 if ($to eq '7bit' or $to eq '8bit');
1641         return MIME::QuotedPrint::encode($message, "\n", 0)
1642                 if ($to eq 'quoted-printable');
1643         return MIME::Base64::encode($message, "\n")
1644                 if ($to eq 'base64');
1645         die "invalid transfer encoding";
1646 }
1647
1648 sub unique_email_list {
1649         my %seen;
1650         my @emails;
1651
1652         foreach my $entry (@_) {
1653                 my $clean = extract_valid_address_or_die($entry);
1654                 $seen{$clean} ||= 0;
1655                 next if $seen{$clean}++;
1656                 push @emails, $entry;
1657         }
1658         return @emails;
1659 }
1660
1661 sub validate_patch {
1662         my $fn = shift;
1663         open(my $fh, '<', $fn)
1664                 or die "unable to open $fn: $!\n";
1665         while (my $line = <$fh>) {
1666                 if (length($line) > 998) {
1667                         return "$.: patch contains a line longer than 998 characters";
1668                 }
1669         }
1670         return;
1671 }
1672
1673 sub file_has_nonascii {
1674         my $fn = shift;
1675         open(my $fh, '<', $fn)
1676                 or die "unable to open $fn: $!\n";
1677         while (my $line = <$fh>) {
1678                 return 1 if $line =~ /[^[:ascii:]]/;
1679         }
1680         return 0;
1681 }
1682
1683 sub body_or_subject_has_nonascii {
1684         my $fn = shift;
1685         open(my $fh, '<', $fn)
1686                 or die "unable to open $fn: $!\n";
1687         while (my $line = <$fh>) {
1688                 last if $line =~ /^$/;
1689                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1690         }
1691         while (my $line = <$fh>) {
1692                 return 1 if $line =~ /[^[:ascii:]]/;
1693         }
1694         return 0;
1695 }