git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49 git send-email --dump-aliases
  50
  51   Composing:
  52     --from                  <str>  * Email From:
  53     --[no-]to               <str>  * Email To:
  54     --[no-]cc               <str>  * Email Cc:
  55     --[no-]bcc              <str>  * Email Bcc:
  56     --subject               <str>  * Email "Subject:"
  57     --in-reply-to           <str>  * Email "In-Reply-To:"
  58     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  59     --[no-]annotate                * Review each patch that will be sent in an editor.
  60     --compose                      * Open an editor for introduction.
  61     --compose-encoding      <str>  * Encoding to assume for introduction.
  62     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  63     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  64
  65   Sending:
  66     --envelope-sender       <str>  * Email envelope sender.
  67     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  68                                      is optional. Default 'localhost'.
  69     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  70     --smtp-server-port      <int>  * Outgoing SMTP server port.
  71     --smtp-user             <str>  * Username for SMTP-AUTH.
  72     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  73     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  74     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  75     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  76                                      Pass an empty string to disable certificate
  77                                      verification.
  78     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  79     --smtp-auth             <str>  * Space-separated list of allowed AUTH mechanisms.
  80                                      This setting forces to use one of the listed mechanisms.
  81     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  82
  83   Automating:
  84     --identity              <str>  * Use the sendemail.<id> options.
  85     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  86     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  87     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  88     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  89     --[no-]to-cover                * Email To: addresses in the cover letter.
  90     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  91     --[no-]suppress-from           * Send to self. Default off.
  92     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  93     --[no-]thread                  * Use In-Reply-To: field. Default on.
  94
  95   Administering:
  96     --confirm               <str>  * Confirm recipients before sending;
  97                                      auto, cc, compose, always, or never.
  98     --quiet                        * Output one line of info per email.
  99     --dry-run                      * Don't actually send the emails.
 100     --[no-]validate                * Perform patch sanity checks. Default on.
 101     --[no-]format-patch            * understand any non optional arguments as
 102                                      `git format-patch` ones.
 103     --force                        * Send even if safety checks would prevent it.
 104
 105   Information:
 106     --dump-aliases                 * Dump configured aliases and exit.
 107
 108 EOT
 109         exit(1);
 110 }
 111
 112 # most mail servers generate the Date: header, but not all...
 113 sub format_2822_time {
 114         my ($time) = @_;
 115         my @localtm = localtime($time);
 116         my @gmttm = gmtime($time);
 117         my $localmin = $localtm[1] + $localtm[2] * 60;
 118         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 119         if ($localtm[0] != $gmttm[0]) {
 120                 die "local zone differs from GMT by a non-minute interval\n";
 121         }
 122         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 123                 $localmin += 1440;
 124         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 125                 $localmin -= 1440;
 126         } elsif ($gmttm[6] != $localtm[6]) {
 127                 die "local time offset greater than or equal to 24 hours\n";
 128         }
 129         my $offset = $localmin - $gmtmin;
 130         my $offhour = $offset / 60;
 131         my $offmin = abs($offset % 60);
 132         if (abs($offhour) >= 24) {
 133                 die ("local time offset greater than or equal to 24 hours\n");
 134         }
 135
 136         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 137                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 138                        $localtm[3],
 139                        qw(Jan Feb Mar Apr May Jun
 140                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 141                        $localtm[5]+1900,
 142                        $localtm[2],
 143                        $localtm[1],
 144                        $localtm[0],
 145                        ($offset >= 0) ? '+' : '-',
 146                        abs($offhour),
 147                        $offmin,
 148                        );
 149 }
 150
 151 my $have_email_valid = eval { require Email::Valid; 1 };
 152 my $have_mail_address = eval { require Mail::Address; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 # Regexes for RFC 2047 productions.
 157 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 158 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 159 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 160
 161 # Variables we fill in automatically, or via prompting:
 162 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 163         $initial_reply_to,$initial_subject,@files,
 164         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184 my $format_patch;
 185 my $compose_filename;
 186 my $force = 0;
 187 my $dump_aliases = 0;
 188
 189 # Handle interactive edition of files.
 190 my $multiedit;
 191 my $editor;
 192
 193 sub do_edit {
 194         if (!defined($editor)) {
 195                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 196         }
 197         if (defined($multiedit) && !$multiedit) {
 198                 map {
 199                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 200                         if (($? & 127) || ($? >> 8)) {
 201                                 die("the editor exited uncleanly, aborting everything");
 202                         }
 203                 } @_;
 204         } else {
 205                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 206                 if (($? & 127) || ($? >> 8)) {
 207                         die("the editor exited uncleanly, aborting everything");
 208                 }
 209         }
 210 }
 211
 212 # Variables with corresponding config settings
 213 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 214 my ($cover_cc, $cover_to);
 215 my ($to_cmd, $cc_cmd);
 216 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 217 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 218 my ($identity, $aliasfiletype, @alias_files, $smtp_domain, $smtp_auth);
 219 my ($validate, $confirm);
 220 my (@suppress_cc);
 221 my ($auto_8bit_encoding);
 222 my ($compose_encoding);
 223 my ($target_xfer_encoding);
 224
 225 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 226
 227 my %config_bool_settings = (
 228     "thread" => [\$thread, 1],
 229     "chainreplyto" => [\$chain_reply_to, 0],
 230     "suppressfrom" => [\$suppress_from, undef],
 231     "signedoffbycc" => [\$signed_off_by_cc, undef],
 232     "cccover" => [\$cover_cc, undef],
 233     "tocover" => [\$cover_to, undef],
 234     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 235     "validate" => [\$validate, 1],
 236     "multiedit" => [\$multiedit, undef],
 237     "annotate" => [\$annotate, undef],
 238     "xmailer" => [\$use_xmailer, 1]
 239 );
 240
 241 my %config_settings = (
 242     "smtpserver" => \$smtp_server,
 243     "smtpserverport" => \$smtp_server_port,
 244     "smtpserveroption" => \@smtp_server_options,
 245     "smtpuser" => \$smtp_authuser,
 246     "smtppass" => \$smtp_authpass,
 247     "smtpdomain" => \$smtp_domain,
 248     "smtpauth" => \$smtp_auth,
 249     "to" => \@initial_to,
 250     "tocmd" => \$to_cmd,
 251     "cc" => \@initial_cc,
 252     "cccmd" => \$cc_cmd,
 253     "aliasfiletype" => \$aliasfiletype,
 254     "bcc" => \@bcclist,
 255     "suppresscc" => \@suppress_cc,
 256     "envelopesender" => \$envelope_sender,
 257     "confirm"   => \$confirm,
 258     "from" => \$sender,
 259     "assume8bitencoding" => \$auto_8bit_encoding,
 260     "composeencoding" => \$compose_encoding,
 261     "transferencoding" => \$target_xfer_encoding,
 262 );
 263
 264 my %config_path_settings = (
 265     "aliasesfile" => \@alias_files,
 266     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 267 );
 268
 269 # Handle Uncouth Termination
 270 sub signal_handler {
 271
 272         # Make text normal
 273         print color("reset"), "\n";
 274
 275         # SMTP password masked
 276         system "stty echo";
 277
 278         # tmp files from --compose
 279         if (defined $compose_filename) {
 280                 if (-e $compose_filename) {
 281                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 282                 }
 283                 if (-e ($compose_filename . ".final")) {
 284                         print "'$compose_filename.final' contains the composed email.\n"
 285                 }
 286         }
 287
 288         exit;
 289 };
 290
 291 $SIG{TERM} = \&signal_handler;
 292 $SIG{INT}  = \&signal_handler;
 293
 294 # Begin by accumulating all the variables (defined above), that we will end up
 295 # needing, first, from the command line:
 296
 297 my $help;
 298 my $rc = GetOptions("h" => \$help,
 299                     "dump-aliases" => \$dump_aliases);
 300 usage() unless $rc;
 301 die "--dump-aliases incompatible with other options\n"
 302     if !$help and $dump_aliases and @ARGV;
 303 $rc = GetOptions(
 304                     "sender|from=s" => \$sender,
 305                     "in-reply-to=s" => \$initial_reply_to,
 306                     "subject=s" => \$initial_subject,
 307                     "to=s" => \@initial_to,
 308                     "to-cmd=s" => \$to_cmd,
 309                     "no-to" => \$no_to,
 310                     "cc=s" => \@initial_cc,
 311                     "no-cc" => \$no_cc,
 312                     "bcc=s" => \@bcclist,
 313                     "no-bcc" => \$no_bcc,
 314                     "chain-reply-to!" => \$chain_reply_to,
 315                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 316                     "smtp-server=s" => \$smtp_server,
 317                     "smtp-server-option=s" => \@smtp_server_options,
 318                     "smtp-server-port=s" => \$smtp_server_port,
 319                     "smtp-user=s" => \$smtp_authuser,
 320                     "smtp-pass:s" => \$smtp_authpass,
 321                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 322                     "smtp-encryption=s" => \$smtp_encryption,
 323                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 324                     "smtp-debug:i" => \$debug_net_smtp,
 325                     "smtp-domain:s" => \$smtp_domain,
 326                     "smtp-auth=s" => \$smtp_auth,
 327                     "identity=s" => \$identity,
 328                     "annotate!" => \$annotate,
 329                     "no-annotate" => sub {$annotate = 0},
 330                     "compose" => \$compose,
 331                     "quiet" => \$quiet,
 332                     "cc-cmd=s" => \$cc_cmd,
 333                     "suppress-from!" => \$suppress_from,
 334                     "no-suppress-from" => sub {$suppress_from = 0},
 335                     "suppress-cc=s" => \@suppress_cc,
 336                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 337                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 338                     "cc-cover|cc-cover!" => \$cover_cc,
 339                     "no-cc-cover" => sub {$cover_cc = 0},
 340                     "to-cover|to-cover!" => \$cover_to,
 341                     "no-to-cover" => sub {$cover_to = 0},
 342                     "confirm=s" => \$confirm,
 343                     "dry-run" => \$dry_run,
 344                     "envelope-sender=s" => \$envelope_sender,
 345                     "thread!" => \$thread,
 346                     "no-thread" => sub {$thread = 0},
 347                     "validate!" => \$validate,
 348                     "no-validate" => sub {$validate = 0},
 349                     "transfer-encoding=s" => \$target_xfer_encoding,
 350                     "format-patch!" => \$format_patch,
 351                     "no-format-patch" => sub {$format_patch = 0},
 352                     "8bit-encoding=s" => \$auto_8bit_encoding,
 353                     "compose-encoding=s" => \$compose_encoding,
 354                     "force" => \$force,
 355                     "xmailer!" => \$use_xmailer,
 356                     "no-xmailer" => sub {$use_xmailer = 0},
 357          );
 358
 359 usage() if $help;
 360 unless ($rc) {
 361     usage();
 362 }
 363
 364 die "Cannot run git format-patch from outside a repository\n"
 365         if $format_patch and not $repo;
 366
 367 # Now, let's fill any that aren't set in with defaults:
 368
 369 sub read_config {
 370         my ($prefix) = @_;
 371
 372         foreach my $setting (keys %config_bool_settings) {
 373                 my $target = $config_bool_settings{$setting}->[0];
 374                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 375         }
 376
 377         foreach my $setting (keys %config_path_settings) {
 378                 my $target = $config_path_settings{$setting};
 379                 if (ref($target) eq "ARRAY") {
 380                         unless (@$target) {
 381                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 382                                 @$target = @values if (@values && defined $values[0]);
 383                         }
 384                 }
 385                 else {
 386                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 387                 }
 388         }
 389
 390         foreach my $setting (keys %config_settings) {
 391                 my $target = $config_settings{$setting};
 392                 next if $setting eq "to" and defined $no_to;
 393                 next if $setting eq "cc" and defined $no_cc;
 394                 next if $setting eq "bcc" and defined $no_bcc;
 395                 if (ref($target) eq "ARRAY") {
 396                         unless (@$target) {
 397                                 my @values = Git::config(@repo, "$prefix.$setting");
 398                                 @$target = @values if (@values && defined $values[0]);
 399                         }
 400                 }
 401                 else {
 402                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 403                 }
 404         }
 405
 406         if (!defined $smtp_encryption) {
 407                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 408                 if (defined $enc) {
 409                         $smtp_encryption = $enc;
 410                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 411                         $smtp_encryption = 'ssl';
 412                 }
 413         }
 414 }
 415
 416 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 417 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 418 read_config("sendemail.$identity") if (defined $identity);
 419 read_config("sendemail");
 420
 421 # fall back on builtin bool defaults
 422 foreach my $setting (values %config_bool_settings) {
 423         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 424 }
 425
 426 # 'default' encryption is none -- this only prevents a warning
 427 $smtp_encryption = '' unless (defined $smtp_encryption);
 428
 429 # Set CC suppressions
 430 my(%suppress_cc);
 431 if (@suppress_cc) {
 432         foreach my $entry (@suppress_cc) {
 433                 die "Unknown --suppress-cc field: '$entry'\n"
 434                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 435                 $suppress_cc{$entry} = 1;
 436         }
 437 }
 438
 439 if ($suppress_cc{'all'}) {
 440         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 441                 $suppress_cc{$entry} = 1;
 442         }
 443         delete $suppress_cc{'all'};
 444 }
 445
 446 # If explicit old-style ones are specified, they trump --suppress-cc.
 447 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 448 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 449
 450 if ($suppress_cc{'body'}) {
 451         foreach my $entry (qw (sob bodycc)) {
 452                 $suppress_cc{$entry} = 1;
 453         }
 454         delete $suppress_cc{'body'};
 455 }
 456
 457 # Set confirm's default value
 458 my $confirm_unconfigured = !defined $confirm;
 459 if ($confirm_unconfigured) {
 460         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 461 };
 462 die "Unknown --confirm setting: '$confirm'\n"
 463         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 464
 465 # Debugging, print out the suppressions.
 466 if (0) {
 467         print "suppressions:\n";
 468         foreach my $entry (keys %suppress_cc) {
 469                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 470         }
 471 }
 472
 473 my ($repoauthor, $repocommitter);
 474 ($repoauthor) = Git::ident_person(@repo, 'author');
 475 ($repocommitter) = Git::ident_person(@repo, 'committer');
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return Git::parse_mailboxes($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/:include:/) {
 496                 print STDERR "warning: `:include:` not supported: $_\n";
 497         } elsif (/[\/|]/) {
 498                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 499         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 500                 my ($alias, $addr) = ($1, $2);
 501                 $aliases{$alias} = [ split_addrs($addr) ];
 502         } else {
 503                 print STDERR "warning: sendmail line is not recognized: $_\n";
 504         }
 505 }
 506
 507 sub parse_sendmail_aliases {
 508         my $fh = shift;
 509         my $s = '';
 510         while (<$fh>) {
 511                 chomp;
 512                 next if /^\s*$/ || /^\s*#/;
 513                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 514                 parse_sendmail_alias($s) if $s;
 515                 $s = $_;
 516         }
 517         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 518         parse_sendmail_alias($s) if $s;
 519 }
 520
 521 my %parse_alias = (
 522         # multiline formats can be supported in the future
 523         mutt => sub { my $fh = shift; while (<$fh>) {
 524                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 525                         my ($alias, $addr) = ($1, $2);
 526                         $addr =~ s/#.*$//; # mutt allows # comments
 527                         # commas delimit multiple addresses
 528                         my @addr = split_addrs($addr);
 529
 530                         # quotes may be escaped in the file,
 531                         # unescape them so we do not double-escape them later.
 532                         s/\\"/"/g foreach @addr;
 533                         $aliases{$alias} = \@addr
 534                 }}},
 535         mailrc => sub { my $fh = shift; while (<$fh>) {
 536                 if (/^alias\s+(\S+)\s+(.*)$/) {
 537                         # spaces delimit multiple addresses
 538                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 539                 }}},
 540         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 541                 for (my $x = ''; defined($x); $x = $_) {
 542                         chomp $x;
 543                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 544                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 545                         $aliases{$1} = [ split_addrs($2) ];
 546                 }},
 547         elm => sub  { my $fh = shift;
 548                       while (<$fh>) {
 549                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 550                               my ($alias, $addr) = ($1, $2);
 551                                $aliases{$alias} = [ split_addrs($addr) ];
 552                           }
 553                       } },
 554         sendmail => \&parse_sendmail_aliases,
 555         gnus => sub { my $fh = shift; while (<$fh>) {
 556                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 557                         $aliases{$1} = [ $2 ];
 558                 }}}
 559 );
 560
 561 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 562         foreach my $file (@alias_files) {
 563                 open my $fh, '<', $file or die "opening $file: $!\n";
 564                 $parse_alias{$aliasfiletype}->($fh);
 565                 close $fh;
 566         }
 567 }
 568
 569 if ($dump_aliases) {
 570     print "$_\n" for (sort keys %aliases);
 571     exit(0);
 572 }
 573
 574 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 575 # $f is a revision list specification to be passed to format-patch.
 576 sub is_format_patch_arg {
 577         return unless $repo;
 578         my $f = shift;
 579         try {
 580                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 581                 if (defined($format_patch)) {
 582                         return $format_patch;
 583                 }
 584                 die(<<EOF);
 585 File '$f' exists but it could also be the range of commits
 586 to produce patches for.  Please disambiguate by...
 587
 588     * Saying "./$f" if you mean a file; or
 589     * Giving --format-patch option if you mean a range.
 590 EOF
 591         } catch Git::Error::Command with {
 592                 # Not a valid revision.  Treat it as a filename.
 593                 return 0;
 594         }
 595 }
 596
 597 # Now that all the defaults are set, process the rest of the command line
 598 # arguments and collect up the files that need to be processed.
 599 my @rev_list_opts;
 600 while (defined(my $f = shift @ARGV)) {
 601         if ($f eq "--") {
 602                 push @rev_list_opts, "--", @ARGV;
 603                 @ARGV = ();
 604         } elsif (-d $f and !is_format_patch_arg($f)) {
 605                 opendir my $dh, $f
 606                         or die "Failed to opendir $f: $!";
 607
 608                 push @files, grep { -f $_ } map { catfile($f, $_) }
 609                                 sort readdir $dh;
 610                 closedir $dh;
 611         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 612                 push @files, $f;
 613         } else {
 614                 push @rev_list_opts, $f;
 615         }
 616 }
 617
 618 if (@rev_list_opts) {
 619         die "Cannot run git format-patch from outside a repository\n"
 620                 unless $repo;
 621         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 622 }
 623
 624 if ($validate) {
 625         foreach my $f (@files) {
 626                 unless (-p $f) {
 627                         my $error = validate_patch($f);
 628                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 629                 }
 630         }
 631 }
 632
 633 if (@files) {
 634         unless ($quiet) {
 635                 print $_,"\n" for (@files);
 636         }
 637 } else {
 638         print STDERR "\nNo patch files specified!\n\n";
 639         usage();
 640 }
 641
 642 sub get_patch_subject {
 643         my $fn = shift;
 644         open (my $fh, '<', $fn);
 645         while (my $line = <$fh>) {
 646                 next unless ($line =~ /^Subject: (.*)$/);
 647                 close $fh;
 648                 return "GIT: $1\n";
 649         }
 650         close $fh;
 651         die "No subject line in $fn ?";
 652 }
 653
 654 if ($compose) {
 655         # Note that this does not need to be secure, but we will make a small
 656         # effort to have it be unique
 657         $compose_filename = ($repo ?
 658                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 659                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 660         open my $c, ">", $compose_filename
 661                 or die "Failed to open for writing $compose_filename: $!";
 662
 663
 664         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 665         my $tpl_subject = $initial_subject || '';
 666         my $tpl_reply_to = $initial_reply_to || '';
 667
 668         print $c <<EOT;
 669 From $tpl_sender # This line is ignored.
 670 GIT: Lines beginning in "GIT:" will be removed.
 671 GIT: Consider including an overall diffstat or table of contents
 672 GIT: for the patch you are writing.
 673 GIT:
 674 GIT: Clear the body content if you don't wish to send a summary.
 675 From: $tpl_sender
 676 Subject: $tpl_subject
 677 In-Reply-To: $tpl_reply_to
 678
 679 EOT
 680         for my $f (@files) {
 681                 print $c get_patch_subject($f);
 682         }
 683         close $c;
 684
 685         if ($annotate) {
 686                 do_edit($compose_filename, @files);
 687         } else {
 688                 do_edit($compose_filename);
 689         }
 690
 691         open my $c2, ">", $compose_filename . ".final"
 692                 or die "Failed to open $compose_filename.final : " . $!;
 693
 694         open $c, "<", $compose_filename
 695                 or die "Failed to open $compose_filename : " . $!;
 696
 697         my $need_8bit_cte = file_has_nonascii($compose_filename);
 698         my $in_body = 0;
 699         my $summary_empty = 1;
 700         if (!defined $compose_encoding) {
 701                 $compose_encoding = "UTF-8";
 702         }
 703         while(<$c>) {
 704                 next if m/^GIT:/;
 705                 if ($in_body) {
 706                         $summary_empty = 0 unless (/^\n$/);
 707                 } elsif (/^\n$/) {
 708                         $in_body = 1;
 709                         if ($need_8bit_cte) {
 710                                 print $c2 "MIME-Version: 1.0\n",
 711                                          "Content-Type: text/plain; ",
 712                                            "charset=$compose_encoding\n",
 713                                          "Content-Transfer-Encoding: 8bit\n";
 714                         }
 715                 } elsif (/^MIME-Version:/i) {
 716                         $need_8bit_cte = 0;
 717                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 718                         $initial_subject = $1;
 719                         my $subject = $initial_subject;
 720                         $_ = "Subject: " .
 721                                 quote_subject($subject, $compose_encoding) .
 722                                 "\n";
 723                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 724                         $initial_reply_to = $1;
 725                         next;
 726                 } elsif (/^From:\s*(.+)\s*$/i) {
 727                         $sender = $1;
 728                         next;
 729                 } elsif (/^(?:To|Cc|Bcc):/i) {
 730                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 731                         next;
 732                 }
 733                 print $c2 $_;
 734         }
 735         close $c;
 736         close $c2;
 737
 738         if ($summary_empty) {
 739                 print "Summary email is empty, skipping it\n";
 740                 $compose = -1;
 741         }
 742 } elsif ($annotate) {
 743         do_edit(@files);
 744 }
 745
 746 sub ask {
 747         my ($prompt, %arg) = @_;
 748         my $valid_re = $arg{valid_re};
 749         my $default = $arg{default};
 750         my $confirm_only = $arg{confirm_only};
 751         my $resp;
 752         my $i = 0;
 753         return defined $default ? $default : undef
 754                 unless defined $term->IN and defined fileno($term->IN) and
 755                        defined $term->OUT and defined fileno($term->OUT);
 756         while ($i++ < 10) {
 757                 $resp = $term->readline($prompt);
 758                 if (!defined $resp) { # EOF
 759                         print "\n";
 760                         return defined $default ? $default : undef;
 761                 }
 762                 if ($resp eq '' and defined $default) {
 763                         return $default;
 764                 }
 765                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 766                         return $resp;
 767                 }
 768                 if ($confirm_only) {
 769                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 770                         if (defined $yesno && $yesno =~ /y/i) {
 771                                 return $resp;
 772                         }
 773                 }
 774         }
 775         return;
 776 }
 777
 778 my %broken_encoding;
 779
 780 sub file_declares_8bit_cte {
 781         my $fn = shift;
 782         open (my $fh, '<', $fn);
 783         while (my $line = <$fh>) {
 784                 last if ($line =~ /^$/);
 785                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 786         }
 787         close $fh;
 788         return 0;
 789 }
 790
 791 foreach my $f (@files) {
 792         next unless (body_or_subject_has_nonascii($f)
 793                      && !file_declares_8bit_cte($f));
 794         $broken_encoding{$f} = 1;
 795 }
 796
 797 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 798         print "The following files are 8bit, but do not declare " .
 799                 "a Content-Transfer-Encoding.\n";
 800         foreach my $f (sort keys %broken_encoding) {
 801                 print "    $f\n";
 802         }
 803         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 804                                   valid_re => qr/.{4}/, confirm_only => 1,
 805                                   default => "UTF-8");
 806 }
 807
 808 if (!$force) {
 809         for my $f (@files) {
 810                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 811                         die "Refusing to send because the patch\n\t$f\n"
 812                                 . "has the template subject '*** SUBJECT HERE ***'. "
 813                                 . "Pass --force if you really want to send.\n";
 814                 }
 815         }
 816 }
 817
 818 if (defined $sender) {
 819         $sender =~ s/^\s+|\s+$//g;
 820         ($sender) = expand_aliases($sender);
 821 } else {
 822         $sender = $repoauthor || $repocommitter || '';
 823 }
 824
 825 # $sender could be an already sanitized address
 826 # (e.g. sendemail.from could be manually sanitized by user).
 827 # But it's a no-op to run sanitize_address on an already sanitized address.
 828 $sender = sanitize_address($sender);
 829
 830 my $prompting = 0;
 831 if (!@initial_to && !defined $to_cmd) {
 832         my $to = ask("Who should the emails be sent to (if any)? ",
 833                      default => "",
 834                      valid_re => qr/\@.*\./, confirm_only => 1);
 835         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 836         $prompting++;
 837 }
 838
 839 sub expand_aliases {
 840         return map { expand_one_alias($_) } @_;
 841 }
 842
 843 my %EXPANDED_ALIASES;
 844 sub expand_one_alias {
 845         my $alias = shift;
 846         if ($EXPANDED_ALIASES{$alias}) {
 847                 die "fatal: alias '$alias' expands to itself\n";
 848         }
 849         local $EXPANDED_ALIASES{$alias} = 1;
 850         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 851 }
 852
 853 @initial_to = process_address_list(@initial_to);
 854 @initial_cc = process_address_list(@initial_cc);
 855 @bcclist = process_address_list(@bcclist);
 856
 857 if ($thread && !defined $initial_reply_to && $prompting) {
 858         $initial_reply_to = ask(
 859                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 860                 default => "",
 861                 valid_re => qr/\@.*\./, confirm_only => 1);
 862 }
 863 if (defined $initial_reply_to) {
 864         $initial_reply_to =~ s/^\s*<?//;
 865         $initial_reply_to =~ s/>?\s*$//;
 866         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 867 }
 868
 869 if (!defined $smtp_server) {
 870         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 871                 if (-x $_) {
 872                         $smtp_server = $_;
 873                         last;
 874                 }
 875         }
 876         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 877 }
 878
 879 if ($compose && $compose > 0) {
 880         @files = ($compose_filename . ".final", @files);
 881 }
 882
 883 # Variables we set as part of the loop over files
 884 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 885         $needs_confirm, $message_num, $ask_default);
 886
 887 sub extract_valid_address {
 888         my $address = shift;
 889         my $local_part_regexp = qr/[^<>"\s@]+/;
 890         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 891
 892         # check for a local address:
 893         return $address if ($address =~ /^($local_part_regexp)$/);
 894
 895         $address =~ s/^\s*<(.*)>\s*$/$1/;
 896         if ($have_email_valid) {
 897                 return scalar Email::Valid->address($address);
 898         }
 899
 900         # less robust/correct than the monster regexp in Email::Valid,
 901         # but still does a 99% job, and one less dependency
 902         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 903         return;
 904 }
 905
 906 sub extract_valid_address_or_die {
 907         my $address = shift;
 908         $address = extract_valid_address($address);
 909         die "error: unable to extract a valid address from: $address\n"
 910                 if !$address;
 911         return $address;
 912 }
 913
 914 sub validate_address {
 915         my $address = shift;
 916         while (!extract_valid_address($address)) {
 917                 print STDERR "error: unable to extract a valid address from: $address\n";
 918                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 919                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 920                         default => 'q');
 921                 if (/^d/i) {
 922                         return undef;
 923                 } elsif (/^q/i) {
 924                         cleanup_compose_files();
 925                         exit(0);
 926                 }
 927                 $address = ask("Who should the email be sent to (if any)? ",
 928                         default => "",
 929                         valid_re => qr/\@.*\./, confirm_only => 1);
 930         }
 931         return $address;
 932 }
 933
 934 sub validate_address_list {
 935         return (grep { defined $_ }
 936                 map { validate_address($_) } @_);
 937 }
 938
 939 # Usually don't need to change anything below here.
 940
 941 # we make a "fake" message id by taking the current number
 942 # of seconds since the beginning of Unix time and tacking on
 943 # a random number to the end, in case we are called quicker than
 944 # 1 second since the last time we were called.
 945
 946 # We'll setup a template for the message id, using the "from" address:
 947
 948 my ($message_id_stamp, $message_id_serial);
 949 sub make_message_id {
 950         my $uniq;
 951         if (!defined $message_id_stamp) {
 952                 $message_id_stamp = sprintf("%s-%s", time, $$);
 953                 $message_id_serial = 0;
 954         }
 955         $message_id_serial++;
 956         $uniq = "$message_id_stamp-$message_id_serial";
 957
 958         my $du_part;
 959         for ($sender, $repocommitter, $repoauthor) {
 960                 $du_part = extract_valid_address(sanitize_address($_));
 961                 last if (defined $du_part and $du_part ne '');
 962         }
 963         if (not defined $du_part or $du_part eq '') {
 964                 require Sys::Hostname;
 965                 $du_part = 'user@' . Sys::Hostname::hostname();
 966         }
 967         my $message_id_template = "<%s-git-send-email-%s>";
 968         $message_id = sprintf($message_id_template, $uniq, $du_part);
 969         #print "new message id = $message_id\n"; # Was useful for debugging
 970 }
 971
 972
 973
 974 $time = time - scalar $#files;
 975
 976 sub unquote_rfc2047 {
 977         local ($_) = @_;
 978         my $charset;
 979         my $sep = qr/[ \t]+/;
 980         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 981                 my @words = split $sep, $&;
 982                 foreach (@words) {
 983                         m/$re_encoded_word/;
 984                         $charset = $1;
 985                         my $encoding = $2;
 986                         my $text = $3;
 987                         if ($encoding eq 'q' || $encoding eq 'Q') {
 988                                 $_ = $text;
 989                                 s/_/ /g;
 990                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 991                         } else {
 992                                 # other encodings not supported yet
 993                         }
 994                 }
 995                 join '', @words;
 996         }eg;
 997         return wantarray ? ($_, $charset) : $_;
 998 }
 999
