git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213     "from" => \$sender,
 214 );
 215
 216 # Handle Uncouth Termination
 217 sub signal_handler {
 218
 219         # Make text normal
 220         print color("reset"), "\n";
 221
 222         # SMTP password masked
 223         system "stty echo";
 224
 225         # tmp files from --compose
 226         if (defined $compose_filename) {
 227                 if (-e $compose_filename) {
 228                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229                 }
 230                 if (-e ($compose_filename . ".final")) {
 231                         print "'$compose_filename.final' contains the composed email.\n"
 232                 }
 233         }
 234
 235         exit;
 236 };
 237
 238 $SIG{TERM} = \&signal_handler;
 239 $SIG{INT}  = \&signal_handler;
 240
 241 # Begin by accumulating all the variables (defined above), that we will end up
 242 # needing, first, from the command line:
 243
 244 my $rc = GetOptions("sender|from=s" => \$sender,
 245                     "in-reply-to=s" => \$initial_reply_to,
 246                     "subject=s" => \$initial_subject,
 247                     "to=s" => \@to,
 248                     "cc=s" => \@initial_cc,
 249                     "bcc=s" => \@bcclist,
 250                     "chain-reply-to!" => \$chain_reply_to,
 251                     "smtp-server=s" => \$smtp_server,
 252                     "smtp-server-port=s" => \$smtp_server_port,
 253                     "smtp-user=s" => \$smtp_authuser,
 254                     "smtp-pass:s" => \$smtp_authpass,
 255                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 256                     "smtp-encryption=s" => \$smtp_encryption,
 257                     "identity=s" => \$identity,
 258                     "annotate" => \$annotate,
 259                     "compose" => \$compose,
 260                     "quiet" => \$quiet,
 261                     "cc-cmd=s" => \$cc_cmd,
 262                     "suppress-from!" => \$suppress_from,
 263                     "suppress-cc=s" => \@suppress_cc,
 264                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 265                     "confirm=s" => \$confirm,
 266                     "dry-run" => \$dry_run,
 267                     "envelope-sender=s" => \$envelope_sender,
 268                     "thread!" => \$thread,
 269                     "validate!" => \$validate,
 270                     "format-patch!" => \$format_patch,
 271          );
 272
 273 unless ($rc) {
 274     usage();
 275 }
 276
 277 die "Cannot run git format-patch from outside a repository\n"
 278         if $format_patch and not $repo;
 279
 280 # Now, let's fill any that aren't set in with defaults:
 281
 282 sub read_config {
 283         my ($prefix) = @_;
 284
 285         foreach my $setting (keys %config_bool_settings) {
 286                 my $target = $config_bool_settings{$setting}->[0];
 287                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 288         }
 289
 290         foreach my $setting (keys %config_settings) {
 291                 my $target = $config_settings{$setting};
 292                 if (ref($target) eq "ARRAY") {
 293                         unless (@$target) {
 294                                 my @values = Git::config(@repo, "$prefix.$setting");
 295                                 @$target = @values if (@values && defined $values[0]);
 296                         }
 297                 }
 298                 else {
 299                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 300                 }
 301         }
 302
 303         if (!defined $smtp_encryption) {
 304                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 305                 if (defined $enc) {
 306                         $smtp_encryption = $enc;
 307                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 308                         $smtp_encryption = 'ssl';
 309                 }
 310         }
 311 }
 312
 313 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 314 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 315 read_config("sendemail.$identity") if (defined $identity);
 316 read_config("sendemail");
 317
 318 # fall back on builtin bool defaults
 319 foreach my $setting (values %config_bool_settings) {
 320         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 321 }
 322
 323 # 'default' encryption is none -- this only prevents a warning
 324 $smtp_encryption = '' unless (defined $smtp_encryption);
 325
 326 # Set CC suppressions
 327 my(%suppress_cc);
 328 if (@suppress_cc) {
 329         foreach my $entry (@suppress_cc) {
 330                 die "Unknown --suppress-cc field: '$entry'\n"
 331                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 332                 $suppress_cc{$entry} = 1;
 333         }
 334 }
 335
 336 if ($suppress_cc{'all'}) {
 337         foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
 338                 $suppress_cc{$entry} = 1;
 339         }
 340         delete $suppress_cc{'all'};
 341 }
 342
 343 # If explicit old-style ones are specified, they trump --suppress-cc.
 344 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 345 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 346
 347 if ($suppress_cc{'body'}) {
 348         foreach my $entry (qw (sob bodycc)) {
 349                 $suppress_cc{$entry} = 1;
 350         }
 351         delete $suppress_cc{'body'};
 352 }
 353
 354 # Set confirm's default value
 355 my $confirm_unconfigured = !defined $confirm;
 356 if ($confirm_unconfigured) {
 357         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 358 };
 359 die "Unknown --confirm setting: '$confirm'\n"
 360         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 361
 362 # Debugging, print out the suppressions.
 363 if (0) {
 364         print "suppressions:\n";
 365         foreach my $entry (keys %suppress_cc) {
 366                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 367         }
 368 }
 369
 370 my ($repoauthor, $repocommitter);
 371 ($repoauthor) = Git::ident_person(@repo, 'author');
 372 ($repocommitter) = Git::ident_person(@repo, 'committer');
 373
 374 # Verify the user input
 375
 376 foreach my $entry (@to) {
 377         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 378 }
 379
 380 foreach my $entry (@initial_cc) {
 381         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 382 }
 383
 384 foreach my $entry (@bcclist) {
 385         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 386 }
 387
 388 sub parse_address_line {
 389         if ($have_mail_address) {
 390                 return map { $_->format } Mail::Address->parse($_[0]);
 391         } else {
 392                 return split_addrs($_[0]);
 393         }
 394 }
 395
 396 sub split_addrs {
 397         return quotewords('\s*,\s*', 1, @_);
 398 }
 399
 400 my %aliases;
 401 my %parse_alias = (
 402         # multiline formats can be supported in the future
 403         mutt => sub { my $fh = shift; while (<$fh>) {
 404                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 405                         my ($alias, $addr) = ($1, $2);
 406                         $addr =~ s/#.*$//; # mutt allows # comments
 407                          # commas delimit multiple addresses
 408                         $aliases{$alias} = [ split_addrs($addr) ];
 409                 }}},
 410         mailrc => sub { my $fh = shift; while (<$fh>) {
 411                 if (/^alias\s+(\S+)\s+(.*)$/) {
 412                         # spaces delimit multiple addresses
 413                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 414                 }}},
 415         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 416                 for (my $x = ''; defined($x); $x = $_) {
 417                         chomp $x;
 418                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 419                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 420                         $aliases{$1} = [ split_addrs($2) ];
 421                 }},
 422         elm => sub  { my $fh = shift;
 423                       while (<$fh>) {
 424                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 425                               my ($alias, $addr) = ($1, $2);
 426                                $aliases{$alias} = [ split_addrs($addr) ];
 427                           }
 428                       } },
 429
 430         gnus => sub { my $fh = shift; while (<$fh>) {
 431                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 432                         $aliases{$1} = [ $2 ];
 433                 }}}
 434 );
 435
 436 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 437         foreach my $file (@alias_files) {
 438                 open my $fh, '<', $file or die "opening $file: $!\n";
 439                 $parse_alias{$aliasfiletype}->($fh);
 440                 close $fh;
 441         }
 442 }
 443
 444 ($sender) = expand_aliases($sender) if defined $sender;
 445
 446 # returns 1 if the conflict must be solved using it as a format-patch argument
 447 sub check_file_rev_conflict($) {
 448         return unless $repo;
 449         my $f = shift;
 450         try {
 451                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 452                 if (defined($format_patch)) {
 453                         print "foo\n";
 454                         return $format_patch;
 455                 }
 456                 die(<<EOF);
 457 File '$f' exists but it could also be the range of commits
 458 to produce patches for.  Please disambiguate by...
 459
 460     * Saying "./$f" if you mean a file; or
 461     * Giving --format-patch option if you mean a range.
 462 EOF
 463         } catch Git::Error::Command with {
 464                 return 0;
 465         }
 466 }
 467
 468 # Now that all the defaults are set, process the rest of the command line
 469 # arguments and collect up the files that need to be processed.
 470 my @rev_list_opts;
 471 while (defined(my $f = shift @ARGV)) {
 472         if ($f eq "--") {
 473                 push @rev_list_opts, "--", @ARGV;
 474                 @ARGV = ();
 475         } elsif (-d $f and !check_file_rev_conflict($f)) {
 476                 opendir(DH,$f)
 477                         or die "Failed to opendir $f: $!";
 478
 479                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 480                                 sort readdir(DH);
 481                 closedir(DH);
 482         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 483                 push @files, $f;
 484         } else {
 485                 push @rev_list_opts, $f;
 486         }
 487 }
 488
 489 if (@rev_list_opts) {
 490         die "Cannot run git format-patch from outside a repository\n"
 491                 unless $repo;
 492         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 493 }
 494
 495 if ($validate) {
 496         foreach my $f (@files) {
 497                 unless (-p $f) {
 498                         my $error = validate_patch($f);
 499                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 500                 }
 501         }
 502 }
 503
 504 if (@files) {
 505         unless ($quiet) {
 506                 print $_,"\n" for (@files);
 507         }
 508 } else {
 509         print STDERR "\nNo patch files specified!\n\n";
 510         usage();
 511 }
 512
 513 sub get_patch_subject($) {
 514         my $fn = shift;
 515         open (my $fh, '<', $fn);
 516         while (my $line = <$fh>) {
 517                 next unless ($line =~ /^Subject: (.*)$/);
 518                 close $fh;
 519                 return "GIT: $1\n";
 520         }
 521         close $fh;
 522         die "No subject line in $fn ?";
 523 }
 524
 525 if ($compose) {
 526         # Note that this does not need to be secure, but we will make a small
 527         # effort to have it be unique
 528         $compose_filename = ($repo ?
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 530                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 531         open(C,">",$compose_filename)
 532                 or die "Failed to open for writing $compose_filename: $!";
 533
 534
 535         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 536         my $tpl_subject = $initial_subject || '';
 537         my $tpl_reply_to = $initial_reply_to || '';
 538
 539         print C <<EOT;
 540 From $tpl_sender # This line is ignored.
 541 GIT: Lines beginning in "GIT:" will be removed.
 542 GIT: Consider including an overall diffstat or table of contents
 543 GIT: for the patch you are writing.
 544 GIT:
 545 GIT: Clear the body content if you don't wish to send a summary.
 546 From: $tpl_sender
 547 Subject: $tpl_subject
 548 In-Reply-To: $tpl_reply_to
 549
 550 EOT
 551         for my $f (@files) {
 552                 print C get_patch_subject($f);
 553         }
 554         close(C);
 555
 556         if ($annotate) {
 557                 do_edit($compose_filename, @files);
 558         } else {
 559                 do_edit($compose_filename);
 560         }
 561
 562         open(C2,">",$compose_filename . ".final")
 563                 or die "Failed to open $compose_filename.final : " . $!;
 564
 565         open(C,"<",$compose_filename)
 566                 or die "Failed to open $compose_filename : " . $!;
 567
 568         my $need_8bit_cte = file_has_nonascii($compose_filename);
 569         my $in_body = 0;
 570         my $summary_empty = 1;
 571         while(<C>) {
 572                 next if m/^GIT:/;
 573                 if ($in_body) {
 574                         $summary_empty = 0 unless (/^\n$/);
 575                 } elsif (/^\n$/) {
 576                         $in_body = 1;
 577                         if ($need_8bit_cte) {
 578                                 print C2 "MIME-Version: 1.0\n",
 579                                          "Content-Type: text/plain; ",
 580                                            "charset=utf-8\n",
 581                                          "Content-Transfer-Encoding: 8bit\n";
 582                         }
 583                 } elsif (/^MIME-Version:/i) {
 584                         $need_8bit_cte = 0;
 585                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 586                         $initial_subject = $1;
 587                         my $subject = $initial_subject;
 588                         $_ = "Subject: " .
 589                                 ($subject =~ /[^[:ascii:]]/ ?
 590                                  quote_rfc2047($subject) :
 591                                  $subject) .
 592                                 "\n";
 593                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 594                         $initial_reply_to = $1;
 595                         next;
 596                 } elsif (/^From:\s*(.+)\s*$/i) {
 597                         $sender = $1;
 598                         next;
 599                 } elsif (/^(?:To|Cc|Bcc):/i) {
 600                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 601                         next;
 602                 }
 603                 print C2 $_;
 604         }
 605         close(C);
 606         close(C2);
 607
 608         if ($summary_empty) {
 609                 print "Summary email is empty, skipping it\n";
 610                 $compose = -1;
 611         }
 612 } elsif ($annotate) {
 613         do_edit(@files);
 614 }
 615
 616 sub ask {
 617         my ($prompt, %arg) = @_;
 618         my $valid_re = $arg{valid_re};
 619         my $default = $arg{default};
 620         my $resp;
 621         my $i = 0;
 622         return defined $default ? $default : undef
 623                 unless defined $term->IN and defined fileno($term->IN) and
 624                        defined $term->OUT and defined fileno($term->OUT);
 625         while ($i++ < 10) {
 626                 $resp = $term->readline($prompt);
 627                 if (!defined $resp) { # EOF
 628                         print "\n";
 629                         return defined $default ? $default : undef;
 630                 }
 631                 if ($resp eq '' and defined $default) {
 632                         return $default;
 633                 }
 634                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 635                         return $resp;
 636                 }
 637         }
 638         return undef;
 639 }
 640
 641 my $prompting = 0;
 642 if (!defined $sender) {
 643         $sender = $repoauthor || $repocommitter || '';
 644         $sender = ask("Who should the emails appear to be from? [$sender] ",
 645                       default => $sender);
 646         print "Emails will be sent from: ", $sender, "\n";
 647         $prompting++;
 648 }
 649
 650 if (!@to) {
 651         my $to = ask("Who should the emails be sent to? ");
 652         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 653         $prompting++;
 654 }
 655
 656 sub expand_aliases {
 657         my @cur = @_;
 658         my @last;
 659         do {
 660                 @last = @cur;
 661                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 662         } while (join(',',@cur) ne join(',',@last));
 663         return @cur;
 664 }
 665
 666 @to = expand_aliases(@to);
 667 @to = (map { sanitize_address($_) } @to);
 668 @initial_cc = expand_aliases(@initial_cc);
 669 @bcclist = expand_aliases(@bcclist);
 670
 671 if ($thread && !defined $initial_reply_to && $prompting) {
 672         $initial_reply_to = ask(
 673                 "Message-ID to be used as In-Reply-To for the first email? ");
 674 }
 675 if (defined $initial_reply_to) {
 676         $initial_reply_to =~ s/^\s*<?//;
 677         $initial_reply_to =~ s/>?\s*$//;
 678         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 679 }
 680
 681 if (!defined $smtp_server) {
 682         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 683                 if (-x $_) {
 684                         $smtp_server = $_;
 685                         last;
 686                 }
 687         }
 688         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 689 }
 690
 691 if ($compose && $compose > 0) {
 692         @files = ($compose_filename . ".final", @files);
 693 }
 694
 695 # Variables we set as part of the loop over files
 696 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 697         $needs_confirm, $message_num, $ask_default);
 698
 699 sub extract_valid_address {
 700         my $address = shift;
 701         my $local_part_regexp = '[^<>"\s@]+';
 702         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 703
 704         # check for a local address:
 705         return $address if ($address =~ /^($local_part_regexp)$/);
 706
 707         $address =~ s/^\s*<(.*)>\s*$/$1/;
 708         if ($have_email_valid) {
 709                 return scalar Email::Valid->address($address);
 710         } else {
 711                 # less robust/correct than the monster regexp in Email::Valid,
 712                 # but still does a 99% job, and one less dependency
 713                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 714                 return $1;
 715         }
 716 }
 717
 718 # Usually don't need to change anything below here.
 719
 720 # we make a "fake" message id by taking the current number
 721 # of seconds since the beginning of Unix time and tacking on
 722 # a random number to the end, in case we are called quicker than
 723 # 1 second since the last time we were called.
 724
 725 # We'll setup a template for the message id, using the "from" address:
 726
 727 my ($message_id_stamp, $message_id_serial);
 728 sub make_message_id
 729 {
 730         my $uniq;
 731         if (!defined $message_id_stamp) {
 732                 $message_id_stamp = sprintf("%s-%s", time, $$);
 733                 $message_id_serial = 0;
 734         }
 735         $message_id_serial++;
 736         $uniq = "$message_id_stamp-$message_id_serial";
 737
 738         my $du_part;
 739         for ($sender, $repocommitter, $repoauthor) {
 740                 $du_part = extract_valid_address(sanitize_address($_));
 741                 last if (defined $du_part and $du_part ne '');
 742         }
 743         if (not defined $du_part or $du_part eq '') {
 744                 use Sys::Hostname qw();
 745                 $du_part = 'user@' . Sys::Hostname::hostname();
 746         }
 747         my $message_id_template = "<%s-git-send-email-%s>";
 748         $message_id = sprintf($message_id_template, $uniq, $du_part);
 749         #print "new message id = $message_id\n"; # Was useful for debugging
 750 }
 751
 752
 753
 754 $time = time - scalar $#files;
 755
 756 sub unquote_rfc2047 {
 757         local ($_) = @_;
 758         my $encoding;
 759         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 760                 $encoding = $1;
 761                 s/_/ /g;
 762                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 763         }
 764         return wantarray ? ($_, $encoding) : $_;
 765 }
 766
 767 sub quote_rfc2047 {
 768         local $_ = shift;
 769         my $encoding = shift || 'utf-8';
 770         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 771         s/(.*)/=\?$encoding\?q\?$1\?=/;
 772         return $_;
 773 }
 774
 775 # use the simplest quoting being able to handle the recipient
 776 sub sanitize_address
 777 {
 778         my ($recipient) = @_;
 779         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 780
 781         if (not $recipient_name) {
 782                 return "$recipient";
 783         }
 784
 785         # if recipient_name is already quoted, do nothing
 786         if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
 787                 return $recipient;
 788         }
 789
 790         # rfc2047 is needed if a non-ascii char is included
 791         if ($recipient_name =~ /[^[:ascii:]]/) {
 792                 $recipient_name =~ s/^"(.*)"$/$1/;
 793                 $recipient_name = quote_rfc2047($recipient_name);
 794         }
 795
 796         # double quotes are needed if specials or CTLs are included
 797         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 798                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 799                 $recipient_name = "\"$recipient_name\"";
 800         }
 801
 802         return "$recipient_name $recipient_addr";
 803
 804 }
 805
 806 # Returns 1 if the message was sent, and 0 otherwise.
 807 # In actuality, the whole program dies when a there
 808 # is an error sending a message.
 809
 810 sub send_message
 811 {
 812         my @recipients = unique_email_list(@to);
 813         @cc = (grep { my $cc = extract_valid_address($_);
 814                       not grep { $cc eq $_ } @recipients
 815                     }
 816                map { sanitize_address($_) }
 817                @cc);
 818         my $to = join (",\n\t", @recipients);
 819         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 820         @recipients = (map { extract_valid_address($_) } @recipients);
 821         my $date = format_2822_time($time++);
 822         my $gitversion = '@@GIT_VERSION@@';
 823         if ($gitversion =~ m/..GIT_VERSION../) {
 824             $gitversion = Git::version();
 825         }
 826
 827         my $cc = join(", ", unique_email_list(@cc));
 828         my $ccline = "";
 829         if ($cc ne '') {
 830                 $ccline = "\nCc: $cc";
 831         }
 832         my $sanitized_sender = sanitize_address($sender);
 833         make_message_id() unless defined($message_id);
 834
 835         my $header = "From: $sanitized_sender
 836 To: $to${ccline}
 837 Subject: $subject
 838 Date: $date
 839 Message-Id: $message_id
 840 X-Mailer: git-send-email $gitversion
 841 ";
 842         if ($reply_to) {
 843
 844                 $header .= "In-Reply-To: $reply_to\n";
 845                 $header .= "References: $references\n";
 846         }
 847         if (@xh) {
 848                 $header .= join("\n", @xh) . "\n";
 849         }
 850
 851         my @sendmail_parameters = ('-i', @recipients);
 852         my $raw_from = $sanitized_sender;
 853         $raw_from = $envelope_sender if (defined $envelope_sender);
 854         $raw_from = extract_valid_address($raw_from);
 855         unshift (@sendmail_parameters,
 856                         '-f', $raw_from) if(defined $envelope_sender);
 857
 858         if ($needs_confirm && !$dry_run) {
 859                 print "\n$header\n";
 860                 if ($needs_confirm eq "inform") {
 861                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 862                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 863                         print "    The Cc list above has been expanded by additional\n";
 864                         print "    addresses found in the patch commit message. By default\n";
 865                         print "    send-email prompts before sending whenever this occurs.\n";
 866                         print "    This behavior is controlled by the sendemail.confirm\n";
 867                         print "    configuration setting.\n";
 868                         print "\n";
 869                         print "    For additional information, run 'git send-email --help'.\n";
 870                         print "    To retain the current behavior, but squelch this message,\n";
 871                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 872                 }
 873                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 874                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 875                          default => $ask_default);
 876                 die "Send this email reply required" unless defined $_;
 877                 if (/^n/i) {
 878                         return 0;
 879                 } elsif (/^q/i) {
 880                         cleanup_compose_files();
 881                         exit(0);
 882                 } elsif (/^a/i) {
 883                         $confirm = 'never';
 884                 }
 885         }
 886
 887         if ($dry_run) {
 888                 # We don't want to send the email.
 889         } elsif ($smtp_server =~ m#^/#) {
 890                 my $pid = open my $sm, '|-';
 891                 defined $pid or die $!;
 892                 if (!$pid) {
 893                         exec($smtp_server, @sendmail_parameters) or die $!;
 894                 }
 895                 print $sm "$header\n$message";
 896                 close $sm or die $?;
 897         } else {
 898
 899                 if (!defined $smtp_server) {
 900                         die "The required SMTP server is not properly defined."
 901                 }
 902
 903                 if ($smtp_encryption eq 'ssl') {
 904                         $smtp_server_port ||= 465; # ssmtp
 905                         require Net::SMTP::SSL;
 906                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 907                 }
 908                 else {
 909                         require Net::SMTP;
 910                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 911                                                  ? "$smtp_server:$smtp_server_port"
 912                                                  : $smtp_server);
 913                         if ($smtp_encryption eq 'tls') {
 914                                 require Net::SMTP::SSL;
 915                                 $smtp->command('STARTTLS');
 916                                 $smtp->response();
 917                                 if ($smtp->code == 220) {
 918                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 919                                                 or die "STARTTLS failed! ".$smtp->message;
 920                                         $smtp_encryption = '';
 921                                         # Send EHLO again to receive fresh
 922                                         # supported commands
 923                                         $smtp->hello();
 924                                 } else {
 925                                         die "Server does not support STARTTLS! ".$smtp->message;
 926                                 }
 927                         }
 928                 }
 929
 930                 if (!$smtp) {
 931                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 932                 }
 933
 934                 if (defined $smtp_authuser) {
 935
 936                         if (!defined $smtp_authpass) {
 937
 938                                 system "stty -echo";
 939
 940                                 do {
 941                                         print "Password: ";
 942                                         $_ = <STDIN>;
 943                                         print "\n";
 944                                 } while (!defined $_);
 945
 946                                 chomp($smtp_authpass = $_);
 947
 948                                 system "stty echo";
 949                         }
 950
 951                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 952                 }
 953
 954                 $smtp->mail( $raw_from ) or die $smtp->message;
 955                 $smtp->to( @recipients ) or die $smtp->message;
 956                 $smtp->data or die $smtp->message;
 957                 $smtp->datasend("$header\n$message") or die $smtp->message;
 958                 $smtp->dataend() or die $smtp->message;
 959                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 960         }
 961         if ($quiet) {
 962                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 963         } else {
 964                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 965                 if ($smtp_server !~ m#^/#) {
 966                         print "Server: $smtp_server\n";
 967                         print "MAIL FROM:<$raw_from>\n";
 968                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 969                 } else {
 970                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 971                 }
 972                 print $header, "\n";
 973                 if ($smtp) {
 974                         print "Result: ", $smtp->code, ' ',
 975                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 976                 } else {
 977                         print "Result: OK\n";
 978                 }
 979         }
 980
 981         return 1;
 982 }
 983
 984 $reply_to = $initial_reply_to;
 985 $references = $initial_reply_to || '';
 986 $subject = $initial_subject;
 987 $message_num = 0;
 988
 989 foreach my $t (@files) {
 990         open(F,"<",$t) or die "can't open file $t";
 991
 992         my $author = undef;
 993         my $author_encoding;
 994         my $has_content_type;
 995         my $body_encoding;
 996         @cc = ();
 997         @xh = ();
 998         my $input_format = undef;
 999         my @header = ();
1000         $message = "";
1001         $message_num++;
1002         # First unfold multiline header fields
1003         while(<F>) {
1004                 last if /^\s*$/;
1005                 if (/^\s+\S/ and @header) {
1006                         chomp($header[$#header]);
1007                         s/^\s+/ /;
1008                         $header[$#header] .= $_;
1009             } else {
1010                         push(@header, $_);
1011                 }
1012         }
1013         # Now parse the header
1014         foreach(@header) {
1015                 if (/^From /) {
1016                         $input_format = 'mbox';
1017                         next;
1018                 }
1019                 chomp;
1020                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1021                         $input_format = 'mbox';
1022                 }
1023
1024                 if (defined $input_format && $input_format eq 'mbox') {
1025                         if (/^Subject:\s+(.*)$/) {
1026                                 $subject = $1;
1027                         }
1028                         elsif (/^From:\s+(.*)$/) {
1029                                 ($author, $author_encoding) = unquote_rfc2047($1);
1030                                 next if $suppress_cc{'author'};
1031                                 next if $suppress_cc{'self'} and $author eq $sender;
1032                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1033                                         $1, $_) unless $quiet;
1034                                 push @cc, $1;
1035                         }
1036                         elsif (/^Cc:\s+(.*)$/) {
1037                                 foreach my $addr (parse_address_line($1)) {
1038                                         if (unquote_rfc2047($addr) eq $sender) {
1039                                                 next if ($suppress_cc{'self'});
1040                                         } else {
1041                                                 next if ($suppress_cc{'cc'});
1042                                         }
1043                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1044                                                 $addr, $_) unless $quiet;
1045                                         push @cc, $addr;
1046                                 }
1047                         }
1048                         elsif (/^Content-type:/i) {
1049                                 $has_content_type = 1;
1050                                 if (/charset="?([^ "]+)/) {
1051                                         $body_encoding = $1;
1052                                 }
1053                                 push @xh, $_;
1054                         }
1055                         elsif (/^Message-Id: (.*)/i) {
1056                                 $message_id = $1;
1057                         }
1058                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1059                                 push @xh, $_;
1060                         }
1061
1062                 } else {
1063                         # In the traditional
1064                         # "send lots of email" format,
1065                         # line 1 = cc
1066                         # line 2 = subject
1067                         # So let's support that, too.
1068                         $input_format = 'lots';
1069                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1070                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1071                                         $_, $_) unless $quiet;
1072                                 push @cc, $_;
1073                         } elsif (!defined $subject) {
1074                                 $subject = $_;
1075                         }
1076                 }
1077         }
1078         # Now parse the message body
1079         while(<F>) {
1080                 $message .=  $_;
1081                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1082                         chomp;
1083                         my ($what, $c) = ($1, $2);
1084                         chomp $c;
1085                         if ($c eq $sender) {
1086                                 next if ($suppress_cc{'self'});
1087                         } else {
1088                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1089                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1090                         }
1091                         push @cc, $c;
1092                         printf("(body) Adding cc: %s from line '%s'\n",
1093                                 $c, $_) unless $quiet;
1094                 }
1095         }
1096         close F;
1097
1098         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1099                 open(F, "$cc_cmd $t |")
1100                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1101                 while(<F>) {
1102                         my $c = $_;
1103                         $c =~ s/^\s*//g;
1104                         $c =~ s/\n$//g;
1105                         next if ($c eq $sender and $suppress_from);
1106                         push @cc, $c;
1107                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1108                                 $c, $cc_cmd) unless $quiet;
1109                 }
1110                 close F
1111                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1112         }
1113
1114         if (defined $author and $author ne $sender) {
1115                 $message = "From: $author\n\n$message";
1116                 if (defined $author_encoding) {
1117                         if ($has_content_type) {
1118                                 if ($body_encoding eq $author_encoding) {
1119                                         # ok, we already have the right encoding
1120                                 }
1121                                 else {
1122                                         # uh oh, we should re-encode
1123                                 }
1124                         }
1125                         else {
1126                                 push @xh,
1127                                   'MIME-Version: 1.0',
1128                                   "Content-Type: text/plain; charset=$author_encoding",
1129                                   'Content-Transfer-Encoding: 8bit';
1130                         }
1131                 }
1132         }
1133
1134         $needs_confirm = (
1135                 $confirm eq "always" or
1136                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1137                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1138         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1139
1140         @cc = (@initial_cc, @cc);
1141
1142         my $message_was_sent = send_message();
1143
1144         # set up for the next message
1145         if ($message_was_sent and $chain_reply_to || not defined $reply_to || length($reply_to) == 0) {
1146                 $reply_to = $message_id;
1147                 if (length $references > 0) {
1148                         $references .= "\n $message_id";
1149                 } else {
1150                         $references = "$message_id";
1151                 }
1152         }
1153         $message_id = undef;
1154 }
1155
1156 cleanup_compose_files();
1157
1158 sub cleanup_compose_files() {
1159         unlink($compose_filename, $compose_filename . ".final") if $compose;
1160 }
1161
1162 $smtp->quit if $smtp;
1163
1164 sub unique_email_list(@) {
1165         my %seen;
1166         my @emails;
1167
1168         foreach my $entry (@_) {
1169                 if (my $clean = extract_valid_address($entry)) {
1170                         $seen{$clean} ||= 0;
1171                         next if $seen{$clean}++;
1172                         push @emails, $entry;
1173                 } else {
1174                         print STDERR "W: unable to extract a valid address",
1175                                         " from: $entry\n";
1176                 }
1177         }
1178         return @emails;
1179 }
1180
1181 sub validate_patch {
1182         my $fn = shift;
1183         open(my $fh, '<', $fn)
1184                 or die "unable to open $fn: $!\n";
1185         while (my $line = <$fh>) {
1186                 if (length($line) > 998) {
1187                         return "$.: patch contains a line longer than 998 characters";
1188                 }
1189         }
1190         return undef;
1191 }
1192
1193 sub file_has_nonascii {
1194         my $fn = shift;
1195         open(my $fh, '<', $fn)
1196                 or die "unable to open $fn: $!\n";
1197         while (my $line = <$fh>) {
1198                 return 1 if $line =~ /[^[:ascii:]]/;
1199         }
1200         return 0;
1201 }