git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  27 # --without-PROGRAM version used.
  28 AC_DEFUN([GIT_ARG_SET_PATH],
  29 [AC_ARG_WITH([$1],
  30  [AS_HELP_STRING([--with-$1=PATH],
  31                  [provide PATH to $1])],
  32  [GIT_CONF_APPEND_PATH($1,$2)],[])
  33 ])# GIT_ARG_SET_PATH
  34 #
  35 # GIT_CONF_APPEND_PATH(PROGRAM)
  36 # ------------------------------
  37 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38 # Used by GIT_ARG_SET_PATH(PROGRAM)
  39 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  40 # --without-PROGRAM is used.
  41 AC_DEFUN([GIT_CONF_APPEND_PATH],
  42 [PROGRAM=m4_toupper($1); \
  43 if test "$withval" = "no"; then \
  44         if test -n "$2"; then \
  45                 m4_toupper($1)_PATH=$withval; \
  46                 AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                 GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49         else \
  50                 AC_MSG_ERROR([You cannot use git without $1]); \
  51         fi; \
  52 else \
  53         if test "$withval" = "yes"; then \
  54                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55         else \
  56                 m4_toupper($1)_PATH=$withval; \
  57                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59         fi; \
  60 fi; \
  61 ]) # GIT_CONF_APPEND_PATH
  62 #
  63 # GIT_PARSE_WITH(PACKAGE)
  64 # -----------------------
  65 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  66 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69 AC_DEFUN([GIT_PARSE_WITH],
  70 [PACKAGE=m4_toupper($1); \
  71 if test "$withval" = "no"; then \
  72         m4_toupper(NO_$1)=YesPlease; \
  73 elif test "$withval" = "yes"; then \
  74         m4_toupper(NO_$1)=; \
  75 else \
  76         m4_toupper(NO_$1)=; \
  77         m4_toupper($1)DIR=$withval; \
  78         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80 fi \
  81 ])# GIT_PARSE_WITH
  82 #
  83 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84 # ---------------------
  85 # Set VAR to the value specied by --with-WITHNAME.
  86 # No verification of arguments is performed, but warnings are issued
  87 # if either 'yes' or 'no' is specified.
  88 # HELP_TEXT is presented when --help is called.
  89 # This is a direct way to allow setting variables in the Makefile.
  90 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91 [AC_ARG_WITH([$1],
  92  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93  if test -n "$withval"; then \
  94   if test "$withval" = "yes" -o "$withval" = "no"; then \
  95     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                      [a value for $1 ($2).  Maybe you do...?]); \
  97   fi; \
  98   \
  99   AC_MSG_NOTICE([Setting $2 to $withval]); \
 100   GIT_CONF_APPEND_LINE($2=$withval); \
 101  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103 dnl
 104 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105 dnl -----------------------------------------
 106 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108 dnl -Wall), it does not work.  By looking for function definition in
 109 dnl libraries, this problem can be worked around.
 110 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111   AC_SEARCH_LIBS([$1],,
 112   [$2],[$3])
 113 ],[$3])])
 114
 115 dnl
 116 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117 dnl -----------------------------
 118 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119 dnl tests that may want to take user settings into account.
 120 AC_DEFUN([GIT_STASH_FLAGS],[
 121 if test -n "$1"; then
 122    old_CPPFLAGS="$CPPFLAGS"
 123    old_LDFLAGS="$LDFLAGS"
 124    CPPFLAGS="-I$1/include $CPPFLAGS"
 125    LDFLAGS="-L$1/$lib $LDFLAGS"
 126 fi
 127 ])
 128
 129 dnl
 130 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131 dnl -----------------------------
 132 dnl Restore the stashed *FLAGS values.
 133 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134 if test -n "$1"; then
 135    CPPFLAGS="$old_CPPFLAGS"
 136    LDFLAGS="$old_LDFLAGS"
 137 fi
 138 ])
 139
 140 ## Site configuration related to programs (before tests)
 141 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 142 #
 143 # Set lib to alternative name of lib directory (e.g. lib64)
 144 AC_ARG_WITH([lib],
 145  [AS_HELP_STRING([--with-lib=ARG],
 146                  [ARG specifies alternative name for lib directory])],
 147  [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149 else \
 150         lib=$withval; \
 151         AC_MSG_NOTICE([Setting lib to '$lib']); \
 152         GIT_CONF_APPEND_LINE(lib=$withval); \
 153 fi; \
 154 ],[])
 155
 156 if test -z "$lib"; then
 157    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158    lib=lib
 159 fi
 160
 161 AC_ARG_ENABLE([pthreads],
 162  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164   [The default if FLAGS is not specified is to try first -pthread]
 165   [and then -lpthread.]
 166   [--without-pthreads will disable threading.])],
 167 [
 168 if test "x$enableval" = "xyes"; then
 169    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170 elif test "x$enableval" != "xno"; then
 171    PTHREAD_CFLAGS=$enableval
 172    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173 else
 174    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175    NO_PTHREADS=YesPlease
 176    USER_NOPTHREAD=1
 177 fi],
 178 [
 179    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180 ])
 181
 182 # Define option to enable JavaScript minification
 183 AC_ARG_ENABLE([jsmin],
 184 [AS_HELP_STRING([--enable-jsmin=PATH],
 185   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186 [
 187   JSMIN=$enableval;
 188   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189   GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190 ])
 191
 192 # Define option to enable CSS minification
 193 AC_ARG_ENABLE([cssmin],
 194 [AS_HELP_STRING([--enable-cssmin=PATH],
 195   [PATH is the name of a CSS minifier or the absolute path to one.])],
 196 [
 197   CSSMIN=$enableval;
 198   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199   GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200 ])
 201
 202 ## Site configuration (override autodetection)
 203 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 204 AC_MSG_NOTICE([CHECKS for site configuration])
 205 #
 206 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207 # tests.  These tests take up a significant amount of the total test time
 208 # but are not needed unless you plan to talk to SVN repos.
 209 #
 210 # Define PPC_SHA1 environment variable when running make to make use of
 211 # a bundled SHA1 routine optimized for PowerPC.
 212 #
 213 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214 # This also implies BLK_SHA1.
 215 #
 216 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217 # /foo/bar/include and /foo/bar/lib directories.
 218 AC_ARG_WITH(openssl,
 219 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221 GIT_PARSE_WITH(openssl))
 222 #
 223 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 224 # git-http-push are not built, and you cannot use http:// and https://
 225 # transports.
 226 #
 227 # Define CURLDIR=/foo/bar if your curl header and library files are in
 228 # /foo/bar/include and /foo/bar/lib directories.
 229 AC_ARG_WITH(curl,
 230 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232 GIT_PARSE_WITH(curl))
 233 #
 234 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235 # not built, and you cannot push using http:// and https:// transports.
 236 #
 237 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 238 # /foo/bar/include and /foo/bar/lib directories.
 239 AC_ARG_WITH(expat,
 240 AS_HELP_STRING([--with-expat],
 241 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243 GIT_PARSE_WITH(expat))
 244 #
 245 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246 # installed in /sw, but don't want GIT to link against any libraries
 247 # installed there.  If defined you may specify your own (or Fink's)
 248 # include directories and library directories by defining CFLAGS
 249 # and LDFLAGS appropriately.
 250 #
 251 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252 # have DarwinPorts installed in /opt/local, but don't want GIT to
 253 # link against any libraries installed there.  If defined you may
 254 # specify your own (or DarwinPort's) include directories and
 255 # library directories by defining CFLAGS and LDFLAGS appropriately.
 256 #
 257 # Define NO_MMAP if you want to avoid mmap.
 258 #
 259 # Define NO_ICONV if your libc does not properly support iconv.
 260 AC_ARG_WITH(iconv,
 261 AS_HELP_STRING([--without-iconv],
 262 [if your architecture doesn't properly support iconv])
 263 AS_HELP_STRING([--with-iconv=PATH],
 264 [PATH is prefix for libiconv library and headers])
 265 AS_HELP_STRING([],
 266 [used only if you need linking with libiconv]),
 267 GIT_PARSE_WITH(iconv))
 268
 269 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 270 #
 271 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 272 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274 # randomly break unless your underlying filesystem supports those sub-second
 275 # times (my ext3 doesn't).
 276 #
 277 # Define USE_STDEV below if you want git to care about the underlying device
 278 # change being considered an inode change from the update-index perspective.
 279
 280 #
 281 # Allow user to set ETC_GITCONFIG variable
 282 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                         Use VALUE instead of /etc/gitconfig as the
 284                         global git configuration file.
 285                         If VALUE is not fully qualified it will be interpreted
 286                         as a path relative to the computed prefix at runtime.)
 287
 288 #
 289 # Allow user to set ETC_GITATTRIBUTES variable
 290 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 291                         Use VALUE instead of /etc/gitattributes as the
 292                         global git attributes file.
 293                         If VALUE is not fully qualified it will be interpreted
 294                         as a path relative to the computed prefix at runtime.)
 295
 296 #
 297 # Allow user to set the default pager
 298 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 299                         Use VALUE as the fall-back pager instead of 'less'.
 300                         This is used by things like 'git log' when the user
 301                         does not specify a pager to use through alternate
 302                         methods. eg: /usr/bin/pager)
 303 #
 304 # Allow user to set the default editor
 305 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 306                         Use VALUE as the fall-back editor instead of 'vi'.
 307                         This is used by things like 'git commit' when the user
 308                         does not specify a preferred editor through other
 309                         methods. eg: /usr/bin/editor)
 310
 311 #
 312 # Define SHELL_PATH to provide path to shell.
 313 GIT_ARG_SET_PATH(shell)
 314 #
 315 # Define PERL_PATH to provide path to Perl.
 316 GIT_ARG_SET_PATH(perl)
 317 #
 318 # Define PYTHON_PATH to provide path to Python.
 319 GIT_ARG_SET_PATH(python, allow-without)
 320 #
 321 # Define ZLIB_PATH to provide path to zlib.
 322 GIT_ARG_SET_PATH(zlib)
 323 #
 324 # Declare the with-tcltk/without-tcltk options.
 325 AC_ARG_WITH(tcltk,
 326 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 327 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 328 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 329 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 330 GIT_PARSE_WITH(tcltk))
 331 #
 332
 333
 334 ## Checks for programs.
 335 AC_MSG_NOTICE([CHECKS for programs])
 336 #
 337 AC_PROG_CC([cc gcc])
 338 AC_C_INLINE
 339 case $ac_cv_c_inline in
 340   inline | yes | no)    ;;
 341   *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 342 esac
 343
 344 # which switch to pass runtime path to dynamic libraries to the linker
 345 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 346    SAVE_LDFLAGS="${LDFLAGS}"
 347    LDFLAGS="${SAVE_LDFLAGS} -R /"
 348    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 349    LDFLAGS="${SAVE_LDFLAGS}"
 350 ])
 351 if test "$git_cv_ld_dashr" = "yes"; then
 352    AC_SUBST(CC_LD_DYNPATH, [-R])
 353 else
 354    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 355       SAVE_LDFLAGS="${LDFLAGS}"
 356       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 357       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 358       LDFLAGS="${SAVE_LDFLAGS}"
 359    ])
 360    if test "$git_cv_ld_wl_rpath" = "yes"; then
 361       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 362    else
 363       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 364          SAVE_LDFLAGS="${LDFLAGS}"
 365          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 366          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 367          LDFLAGS="${SAVE_LDFLAGS}"
 368       ])
 369       if test "$git_cv_ld_rpath" = "yes"; then
 370          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 371       else
 372          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 373       fi
 374    fi
 375 fi
 376 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 377 AC_CHECK_TOOLS(AR, [gar ar], :)
 378 AC_CHECK_PROGS(TAR, [gtar tar])
 379 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 380 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 381 # or will be empty otherwise.
 382 if test -z "$NO_TCLTK"; then
 383   if test "$with_tcltk" = ""; then
 384   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 385     TCLTK_PATH=wish
 386     AC_SUBST(TCLTK_PATH)
 387   elif test "$with_tcltk" = "yes"; then
 388   # Tcl/Tk check requested.
 389     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 390   else
 391     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 392     TCLTK_PATH="$with_tcltk"
 393     AC_SUBST(TCLTK_PATH)
 394   fi
 395 fi
 396 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 397 if test -n "$ASCIIDOC"; then
 398         AC_MSG_CHECKING([for asciidoc version])
 399         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 400         case "${asciidoc_version}" in
 401         asciidoc' '7*)
 402                 ASCIIDOC7=YesPlease
 403                 AC_MSG_RESULT([${asciidoc_version} > 7])
 404                 ;;
 405         asciidoc' '8*)
 406                 ASCIIDOC7=
 407                 AC_MSG_RESULT([${asciidoc_version}])
 408                 ;;
 409         *)
 410                 ASCIIDOC7=
 411                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 412                 ;;
 413         esac
 414 fi
 415 AC_SUBST(ASCIIDOC7)
 416
 417
 418 ## Checks for libraries.
 419 AC_MSG_NOTICE([CHECKS for libraries])
 420 #
 421 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 422 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 423
 424 GIT_STASH_FLAGS($OPENSSLDIR)
 425
 426 AC_CHECK_LIB([crypto], [SHA1_Init],
 427 [NEEDS_SSL_WITH_CRYPTO=],
 428 [AC_CHECK_LIB([ssl], [SHA1_Init],
 429  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 430  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 431
 432 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 433
 434 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 435 AC_SUBST(NO_OPENSSL)
 436
 437 #
 438 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 439 # git-http-push are not built, and you cannot use http:// and https://
 440 # transports.
 441
 442 GIT_STASH_FLAGS($CURLDIR)
 443
 444 AC_CHECK_LIB([curl], [curl_global_init],
 445 [NO_CURL=],
 446 [NO_CURL=YesPlease])
 447
 448 GIT_UNSTASH_FLAGS($CURLDIR)
 449
 450 AC_SUBST(NO_CURL)
 451
 452 #
 453 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 454 # not built, and you cannot push using http:// and https:// transports.
 455
 456 GIT_STASH_FLAGS($EXPATDIR)
 457
 458 AC_CHECK_LIB([expat], [XML_ParserCreate],
 459 [NO_EXPAT=],
 460 [NO_EXPAT=YesPlease])
 461
 462 GIT_UNSTASH_FLAGS($EXPATDIR)
 463
 464 AC_SUBST(NO_EXPAT)
 465
 466 #
 467 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 468 # some Solaris installations).
 469 # Define NO_ICONV if neither libc nor libiconv support iconv.
 470
 471 if test -z "$NO_ICONV"; then
 472
 473 GIT_STASH_FLAGS($ICONVDIR)
 474
 475 AC_DEFUN([ICONVTEST_SRC],
 476 [AC_LANG_PROGRAM([#include <iconv.h>],
 477  [iconv_open("", "");])])
 478
 479 if test -n "$ICONVDIR"; then
 480    lib_order="-liconv -lc"
 481 else
 482    lib_order="-lc -liconv"
 483 fi
 484
 485 NO_ICONV=YesPlease
 486
 487 for l in $lib_order; do
 488     if test "$l" = "-liconv"; then
 489        NEEDS_LIBICONV=YesPlease
 490     else
 491        NEEDS_LIBICONV=
 492     fi
 493
 494     old_LIBS="$LIBS"
 495     LIBS="$LIBS $l"
 496     AC_MSG_CHECKING([for iconv in $l])
 497     AC_LINK_IFELSE([ICONVTEST_SRC],
 498         [AC_MSG_RESULT([yes])
 499         NO_ICONV=
 500         break],
 501         [AC_MSG_RESULT([no])])
 502     LIBS="$old_LIBS"
 503 done
 504
 505 #in case of break
 506 LIBS="$old_LIBS"
 507
 508 GIT_UNSTASH_FLAGS($ICONVDIR)
 509
 510 AC_SUBST(NEEDS_LIBICONV)
 511 AC_SUBST(NO_ICONV)
 512
 513 if test -n "$NO_ICONV"; then
 514     NEEDS_LIBICONV=
 515 fi
 516
 517 fi
 518
 519 #
 520 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 521
 522 GIT_STASH_FLAGS($ZLIB_PATH)
 523
 524 AC_DEFUN([ZLIBTEST_SRC], [
 525 AC_LANG_PROGRAM([#include <zlib.h>],
 526  [deflateBound(0, 0);])])
 527 AC_MSG_CHECKING([for deflateBound in -lz])
 528 old_LIBS="$LIBS"
 529 LIBS="$LIBS -lz"
 530 AC_LINK_IFELSE([ZLIBTEST_SRC],
 531         [AC_MSG_RESULT([yes])],
 532         [AC_MSG_RESULT([no])
 533         NO_DEFLATE_BOUND=yes])
 534 LIBS="$old_LIBS"
 535
 536 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 537
 538 AC_SUBST(NO_DEFLATE_BOUND)
 539
 540 #
 541 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 542 # Patrick Mauritz).
 543 AC_CHECK_LIB([c], [socket],
 544 [NEEDS_SOCKET=],
 545 [NEEDS_SOCKET=YesPlease])
 546 AC_SUBST(NEEDS_SOCKET)
 547 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 548
 549 #
 550 # The next few tests will define NEEDS_RESOLV if linking with
 551 # libresolv provides some of the functions we would normally get
 552 # from libc.
 553 NEEDS_RESOLV=
 554 AC_SUBST(NEEDS_RESOLV)
 555 #
 556 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 557 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 558 NO_INET_NTOP=
 559 AC_SUBST(NO_INET_NTOP)
 560 AC_CHECK_FUNC([inet_ntop],
 561         [],
 562     [AC_CHECK_LIB([resolv], [inet_ntop],
 563             [NEEDS_RESOLV=YesPlease],
 564         [NO_INET_NTOP=YesPlease])
 565 ])
 566 #
 567 # Define NO_INET_PTON if linking with -lresolv is not enough.
 568 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 569 NO_INET_PTON=
 570 AC_SUBST(NO_INET_PTON)
 571 AC_CHECK_FUNC([inet_pton],
 572         [],
 573     [AC_CHECK_LIB([resolv], [inet_pton],
 574             [NEEDS_RESOLV=YesPlease],
 575         [NO_INET_PTON=YesPlease])
 576 ])
 577 #
 578 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 579 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 580 NO_HSTRERROR=
 581 AC_CHECK_FUNC([hstrerror],
 582         [],
 583     [AC_CHECK_LIB([resolv], [hstrerror],
 584             [NEEDS_RESOLV=YesPlease],
 585         [NO_HSTRERROR=YesPlease])
 586 ])
 587 AC_SUBST(NO_HSTRERROR)
 588 #
 589 # If any of the above tests determined that -lresolv is needed at
 590 # build-time, also set it here for remaining configure-time checks.
 591 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 592
 593 AC_CHECK_LIB([c], [basename],
 594 [NEEDS_LIBGEN=],
 595 [NEEDS_LIBGEN=YesPlease])
 596 AC_SUBST(NEEDS_LIBGEN)
 597 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 598
 599 ## Checks for header files.
 600 AC_MSG_NOTICE([CHECKS for header files])
 601 #
 602 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 603 AC_CHECK_HEADER([sys/select.h],
 604 [NO_SYS_SELECT_H=],
 605 [NO_SYS_SELECT_H=UnfortunatelyYes])
 606 AC_SUBST(NO_SYS_SELECT_H)
 607 #
 608 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 609 AC_CHECK_HEADER([sys/poll.h],
 610 [NO_SYS_POLL_H=],
 611 [NO_SYS_POLL_H=UnfortunatelyYes])
 612 AC_SUBST(NO_SYS_POLL_H)
 613 #
 614 # Define NO_INTTYPES_H if you don't have inttypes.h
 615 AC_CHECK_HEADER([inttypes.h],
 616 [NO_INTTYPES_H=],
 617 [NO_INTTYPES_H=UnfortunatelyYes])
 618 AC_SUBST(NO_INTTYPES_H)
 619 #
 620 # Define OLD_ICONV if your library has an old iconv(), where the second
 621 # (input buffer pointer) parameter is declared with type (const char **).
 622 AC_DEFUN([OLDICONVTEST_SRC], [
 623 AC_LANG_PROGRAM([[
 624 #include <iconv.h>
 625
 626 extern size_t iconv(iconv_t cd,
 627                     char **inbuf, size_t *inbytesleft,
 628                     char **outbuf, size_t *outbytesleft);
 629 ]], [])])
 630
 631 GIT_STASH_FLAGS($ICONVDIR)
 632
 633 AC_MSG_CHECKING([for old iconv()])
 634 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 635         [AC_MSG_RESULT([no])],
 636         [AC_MSG_RESULT([yes])
 637         OLD_ICONV=UnfortunatelyYes])
 638
 639 GIT_UNSTASH_FLAGS($ICONVDIR)
 640
 641 AC_SUBST(OLD_ICONV)
 642
 643 ## Checks for typedefs, structures, and compiler characteristics.
 644 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 645 #
 646 TYPE_SOCKLEN_T
 647 case $ac_cv_type_socklen_t in
 648   yes)  ;;
 649   *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 650 esac
 651
 652 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 653 AC_CHECK_MEMBER(struct dirent.d_ino,
 654 [NO_D_INO_IN_DIRENT=],
 655 [NO_D_INO_IN_DIRENT=YesPlease],
 656 [#include <dirent.h>])
 657 AC_SUBST(NO_D_INO_IN_DIRENT)
 658 #
 659 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 660 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 661 AC_CHECK_MEMBER(struct dirent.d_type,
 662 [NO_D_TYPE_IN_DIRENT=],
 663 [NO_D_TYPE_IN_DIRENT=YesPlease],
 664 [#include <dirent.h>])
 665 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 666 #
 667 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 668 # sockaddr_storage.
 669 AC_CHECK_TYPE(struct sockaddr_storage,
 670 [NO_SOCKADDR_STORAGE=],
 671 [NO_SOCKADDR_STORAGE=YesPlease],[
 672 #include <sys/types.h>
 673 #include <sys/socket.h>
 674 ])
 675 AC_SUBST(NO_SOCKADDR_STORAGE)
 676 #
 677 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 678 AC_CHECK_TYPE([struct addrinfo],[
 679  GIT_CHECK_FUNC([getaddrinfo],
 680   [NO_IPV6=],
 681   [NO_IPV6=YesPlease])
 682 ],[NO_IPV6=YesPlease],[
 683 #include <sys/types.h>
 684 #include <sys/socket.h>
 685 #include <netdb.h>
 686 ])
 687 AC_SUBST(NO_IPV6)
 688 #
 689 # Define NO_REGEX if you have no or inferior regex support in your C library.
 690 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 691  [ac_cv_c_excellent_regex], [
 692 AC_EGREP_CPP(yippeeyeswehaveit,
 693         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 694 #include <regex.h>
 695 ],
 696 [#ifdef REG_STARTEND
 697 yippeeyeswehaveit
 698 #endif
 699 ]),
 700         [ac_cv_c_excellent_regex=yes],
 701         [ac_cv_c_excellent_regex=no])
 702 ])
 703 if test $ac_cv_c_excellent_regex = yes; then
 704         NO_REGEX=
 705 else
 706         NO_REGEX=YesPlease
 707 fi
 708 AC_SUBST(NO_REGEX)
 709 #
 710 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 711 # when attempting to read from an fopen'ed directory.
 712 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 713  [ac_cv_fread_reads_directories],
 714 [
 715 AC_RUN_IFELSE(
 716         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 717                 [[char c;
 718                 FILE *f = fopen(".", "r");
 719                 return f && fread(&c, 1, 1, f)]])],
 720         [ac_cv_fread_reads_directories=no],
 721         [ac_cv_fread_reads_directories=yes])
 722 ])
 723 if test $ac_cv_fread_reads_directories = yes; then
 724         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 725 else
 726         FREAD_READS_DIRECTORIES=
 727 fi
 728 AC_SUBST(FREAD_READS_DIRECTORIES)
 729 #
 730 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 731 # or vsnprintf() return -1 instead of number of characters which would
 732 # have been written to the final string if enough space had been available.
 733 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 734  [ac_cv_snprintf_returns_bogus],
 735 [
 736 AC_RUN_IFELSE(
 737         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 738                 #include "stdarg.h"
 739
 740                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 741                 {
 742                   int ret;
 743                   va_list ap;
 744                   va_start(ap, format);
 745                   ret = vsnprintf(str, maxsize, format, ap);
 746                   va_end(ap);
 747                   return ret;
 748                 }],
 749                 [[char buf[6];
 750                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 751                       || strcmp(buf, "12")) return 1;
 752                   if (snprintf(buf, 3, "%s", "12345") != 5
 753                       || strcmp(buf, "12")) return 1]])],
 754         [ac_cv_snprintf_returns_bogus=no],
 755         [ac_cv_snprintf_returns_bogus=yes])
 756 ])
 757 if test $ac_cv_snprintf_returns_bogus = yes; then
 758         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 759 else
 760         SNPRINTF_RETURNS_BOGUS=
 761 fi
 762 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 763
 764
 765 ## Checks for library functions.
 766 ## (in default C library and libraries checked by AC_CHECK_LIB)
 767 AC_MSG_NOTICE([CHECKS for library functions])
 768 #
 769 # Define NO_LIBGEN_H if you don't have libgen.h.
 770 AC_CHECK_HEADER([libgen.h],
 771 [NO_LIBGEN_H=],
 772 [NO_LIBGEN_H=YesPlease])
 773 AC_SUBST(NO_LIBGEN_H)
 774 #
 775 # Define HAVE_PATHS_H if you have paths.h.
 776 AC_CHECK_HEADER([paths.h],
 777 [HAVE_PATHS_H=YesPlease],
 778 [HAVE_PATHS_H=])
 779 AC_SUBST(HAVE_PATHS_H)
 780 #
 781 # Define NO_STRCASESTR if you don't have strcasestr.
 782 GIT_CHECK_FUNC(strcasestr,
 783 [NO_STRCASESTR=],
 784 [NO_STRCASESTR=YesPlease])
 785 AC_SUBST(NO_STRCASESTR)
 786 #
 787 # Define NO_STRTOK_R if you don't have strtok_r
 788 GIT_CHECK_FUNC(strtok_r,
 789 [NO_STRTOK_R=],
 790 [NO_STRTOK_R=YesPlease])
 791 AC_SUBST(NO_STRTOK_R)
 792 #
 793 # Define NO_FNMATCH if you don't have fnmatch
 794 GIT_CHECK_FUNC(fnmatch,
 795 [NO_FNMATCH=],
 796 [NO_FNMATCH=YesPlease])
 797 AC_SUBST(NO_FNMATCH)
 798 #
 799 # Define NO_FNMATCH_CASEFOLD if your fnmatch function doesn't have the
 800 # FNM_CASEFOLD GNU extension.
 801 AC_CACHE_CHECK([whether the fnmatch function supports the FNMATCH_CASEFOLD GNU extension],
 802  [ac_cv_c_excellent_fnmatch], [
 803 AC_EGREP_CPP(yippeeyeswehaveit,
 804         AC_LANG_PROGRAM([
 805 #include <fnmatch.h>
 806 ],
 807 [#ifdef FNM_CASEFOLD
 808 yippeeyeswehaveit
 809 #endif
 810 ]),
 811         [ac_cv_c_excellent_fnmatch=yes],
 812         [ac_cv_c_excellent_fnmatch=no])
 813 ])
 814 if test $ac_cv_c_excellent_fnmatch = yes; then
 815         NO_FNMATCH_CASEFOLD=
 816 else
 817         NO_FNMATCH_CASEFOLD=YesPlease
 818 fi
 819 AC_SUBST(NO_FNMATCH_CASEFOLD)
 820 #
 821 # Define NO_MEMMEM if you don't have memmem.
 822 GIT_CHECK_FUNC(memmem,
 823 [NO_MEMMEM=],
 824 [NO_MEMMEM=YesPlease])
 825 AC_SUBST(NO_MEMMEM)
 826 #
 827 # Define NO_STRLCPY if you don't have strlcpy.
 828 GIT_CHECK_FUNC(strlcpy,
 829 [NO_STRLCPY=],
 830 [NO_STRLCPY=YesPlease])
 831 AC_SUBST(NO_STRLCPY)
 832 #
 833 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 834 AC_CHECK_TYPE(uintmax_t,
 835 [NO_UINTMAX_T=],
 836 [NO_UINTMAX_T=YesPlease],[
 837 #include <inttypes.h>
 838 ])
 839 AC_SUBST(NO_UINTMAX_T)
 840 #
 841 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 842 GIT_CHECK_FUNC(strtoumax,
 843 [NO_STRTOUMAX=],
 844 [NO_STRTOUMAX=YesPlease])
 845 AC_SUBST(NO_STRTOUMAX)
 846 #
 847 # Define NO_SETENV if you don't have setenv in the C library.
 848 GIT_CHECK_FUNC(setenv,
 849 [NO_SETENV=],
 850 [NO_SETENV=YesPlease])
 851 AC_SUBST(NO_SETENV)
 852 #
 853 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 854 GIT_CHECK_FUNC(unsetenv,
 855 [NO_UNSETENV=],
 856 [NO_UNSETENV=YesPlease])
 857 AC_SUBST(NO_UNSETENV)
 858 #
 859 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 860 GIT_CHECK_FUNC(mkdtemp,
 861 [NO_MKDTEMP=],
 862 [NO_MKDTEMP=YesPlease])
 863 AC_SUBST(NO_MKDTEMP)
 864 #
 865 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 866 GIT_CHECK_FUNC(mkstemps,
 867 [NO_MKSTEMPS=],
 868 [NO_MKSTEMPS=YesPlease])
 869 AC_SUBST(NO_MKSTEMPS)
 870 #
 871 # Define NO_INITGROUPS if you don't have initgroups in the C library.
 872 GIT_CHECK_FUNC(initgroups,
 873 [NO_INITGROUPS=],
 874 [NO_INITGROUPS=YesPlease])
 875 AC_SUBST(NO_INITGROUPS)
 876 #
 877 #
 878 # Define NO_MMAP if you want to avoid mmap.
 879 #
 880 # Define NO_ICONV if your libc does not properly support iconv.
 881
 882
 883 ## Other checks.
 884 # Define USE_PIC if you need the main git objects to be built with -fPIC
 885 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 886 #
 887 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 888 # Enable it on Windows.  By default, symrefs are still used.
 889 #
 890 # Define NO_PTHREADS if we do not have pthreads.
 891 #
 892 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
 893 AC_DEFUN([PTHREADTEST_SRC], [
 894 AC_LANG_PROGRAM([[
 895 #include <pthread.h>
 896 ]], [[
 897         pthread_mutex_t test_mutex;
 898         int retcode = 0;
 899         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 900         retcode |= pthread_mutex_lock(&test_mutex);
 901         retcode |= pthread_mutex_unlock(&test_mutex);
 902         return retcode;
 903 ]])])
 904
 905 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 906 dnl   [[#include <pthread.h>]],
 907 dnl   [[pthread_mutex_t test_mutex;]]
 908 dnl )])
 909
 910 NO_PTHREADS=UnfortunatelyYes
 911 PTHREAD_LIBS=
 912
 913 if test -n "$USER_NOPTHREAD"; then
 914    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 915 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 916 # -D_REENTRANT' or some such.
 917 elif test -z "$PTHREAD_CFLAGS"; then
 918   threads_found=no
 919   for opt in -mt -pthread -lpthread; do
 920      old_CFLAGS="$CFLAGS"
 921      CFLAGS="$opt $CFLAGS"
 922      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 923      AC_LINK_IFELSE([PTHREADTEST_SRC],
 924         [AC_MSG_RESULT([yes])
 925                 NO_PTHREADS=
 926                 PTHREAD_LIBS="$opt"
 927                 PTHREAD_CFLAGS="$opt"
 928                 threads_found=yes
 929                 break
 930         ],
 931         [AC_MSG_RESULT([no])])
 932       CFLAGS="$old_CFLAGS"
 933   done
 934   if test $threads_found != yes; then
 935     AC_CHECK_LIB([pthread], [pthread_create],
 936         [PTHREAD_LIBS="-lpthread"],
 937         [NO_PTHREADS=UnfortunatelyYes])
 938   fi
 939 else
 940   old_CFLAGS="$CFLAGS"
 941   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 942   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 943   AC_LINK_IFELSE([PTHREADTEST_SRC],
 944         [AC_MSG_RESULT([yes])
 945                 NO_PTHREADS=
 946                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
 947         ],
 948         [AC_MSG_RESULT([no])])
 949
 950   CFLAGS="$old_CFLAGS"
 951 fi
 952
 953 CFLAGS="$old_CFLAGS"
 954
 955 AC_SUBST(PTHREAD_CFLAGS)
 956 AC_SUBST(PTHREAD_LIBS)
 957 AC_SUBST(NO_PTHREADS)
 958
 959 ## Output files
 960 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 961 AC_OUTPUT
 962
 963
 964 ## Cleanup
 965 rm -f "${config_append}"