1000 sub quote_rfc2047 {
1001         local $_ = shift;
1002         my $encoding = shift || 'UTF-8';
1003         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
1004         s/(.*)/=\?$encoding\?q\?$1\?=/;
1005         return $_;
1006 }
1007
1008 sub is_rfc2047_quoted {
1009         my $s = shift;
1010         length($s) <= 75 &&
1011         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1012 }
1013
1014 sub subject_needs_rfc2047_quoting {
1015         my $s = shift;
1016
1017         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1018 }
1019
1020 sub quote_subject {
1021         local $subject = shift;
1022         my $encoding = shift || 'UTF-8';
1023
1024         if (subject_needs_rfc2047_quoting($subject)) {
1025                 return quote_rfc2047($subject, $encoding);
1026         }
1027         return $subject;
1028 }
1029
1030 # use the simplest quoting being able to handle the recipient
1031 sub sanitize_address {
1032         my ($recipient) = @_;
1033
1034         # remove garbage after email address
1035         $recipient =~ s/(.*>).*$/$1/;
1036
1037         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1038
1039         if (not $recipient_name) {
1040                 return $recipient;
1041         }
1042
1043         # if recipient_name is already quoted, do nothing
1044         if (is_rfc2047_quoted($recipient_name)) {
1045                 return $recipient;
1046         }
1047
1048         # remove non-escaped quotes
1049         $recipient_name =~ s/(^|[^\\])"/$1/g;
1050
1051         # rfc2047 is needed if a non-ascii char is included
1052         if ($recipient_name =~ /[^[:ascii:]]/) {
1053                 $recipient_name = quote_rfc2047($recipient_name);
1054         }
1055
1056         # double quotes are needed if specials or CTLs are included
1057         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1058                 $recipient_name =~ s/([\\\r])/\\$1/g;
1059                 $recipient_name = qq["$recipient_name"];
1060         }
1061
1062         return "$recipient_name $recipient_addr";
1063
1064 }
1065
1066 sub sanitize_address_list {
1067         return (map { sanitize_address($_) } @_);
1068 }
1069
1070 sub process_address_list {
1071         my @addr_list = map { parse_address_line($_) } @_;
1072         @addr_list = expand_aliases(@addr_list);
1073         @addr_list = sanitize_address_list(@addr_list);
1074         @addr_list = validate_address_list(@addr_list);
1075         return @addr_list;
1076 }
1077
1078 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1079 #
1080 # Tightly configured MTAa require that a caller sends a real DNS
1081 # domain name that corresponds the IP address in the HELO/EHLO
1082 # handshake. This is used to verify the connection and prevent
1083 # spammers from trying to hide their identity. If the DNS and IP don't
1084 # match, the receiveing MTA may deny the connection.
1085 #
1086 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1087 #
1088 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1089 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1090 #
1091 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1092 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1093
1094 sub valid_fqdn {
1095         my $domain = shift;
1096         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1097 }
1098
1099 sub maildomain_net {
1100         my $maildomain;
1101
1102         if (eval { require Net::Domain; 1 }) {
1103                 my $domain = Net::Domain::domainname();
1104                 $maildomain = $domain if valid_fqdn($domain);
1105         }
1106
1107         return $maildomain;
1108 }
1109
1110 sub maildomain_mta {
1111         my $maildomain;
1112
1113         if (eval { require Net::SMTP; 1 }) {
1114                 for my $host (qw(mailhost localhost)) {
1115                         my $smtp = Net::SMTP->new($host);
1116                         if (defined $smtp) {
1117                                 my $domain = $smtp->domain;
1118                                 $smtp->quit;
1119
1120                                 $maildomain = $domain if valid_fqdn($domain);
1121
1122                                 last if $maildomain;
1123                         }
1124                 }
1125         }
1126
1127         return $maildomain;
1128 }
1129
1130 sub maildomain {
1131         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1132 }
1133
1134 sub smtp_host_string {
1135         if (defined $smtp_server_port) {
1136                 return "$smtp_server:$smtp_server_port";
1137         } else {
1138                 return $smtp_server;
1139         }
1140 }
1141
1142 # Returns 1 if authentication succeeded or was not necessary
1143 # (smtp_user was not specified), and 0 otherwise.
1144
1145 sub smtp_auth_maybe {
1146         if (!defined $smtp_authuser || $auth) {
1147                 return 1;
1148         }
1149
1150         # Workaround AUTH PLAIN/LOGIN interaction defect
1151         # with Authen::SASL::Cyrus
1152         eval {
1153                 require Authen::SASL;
1154                 Authen::SASL->import(qw(Perl));
1155         };
1156
1157         # Check mechanism naming as defined in:
1158         # https://tools.ietf.org/html/rfc4422#page-8
1159         if ($smtp_auth && $smtp_auth !~ /^(\b[A-Z0-9-_]{1,20}\s*)*$/) {
1160                 die "invalid smtp auth: '${smtp_auth}'";
1161         }
1162
1163         # TODO: Authentication may fail not because credentials were
1164         # invalid but due to other reasons, in which we should not
1165         # reject credentials.
1166         $auth = Git::credential({
1167                 'protocol' => 'smtp',
1168                 'host' => smtp_host_string(),
1169                 'username' => $smtp_authuser,
1170                 # if there's no password, "git credential fill" will
1171                 # give us one, otherwise it'll just pass this one.
1172                 'password' => $smtp_authpass
1173         }, sub {
1174                 my $cred = shift;
1175
1176                 if ($smtp_auth) {
1177                         my $sasl = Authen::SASL->new(
1178                                 mechanism => $smtp_auth,
1179                                 callback => {
1180                                         user => $cred->{'username'},
1181                                         pass => $cred->{'password'},
1182                                         authname => $cred->{'username'},
1183                                 }
1184                         );
1185
1186                         return !!$smtp->auth($sasl);
1187                 }
1188
1189                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1190         });
1191
1192         return $auth;
1193 }
1194
1195 sub ssl_verify_params {
1196         eval {
1197                 require IO::Socket::SSL;
1198                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1199         };
1200         if ($@) {
1201                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1202                 return;
1203         }
1204
1205         if (!defined $smtp_ssl_cert_path) {
1206                 # use the OpenSSL defaults
1207                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1208         }
1209
1210         if ($smtp_ssl_cert_path eq "") {
1211                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1212         } elsif (-d $smtp_ssl_cert_path) {
1213                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1214                         SSL_ca_path => $smtp_ssl_cert_path);
1215         } elsif (-f $smtp_ssl_cert_path) {
1216                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1217                         SSL_ca_file => $smtp_ssl_cert_path);
1218         } else {
1219                 die "CA path \"$smtp_ssl_cert_path\" does not exist";
1220         }
1221 }
1222
1223 sub file_name_is_absolute {
1224         my ($path) = @_;
1225
1226         # msys does not grok DOS drive-prefixes
1227         if ($^O eq 'msys') {
1228                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1229         }
1230
1231         require File::Spec::Functions;
1232         return File::Spec::Functions::file_name_is_absolute($path);
1233 }
1234
1235 # Returns 1 if the message was sent, and 0 otherwise.
1236 # In actuality, the whole program dies when there
1237 # is an error sending a message.
1238
1239 sub send_message {
1240         my @recipients = unique_email_list(@to);
1241         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1242                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1243                     }
1244                @cc);
1245         my $to = join (",\n\t", @recipients);
1246         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1247         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1248         my $date = format_2822_time($time++);
1249         my $gitversion = '@@GIT_VERSION@@';
1250         if ($gitversion =~ m/..GIT_VERSION../) {
1251             $gitversion = Git::version();
1252         }
1253
1254         my $cc = join(",\n\t", unique_email_list(@cc));
1255         my $ccline = "";
1256         if ($cc ne '') {
1257                 $ccline = "\nCc: $cc";
1258         }
1259         make_message_id() unless defined($message_id);
1260
1261         my $header = "From: $sender
1262 To: $to${ccline}
1263 Subject: $subject
1264 Date: $date
1265 Message-Id: $message_id
1266 ";
1267         if ($use_xmailer) {
1268                 $header .= "X-Mailer: git-send-email $gitversion\n";
1269         }
1270         if ($reply_to) {
1271
1272                 $header .= "In-Reply-To: $reply_to\n";
1273                 $header .= "References: $references\n";
1274         }
1275         if (@xh) {
1276                 $header .= join("\n", @xh) . "\n";
1277         }
1278
1279         my @sendmail_parameters = ('-i', @recipients);
1280         my $raw_from = $sender;
1281         if (defined $envelope_sender && $envelope_sender ne "auto") {
1282                 $raw_from = $envelope_sender;
1283         }
1284         $raw_from = extract_valid_address($raw_from);
1285         unshift (@sendmail_parameters,
1286                         '-f', $raw_from) if(defined $envelope_sender);
1287
1288         if ($needs_confirm && !$dry_run) {
1289                 print "\n$header\n";
1290                 if ($needs_confirm eq "inform") {
1291                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1292                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1293                         print "    The Cc list above has been expanded by additional\n";
1294                         print "    addresses found in the patch commit message. By default\n";
1295                         print "    send-email prompts before sending whenever this occurs.\n";
1296                         print "    This behavior is controlled by the sendemail.confirm\n";
1297                         print "    configuration setting.\n";
1298                         print "\n";
1299                         print "    For additional information, run 'git send-email --help'.\n";
1300                         print "    To retain the current behavior, but squelch this message,\n";
1301                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1302                 }
1303                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1304                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1305                          default => $ask_default);
1306                 die "Send this email reply required" unless defined $_;
1307                 if (/^n/i) {
1308                         return 0;
1309                 } elsif (/^q/i) {
1310                         cleanup_compose_files();
1311                         exit(0);
1312                 } elsif (/^a/i) {
1313                         $confirm = 'never';
1314                 }
1315         }
1316
1317         unshift (@sendmail_parameters, @smtp_server_options);
1318
1319         if ($dry_run) {
1320                 # We don't want to send the email.
1321         } elsif (file_name_is_absolute($smtp_server)) {
1322                 my $pid = open my $sm, '|-';
1323                 defined $pid or die $!;
1324                 if (!$pid) {
1325                         exec($smtp_server, @sendmail_parameters) or die $!;
1326                 }
1327                 print $sm "$header\n$message";
1328                 close $sm or die $!;
1329         } else {
1330
1331                 if (!defined $smtp_server) {
1332                         die "The required SMTP server is not properly defined."
1333                 }
1334
1335                 if ($smtp_encryption eq 'ssl') {
1336                         $smtp_server_port ||= 465; # ssmtp
1337                         require Net::SMTP::SSL;
1338                         $smtp_domain ||= maildomain();
1339                         require IO::Socket::SSL;
1340
1341                         # Suppress "variable accessed once" warning.
1342                         {
1343                                 no warnings 'once';
1344                                 $IO::Socket::SSL::DEBUG = 1;
1345                         }
1346
1347                         # Net::SMTP::SSL->new() does not forward any SSL options
1348                         IO::Socket::SSL::set_client_defaults(
1349                                 ssl_verify_params());
1350                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1351                                                       Hello => $smtp_domain,
1352                                                       Port => $smtp_server_port,
1353                                                       Debug => $debug_net_smtp);
1354                 }
1355                 else {
1356                         require Net::SMTP;
1357                         $smtp_domain ||= maildomain();
1358                         $smtp_server_port ||= 25;
1359                         $smtp ||= Net::SMTP->new($smtp_server,
1360                                                  Hello => $smtp_domain,
1361                                                  Debug => $debug_net_smtp,
1362                                                  Port => $smtp_server_port);
1363                         if ($smtp_encryption eq 'tls' && $smtp) {
1364                                 require Net::SMTP::SSL;
1365                                 $smtp->command('STARTTLS');
1366                                 $smtp->response();
1367                                 if ($smtp->code == 220) {
1368                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1369                                                                           ssl_verify_params())
1370                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1371                                         $smtp_encryption = '';
1372                                         # Send EHLO again to receive fresh
1373                                         # supported commands
1374                                         $smtp->hello($smtp_domain);
1375                                 } else {
1376                                         die "Server does not support STARTTLS! ".$smtp->message;
1377                                 }
1378                         }
1379                 }
1380
1381                 if (!$smtp) {
1382                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1383                             "VALUES: server=$smtp_server ",
1384                             "encryption=$smtp_encryption ",
1385                             "hello=$smtp_domain",
1386                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1387                 }
1388
1389                 smtp_auth_maybe or die $smtp->message;
1390
1391                 $smtp->mail( $raw_from ) or die $smtp->message;
1392                 $smtp->to( @recipients ) or die $smtp->message;
1393                 $smtp->data or die $smtp->message;
1394                 $smtp->datasend("$header\n") or die $smtp->message;
1395                 my @lines = split /^/, $message;
1396                 foreach my $line (@lines) {
1397                         $smtp->datasend("$line") or die $smtp->message;
1398                 }
1399                 $smtp->dataend() or die $smtp->message;
1400                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1401         }
1402         if ($quiet) {
1403                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1404         } else {
1405                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1406                 if (!file_name_is_absolute($smtp_server)) {
1407                         print "Server: $smtp_server\n";
1408                         print "MAIL FROM:<$raw_from>\n";
1409                         foreach my $entry (@recipients) {
1410                             print "RCPT TO:<$entry>\n";
1411                         }
1412                 } else {
1413                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1414                 }
1415                 print $header, "\n";
1416                 if ($smtp) {
1417                         print "Result: ", $smtp->code, ' ',
1418                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1419                 } else {
1420                         print "Result: OK\n";
1421                 }
1422         }
1423
1424         return 1;
1425 }
1426
1427 $reply_to = $initial_reply_to;
1428 $references = $initial_reply_to || '';
1429 $subject = $initial_subject;
1430 $message_num = 0;
1431
1432 foreach my $t (@files) {
1433         open my $fh, "<", $t or die "can't open file $t";
1434
1435         my $author = undef;
1436         my $sauthor = undef;
1437         my $author_encoding;
1438         my $has_content_type;
1439         my $body_encoding;
1440         my $xfer_encoding;
1441         my $has_mime_version;
1442         @to = ();
1443         @cc = ();
1444         @xh = ();
1445         my $input_format = undef;
1446         my @header = ();
1447         $message = "";
1448         $message_num++;
1449         # First unfold multiline header fields
1450         while(<$fh>) {
1451                 last if /^\s*$/;
1452                 if (/^\s+\S/ and @header) {
1453                         chomp($header[$#header]);
1454                         s/^\s+/ /;
1455                         $header[$#header] .= $_;
1456             } else {
1457                         push(@header, $_);
1458                 }
1459         }
1460         # Now parse the header
1461         foreach(@header) {
1462                 if (/^From /) {
1463                         $input_format = 'mbox';
1464                         next;
1465                 }
1466                 chomp;
1467                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1468                         $input_format = 'mbox';
1469                 }
1470
1471                 if (defined $input_format && $input_format eq 'mbox') {
1472                         if (/^Subject:\s+(.*)$/i) {
1473                                 $subject = $1;
1474                         }
1475                         elsif (/^From:\s+(.*)$/i) {
1476                                 ($author, $author_encoding) = unquote_rfc2047($1);
1477                                 $sauthor = sanitize_address($author);
1478                                 next if $suppress_cc{'author'};
1479                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1480                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1481                                         $1, $_) unless $quiet;
1482                                 push @cc, $1;
1483                         }
1484                         elsif (/^To:\s+(.*)$/i) {
1485                                 foreach my $addr (parse_address_line($1)) {
1486                                         printf("(mbox) Adding to: %s from line '%s'\n",
1487                                                 $addr, $_) unless $quiet;
1488                                         push @to, $addr;
1489                                 }
1490                         }
1491                         elsif (/^Cc:\s+(.*)$/i) {
1492                                 foreach my $addr (parse_address_line($1)) {
1493                                         my $qaddr = unquote_rfc2047($addr);
1494                                         my $saddr = sanitize_address($qaddr);
1495                                         if ($saddr eq $sender) {
1496                                                 next if ($suppress_cc{'self'});
1497                                         } else {
1498                                                 next if ($suppress_cc{'cc'});
1499                                         }
1500                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1501                                                 $addr, $_) unless $quiet;
1502                                         push @cc, $addr;
1503                                 }
1504                         }
1505                         elsif (/^Content-type:/i) {
1506                                 $has_content_type = 1;
1507                                 if (/charset="?([^ "]+)/) {
1508                                         $body_encoding = $1;
1509                                 }
1510                                 push @xh, $_;
1511                         }
1512                         elsif (/^MIME-Version/i) {
1513                                 $has_mime_version = 1;
1514                                 push @xh, $_;
1515                         }
1516                         elsif (/^Message-Id: (.*)/i) {
1517                                 $message_id = $1;
1518                         }
1519                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1520                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1521                         }
1522                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1523                                 push @xh, $_;
1524                         }
1525
1526                 } else {
1527                         # In the traditional
1528                         # "send lots of email" format,
1529                         # line 1 = cc
1530                         # line 2 = subject
1531                         # So let's support that, too.
1532                         $input_format = 'lots';
1533                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1534                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1535                                         $_, $_) unless $quiet;
1536                                 push @cc, $_;
1537                         } elsif (!defined $subject) {
1538                                 $subject = $_;
1539                         }
1540                 }
1541         }
1542         # Now parse the message body
1543         while(<$fh>) {
1544                 $message .=  $_;
1545                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1546                         chomp;
1547                         my ($what, $c) = ($1, $2);
1548                         chomp $c;
1549                         my $sc = sanitize_address($c);
1550                         if ($sc eq $sender) {
1551                                 next if ($suppress_cc{'self'});
1552                         } else {
1553                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1554                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1555                         }
1556                         push @cc, $c;
1557                         printf("(body) Adding cc: %s from line '%s'\n",
1558                                 $c, $_) unless $quiet;
1559                 }
1560         }
1561         close $fh;
1562
1563         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1564                 if defined $to_cmd;
1565         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1566                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1567
1568         if ($broken_encoding{$t} && !$has_content_type) {
1569                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1570                 $has_content_type = 1;
1571                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1572                 $body_encoding = $auto_8bit_encoding;
1573         }
1574
1575         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1576                 $subject = quote_subject($subject, $auto_8bit_encoding);
1577         }
1578
1579         if (defined $sauthor and $sauthor ne $sender) {
1580                 $message = "From: $author\n\n$message";
1581                 if (defined $author_encoding) {
1582                         if ($has_content_type) {
1583                                 if ($body_encoding eq $author_encoding) {
1584                                         # ok, we already have the right encoding
1585                                 }
1586                                 else {
1587                                         # uh oh, we should re-encode
1588                                 }
1589                         }
1590                         else {
1591                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1592                                 $has_content_type = 1;
1593                                 push @xh,
1594                                   "Content-Type: text/plain; charset=$author_encoding";
1595                         }
1596                 }
1597         }
1598         if (defined $target_xfer_encoding) {
1599                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1600                 $message = apply_transfer_encoding(
1601                         $message, $xfer_encoding, $target_xfer_encoding);
1602                 $xfer_encoding = $target_xfer_encoding;
1603         }
1604         if (defined $xfer_encoding) {
1605                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1606         }
1607         if (defined $xfer_encoding or $has_content_type) {
1608                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1609         }
1610
1611         $needs_confirm = (
1612                 $confirm eq "always" or
1613                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1614                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1615         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1616
1617         @to = process_address_list(@to);
1618         @cc = process_address_list(@cc);
1619
1620         @to = (@initial_to, @to);
1621         @cc = (@initial_cc, @cc);
1622
1623         if ($message_num == 1) {
1624                 if (defined $cover_cc and $cover_cc) {
1625                         @initial_cc = @cc;
1626                 }
1627                 if (defined $cover_to and $cover_to) {
1628                         @initial_to = @to;
1629                 }
1630         }
1631
1632         my $message_was_sent = send_message();
1633
1634         # set up for the next message
1635         if ($thread && $message_was_sent &&
1636                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1637                 $message_num == 1)) {
1638                 $reply_to = $message_id;
1639                 if (length $references > 0) {
1640                         $references .= "\n $message_id";
1641                 } else {
1642                         $references = "$message_id";
1643                 }
1644         }
1645         $message_id = undef;
1646 }
1647
1648 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1649 # and return a results array
1650 sub recipients_cmd {
1651         my ($prefix, $what, $cmd, $file) = @_;
1652
1653         my @addresses = ();
1654         open my $fh, "-|", "$cmd \Q$file\E"
1655             or die "($prefix) Could not execute '$cmd'";
1656         while (my $address = <$fh>) {
1657                 $address =~ s/^\s*//g;
1658                 $address =~ s/\s*$//g;
1659                 $address = sanitize_address($address);
1660                 next if ($address eq $sender and $suppress_cc{'self'});
1661                 push @addresses, $address;
1662                 printf("($prefix) Adding %s: %s from: '%s'\n",
1663                        $what, $address, $cmd) unless $quiet;
1664                 }
1665         close $fh
1666             or die "($prefix) failed to close pipe to '$cmd'";
1667         return @addresses;
1668 }
1669
1670 cleanup_compose_files();
1671
1672 sub cleanup_compose_files {
1673         unlink($compose_filename, $compose_filename . ".final") if $compose;
1674 }
1675
1676 $smtp->quit if $smtp;
1677
1678 sub apply_transfer_encoding {
1679         my $message = shift;
1680         my $from = shift;
1681         my $to = shift;
1682
1683         return $message if ($from eq $to and $from ne '7bit');
1684
1685         require MIME::QuotedPrint;
1686         require MIME::Base64;
1687
1688         $message = MIME::QuotedPrint::decode($message)
1689                 if ($from eq 'quoted-printable');
1690         $message = MIME::Base64::decode($message)
1691                 if ($from eq 'base64');
1692
1693         die "cannot send message as 7bit"
1694                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1695         return $message
1696                 if ($to eq '7bit' or $to eq '8bit');
1697         return MIME::QuotedPrint::encode($message, "\n", 0)
1698                 if ($to eq 'quoted-printable');
1699         return MIME::Base64::encode($message, "\n")
1700                 if ($to eq 'base64');
1701         die "invalid transfer encoding";
1702 }
1703
1704 sub unique_email_list {
1705         my %seen;
1706         my @emails;
1707
1708         foreach my $entry (@_) {
1709                 my $clean = extract_valid_address_or_die($entry);
1710                 $seen{$clean} ||= 0;
1711                 next if $seen{$clean}++;
1712                 push @emails, $entry;
1713         }
1714         return @emails;
1715 }
1716
1717 sub validate_patch {
1718         my $fn = shift;
1719         open(my $fh, '<', $fn)
1720                 or die "unable to open $fn: $!\n";
1721         while (my $line = <$fh>) {
1722                 if (length($line) > 998) {
1723                         return "$.: patch contains a line longer than 998 characters";
1724                 }
1725         }
1726         return;
1727 }
1728
1729 sub file_has_nonascii {
1730         my $fn = shift;
1731         open(my $fh, '<', $fn)
1732                 or die "unable to open $fn: $!\n";
1733         while (my $line = <$fh>) {
1734                 return 1 if $line =~ /[^[:ascii:]]/;
1735         }
1736         return 0;
1737 }
1738
1739 sub body_or_subject_has_nonascii {
1740         my $fn = shift;
1741         open(my $fh, '<', $fn)
1742                 or die "unable to open $fn: $!\n";
1743         while (my $line = <$fh>) {
1744                 last if $line =~ /^$/;
1745                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1746         }
1747         while (my $line = <$fh>) {
1748                 return 1 if $line =~ /[^[:ascii:]]/;
1749         }
1750         return 0;
1751 }