git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef]
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "suppresscc" => \@suppress_cc,
 232     "envelopesender" => \$envelope_sender,
 233     "confirm"   => \$confirm,
 234     "from" => \$sender,
 235     "assume8bitencoding" => \$auto_8bit_encoding,
 236     "composeencoding" => \$compose_encoding,
 237 );
 238
 239 my %config_path_settings = (
 240     "aliasesfile" => \@alias_files,
 241 );
 242
 243 # Help users prepare for 1.7.0
 244 sub chain_reply_to {
 245         if (defined $chain_reply_to &&
 246             $chain_reply_to eq $not_set_by_user) {
 247                 print STDERR
 248                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 249                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 250                     "you want to keep --chain-reply-to as your default.\n";
 251                 $chain_reply_to = 0;
 252         }
 253         return $chain_reply_to;
 254 }
 255
 256 # Handle Uncouth Termination
 257 sub signal_handler {
 258
 259         # Make text normal
 260         print color("reset"), "\n";
 261
 262         # SMTP password masked
 263         system "stty echo";
 264
 265         # tmp files from --compose
 266         if (defined $compose_filename) {
 267                 if (-e $compose_filename) {
 268                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 269                 }
 270                 if (-e ($compose_filename . ".final")) {
 271                         print "'$compose_filename.final' contains the composed email.\n"
 272                 }
 273         }
 274
 275         exit;
 276 };
 277
 278 $SIG{TERM} = \&signal_handler;
 279 $SIG{INT}  = \&signal_handler;
 280
 281 # Begin by accumulating all the variables (defined above), that we will end up
 282 # needing, first, from the command line:
 283
 284 my $help;
 285 my $rc = GetOptions("h" => \$help,
 286                     "sender|from=s" => \$sender,
 287                     "in-reply-to=s" => \$initial_reply_to,
 288                     "subject=s" => \$initial_subject,
 289                     "to=s" => \@initial_to,
 290                     "to-cmd=s" => \$to_cmd,
 291                     "no-to" => \$no_to,
 292                     "cc=s" => \@initial_cc,
 293                     "no-cc" => \$no_cc,
 294                     "bcc=s" => \@bcclist,
 295                     "no-bcc" => \$no_bcc,
 296                     "chain-reply-to!" => \$chain_reply_to,
 297                     "smtp-server=s" => \$smtp_server,
 298                     "smtp-server-option=s" => \@smtp_server_options,
 299                     "smtp-server-port=s" => \$smtp_server_port,
 300                     "smtp-user=s" => \$smtp_authuser,
 301                     "smtp-pass:s" => \$smtp_authpass,
 302                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 303                     "smtp-encryption=s" => \$smtp_encryption,
 304                     "smtp-debug:i" => \$debug_net_smtp,
 305                     "smtp-domain:s" => \$smtp_domain,
 306                     "identity=s" => \$identity,
 307                     "annotate" => \$annotate,
 308                     "compose" => \$compose,
 309                     "quiet" => \$quiet,
 310                     "cc-cmd=s" => \$cc_cmd,
 311                     "suppress-from!" => \$suppress_from,
 312                     "suppress-cc=s" => \@suppress_cc,
 313                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 314                     "confirm=s" => \$confirm,
 315                     "dry-run" => \$dry_run,
 316                     "envelope-sender=s" => \$envelope_sender,
 317                     "thread!" => \$thread,
 318                     "validate!" => \$validate,
 319                     "format-patch!" => \$format_patch,
 320                     "8bit-encoding=s" => \$auto_8bit_encoding,
 321                     "compose-encoding=s" => \$compose_encoding,
 322                     "force" => \$force,
 323          );
 324
 325 usage() if $help;
 326 unless ($rc) {
 327     usage();
 328 }
 329
 330 die "Cannot run git format-patch from outside a repository\n"
 331         if $format_patch and not $repo;
 332
 333 # Now, let's fill any that aren't set in with defaults:
 334
 335 sub read_config {
 336         my ($prefix) = @_;
 337
 338         foreach my $setting (keys %config_bool_settings) {
 339                 my $target = $config_bool_settings{$setting}->[0];
 340                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 341         }
 342
 343         foreach my $setting (keys %config_path_settings) {
 344                 my $target = $config_path_settings{$setting};
 345                 if (ref($target) eq "ARRAY") {
 346                         unless (@$target) {
 347                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 348                                 @$target = @values if (@values && defined $values[0]);
 349                         }
 350                 }
 351                 else {
 352                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 353                 }
 354         }
 355
 356         foreach my $setting (keys %config_settings) {
 357                 my $target = $config_settings{$setting};
 358                 next if $setting eq "to" and defined $no_to;
 359                 next if $setting eq "cc" and defined $no_cc;
 360                 next if $setting eq "bcc" and defined $no_bcc;
 361                 if (ref($target) eq "ARRAY") {
 362                         unless (@$target) {
 363                                 my @values = Git::config(@repo, "$prefix.$setting");
 364                                 @$target = @values if (@values && defined $values[0]);
 365                         }
 366                 }
 367                 else {
 368                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 369                 }
 370         }
 371
 372         if (!defined $smtp_encryption) {
 373                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 374                 if (defined $enc) {
 375                         $smtp_encryption = $enc;
 376                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 377                         $smtp_encryption = 'ssl';
 378                 }
 379         }
 380 }
 381
 382 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 383 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 384 read_config("sendemail.$identity") if (defined $identity);
 385 read_config("sendemail");
 386
 387 # fall back on builtin bool defaults
 388 foreach my $setting (values %config_bool_settings) {
 389         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 390 }
 391
 392 # 'default' encryption is none -- this only prevents a warning
 393 $smtp_encryption = '' unless (defined $smtp_encryption);
 394
 395 # Set CC suppressions
 396 my(%suppress_cc);
 397 if (@suppress_cc) {
 398         foreach my $entry (@suppress_cc) {
 399                 die "Unknown --suppress-cc field: '$entry'\n"
 400                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 401                 $suppress_cc{$entry} = 1;
 402         }
 403 }
 404
 405 if ($suppress_cc{'all'}) {
 406         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 407                 $suppress_cc{$entry} = 1;
 408         }
 409         delete $suppress_cc{'all'};
 410 }
 411
 412 # If explicit old-style ones are specified, they trump --suppress-cc.
 413 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 414 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 415
 416 if ($suppress_cc{'body'}) {
 417         foreach my $entry (qw (sob bodycc)) {
 418                 $suppress_cc{$entry} = 1;
 419         }
 420         delete $suppress_cc{'body'};
 421 }
 422
 423 # Set confirm's default value
 424 my $confirm_unconfigured = !defined $confirm;
 425 if ($confirm_unconfigured) {
 426         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 427 };
 428 die "Unknown --confirm setting: '$confirm'\n"
 429         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 430
 431 # Debugging, print out the suppressions.
 432 if (0) {
 433         print "suppressions:\n";
 434         foreach my $entry (keys %suppress_cc) {
 435                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 436         }
 437 }
 438
 439 my ($repoauthor, $repocommitter);
 440 ($repoauthor) = Git::ident_person(@repo, 'author');
 441 ($repocommitter) = Git::ident_person(@repo, 'committer');
 442
 443 # Verify the user input
 444
 445 foreach my $entry (@initial_to) {
 446         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@initial_cc) {
 450         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 foreach my $entry (@bcclist) {
 454         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 455 }
 456
 457 sub parse_address_line {
 458         if ($have_mail_address) {
 459                 return map { $_->format } Mail::Address->parse($_[0]);
 460         } else {
 461                 return split_addrs($_[0]);
 462         }
 463 }
 464
 465 sub split_addrs {
 466         return quotewords('\s*,\s*', 1, @_);
 467 }
 468
 469 my %aliases;
 470 my %parse_alias = (
 471         # multiline formats can be supported in the future
 472         mutt => sub { my $fh = shift; while (<$fh>) {
 473                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 474                         my ($alias, $addr) = ($1, $2);
 475                         $addr =~ s/#.*$//; # mutt allows # comments
 476                          # commas delimit multiple addresses
 477                         $aliases{$alias} = [ split_addrs($addr) ];
 478                 }}},
 479         mailrc => sub { my $fh = shift; while (<$fh>) {
 480                 if (/^alias\s+(\S+)\s+(.*)$/) {
 481                         # spaces delimit multiple addresses
 482                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 483                 }}},
 484         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 485                 for (my $x = ''; defined($x); $x = $_) {
 486                         chomp $x;
 487                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 488                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 489                         $aliases{$1} = [ split_addrs($2) ];
 490                 }},
 491         elm => sub  { my $fh = shift;
 492                       while (<$fh>) {
 493                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 494                               my ($alias, $addr) = ($1, $2);
 495                                $aliases{$alias} = [ split_addrs($addr) ];
 496                           }
 497                       } },
 498
 499         gnus => sub { my $fh = shift; while (<$fh>) {
 500                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 501                         $aliases{$1} = [ $2 ];
 502                 }}}
 503 );
 504
 505 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 506         foreach my $file (@alias_files) {
 507                 open my $fh, '<', $file or die "opening $file: $!\n";
 508                 $parse_alias{$aliasfiletype}->($fh);
 509                 close $fh;
 510         }
 511 }
 512
 513 ($sender) = expand_aliases($sender) if defined $sender;
 514
 515 # returns 1 if the conflict must be solved using it as a format-patch argument
 516 sub check_file_rev_conflict($) {
 517         return unless $repo;
 518         my $f = shift;
 519         try {
 520                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 521                 if (defined($format_patch)) {
 522                         return $format_patch;
 523                 }
 524                 die(<<EOF);
 525 File '$f' exists but it could also be the range of commits
 526 to produce patches for.  Please disambiguate by...
 527
 528     * Saying "./$f" if you mean a file; or
 529     * Giving --format-patch option if you mean a range.
 530 EOF
 531         } catch Git::Error::Command with {
 532                 return 0;
 533         }
 534 }
 535
 536 # Now that all the defaults are set, process the rest of the command line
 537 # arguments and collect up the files that need to be processed.
 538 my @rev_list_opts;
 539 while (defined(my $f = shift @ARGV)) {
 540         if ($f eq "--") {
 541                 push @rev_list_opts, "--", @ARGV;
 542                 @ARGV = ();
 543         } elsif (-d $f and !check_file_rev_conflict($f)) {
 544                 opendir my $dh, $f
 545                         or die "Failed to opendir $f: $!";
 546
 547                 push @files, grep { -f $_ } map { catfile($f, $_) }
 548                                 sort readdir $dh;
 549                 closedir $dh;
 550         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 551                 push @files, $f;
 552         } else {
 553                 push @rev_list_opts, $f;
 554         }
 555 }
 556
 557 if (@rev_list_opts) {
 558         die "Cannot run git format-patch from outside a repository\n"
 559                 unless $repo;
 560         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 561 }
 562
 563 if ($validate) {
 564         foreach my $f (@files) {
 565                 unless (-p $f) {
 566                         my $error = validate_patch($f);
 567                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 568                 }
 569         }
 570 }
 571
 572 if (@files) {
 573         unless ($quiet) {
 574                 print $_,"\n" for (@files);
 575         }
 576 } else {
 577         print STDERR "\nNo patch files specified!\n\n";
 578         usage();
 579 }
 580
 581 sub get_patch_subject {
 582         my $fn = shift;
 583         open (my $fh, '<', $fn);
 584         while (my $line = <$fh>) {
 585                 next unless ($line =~ /^Subject: (.*)$/);
 586                 close $fh;
 587                 return "GIT: $1\n";
 588         }
 589         close $fh;
 590         die "No subject line in $fn ?";
 591 }
 592
 593 if ($compose) {
 594         # Note that this does not need to be secure, but we will make a small
 595         # effort to have it be unique
 596         $compose_filename = ($repo ?
 597                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 598                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 599         open my $c, ">", $compose_filename
 600                 or die "Failed to open for writing $compose_filename: $!";
 601
 602
 603         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 604         my $tpl_subject = $initial_subject || '';
 605         my $tpl_reply_to = $initial_reply_to || '';
 606
 607         print $c <<EOT;
 608 From $tpl_sender # This line is ignored.
 609 GIT: Lines beginning in "GIT:" will be removed.
 610 GIT: Consider including an overall diffstat or table of contents
 611 GIT: for the patch you are writing.
 612 GIT:
 613 GIT: Clear the body content if you don't wish to send a summary.
 614 From: $tpl_sender
 615 Subject: $tpl_subject
 616 In-Reply-To: $tpl_reply_to
 617
 618 EOT
 619         for my $f (@files) {
 620                 print $c get_patch_subject($f);
 621         }
 622         close $c;
 623
 624         if ($annotate) {
 625                 do_edit($compose_filename, @files);
 626         } else {
 627                 do_edit($compose_filename);
 628         }
 629
 630         open my $c2, ">", $compose_filename . ".final"
 631                 or die "Failed to open $compose_filename.final : " . $!;
 632
 633         open $c, "<", $compose_filename
 634                 or die "Failed to open $compose_filename : " . $!;
 635
 636         my $need_8bit_cte = file_has_nonascii($compose_filename);
 637         my $in_body = 0;
 638         my $summary_empty = 1;
 639         if (!defined $compose_encoding) {
 640                 $compose_encoding = "UTF-8";
 641         }
 642         while(<$c>) {
 643                 next if m/^GIT:/;
 644                 if ($in_body) {
 645                         $summary_empty = 0 unless (/^\n$/);
 646                 } elsif (/^\n$/) {
 647                         $in_body = 1;
 648                         if ($need_8bit_cte) {
 649                                 print $c2 "MIME-Version: 1.0\n",
 650                                          "Content-Type: text/plain; ",
 651                                            "charset=$compose_encoding\n",
 652                                          "Content-Transfer-Encoding: 8bit\n";
 653                         }
 654                 } elsif (/^MIME-Version:/i) {
 655                         $need_8bit_cte = 0;
 656                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 657                         $initial_subject = $1;
 658                         my $subject = $initial_subject;
 659                         $_ = "Subject: " .
 660                                 quote_subject($subject, $compose_encoding) .
 661                                 "\n";
 662                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 663                         $initial_reply_to = $1;
 664                         next;
 665                 } elsif (/^From:\s*(.+)\s*$/i) {
 666                         $sender = $1;
 667                         next;
 668                 } elsif (/^(?:To|Cc|Bcc):/i) {
 669                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 670                         next;
 671                 }
 672                 print $c2 $_;
 673         }
 674         close $c;
 675         close $c2;
 676
 677         if ($summary_empty) {
 678                 print "Summary email is empty, skipping it\n";
 679                 $compose = -1;
 680         }
 681 } elsif ($annotate) {
 682         do_edit(@files);
 683 }
 684
 685 sub ask {
 686         my ($prompt, %arg) = @_;
 687         my $valid_re = $arg{valid_re};
 688         my $default = $arg{default};
 689         my $confirm_only = $arg{confirm_only};
 690         my $resp;
 691         my $i = 0;
 692         return defined $default ? $default : undef
 693                 unless defined $term->IN and defined fileno($term->IN) and
 694                        defined $term->OUT and defined fileno($term->OUT);
 695         while ($i++ < 10) {
 696                 $resp = $term->readline($prompt);
 697                 if (!defined $resp) { # EOF
 698                         print "\n";
 699                         return defined $default ? $default : undef;
 700                 }
 701                 if ($resp eq '' and defined $default) {
 702                         return $default;
 703                 }
 704                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 705                         return $resp;
 706                 }
 707                 if ($confirm_only) {
 708                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 709                         if (defined $yesno && $yesno =~ /y/i) {
 710                                 return $resp;
 711                         }
 712                 }
 713         }
 714         return undef;
 715 }
 716
 717 my %broken_encoding;
 718
 719 sub file_declares_8bit_cte {
 720         my $fn = shift;
 721         open (my $fh, '<', $fn);
 722         while (my $line = <$fh>) {
 723                 last if ($line =~ /^$/);
 724                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 725         }
 726         close $fh;
 727         return 0;
 728 }
 729
 730 foreach my $f (@files) {
 731         next unless (body_or_subject_has_nonascii($f)
 732                      && !file_declares_8bit_cte($f));
 733         $broken_encoding{$f} = 1;
 734 }
 735
 736 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 737         print "The following files are 8bit, but do not declare " .
 738                 "a Content-Transfer-Encoding.\n";
 739         foreach my $f (sort keys %broken_encoding) {
 740                 print "    $f\n";
 741         }
 742         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 743                                   default => "UTF-8");
 744 }
 745
 746 if (!$force) {
 747         for my $f (@files) {
 748                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 749                         die "Refusing to send because the patch\n\t$f\n"
 750                                 . "has the template subject '*** SUBJECT HERE ***'. "
 751                                 . "Pass --force if you really want to send.\n";
 752                 }
 753         }
 754 }
 755
 756 if (!defined $sender) {
 757         $sender = $repoauthor || $repocommitter || '';
 758 }
 759
 760 my $prompting = 0;
 761 if (!@initial_to && !defined $to_cmd) {
 762         my $to = ask("Who should the emails be sent to (if any)? ",
 763                      default => "",
 764                      valid_re => qr/\@.*\./, confirm_only => 1);
 765         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 766         $prompting++;
 767 }
 768
 769 sub expand_aliases {
 770         return map { expand_one_alias($_) } @_;
 771 }
 772
 773 my %EXPANDED_ALIASES;
 774 sub expand_one_alias {
 775         my $alias = shift;
 776         if ($EXPANDED_ALIASES{$alias}) {
 777                 die "fatal: alias '$alias' expands to itself\n";
 778         }
 779         local $EXPANDED_ALIASES{$alias} = 1;
 780         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 781 }
 782
 783 @initial_to = expand_aliases(@initial_to);
 784 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 785 @initial_cc = expand_aliases(@initial_cc);
 786 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 787 @bcclist = expand_aliases(@bcclist);
 788 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 789
 790 if ($thread && !defined $initial_reply_to && $prompting) {
 791         $initial_reply_to = ask(
 792                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 793                 default => "",
 794                 valid_re => qr/\@.*\./, confirm_only => 1);
 795 }
 796 if (defined $initial_reply_to) {
 797         $initial_reply_to =~ s/^\s*<?//;
 798         $initial_reply_to =~ s/>?\s*$//;
 799         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 800 }
 801
 802 if (!defined $smtp_server) {
 803         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 804                 if (-x $_) {
 805                         $smtp_server = $_;
 806                         last;
 807                 }
 808         }
 809         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 810 }
 811
 812 if ($compose && $compose > 0) {
 813         @files = ($compose_filename . ".final", @files);
 814 }
 815
 816 # Variables we set as part of the loop over files
 817 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 818         $needs_confirm, $message_num, $ask_default);
 819
 820 sub extract_valid_address {
 821         my $address = shift;
 822         my $local_part_regexp = qr/[^<>"\s@]+/;
 823         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 824
 825         # check for a local address:
 826         return $address if ($address =~ /^($local_part_regexp)$/);
 827
 828         $address =~ s/^\s*<(.*)>\s*$/$1/;
 829         if ($have_email_valid) {
 830                 return scalar Email::Valid->address($address);
 831         }
 832
 833         # less robust/correct than the monster regexp in Email::Valid,
 834         # but still does a 99% job, and one less dependency
 835         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 836         return undef;
 837 }
 838
 839 sub extract_valid_address_or_die {
 840         my $address = shift;
 841         $address = extract_valid_address($address);
 842         die "error: unable to extract a valid address from: $address\n"
 843                 if !$address;
 844         return $address;
 845 }
 846
 847 sub validate_address {
 848         my $address = shift;
 849         while (!extract_valid_address($address)) {
 850                 print STDERR "error: unable to extract a valid address from: $address\n";
 851                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 852                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 853                         default => 'q');
 854                 if (/^d/i) {
 855                         return undef;
 856                 } elsif (/^q/i) {
 857                         cleanup_compose_files();
 858                         exit(0);
 859                 }
 860                 $address = ask("Who should the email be sent to (if any)? ",
 861                         default => "",
 862                         valid_re => qr/\@.*\./, confirm_only => 1);
 863         }
 864         return $address;
 865 }
 866
 867 sub validate_address_list {
 868         return (grep { defined $_ }
 869                 map { validate_address($_) } @_);
 870 }
 871
 872 # Usually don't need to change anything below here.
 873
 874 # we make a "fake" message id by taking the current number
 875 # of seconds since the beginning of Unix time and tacking on
 876 # a random number to the end, in case we are called quicker than
 877 # 1 second since the last time we were called.
 878
 879 # We'll setup a template for the message id, using the "from" address:
 880
 881 my ($message_id_stamp, $message_id_serial);
 882 sub make_message_id {
 883         my $uniq;
 884         if (!defined $message_id_stamp) {
 885                 $message_id_stamp = sprintf("%s-%s", time, $$);
 886                 $message_id_serial = 0;
 887         }
 888         $message_id_serial++;
 889         $uniq = "$message_id_stamp-$message_id_serial";
 890
 891         my $du_part;
 892         for ($sender, $repocommitter, $repoauthor) {
 893                 $du_part = extract_valid_address(sanitize_address($_));
 894                 last if (defined $du_part and $du_part ne '');
 895         }
 896         if (not defined $du_part or $du_part eq '') {
 897                 require Sys::Hostname;
 898                 $du_part = 'user@' . Sys::Hostname::hostname();
 899         }
 900         my $message_id_template = "<%s-git-send-email-%s>";
 901         $message_id = sprintf($message_id_template, $uniq, $du_part);
 902         #print "new message id = $message_id\n"; # Was useful for debugging
 903 }
 904
 905
 906
 907 $time = time - scalar $#files;
 908
 909 sub unquote_rfc2047 {
 910         local ($_) = @_;
 911         my $encoding;
 912         s{=\?([^?]+)\?q\?(.*?)\?=}{
 913                 $encoding = $1;
 914                 my $e = $2;
 915                 $e =~ s/_/ /g;
 916                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 917                 $e;
 918         }eg;
 919         return wantarray ? ($_, $encoding) : $_;
 920 }
 921
 922 sub quote_rfc2047 {
 923         local $_ = shift;
 924         my $encoding = shift || 'UTF-8';
 925         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 926         s/(.*)/=\?$encoding\?q\?$1\?=/;
 927         return $_;
 928 }
 929
 930 sub is_rfc2047_quoted {
 931         my $s = shift;
 932         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 933         my $encoded_text = qr/[!->@-~]+/;
 934         length($s) <= 75 &&
 935         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 936 }
 937
 938 sub subject_needs_rfc2047_quoting {
 939         my $s = shift;
 940
 941         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 942 }
 943
 944 sub quote_subject {
 945         local $subject = shift;
 946         my $encoding = shift || 'UTF-8';
 947
 948         if (subject_needs_rfc2047_quoting($subject)) {
 949                 return quote_rfc2047($subject, $encoding);
 950         }
 951         return $subject;
 952 }
 953
 954 # use the simplest quoting being able to handle the recipient
 955 sub sanitize_address {
 956         my ($recipient) = @_;
 957
 958         # remove garbage after email address
 959         $recipient =~ s/(.*>).*$/$1/;
 960
 961         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 962
 963         if (not $recipient_name) {
 964                 return $recipient;
 965         }
 966
 967         # if recipient_name is already quoted, do nothing
 968         if (is_rfc2047_quoted($recipient_name)) {
 969                 return $recipient;
 970         }
 971
 972         # rfc2047 is needed if a non-ascii char is included
 973         if ($recipient_name =~ /[^[:ascii:]]/) {
 974                 $recipient_name =~ s/^"(.*)"$/$1/;
 975                 $recipient_name = quote_rfc2047($recipient_name);
 976         }
 977
 978         # double quotes are needed if specials or CTLs are included
 979         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 980                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 981                 $recipient_name = qq["$recipient_name"];
 982         }
 983
 984         return "$recipient_name $recipient_addr";
 985
 986 }
 987
 988 sub sanitize_address_list {
 989         return (map { sanitize_address($_) } @_);
 990 }
 991
 992 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 993 #
 994 # Tightly configured MTAa require that a caller sends a real DNS
 995 # domain name that corresponds the IP address in the HELO/EHLO
 996 # handshake. This is used to verify the connection and prevent
 997 # spammers from trying to hide their identity. If the DNS and IP don't
 998 # match, the receiveing MTA may deny the connection.
 999 #
