git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  60
  61   Sending:
  62     --envelope-sender       <str>  * Email envelope sender.
  63     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  64                                      is optional. Default 'localhost'.
  65     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  66     --smtp-server-port      <int>  * Outgoing SMTP server port.
  67     --smtp-user             <str>  * Username for SMTP-AUTH.
  68     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  69     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  70     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  71     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  72     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  73
  74   Automating:
  75     --identity              <str>  * Use the sendemail.<id> options.
  76     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  77     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  78     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  79     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  80     --[no-]suppress-from           * Send to self. Default off.
  81     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  82     --[no-]thread                  * Use In-Reply-To: field. Default on.
  83
  84   Administering:
  85     --confirm               <str>  * Confirm recipients before sending;
  86                                      auto, cc, compose, always, or never.
  87     --quiet                        * Output one line of info per email.
  88     --dry-run                      * Don't actually send the emails.
  89     --[no-]validate                * Perform patch sanity checks. Default on.
  90     --[no-]format-patch            * understand any non optional arguments as
  91                                      `git format-patch` ones.
  92     --force                        * Send even if safety checks would prevent it.
  93
  94 EOT
  95         exit(1);
  96 }
  97
  98 # most mail servers generate the Date: header, but not all...
  99 sub format_2822_time {
 100         my ($time) = @_;
 101         my @localtm = localtime($time);
 102         my @gmttm = gmtime($time);
 103         my $localmin = $localtm[1] + $localtm[2] * 60;
 104         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 105         if ($localtm[0] != $gmttm[0]) {
 106                 die "local zone differs from GMT by a non-minute interval\n";
 107         }
 108         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 109                 $localmin += 1440;
 110         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 111                 $localmin -= 1440;
 112         } elsif ($gmttm[6] != $localtm[6]) {
 113                 die "local time offset greater than or equal to 24 hours\n";
 114         }
 115         my $offset = $localmin - $gmtmin;
 116         my $offhour = $offset / 60;
 117         my $offmin = abs($offset % 60);
 118         if (abs($offhour) >= 24) {
 119                 die ("local time offset greater than or equal to 24 hours\n");
 120         }
 121
 122         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 123                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 124                        $localtm[3],
 125                        qw(Jan Feb Mar Apr May Jun
 126                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 127                        $localtm[5]+1900,
 128                        $localtm[2],
 129                        $localtm[1],
 130                        $localtm[0],
 131                        ($offset >= 0) ? '+' : '-',
 132                        abs($offhour),
 133                        $offmin,
 134                        );
 135 }
 136
 137 my $have_email_valid = eval { require Email::Valid; 1 };
 138 my $have_mail_address = eval { require Mail::Address; 1 };
 139 my $smtp;
 140 my $auth;
 141
 142 # Variables we fill in automatically, or via prompting:
 143 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 144         $initial_reply_to,$initial_subject,@files,
 145         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 146
 147 my $envelope_sender;
 148
 149 # Example reply to:
 150 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 151
 152 my $repo = eval { Git->repository() };
 153 my @repo = $repo ? ($repo) : ();
 154 my $term = eval {
 155         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 156                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 157                 : new Term::ReadLine 'git-send-email';
 158 };
 159 if ($@) {
 160         $term = new FakeTerm "$@: going non-interactive";
 161 }
 162
 163 # Behavior modification variables
 164 my ($quiet, $dry_run) = (0, 0);
 165 my $format_patch;
 166 my $compose_filename;
 167 my $force = 0;
 168
 169 # Handle interactive edition of files.
 170 my $multiedit;
 171 my $editor;
 172
 173 sub do_edit {
 174         if (!defined($editor)) {
 175                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 176         }
 177         if (defined($multiedit) && !$multiedit) {
 178                 map {
 179                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 180                         if (($? & 127) || ($? >> 8)) {
 181                                 die("the editor exited uncleanly, aborting everything");
 182                         }
 183                 } @_;
 184         } else {
 185                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 186                 if (($? & 127) || ($? >> 8)) {
 187                         die("the editor exited uncleanly, aborting everything");
 188                 }
 189         }
 190 }
 191
 192 # Variables with corresponding config settings
 193 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 194 my ($to_cmd, $cc_cmd);
 195 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 196 my ($smtp_authuser, $smtp_encryption);
 197 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 198 my ($validate, $confirm);
 199 my (@suppress_cc);
 200 my ($auto_8bit_encoding);
 201
 202 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 203
 204 my $not_set_by_user = "true but not set by the user";
 205
 206 my %config_bool_settings = (
 207     "thread" => [\$thread, 1],
 208     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 209     "suppressfrom" => [\$suppress_from, undef],
 210     "signedoffbycc" => [\$signed_off_by_cc, undef],
 211     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 212     "validate" => [\$validate, 1],
 213     "multiedit" => [\$multiedit, undef]
 214 );
 215
 216 my %config_settings = (
 217     "smtpserver" => \$smtp_server,
 218     "smtpserverport" => \$smtp_server_port,
 219     "smtpserveroption" => \@smtp_server_options,
 220     "smtpuser" => \$smtp_authuser,
 221     "smtppass" => \$smtp_authpass,
 222     "smtpdomain" => \$smtp_domain,
 223     "to" => \@initial_to,
 224     "tocmd" => \$to_cmd,
 225     "cc" => \@initial_cc,
 226     "cccmd" => \$cc_cmd,
 227     "aliasfiletype" => \$aliasfiletype,
 228     "bcc" => \@bcclist,
 229     "suppresscc" => \@suppress_cc,
 230     "envelopesender" => \$envelope_sender,
 231     "confirm"   => \$confirm,
 232     "from" => \$sender,
 233     "assume8bitencoding" => \$auto_8bit_encoding,
 234 );
 235
 236 my %config_path_settings = (
 237     "aliasesfile" => \@alias_files,
 238 );
 239
 240 # Help users prepare for 1.7.0
 241 sub chain_reply_to {
 242         if (defined $chain_reply_to &&
 243             $chain_reply_to eq $not_set_by_user) {
 244                 print STDERR
 245                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 246                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 247                     "you want to keep --chain-reply-to as your default.\n";
 248                 $chain_reply_to = 0;
 249         }
 250         return $chain_reply_to;
 251 }
 252
 253 # Handle Uncouth Termination
 254 sub signal_handler {
 255
 256         # Make text normal
 257         print color("reset"), "\n";
 258
 259         # SMTP password masked
 260         system "stty echo";
 261
 262         # tmp files from --compose
 263         if (defined $compose_filename) {
 264                 if (-e $compose_filename) {
 265                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 266                 }
 267                 if (-e ($compose_filename . ".final")) {
 268                         print "'$compose_filename.final' contains the composed email.\n"
 269                 }
 270         }
 271
 272         exit;
 273 };
 274
 275 $SIG{TERM} = \&signal_handler;
 276 $SIG{INT}  = \&signal_handler;
 277
 278 # Begin by accumulating all the variables (defined above), that we will end up
 279 # needing, first, from the command line:
 280
 281 my $help;
 282 my $rc = GetOptions("h" => \$help,
 283                     "sender|from=s" => \$sender,
 284                     "in-reply-to=s" => \$initial_reply_to,
 285                     "subject=s" => \$initial_subject,
 286                     "to=s" => \@initial_to,
 287                     "to-cmd=s" => \$to_cmd,
 288                     "no-to" => \$no_to,
 289                     "cc=s" => \@initial_cc,
 290                     "no-cc" => \$no_cc,
 291                     "bcc=s" => \@bcclist,
 292                     "no-bcc" => \$no_bcc,
 293                     "chain-reply-to!" => \$chain_reply_to,
 294                     "smtp-server=s" => \$smtp_server,
 295                     "smtp-server-option=s" => \@smtp_server_options,
 296                     "smtp-server-port=s" => \$smtp_server_port,
 297                     "smtp-user=s" => \$smtp_authuser,
 298                     "smtp-pass:s" => \$smtp_authpass,
 299                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 300                     "smtp-encryption=s" => \$smtp_encryption,
 301                     "smtp-debug:i" => \$debug_net_smtp,
 302                     "smtp-domain:s" => \$smtp_domain,
 303                     "identity=s" => \$identity,
 304                     "annotate" => \$annotate,
 305                     "compose" => \$compose,
 306                     "quiet" => \$quiet,
 307                     "cc-cmd=s" => \$cc_cmd,
 308                     "suppress-from!" => \$suppress_from,
 309                     "suppress-cc=s" => \@suppress_cc,
 310                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 311                     "confirm=s" => \$confirm,
 312                     "dry-run" => \$dry_run,
 313                     "envelope-sender=s" => \$envelope_sender,
 314                     "thread!" => \$thread,
 315                     "validate!" => \$validate,
 316                     "format-patch!" => \$format_patch,
 317                     "8bit-encoding=s" => \$auto_8bit_encoding,
 318                     "force" => \$force,
 319          );
 320
 321 usage() if $help;
 322 unless ($rc) {
 323     usage();
 324 }
 325
 326 die "Cannot run git format-patch from outside a repository\n"
 327         if $format_patch and not $repo;
 328
 329 # Now, let's fill any that aren't set in with defaults:
 330
 331 sub read_config {
 332         my ($prefix) = @_;
 333
 334         foreach my $setting (keys %config_bool_settings) {
 335                 my $target = $config_bool_settings{$setting}->[0];
 336                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 337         }
 338
 339         foreach my $setting (keys %config_path_settings) {
 340                 my $target = $config_path_settings{$setting};
 341                 if (ref($target) eq "ARRAY") {
 342                         unless (@$target) {
 343                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 344                                 @$target = @values if (@values && defined $values[0]);
 345                         }
 346                 }
 347                 else {
 348                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 349                 }
 350         }
 351
 352         foreach my $setting (keys %config_settings) {
 353                 my $target = $config_settings{$setting};
 354                 next if $setting eq "to" and defined $no_to;
 355                 next if $setting eq "cc" and defined $no_cc;
 356                 next if $setting eq "bcc" and defined $no_bcc;
 357                 if (ref($target) eq "ARRAY") {
 358                         unless (@$target) {
 359                                 my @values = Git::config(@repo, "$prefix.$setting");
 360                                 @$target = @values if (@values && defined $values[0]);
 361                         }
 362                 }
 363                 else {
 364                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 365                 }
 366         }
 367
 368         if (!defined $smtp_encryption) {
 369                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 370                 if (defined $enc) {
 371                         $smtp_encryption = $enc;
 372                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 373                         $smtp_encryption = 'ssl';
 374                 }
 375         }
 376 }
 377
 378 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 379 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 380 read_config("sendemail.$identity") if (defined $identity);
 381 read_config("sendemail");
 382
 383 # fall back on builtin bool defaults
 384 foreach my $setting (values %config_bool_settings) {
 385         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 386 }
 387
 388 # 'default' encryption is none -- this only prevents a warning
 389 $smtp_encryption = '' unless (defined $smtp_encryption);
 390
 391 # Set CC suppressions
 392 my(%suppress_cc);
 393 if (@suppress_cc) {
 394         foreach my $entry (@suppress_cc) {
 395                 die "Unknown --suppress-cc field: '$entry'\n"
 396                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 397                 $suppress_cc{$entry} = 1;
 398         }
 399 }
 400
 401 if ($suppress_cc{'all'}) {
 402         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 403                 $suppress_cc{$entry} = 1;
 404         }
 405         delete $suppress_cc{'all'};
 406 }
 407
 408 # If explicit old-style ones are specified, they trump --suppress-cc.
 409 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 410 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 411
 412 if ($suppress_cc{'body'}) {
 413         foreach my $entry (qw (sob bodycc)) {
 414                 $suppress_cc{$entry} = 1;
 415         }
 416         delete $suppress_cc{'body'};
 417 }
 418
 419 # Set confirm's default value
 420 my $confirm_unconfigured = !defined $confirm;
 421 if ($confirm_unconfigured) {
 422         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 423 };
 424 die "Unknown --confirm setting: '$confirm'\n"
 425         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 426
 427 # Debugging, print out the suppressions.
 428 if (0) {
 429         print "suppressions:\n";
 430         foreach my $entry (keys %suppress_cc) {
 431                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 432         }
 433 }
 434
 435 my ($repoauthor, $repocommitter);
 436 ($repoauthor) = Git::ident_person(@repo, 'author');
 437 ($repocommitter) = Git::ident_person(@repo, 'committer');
 438
 439 # Verify the user input
 440
 441 foreach my $entry (@initial_to) {
 442         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 443 }
 444
 445 foreach my $entry (@initial_cc) {
 446         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@bcclist) {
 450         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 sub parse_address_line {
 454         if ($have_mail_address) {
 455                 return map { $_->format } Mail::Address->parse($_[0]);
 456         } else {
 457                 return split_addrs($_[0]);
 458         }
 459 }
 460
 461 sub split_addrs {
 462         return quotewords('\s*,\s*', 1, @_);
 463 }
 464
 465 my %aliases;
 466 my %parse_alias = (
 467         # multiline formats can be supported in the future
 468         mutt => sub { my $fh = shift; while (<$fh>) {
 469                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 470                         my ($alias, $addr) = ($1, $2);
 471                         $addr =~ s/#.*$//; # mutt allows # comments
 472                          # commas delimit multiple addresses
 473                         $aliases{$alias} = [ split_addrs($addr) ];
 474                 }}},
 475         mailrc => sub { my $fh = shift; while (<$fh>) {
 476                 if (/^alias\s+(\S+)\s+(.*)$/) {
 477                         # spaces delimit multiple addresses
 478                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 479                 }}},
 480         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 481                 for (my $x = ''; defined($x); $x = $_) {
 482                         chomp $x;
 483                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 484                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 485                         $aliases{$1} = [ split_addrs($2) ];
 486                 }},
 487         elm => sub  { my $fh = shift;
 488                       while (<$fh>) {
 489                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 490                               my ($alias, $addr) = ($1, $2);
 491                                $aliases{$alias} = [ split_addrs($addr) ];
 492                           }
 493                       } },
 494
 495         gnus => sub { my $fh = shift; while (<$fh>) {
 496                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 497                         $aliases{$1} = [ $2 ];
 498                 }}}
 499 );
 500
 501 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 502         foreach my $file (@alias_files) {
 503                 open my $fh, '<', $file or die "opening $file: $!\n";
 504                 $parse_alias{$aliasfiletype}->($fh);
 505                 close $fh;
 506         }
 507 }
 508
 509 ($sender) = expand_aliases($sender) if defined $sender;
 510
 511 # returns 1 if the conflict must be solved using it as a format-patch argument
 512 sub check_file_rev_conflict($) {
 513         return unless $repo;
 514         my $f = shift;
 515         try {
 516                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 517                 if (defined($format_patch)) {
 518                         return $format_patch;
 519                 }
 520                 die(<<EOF);
 521 File '$f' exists but it could also be the range of commits
 522 to produce patches for.  Please disambiguate by...
 523
 524     * Saying "./$f" if you mean a file; or
 525     * Giving --format-patch option if you mean a range.
 526 EOF
 527         } catch Git::Error::Command with {
 528                 return 0;
 529         }
 530 }
 531
 532 # Now that all the defaults are set, process the rest of the command line
 533 # arguments and collect up the files that need to be processed.
 534 my @rev_list_opts;
 535 while (defined(my $f = shift @ARGV)) {
 536         if ($f eq "--") {
 537                 push @rev_list_opts, "--", @ARGV;
 538                 @ARGV = ();
 539         } elsif (-d $f and !check_file_rev_conflict($f)) {
 540                 opendir my $dh, $f
 541                         or die "Failed to opendir $f: $!";
 542
 543                 push @files, grep { -f $_ } map { catfile($f, $_) }
 544                                 sort readdir $dh;
 545                 closedir $dh;
 546         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 547                 push @files, $f;
 548         } else {
 549                 push @rev_list_opts, $f;
 550         }
 551 }
 552
 553 if (@rev_list_opts) {
 554         die "Cannot run git format-patch from outside a repository\n"
 555                 unless $repo;
 556         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 557 }
 558
 559 if ($validate) {
 560         foreach my $f (@files) {
 561                 unless (-p $f) {
 562                         my $error = validate_patch($f);
 563                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 564                 }
 565         }
 566 }
 567
 568 if (@files) {
 569         unless ($quiet) {
 570                 print $_,"\n" for (@files);
 571         }
 572 } else {
 573         print STDERR "\nNo patch files specified!\n\n";
 574         usage();
 575 }
 576
 577 sub get_patch_subject {
 578         my $fn = shift;
 579         open (my $fh, '<', $fn);
 580         while (my $line = <$fh>) {
 581                 next unless ($line =~ /^Subject: (.*)$/);
 582                 close $fh;
 583                 return "GIT: $1\n";
 584         }
 585         close $fh;
 586         die "No subject line in $fn ?";
 587 }
 588
 589 if ($compose) {
 590         # Note that this does not need to be secure, but we will make a small
 591         # effort to have it be unique
 592         $compose_filename = ($repo ?
 593                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 594                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 595         open my $c, ">", $compose_filename
 596                 or die "Failed to open for writing $compose_filename: $!";
 597
 598
 599         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 600         my $tpl_subject = $initial_subject || '';
 601         my $tpl_reply_to = $initial_reply_to || '';
 602
 603         print $c <<EOT;
 604 From $tpl_sender # This line is ignored.
 605 GIT: Lines beginning in "GIT:" will be removed.
 606 GIT: Consider including an overall diffstat or table of contents
 607 GIT: for the patch you are writing.
 608 GIT:
 609 GIT: Clear the body content if you don't wish to send a summary.
 610 From: $tpl_sender
 611 Subject: $tpl_subject
 612 In-Reply-To: $tpl_reply_to
 613
 614 EOT
 615         for my $f (@files) {
 616                 print $c get_patch_subject($f);
 617         }
 618         close $c;
 619
 620         if ($annotate) {
 621                 do_edit($compose_filename, @files);
 622         } else {
 623                 do_edit($compose_filename);
 624         }
 625
 626         open my $c2, ">", $compose_filename . ".final"
 627                 or die "Failed to open $compose_filename.final : " . $!;
 628
 629         open $c, "<", $compose_filename
 630                 or die "Failed to open $compose_filename : " . $!;
 631
 632         my $need_8bit_cte = file_has_nonascii($compose_filename);
 633         my $in_body = 0;
 634         my $summary_empty = 1;
 635         while(<$c>) {
 636                 next if m/^GIT:/;
 637                 if ($in_body) {
 638                         $summary_empty = 0 unless (/^\n$/);
 639                 } elsif (/^\n$/) {
 640                         $in_body = 1;
 641                         if ($need_8bit_cte) {
 642                                 print $c2 "MIME-Version: 1.0\n",
 643                                          "Content-Type: text/plain; ",
 644                                            "charset=UTF-8\n",
 645                                          "Content-Transfer-Encoding: 8bit\n";
 646                         }
 647                 } elsif (/^MIME-Version:/i) {
 648                         $need_8bit_cte = 0;
 649                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 650                         $initial_subject = $1;
 651                         my $subject = $initial_subject;
 652                         $_ = "Subject: " .
 653                                 ($subject =~ /[^[:ascii:]]/ ?
 654                                  quote_rfc2047($subject) :
 655                                  $subject) .
 656                                 "\n";
 657                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 658                         $initial_reply_to = $1;
 659                         next;
 660                 } elsif (/^From:\s*(.+)\s*$/i) {
 661                         $sender = $1;
 662                         next;
 663                 } elsif (/^(?:To|Cc|Bcc):/i) {
 664                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 665                         next;
 666                 }
 667                 print $c2 $_;
 668         }
 669         close $c;
 670         close $c2;
 671
 672         if ($summary_empty) {
 673                 print "Summary email is empty, skipping it\n";
 674                 $compose = -1;
 675         }
 676 } elsif ($annotate) {
 677         do_edit(@files);
 678 }
 679
 680 sub ask {
 681         my ($prompt, %arg) = @_;
 682         my $valid_re = $arg{valid_re};
 683         my $default = $arg{default};
 684         my $resp;
 685         my $i = 0;
 686         return defined $default ? $default : undef
 687                 unless defined $term->IN and defined fileno($term->IN) and
 688                        defined $term->OUT and defined fileno($term->OUT);
 689         while ($i++ < 10) {
 690                 $resp = $term->readline($prompt);
 691                 if (!defined $resp) { # EOF
 692                         print "\n";
 693                         return defined $default ? $default : undef;
 694                 }
 695                 if ($resp eq '' and defined $default) {
 696                         return $default;
 697                 }
 698                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 699                         return $resp;
 700                 }
 701         }
 702         return undef;
 703 }
 704
 705 my %broken_encoding;
 706
 707 sub file_declares_8bit_cte {
 708         my $fn = shift;
 709         open (my $fh, '<', $fn);
 710         while (my $line = <$fh>) {
 711                 last if ($line =~ /^$/);
 712                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 713         }
 714         close $fh;
 715         return 0;
 716 }
 717
 718 foreach my $f (@files) {
 719         next unless (body_or_subject_has_nonascii($f)
 720                      && !file_declares_8bit_cte($f));
 721         $broken_encoding{$f} = 1;
 722 }
 723
 724 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 725         print "The following files are 8bit, but do not declare " .
 726                 "a Content-Transfer-Encoding.\n";
 727         foreach my $f (sort keys %broken_encoding) {
 728                 print "    $f\n";
 729         }
 730         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 731                                   default => "UTF-8");
 732 }
 733
 734 if (!$force) {
 735         for my $f (@files) {
 736                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 737                         die "Refusing to send because the patch\n\t$f\n"
 738                                 . "has the template subject '*** SUBJECT HERE ***'. "
 739                                 . "Pass --force if you really want to send.\n";
 740                 }
 741         }
 742 }
 743
 744 my $prompting = 0;
 745 if (!defined $sender) {
 746         $sender = $repoauthor || $repocommitter || '';
 747         $sender = ask("Who should the emails appear to be from? [$sender] ",
 748                       default => $sender);
 749         print "Emails will be sent from: ", $sender, "\n";
 750         $prompting++;
 751 }
 752
 753 if (!@initial_to && !defined $to_cmd) {
 754         my $to = ask("Who should the emails be sent to? ");
 755         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 756         $prompting++;
 757 }
 758
 759 sub expand_aliases {
 760         return map { expand_one_alias($_) } @_;
 761 }
 762
 763 my %EXPANDED_ALIASES;
 764 sub expand_one_alias {
 765         my $alias = shift;
 766         if ($EXPANDED_ALIASES{$alias}) {
 767                 die "fatal: alias '$alias' expands to itself\n";
 768         }
 769         local $EXPANDED_ALIASES{$alias} = 1;
 770         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 771 }
 772
 773 @initial_to = expand_aliases(@initial_to);
 774 @initial_to = (map { sanitize_address($_) } @initial_to);
 775 @initial_cc = expand_aliases(@initial_cc);
 776 @bcclist = expand_aliases(@bcclist);
 777
 778 if ($thread && !defined $initial_reply_to && $prompting) {
 779         $initial_reply_to = ask(
 780                 "Message-ID to be used as In-Reply-To for the first email? ");
 781 }
 782 if (defined $initial_reply_to) {
 783         $initial_reply_to =~ s/^\s*<?//;
 784         $initial_reply_to =~ s/>?\s*$//;
 785         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 786 }
 787
 788 if (!defined $smtp_server) {
 789         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 790                 if (-x $_) {
 791                         $smtp_server = $_;
 792                         last;
 793                 }
 794         }
 795         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 796 }
 797
 798 if ($compose && $compose > 0) {
 799         @files = ($compose_filename . ".final", @files);
 800 }
 801
 802 # Variables we set as part of the loop over files
 803 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 804         $needs_confirm, $message_num, $ask_default);
 805
 806 sub extract_valid_address {
 807         my $address = shift;
 808         my $local_part_regexp = qr/[^<>"\s@]+/;
 809         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 810
 811         # check for a local address:
 812         return $address if ($address =~ /^($local_part_regexp)$/);
 813
 814         $address =~ s/^\s*<(.*)>\s*$/$1/;
 815         if ($have_email_valid) {
 816                 return scalar Email::Valid->address($address);
 817         } else {
 818                 # less robust/correct than the monster regexp in Email::Valid,
 819                 # but still does a 99% job, and one less dependency
 820                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 821                 return $1;
 822         }
 823 }
 824
 825 # Usually don't need to change anything below here.
 826
 827 # we make a "fake" message id by taking the current number
 828 # of seconds since the beginning of Unix time and tacking on
 829 # a random number to the end, in case we are called quicker than
 830 # 1 second since the last time we were called.
 831
 832 # We'll setup a template for the message id, using the "from" address:
 833
 834 my ($message_id_stamp, $message_id_serial);
 835 sub make_message_id {
 836         my $uniq;
 837         if (!defined $message_id_stamp) {
 838                 $message_id_stamp = sprintf("%s-%s", time, $$);
 839                 $message_id_serial = 0;
 840         }
 841         $message_id_serial++;
 842         $uniq = "$message_id_stamp-$message_id_serial";
 843
 844         my $du_part;
 845         for ($sender, $repocommitter, $repoauthor) {
 846                 $du_part = extract_valid_address(sanitize_address($_));
 847                 last if (defined $du_part and $du_part ne '');
 848         }
 849         if (not defined $du_part or $du_part eq '') {
 850                 require Sys::Hostname;
 851                 $du_part = 'user@' . Sys::Hostname::hostname();
 852         }
 853         my $message_id_template = "<%s-git-send-email-%s>";
 854         $message_id = sprintf($message_id_template, $uniq, $du_part);
 855         #print "new message id = $message_id\n"; # Was useful for debugging
 856 }
 857
 858
 859
 860 $time = time - scalar $#files;
 861
 862 sub unquote_rfc2047 {
 863         local ($_) = @_;
 864         my $encoding;
 865         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 866                 $encoding = $1;
 867                 s/_/ /g;
 868                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 869         }
 870         return wantarray ? ($_, $encoding) : $_;
 871 }
 872
 873 sub quote_rfc2047 {
 874         local $_ = shift;
 875         my $encoding = shift || 'UTF-8';
 876         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 877         s/(.*)/=\?$encoding\?q\?$1\?=/;
 878         return $_;
 879 }
 880
 881 sub is_rfc2047_quoted {
 882         my $s = shift;
 883         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 884         my $encoded_text = qr/[!->@-~]+/;
 885         length($s) <= 75 &&
 886         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 887 }
 888
 889 # use the simplest quoting being able to handle the recipient
 890 sub sanitize_address {
 891         my ($recipient) = @_;
 892         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 893
 894         if (not $recipient_name) {
 895                 return $recipient;
 896         }
 897
 898         # if recipient_name is already quoted, do nothing
 899         if (is_rfc2047_quoted($recipient_name)) {
 900                 return $recipient;
 901         }
 902
 903         # rfc2047 is needed if a non-ascii char is included
 904         if ($recipient_name =~ /[^[:ascii:]]/) {
 905                 $recipient_name =~ s/^"(.*)"$/$1/;
 906                 $recipient_name = quote_rfc2047($recipient_name);
 907         }
 908
 909         # double quotes are needed if specials or CTLs are included
 910         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 911                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 912                 $recipient_name = qq["$recipient_name"];
 913         }
 914
 915         return "$recipient_name $recipient_addr";
 916
 917 }
 918
 919 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 920 #
 921 # Tightly configured MTAa require that a caller sends a real DNS
 922 # domain name that corresponds the IP address in the HELO/EHLO
 923 # handshake. This is used to verify the connection and prevent
 924 # spammers from trying to hide their identity. If the DNS and IP don't
 925 # match, the receiveing MTA may deny the connection.
 926 #
 927 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 928 #
 929 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 930 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 931 #
 932 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 933 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 934
 935 sub valid_fqdn {
 936         my $domain = shift;
 937         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 938 }
 939
 940 sub maildomain_net {
 941         my $maildomain;
 942
 943         if (eval { require Net::Domain; 1 }) {
 944                 my $domain = Net::Domain::domainname();
 945                 $maildomain = $domain if valid_fqdn($domain);
 946         }
 947
 948         return $maildomain;
 949 }
 950
 951 sub maildomain_mta {
 952         my $maildomain;
 953
 954         if (eval { require Net::SMTP; 1 }) {
 955                 for my $host (qw(mailhost localhost)) {
 956                         my $smtp = Net::SMTP->new($host);
 957                         if (defined $smtp) {
 958                                 my $domain = $smtp->domain;
 959                                 $smtp->quit;
 960
 961                                 $maildomain = $domain if valid_fqdn($domain);
 962
 963                                 last if $maildomain;
 964                         }
 965                 }
 966         }
 967
 968         return $maildomain;
 969 }
 970
 971 sub maildomain {
 972         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 973 }
 974
 975 # Returns 1 if the message was sent, and 0 otherwise.
 976 # In actuality, the whole program dies when there
 977 # is an error sending a message.
 978
 979 sub send_message {
 980         my @recipients = unique_email_list(@to);
 981         @cc = (grep { my $cc = extract_valid_address($_);
 982                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
 983                     }
 984                map { sanitize_address($_) }
 985                @cc);
 986         my $to = join (",\n\t", @recipients);
 987         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 988         @recipients = (map { extract_valid_address($_) } @recipients);
 989         my $date = format_2822_time($time++);
 990         my $gitversion = '@@GIT_VERSION@@';
 991         if ($gitversion =~ m/..GIT_VERSION../) {
 992             $gitversion = Git::version();
 993         }
 994
 995         my $cc = join(",\n\t", unique_email_list(@cc));
 996         my $ccline = "";
 997         if ($cc ne '') {
 998                 $ccline = "\nCc: $cc";
 999         }
1000         my $sanitized_sender = sanitize_address($sender);
1001         make_message_id() unless defined($message_id);
1002
1003         my $header = "From: $sanitized_sender
1004 To: $to${ccline}
1005 Subject: $subject
1006 Date: $date
1007 Message-Id: $message_id
1008 X-Mailer: git-send-email $gitversion
1009 ";
1010         if ($reply_to) {
1011
1012                 $header .= "In-Reply-To: $reply_to\n";
1013                 $header .= "References: $references\n";
1014         }
1015         if (@xh) {
1016                 $header .= join("\n", @xh) . "\n";
1017         }
1018
1019         my @sendmail_parameters = ('-i', @recipients);
1020         my $raw_from = $sanitized_sender;
1021         if (defined $envelope_sender && $envelope_sender ne "auto") {
1022                 $raw_from = $envelope_sender;
1023         }
1024         $raw_from = extract_valid_address($raw_from);
1025         unshift (@sendmail_parameters,
1026                         '-f', $raw_from) if(defined $envelope_sender);
1027
1028         if ($needs_confirm && !$dry_run) {
1029                 print "\n$header\n";
1030                 if ($needs_confirm eq "inform") {
1031                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1032                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1033                         print "    The Cc list above has been expanded by additional\n";
1034                         print "    addresses found in the patch commit message. By default\n";
1035                         print "    send-email prompts before sending whenever this occurs.\n";
1036                         print "    This behavior is controlled by the sendemail.confirm\n";
1037                         print "    configuration setting.\n";
1038                         print "\n";
1039                         print "    For additional information, run 'git send-email --help'.\n";
1040                         print "    To retain the current behavior, but squelch this message,\n";
1041                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1042                 }
1043                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1044                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1045                          default => $ask_default);
1046                 die "Send this email reply required" unless defined $_;
1047                 if (/^n/i) {
1048                         return 0;
1049                 } elsif (/^q/i) {
1050                         cleanup_compose_files();
1051                         exit(0);
1052                 } elsif (/^a/i) {
1053                         $confirm = 'never';
1054                 }
1055         }
1056
1057         unshift (@sendmail_parameters, @smtp_server_options);
1058
1059         if ($dry_run) {
1060                 # We don't want to send the email.
1061         } elsif ($smtp_server =~ m#^/#) {
1062                 my $pid = open my $sm, '|-';
1063                 defined $pid or die $!;
1064                 if (!$pid) {
1065                         exec($smtp_server, @sendmail_parameters) or die $!;
1066                 }
1067                 print $sm "$header\n$message";
1068                 close $sm or die $!;
1069         } else {
1070
1071                 if (!defined $smtp_server) {
1072                         die "The required SMTP server is not properly defined."
1073                 }
1074
1075                 if ($smtp_encryption eq 'ssl') {
1076                         $smtp_server_port ||= 465; # ssmtp
1077                         require Net::SMTP::SSL;
1078                         $smtp_domain ||= maildomain();
1079                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1080                                                       Hello => $smtp_domain,
1081                                                       Port => $smtp_server_port);
1082                 }
1083                 else {
1084                         require Net::SMTP;
1085                         $smtp_domain ||= maildomain();
1086                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1087                                                  ? "$smtp_server:$smtp_server_port"
1088                                                  : $smtp_server,
1089                                                  Hello => $smtp_domain,
1090                                                  Debug => $debug_net_smtp);
1091                         if ($smtp_encryption eq 'tls' && $smtp) {
1092                                 require Net::SMTP::SSL;
1093                                 $smtp->command('STARTTLS');
1094                                 $smtp->response();
1095                                 if ($smtp->code == 220) {
1096                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1097                                                 or die "STARTTLS failed! ".$smtp->message;
1098                                         $smtp_encryption = '';
1099                                         # Send EHLO again to receive fresh
1100                                         # supported commands
1101                                         $smtp->hello($smtp_domain);
1102                                 } else {
1103                                         die "Server does not support STARTTLS! ".$smtp->message;
1104                                 }
1105                         }
1106                 }
1107
1108                 if (!$smtp) {
1109                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1110                             "VALUES: server=$smtp_server ",
1111                             "encryption=$smtp_encryption ",
1112                             "hello=$smtp_domain",
1113                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1114                 }
1115
1116                 if (defined $smtp_authuser) {
1117                         # Workaround AUTH PLAIN/LOGIN interaction defect
1118                         # with Authen::SASL::Cyrus
1119                         eval {
1120                                 require Authen::SASL;
1121                                 Authen::SASL->import(qw(Perl));
1122                         };
1123
1124                         if (!defined $smtp_authpass) {
1125
1126                                 system "stty -echo";
1127
1128                                 do {
1129                                         print "Password: ";
1130                                         $_ = <STDIN>;
1131                                         print "\n";
1132                                 } while (!defined $_);
1133
1134                                 chomp($smtp_authpass = $_);
1135
1136                                 system "stty echo";
1137                         }
1138
1139                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1140                 }
1141
1142                 $smtp->mail( $raw_from ) or die $smtp->message;
1143                 $smtp->to( @recipients ) or die $smtp->message;
1144                 $smtp->data or die $smtp->message;
1145                 $smtp->datasend("$header\n$message") or die $smtp->message;
1146                 $smtp->dataend() or die $smtp->message;
1147                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1148         }
1149         if ($quiet) {
1150                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1151         } else {
1152                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1153                 if ($smtp_server !~ m#^/#) {
1154                         print "Server: $smtp_server\n";
1155                         print "MAIL FROM:<$raw_from>\n";
1156                         foreach my $entry (@recipients) {
1157                             print "RCPT TO:<$entry>\n";
1158                         }
1159                 } else {
1160                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1161                 }
1162                 print $header, "\n";
1163                 if ($smtp) {
1164                         print "Result: ", $smtp->code, ' ',
1165                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1166                 } else {
1167                         print "Result: OK\n";
1168                 }
1169         }
1170
1171         return 1;
1172 }
1173
1174 $reply_to = $initial_reply_to;
1175 $references = $initial_reply_to || '';
1176 $subject = $initial_subject;
1177 $message_num = 0;
1178
1179 foreach my $t (@files) {
1180         open my $fh, "<", $t or die "can't open file $t";
1181
1182         my $author = undef;
1183         my $author_encoding;
1184         my $has_content_type;
1185         my $body_encoding;
1186         @to = ();
1187         @cc = ();
1188         @xh = ();
1189         my $input_format = undef;
1190         my @header = ();
1191         $message = "";
1192         $message_num++;
1193         # First unfold multiline header fields
1194         while(<$fh>) {
1195                 last if /^\s*$/;
1196                 if (/^\s+\S/ and @header) {
1197                         chomp($header[$#header]);
1198                         s/^\s+/ /;
1199                         $header[$#header] .= $_;
1200             } else {
1201                         push(@header, $_);
1202                 }
1203         }
1204         # Now parse the header
1205         foreach(@header) {
1206                 if (/^From /) {
1207                         $input_format = 'mbox';
1208                         next;
1209                 }
1210                 chomp;
1211                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1212                         $input_format = 'mbox';
1213                 }
1214
1215                 if (defined $input_format && $input_format eq 'mbox') {
1216                         if (/^Subject:\s+(.*)$/) {
1217                                 $subject = $1;
1218                         }
1219                         elsif (/^From:\s+(.*)$/) {
1220                                 ($author, $author_encoding) = unquote_rfc2047($1);
1221                                 next if $suppress_cc{'author'};
1222                                 next if $suppress_cc{'self'} and $author eq $sender;
1223                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1224                                         $1, $_) unless $quiet;
1225                                 push @cc, $1;
1226                         }
1227                         elsif (/^To:\s+(.*)$/) {
1228                                 foreach my $addr (parse_address_line($1)) {
1229                                         printf("(mbox) Adding to: %s from line '%s'\n",
1230                                                 $addr, $_) unless $quiet;
1231                                         push @to, sanitize_address($addr);
1232                                 }
1233                         }
1234                         elsif (/^Cc:\s+(.*)$/) {
1235                                 foreach my $addr (parse_address_line($1)) {
1236                                         if (unquote_rfc2047($addr) eq $sender) {
1237                                                 next if ($suppress_cc{'self'});
1238                                         } else {
1239                                                 next if ($suppress_cc{'cc'});
1240                                         }
1241                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1242                                                 $addr, $_) unless $quiet;
1243                                         push @cc, $addr;
1244                                 }
1245                         }
1246                         elsif (/^Content-type:/i) {
1247                                 $has_content_type = 1;
1248                                 if (/charset="?([^ "]+)/) {
1249                                         $body_encoding = $1;
1250                                 }
1251                                 push @xh, $_;
1252                         }
1253                         elsif (/^Message-Id: (.*)/i) {
1254                                 $message_id = $1;
1255                         }
1256                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1257                                 push @xh, $_;
1258                         }
1259
1260                 } else {
1261                         # In the traditional
1262                         # "send lots of email" format,
1263                         # line 1 = cc
1264                         # line 2 = subject
1265                         # So let's support that, too.
1266                         $input_format = 'lots';
1267                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1268                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1269                                         $_, $_) unless $quiet;
1270                                 push @cc, $_;
1271                         } elsif (!defined $subject) {
1272                                 $subject = $_;
1273                         }
1274                 }
1275         }
1276         # Now parse the message body
1277         while(<$fh>) {
1278                 $message .=  $_;
1279                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1280                         chomp;
1281                         my ($what, $c) = ($1, $2);
1282                         chomp $c;
1283                         if ($c eq $sender) {
1284                                 next if ($suppress_cc{'self'});
1285                         } else {
1286                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1287                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1288                         }
1289                         push @cc, $c;
1290                         printf("(body) Adding cc: %s from line '%s'\n",
1291                                 $c, $_) unless $quiet;
1292                 }
1293         }
1294         close $fh;
1295
1296         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1297                 if defined $to_cmd;
1298         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1299                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1300
1301         if ($broken_encoding{$t} && !$has_content_type) {
1302                 $has_content_type = 1;
1303                 push @xh, "MIME-Version: 1.0",
1304                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1305                         "Content-Transfer-Encoding: 8bit";
1306                 $body_encoding = $auto_8bit_encoding;
1307         }
1308
1309         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1310                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1311         }
1312
1313         if (defined $author and $author ne $sender) {
1314                 $message = "From: $author\n\n$message";
1315                 if (defined $author_encoding) {
1316                         if ($has_content_type) {
1317                                 if ($body_encoding eq $author_encoding) {
1318                                         # ok, we already have the right encoding
1319                                 }
1320                                 else {
1321                                         # uh oh, we should re-encode
1322                                 }
1323                         }
1324                         else {
1325                                 $has_content_type = 1;
1326                                 push @xh,
1327                                   'MIME-Version: 1.0',
1328                                   "Content-Type: text/plain; charset=$author_encoding",
1329                                   'Content-Transfer-Encoding: 8bit';
1330                         }
1331                 }
1332         }
1333
1334         $needs_confirm = (
1335                 $confirm eq "always" or
1336                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1337                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1338         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1339
1340         @to = (@initial_to, @to);
1341         @cc = (@initial_cc, @cc);
1342
1343         my $message_was_sent = send_message();
1344
1345         # set up for the next message
1346         if ($thread && $message_was_sent &&
1347                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1348                 $message_num == 1)) {
1349                 $reply_to = $message_id;
1350                 if (length $references > 0) {
1351                         $references .= "\n $message_id";
1352                 } else {
1353                         $references = "$message_id";
1354                 }
1355         }
1356         $message_id = undef;
1357 }
1358
1359 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1360 # and return a results array
1361 sub recipients_cmd {
1362         my ($prefix, $what, $cmd, $file) = @_;
1363
1364         my $sanitized_sender = sanitize_address($sender);
1365         my @addresses = ();
1366         open my $fh, "$cmd \Q$file\E |"
1367             or die "($prefix) Could not execute '$cmd'";
1368         while (my $address = <$fh>) {
1369                 $address =~ s/^\s*//g;
1370                 $address =~ s/\s*$//g;
1371                 $address = sanitize_address($address);
1372                 next if ($address eq $sanitized_sender and $suppress_from);
1373                 push @addresses, $address;
1374                 printf("($prefix) Adding %s: %s from: '%s'\n",
1375                        $what, $address, $cmd) unless $quiet;
1376                 }
1377         close $fh
1378             or die "($prefix) failed to close pipe to '$cmd'";
1379         return @addresses;
1380 }
1381
1382 cleanup_compose_files();
1383
1384 sub cleanup_compose_files {
1385         unlink($compose_filename, $compose_filename . ".final") if $compose;
1386 }
1387
1388 $smtp->quit if $smtp;
1389
1390 sub unique_email_list {
1391         my %seen;
1392         my @emails;
1393
1394         foreach my $entry (@_) {
1395                 if (my $clean = extract_valid_address($entry)) {
1396                         $seen{$clean} ||= 0;
1397                         next if $seen{$clean}++;
1398                         push @emails, $entry;
1399                 } else {
1400                         print STDERR "W: unable to extract a valid address",
1401                                         " from: $entry\n";
1402                 }
1403         }
1404         return @emails;
1405 }
1406
1407 sub validate_patch {
1408         my $fn = shift;
1409         open(my $fh, '<', $fn)
1410                 or die "unable to open $fn: $!\n";
1411         while (my $line = <$fh>) {
1412                 if (length($line) > 998) {
1413                         return "$.: patch contains a line longer than 998 characters";
1414                 }
1415         }
1416         return undef;
1417 }
1418
1419 sub file_has_nonascii {
1420         my $fn = shift;
1421         open(my $fh, '<', $fn)
1422                 or die "unable to open $fn: $!\n";
1423         while (my $line = <$fh>) {
1424                 return 1 if $line =~ /[^[:ascii:]]/;
1425         }
1426         return 0;
1427 }
1428
1429 sub body_or_subject_has_nonascii {
1430         my $fn = shift;
1431         open(my $fh, '<', $fn)
1432                 or die "unable to open $fn: $!\n";
1433         while (my $line = <$fh>) {
1434                 last if $line =~ /^$/;
1435                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1436         }
1437         while (my $line = <$fh>) {
1438                 return 1 if $line =~ /[^[:ascii:]]/;
1439         }
1440         return 0;
1441 }