1000 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1001 #
1002 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1003 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1004 #
1005 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1006 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1007
1008 sub valid_fqdn {
1009         my $domain = shift;
1010         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1011 }
1012
1013 sub maildomain_net {
1014         my $maildomain;
1015
1016         if (eval { require Net::Domain; 1 }) {
1017                 my $domain = Net::Domain::domainname();
1018                 $maildomain = $domain if valid_fqdn($domain);
1019         }
1020
1021         return $maildomain;
1022 }
1023
1024 sub maildomain_mta {
1025         my $maildomain;
1026
1027         if (eval { require Net::SMTP; 1 }) {
1028                 for my $host (qw(mailhost localhost)) {
1029                         my $smtp = Net::SMTP->new($host);
1030                         if (defined $smtp) {
1031                                 my $domain = $smtp->domain;
1032                                 $smtp->quit;
1033
1034                                 $maildomain = $domain if valid_fqdn($domain);
1035
1036                                 last if $maildomain;
1037                         }
1038                 }
1039         }
1040
1041         return $maildomain;
1042 }
1043
1044 sub maildomain {
1045         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1046 }
1047
1048 # Returns 1 if the message was sent, and 0 otherwise.
1049 # In actuality, the whole program dies when there
1050 # is an error sending a message.
1051
1052 sub send_message {
1053         my @recipients = unique_email_list(@to);
1054         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1055                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1056                     }
1057                @cc);
1058         my $to = join (",\n\t", @recipients);
1059         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1060         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1061         my $date = format_2822_time($time++);
1062         my $gitversion = '@@GIT_VERSION@@';
1063         if ($gitversion =~ m/..GIT_VERSION../) {
1064             $gitversion = Git::version();
1065         }
1066
1067         my $cc = join(",\n\t", unique_email_list(@cc));
1068         my $ccline = "";
1069         if ($cc ne '') {
1070                 $ccline = "\nCc: $cc";
1071         }
1072         my $sanitized_sender = sanitize_address($sender);
1073         make_message_id() unless defined($message_id);
1074
1075         my $header = "From: $sanitized_sender
1076 To: $to${ccline}
1077 Subject: $subject
1078 Date: $date
1079 Message-Id: $message_id
1080 X-Mailer: git-send-email $gitversion
1081 ";
1082         if ($reply_to) {
1083
1084                 $header .= "In-Reply-To: $reply_to\n";
1085                 $header .= "References: $references\n";
1086         }
1087         if (@xh) {
1088                 $header .= join("\n", @xh) . "\n";
1089         }
1090
1091         my @sendmail_parameters = ('-i', @recipients);
1092         my $raw_from = $sanitized_sender;
1093         if (defined $envelope_sender && $envelope_sender ne "auto") {
1094                 $raw_from = $envelope_sender;
1095         }
1096         $raw_from = extract_valid_address($raw_from);
1097         unshift (@sendmail_parameters,
1098                         '-f', $raw_from) if(defined $envelope_sender);
1099
1100         if ($needs_confirm && !$dry_run) {
1101                 print "\n$header\n";
1102                 if ($needs_confirm eq "inform") {
1103                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1104                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1105                         print "    The Cc list above has been expanded by additional\n";
1106                         print "    addresses found in the patch commit message. By default\n";
1107                         print "    send-email prompts before sending whenever this occurs.\n";
1108                         print "    This behavior is controlled by the sendemail.confirm\n";
1109                         print "    configuration setting.\n";
1110                         print "\n";
1111                         print "    For additional information, run 'git send-email --help'.\n";
1112                         print "    To retain the current behavior, but squelch this message,\n";
1113                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1114                 }
1115                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1116                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1117                          default => $ask_default);
1118                 die "Send this email reply required" unless defined $_;
1119                 if (/^n/i) {
1120                         return 0;
1121                 } elsif (/^q/i) {
1122                         cleanup_compose_files();
1123                         exit(0);
1124                 } elsif (/^a/i) {
1125                         $confirm = 'never';
1126                 }
1127         }
1128
1129         unshift (@sendmail_parameters, @smtp_server_options);
1130
1131         if ($dry_run) {
1132                 # We don't want to send the email.
1133         } elsif ($smtp_server =~ m#^/#) {
1134                 my $pid = open my $sm, '|-';
1135                 defined $pid or die $!;
1136                 if (!$pid) {
1137                         exec($smtp_server, @sendmail_parameters) or die $!;
1138                 }
1139                 print $sm "$header\n$message";
1140                 close $sm or die $!;
1141         } else {
1142
1143                 if (!defined $smtp_server) {
1144                         die "The required SMTP server is not properly defined."
1145                 }
1146
1147                 if ($smtp_encryption eq 'ssl') {
1148                         $smtp_server_port ||= 465; # ssmtp
1149                         require Net::SMTP::SSL;
1150                         $smtp_domain ||= maildomain();
1151                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1152                                                       Hello => $smtp_domain,
1153                                                       Port => $smtp_server_port);
1154                 }
1155                 else {
1156                         require Net::SMTP;
1157                         $smtp_domain ||= maildomain();
1158                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1159                                                  ? "$smtp_server:$smtp_server_port"
1160                                                  : $smtp_server,
1161                                                  Hello => $smtp_domain,
1162                                                  Debug => $debug_net_smtp);
1163                         if ($smtp_encryption eq 'tls' && $smtp) {
1164                                 require Net::SMTP::SSL;
1165                                 $smtp->command('STARTTLS');
1166                                 $smtp->response();
1167                                 if ($smtp->code == 220) {
1168                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1169                                                 or die "STARTTLS failed! ".$smtp->message;
1170                                         $smtp_encryption = '';
1171                                         # Send EHLO again to receive fresh
1172                                         # supported commands
1173                                         $smtp->hello($smtp_domain);
1174                                 } else {
1175                                         die "Server does not support STARTTLS! ".$smtp->message;
1176                                 }
1177                         }
1178                 }
1179
1180                 if (!$smtp) {
1181                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1182                             "VALUES: server=$smtp_server ",
1183                             "encryption=$smtp_encryption ",
1184                             "hello=$smtp_domain",
1185                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1186                 }
1187
1188                 if (defined $smtp_authuser) {
1189                         # Workaround AUTH PLAIN/LOGIN interaction defect
1190                         # with Authen::SASL::Cyrus
1191                         eval {
1192                                 require Authen::SASL;
1193                                 Authen::SASL->import(qw(Perl));
1194                         };
1195
1196                         if (!defined $smtp_authpass) {
1197
1198                                 system "stty -echo";
1199
1200                                 do {
1201                                         print "Password: ";
1202                                         $_ = <STDIN>;
1203                                         print "\n";
1204                                 } while (!defined $_);
1205
1206                                 chomp($smtp_authpass = $_);
1207
1208                                 system "stty echo";
1209                         }
1210
1211                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1212                 }
1213
1214                 $smtp->mail( $raw_from ) or die $smtp->message;
1215                 $smtp->to( @recipients ) or die $smtp->message;
1216                 $smtp->data or die $smtp->message;
1217                 $smtp->datasend("$header\n$message") or die $smtp->message;
1218                 $smtp->dataend() or die $smtp->message;
1219                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1220         }
1221         if ($quiet) {
1222                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1223         } else {
1224                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1225                 if ($smtp_server !~ m#^/#) {
1226                         print "Server: $smtp_server\n";
1227                         print "MAIL FROM:<$raw_from>\n";
1228                         foreach my $entry (@recipients) {
1229                             print "RCPT TO:<$entry>\n";
1230                         }
1231                 } else {
1232                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1233                 }
1234                 print $header, "\n";
1235                 if ($smtp) {
1236                         print "Result: ", $smtp->code, ' ',
1237                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1238                 } else {
1239                         print "Result: OK\n";
1240                 }
1241         }
1242
1243         return 1;
1244 }
1245
1246 $reply_to = $initial_reply_to;
1247 $references = $initial_reply_to || '';
1248 $subject = $initial_subject;
1249 $message_num = 0;
1250
1251 foreach my $t (@files) {
1252         open my $fh, "<", $t or die "can't open file $t";
1253
1254         my $author = undef;
1255         my $author_encoding;
1256         my $has_content_type;
1257         my $body_encoding;
1258         @to = ();
1259         @cc = ();
1260         @xh = ();
1261         my $input_format = undef;
1262         my @header = ();
1263         $message = "";
1264         $message_num++;
1265         # First unfold multiline header fields
1266         while(<$fh>) {
1267                 last if /^\s*$/;
1268                 if (/^\s+\S/ and @header) {
1269                         chomp($header[$#header]);
1270                         s/^\s+/ /;
1271                         $header[$#header] .= $_;
1272             } else {
1273                         push(@header, $_);
1274                 }
1275         }
1276         # Now parse the header
1277         foreach(@header) {
1278                 if (/^From /) {
1279                         $input_format = 'mbox';
1280                         next;
1281                 }
1282                 chomp;
1283                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1284                         $input_format = 'mbox';
1285                 }
1286
1287                 if (defined $input_format && $input_format eq 'mbox') {
1288                         if (/^Subject:\s+(.*)$/i) {
1289                                 $subject = $1;
1290                         }
1291                         elsif (/^From:\s+(.*)$/i) {
1292                                 ($author, $author_encoding) = unquote_rfc2047($1);
1293                                 next if $suppress_cc{'author'};
1294                                 next if $suppress_cc{'self'} and $author eq $sender;
1295                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1296                                         $1, $_) unless $quiet;
1297                                 push @cc, $1;
1298                         }
1299                         elsif (/^To:\s+(.*)$/i) {
1300                                 foreach my $addr (parse_address_line($1)) {
1301                                         printf("(mbox) Adding to: %s from line '%s'\n",
1302                                                 $addr, $_) unless $quiet;
1303                                         push @to, $addr;
1304                                 }
1305                         }
1306                         elsif (/^Cc:\s+(.*)$/i) {
1307                                 foreach my $addr (parse_address_line($1)) {
1308                                         if (unquote_rfc2047($addr) eq $sender) {
1309                                                 next if ($suppress_cc{'self'});
1310                                         } else {
1311                                                 next if ($suppress_cc{'cc'});
1312                                         }
1313                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1314                                                 $addr, $_) unless $quiet;
1315                                         push @cc, $addr;
1316                                 }
1317                         }
1318                         elsif (/^Content-type:/i) {
1319                                 $has_content_type = 1;
1320                                 if (/charset="?([^ "]+)/) {
1321                                         $body_encoding = $1;
1322                                 }
1323                                 push @xh, $_;
1324                         }
1325                         elsif (/^Message-Id: (.*)/i) {
1326                                 $message_id = $1;
1327                         }
1328                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1329                                 push @xh, $_;
1330                         }
1331
1332                 } else {
1333                         # In the traditional
1334                         # "send lots of email" format,
1335                         # line 1 = cc
1336                         # line 2 = subject
1337                         # So let's support that, too.
1338                         $input_format = 'lots';
1339                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1340                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1341                                         $_, $_) unless $quiet;
1342                                 push @cc, $_;
1343                         } elsif (!defined $subject) {
1344                                 $subject = $_;
1345                         }
1346                 }
1347         }
1348         # Now parse the message body
1349         while(<$fh>) {
1350                 $message .=  $_;
1351                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1352                         chomp;
1353                         my ($what, $c) = ($1, $2);
1354                         chomp $c;
1355                         if ($c eq $sender) {
1356                                 next if ($suppress_cc{'self'});
1357                         } else {
1358                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1359                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1360                         }
1361                         push @cc, $c;
1362                         printf("(body) Adding cc: %s from line '%s'\n",
1363                                 $c, $_) unless $quiet;
1364                 }
1365         }
1366         close $fh;
1367
1368         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1369                 if defined $to_cmd;
1370         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1371                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1372
1373         if ($broken_encoding{$t} && !$has_content_type) {
1374                 $has_content_type = 1;
1375                 push @xh, "MIME-Version: 1.0",
1376                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1377                         "Content-Transfer-Encoding: 8bit";
1378                 $body_encoding = $auto_8bit_encoding;
1379         }
1380
1381         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1382                 $subject = quote_subject($subject, $auto_8bit_encoding);
1383         }
1384
1385         if (defined $author and $author ne $sender) {
1386                 $message = "From: $author\n\n$message";
1387                 if (defined $author_encoding) {
1388                         if ($has_content_type) {
1389                                 if ($body_encoding eq $author_encoding) {
1390                                         # ok, we already have the right encoding
1391                                 }
1392                                 else {
1393                                         # uh oh, we should re-encode
1394                                 }
1395                         }
1396                         else {
1397                                 $has_content_type = 1;
1398                                 push @xh,
1399                                   'MIME-Version: 1.0',
1400                                   "Content-Type: text/plain; charset=$author_encoding",
1401                                   'Content-Transfer-Encoding: 8bit';
1402                         }
1403                 }
1404         }
1405
1406         $needs_confirm = (
1407                 $confirm eq "always" or
1408                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1409                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1410         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1411
1412         @to = validate_address_list(sanitize_address_list(@to));
1413         @cc = validate_address_list(sanitize_address_list(@cc));
1414
1415         @to = (@initial_to, @to);
1416         @cc = (@initial_cc, @cc);
1417
1418         my $message_was_sent = send_message();
1419
1420         # set up for the next message
1421         if ($thread && $message_was_sent &&
1422                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1423                 $message_num == 1)) {
1424                 $reply_to = $message_id;
1425                 if (length $references > 0) {
1426                         $references .= "\n $message_id";
1427                 } else {
1428                         $references = "$message_id";
1429                 }
1430         }
1431         $message_id = undef;
1432 }
1433
1434 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1435 # and return a results array
1436 sub recipients_cmd {
1437         my ($prefix, $what, $cmd, $file) = @_;
1438
1439         my $sanitized_sender = sanitize_address($sender);
1440         my @addresses = ();
1441         open my $fh, "$cmd \Q$file\E |"
1442             or die "($prefix) Could not execute '$cmd'";
1443         while (my $address = <$fh>) {
1444                 $address =~ s/^\s*//g;
1445                 $address =~ s/\s*$//g;
1446                 $address = sanitize_address($address);
1447                 next if ($address eq $sanitized_sender and $suppress_from);
1448                 push @addresses, $address;
1449                 printf("($prefix) Adding %s: %s from: '%s'\n",
1450                        $what, $address, $cmd) unless $quiet;
1451                 }
1452         close $fh
1453             or die "($prefix) failed to close pipe to '$cmd'";
1454         return @addresses;
1455 }
1456
1457 cleanup_compose_files();
1458
1459 sub cleanup_compose_files {
1460         unlink($compose_filename, $compose_filename . ".final") if $compose;
1461 }
1462
1463 $smtp->quit if $smtp;
1464
1465 sub unique_email_list {
1466         my %seen;
1467         my @emails;
1468
1469         foreach my $entry (@_) {
1470                 my $clean = extract_valid_address_or_die($entry);
1471                 $seen{$clean} ||= 0;
1472                 next if $seen{$clean}++;
1473                 push @emails, $entry;
1474         }
1475         return @emails;
1476 }
1477
1478 sub validate_patch {
1479         my $fn = shift;
1480         open(my $fh, '<', $fn)
1481                 or die "unable to open $fn: $!\n";
1482         while (my $line = <$fh>) {
1483                 if (length($line) > 998) {
1484                         return "$.: patch contains a line longer than 998 characters";
1485                 }
1486         }
1487         return undef;
1488 }
1489
1490 sub file_has_nonascii {
1491         my $fn = shift;
1492         open(my $fh, '<', $fn)
1493                 or die "unable to open $fn: $!\n";
1494         while (my $line = <$fh>) {
1495                 return 1 if $line =~ /[^[:ascii:]]/;
1496         }
1497         return 0;
1498 }
1499
1500 sub body_or_subject_has_nonascii {
1501         my $fn = shift;
1502         open(my $fh, '<', $fn)
1503                 or die "unable to open $fn: $!\n";
1504         while (my $line = <$fh>) {
1505                 last if $line =~ /^$/;
1506                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1507         }
1508         while (my $line = <$fh>) {
1509                 return 1 if $line =~ /[^[:ascii:]]/;
1510         }
1511         return 0;
1512 }