git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 if (! exists $ENV{SVN_SSH}) {
  25         if (exists $ENV{GIT_SSH}) {
  26                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27                 if ($^O eq 'msys') {
  28                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  29                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  30                 }
  31         }
  32 }
  33
  34 $Git::SVN::Log::TZ = $ENV{TZ};
  35 $ENV{TZ} = 'UTC';
  36 $| = 1; # unbuffer STDOUT
  37
  38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  39 sub _req_svn {
  40         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  41         require SVN::Ra;
  42         require SVN::Delta;
  43         if ($SVN::Core::VERSION lt '1.1.0') {
  44                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  45         }
  46 }
  47 my $can_compress = eval { require Compress::Zlib; 1};
  48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  51 use Carp qw/croak/;
  52 use Digest::MD5;
  53 use IO::File qw//;
  54 use File::Basename qw/dirname basename/;
  55 use File::Path qw/mkpath/;
  56 use File::Spec;
  57 use File::Find;
  58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  59 use IPC::Open3;
  60 use Git;
  61
  62 BEGIN {
  63         # import functions from Git into our packages, en masse
  64         no strict 'refs';
  65         foreach (qw/command command_oneline command_noisy command_output_pipe
  66                     command_input_pipe command_close_pipe
  67                     command_bidi_pipe command_close_bidi_pipe/) {
  68                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  69                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  70                         __PACKAGE__) {
  71                         *{"${package}::$_"} = \&{"Git::$_"};
  72                 }
  73         }
  74 }
  75
  76 my ($SVN);
  77
  78 $sha1 = qr/[a-f\d]{40}/;
  79 $sha1_short = qr/[a-f\d]{4,40}/;
  80 my ($_stdin, $_help, $_edit,
  81         $_message, $_file, $_branch_dest,
  82         $_template, $_shared,
  83         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  84         $_merge, $_strategy, $_dry_run, $_local,
  85         $_prefix, $_no_checkout, $_url, $_verbose,
  86         $_git_format, $_commit_url, $_tag);
  87 $Git::SVN::_follow_parent = 1;
  88 $_q ||= 0;
  89 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  90                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  91                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  92                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  93 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  94                 'authors-file|A=s' => \$_authors,
  95                 'authors-prog=s' => \$_authors_prog,
  96                 'repack:i' => \$Git::SVN::_repack,
  97                 'noMetadata' => \$Git::SVN::_no_metadata,
  98                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  99                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 100                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 101                 'no-checkout' => \$_no_checkout,
 102                 'quiet|q+' => \$_q,
 103                 'repack-flags|repack-args|repack-opts=s' =>
 104                    \$Git::SVN::_repack_flags,
 105                 'use-log-author' => \$Git::SVN::_use_log_author,
 106                 'add-author-from' => \$Git::SVN::_add_author_from,
 107                 'localtime' => \$Git::SVN::_localtime,
 108                 %remote_opts );
 109
 110 my ($_trunk, @_tags, @_branches, $_stdlayout);
 111 my %icv;
 112 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 113                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 114                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 115                   'stdlayout|s' => \$_stdlayout,
 116                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 117                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 118                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 119                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 120                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 121                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 122                   %remote_opts );
 123 my %cmt_opts = ( 'edit|e' => \$_edit,
 124                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 125                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 126                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 127                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 128 );
 129
 130 my %cmd = (
 131         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 132                         { 'revision|r=s' => \$_revision,
 133                           'fetch-all|all' => \$_fetch_all,
 134                           'parent|p' => \$_fetch_parent,
 135                            %fc_opts } ],
 136         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 137                         { 'revision|r=s' => \$_revision,
 138                            %fc_opts, %init_opts } ],
 139         init => [ \&cmd_init, "Initialize a repo for tracking" .
 140                           " (requires URL argument)",
 141                           \%init_opts ],
 142         'multi-init' => [ \&cmd_multi_init,
 143                           "Deprecated alias for ".
 144                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 145                           \%init_opts ],
 146         dcommit => [ \&cmd_dcommit,
 147                      'Commit several diffs to merge with upstream',
 148                         { 'merge|m|M' => \$_merge,
 149                           'strategy|s=s' => \$_strategy,
 150                           'verbose|v' => \$_verbose,
 151                           'dry-run|n' => \$_dry_run,
 152                           'fetch-all|all' => \$_fetch_all,
 153                           'commit-url=s' => \$_commit_url,
 154                           'revision|r=i' => \$_revision,
 155                           'no-rebase' => \$_no_rebase,
 156                         %cmt_opts, %fc_opts } ],
 157         branch => [ \&cmd_branch,
 158                     'Create a branch in the SVN repository',
 159                     { 'message|m=s' => \$_message,
 160                       'destination|d=s' => \$_branch_dest,
 161                       'dry-run|n' => \$_dry_run,
 162                       'tag|t' => \$_tag,
 163                       'username=s' => \$Git::SVN::Prompt::_username,
 164                       'commit-url=s' => \$_commit_url } ],
 165         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 166                  'Create a tag in the SVN repository',
 167                  { 'message|m=s' => \$_message,
 168                    'destination|d=s' => \$_branch_dest,
 169                    'dry-run|n' => \$_dry_run,
 170                    'username=s' => \$Git::SVN::Prompt::_username,
 171                    'commit-url=s' => \$_commit_url } ],
 172         'set-tree' => [ \&cmd_set_tree,
 173                         "Set an SVN repository to a git tree-ish",
 174                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 175         'create-ignore' => [ \&cmd_create_ignore,
 176                              'Create a .gitignore per svn:ignore',
 177                              { 'revision|r=i' => \$_revision
 178                              } ],
 179         'mkdirs' => [ \&cmd_mkdirs ,
 180                       "recreate empty directories after a checkout",
 181                       { 'revision|r=i' => \$_revision } ],
 182         'propget' => [ \&cmd_propget,
 183                        'Print the value of a property on a file or directory',
 184                        { 'revision|r=i' => \$_revision } ],
 185         'proplist' => [ \&cmd_proplist,
 186                        'List all properties of a file or directory',
 187                        { 'revision|r=i' => \$_revision } ],
 188         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 189                         { 'revision|r=i' => \$_revision
 190                         } ],
 191         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 192                         { 'revision|r=i' => \$_revision
 193                         } ],
 194         'multi-fetch' => [ \&cmd_multi_fetch,
 195                            "Deprecated alias for $0 fetch --all",
 196                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 197         'migrate' => [ sub { },
 198                        # no-op, we automatically run this anyways,
 199                        'Migrate configuration/metadata/layout from
 200                         previous versions of git-svn',
 201                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 202                          %remote_opts } ],
 203         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 204                         { 'limit=i' => \$Git::SVN::Log::limit,
 205                           'revision|r=s' => \$_revision,
 206                           'verbose|v' => \$Git::SVN::Log::verbose,
 207                           'incremental' => \$Git::SVN::Log::incremental,
 208                           'oneline' => \$Git::SVN::Log::oneline,
 209                           'show-commit' => \$Git::SVN::Log::show_commit,
 210                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 211                           'authors-file|A=s' => \$_authors,
 212                           'color' => \$Git::SVN::Log::color,
 213                           'pager=s' => \$Git::SVN::Log::pager
 214                         } ],
 215         'find-rev' => [ \&cmd_find_rev,
 216                         "Translate between SVN revision numbers and tree-ish",
 217                         {} ],
 218         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 219                         { 'merge|m|M' => \$_merge,
 220                           'verbose|v' => \$_verbose,
 221                           'strategy|s=s' => \$_strategy,
 222                           'local|l' => \$_local,
 223                           'fetch-all|all' => \$_fetch_all,
 224                           'dry-run|n' => \$_dry_run,
 225                           %fc_opts } ],
 226         'commit-diff' => [ \&cmd_commit_diff,
 227                            'Commit a diff between two trees',
 228                         { 'message|m=s' => \$_message,
 229                           'file|F=s' => \$_file,
 230                           'revision|r=s' => \$_revision,
 231                         %cmt_opts } ],
 232         'info' => [ \&cmd_info,
 233                     "Show info about the latest SVN revision
 234                      on the current branch",
 235                     { 'url' => \$_url, } ],
 236         'blame' => [ \&Git::SVN::Log::cmd_blame,
 237                     "Show what revision and author last modified each line of a file",
 238                     { 'git-format' => \$_git_format } ],
 239         'reset' => [ \&cmd_reset,
 240                      "Undo fetches back to the specified SVN revision",
 241                      { 'revision|r=s' => \$_revision,
 242                        'parent|p' => \$_fetch_parent } ],
 243         'gc' => [ \&cmd_gc,
 244                   "Compress unhandled.log files in .git/svn and remove " .
 245                   "index files in .git/svn",
 246                 {} ],
 247 );
 248
 249 my $cmd;
 250 for (my $i = 0; $i < @ARGV; $i++) {
 251         if (defined $cmd{$ARGV[$i]}) {
 252                 $cmd = $ARGV[$i];
 253                 splice @ARGV, $i, 1;
 254                 last;
 255         } elsif ($ARGV[$i] eq 'help') {
 256                 $cmd = $ARGV[$i+1];
 257                 usage(0);
 258         }
 259 };
 260
 261 # make sure we're always running at the top-level working directory
 262 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 263         unless (-d $ENV{GIT_DIR}) {
 264                 if ($git_dir_user_set) {
 265                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 266                             "but it is not a directory\n";
 267                 }
 268                 my $git_dir = delete $ENV{GIT_DIR};
 269                 my $cdup = undef;
 270                 git_cmd_try {
 271                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 272                         $git_dir = '.' unless ($cdup);
 273                         chomp $cdup if ($cdup);
 274                         $cdup = "." unless ($cdup && length $cdup);
 275                 } "Already at toplevel, but $git_dir not found\n";
 276                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 277                 unless (-d $git_dir) {
 278                         die "$git_dir still not found after going to ",
 279                             "'$cdup'\n";
 280                 }
 281                 $ENV{GIT_DIR} = $git_dir;
 282         }
 283         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 284 }
 285
 286 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 287
 288 read_git_config(\%opts);
 289 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 290         Getopt::Long::Configure('pass_through');
 291 }
 292 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 293                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 294                     'id|i=s' => \$Git::SVN::default_ref_id,
 295                     'svn-remote|remote|R=s' => sub {
 296                        $Git::SVN::no_reuse_existing = 1;
 297                        $Git::SVN::default_repo_id = $_[1] });
 298 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 299
 300 usage(0) if $_help;
 301 version() if $_version;
 302 usage(1) unless defined $cmd;
 303 load_authors() if $_authors;
 304 if (defined $_authors_prog) {
 305         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 306 }
 307
 308 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 309         Git::SVN::Migration::migration_check();
 310 }
 311 Git::SVN::init_vars();
 312 eval {
 313         Git::SVN::verify_remotes_sanity();
 314         $cmd{$cmd}->[0]->(@ARGV);
 315 };
 316 fatal $@ if $@;
 317 post_fetch_checkout();
 318 exit 0;
 319
 320 ####################### primary functions ######################
 321 sub usage {
 322         my $exit = shift || 0;
 323         my $fd = $exit ? \*STDERR : \*STDOUT;
 324         print $fd <<"";
 325 git-svn - bidirectional operations between a single Subversion tree and git
 326 Usage: git svn <command> [options] [arguments]\n
 327
 328         print $fd "Available commands:\n" unless $cmd;
 329
 330         foreach (sort keys %cmd) {
 331                 next if $cmd && $cmd ne $_;
 332                 next if /^multi-/; # don't show deprecated commands
 333                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 334                 foreach (sort keys %{$cmd{$_}->[2]}) {
 335                         # mixed-case options are for .git/config only
 336                         next if /[A-Z]/ && /^[a-z]+$/i;
 337                         # prints out arguments as they should be passed:
 338                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 339                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 340                                                         "--$_" : "-$_" }
 341                                                 split /\|/,$_)," $x\n";
 342                 }
 343         }
 344         print $fd <<"";
 345 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 346 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 347 one git repository and want to keep them separate.  See git-svn(1) for more
 348 information.
 349
 350         exit $exit;
 351 }
 352
 353 sub version {
 354         ::_req_svn();
 355         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 356         exit 0;
 357 }
 358
 359 sub do_git_init_db {
 360         unless (-d $ENV{GIT_DIR}) {
 361                 my @init_db = ('init');
 362                 push @init_db, "--template=$_template" if defined $_template;
 363                 if (defined $_shared) {
 364                         if ($_shared =~ /[a-z]/) {
 365                                 push @init_db, "--shared=$_shared";
 366                         } else {
 367                                 push @init_db, "--shared";
 368                         }
 369                 }
 370                 command_noisy(@init_db);
 371                 $_repository = Git->repository(Repository => ".git");
 372         }
 373         my $set;
 374         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 375         foreach my $i (keys %icv) {
 376                 die "'$set' and '$i' cannot both be set\n" if $set;
 377                 next unless defined $icv{$i};
 378                 command_noisy('config', "$pfx.$i", $icv{$i});
 379                 $set = $i;
 380         }
 381         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 382         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 383                 if defined $$ignore_regex;
 384 }
 385
 386 sub init_subdir {
 387         my $repo_path = shift or return;
 388         mkpath([$repo_path]) unless -d $repo_path;
 389         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 390         $ENV{GIT_DIR} = '.git';
 391         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 392 }
 393
 394 sub cmd_clone {
 395         my ($url, $path) = @_;
 396         if (!defined $path &&
 397             (defined $_trunk || @_branches || @_tags ||
 398              defined $_stdlayout) &&
 399             $url !~ m#^[a-z\+]+://#) {
 400                 $path = $url;
 401         }
 402         $path = basename($url) if !defined $path || !length $path;
 403         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 404         cmd_init($url, $path);
 405         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 406             if $_authors;
 407         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 408 }
 409
 410 sub cmd_init {
 411         if (defined $_stdlayout) {
 412                 $_trunk = 'trunk' if (!defined $_trunk);
 413                 @_tags = 'tags' if (! @_tags);
 414                 @_branches = 'branches' if (! @_branches);
 415         }
 416         if (defined $_trunk || @_branches || @_tags) {
 417                 return cmd_multi_init(@_);
 418         }
 419         my $url = shift or die "SVN repository location required ",
 420                                "as a command-line argument\n";
 421         $url = canonicalize_url($url);
 422         init_subdir(@_);
 423         do_git_init_db();
 424
 425         if ($Git::SVN::_minimize_url eq 'unset') {
 426                 $Git::SVN::_minimize_url = 0;
 427         }
 428
 429         Git::SVN->init($url);
 430 }
 431
 432 sub cmd_fetch {
 433         if (grep /^\d+=./, @_) {
 434                 die "'<rev>=<commit>' fetch arguments are ",
 435                     "no longer supported.\n";
 436         }
 437         my ($remote) = @_;
 438         if (@_ > 1) {
 439                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 440         }
 441         $Git::SVN::no_reuse_existing = undef;
 442         if ($_fetch_parent) {
 443                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 444                 unless ($gs) {
 445                         die "Unable to determine upstream SVN information from ",
 446                             "working tree history\n";
 447                 }
 448                 # just fetch, don't checkout.
 449                 $_no_checkout = 'true';
 450                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 451         } elsif ($_fetch_all) {
 452                 cmd_multi_fetch();
 453         } else {
 454                 $remote ||= $Git::SVN::default_repo_id;
 455                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 456         }
 457 }
 458
 459 sub cmd_set_tree {
 460         my (@commits) = @_;
 461         if ($_stdin || !@commits) {
 462                 print "Reading from stdin...\n";
 463                 @commits = ();
 464                 while (<STDIN>) {
 465                         if (/\b($sha1_short)\b/o) {
 466                                 unshift @commits, $1;
 467                         }
 468                 }
 469         }
 470         my @revs;
 471         foreach my $c (@commits) {
 472                 my @tmp = command('rev-parse',$c);
 473                 if (scalar @tmp == 1) {
 474                         push @revs, $tmp[0];
 475                 } elsif (scalar @tmp > 1) {
 476                         push @revs, reverse(command('rev-list',@tmp));
 477                 } else {
 478                         fatal "Failed to rev-parse $c";
 479                 }
 480         }
 481         my $gs = Git::SVN->new;
 482         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 483         $gs->fetch;
 484         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 485                 fatal "There are new revisions that were fetched ",
 486                       "and need to be merged (or acknowledged) ",
 487                       "before committing.\nlast rev: $r_last\n",
 488                       " current: $gs->{last_rev}";
 489         }
 490         $gs->set_tree($_) foreach @revs;
 491         print "Done committing ",scalar @revs," revisions to SVN\n";
 492         unlink $gs->{index};
 493 }
 494
 495 sub cmd_dcommit {
 496         my $head = shift;
 497         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 498                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 499                 . "or stash them with `git stash'.\n";
 500         $head ||= 'HEAD';
 501
 502         my $old_head;
 503         if ($head ne 'HEAD') {
 504                 $old_head = eval {
 505                         command_oneline([qw/symbolic-ref -q HEAD/])
 506                 };
 507                 if ($old_head) {
 508                         $old_head =~ s{^refs/heads/}{};
 509                 } else {
 510                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 511                 }
 512                 command(['checkout', $head], STDERR => 0);
 513         }
 514
 515         my @refs;
 516         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 517         unless ($gs) {
 518                 die "Unable to determine upstream SVN information from ",
 519                     "$head history.\nPerhaps the repository is empty.";
 520         }
 521
 522         if (defined $_commit_url) {
 523                 $url = $_commit_url;
 524         } else {
 525                 $url = eval { command_oneline('config', '--get',
 526                               "svn-remote.$gs->{repo_id}.commiturl") };
 527                 if (!$url) {
 528                         $url = $gs->full_url
 529                 }
 530         }
 531
 532         my $last_rev = $_revision if defined $_revision;
 533         if ($url) {
 534                 print "Committing to $url ...\n";
 535         }
 536         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 537         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 538                 warn "Attempting to commit more than one change while ",
 539                      "--no-rebase is enabled.\n",
 540                      "If these changes depend on each other, re-running ",
 541                      "without --no-rebase may be required."
 542         }
 543         my $expect_url = $url;
 544         Git::SVN::remove_username($expect_url);
 545         while (1) {
 546                 my $d = shift @$linear_refs or last;
 547                 unless (defined $last_rev) {
 548                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 549                         unless (defined $last_rev) {
 550                                 fatal "Unable to extract revision information ",
 551                                       "from commit $d~1";
 552                         }
 553                 }
 554                 if ($_dry_run) {
 555                         print "diff-tree $d~1 $d\n";
 556                 } else {
 557                         my $cmt_rev;
 558                         my %ed_opts = ( r => $last_rev,
 559                                         log => get_commit_entry($d)->{log},
 560                                         ra => Git::SVN::Ra->new($url),
 561                                         config => SVN::Core::config_get_config(
 562                                                 $Git::SVN::Ra::config_dir
 563                                         ),
 564                                         tree_a => "$d~1",
 565                                         tree_b => $d,
 566                                         editor_cb => sub {
 567                                                print "Committed r$_[0]\n";
 568                                                $cmt_rev = $_[0];
 569                                         },
 570                                         svn_path => '');
 571                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 572                                 print "No changes\n$d~1 == $d\n";
 573                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 574                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 575                                                                $parents->{$d};
 576                         }
 577                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 578                         $last_rev = $cmt_rev;
 579                         next if $_no_rebase;
 580
 581                         # we always want to rebase against the current HEAD,
 582                         # not any head that was passed to us
 583                         my @diff = command('diff-tree', $d,
 584                                            $gs->refname, '--');
 585                         my @finish;
 586                         if (@diff) {
 587                                 @finish = rebase_cmd();
 588                                 print STDERR "W: $d and ", $gs->refname,
 589                                              " differ, using @finish:\n",
 590                                              join("\n", @diff), "\n";
 591                         } else {
 592                                 print "No changes between current HEAD and ",
 593                                       $gs->refname,
 594                                       "\nResetting to the latest ",
 595                                       $gs->refname, "\n";
 596                                 @finish = qw/reset --mixed/;
 597                         }
 598                         command_noisy(@finish, $gs->refname);
 599                         if (@diff) {
 600                                 @refs = ();
 601                                 my ($url_, $rev_, $uuid_, $gs_) =
 602                                               working_head_info('HEAD', \@refs);
 603                                 my ($linear_refs_, $parents_) =
 604                                               linearize_history($gs_, \@refs);
 605                                 if (scalar(@$linear_refs) !=
 606                                     scalar(@$linear_refs_)) {
 607                                         fatal "# of revisions changed ",
 608                                           "\nbefore:\n",
 609                                           join("\n", @$linear_refs),
 610                                           "\n\nafter:\n",
 611                                           join("\n", @$linear_refs_), "\n",
 612                                           'If you are attempting to commit ',
 613                                           "merges, try running:\n\t",
 614                                           'git rebase --interactive',
 615                                           '--preserve-merges ',
 616                                           $gs->refname,
 617                                           "\nBefore dcommitting";
 618                                 }
 619                                 if ($url_ ne $expect_url) {
 620                                         if ($url_ eq $gs->metadata_url) {
 621                                                 print
 622                                                   "Accepting rewritten URL:",
 623                                                   " $url_\n";
 624                                         } else {
 625                                                 fatal
 626                                                   "URL mismatch after rebase:",
 627                                                   " $url_ != $expect_url";
 628                                         }
 629                                 }
 630                                 if ($uuid_ ne $uuid) {
 631                                         fatal "uuid mismatch after rebase: ",
 632                                               "$uuid_ != $uuid";
 633                                 }
 634                                 # remap parents
 635                                 my (%p, @l, $i);
 636                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 637                                         my $new = $linear_refs_->[$i] or next;
 638                                         $p{$new} =
 639                                                 $parents->{$linear_refs->[$i]};
 640                                         push @l, $new;
 641                                 }
 642                                 $parents = \%p;
 643                                 $linear_refs = \@l;
 644                         }
 645                 }
 646         }
 647
 648         if ($old_head) {
 649                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 650                 my $new_is_symbolic = eval {
 651                         command_oneline(qw/symbolic-ref -q HEAD/);
 652                 };
 653                 if ($new_is_symbolic) {
 654                         print "dcommitted the branch ", $head, "\n";
 655                 } else {
 656                         print "dcommitted on a detached HEAD because you gave ",
 657                               "a revision argument.\n",
 658                               "The rewritten commit is: ", $new_head, "\n";
 659                 }
 660                 command(['checkout', $old_head], STDERR => 0);
 661         }
 662
 663         unlink $gs->{index};
 664 }
 665
 666 sub cmd_branch {
 667         my ($branch_name, $head) = @_;
 668
 669         unless (defined $branch_name && length $branch_name) {
 670                 die(($_tag ? "tag" : "branch") . " name required\n");
 671         }
 672         $head ||= 'HEAD';
 673
 674         my (undef, $rev, undef, $gs) = working_head_info($head);
 675         my $src = $gs->full_url;
 676
 677         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 678         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 679         my $glob;
 680         if ($#{$allglobs} == 0) {
 681                 $glob = $allglobs->[0];
 682         } else {
 683                 unless(defined $_branch_dest) {
 684                         die "Multiple ",
 685                             $_tag ? "tag" : "branch",
 686                             " paths defined for Subversion repository.\n",
 687                             "You must specify where you want to create the ",
 688                             $_tag ? "tag" : "branch",
 689                             " with the --destination argument.\n";
 690                 }
 691                 foreach my $g (@{$allglobs}) {
 692                         # SVN::Git::Editor could probably be moved to Git.pm..
 693                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 694                         if ($_branch_dest =~ /$re/) {
 695                                 $glob = $g;
 696                                 last;
 697                         }
 698                 }
 699                 unless (defined $glob) {
 700                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 701                         foreach my $g (@{$allglobs}) {
 702                                 $g->{path}->{left} =~ /$dest_re/ or next;
 703                                 if (defined $glob) {
 704                                         die "Ambiguous destination: ",
 705                                             $_branch_dest, "\nmatches both '",
 706                                             $glob->{path}->{left}, "' and '",
 707                                             $g->{path}->{left}, "'\n";
 708                                 }
 709                                 $glob = $g;
 710                         }
 711                         unless (defined $glob) {
 712                                 die "Unknown ",
 713                                     $_tag ? "tag" : "branch",
 714                                     " destination $_branch_dest\n";
 715                         }
 716                 }
 717         }
 718         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 719         my $url;
 720         if (defined $_commit_url) {
 721                 $url = $_commit_url;
 722         } else {
 723                 $url = eval { command_oneline('config', '--get',
 724                         "svn-remote.$gs->{repo_id}.commiturl") };
 725                 if (!$url) {
 726                         $url = $remote->{url};
 727                 }
 728         }
 729         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 730
 731         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 732                 $src=~s/^http:/https:/;
 733         }
 734
 735         ::_req_svn();
 736
 737         my $ctx = SVN::Client->new(
 738                 auth    => Git::SVN::Ra::_auth_providers(),
 739                 log_msg => sub {
 740                         ${ $_[0] } = defined $_message
 741                                 ? $_message
 742                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 743                                 . $branch_name;
 744                 },
 745         );
 746
 747         eval {
 748                 $ctx->ls($dst, 'HEAD', 0);
 749         } and die "branch ${branch_name} already exists\n";
 750
 751         print "Copying ${src} at r${rev} to ${dst}...\n";
 752         $ctx->copy($src, $rev, $dst)
 753                 unless $_dry_run;
 754
 755         $gs->fetch_all;
 756 }
 757
 758 sub cmd_find_rev {
 759         my $revision_or_hash = shift or die "SVN or git revision required ",
 760                                             "as a command-line argument\n";
 761         my $result;
 762         if ($revision_or_hash =~ /^r\d+$/) {
 763                 my $head = shift;
 764                 $head ||= 'HEAD';
 765                 my @refs;
 766                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 767                 unless ($gs) {
 768                         die "Unable to determine upstream SVN information from ",
 769                             "$head history\n";
 770                 }
 771                 my $desired_revision = substr($revision_or_hash, 1);
 772                 $result = $gs->rev_map_get($desired_revision, $uuid);
 773         } else {
 774                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 775                 $result = $rev;
 776         }
 777         print "$result\n" if $result;
 778 }
 779
 780 sub cmd_rebase {
 781         command_noisy(qw/update-index --refresh/);
 782         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 783         unless ($gs) {
 784                 die "Unable to determine upstream SVN information from ",
 785                     "working tree history\n";
 786         }
 787         if ($_dry_run) {
 788                 print "Remote Branch: " . $gs->refname . "\n";
 789                 print "SVN URL: " . $url . "\n";
 790                 return;
 791         }
 792         if (command(qw/diff-index HEAD --/)) {
 793                 print STDERR "Cannot rebase with uncommited changes:\n";
 794                 command_noisy('status');
 795                 exit 1;
 796         }
 797         unless ($_local) {
 798                 # rebase will checkout for us, so no need to do it explicitly
 799                 $_no_checkout = 'true';
 800                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 801         }
 802         command_noisy(rebase_cmd(), $gs->refname);
 803         $gs->mkemptydirs;
 804 }
 805
 806 sub cmd_show_ignore {
 807         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 808         $gs ||= Git::SVN->new;
 809         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 810         $gs->prop_walk($gs->{path}, $r, sub {
 811                 my ($gs, $path, $props) = @_;
 812                 print STDOUT "\n# $path\n";
 813                 my $s = $props->{'svn:ignore'} or return;
 814                 $s =~ s/[\r\n]+/\n/g;
 815                 $s =~ s/^\n+//;
 816                 chomp $s;
 817                 $s =~ s#^#$path#gm;
 818                 print STDOUT "$s\n";
 819         });
 820 }
 821
 822 sub cmd_show_externals {
 823         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 824         $gs ||= Git::SVN->new;
 825         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 826         $gs->prop_walk($gs->{path}, $r, sub {
 827                 my ($gs, $path, $props) = @_;
 828                 print STDOUT "\n# $path\n";
 829                 my $s = $props->{'svn:externals'} or return;
 830                 $s =~ s/[\r\n]+/\n/g;
 831                 chomp $s;
 832                 $s =~ s#^#$path#gm;
 833                 print STDOUT "$s\n";
 834         });
 835 }
 836
 837 sub cmd_create_ignore {
 838         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 839         $gs ||= Git::SVN->new;
 840         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 841         $gs->prop_walk($gs->{path}, $r, sub {
 842                 my ($gs, $path, $props) = @_;
 843                 # $path is of the form /path/to/dir/
 844                 $path = '.' . $path;
 845                 # SVN can have attributes on empty directories,
 846                 # which git won't track
 847                 mkpath([$path]) unless -d $path;
 848                 my $ignore = $path . '.gitignore';
 849                 my $s = $props->{'svn:ignore'} or return;
 850                 open(GITIGNORE, '>', $ignore)
 851                   or fatal("Failed to open `$ignore' for writing: $!");
 852                 $s =~ s/[\r\n]+/\n/g;
 853                 $s =~ s/^\n+//;
 854                 chomp $s;
 855                 # Prefix all patterns so that the ignore doesn't apply
 856                 # to sub-directories.
 857                 $s =~ s#^#/#gm;
 858                 print GITIGNORE "$s\n";
 859                 close(GITIGNORE)
 860                   or fatal("Failed to close `$ignore': $!");
 861                 command_noisy('add', '-f', $ignore);
 862         });
 863 }
 864
 865 sub cmd_mkdirs {
 866         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 867         $gs ||= Git::SVN->new;
 868         $gs->mkemptydirs($_revision);
 869 }
 870
 871 sub canonicalize_path {
 872         my ($path) = @_;
 873         my $dot_slash_added = 0;
 874         if (substr($path, 0, 1) ne "/") {
 875                 $path = "./" . $path;
 876                 $dot_slash_added = 1;
 877         }
 878         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 879         # good reason), so let's do this manually.
 880         $path =~ s#/+#/#g;
 881         $path =~ s#/\.(?:/|$)#/#g;
 882         $path =~ s#/[^/]+/\.\.##g;
 883         $path =~ s#/$##g;
 884         $path =~ s#^\./## if $dot_slash_added;
 885         $path =~ s#^/##;
 886         $path =~ s#^\.$##;
 887         return $path;
 888 }
 889
 890 sub canonicalize_url {
 891         my ($url) = @_;
 892         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 893         return $url;
 894 }
 895
 896 # get_svnprops(PATH)
 897 # ------------------
 898 # Helper for cmd_propget and cmd_proplist below.
 899 sub get_svnprops {
 900         my $path = shift;
 901         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 902         $gs ||= Git::SVN->new;
 903
 904         # prefix THE PATH by the sub-directory from which the user
 905         # invoked us.
 906         $path = $cmd_dir_prefix . $path;
 907         fatal("No such file or directory: $path") unless -e $path;
 908         my $is_dir = -d $path ? 1 : 0;
 909         $path = $gs->{path} . '/' . $path;
 910
 911         # canonicalize the path (otherwise libsvn will abort or fail to
 912         # find the file)
 913         $path = canonicalize_path($path);
 914
 915         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 916         my $props;
 917         if ($is_dir) {
 918                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 919         }
 920         else {
 921                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 922         }
 923         return $props;
 924 }
 925
 926 # cmd_propget (PROP, PATH)
 927 # ------------------------
 928 # Print the SVN property PROP for PATH.
 929 sub cmd_propget {
 930         my ($prop, $path) = @_;
 931         $path = '.' if not defined $path;
 932         usage(1) if not defined $prop;
 933         my $props = get_svnprops($path);
 934         if (not defined $props->{$prop}) {
 935                 fatal("`$path' does not have a `$prop' SVN property.");
 936         }
 937         print $props->{$prop} . "\n";
 938 }
 939
 940 # cmd_proplist (PATH)
 941 # -------------------
 942 # Print the list of SVN properties for PATH.
 943 sub cmd_proplist {
 944         my $path = shift;
 945         $path = '.' if not defined $path;
 946         my $props = get_svnprops($path);
 947         print "Properties on '$path':\n";
 948         foreach (sort keys %{$props}) {
 949                 print "  $_\n";
 950         }
 951 }
 952
 953 sub cmd_multi_init {
 954         my $url = shift;
 955         unless (defined $_trunk || @_branches || @_tags) {
 956                 usage(1);
 957         }
 958
 959         $_prefix = '' unless defined $_prefix;
 960         if (defined $url) {
 961                 $url = canonicalize_url($url);
 962                 init_subdir(@_);
 963         }
 964         do_git_init_db();
 965         if (defined $_trunk) {
 966                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 967                 # try both old-style and new-style lookups:
 968                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 969                 unless ($gs_trunk) {
 970                         my ($trunk_url, $trunk_path) =
 971                                               complete_svn_url($url, $_trunk);
 972                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 973                                                    undef, $trunk_ref);
 974                 }
 975         }
 976         return unless @_branches || @_tags;
 977         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 978         foreach my $path (@_branches) {
 979                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 980         }
 981         foreach my $path (@_tags) {
 982                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 983         }
 984 }
 985
 986 sub cmd_multi_fetch {
 987         $Git::SVN::no_reuse_existing = undef;
 988         my $remotes = Git::SVN::read_all_remotes();
 989         foreach my $repo_id (sort keys %$remotes) {
 990                 if ($remotes->{$repo_id}->{url}) {
 991                         Git::SVN::fetch_all($repo_id, $remotes);
 992                 }
 993         }
 994 }
 995
 996 # this command is special because it requires no metadata
 997 sub cmd_commit_diff {
 998         my ($ta, $tb, $url) = @_;
 999         my $usage = "Usage: $0 commit-diff -r<revision> ".
1000                     "<tree-ish> <tree-ish> [<URL>]";
1001         fatal($usage) if (!defined $ta || !defined $tb);
1002         my $svn_path = '';
1003         if (!defined $url) {
1004                 my $gs = eval { Git::SVN->new };
1005                 if (!$gs) {
1006                         fatal("Needed URL or usable git-svn --id in ",
1007                               "the command-line\n", $usage);
1008                 }
1009                 $url = $gs->{url};
1010                 $svn_path = $gs->{path};
1011         }
1012         unless (defined $_revision) {
1013                 fatal("-r|--revision is a required argument\n", $usage);
1014         }
1015         if (defined $_message && defined $_file) {
1016                 fatal("Both --message/-m and --file/-F specified ",
1017                       "for the commit message.\n",
1018                       "I have no idea what you mean");
1019         }
1020         if (defined $_file) {
1021                 $_message = file_to_s($_file);
1022         } else {
1023                 $_message ||= get_commit_entry($tb)->{log};
1024         }
1025         my $ra ||= Git::SVN::Ra->new($url);
1026         my $r = $_revision;
1027         if ($r eq 'HEAD') {
1028                 $r = $ra->get_latest_revnum;
1029         } elsif ($r !~ /^\d+$/) {
1030                 die "revision argument: $r not understood by git-svn\n";
1031         }
1032         my %ed_opts = ( r => $r,
1033                         log => $_message,
1034                         ra => $ra,
1035                         tree_a => $ta,
1036                         tree_b => $tb,
1037                         editor_cb => sub { print "Committed r$_[0]\n" },
1038                         svn_path => $svn_path );
1039         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1040                 print "No changes\n$ta == $tb\n";
1041         }
1042 }
1043
1044 sub escape_uri_only {
1045         my ($uri) = @_;
1046         my @tmp;
1047         foreach (split m{/}, $uri) {
1048                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1049                 push @tmp, $_;
1050         }
1051         join('/', @tmp);
1052 }
1053
1054 sub escape_url {
1055         my ($url) = @_;
1056         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1057                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1058                 $url = "$scheme://$domain$uri";
1059         }
1060         $url;
1061 }
1062
1063 sub cmd_info {
1064         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1065         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1066         if (exists $_[1]) {
1067                 die "Too many arguments specified\n";
1068         }
1069
1070         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1071
1072         if (!$file_type && !$diff_status) {
1073                 print STDERR "svn: '$path' is not under version control\n";
1074                 exit 1;
1075         }
1076
1077         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1078         unless ($gs) {
1079                 die "Unable to determine upstream SVN information from ",
1080                     "working tree history\n";
1081         }
1082
1083         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1084         $path = "." if $path eq "";
1085
1086         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1087
1088         if ($_url) {
1089                 print escape_url($full_url), "\n";
1090                 return;
1091         }
1092
1093         my $result = "Path: $path\n";
1094         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1095         $result .= "URL: " . escape_url($full_url) . "\n";
1096
1097         eval {
1098                 my $repos_root = $gs->repos_root;
1099                 Git::SVN::remove_username($repos_root);
1100                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1101         };
1102         if ($@) {
1103                 $result .= "Repository Root: (offline)\n";
1104         }
1105         ::_req_svn();
1106         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1107                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1108         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1109
1110         $result .= "Node Kind: " .
1111                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1112
1113         my $schedule = $diff_status eq "A"
1114                        ? "add"
1115                        : ($diff_status eq "D" ? "delete" : "normal");
1116         $result .= "Schedule: $schedule\n";
1117
1118         if ($diff_status eq "A") {
1119                 print $result, "\n";
1120                 return;
1121         }
1122
1123         my ($lc_author, $lc_rev, $lc_date_utc);
1124         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1125         my $log = command_output_pipe(@args);
1126         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1127         while (<$log>) {
1128                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1129                         $lc_author = $1;
1130                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1131                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1132                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1133                 }
1134         }
1135         close $log;
1136
1137         Git::SVN::Log::set_local_timezone();
1138
1139         $result .= "Last Changed Author: $lc_author\n";
1140         $result .= "Last Changed Rev: $lc_rev\n";
1141         $result .= "Last Changed Date: " .
1142                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1143
1144         if ($file_type ne "dir") {
1145                 my $text_last_updated_date =
1146                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1147                 $result .=
1148                     "Text Last Updated: " .
1149                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1150                     "\n";
1151                 my $checksum;
1152                 if ($diff_status eq "D") {
1153                         my ($fh, $ctx) =
1154                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1155                         if ($file_type eq "link") {
1156                                 my $file_name = <$fh>;
1157                                 $checksum = md5sum("link $file_name");
1158                         } else {
1159                                 $checksum = md5sum($fh);
1160                         }
1161                         command_close_pipe($fh, $ctx);
1162                 } elsif ($file_type eq "link") {
1163                         my $file_name =
1164                             command(qw(cat-file blob), "HEAD:$path");
1165                         $checksum =
1166                             md5sum("link " . $file_name);
1167                 } else {
1168                         open FILE, "<", $path or die $!;
1169                         $checksum = md5sum(\*FILE);
1170                         close FILE or die $!;
1171                 }
1172                 $result .= "Checksum: " . $checksum . "\n";
1173         }
1174
1175         print $result, "\n";
1176 }
1177
1178 sub cmd_reset {
1179         my $target = shift || $_revision or die "SVN revision required\n";
1180         $target = $1 if $target =~ /^r(\d+)$/;
1181         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1182         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1183         unless ($gs) {
1184                 die "Unable to determine upstream SVN information from ".
1185                     "history\n";
1186         }
1187         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1188         $gs->rev_map_set($r, $c, 'reset', $uuid);
1189         print "r$r = $c ($gs->{ref_id})\n";
1190 }
1191
1192 sub cmd_gc {
1193         if (!$can_compress) {
1194                 warn "Compress::Zlib could not be found; unhandled.log " .
1195                      "files will not be compressed.\n";
1196         }
1197         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1198 }
1199
1200 ########################### utility functions #########################
1201
1202 sub rebase_cmd {
1203         my @cmd = qw/rebase/;
1204         push @cmd, '-v' if $_verbose;
1205         push @cmd, qw/--merge/ if $_merge;
1206         push @cmd, "--strategy=$_strategy" if $_strategy;
1207         @cmd;
1208 }
1209
1210 sub post_fetch_checkout {
1211         return if $_no_checkout;
1212         my $gs = $Git::SVN::_head or return;
1213         return if verify_ref('refs/heads/master^0');
1214
1215         # look for "trunk" ref if it exists
1216         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1217         my $fetch = $remote->{fetch};
1218         if ($fetch) {
1219                 foreach my $p (keys %$fetch) {
1220                         basename($fetch->{$p}) eq 'trunk' or next;
1221                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1222                         last;
1223                 }
1224         }
1225
1226         my $valid_head = verify_ref('HEAD^0');
1227         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1228         return if ($valid_head || !verify_ref('HEAD^0'));
1229
1230         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1231         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1232         return if -f $index;
1233
1234         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1235         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1236         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1237         print STDERR "Checked out HEAD:\n  ",
1238                      $gs->full_url, " r", $gs->last_rev, "\n";
1239         $gs->mkemptydirs($gs->last_rev);
1240 }
1241
1242 sub complete_svn_url {
1243         my ($url, $path) = @_;
1244         $path =~ s#/+$##;
1245         if ($path !~ m#^[a-z\+]+://#) {
1246                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1247                         fatal("E: '$path' is not a complete URL ",
1248                               "and a separate URL is not specified");
1249                 }
1250                 return ($url, $path);
1251         }
1252         return ($path, '');
1253 }
1254
1255 sub complete_url_ls_init {
1256         my ($ra, $repo_path, $switch, $pfx) = @_;
1257         unless ($repo_path) {
1258                 print STDERR "W: $switch not specified\n";
1259                 return;
1260         }
1261         $repo_path =~ s#/+$##;
1262         if ($repo_path =~ m#^[a-z\+]+://#) {
1263                 $ra = Git::SVN::Ra->new($repo_path);
1264                 $repo_path = '';
1265         } else {
1266                 $repo_path =~ s#^/+##;
1267                 unless ($ra) {
1268                         fatal("E: '$repo_path' is not a complete URL ",
1269                               "and a separate URL is not specified");
1270                 }
1271         }
1272         my $url = $ra->{url};
1273         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1274         my $k = "svn-remote.$gs->{repo_id}.url";
1275         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1276         if ($orig_url && ($orig_url ne $gs->{url})) {
1277                 die "$k already set: $orig_url\n",
1278                     "wanted to set to: $gs->{url}\n";
1279         }
1280         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1281         my $remote_path = "$gs->{path}/$repo_path";
1282         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1283         $remote_path =~ s#/+#/#g;
1284         $remote_path =~ s#^/##g;
1285         $remote_path .= "/*" if $remote_path !~ /\*/;
1286         my ($n) = ($switch =~ /^--(\w+)/);
1287         if (length $pfx && $pfx !~ m#/$#) {
1288                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1289         }
1290         command_noisy('config',
1291                       '--add',
1292                       "svn-remote.$gs->{repo_id}.$n",
1293                       "$remote_path:refs/remotes/$pfx*" .
1294                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1295 }
1296
1297 sub verify_ref {
1298         my ($ref) = @_;
1299         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1300                                { STDERR => 0 }); };
1301 }
1302
1303 sub get_tree_from_treeish {
1304         my ($treeish) = @_;
1305         # $treeish can be a symbolic ref, too:
1306         my $type = command_oneline(qw/cat-file -t/, $treeish);
1307         my $expected;
1308         while ($type eq 'tag') {
1309                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1310         }
1311         if ($type eq 'commit') {
1312                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1313                                                     $treeish))[0];
1314                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1315                 die "Unable to get tree from $treeish\n" unless $expected;
1316         } elsif ($type eq 'tree') {
1317                 $expected = $treeish;
1318         } else {
1319                 die "$treeish is a $type, expected tree, tag or commit\n";
1320         }
1321         return $expected;
1322 }
1323
1324 sub get_commit_entry {
1325         my ($treeish) = shift;
1326         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1327         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1328         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1329         open my $log_fh, '>', $commit_editmsg or croak $!;
1330
1331         my $type = command_oneline(qw/cat-file -t/, $treeish);
1332         if ($type eq 'commit' || $type eq 'tag') {
1333                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1334                                                          $type, $treeish);
1335                 my $in_msg = 0;
1336                 my $author;
1337                 my $saw_from = 0;
1338                 my $msgbuf = "";
1339                 while (<$msg_fh>) {
1340                         if (!$in_msg) {
1341                                 $in_msg = 1 if (/^\s*$/);
1342                                 $author = $1 if (/^author (.*>)/);
1343                         } elsif (/^git-svn-id: /) {
1344                                 # skip this for now, we regenerate the
1345                                 # correct one on re-fetch anyways
1346                                 # TODO: set *:merge properties or like...
1347                         } else {
1348                                 if (/^From:/ || /^Signed-off-by:/) {
1349                                         $saw_from = 1;
1350                                 }
1351                                 $msgbuf .= $_;
1352                         }
1353                 }
1354                 $msgbuf =~ s/\s+$//s;
1355                 if ($Git::SVN::_add_author_from && defined($author)
1356                     && !$saw_from) {
1357                         $msgbuf .= "\n\nFrom: $author";
1358                 }
1359                 print $log_fh $msgbuf or croak $!;
1360                 command_close_pipe($msg_fh, $ctx);
1361         }
1362         close $log_fh or croak $!;
1363
1364         if ($_edit || ($type eq 'tree')) {
1365                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1366                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1367         }
1368         rename $commit_editmsg, $commit_msg or croak $!;
1369         {
1370                 require Encode;
1371                 # SVN requires messages to be UTF-8 when entering the repo
1372                 local $/;
1373                 open $log_fh, '<', $commit_msg or croak $!;
1374                 binmode $log_fh;
1375                 chomp($log_entry{log} = <$log_fh>);
1376
1377                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1378                 my $msg = $log_entry{log};
1379
1380                 eval { $msg = Encode::decode($enc, $msg, 1) };
1381                 if ($@) {
1382                         die "Could not decode as $enc:\n", $msg,
1383                             "\nPerhaps you need to set i18n.commitencoding\n";
1384                 }
1385
1386                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1387                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1388
1389                 $log_entry{log} = $msg;
1390
1391                 close $log_fh or croak $!;
1392         }
1393         unlink $commit_msg;
1394         \%log_entry;
1395 }
1396
1397 sub s_to_file {
1398         my ($str, $file, $mode) = @_;
1399         open my $fd,'>',$file or croak $!;
1400         print $fd $str,"\n" or croak $!;
1401         close $fd or croak $!;
1402         chmod ($mode &~ umask, $file) if (defined $mode);
1403 }
1404
1405 sub file_to_s {
1406         my $file = shift;
1407         open my $fd,'<',$file or croak "$!: file: $file\n";
1408         local $/;
1409         my $ret = <$fd>;
1410         close $fd or croak $!;
1411         $ret =~ s/\s*$//s;
1412         return $ret;
1413 }
1414
1415 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1416 sub load_authors {
1417         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1418         my $log = $cmd eq 'log';
1419         while (<$authors>) {
1420                 chomp;
1421                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1422                 my ($user, $name, $email) = ($1, $2, $3);
1423                 if ($log) {
1424                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1425                 } else {
1426                         $users{$user} = [$name, $email];
1427                 }
1428         }
1429         close $authors or croak $!;
1430 }
1431
1432 # convert GetOpt::Long specs for use by git-config
1433 sub read_git_config {
1434         my $opts = shift;
1435         my @config_only;
1436         foreach my $o (keys %$opts) {
1437                 # if we have mixedCase and a long option-only, then
1438                 # it's a config-only variable that we don't need for
1439                 # the command-line.
1440                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1441                 my $v = $opts->{$o};
1442                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1443                 $key =~ s/-//g;
1444                 my $arg = 'git config';
1445                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1446                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1447                 if (ref $v eq 'ARRAY') {
1448                         chomp(my @tmp = `$arg --get-all svn.$key`);
1449                         @$v = @tmp if @tmp;
1450                 } else {
1451                         chomp(my $tmp = `$arg --get svn.$key`);
1452                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1453                                 $$v = $tmp;
1454                         }
1455                 }
1456         }
1457         delete @$opts{@config_only} if @config_only;
1458 }
1459
1460 sub extract_metadata {
1461         my $id = shift or return (undef, undef, undef);
1462         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1463                                                         \s([a-f\d\-]+)$/ix);
1464         if (!defined $rev || !$uuid || !$url) {
1465                 # some of the original repositories I made had
1466                 # identifiers like this:
1467                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1468         }
1469         return ($url, $rev, $uuid);
1470 }
1471
1472 sub cmt_metadata {
1473         return extract_metadata((grep(/^git-svn-id: /,
1474                 command(qw/cat-file commit/, shift)))[-1]);
1475 }
1476
1477 sub cmt_sha2rev_batch {
1478         my %s2r;
1479         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1480         my $list = shift;
1481
1482         foreach my $sha (@{$list}) {
1483                 my $first = 1;
1484                 my $size = 0;
1485                 print $out $sha, "\n";
1486
1487                 while (my $line = <$in>) {
1488                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1489                                 last;
1490                         } elsif ($first &&
1491                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1492                                 $first = 0;
1493                                 $size = $1;
1494                                 next;
1495                         } elsif ($line =~ /^(git-svn-id: )/) {
1496                                 my (undef, $rev, undef) =
1497                                                       extract_metadata($line);
1498                                 $s2r{$sha} = $rev;
1499                         }
1500
1501                         $size -= length($line);
1502                         last if ($size == 0);
1503                 }
1504         }
1505
1506         command_close_bidi_pipe($pid, $in, $out, $ctx);
1507
1508         return \%s2r;
1509 }
1510
1511 sub working_head_info {
1512         my ($head, $refs) = @_;
1513         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1514         my ($fh, $ctx) = command_output_pipe(@args, $head);
1515         my $hash;
1516         my %max;
1517         while (<$fh>) {
1518                 if ( m{^commit ($::sha1)$} ) {
1519                         unshift @$refs, $hash if $hash and $refs;
1520                         $hash = $1;
1521                         next;
1522                 }
1523                 next unless s{^\s*(git-svn-id:)}{$1};
1524                 my ($url, $rev, $uuid) = extract_metadata($_);
1525                 if (defined $url && defined $rev) {
1526                         next if $max{$url} and $max{$url} < $rev;
1527                         if (my $gs = Git::SVN->find_by_url($url)) {
1528                                 my $c = $gs->rev_map_get($rev, $uuid);
1529                                 if ($c && $c eq $hash) {
1530                                         close $fh; # break the pipe
1531                                         return ($url, $rev, $uuid, $gs);
1532                                 } else {
1533                                         $max{$url} ||= $gs->rev_map_max;
1534                                 }
1535                         }
1536                 }
1537         }
1538         command_close_pipe($fh, $ctx);
1539         (undef, undef, undef, undef);
1540 }
1541
1542 sub read_commit_parents {
1543         my ($parents, $c) = @_;
1544         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1545         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1546         @{$parents->{$c}} = split(/ /, $p);
1547 }
1548
1549 sub linearize_history {
1550         my ($gs, $refs) = @_;
1551         my %parents;
1552         foreach my $c (@$refs) {
1553                 read_commit_parents(\%parents, $c);
1554         }
1555
1556         my @linear_refs;
1557         my %skip = ();
1558         my $last_svn_commit = $gs->last_commit;
1559         foreach my $c (reverse @$refs) {
1560                 next if $c eq $last_svn_commit;
1561                 last if $skip{$c};
1562
1563                 unshift @linear_refs, $c;
1564                 $skip{$c} = 1;
1565
1566                 # we only want the first parent to diff against for linear
1567                 # history, we save the rest to inject when we finalize the
1568                 # svn commit
1569                 my $fp_a = verify_ref("$c~1");
1570                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1571                 if (!$fp_a || !$fp_b) {
1572                         die "Commit $c\n",
1573                             "has no parent commit, and therefore ",
1574                             "nothing to diff against.\n",
1575                             "You should be working from a repository ",
1576                             "originally created by git-svn\n";
1577                 }
1578                 if ($fp_a ne $fp_b) {
1579                         die "$c~1 = $fp_a, however parsing commit $c ",
1580                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1581                 }
1582
1583                 foreach my $p (@{$parents{$c}}) {
1584                         $skip{$p} = 1;
1585                 }
1586         }
1587         (\@linear_refs, \%parents);
1588 }
1589
1590 sub find_file_type_and_diff_status {
1591         my ($path) = @_;
1592         return ('dir', '') if $path eq '';
1593
1594         my $diff_output =
1595             command_oneline(qw(diff --cached --name-status --), $path) || "";
1596         my $diff_status = (split(' ', $diff_output))[0] || "";
1597
1598         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1599
1600         return (undef, undef) if !$diff_status && !$ls_tree;
1601
1602         if ($diff_status eq "A") {
1603                 return ("link", $diff_status) if -l $path;
1604                 return ("dir", $diff_status) if -d $path;
1605                 return ("file", $diff_status);
1606         }
1607
1608         my $mode = (split(' ', $ls_tree))[0] || "";
1609
1610         return ("link", $diff_status) if $mode eq "120000";
1611         return ("dir", $diff_status) if $mode eq "040000";
1612         return ("file", $diff_status);
1613 }
1614
1615 sub md5sum {
1616         my $arg = shift;
1617         my $ref = ref $arg;
1618         my $md5 = Digest::MD5->new();
1619         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1620                 $md5->addfile($arg) or croak $!;
1621         } elsif ($ref eq 'SCALAR') {
1622                 $md5->add($$arg) or croak $!;
1623         } elsif (!$ref) {
1624                 $md5->add($arg) or croak $!;
1625         } else {
1626                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1627         }
1628         return $md5->hexdigest();
1629 }
1630
1631 sub gc_directory {
1632         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1633                 my $out_filename = $_ . ".gz";
1634                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1635                 binmode $in_fh;
1636                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1637                                 die "Unable to open $out_filename: $!\n";
1638
1639                 my $res;
1640                 while ($res = sysread($in_fh, my $str, 1024)) {
1641                         $gz->gzwrite($str) or
1642                                 die "Unable to write: ".$gz->gzerror()."!\n";
1643                 }
1644                 unlink $_ or die "unlink $File::Find::name: $!\n";
1645         } elsif (-f $_ && basename($_) eq "index") {
1646                 unlink $_ or die "unlink $_: $!\n";
1647         }
1648 }
1649
1650 package Git::SVN;
1651 use strict;
1652 use warnings;
1653 use Fcntl qw/:DEFAULT :seek/;
1654 use constant rev_map_fmt => 'NH40';
1655 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1656             $_repack $_repack_flags $_use_svm_props $_head
1657             $_use_svnsync_props $no_reuse_existing $_minimize_url
1658             $_use_log_author $_add_author_from $_localtime/;
1659 use Carp qw/croak/;
1660 use File::Path qw/mkpath/;
1661 use File::Copy qw/copy/;
1662 use IPC::Open3;
1663 use Memoize;  # core since 5.8.0, Jul 2002
1664 use Memoize::Storable;
1665
1666 my ($_gc_nr, $_gc_period);
1667
1668 # properties that we do not log:
1669 my %SKIP_PROP;
1670 BEGIN {
1671         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1672                                         svn:special svn:executable
1673                                         svn:entry:committed-rev
1674                                         svn:entry:last-author
1675                                         svn:entry:uuid
1676                                         svn:entry:committed-date/;
1677
1678         # some options are read globally, but can be overridden locally
1679         # per [svn-remote "..."] section.  Command-line options will *NOT*
1680         # override options set in an [svn-remote "..."] section
1681         no strict 'refs';
1682         for my $option (qw/follow_parent no_metadata use_svm_props
1683                            use_svnsync_props/) {
1684                 my $key = $option;
1685                 $key =~ tr/_//d;
1686                 my $prop = "-$option";
1687                 *$option = sub {
1688                         my ($self) = @_;
1689                         return $self->{$prop} if exists $self->{$prop};
1690                         my $k = "svn-remote.$self->{repo_id}.$key";
1691                         eval { command_oneline(qw/config --get/, $k) };
1692                         if ($@) {
1693                                 $self->{$prop} = ${"Git::SVN::_$option"};
1694                         } else {
1695                                 my $v = command_oneline(qw/config --bool/,$k);
1696                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1697                         }
1698                         return $self->{$prop};
1699                 }
1700         }
1701 }
1702
1703
1704 my (%LOCKFILES, %INDEX_FILES);
1705 END {
1706         unlink keys %LOCKFILES if %LOCKFILES;
1707         unlink keys %INDEX_FILES if %INDEX_FILES;
1708 }
1709
1710 sub resolve_local_globs {
1711         my ($url, $fetch, $glob_spec) = @_;
1712         return unless defined $glob_spec;
1713         my $ref = $glob_spec->{ref};
1714         my $path = $glob_spec->{path};
1715         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1716                 next unless m#^$ref->{regex}$#;
1717                 my $p = $1;
1718                 my $pathname = desanitize_refname($path->full_path($p));
1719                 my $refname = desanitize_refname($ref->full_path($p));
1720                 if (my $existing = $fetch->{$pathname}) {
1721                         if ($existing ne $refname) {
1722                                 die "Refspec conflict:\n",
1723                                     "existing: $existing\n",
1724                                     " globbed: $refname\n";
1725                         }
1726                         my $u = (::cmt_metadata("$refname"))[0];
1727                         $u =~ s!^\Q$url\E(/|$)!! or die
1728                           "$refname: '$url' not found in '$u'\n";
1729                         if ($pathname ne $u) {
1730                                 warn "W: Refspec glob conflict ",
1731                                      "(ref: $refname):\n",
1732                                      "expected path: $pathname\n",
1733                                      "    real path: $u\n",
1734                                      "Continuing ahead with $u\n";
1735                                 next;
1736                         }
1737                 } else {
1738                         $fetch->{$pathname} = $refname;
1739                 }
1740         }
1741 }
1742
1743 sub parse_revision_argument {
1744         my ($base, $head) = @_;
1745         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1746                 return ($base, $head);
1747         }
1748         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1749         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1750         return ($head, $head) if ($::_revision eq 'HEAD');
1751         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1752         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1753         die "revision argument: $::_revision not understood by git-svn\n";
1754 }
1755
1756 sub fetch_all {
1757         my ($repo_id, $remotes) = @_;
1758         if (ref $repo_id) {
1759                 my $gs = $repo_id;
1760                 $repo_id = undef;
1761                 $repo_id = $gs->{repo_id};
1762         }
1763         $remotes ||= read_all_remotes();
1764         my $remote = $remotes->{$repo_id} or
1765                      die "[svn-remote \"$repo_id\"] unknown\n";
1766         my $fetch = $remote->{fetch};
1767         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1768         my (@gs, @globs);
1769         my $ra = Git::SVN::Ra->new($url);
1770         my $uuid = $ra->get_uuid;
1771         my $head = $ra->get_latest_revnum;
1772
1773         # ignore errors, $head revision may not even exist anymore
1774         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1775         warn "W: $@\n" if $@;
1776
1777         my $base = defined $fetch ? $head : 0;
1778
1779         # read the max revs for wildcard expansion (branches/*, tags/*)
1780         foreach my $t (qw/branches tags/) {
1781                 defined $remote->{$t} or next;
1782                 push @globs, @{$remote->{$t}};
1783
1784                 my $max_rev = eval { tmp_config(qw/--int --get/,
1785                                          "svn-remote.$repo_id.${t}-maxRev") };
1786                 if (defined $max_rev && ($max_rev < $base)) {
1787                         $base = $max_rev;
1788                 } elsif (!defined $max_rev) {
1789                         $base = 0;
1790                 }
1791         }
1792
1793         if ($fetch) {
1794                 foreach my $p (sort keys %$fetch) {
1795                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1796                         my $lr = $gs->rev_map_max;
1797                         if (defined $lr) {
1798                                 $base = $lr if ($lr < $base);
1799                         }
1800                         push @gs, $gs;
1801                 }
1802         }
1803
1804         ($base, $head) = parse_revision_argument($base, $head);
1805         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1806 }
1807
1808 sub read_all_remotes {
1809         my $r = {};
1810         my $use_svm_props = eval { command_oneline(qw/config --bool
1811             svn.useSvmProps/) };
1812         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1813         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1814         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1815                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1816                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1817                         die("svn-remote.$remote: remote ref '$remote_ref' "
1818                             . "must start with 'refs/'\n")
1819                                 unless $remote_ref =~ m{^refs/};
1820                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1821                         $r->{$remote}->{svm} = {} if $use_svm_props;
1822                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1823                         $r->{$1}->{svm} = {};
1824                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1825                         $r->{$1}->{url} = $2;
1826                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1827                         my ($remote, $t, $local_ref, $remote_ref) =
1828                                                              ($1, $2, $3, $4);
1829                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1830                             . "must start with 'refs/'\n")
1831                                 unless $remote_ref =~ m{^refs/};
1832                         my $rs = {
1833                             t => $t,
1834                             remote => $remote,
1835                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1836                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1837                         if (length($rs->{ref}->{right}) != 0) {
1838                                 die "The '*' glob character must be the last ",
1839                                     "character of '$remote_ref'\n";
1840                         }
1841                         push @{ $r->{$remote}->{$t} }, $rs;
1842                 }
1843         }
1844
1845         map {
1846                 if (defined $r->{$_}->{svm}) {
1847                         my $svm;
1848                         eval {
1849                                 my $section = "svn-remote.$_";
1850                                 $svm = {
1851                                         source => tmp_config('--get',
1852                                             "$section.svm-source"),
1853                                         replace => tmp_config('--get',
1854                                             "$section.svm-replace"),
1855                                 }
1856                         };
1857                         $r->{$_}->{svm} = $svm;
1858                 }
1859         } keys %$r;
1860
1861         $r;
1862 }
1863
1864 sub init_vars {
1865         $_gc_nr = $_gc_period = 1000;
1866         if (defined $_repack || defined $_repack_flags) {
1867                warn "Repack options are obsolete; they have no effect.\n";
1868         }
1869 }
1870
1871 sub verify_remotes_sanity {
1872         return unless -d $ENV{GIT_DIR};
1873         my %seen;
1874         foreach (command(qw/config -l/)) {
1875                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1876                         if ($seen{$1}) {
1877                                 die "Remote ref refs/remote/$1 is tracked by",
1878                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1879                                     "Please resolve this ambiguity in ",
1880                                     "your git configuration file before ",
1881                                     "continuing\n";
1882                         }
1883                         $seen{$1} = $_;
1884                 }
1885         }
1886 }
1887
1888 sub find_existing_remote {
1889         my ($url, $remotes) = @_;
1890         return undef if $no_reuse_existing;
1891         my $existing;
1892         foreach my $repo_id (keys %$remotes) {
1893                 my $u = $remotes->{$repo_id}->{url} or next;
1894                 next if $u ne $url;
1895                 $existing = $repo_id;
1896                 last;
1897         }
1898         $existing;
1899 }
1900
1901 sub init_remote_config {
1902         my ($self, $url, $no_write) = @_;
1903         $url =~ s!/+$!!; # strip trailing slash
1904         my $r = read_all_remotes();
1905         my $existing = find_existing_remote($url, $r);
1906         if ($existing) {
1907                 unless ($no_write) {
1908                         print STDERR "Using existing ",
1909                                      "[svn-remote \"$existing\"]\n";
1910                 }
1911                 $self->{repo_id} = $existing;
1912         } elsif ($_minimize_url) {
1913                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1914                 $existing = find_existing_remote($min_url, $r);
1915                 if ($existing) {
1916                         unless ($no_write) {
1917                                 print STDERR "Using existing ",
1918                                              "[svn-remote \"$existing\"]\n";
1919                         }
1920                         $self->{repo_id} = $existing;
1921                 }
1922                 if ($min_url ne $url) {
1923                         unless ($no_write) {
1924                                 print STDERR "Using higher level of URL: ",
1925                                              "$url => $min_url\n";
1926                         }
1927                         my $old_path = $self->{path};
1928                         $self->{path} = $url;
1929                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1930                         if (length $old_path) {
1931                                 $self->{path} .= "/$old_path";
1932                         }
1933                         $url = $min_url;
1934                 }
1935         }
1936         my $orig_url;
1937         if (!$existing) {
1938                 # verify that we aren't overwriting anything:
1939                 $orig_url = eval {
1940                         command_oneline('config', '--get',
1941                                         "svn-remote.$self->{repo_id}.url")
1942                 };
1943                 if ($orig_url && ($orig_url ne $url)) {
1944                         die "svn-remote.$self->{repo_id}.url already set: ",
1945                             "$orig_url\nwanted to set to: $url\n";
1946                 }
1947         }
1948         my ($xrepo_id, $xpath) = find_ref($self->refname);
1949         if (!$no_write && defined $xpath) {
1950                 die "svn-remote.$xrepo_id.fetch already set to track ",
1951                     "$xpath:", $self->refname, "\n";
1952         }
1953         unless ($no_write) {
1954                 command_noisy('config',
1955                               "svn-remote.$self->{repo_id}.url", $url);
1956                 $self->{path} =~ s{^/}{};
1957                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1958                 command_noisy('config', '--add',
1959                               "svn-remote.$self->{repo_id}.fetch",
1960                               "$self->{path}:".$self->refname);
1961         }
1962         $self->{url} = $url;
1963 }
1964
1965 sub find_by_url { # repos_root and, path are optional
1966         my ($class, $full_url, $repos_root, $path) = @_;
1967
1968         return undef unless defined $full_url;
1969         remove_username($full_url);
1970         remove_username($repos_root) if defined $repos_root;
1971         my $remotes = read_all_remotes();
1972         if (defined $full_url && defined $repos_root && !defined $path) {
1973                 $path = $full_url;
1974                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1975         }
1976         foreach my $repo_id (keys %$remotes) {
1977                 my $u = $remotes->{$repo_id}->{url} or next;
1978                 remove_username($u);
1979                 next if defined $repos_root && $repos_root ne $u;
1980
1981                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1982                 foreach my $t (qw/branches tags/) {
1983                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1984                                 resolve_local_globs($u, $fetch, $globspec);
1985                         }
1986                 }
1987                 my $p = $path;
1988                 my $rwr = rewrite_root({repo_id => $repo_id});
1989                 my $svm = $remotes->{$repo_id}->{svm}
1990                         if defined $remotes->{$repo_id}->{svm};
1991                 unless (defined $p) {
1992                         $p = $full_url;
1993                         my $z = $u;
1994                         my $prefix = '';
1995                         if ($rwr) {
1996                                 $z = $rwr;
1997                                 remove_username($z);
1998                         } elsif (defined $svm) {
1999                                 $z = $svm->{source};
2000                                 $prefix = $svm->{replace};
2001                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2002                                 $prefix =~ s#/$##;
2003                         }
2004                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2005                 }
2006                 foreach my $f (keys %$fetch) {
2007                         next if $f ne $p;
2008                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2009                 }
2010         }
2011         undef;
2012 }
2013
2014 sub init {
2015         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2016         my $self = _new($class, $repo_id, $ref_id, $path);
2017         if (defined $url) {
2018                 $self->init_remote_config($url, $no_write);
2019         }
2020         $self;
2021 }
2022
2023 sub find_ref {
2024         my ($ref_id) = @_;
2025         foreach (command(qw/config -l/)) {
2026                 next unless m!^svn-remote\.(.+)\.fetch=
2027                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2028                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2029                 if ($ref eq $ref_id) {
2030                         $path = '' if ($path =~ m#^\./?#);
2031                         return ($repo_id, $path);
2032                 }
2033         }
2034         (undef, undef, undef);
2035 }
2036
2037 sub new {
2038         my ($class, $ref_id, $repo_id, $path) = @_;
2039         if (defined $ref_id && !defined $repo_id && !defined $path) {
2040                 ($repo_id, $path) = find_ref($ref_id);
2041                 if (!defined $repo_id) {
2042                         die "Could not find a \"svn-remote.*.fetch\" key ",
2043                             "in the repository configuration matching: ",
2044                             "$ref_id\n";
2045                 }
2046         }
2047         my $self = _new($class, $repo_id, $ref_id, $path);
2048         if (!defined $self->{path} || !length $self->{path}) {
2049                 my $fetch = command_oneline('config', '--get',
2050                                             "svn-remote.$repo_id.fetch",
2051                                             ":$ref_id\$") or
2052                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2053                          "\":$ref_id\$\" in config\n";
2054                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2055         }
2056         $self->{url} = command_oneline('config', '--get',
2057                                        "svn-remote.$repo_id.url") or
2058                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2059         $self->rebuild;
2060         $self;
2061 }
2062
2063 sub refname {
2064         my ($refname) = $_[0]->{ref_id} ;
2065
2066         # It cannot end with a slash /, we'll throw up on this because
2067         # SVN can't have directories with a slash in their name, either:
2068         if ($refname =~ m{/$}) {
2069                 die "ref: '$refname' ends with a trailing slash, this is ",
2070                     "not permitted by git nor Subversion\n";
2071         }
2072
2073         # It cannot have ASCII control character space, tilde ~, caret ^,
2074         # colon :, question-mark ?, asterisk *, space, or open bracket [
2075         # anywhere.
2076         #
2077         # Additionally, % must be escaped because it is used for escaping
2078         # and we want our escaped refname to be reversible
2079         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2080
2081         # no slash-separated component can begin with a dot .
2082         # /.* becomes /%2E*
2083         $refname =~ s{/\.}{/%2E}g;
2084
2085         # It cannot have two consecutive dots .. anywhere
2086         # .. becomes %2E%2E
2087         $refname =~ s{\.\.}{%2E%2E}g;
2088
2089         return $refname;
2090 }
2091
2092 sub desanitize_refname {
2093         my ($refname) = @_;
2094         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2095         return $refname;
2096 }
2097
2098 sub svm_uuid {
2099         my ($self) = @_;
2100         return $self->{svm}->{uuid} if $self->svm;
2101         $self->ra;
2102         unless ($self->{svm}) {
2103                 die "SVM UUID not cached, and reading remotely failed\n";
2104         }
2105         $self->{svm}->{uuid};
2106 }
2107
2108 sub svm {
2109         my ($self) = @_;
2110         return $self->{svm} if $self->{svm};
2111         my $svm;
2112         # see if we have it in our config, first:
2113         eval {
2114                 my $section = "svn-remote.$self->{repo_id}";
2115                 $svm = {
2116                   source => tmp_config('--get', "$section.svm-source"),
2117                   uuid => tmp_config('--get', "$section.svm-uuid"),
2118                   replace => tmp_config('--get', "$section.svm-replace"),
2119                 }
2120         };
2121         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2122                 $self->{svm} = $svm;
2123         }
2124         $self->{svm};
2125 }
2126
2127 sub _set_svm_vars {
2128         my ($self, $ra) = @_;
2129         return $ra if $self->svm;
2130
2131         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2132                     "(svm:source, svm:uuid) ",
2133                     "from the following URLs:\n" );
2134         sub read_svm_props {
2135                 my ($self, $ra, $path, $r) = @_;
2136                 my $props = ($ra->get_dir($path, $r))[2];
2137                 my $src = $props->{'svm:source'};
2138                 my $uuid = $props->{'svm:uuid'};
2139                 return undef if (!$src || !$uuid);
2140
2141                 chomp($src, $uuid);
2142
2143                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2144                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2145
2146                 # the '!' is used to mark the repos_root!/relative/path
2147                 $src =~ s{/?!/?}{/};
2148                 $src =~ s{/+$}{}; # no trailing slashes please
2149                 # username is of no interest
2150                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2151
2152                 my $replace = $ra->{url};
2153                 $replace .= "/$path" if length $path;
2154
2155                 my $section = "svn-remote.$self->{repo_id}";
2156                 tmp_config("$section.svm-source", $src);
2157                 tmp_config("$section.svm-replace", $replace);
2158                 tmp_config("$section.svm-uuid", $uuid);
2159                 $self->{svm} = {
2160                         source => $src,
2161                         uuid => $uuid,
2162                         replace => $replace
2163                 };
2164         }
2165
2166         my $r = $ra->get_latest_revnum;
2167         my $path = $self->{path};
2168         my %tried;
2169         while (length $path) {
2170                 unless ($tried{"$self->{url}/$path"}) {
2171                         return $ra if $self->read_svm_props($ra, $path, $r);
2172                         $tried{"$self->{url}/$path"} = 1;
2173                 }
2174                 $path =~ s#/?[^/]+$##;
2175         }
2176         die "Path: '$path' should be ''\n" if $path ne '';
2177         return $ra if $self->read_svm_props($ra, $path, $r);
2178         $tried{"$self->{url}/$path"} = 1;
2179
2180         if ($ra->{repos_root} eq $self->{url}) {
2181                 die @err, (map { "  $_\n" } keys %tried), "\n";
2182         }
2183
2184         # nope, make sure we're connected to the repository root:
2185         my $ok;
2186         my @tried_b;
2187         $path = $ra->{svn_path};
2188         $ra = Git::SVN::Ra->new($ra->{repos_root});
2189         while (length $path) {
2190                 unless ($tried{"$ra->{url}/$path"}) {
2191                         $ok = $self->read_svm_props($ra, $path, $r);
2192                         last if $ok;
2193                         $tried{"$ra->{url}/$path"} = 1;
2194                 }
2195                 $path =~ s#/?[^/]+$##;
2196         }
2197         die "Path: '$path' should be ''\n" if $path ne '';
2198         $ok ||= $self->read_svm_props($ra, $path, $r);
2199         $tried{"$ra->{url}/$path"} = 1;
2200         if (!$ok) {
2201                 die @err, (map { "  $_\n" } keys %tried), "\n";
2202         }
2203         Git::SVN::Ra->new($self->{url});
2204 }
2205
2206 sub svnsync {
2207         my ($self) = @_;
2208         return $self->{svnsync} if $self->{svnsync};
2209
2210         if ($self->no_metadata) {
2211                 die "Can't have both 'noMetadata' and ",
2212                     "'useSvnsyncProps' options set!\n";
2213         }
2214         if ($self->rewrite_root) {
2215                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2216                     "options set!\n";
2217         }
2218         if ($self->rewrite_uuid) {
2219                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2220                     "options set!\n";
2221         }
2222
2223         my $svnsync;
2224         # see if we have it in our config, first:
2225         eval {
2226                 my $section = "svn-remote.$self->{repo_id}";
2227
2228                 my $url = tmp_config('--get', "$section.svnsync-url");
2229                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2230                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2231
2232                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2233                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2234                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2235
2236                 $svnsync = { url => $url, uuid => $uuid }
2237         };
2238         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2239                 return $self->{svnsync} = $svnsync;
2240         }
2241
2242         my $err = "useSvnsyncProps set, but failed to read " .
2243                   "svnsync property: svn:sync-from-";
2244         my $rp = $self->ra->rev_proplist(0);
2245
2246         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2247         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2248                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2249
2250         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2251         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2252                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2253
2254         my $section = "svn-remote.$self->{repo_id}";
2255         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2256         tmp_config('--add', "$section.svnsync-url", $url);
2257         return $self->{svnsync} = { url => $url, uuid => $uuid };
2258 }
2259
2260 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2261 # remote lookup (useful for 'git svn log').
2262 sub ra_uuid {
2263         my ($self) = @_;
2264         unless ($self->{ra_uuid}) {
2265                 my $key = "svn-remote.$self->{repo_id}.uuid";
2266                 my $uuid = eval { tmp_config('--get', $key) };
2267                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2268                         $self->{ra_uuid} = $uuid;
2269                 } else {
2270                         die "ra_uuid called without URL\n" unless $self->{url};
2271                         $self->{ra_uuid} = $self->ra->get_uuid;
2272                         tmp_config('--add', $key, $self->{ra_uuid});
2273                 }
2274         }
2275         $self->{ra_uuid};
2276 }
2277
2278 sub _set_repos_root {
2279         my ($self, $repos_root) = @_;
2280         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2281         $repos_root ||= $self->ra->{repos_root};
2282         tmp_config($k, $repos_root);
2283         $repos_root;
2284 }
2285
2286 sub repos_root {
2287         my ($self) = @_;
2288         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2289         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2290 }
2291
2292 sub ra {
2293         my ($self) = shift;
2294         my $ra = Git::SVN::Ra->new($self->{url});
2295         $self->_set_repos_root($ra->{repos_root});
2296         if ($self->use_svm_props && !$self->{svm}) {
2297                 if ($self->no_metadata) {
2298                         die "Can't have both 'noMetadata' and ",
2299                             "'useSvmProps' options set!\n";
2300                 } elsif ($self->use_svnsync_props) {
2301                         die "Can't have both 'useSvnsyncProps' and ",
2302                             "'useSvmProps' options set!\n";
2303                 }
2304                 $ra = $self->_set_svm_vars($ra);
2305                 $self->{-want_revprops} = 1;
2306         }
2307         $ra;
2308 }
2309
2310 # prop_walk(PATH, REV, SUB)
2311 # -------------------------
2312 # Recursively traverse PATH at revision REV and invoke SUB for each
2313 # directory that contains a SVN property.  SUB will be invoked as
2314 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2315 # Git::SVN, `path' the path to the directory where the properties
2316 # `props' were found.  The `path' will be relative to point of checkout,
2317 # that is, if url://repo/trunk is the current Git branch, and that
2318 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2319 # as `path' (note the trailing `/').
2320 sub prop_walk {
2321         my ($self, $path, $rev, $sub) = @_;
2322
2323         $path =~ s#^/##;
2324         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2325         $path =~ s#^/*#/#g;
2326         my $p = $path;
2327         # Strip the irrelevant part of the path.
2328         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2329         # Ensure the path is terminated by a `/'.
2330         $p =~ s#/*$#/#;
2331
2332         # The properties contain all the internal SVN stuff nobody
2333         # (usually) cares about.
2334         my $interesting_props = 0;
2335         foreach (keys %{$props}) {
2336                 # If it doesn't start with `svn:', it must be a
2337                 # user-defined property.
2338                 ++$interesting_props and next if $_ !~ /^svn:/;
2339                 # FIXME: Fragile, if SVN adds new public properties,
2340                 # this needs to be updated.
2341                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2342                                                  |eol-style|mime-type
2343                                                  |externals|needs-lock)$/x;
2344         }
2345         &$sub($self, $p, $props) if $interesting_props;
2346
2347         foreach (sort keys %$dirent) {
2348                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2349                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2350         }
2351 }
2352
2353 sub last_rev { ($_[0]->last_rev_commit)[0] }
2354 sub last_commit { ($_[0]->last_rev_commit)[1] }
2355
2356 # returns the newest SVN revision number and newest commit SHA1
2357 sub last_rev_commit {
2358         my ($self) = @_;
2359         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2360                 return ($self->{last_rev}, $self->{last_commit});
2361         }
2362         my $c = ::verify_ref($self->refname.'^0');
2363         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2364                 my $rev = (::cmt_metadata($c))[1];
2365                 if (defined $rev) {
2366                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2367                         return ($rev, $c);
2368                 }
2369         }
2370         my $map_path = $self->map_path;
2371         unless (-e $map_path) {
2372                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2373                 return (undef, undef);
2374         }
2375         my ($rev, $commit) = $self->rev_map_max(1);
2376         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2377         return ($rev, $commit);
2378 }
2379
2380 sub get_fetch_range {
2381         my ($self, $min, $max) = @_;
2382         $max ||= $self->ra->get_latest_revnum;
2383         $min ||= $self->rev_map_max;
2384         (++$min, $max);
2385 }
2386
2387 sub tmp_config {
2388         my (@args) = @_;
2389         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2390         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2391         if (! -f $config && -f $old_def_config) {
2392                 rename $old_def_config, $config or
2393                        die "Failed rename $old_def_config => $config: $!\n";
2394         }
2395         my $old_config = $ENV{GIT_CONFIG};
2396         $ENV{GIT_CONFIG} = $config;
2397         $@ = undef;
2398         my @ret = eval {
2399                 unless (-f $config) {
2400                         mkfile($config);
2401                         open my $fh, '>', $config or
2402                             die "Can't open $config: $!\n";
2403                         print $fh "; This file is used internally by ",
2404                                   "git-svn\n" or die
2405                                   "Couldn't write to $config: $!\n";
2406                         print $fh "; You should not have to edit it\n" or
2407                               die "Couldn't write to $config: $!\n";
2408                         close $fh or die "Couldn't close $config: $!\n";
2409                 }
2410                 command('config', @args);
2411         };
2412         my $err = $@;
2413         if (defined $old_config) {
2414                 $ENV{GIT_CONFIG} = $old_config;
2415         } else {
2416                 delete $ENV{GIT_CONFIG};
2417         }
2418         die $err if $err;
2419         wantarray ? @ret : $ret[0];
2420 }
2421
2422 sub tmp_index_do {
2423         my ($self, $sub) = @_;
2424         my $old_index = $ENV{GIT_INDEX_FILE};
2425         $ENV{GIT_INDEX_FILE} = $self->{index};
2426         $@ = undef;
2427         my @ret = eval {
2428                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2429                 mkpath([$dir]) unless -d $dir;
2430                 &$sub;
2431         };
2432         my $err = $@;
2433         if (defined $old_index) {
2434                 $ENV{GIT_INDEX_FILE} = $old_index;
2435         } else {
2436                 delete $ENV{GIT_INDEX_FILE};
2437         }
2438         die $err if $err;
2439         wantarray ? @ret : $ret[0];
2440 }
2441
2442 sub assert_index_clean {
2443         my ($self, $treeish) = @_;
2444
2445         $self->tmp_index_do(sub {
2446                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2447                 my $x = command_oneline('write-tree');
2448                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2449                            /^tree ($::sha1)/mo);
2450                 return if $y eq $x;
2451
2452                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2453                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2454                 command_noisy('read-tree', $treeish);
2455                 $x = command_oneline('write-tree');
2456                 if ($y ne $x) {
2457                         ::fatal "trees ($treeish) $y != $x\n",
2458                                 "Something is seriously wrong...";
2459                 }
2460         });
2461 }
2462
2463 sub get_commit_parents {
2464         my ($self, $log_entry) = @_;
2465         my (%seen, @ret, @tmp);
2466         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2467         if (my $ip = $self->{inject_parents}) {
2468                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2469                         push @tmp, $commit;
2470                 }
2471         }
2472         if (my $cur = ::verify_ref($self->refname.'^0')) {
2473                 push @tmp, $cur;
2474         }
2475         if (my $ipd = $self->{inject_parents_dcommit}) {
2476                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2477                         push @tmp, @$commit;
2478                 }
2479         }
2480         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2481         while (my $p = shift @tmp) {
2482                 next if $seen{$p};
2483                 $seen{$p} = 1;
2484                 push @ret, $p;
2485         }
2486         @ret;
2487 }
2488
2489 sub rewrite_root {
2490         my ($self) = @_;
2491         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2492         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2493         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2494         if ($rwr) {
2495                 $rwr =~ s#/+$##;
2496                 if ($rwr !~ m#^[a-z\+]+://#) {
2497                         die "$rwr is not a valid URL (key: $k)\n";
2498                 }
2499         }
2500         $self->{-rewrite_root} = $rwr;
2501 }
2502
2503 sub rewrite_uuid {
2504         my ($self) = @_;
2505         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2506         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2507         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2508         if ($rwid) {
2509                 $rwid =~ s#/+$##;
2510                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2511                         die "$rwid is not a valid UUID (key: $k)\n";
2512                 }
2513         }
2514         $self->{-rewrite_uuid} = $rwid;
2515 }
2516
2517 sub metadata_url {
2518         my ($self) = @_;
2519         ($self->rewrite_root || $self->{url}) .
2520            (length $self->{path} ? '/' . $self->{path} : '');
2521 }
2522
2523 sub full_url {
2524         my ($self) = @_;
2525         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2526 }
2527
2528
2529 sub set_commit_header_env {
2530         my ($log_entry) = @_;
2531         my %env;
2532         foreach my $ned (qw/NAME EMAIL DATE/) {
2533                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2534                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2535                 }
2536         }
2537
2538         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2539         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2540         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2541
2542         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2543                                                 ? $log_entry->{commit_name}
2544                                                 : $log_entry->{name};
2545         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2546                                                 ? $log_entry->{commit_email}
2547                                                 : $log_entry->{email};
2548         \%env;
2549 }
2550
2551 sub restore_commit_header_env {
2552         my ($env) = @_;
2553         foreach my $ned (qw/NAME EMAIL DATE/) {
2554                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2555                         my $k = "GIT_${ac}_${ned}";
2556                         if (defined $env->{$k}) {
2557                                 $ENV{$k} = $env->{$k};
2558                         } else {
2559                                 delete $ENV{$k};
2560                         }
2561                 }
2562         }
2563 }
2564
2565 sub gc {
2566         command_noisy('gc', '--auto');
2567 };
2568
2569 sub do_git_commit {
2570         my ($self, $log_entry) = @_;
2571         my $lr = $self->last_rev;
2572         if (defined $lr && $lr >= $log_entry->{revision}) {
2573                 die "Last fetched revision of ", $self->refname,
2574                     " was r$lr, but we are about to fetch: ",
2575                     "r$log_entry->{revision}!\n";
2576         }
2577         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2578                 croak "$log_entry->{revision} = $c already exists! ",
2579                       "Why are we refetching it?\n";
2580         }
2581         my $old_env = set_commit_header_env($log_entry);
2582         my $tree = $log_entry->{tree};
2583         if (!defined $tree) {
2584                 $tree = $self->tmp_index_do(sub {
2585                                             command_oneline('write-tree') });
2586         }
2587         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2588
2589         my @exec = ('git', 'commit-tree', $tree);
2590         foreach ($self->get_commit_parents($log_entry)) {
2591                 push @exec, '-p', $_;
2592         }
2593         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2594                                                                    or croak $!;
2595         binmode $msg_fh;
2596
2597         # we always get UTF-8 from SVN, but we may want our commits in
2598         # a different encoding.
2599         if (my $enc = Git::config('i18n.commitencoding')) {
2600                 require Encode;
2601                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2602         }
2603         print $msg_fh $log_entry->{log} or croak $!;
2604         restore_commit_header_env($old_env);
2605         unless ($self->no_metadata) {
2606                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2607                               or croak $!;
2608         }
2609         $msg_fh->flush == 0 or croak $!;
2610         close $msg_fh or croak $!;
2611         chomp(my $commit = do { local $/; <$out_fh> });
2612         close $out_fh or croak $!;
2613         waitpid $pid, 0;
2614         croak $? if $?;
2615         if ($commit !~ /^$::sha1$/o) {
2616                 die "Failed to commit, invalid sha1: $commit\n";
2617         }
2618
2619         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2620
2621         $self->{last_rev} = $log_entry->{revision};
2622         $self->{last_commit} = $commit;
2623         print "r$log_entry->{revision}" unless $::_q > 1;
2624         if (defined $log_entry->{svm_revision}) {
2625                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2626                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2627                                    0, $self->svm_uuid);
2628         }
2629         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2630         if (--$_gc_nr == 0) {
2631                 $_gc_nr = $_gc_period;
2632                 gc();
2633         }
2634         return $commit;
2635 }
2636
2637 sub match_paths {
2638         my ($self, $paths, $r) = @_;
2639         return 1 if $self->{path} eq '';
2640         if (my $path = $paths->{"/$self->{path}"}) {
2641                 return ($path->{action} eq 'D') ? 0 : 1;
2642         }
2643         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2644         if (grep /$self->{path_regex}/, keys %$paths) {
2645                 return 1;
2646         }
2647         my $c = '';
2648         foreach (split m#/#, $self->{path}) {
2649                 $c .= "/$_";
2650                 next unless ($paths->{$c} &&
2651                              ($paths->{$c}->{action} =~ /^[AR]$/));
2652                 if ($self->ra->check_path($self->{path}, $r) ==
2653                     $SVN::Node::dir) {
2654                         return 1;
2655                 }
2656         }
2657         return 0;
2658 }
2659
2660 sub find_parent_branch {
2661         my ($self, $paths, $rev) = @_;
2662         return undef unless $self->follow_parent;
2663         unless (defined $paths) {
2664                 my $err_handler = $SVN::Error::handler;
2665                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2666                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2667                                    sub { $paths = $_[0] });
2668                 $SVN::Error::handler = $err_handler;
2669         }
2670         return undef unless defined $paths;
2671
2672         # look for a parent from another branch:
2673         my @b_path_components = split m#/#, $self->{path};
2674         my @a_path_components;
2675         my $i;
2676         while (@b_path_components) {
2677                 $i = $paths->{'/'.join('/', @b_path_components)};
2678                 last if $i && defined $i->{copyfrom_path};
2679                 unshift(@a_path_components, pop(@b_path_components));
2680         }
2681         return undef unless defined $i && defined $i->{copyfrom_path};
2682         my $branch_from = $i->{copyfrom_path};
2683         if (@a_path_components) {
2684                 print STDERR "branch_from: $branch_from => ";
2685                 $branch_from .= '/'.join('/', @a_path_components);
2686                 print STDERR $branch_from, "\n";
2687         }
2688         my $r = $i->{copyfrom_rev};
2689         my $repos_root = $self->ra->{repos_root};
2690         my $url = $self->ra->{url};
2691         my $new_url = $url . $branch_from;
2692         print STDERR  "Found possible branch point: ",
2693                       "$new_url => ", $self->full_url, ", $r\n"
2694                       unless $::_q > 1;
2695         $branch_from =~ s#^/##;
2696         my $gs = $self->other_gs($new_url, $url,
2697                                  $branch_from, $r, $self->{ref_id});
2698         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2699         {
2700                 my ($base, $head);
2701                 if (!defined $r0 || !defined $parent) {
2702                         ($base, $head) = parse_revision_argument(0, $r);
2703                 } else {
2704                         if ($r0 < $r) {
2705                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2706                                         0, 1, sub { $base = $_[1] - 1 });
2707                         }
2708                 }
2709                 if (defined $base && $base <= $r) {
2710                         $gs->fetch($base, $r);
2711                 }
2712                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2713         }
2714         if (defined $r0 && defined $parent) {
2715                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2716                              unless $::_q > 1;
2717                 my $ed;
2718                 if ($self->ra->can_do_switch) {
2719                         $self->assert_index_clean($parent);
2720                         print STDERR "Following parent with do_switch\n"
2721                                      unless $::_q > 1;
2722                         # do_switch works with svn/trunk >= r22312, but that
2723                         # is not included with SVN 1.4.3 (the latest version
2724                         # at the moment), so we can't rely on it
2725                         $self->{last_rev} = $r0;
2726                         $self->{last_commit} = $parent;
2727                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2728                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2729                                               $self->full_url, $ed)
2730                           or die "SVN connection failed somewhere...\n";
2731                 } elsif ($self->ra->trees_match($new_url, $r0,
2732                                                 $self->full_url, $rev)) {
2733                         print STDERR "Trees match:\n",
2734                                      "  $new_url\@$r0\n",
2735                                      "  ${\$self->full_url}\@$rev\n",
2736                                      "Following parent with no changes\n"
2737                                      unless $::_q > 1;
2738                         $self->tmp_index_do(sub {
2739                             command_noisy('read-tree', $parent);
2740                         });
2741                         $self->{last_commit} = $parent;
2742                 } else {
2743                         print STDERR "Following parent with do_update\n"
2744                                      unless $::_q > 1;
2745                         $ed = SVN::Git::Fetcher->new($self);
2746                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2747                           or die "SVN connection failed somewhere...\n";
2748                 }
2749                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2750                 return $self->make_log_entry($rev, [$parent], $ed);
2751         }
2752         return undef;
2753 }
2754
2755 sub do_fetch {
2756         my ($self, $paths, $rev) = @_;
2757         my $ed;
2758         my ($last_rev, @parents);
2759         if (my $lc = $self->last_commit) {
2760                 # we can have a branch that was deleted, then re-added
2761                 # under the same name but copied from another path, in
2762                 # which case we'll have multiple parents (we don't
2763                 # want to break the original ref, nor lose copypath info):
2764                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2765                         push @{$log_entry->{parents}}, $lc;
2766                         return $log_entry;
2767                 }
2768                 $ed = SVN::Git::Fetcher->new($self);
2769                 $last_rev = $self->{last_rev};
2770                 $ed->{c} = $lc;
2771                 @parents = ($lc);
2772         } else {
2773                 $last_rev = $rev;
2774                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2775                         return $log_entry;
2776                 }
2777                 $ed = SVN::Git::Fetcher->new($self);
2778         }
2779         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2780                 die "SVN connection failed somewhere...\n";
2781         }
2782         $self->make_log_entry($rev, \@parents, $ed);
2783 }
2784
2785 sub mkemptydirs {
2786         my ($self, $r) = @_;
2787
2788         sub scan {
2789                 my ($r, $empty_dirs, $line) = @_;
2790                 if (defined $r && $line =~ /^r(\d+)$/) {
2791                         return 0 if $1 > $r;
2792                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2793                         $empty_dirs->{$1} = 1;
2794                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2795                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2796                         delete @$empty_dirs{@d};
2797                 }
2798                 1; # continue
2799         };
2800
2801         my %empty_dirs = ();
2802         my $gz_file = "$self->{dir}/unhandled.log.gz";
2803         if (-f $gz_file) {
2804                 if (!$can_compress) {
2805                         warn "Compress::Zlib could not be found; ",
2806                              "empty directories in $gz_file will not be read\n";
2807                 } else {
2808                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2809                                 die "Unable to open $gz_file: $!\n";
2810                         my $line;
2811                         while ($gz->gzreadline($line) > 0) {
2812                                 scan($r, \%empty_dirs, $line) or last;
2813                         }
2814                         $gz->gzclose;
2815                 }
2816         }
2817
2818         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2819                 binmode $fh or croak "binmode: $!";
2820                 while (<$fh>) {
2821                         scan($r, \%empty_dirs, $_) or last;
2822                 }
2823                 close $fh;
2824         }
2825
2826         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2827         foreach my $d (sort keys %empty_dirs) {
2828                 $d = uri_decode($d);
2829                 $d =~ s/$strip//;
2830                 next if -d $d;
2831                 if (-e _) {
2832                         warn "$d exists but is not a directory\n";
2833                 } else {
2834                         print "creating empty directory: $d\n";
2835                         mkpath([$d]);
2836                 }
2837         }
2838 }
2839
2840 sub get_untracked {
2841         my ($self, $ed) = @_;
2842         my @out;
2843         my $h = $ed->{empty};
2844         foreach (sort keys %$h) {
2845                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2846                 push @out, "  $act: " . uri_encode($_);
2847                 warn "W: $act: $_\n";
2848         }
2849         foreach my $t (qw/dir_prop file_prop/) {
2850                 $h = $ed->{$t} or next;
2851                 foreach my $path (sort keys %$h) {
2852                         my $ppath = $path eq '' ? '.' : $path;
2853                         foreach my $prop (sort keys %{$h->{$path}}) {
2854                                 next if $SKIP_PROP{$prop};
2855                                 my $v = $h->{$path}->{$prop};
2856                                 my $t_ppath_prop = "$t: " .
2857                                                     uri_encode($ppath) . ' ' .
2858                                                     uri_encode($prop);
2859                                 if (defined $v) {
2860                                         push @out, "  +$t_ppath_prop " .
2861                                                    uri_encode($v);
2862                                 } else {
2863                                         push @out, "  -$t_ppath_prop";
2864                                 }
2865                         }
2866                 }
2867         }
2868         foreach my $t (qw/absent_file absent_directory/) {
2869                 $h = $ed->{$t} or next;
2870                 foreach my $parent (sort keys %$h) {
2871                         foreach my $path (sort @{$h->{$parent}}) {
2872                                 push @out, "  $t: " .
2873                                            uri_encode("$parent/$path");
2874                                 warn "W: $t: $parent/$path ",
2875                                      "Insufficient permissions?\n";
2876                         }
2877                 }
2878         }
2879         \@out;
2880 }
2881
2882 # parse_svn_date(DATE)
2883 # --------------------
2884 # Given a date (in UTC) from Subversion, return a string in the format
2885 # "<TZ Offset> <local date/time>" that Git will use.
2886 #
2887 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2888 # is true we'll convert it to the local timezone instead.
2889 sub parse_svn_date {
2890         my $date = shift || return '+0000 1970-01-01 00:00:00';
2891         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2892                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2893                                          croak "Unable to parse date: $date\n";
2894         my $parsed_date;    # Set next.
2895
2896         if ($Git::SVN::_localtime) {
2897                 # Translate the Subversion datetime to an epoch time.
2898                 # Begin by switching ourselves to $date's timezone, UTC.
2899                 my $old_env_TZ = $ENV{TZ};
2900                 $ENV{TZ} = 'UTC';
2901
2902                 my $epoch_in_UTC =
2903                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2904
2905                 # Determine our local timezone (including DST) at the
2906                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2907                 # value of TZ, if any, at the time we were run.
2908                 if (defined $Git::SVN::Log::TZ) {
2909                         $ENV{TZ} = $Git::SVN::Log::TZ;
2910                 } else {
2911                         delete $ENV{TZ};
2912                 }
2913
2914                 my $our_TZ =
2915                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2916
2917                 # This converts $epoch_in_UTC into our local timezone.
2918                 my ($sec, $min, $hour, $mday, $mon, $year,
2919                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2920
2921                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2922                                        $our_TZ, $year + 1900, $mon + 1,
2923                                        $mday, $hour, $min, $sec);
2924
2925                 # Reset us to the timezone in effect when we entered
2926                 # this routine.
2927                 if (defined $old_env_TZ) {
2928                         $ENV{TZ} = $old_env_TZ;
2929                 } else {
2930                         delete $ENV{TZ};
2931                 }
2932         } else {
2933                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2934         }
2935
2936         return $parsed_date;
2937 }
2938
2939 sub other_gs {
2940         my ($self, $new_url, $url,
2941             $branch_from, $r, $old_ref_id) = @_;
2942         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2943         unless ($gs) {
2944                 my $ref_id = $old_ref_id;
2945                 $ref_id =~ s/\@\d+$//;
2946                 $ref_id .= "\@$r";
2947                 # just grow a tail if we're not unique enough :x
2948                 $ref_id .= '-' while find_ref($ref_id);
2949                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2950                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2951                 if ($u =~ s#^\Q$url\E(/|$)##) {
2952                         $p = $u;
2953                         $u = $url;
2954                         $repo_id = $self->{repo_id};
2955                 }
2956                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2957         }
2958         $gs
2959 }
2960
2961 sub call_authors_prog {
2962         my ($orig_author) = @_;
2963         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2964         my $author = `$::_authors_prog $orig_author`;
2965         if ($? != 0) {
2966                 die "$::_authors_prog failed with exit code $?\n"
2967         }
2968         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2969                 my ($name, $email) = ($1, $2);
2970                 $email = undef if length $2 == 0;
2971                 return [$name, $email];
2972         } else {
2973                 die "Author: $orig_author: $::_authors_prog returned "
2974                         . "invalid author format: $author\n";
2975         }
2976 }
2977
2978 sub check_author {
2979         my ($author) = @_;
2980         if (!defined $author || length $author == 0) {
2981                 $author = '(no author)';
2982         }
2983         if (!defined $::users{$author}) {
2984                 if (defined $::_authors_prog) {
2985                         $::users{$author} = call_authors_prog($author);
2986                 } elsif (defined $::_authors) {
2987                         die "Author: $author not defined in $::_authors file\n";
2988                 }
2989         }
2990         $author;
2991 }
2992
2993 sub find_extra_svk_parents {
2994         my ($self, $ed, $tickets, $parents) = @_;
2995         # aha!  svk:merge property changed...
2996         my @tickets = split "\n", $tickets;
2997         my @known_parents;
2998         for my $ticket ( @tickets ) {
2999                 my ($uuid, $path, $rev) = split /:/, $ticket;
3000                 if ( $uuid eq $self->ra_uuid ) {
3001                         my $url = $self->{url};
3002                         my $repos_root = $url;
3003                         my $branch_from = $path;
3004                         $branch_from =~ s{^/}{};
3005                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3006                                                  $url,
3007                                                  $branch_from,
3008                                                  $rev,
3009                                                  $self->{ref_id});
3010                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3011                                 # wahey!  we found it, but it might be
3012                                 # an old one (!)
3013                                 push @known_parents, [ $rev, $commit ];
3014                         }
3015                 }
3016         }
3017         # Ordering matters; highest-numbered commit merge tickets
3018         # first, as they may account for later merge ticket additions
3019         # or changes.
3020         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3021         for my $parent ( @known_parents ) {
3022                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3023                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3024                 my $new;
3025                 while ( <$msg_fh> ) {
3026                         $new=1;last;
3027                 }
3028                 command_close_pipe($msg_fh, $ctx);
3029                 if ( $new ) {
3030                         print STDERR
3031                             "Found merge parent (svk:merge ticket): $parent\n";
3032                         push @$parents, $parent;
3033                 }
3034         }
3035 }
3036
3037 sub lookup_svn_merge {
3038         my $uuid = shift;
3039         my $url = shift;
3040         my $merge = shift;
3041
3042         my ($source, $revs) = split ":", $merge;
3043         my $path = $source;
3044         $path =~ s{^/}{};
3045         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3046         if ( !$gs ) {
3047                 warn "Couldn't find revmap for $url$source\n";
3048                 return;
3049         }
3050         my @ranges = split ",", $revs;
3051         my ($tip, $tip_commit);
3052         my @merged_commit_ranges;
3053         # find the tip
3054         for my $range ( @ranges ) {
3055                 my ($bottom, $top) = split "-", $range;
3056                 $top ||= $bottom;
3057                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3058                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3059
3060                 unless ($top_commit and $bottom_commit) {
3061                         warn "W:unknown path/rev in svn:mergeinfo "
3062                                 ."dirprop: $source:$range\n";
3063                         next;
3064                 }
3065
3066                 push @merged_commit_ranges,
3067                         "$bottom_commit^..$top_commit";
3068
3069                 if ( !defined $tip or $top > $tip ) {
3070                         $tip = $top;
3071                         $tip_commit = $top_commit;
3072                 }
3073         }
3074         return ($tip_commit, @merged_commit_ranges);
3075 }
3076
3077 sub _rev_list {
3078         my ($msg_fh, $ctx) = command_output_pipe(
3079                 "rev-list", @_,
3080                );
3081         my @rv;
3082         while ( <$msg_fh> ) {
3083                 chomp;
3084                 push @rv, $_;
3085         }
3086         command_close_pipe($msg_fh, $ctx);
3087         @rv;
3088 }
3089
3090 sub check_cherry_pick {
3091         my $base = shift;
3092         my $tip = shift;
3093         my @ranges = @_;
3094         my %commits = map { $_ => 1 }
3095                 _rev_list("--no-merges", $tip, "--not", $base);
3096         for my $range ( @ranges ) {
3097                 delete @commits{_rev_list($range)};
3098         }
3099         for my $commit (keys %commits) {
3100                 if (has_no_changes($commit)) {
3101                         delete $commits{$commit};
3102                 }
3103         }
3104         return (keys %commits);
3105 }
3106
3107 sub has_no_changes {
3108         my $commit = shift;
3109
3110         my @revs = split / /, command_oneline(
3111                 qw(rev-list --parents -1 -m), $commit);
3112
3113         # Commits with no parents, e.g. the start of a partial branch,
3114         # have changes by definition.
3115         return 1 if (@revs < 2);
3116
3117         # Commits with multiple parents, e.g a merge, have no changes
3118         # by definition.
3119         return 0 if (@revs > 2);
3120
3121         return (command_oneline("rev-parse", "$commit^{tree}") eq
3122                 command_oneline("rev-parse", "$commit~1^{tree}"));
3123 }
3124
3125 # The GIT_DIR environment variable is not always set until after the command
3126 # line arguments are processed, so we can't memoize in a BEGIN block.
3127 {
3128         my $memoized = 0;
3129
3130         sub memoize_svn_mergeinfo_functions {
3131                 return if $memoized;
3132                 $memoized = 1;
3133
3134                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3135                 mkpath([$cache_path]) unless -d $cache_path;
3136
3137                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3138                     "$cache_path/lookup_svn_merge.db", 'nstore';
3139                 memoize 'lookup_svn_merge',
3140                         SCALAR_CACHE => 'FAULT',
3141                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3142                 ;
3143
3144                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3145                     "$cache_path/check_cherry_pick.db", 'nstore';
3146                 memoize 'check_cherry_pick',
3147                         SCALAR_CACHE => 'FAULT',
3148                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3149                 ;
3150
3151                 tie my %has_no_changes_cache => 'Memoize::Storable',
3152                     "$cache_path/has_no_changes.db", 'nstore';
3153                 memoize 'has_no_changes',
3154                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3155                         LIST_CACHE => 'FAULT',
3156                 ;
3157         }
3158 }
3159
3160 sub parents_exclude {
3161         my $parents = shift;
3162         my @commits = @_;
3163         return unless @commits;
3164
3165         my @excluded;
3166         my $excluded;
3167         do {
3168                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3169                 $excluded = command_oneline(@cmd);
3170                 if ( $excluded ) {
3171                         my @new;
3172                         my $found;
3173                         for my $commit ( @commits ) {
3174                                 if ( $commit eq $excluded ) {
3175                                         push @excluded, $commit;
3176                                         $found++;
3177                                         last;
3178                                 }
3179                                 else {
3180                                         push @new, $commit;
3181                                 }
3182                         }
3183                         die "saw commit '$excluded' in rev-list output, "
3184                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3185                                         unless $found;
3186                         @commits = @new;
3187                 }
3188         }
3189                 while ($excluded and @commits);
3190
3191         return @excluded;
3192 }
3193
3194
3195 # note: this function should only be called if the various dirprops
3196 # have actually changed
3197 sub find_extra_svn_parents {
3198         my ($self, $ed, $mergeinfo, $parents) = @_;
3199         # aha!  svk:merge property changed...
3200
3201         memoize_svn_mergeinfo_functions();
3202
3203         # We first search for merged tips which are not in our
3204         # history.  Then, we figure out which git revisions are in
3205         # that tip, but not this revision.  If all of those revisions
3206         # are now marked as merge, we can add the tip as a parent.
3207         my @merges = split "\n", $mergeinfo;
3208         my @merge_tips;
3209         my $url = $self->{url};
3210         my $uuid = $self->ra_uuid;
3211         my %ranges;
3212         for my $merge ( @merges ) {
3213                 my ($tip_commit, @ranges) =
3214                         lookup_svn_merge( $uuid, $url, $merge );
3215                 unless (!$tip_commit or
3216                                 grep { $_ eq $tip_commit } @$parents ) {
3217                         push @merge_tips, $tip_commit;
3218                         $ranges{$tip_commit} = \@ranges;
3219                 } else {
3220                         push @merge_tips, undef;
3221                 }
3222         }
3223
3224         my %excluded = map { $_ => 1 }
3225                 parents_exclude($parents, grep { defined } @merge_tips);
3226
3227         # check merge tips for new parents
3228         my @new_parents;
3229         for my $merge_tip ( @merge_tips ) {
3230                 my $spec = shift @merges;
3231                 next unless $merge_tip and $excluded{$merge_tip};
3232
3233                 my $ranges = $ranges{$merge_tip};
3234
3235                 # check out 'new' tips
3236                 my $merge_base;
3237                 eval {
3238                         $merge_base = command_oneline(
3239                                 "merge-base",
3240                                 @$parents, $merge_tip,
3241                         );
3242                 };
3243                 if ($@) {
3244                         die "An error occurred during merge-base"
3245                                 unless $@->isa("Git::Error::Command");
3246
3247                         warn "W: Cannot find common ancestor between ".
3248                              "@$parents and $merge_tip. Ignoring merge info.\n";
3249                         next;
3250                 }
3251
3252                 # double check that there are no missing non-merge commits
3253                 my (@incomplete) = check_cherry_pick(
3254                         $merge_base, $merge_tip,
3255                         @$ranges,
3256                        );
3257
3258                 if ( @incomplete ) {
3259                         warn "W:svn cherry-pick ignored ($spec) - missing "
3260                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3261                 } else {
3262                         warn
3263                                 "Found merge parent (svn:mergeinfo prop): ",
3264                                         $merge_tip, "\n";
3265                         push @new_parents, $merge_tip;
3266                 }
3267         }
3268
3269         # cater for merges which merge commits from multiple branches
3270         if ( @new_parents > 1 ) {
3271                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3272                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3273                                 next if $i == $j;
3274                                 next unless $new_parents[$i];
3275                                 next unless $new_parents[$j];
3276                                 my $revs = command_oneline(
3277                                         "rev-list", "-1",
3278                                         "$new_parents[$i]..$new_parents[$j]",
3279                                        );
3280                                 if ( !$revs ) {
3281                                         undef($new_parents[$j]);
3282                                 }
3283                         }
3284                 }
3285         }
3286         push @$parents, grep { defined } @new_parents;
3287 }
3288
3289 sub make_log_entry {
3290         my ($self, $rev, $parents, $ed) = @_;
3291         my $untracked = $self->get_untracked($ed);
3292
3293         my @parents = @$parents;
3294         my $ps = $ed->{path_strip} || "";
3295         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3296                 my $props = $ed->{dir_prop}{$path};
3297                 if ( $props->{"svk:merge"} ) {
3298                         $self->find_extra_svk_parents
3299                                 ($ed, $props->{"svk:merge"}, \@parents);
3300                 }
3301                 if ( $props->{"svn:mergeinfo"} ) {
3302                         $self->find_extra_svn_parents
3303                                 ($ed,
3304                                  $props->{"svn:mergeinfo"},
3305                                  \@parents);
3306                 }
3307         }
3308
3309         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3310         print $un "r$rev\n" or croak $!;
3311         print $un $_, "\n" foreach @$untracked;
3312         my %log_entry = ( parents => \@parents, revision => $rev,
3313                           log => '');
3314
3315         my $headrev;
3316         my $logged = delete $self->{logged_rev_props};
3317         if (!$logged || $self->{-want_revprops}) {
3318                 my $rp = $self->ra->rev_proplist($rev);
3319                 foreach (sort keys %$rp) {
3320                         my $v = $rp->{$_};
3321                         if (/^svn:(author|date|log)$/) {
3322                                 $log_entry{$1} = $v;
3323                         } elsif ($_ eq 'svm:headrev') {
3324                                 $headrev = $v;
3325                         } else {
3326                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3327                                           uri_encode($v), "\n";
3328                         }
3329                 }
3330         } else {
3331                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3332         }
3333         close $un or croak $!;
3334
3335         $log_entry{date} = parse_svn_date($log_entry{date});
3336         $log_entry{log} .= "\n";
3337         my $author = $log_entry{author} = check_author($log_entry{author});
3338         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3339                                                        : ($author, undef);
3340
3341         my ($commit_name, $commit_email) = ($name, $email);
3342         if ($_use_log_author) {
3343                 my $name_field;
3344                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3345                         $name_field = $1;
3346                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3347                         $name_field = $1;
3348                 }
3349                 if (!defined $name_field) {
3350                         if (!defined $email) {
3351                                 $email = $name;
3352                         }
3353                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3354                         ($name, $email) = ($1, $2);
3355                 } elsif ($name_field =~ /(.*)@/) {
3356                         ($name, $email) = ($1, $name_field);
3357                 } else {
3358                         ($name, $email) = ($name_field, $name_field);
3359                 }
3360         }
3361         if (defined $headrev && $self->use_svm_props) {
3362                 if ($self->rewrite_root) {
3363                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3364                             "options set!\n";
3365                 }
3366                 if ($self->rewrite_uuid) {
3367                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3368                             "options set!\n";
3369                 }
3370                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3371                 # we don't want "SVM: initializing mirror for junk" ...
3372                 return undef if $r == 0;
3373                 my $svm = $self->svm;
3374                 if ($uuid ne $svm->{uuid}) {
3375                         die "UUID mismatch on SVM path:\n",
3376                             "expected: $svm->{uuid}\n",
3377                             "     got: $uuid\n";
3378                 }
3379                 my $full_url = $self->full_url;
3380                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3381                              die "Failed to replace '$svm->{replace}' with ",
3382                                  "'$svm->{source}' in $full_url\n";
3383                 # throw away username for storing in records
3384                 remove_username($full_url);
3385                 $log_entry{metadata} = "$full_url\@$r $uuid";
3386                 $log_entry{svm_revision} = $r;
3387                 $email ||= "$author\@$uuid";
3388                 $commit_email ||= "$author\@$uuid";
3389         } elsif ($self->use_svnsync_props) {
3390                 my $full_url = $self->svnsync->{url};
3391                 $full_url .= "/$self->{path}" if length $self->{path};
3392                 remove_username($full_url);
3393                 my $uuid = $self->svnsync->{uuid};
3394                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3395                 $email ||= "$author\@$uuid";
3396                 $commit_email ||= "$author\@$uuid";
3397         } else {
3398                 my $url = $self->metadata_url;
3399                 remove_username($url);
3400                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3401                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3402                 $email ||= "$author\@" . $uuid;
3403                 $commit_email ||= "$author\@" . $uuid;
3404         }
3405         $log_entry{name} = $name;
3406         $log_entry{email} = $email;
3407         $log_entry{commit_name} = $commit_name;
3408         $log_entry{commit_email} = $commit_email;
3409         \%log_entry;
3410 }
3411
3412 sub fetch {
3413         my ($self, $min_rev, $max_rev, @parents) = @_;
3414         my ($last_rev, $last_commit) = $self->last_rev_commit;
3415         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3416         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3417 }
3418
3419 sub set_tree_cb {
3420         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3421         $self->{inject_parents} = { $rev => $tree };
3422         $self->fetch(undef, undef);
3423 }
3424
3425 sub set_tree {
3426         my ($self, $tree) = (shift, shift);
3427         my $log_entry = ::get_commit_entry($tree);
3428         unless ($self->{last_rev}) {
3429                 ::fatal("Must have an existing revision to commit");
3430         }
3431         my %ed_opts = ( r => $self->{last_rev},
3432                         log => $log_entry->{log},
3433                         ra => $self->ra,
3434                         tree_a => $self->{last_commit},
3435                         tree_b => $tree,
3436                         editor_cb => sub {
3437                                $self->set_tree_cb($log_entry, $tree, @_) },
3438                         svn_path => $self->{path} );
3439         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3440                 print "No changes\nr$self->{last_rev} = $tree\n";
3441         }
3442 }
3443
3444 sub rebuild_from_rev_db {
3445         my ($self, $path) = @_;
3446         my $r = -1;
3447         open my $fh, '<', $path or croak "open: $!";
3448         binmode $fh or croak "binmode: $!";
3449         while (<$fh>) {
3450                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3451                 chomp($_);
3452                 ++$r;
3453                 next if $_ eq ('0' x 40);
3454                 $self->rev_map_set($r, $_);
3455                 print "r$r = $_\n";
3456         }
3457         close $fh or croak "close: $!";
3458         unlink $path or croak "unlink: $!";
3459 }
3460
3461 sub rebuild {
3462         my ($self) = @_;
3463         my $map_path = $self->map_path;
3464         my $partial = (-e $map_path && ! -z $map_path);
3465         return unless ::verify_ref($self->refname.'^0');
3466         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3467                 my $rev_db = $self->rev_db_path;
3468                 $self->rebuild_from_rev_db($rev_db);
3469                 if ($self->use_svm_props) {
3470                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3471                         $self->rebuild_from_rev_db($svm_rev_db);
3472                 }
3473                 $self->unlink_rev_db_symlink;
3474                 return;
3475         }
3476         print "Rebuilding $map_path ...\n" if (!$partial);
3477         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3478                 (undef, undef));
3479         my ($log, $ctx) =
3480             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3481                                 ($head ? "$head.." : "") . $self->refname,
3482                                 '--');
3483         my $metadata_url = $self->metadata_url;
3484         remove_username($metadata_url);
3485         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3486         my $c;
3487         while (<$log>) {
3488                 if ( m{^commit ($::sha1)$} ) {
3489                         $c = $1;
3490                         next;
3491                 }
3492                 next unless s{^\s*(git-svn-id:)}{$1};
3493                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3494                 remove_username($url);
3495
3496                 # ignore merges (from set-tree)
3497                 next if (!defined $rev || !$uuid);
3498
3499                 # if we merged or otherwise started elsewhere, this is
3500                 # how we break out of it
3501                 if (($uuid ne $svn_uuid) ||
3502                     ($metadata_url && $url && ($url ne $metadata_url))) {
3503                         next;
3504                 }
3505                 if ($partial && $head) {
3506                         print "Partial-rebuilding $map_path ...\n";
3507                         print "Currently at $base_rev = $head\n";
3508                         $head = undef;
3509                 }
3510
3511                 $self->rev_map_set($rev, $c);
3512                 print "r$rev = $c\n";
3513         }
3514         command_close_pipe($log, $ctx);
3515         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3516         my $rev_db_path = $self->rev_db_path;
3517         if (-f $self->rev_db_path) {
3518                 unlink $self->rev_db_path or croak "unlink: $!";
3519         }
3520         $self->unlink_rev_db_symlink;
3521 }
3522
3523 # rev_map:
3524 # Tie::File seems to be prone to offset errors if revisions get sparse,
3525 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3526 # one of my favorite modules is out :<  Next up would be one of the DBM
3527 # modules, but I'm not sure which is most portable...
3528 #
3529 # This is the replacement for the rev_db format, which was too big
3530 # and inefficient for large repositories with a lot of sparse history
3531 # (mainly tags)
3532 #
3533 # The format is this:
3534 #   - 24 bytes for every record,
3535 #     * 4 bytes for the integer representing an SVN revision number
3536 #     * 20 bytes representing the sha1 of a git commit
3537 #   - No empty padding records like the old format
3538 #     (except the last record, which can be overwritten)
3539 #   - new records are written append-only since SVN revision numbers
3540 #     increase monotonically
3541 #   - lookups on SVN revision number are done via a binary search
3542 #   - Piping the file to xxd -c24 is a good way of dumping it for
3543 #     viewing or editing (piped back through xxd -r), should the need
3544 #     ever arise.
3545 #   - The last record can be padding revision with an all-zero sha1
3546 #     This is used to optimize fetch performance when using multiple
3547 #     "fetch" directives in .git/config
3548 #
3549 # These files are disposable unless noMetadata or useSvmProps is set
3550
3551 sub _rev_map_set {
3552         my ($fh, $rev, $commit) = @_;
3553
3554         binmode $fh or croak "binmode: $!";
3555         my $size = (stat($fh))[7];
3556         ($size % 24) == 0 or croak "inconsistent size: $size";
3557
3558         my $wr_offset = 0;
3559         if ($size > 0) {
3560                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3561                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3562                 $read == 24 or croak "read only $read bytes (!= 24)";
3563                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3564                 if ($last_commit eq ('0' x40)) {
3565                         if ($size >= 48) {
3566                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3567                                 $read = sysread($fh, $buf, 24) or
3568                                     croak "read: $!";
3569                                 $read == 24 or
3570                                     croak "read only $read bytes (!= 24)";
3571                                 ($last_rev, $last_commit) =
3572                                     unpack(rev_map_fmt, $buf);
3573                                 if ($last_commit eq ('0' x40)) {
3574                                         croak "inconsistent .rev_map\n";
3575                                 }
3576                         }
3577                         if ($last_rev >= $rev) {
3578                                 croak "last_rev is higher!: $last_rev >= $rev";
3579                         }
3580                         $wr_offset = -24;
3581                 }
3582         }
3583         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3584         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3585           croak "write: $!";
3586 }
3587
3588 sub _rev_map_reset {
3589         my ($fh, $rev, $commit) = @_;
3590         my $c = _rev_map_get($fh, $rev);
3591         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3592         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3593         truncate $fh, $offset or croak "truncate: $!";
3594 }
3595
3596 sub mkfile {
3597         my ($path) = @_;
3598         unless (-e $path) {
3599                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3600                 mkpath([$dir]) unless -d $dir;
3601                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3602                 close $fh or die "Couldn't close (create) $path: $!\n";
3603         }
3604 }
3605
3606 sub rev_map_set {
3607         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3608         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3609         my $db = $self->map_path($uuid);
3610         my $db_lock = "$db.lock";
3611         my $sig;
3612         $update_ref ||= 0;
3613         if ($update_ref) {
3614                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3615                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3616         }
3617         mkfile($db);
3618
3619         $LOCKFILES{$db_lock} = 1;
3620         my $sync;
3621         # both of these options make our .rev_db file very, very important
3622         # and we can't afford to lose it because rebuild() won't work
3623         if ($self->use_svm_props || $self->no_metadata) {
3624                 $sync = 1;
3625                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3626                                            "Failed to copy: ",
3627                                            "$db => $db_lock ($!)\n";
3628         } else {
3629                 rename $db, $db_lock or die "rev_map_set(@_): ",
3630                                             "Failed to rename: ",
3631                                             "$db => $db_lock ($!)\n";
3632         }
3633
3634         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3635              or croak "Couldn't open $db_lock: $!\n";
3636         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3637                                  _rev_map_set($fh, $rev, $commit);
3638         if ($sync) {
3639                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3640                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3641         }
3642         close $fh or croak $!;
3643         if ($update_ref) {
3644                 $_head = $self;
3645                 my $note = "";
3646                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3647                 command_noisy('update-ref', '-m', "r$rev$note",
3648                               $self->refname, $commit);
3649         }
3650         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3651                                     "$db_lock => $db ($!)\n";
3652         delete $LOCKFILES{$db_lock};
3653         if ($update_ref) {
3654                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3655                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3656                 kill $sig, $$ if defined $sig;
3657         }
3658 }
3659
3660 # If want_commit, this will return an array of (rev, commit) where
3661 # commit _must_ be a valid commit in the archive.
3662 # Otherwise, it'll return the max revision (whether or not the
3663 # commit is valid or just a 0x40 placeholder).
3664 sub rev_map_max {
3665         my ($self, $want_commit) = @_;
3666         $self->rebuild;
3667         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3668         $want_commit ? ($r, $c) : $r;
3669 }
3670
3671 sub rev_map_max_norebuild {
3672         my ($self, $want_commit) = @_;
3673         my $map_path = $self->map_path;
3674         stat $map_path or return $want_commit ? (0, undef) : 0;
3675         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3676         binmode $fh or croak "binmode: $!";
3677         my $size = (stat($fh))[7];
3678         ($size % 24) == 0 or croak "inconsistent size: $size";
3679
3680         if ($size == 0) {
3681                 close $fh or croak "close: $!";
3682                 return $want_commit ? (0, undef) : 0;
3683         }
3684
3685         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3686         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3687         my ($r, $c) = unpack(rev_map_fmt, $buf);
3688         if ($want_commit && $c eq ('0' x40)) {
3689                 if ($size < 48) {
3690                         return $want_commit ? (0, undef) : 0;
3691                 }
3692                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3693                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3694                 ($r, $c) = unpack(rev_map_fmt, $buf);
3695                 if ($c eq ('0'x40)) {
3696                         croak "Penultimate record is all-zeroes in $map_path";
3697                 }
3698         }
3699         close $fh or croak "close: $!";
3700         $want_commit ? ($r, $c) : $r;
3701 }
3702
3703 sub rev_map_get {
3704         my ($self, $rev, $uuid) = @_;
3705         my $map_path = $self->map_path($uuid);
3706         return undef unless -e $map_path;
3707
3708         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3709         my $c = _rev_map_get($fh, $rev);
3710         close($fh) or croak "close: $!";
3711         $c
3712 }
3713
3714 sub _rev_map_get {
3715         my ($fh, $rev) = @_;
3716
3717         binmode $fh or croak "binmode: $!";
3718         my $size = (stat($fh))[7];
3719         ($size % 24) == 0 or croak "inconsistent size: $size";
3720
3721         if ($size == 0) {
3722                 return undef;
3723         }
3724
3725         my ($l, $u) = (0, $size - 24);
3726         my ($r, $c, $buf);
3727
3728         while ($l <= $u) {
3729                 my $i = int(($l/24 + $u/24) / 2) * 24;
3730                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3731                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3732                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3733
3734                 if ($r < $rev) {
3735                         $l = $i + 24;
3736                 } elsif ($r > $rev) {
3737                         $u = $i - 24;
3738                 } else { # $r == $rev
3739                         return $c eq ('0' x 40) ? undef : $c;
3740                 }
3741         }
3742         undef;
3743 }
3744
3745 # Finds the first svn revision that exists on (if $eq_ok is true) or
3746 # before $rev for the current branch.  It will not search any lower
3747 # than $min_rev.  Returns the git commit hash and svn revision number
3748 # if found, else (undef, undef).
3749 sub find_rev_before {
3750         my ($self, $rev, $eq_ok, $min_rev) = @_;
3751         --$rev unless $eq_ok;
3752         $min_rev ||= 1;
3753         my $max_rev = $self->rev_map_max;
3754         $rev = $max_rev if ($rev > $max_rev);
3755         while ($rev >= $min_rev) {
3756                 if (my $c = $self->rev_map_get($rev)) {
3757                         return ($rev, $c);
3758                 }
3759                 --$rev;
3760         }
3761         return (undef, undef);
3762 }
3763
3764 # Finds the first svn revision that exists on (if $eq_ok is true) or
3765 # after $rev for the current branch.  It will not search any higher
3766 # than $max_rev.  Returns the git commit hash and svn revision number
3767 # if found, else (undef, undef).
3768 sub find_rev_after {
3769         my ($self, $rev, $eq_ok, $max_rev) = @_;
3770         ++$rev unless $eq_ok;
3771         $max_rev ||= $self->rev_map_max;
3772         while ($rev <= $max_rev) {
3773                 if (my $c = $self->rev_map_get($rev)) {
3774                         return ($rev, $c);
3775                 }
3776                 ++$rev;
3777         }
3778         return (undef, undef);
3779 }
3780
3781 sub _new {
3782         my ($class, $repo_id, $ref_id, $path) = @_;
3783         unless (defined $repo_id && length $repo_id) {
3784                 $repo_id = $Git::SVN::default_repo_id;
3785         }
3786         unless (defined $ref_id && length $ref_id) {
3787                 $_prefix = '' unless defined($_prefix);
3788                 $_[2] = $ref_id =
3789                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3790         }
3791         $_[1] = $repo_id;
3792         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3793
3794         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3795         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3796         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3797                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3798                 if (-d $old_dir && ! -d $dir) {
3799                         $dir = $old_dir;
3800                 }
3801         }
3802
3803         $_[3] = $path = '' unless (defined $path);
3804         mkpath([$dir]);
3805         bless {
3806                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3807                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3808                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3809 }
3810
3811 # for read-only access of old .rev_db formats
3812 sub unlink_rev_db_symlink {
3813         my ($self) = @_;
3814         my $link = $self->rev_db_path;
3815         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3816         if (-l $link) {
3817                 unlink $link or croak "unlink: $link failed!";
3818         }
3819 }
3820
3821 sub rev_db_path {
3822         my ($self, $uuid) = @_;
3823         my $db_path = $self->map_path($uuid);
3824         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3825             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3826         $db_path;
3827 }
3828
3829 # the new replacement for .rev_db
3830 sub map_path {
3831         my ($self, $uuid) = @_;
3832         $uuid ||= $self->ra_uuid;
3833         "$self->{map_root}.$uuid";
3834 }
3835
3836 sub uri_encode {
3837         my ($f) = @_;
3838         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3839         $f
3840 }
3841
3842 sub uri_decode {
3843         my ($f) = @_;
3844         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3845         $f
3846 }
3847
3848 sub remove_username {
3849         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3850 }
3851
3852 package Git::SVN::Prompt;
3853 use strict;
3854 use warnings;
3855 require SVN::Core;
3856 use vars qw/$_no_auth_cache $_username/;
3857
3858 sub simple {
3859         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3860         $may_save = undef if $_no_auth_cache;
3861         $default_username = $_username if defined $_username;
3862         if (defined $default_username && length $default_username) {
3863                 if (defined $realm && length $realm) {
3864                         print STDERR "Authentication realm: $realm\n";
3865                         STDERR->flush;
3866                 }
3867                 $cred->username($default_username);
3868         } else {
3869                 username($cred, $realm, $may_save, $pool);
3870         }
3871         $cred->password(_read_password("Password for '" .
3872                                        $cred->username . "': ", $realm));
3873         $cred->may_save($may_save);
3874         $SVN::_Core::SVN_NO_ERROR;
3875 }
3876
3877 sub ssl_server_trust {
3878         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3879         $may_save = undef if $_no_auth_cache;
3880         print STDERR "Error validating server certificate for '$realm':\n";
3881         {
3882                 no warnings 'once';
3883                 # All variables SVN::Auth::SSL::* are used only once,
3884                 # so we're shutting up Perl warnings about this.
3885                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3886                         print STDERR " - The certificate is not issued ",
3887                             "by a trusted authority. Use the\n",
3888                             "   fingerprint to validate ",
3889                             "the certificate manually!\n";
3890                 }
3891                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3892                         print STDERR " - The certificate hostname ",
3893                             "does not match.\n";
3894                 }
3895                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3896                         print STDERR " - The certificate is not yet valid.\n";
3897                 }
3898                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3899                         print STDERR " - The certificate has expired.\n";
3900                 }
3901                 if ($failures & $SVN::Auth::SSL::OTHER) {
3902                         print STDERR " - The certificate has ",
3903                             "an unknown error.\n";
3904                 }
3905         } # no warnings 'once'
3906         printf STDERR
3907                 "Certificate information:\n".
3908                 " - Hostname: %s\n".
3909                 " - Valid: from %s until %s\n".
3910                 " - Issuer: %s\n".
3911                 " - Fingerprint: %s\n",
3912                 map $cert_info->$_, qw(hostname valid_from valid_until
3913                                        issuer_dname fingerprint);
3914         my $choice;
3915 prompt:
3916         print STDERR $may_save ?
3917               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3918               "(R)eject or accept (t)emporarily? ";
3919         STDERR->flush;
3920         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3921         if ($choice =~ /^t$/i) {
3922                 $cred->may_save(undef);
3923         } elsif ($choice =~ /^r$/i) {
3924                 return -1;
3925         } elsif ($may_save && $choice =~ /^p$/i) {
3926                 $cred->may_save($may_save);
3927         } else {
3928                 goto prompt;
3929         }
3930         $cred->accepted_failures($failures);
3931         $SVN::_Core::SVN_NO_ERROR;
3932 }
3933
3934 sub ssl_client_cert {
3935         my ($cred, $realm, $may_save, $pool) = @_;
3936         $may_save = undef if $_no_auth_cache;
3937         print STDERR "Client certificate filename: ";
3938         STDERR->flush;
3939         chomp(my $filename = <STDIN>);
3940         $cred->cert_file($filename);
3941         $cred->may_save($may_save);
3942         $SVN::_Core::SVN_NO_ERROR;
3943 }
3944
3945 sub ssl_client_cert_pw {
3946         my ($cred, $realm, $may_save, $pool) = @_;
3947         $may_save = undef if $_no_auth_cache;
3948         $cred->password(_read_password("Password: ", $realm));
3949         $cred->may_save($may_save);
3950         $SVN::_Core::SVN_NO_ERROR;
3951 }
3952
3953 sub username {
3954         my ($cred, $realm, $may_save, $pool) = @_;
3955         $may_save = undef if $_no_auth_cache;
3956         if (defined $realm && length $realm) {
3957                 print STDERR "Authentication realm: $realm\n";
3958         }
3959         my $username;
3960         if (defined $_username) {
3961                 $username = $_username;
3962         } else {
3963                 print STDERR "Username: ";
3964                 STDERR->flush;
3965                 chomp($username = <STDIN>);
3966         }
3967         $cred->username($username);
3968         $cred->may_save($may_save);
3969         $SVN::_Core::SVN_NO_ERROR;
3970 }
3971
3972 sub _read_password {
3973         my ($prompt, $realm) = @_;
3974         my $password = '';
3975         if (exists $ENV{GIT_ASKPASS}) {
3976                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
3977                 $password = <PH>;
3978                 $password =~ s/[\012\015]//; # \n\r
3979                 close(PH);
3980         } else {
3981                 print STDERR $prompt;
3982                 STDERR->flush;
3983                 require Term::ReadKey;
3984                 Term::ReadKey::ReadMode('noecho');
3985                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3986                         last if $key =~ /[\012\015]/; # \n\r
3987                         $password .= $key;
3988                 }
3989                 Term::ReadKey::ReadMode('restore');
3990                 print STDERR "\n";
3991                 STDERR->flush;
3992         }
3993         $password;
3994 }
3995
3996 package SVN::Git::Fetcher;
3997 use vars qw/@ISA/;
3998 use strict;
3999 use warnings;
4000 use Carp qw/croak/;
4001 use File::Temp qw/tempfile/;
4002 use IO::File qw//;
4003 use vars qw/$_ignore_regex/;
4004
4005 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4006 sub new {
4007         my ($class, $git_svn, $switch_path) = @_;
4008         my $self = SVN::Delta::Editor->new;
4009         bless $self, $class;
4010         if (exists $git_svn->{last_commit}) {
4011                 $self->{c} = $git_svn->{last_commit};
4012                 $self->{empty_symlinks} =
4013                                   _mark_empty_symlinks($git_svn, $switch_path);
4014         }
4015         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4016                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4017         $self->{empty} = {};
4018         $self->{dir_prop} = {};
4019         $self->{file_prop} = {};
4020         $self->{absent_dir} = {};
4021         $self->{absent_file} = {};
4022         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4023         $self;
4024 }
4025
4026 # this uses the Ra object, so it must be called before do_{switch,update},
4027 # not inside them (when the Git::SVN::Fetcher object is passed) to
4028 # do_{switch,update}
4029 sub _mark_empty_symlinks {
4030         my ($git_svn, $switch_path) = @_;
4031         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4032         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4033
4034         my %ret;
4035         my ($rev, $cmt) = $git_svn->last_rev_commit;
4036         return {} unless ($rev && $cmt);
4037
4038         # allow the warning to be printed for each revision we fetch to
4039         # ensure the user sees it.  The user can also disable the workaround
4040         # on the repository even while git svn is running and the next
4041         # revision fetched will skip this expensive function.
4042         my $printed_warning;
4043         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4044         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4045         local $/ = "\0";
4046         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4047         $pfx .= '/' if length($pfx);
4048         while (<$ls>) {
4049                 chomp;
4050                 s/\A100644 blob $empty_blob\t//o or next;
4051                 unless ($printed_warning) {
4052                         print STDERR "Scanning for empty symlinks, ",
4053                                      "this may take a while if you have ",
4054                                      "many empty files\n",
4055                                      "You may disable this with `",
4056                                      "git config svn.brokenSymlinkWorkaround ",
4057                                      "false'.\n",
4058                                      "This may be done in a different ",
4059                                      "terminal without restarting ",
4060                                      "git svn\n";
4061                         $printed_warning = 1;
4062                 }
4063                 my $path = $_;
4064                 my (undef, $props) =
4065                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4066                 if ($props->{'svn:special'}) {
4067                         $ret{$path} = 1;
4068                 }
4069         }
4070         command_close_pipe($ls, $ctx);
4071         \%ret;
4072 }
4073
4074 # returns true if a given path is inside a ".git" directory
4075 sub in_dot_git {
4076         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4077 }
4078
4079 # return value: 0 -- don't ignore, 1 -- ignore
4080 sub is_path_ignored {
4081         my ($self, $path) = @_;
4082         return 1 if in_dot_git($path);
4083         return 1 if defined($self->{ignore_regex}) &&
4084                     $path =~ m!$self->{ignore_regex}!;
4085         return 0 unless defined($_ignore_regex);
4086         return 1 if $path =~ m!$_ignore_regex!o;
4087         return 0;
4088 }
4089
4090 sub set_path_strip {
4091         my ($self, $path) = @_;
4092         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4093 }
4094
4095 sub open_root {
4096         { path => '' };
4097 }
4098
4099 sub open_directory {
4100         my ($self, $path, $pb, $rev) = @_;
4101         { path => $path };
4102 }
4103
4104 sub git_path {
4105         my ($self, $path) = @_;
4106         if ($self->{path_strip}) {
4107                 $path =~ s!$self->{path_strip}!! or
4108                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4109         }
4110         $path;
4111 }
4112
4113 sub delete_entry {
4114         my ($self, $path, $rev, $pb) = @_;
4115         return undef if $self->is_path_ignored($path);
4116
4117         my $gpath = $self->git_path($path);
4118         return undef if ($gpath eq '');
4119
4120         # remove entire directories.
4121         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4122                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4123         if ($tree) {
4124                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4125                                                      -r --name-only -z/,
4126                                                      $tree);
4127                 local $/ = "\0";
4128                 while (<$ls>) {
4129                         chomp;
4130                         my $rmpath = "$gpath/$_";
4131                         $self->{gii}->remove($rmpath);
4132                         print "\tD\t$rmpath\n" unless $::_q;
4133                 }
4134                 print "\tD\t$gpath/\n" unless $::_q;
4135                 command_close_pipe($ls, $ctx);
4136         } else {
4137                 $self->{gii}->remove($gpath);
4138                 print "\tD\t$gpath\n" unless $::_q;
4139         }
4140         $self->{empty}->{$path} = 0;
4141         undef;
4142 }
4143
4144 sub open_file {
4145         my ($self, $path, $pb, $rev) = @_;
4146         my ($mode, $blob);
4147
4148         goto out if $self->is_path_ignored($path);
4149
4150         my $gpath = $self->git_path($path);
4151         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4152                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4153         unless (defined $mode && defined $blob) {
4154                 die "$path was not found in commit $self->{c} (r$rev)\n";
4155         }
4156         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4157                 $mode = '120000';
4158         }
4159 out:
4160         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4161           pool => SVN::Pool->new, action => 'M' };
4162 }
4163
4164 sub add_file {
4165         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4166         my $mode;
4167
4168         if (!$self->is_path_ignored($path)) {
4169                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4170                 delete $self->{empty}->{$dir};
4171                 $mode = '100644';
4172         }
4173         { path => $path, mode_a => $mode, mode_b => $mode,
4174           pool => SVN::Pool->new, action => 'A' };
4175 }
4176
4177 sub add_directory {
4178         my ($self, $path, $cp_path, $cp_rev) = @_;
4179         goto out if $self->is_path_ignored($path);
4180         my $gpath = $self->git_path($path);
4181         if ($gpath eq '') {
4182                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4183                                                      -r --name-only -z/,
4184                                                      $self->{c});
4185                 local $/ = "\0";
4186                 while (<$ls>) {
4187                         chomp;
4188                         $self->{gii}->remove($_);
4189                         print "\tD\t$_\n" unless $::_q;
4190                 }
4191                 command_close_pipe($ls, $ctx);
4192                 $self->{empty}->{$path} = 0;
4193         }
4194         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4195         delete $self->{empty}->{$dir};
4196         $self->{empty}->{$path} = 1;
4197 out:
4198         { path => $path };
4199 }
4200
4201 sub change_dir_prop {
4202         my ($self, $db, $prop, $value) = @_;
4203         return undef if $self->is_path_ignored($db->{path});
4204         $self->{dir_prop}->{$db->{path}} ||= {};
4205         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4206         undef;
4207 }
4208
4209 sub absent_directory {
4210         my ($self, $path, $pb) = @_;
4211         return undef if $self->is_path_ignored($path);
4212         $self->{absent_dir}->{$pb->{path}} ||= [];
4213         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4214         undef;
4215 }
4216
4217 sub absent_file {
4218         my ($self, $path, $pb) = @_;
4219         return undef if $self->is_path_ignored($path);
4220         $self->{absent_file}->{$pb->{path}} ||= [];
4221         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4222         undef;
4223 }
4224
4225 sub change_file_prop {
4226         my ($self, $fb, $prop, $value) = @_;
4227         return undef if $self->is_path_ignored($fb->{path});
4228         if ($prop eq 'svn:executable') {
4229                 if ($fb->{mode_b} != 120000) {
4230                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4231                 }
4232         } elsif ($prop eq 'svn:special') {
4233                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4234         } else {
4235                 $self->{file_prop}->{$fb->{path}} ||= {};
4236                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4237         }
4238         undef;
4239 }
4240
4241 sub apply_textdelta {
4242         my ($self, $fb, $exp) = @_;
4243         return undef if $self->is_path_ignored($fb->{path});
4244         my $fh = $::_repository->temp_acquire('svn_delta');
4245         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4246         # (but $base does not,) so dup() it for reading in close_file
4247         open my $dup, '<&', $fh or croak $!;
4248         my $base = $::_repository->temp_acquire('git_blob');
4249
4250         if ($fb->{blob}) {
4251                 my ($base_is_link, $size);
4252
4253                 if ($fb->{mode_a} eq '120000' &&
4254                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4255                         print $base 'link ' or die "print $!\n";
4256                         $base_is_link = 1;
4257                 }
4258         retry:
4259                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4260                 die "Failed to read object $fb->{blob}" if ($size < 0);
4261
4262                 if (defined $exp) {
4263                         seek $base, 0, 0 or croak $!;
4264                         my $got = ::md5sum($base);
4265                         if ($got ne $exp) {
4266                                 my $err = "Checksum mismatch: ".
4267                                        "$fb->{path} $fb->{blob}\n" .
4268                                        "expected: $exp\n" .
4269                                        "     got: $got\n";
4270                                 if ($base_is_link) {
4271                                         warn $err,
4272                                              "Retrying... (possibly ",
4273                                              "a bad symlink from SVN)\n";
4274                                         $::_repository->temp_reset($base);
4275                                         $base_is_link = 0;
4276                                         goto retry;
4277                                 }
4278                                 die $err;
4279                         }
4280                 }
4281         }
4282         seek $base, 0, 0 or croak $!;
4283         $fb->{fh} = $fh;
4284         $fb->{base} = $base;
4285         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4286 }
4287
4288 sub close_file {
4289         my ($self, $fb, $exp) = @_;
4290         return undef if $self->is_path_ignored($fb->{path});
4291
4292         my $hash;
4293         my $path = $self->git_path($fb->{path});
4294         if (my $fh = $fb->{fh}) {
4295                 if (defined $exp) {
4296                         seek($fh, 0, 0) or croak $!;
4297                         my $got = ::md5sum($fh);
4298                         if ($got ne $exp) {
4299                                 die "Checksum mismatch: $path\n",
4300                                     "expected: $exp\n    got: $got\n";
4301                         }
4302                 }
4303                 if ($fb->{mode_b} == 120000) {
4304                         sysseek($fh, 0, 0) or croak $!;
4305                         my $rd = sysread($fh, my $buf, 5);
4306
4307                         if (!defined $rd) {
4308                                 croak "sysread: $!\n";
4309                         } elsif ($rd == 0) {
4310                                 warn "$path has mode 120000",
4311                                      " but it points to nothing\n",
4312                                      "converting to an empty file with mode",
4313                                      " 100644\n";
4314                                 $fb->{mode_b} = '100644';
4315                         } elsif ($buf ne 'link ') {
4316                                 warn "$path has mode 120000",
4317                                      " but is not a link\n";
4318                         } else {
4319                                 my $tmp_fh = $::_repository->temp_acquire(
4320                                         'svn_hash');
4321                                 my $res;
4322                                 while ($res = sysread($fh, my $str, 1024)) {
4323                                         my $out = syswrite($tmp_fh, $str, $res);
4324                                         defined($out) && $out == $res
4325                                                 or croak("write ",
4326                                                         Git::temp_path($tmp_fh),
4327                                                         ": $!\n");
4328                                 }
4329                                 defined $res or croak $!;
4330
4331                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4332                                 Git::temp_release($tmp_fh, 1);
4333                         }
4334                 }
4335
4336                 $hash = $::_repository->hash_and_insert_object(
4337                                 Git::temp_path($fh));
4338                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4339
4340                 Git::temp_release($fb->{base}, 1);
4341                 Git::temp_release($fh, 1);
4342         } else {
4343                 $hash = $fb->{blob} or die "no blob information\n";
4344         }
4345         $fb->{pool}->clear;
4346         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4347         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4348         undef;
4349 }
4350
4351 sub abort_edit {
4352         my $self = shift;
4353         $self->{nr} = $self->{gii}->{nr};
4354         delete $self->{gii};
4355         $self->SUPER::abort_edit(@_);
4356 }
4357
4358 sub close_edit {
4359         my $self = shift;
4360         $self->{git_commit_ok} = 1;
4361         $self->{nr} = $self->{gii}->{nr};
4362         delete $self->{gii};
4363         $self->SUPER::close_edit(@_);
4364 }
4365
4366 package SVN::Git::Editor;
4367 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4368 use strict;
4369 use warnings;
4370 use Carp qw/croak/;
4371 use IO::File;
4372
4373 sub new {
4374         my ($class, $opts) = @_;
4375         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4376                 die "$_ required!\n" unless (defined $opts->{$_});
4377         }
4378
4379         my $pool = SVN::Pool->new;
4380         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4381         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4382                                      $opts->{r}, $mods);
4383
4384         # $opts->{ra} functions should not be used after this:
4385         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4386                                                 $opts->{editor_cb}, $pool);
4387         my $self = SVN::Delta::Editor->new(@ce, $pool);
4388         bless $self, $class;
4389         foreach (qw/svn_path r tree_a tree_b/) {
4390                 $self->{$_} = $opts->{$_};
4391         }
4392         $self->{url} = $opts->{ra}->{url};
4393         $self->{mods} = $mods;
4394         $self->{types} = $types;
4395         $self->{pool} = $pool;
4396         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4397         $self->{rm} = { };
4398         $self->{path_prefix} = length $self->{svn_path} ?
4399                                "$self->{svn_path}/" : '';
4400         $self->{config} = $opts->{config};
4401         return $self;
4402 }
4403
4404 sub generate_diff {
4405         my ($tree_a, $tree_b) = @_;
4406         my @diff_tree = qw(diff-tree -z -r);
4407         if ($_cp_similarity) {
4408                 push @diff_tree, "-C$_cp_similarity";
4409         } else {
4410                 push @diff_tree, '-C';
4411         }
4412         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4413         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4414         push @diff_tree, $tree_a, $tree_b;
4415         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4416         local $/ = "\0";
4417         my $state = 'meta';
4418         my @mods;
4419         while (<$diff_fh>) {
4420                 chomp $_; # this gets rid of the trailing "\0"
4421                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4422                                         ($::sha1)\s($::sha1)\s
4423                                         ([MTCRAD])\d*$/xo) {
4424                         push @mods, {   mode_a => $1, mode_b => $2,
4425                                         sha1_a => $3, sha1_b => $4,
4426                                         chg => $5 };
4427                         if ($5 =~ /^(?:C|R)$/) {
4428                                 $state = 'file_a';
4429                         } else {
4430                                 $state = 'file_b';
4431                         }
4432                 } elsif ($state eq 'file_a') {
4433                         my $x = $mods[$#mods] or croak "Empty array\n";
4434                         if ($x->{chg} !~ /^(?:C|R)$/) {
4435                                 croak "Error parsing $_, $x->{chg}\n";
4436                         }
4437                         $x->{file_a} = $_;
4438                         $state = 'file_b';
4439                 } elsif ($state eq 'file_b') {
4440                         my $x = $mods[$#mods] or croak "Empty array\n";
4441                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4442                                 croak "Error parsing $_, $x->{chg}\n";
4443                         }
4444                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4445                                 croak "Error parsing $_, $x->{chg}\n";
4446                         }
4447                         $x->{file_b} = $_;
4448                         $state = 'meta';
4449                 } else {
4450                         croak "Error parsing $_\n";
4451                 }
4452         }
4453         command_close_pipe($diff_fh, $ctx);
4454         \@mods;
4455 }
4456
4457 sub check_diff_paths {
4458         my ($ra, $pfx, $rev, $mods) = @_;
4459         my %types;
4460         $pfx .= '/' if length $pfx;
4461
4462         sub type_diff_paths {
4463                 my ($ra, $types, $path, $rev) = @_;
4464                 my @p = split m#/+#, $path;
4465                 my $c = shift @p;
4466                 unless (defined $types->{$c}) {
4467                         $types->{$c} = $ra->check_path($c, $rev);
4468                 }
4469                 while (@p) {
4470                         $c .= '/' . shift @p;
4471                         next if defined $types->{$c};
4472                         $types->{$c} = $ra->check_path($c, $rev);
4473                 }
4474         }
4475
4476         foreach my $m (@$mods) {
4477                 foreach my $f (qw/file_a file_b/) {
4478                         next unless defined $m->{$f};
4479                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4480                         if (length $pfx.$dir && ! defined $types{$dir}) {
4481                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4482                         }
4483                 }
4484         }
4485         \%types;
4486 }
4487
4488 sub split_path {
4489         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4490 }
4491
4492 sub repo_path {
4493         my ($self, $path) = @_;
4494         $self->{path_prefix}.(defined $path ? $path : '');
4495 }
4496
4497 sub url_path {
4498         my ($self, $path) = @_;
4499         if ($self->{url} =~ m#^https?://#) {
4500                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4501         }
4502         $self->{url} . '/' . $self->repo_path($path);
4503 }
4504
4505 sub rmdirs {
4506         my ($self) = @_;
4507         my $rm = $self->{rm};
4508         delete $rm->{''}; # we never delete the url we're tracking
4509         return unless %$rm;
4510
4511         foreach (keys %$rm) {
4512                 my @d = split m#/#, $_;
4513                 my $c = shift @d;
4514                 $rm->{$c} = 1;
4515                 while (@d) {
4516                         $c .= '/' . shift @d;
4517                         $rm->{$c} = 1;
4518                 }
4519         }
4520         delete $rm->{$self->{svn_path}};
4521         delete $rm->{''}; # we never delete the url we're tracking
4522         return unless %$rm;
4523
4524         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4525                                              $self->{tree_b});
4526         local $/ = "\0";
4527         while (<$fh>) {
4528                 chomp;
4529                 my @dn = split m#/#, $_;
4530                 while (pop @dn) {
4531                         delete $rm->{join '/', @dn};
4532                 }
4533                 unless (%$rm) {
4534                         close $fh;
4535                         return;
4536                 }
4537         }
4538         command_close_pipe($fh, $ctx);
4539
4540         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4541         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4542                 $self->close_directory($bat->{$d}, $p);
4543                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4544                 print "\tD+\t$d/\n" unless $::_q;
4545                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4546                 delete $bat->{$d};
4547         }
4548 }
4549
4550 sub open_or_add_dir {
4551         my ($self, $full_path, $baton) = @_;
4552         my $t = $self->{types}->{$full_path};
4553         if (!defined $t) {
4554                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4555         }
4556         {
4557                 no warnings 'once';
4558                 # SVN::Node::none and SVN::Node::file are used only once,
4559                 # so we're shutting up Perl's warnings about them.
4560                 if ($t == $SVN::Node::none) {
4561                         return $self->add_directory($full_path, $baton,
4562                             undef, -1, $self->{pool});
4563                 } elsif ($t == $SVN::Node::dir) {
4564                         return $self->open_directory($full_path, $baton,
4565                             $self->{r}, $self->{pool});
4566                 } # no warnings 'once'
4567                 print STDERR "$full_path already exists in repository at ",
4568                     "r$self->{r} and it is not a directory (",
4569                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4570         } # no warnings 'once'
4571         exit 1;
4572 }
4573
4574 sub ensure_path {
4575         my ($self, $path) = @_;
4576         my $bat = $self->{bat};
4577         my $repo_path = $self->repo_path($path);
4578         return $bat->{''} unless (length $repo_path);
4579         my @p = split m#/+#, $repo_path;
4580         my $c = shift @p;
4581         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4582         while (@p) {
4583                 my $c0 = $c;
4584                 $c .= '/' . shift @p;
4585                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4586         }
4587         return $bat->{$c};
4588 }
4589
4590 # Subroutine to convert a globbing pattern to a regular expression.
4591 # From perl cookbook.
4592 sub glob2pat {
4593         my $globstr = shift;
4594         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4595         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4596         return '^' . $globstr . '$';
4597 }
4598
4599 sub check_autoprop {
4600         my ($self, $pattern, $properties, $file, $fbat) = @_;
4601         # Convert the globbing pattern to a regular expression.
4602         my $regex = glob2pat($pattern);
4603         # Check if the pattern matches the file name.
4604         if($file =~ m/($regex)/) {
4605                 # Parse the list of properties to set.
4606                 my @props = split(/;/, $properties);
4607                 foreach my $prop (@props) {
4608                         # Parse 'name=value' syntax and set the property.
4609                         if ($prop =~ /([^=]+)=(.*)/) {
4610                                 my ($n,$v) = ($1,$2);
4611                                 for ($n, $v) {
4612                                         s/^\s+//; s/\s+$//;
4613                                 }
4614                                 $self->change_file_prop($fbat, $n, $v);
4615                         }
4616                 }
4617         }
4618 }
4619
4620 sub apply_autoprops {
4621         my ($self, $file, $fbat) = @_;
4622         my $conf_t = ${$self->{config}}{'config'};
4623         no warnings 'once';
4624         # Check [miscellany]/enable-auto-props in svn configuration.
4625         if (SVN::_Core::svn_config_get_bool(
4626                 $conf_t,
4627                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4628                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4629                 0)) {
4630                 # Auto-props are enabled.  Enumerate them to look for matches.
4631                 my $callback = sub {
4632                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4633                 };
4634                 SVN::_Core::svn_config_enumerate(
4635                         $conf_t,
4636                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4637                         $callback);
4638         }
4639 }
4640
4641 sub A {
4642         my ($self, $m) = @_;
4643         my ($dir, $file) = split_path($m->{file_b});
4644         my $pbat = $self->ensure_path($dir);
4645         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4646                                         undef, -1);
4647         print "\tA\t$m->{file_b}\n" unless $::_q;
4648         $self->apply_autoprops($file, $fbat);
4649         $self->chg_file($fbat, $m);
4650         $self->close_file($fbat,undef,$self->{pool});
4651 }
4652
4653 sub C {
4654         my ($self, $m) = @_;
4655         my ($dir, $file) = split_path($m->{file_b});
4656         my $pbat = $self->ensure_path($dir);
4657         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4658                                 $self->url_path($m->{file_a}), $self->{r});
4659         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4660         $self->chg_file($fbat, $m);
4661         $self->close_file($fbat,undef,$self->{pool});
4662 }
4663
4664 sub delete_entry {
4665         my ($self, $path, $pbat) = @_;
4666         my $rpath = $self->repo_path($path);
4667         my ($dir, $file) = split_path($rpath);
4668         $self->{rm}->{$dir} = 1;
4669         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4670 }
4671
4672 sub R {
4673         my ($self, $m) = @_;
4674         my ($dir, $file) = split_path($m->{file_b});
4675         my $pbat = $self->ensure_path($dir);
4676         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4677                                 $self->url_path($m->{file_a}), $self->{r});
4678         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4679         $self->apply_autoprops($file, $fbat);
4680         $self->chg_file($fbat, $m);
4681         $self->close_file($fbat,undef,$self->{pool});
4682
4683         ($dir, $file) = split_path($m->{file_a});
4684         $pbat = $self->ensure_path($dir);
4685         $self->delete_entry($m->{file_a}, $pbat);
4686 }
4687
4688 sub M {
4689         my ($self, $m) = @_;
4690         my ($dir, $file) = split_path($m->{file_b});
4691         my $pbat = $self->ensure_path($dir);
4692         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4693                                 $pbat,$self->{r},$self->{pool});
4694         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4695         $self->chg_file($fbat, $m);
4696         $self->close_file($fbat,undef,$self->{pool});
4697 }
4698
4699 sub T { shift->M(@_) }
4700
4701 sub change_file_prop {
4702         my ($self, $fbat, $pname, $pval) = @_;
4703         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4704 }
4705
4706 sub _chg_file_get_blob ($$$$) {
4707         my ($self, $fbat, $m, $which) = @_;
4708         my $fh = $::_repository->temp_acquire("git_blob_$which");
4709         if ($m->{"mode_$which"} =~ /^120/) {
4710                 print $fh 'link ' or croak $!;
4711                 $self->change_file_prop($fbat,'svn:special','*');
4712         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4713                 $self->change_file_prop($fbat,'svn:special',undef);
4714         }
4715         my $blob = $m->{"sha1_$which"};
4716         return ($fh,) if ($blob =~ /^0{40}$/);
4717         my $size = $::_repository->cat_blob($blob, $fh);
4718         croak "Failed to read object $blob" if ($size < 0);
4719         $fh->flush == 0 or croak $!;
4720         seek $fh, 0, 0 or croak $!;
4721
4722         my $exp = ::md5sum($fh);
4723         seek $fh, 0, 0 or croak $!;
4724         return ($fh, $exp);
4725 }
4726
4727 sub chg_file {
4728         my ($self, $fbat, $m) = @_;
4729         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4730                 $self->change_file_prop($fbat,'svn:executable','*');
4731         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4732                 $self->change_file_prop($fbat,'svn:executable',undef);
4733         }
4734         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4735         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4736         my $pool = SVN::Pool->new;
4737         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4738         if (-s $fh_a) {
4739                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4740                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4741                 if (defined $res) {
4742                         die "Unexpected result from send_txstream: $res\n",
4743                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4744                 }
4745         } else {
4746                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4747                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4748                     if ($got ne $exp_b);
4749         }
4750         Git::temp_release($fh_b, 1);
4751         Git::temp_release($fh_a, 1);
4752         $pool->clear;
4753 }
4754
4755 sub D {
4756         my ($self, $m) = @_;
4757         my ($dir, $file) = split_path($m->{file_b});
4758         my $pbat = $self->ensure_path($dir);
4759         print "\tD\t$m->{file_b}\n" unless $::_q;
4760         $self->delete_entry($m->{file_b}, $pbat);
4761 }
4762
4763 sub close_edit {
4764         my ($self) = @_;
4765         my ($p,$bat) = ($self->{pool}, $self->{bat});
4766         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4767                 next if $_ eq '';
4768                 $self->close_directory($bat->{$_}, $p);
4769         }
4770         $self->close_directory($bat->{''}, $p);
4771         $self->SUPER::close_edit($p);
4772         $p->clear;
4773 }
4774
4775 sub abort_edit {
4776         my ($self) = @_;
4777         $self->SUPER::abort_edit($self->{pool});
4778 }
4779
4780 sub DESTROY {
4781         my $self = shift;
4782         $self->SUPER::DESTROY(@_);
4783         $self->{pool}->clear;
4784 }
4785
4786 # this drives the editor
4787 sub apply_diff {
4788         my ($self) = @_;
4789         my $mods = $self->{mods};
4790         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4791         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4792                 my $f = $m->{chg};
4793                 if (defined $o{$f}) {
4794                         $self->$f($m);
4795                 } else {
4796                         fatal("Invalid change type: $f");
4797                 }
4798         }
4799         $self->rmdirs if $_rmdir;
4800         if (@$mods == 0) {
4801                 $self->abort_edit;
4802         } else {
4803                 $self->close_edit;
4804         }
4805         return scalar @$mods;
4806 }
4807
4808 package Git::SVN::Ra;
4809 use vars qw/@ISA $config_dir $_log_window_size/;
4810 use strict;
4811 use warnings;
4812 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4813
4814 BEGIN {
4815         # enforce temporary pool usage for some simple functions
4816         no strict 'refs';
4817         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4818                       get_file/) {
4819                 my $SUPER = "SUPER::$f";
4820                 *$f = sub {
4821                         my $self = shift;
4822                         my $pool = SVN::Pool->new;
4823                         my @ret = $self->$SUPER(@_,$pool);
4824                         $pool->clear;
4825                         wantarray ? @ret : $ret[0];
4826                 };
4827         }
4828 }
4829
4830 sub _auth_providers () {
4831         [
4832           SVN::Client::get_simple_provider(),
4833           SVN::Client::get_ssl_server_trust_file_provider(),
4834           SVN::Client::get_simple_prompt_provider(
4835             \&Git::SVN::Prompt::simple, 2),
4836           SVN::Client::get_ssl_client_cert_file_provider(),
4837           SVN::Client::get_ssl_client_cert_prompt_provider(
4838             \&Git::SVN::Prompt::ssl_client_cert, 2),
4839           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4840           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4841             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4842           SVN::Client::get_username_provider(),
4843           SVN::Client::get_ssl_server_trust_prompt_provider(
4844             \&Git::SVN::Prompt::ssl_server_trust),
4845           SVN::Client::get_username_prompt_provider(
4846             \&Git::SVN::Prompt::username, 2)
4847         ]
4848 }
4849
4850 sub escape_uri_only {
4851         my ($uri) = @_;
4852         my @tmp;
4853         foreach (split m{/}, $uri) {
4854                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4855                 push @tmp, $_;
4856         }
4857         join('/', @tmp);
4858 }
4859
4860 sub escape_url {
4861         my ($url) = @_;
4862         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4863                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4864                 $url = "$scheme://$domain$uri";
4865         }
4866         $url;
4867 }
4868
4869 sub new {
4870         my ($class, $url) = @_;
4871         $url =~ s!/+$!!;
4872         return $RA if ($RA && $RA->{url} eq $url);
4873
4874         ::_req_svn();
4875
4876         SVN::_Core::svn_config_ensure($config_dir, undef);
4877         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4878         my $config = SVN::Core::config_get_config($config_dir);
4879         $RA = undef;
4880         my $dont_store_passwords = 1;
4881         my $conf_t = ${$config}{'config'};
4882         {
4883                 no warnings 'once';
4884                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4885                 # produces warnings that variables are used only once.
4886                 # I had not found the better way to shut them up, so
4887                 # the warnings of type 'once' are disabled in this block.
4888                 if (SVN::_Core::svn_config_get_bool($conf_t,
4889                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4890                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4891                     1) == 0) {
4892                         SVN::_Core::svn_auth_set_parameter($baton,
4893                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4894                             bless (\$dont_store_passwords, "_p_void"));
4895                 }
4896                 if (SVN::_Core::svn_config_get_bool($conf_t,
4897                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4898                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4899                     1) == 0) {
4900                         $Git::SVN::Prompt::_no_auth_cache = 1;
4901                 }
4902         } # no warnings 'once'
4903         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4904                               config => $config,
4905                               pool => SVN::Pool->new,
4906                               auth_provider_callbacks => $callbacks);
4907         $self->{url} = $url;
4908         $self->{svn_path} = $url;
4909         $self->{repos_root} = $self->get_repos_root;
4910         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4911         $self->{cache} = { check_path => { r => 0, data => {} },
4912                            get_dir => { r => 0, data => {} } };
4913         $RA = bless $self, $class;
4914 }
4915
4916 sub check_path {
4917         my ($self, $path, $r) = @_;
4918         my $cache = $self->{cache}->{check_path};
4919         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4920                 return $cache->{data}->{$path};
4921         }
4922         my $pool = SVN::Pool->new;
4923         my $t = $self->SUPER::check_path($path, $r, $pool);
4924         $pool->clear;
4925         if ($r != $cache->{r}) {
4926                 %{$cache->{data}} = ();
4927                 $cache->{r} = $r;
4928         }
4929         $cache->{data}->{$path} = $t;
4930 }
4931
4932 sub get_dir {
4933         my ($self, $dir, $r) = @_;
4934         my $cache = $self->{cache}->{get_dir};
4935         if ($r == $cache->{r}) {
4936                 if (my $x = $cache->{data}->{$dir}) {
4937                         return wantarray ? @$x : $x->[0];
4938                 }
4939         }
4940         my $pool = SVN::Pool->new;
4941         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4942         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4943         $pool->clear;
4944         if ($r != $cache->{r}) {
4945                 %{$cache->{data}} = ();
4946                 $cache->{r} = $r;
4947         }
4948         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4949         wantarray ? (\%dirents, $r, $props) : \%dirents;
4950 }
4951
4952 sub DESTROY {
4953         # do not call the real DESTROY since we store ourselves in $RA
4954 }
4955
4956 # get_log(paths, start, end, limit,
4957 #         discover_changed_paths, strict_node_history, receiver)
4958 sub get_log {
4959         my ($self, @args) = @_;
4960         my $pool = SVN::Pool->new;
4961
4962         # svn_log_changed_path_t objects passed to get_log are likely to be
4963         # overwritten even if only the refs are copied to an external variable,
4964         # so we should dup the structures in their entirety.  Using an
4965         # externally passed pool (instead of our temporary and quickly cleared
4966         # pool in Git::SVN::Ra) does not help matters at all...
4967         my $receiver = pop @args;
4968         my $prefix = "/".$self->{svn_path};
4969         $prefix =~ s#/+($)##;
4970         my $prefix_regex = qr#^\Q$prefix\E#;
4971         push(@args, sub {
4972                 my ($paths) = $_[0];
4973                 return &$receiver(@_) unless $paths;
4974                 $_[0] = ();
4975                 foreach my $p (keys %$paths) {
4976                         my $i = $paths->{$p};
4977                         # Make path relative to our url, not repos_root
4978                         $p =~ s/$prefix_regex//;
4979                         my %s = map { $_ => $i->$_; }
4980                                 qw/copyfrom_path copyfrom_rev action/;
4981                         if ($s{'copyfrom_path'}) {
4982                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4983                         }
4984                         $_[0]{$p} = \%s;
4985                 }
4986                 &$receiver(@_);
4987         });
4988
4989
4990         # the limit parameter was not supported in SVN 1.1.x, so we
4991         # drop it.  Therefore, the receiver callback passed to it
4992         # is made aware of this limitation by being wrapped if
4993         # the limit passed to is being wrapped.
4994         if ($SVN::Core::VERSION le '1.2.0') {
4995                 my $limit = splice(@args, 3, 1);
4996                 if ($limit > 0) {
4997                         my $receiver = pop @args;
4998                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4999                 }
5000         }
5001         my $ret = $self->SUPER::get_log(@args, $pool);
5002         $pool->clear;
5003         $ret;
5004 }
5005
5006 sub trees_match {
5007         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5008         my $ctx = SVN::Client->new(auth => _auth_providers);
5009         my $out = IO::File->new_tmpfile;
5010
5011         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5012         # $ctx->diff(), so we'll create a default one
5013         my $pool = SVN::Pool->new_default_sub;
5014
5015         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5016         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5017         $out->flush;
5018         my $ret = (($out->stat)[7] == 0);
5019         close $out or croak $!;
5020
5021         $ret;
5022 }
5023
5024 sub get_commit_editor {
5025         my ($self, $log, $cb, $pool) = @_;
5026         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5027         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5028 }
5029
5030 sub gs_do_update {
5031         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5032         my $new = ($rev_a == $rev_b);
5033         my $path = $gs->{path};
5034
5035         if ($new && -e $gs->{index}) {
5036                 unlink $gs->{index} or die
5037                   "Couldn't unlink index: $gs->{index}: $!\n";
5038         }
5039         my $pool = SVN::Pool->new;
5040         $editor->set_path_strip($path);
5041         my (@pc) = split m#/#, $path;
5042         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5043                                         1, $editor, $pool);
5044         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5045
5046         # Since we can't rely on svn_ra_reparent being available, we'll
5047         # just have to do some magic with set_path to make it so
5048         # we only want a partial path.
5049         my $sp = '';
5050         my $final = join('/', @pc);
5051         while (@pc) {
5052                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5053                 $sp .= '/' if length $sp;
5054                 $sp .= shift @pc;
5055         }
5056         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5057
5058         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5059
5060         $reporter->finish_report($pool);
5061         $pool->clear;
5062         $editor->{git_commit_ok};
5063 }
5064
5065 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5066 # svn_ra_reparent didn't work before 1.4)
5067 sub gs_do_switch {
5068         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5069         my $path = $gs->{path};
5070         my $pool = SVN::Pool->new;
5071
5072         my $full_url = $self->{url};
5073         my $old_url = $full_url;
5074         $full_url .= '/' . $path if length $path;
5075         my ($ra, $reparented);
5076
5077         if ($old_url =~ m#^svn(\+ssh)?://# ||
5078             ($full_url =~ m#^https?://# &&
5079              escape_url($full_url) ne $full_url)) {
5080                 $_[0] = undef;
5081                 $self = undef;
5082                 $RA = undef;
5083                 $ra = Git::SVN::Ra->new($full_url);
5084                 $ra_invalid = 1;
5085         } elsif ($old_url ne $full_url) {
5086                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5087                 $self->{url} = $full_url;
5088                 $reparented = 1;
5089         }
5090
5091         $ra ||= $self;
5092         $url_b = escape_url($url_b);
5093         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5094         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5095         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5096         $reporter->finish_report($pool);
5097
5098         if ($reparented) {
5099                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5100                 $self->{url} = $old_url;
5101         }
5102
5103         $pool->clear;
5104         $editor->{git_commit_ok};
5105 }
5106
5107 sub longest_common_path {
5108         my ($gsv, $globs) = @_;
5109         my %common;
5110         my $common_max = scalar @$gsv;
5111
5112         foreach my $gs (@$gsv) {
5113                 my @tmp = split m#/#, $gs->{path};
5114                 my $p = '';
5115                 foreach (@tmp) {
5116                         $p .= length($p) ? "/$_" : $_;
5117                         $common{$p} ||= 0;
5118                         $common{$p}++;
5119                 }
5120         }
5121         $globs ||= [];
5122         $common_max += scalar @$globs;
5123         foreach my $glob (@$globs) {
5124                 my @tmp = split m#/#, $glob->{path}->{left};
5125                 my $p = '';
5126                 foreach (@tmp) {
5127                         $p .= length($p) ? "/$_" : $_;
5128                         $common{$p} ||= 0;
5129                         $common{$p}++;
5130                 }
5131         }
5132
5133         my $longest_path = '';
5134         foreach (sort {length $b <=> length $a} keys %common) {
5135                 if ($common{$_} == $common_max) {
5136                         $longest_path = $_;
5137                         last;
5138                 }
5139         }
5140         $longest_path;
5141 }
5142
5143 sub gs_fetch_loop_common {
5144         my ($self, $base, $head, $gsv, $globs) = @_;
5145         return if ($base > $head);
5146         my $inc = $_log_window_size;
5147         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5148         my $longest_path = longest_common_path($gsv, $globs);
5149         my $ra_url = $self->{url};
5150         my $find_trailing_edge;
5151         while (1) {
5152                 my %revs;
5153                 my $err;
5154                 my $err_handler = $SVN::Error::handler;
5155                 $SVN::Error::handler = sub {
5156                         ($err) = @_;
5157                         skip_unknown_revs($err);
5158                 };
5159                 sub _cb {
5160                         my ($paths, $r, $author, $date, $log) = @_;
5161                         [ $paths,
5162                           { author => $author, date => $date, log => $log } ];
5163                 }
5164                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5165                                sub { $revs{$_[1]} = _cb(@_) });
5166                 if ($err) {
5167                         print "Checked through r$max\r";
5168                 } else {
5169                         $find_trailing_edge = 1;
5170                 }
5171                 if ($err and $find_trailing_edge) {
5172                         print STDERR "Path '$longest_path' ",
5173                                      "was probably deleted:\n",
5174                                      $err->expanded_message,
5175                                      "\nWill attempt to follow ",
5176                                      "revisions r$min .. r$max ",
5177                                      "committed before the deletion\n";
5178                         my $hi = $max;
5179                         while (--$hi >= $min) {
5180                                 my $ok;
5181                                 $self->get_log([$longest_path], $min, $hi,
5182                                                0, 1, 1, sub {
5183                                                $ok = $_[1];
5184                                                $revs{$_[1]} = _cb(@_) });
5185                                 if ($ok) {
5186                                         print STDERR "r$min .. r$ok OK\n";
5187                                         last;
5188                                 }
5189                         }
5190                         $find_trailing_edge = 0;
5191                 }
5192                 $SVN::Error::handler = $err_handler;
5193
5194                 my %exists = map { $_->{path} => $_ } @$gsv;
5195                 foreach my $r (sort {$a <=> $b} keys %revs) {
5196                         my ($paths, $logged) = @{$revs{$r}};
5197
5198                         foreach my $gs ($self->match_globs(\%exists, $paths,
5199                                                            $globs, $r)) {
5200                                 if ($gs->rev_map_max >= $r) {
5201                                         next;
5202                                 }
5203                                 next unless $gs->match_paths($paths, $r);
5204                                 $gs->{logged_rev_props} = $logged;
5205                                 if (my $last_commit = $gs->last_commit) {
5206                                         $gs->assert_index_clean($last_commit);
5207                                 }
5208                                 my $log_entry = $gs->do_fetch($paths, $r);
5209                                 if ($log_entry) {
5210                                         $gs->do_git_commit($log_entry);
5211                                 }
5212                                 $INDEX_FILES{$gs->{index}} = 1;
5213                         }
5214                         foreach my $g (@$globs) {
5215                                 my $k = "svn-remote.$g->{remote}." .
5216                                         "$g->{t}-maxRev";
5217                                 Git::SVN::tmp_config($k, $r);
5218                         }
5219                         if ($ra_invalid) {
5220                                 $_[0] = undef;
5221                                 $self = undef;
5222                                 $RA = undef;
5223                                 $self = Git::SVN::Ra->new($ra_url);
5224                                 $ra_invalid = undef;
5225                         }
5226                 }
5227                 # pre-fill the .rev_db since it'll eventually get filled in
5228                 # with '0' x40 if something new gets committed
5229                 foreach my $gs (@$gsv) {
5230                         next if $gs->rev_map_max >= $max;
5231                         next if defined $gs->rev_map_get($max);
5232                         $gs->rev_map_set($max, 0 x40);
5233                 }
5234                 foreach my $g (@$globs) {
5235                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5236                         Git::SVN::tmp_config($k, $max);
5237                 }
5238                 last if $max >= $head;
5239                 $min = $max + 1;
5240                 $max += $inc;
5241                 $max = $head if ($max > $head);
5242         }
5243         Git::SVN::gc();
5244 }
5245
5246 sub get_dir_globbed {
5247         my ($self, $left, $depth, $r) = @_;
5248
5249         my @x = eval { $self->get_dir($left, $r) };
5250         return unless scalar @x == 3;
5251         my $dirents = $x[0];
5252         my @finalents;
5253         foreach my $de (keys %$dirents) {
5254                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5255                 if ($depth > 1) {
5256                         my @args = ("$left/$de", $depth - 1, $r);
5257                         foreach my $dir ($self->get_dir_globbed(@args)) {
5258                                 push @finalents, "$de/$dir";
5259                         }
5260                 } else {
5261                         push @finalents, $de;
5262                 }
5263         }
5264         @finalents;
5265 }
5266
5267 sub match_globs {
5268         my ($self, $exists, $paths, $globs, $r) = @_;
5269
5270         sub get_dir_check {
5271                 my ($self, $exists, $g, $r) = @_;
5272
5273                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5274                                                   $g->{path}->{depth},
5275                                                   $r);
5276
5277                 foreach my $de (@dirs) {
5278                         my $p = $g->{path}->full_path($de);
5279                         next if $exists->{$p};
5280                         next if (length $g->{path}->{right} &&
5281                                  ($self->check_path($p, $r) !=
5282                                   $SVN::Node::dir));
5283                         next unless $p =~ /$g->{path}->{regex}/;
5284                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5285                                          $g->{ref}->full_path($de), 1);
5286                 }
5287         }
5288         foreach my $g (@$globs) {
5289                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5290                         if ($path->{action} =~ /^[AR]$/) {
5291                                 get_dir_check($self, $exists, $g, $r);
5292                         }
5293                 }
5294                 foreach (keys %$paths) {
5295                         if (/$g->{path}->{left_regex}/ &&
5296                             !/$g->{path}->{regex}/) {
5297                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5298                                 get_dir_check($self, $exists, $g, $r);
5299                         }
5300                         next unless /$g->{path}->{regex}/;
5301                         my $p = $1;
5302                         my $pathname = $g->{path}->full_path($p);
5303                         next if $exists->{$pathname};
5304                         next if ($self->check_path($pathname, $r) !=
5305                                  $SVN::Node::dir);
5306                         $exists->{$pathname} = Git::SVN->init(
5307                                               $self->{url}, $pathname, undef,
5308                                               $g->{ref}->full_path($p), 1);
5309                 }
5310                 my $c = '';
5311                 foreach (split m#/#, $g->{path}->{left}) {
5312                         $c .= "/$_";
5313                         next unless ($paths->{$c} &&
5314                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5315                         get_dir_check($self, $exists, $g, $r);
5316                 }
5317         }
5318         values %$exists;
5319 }
5320
5321 sub minimize_url {
5322         my ($self) = @_;
5323         return $self->{url} if ($self->{url} eq $self->{repos_root});
5324         my $url = $self->{repos_root};
5325         my @components = split(m!/!, $self->{svn_path});
5326         my $c = '';
5327         do {
5328                 $url .= "/$c" if length $c;
5329                 eval {
5330                         my $ra = (ref $self)->new($url);
5331                         my $latest = $ra->get_latest_revnum;
5332                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5333                 };
5334         } while ($@ && ($c = shift @components));
5335         $url;
5336 }
5337
5338 sub can_do_switch {
5339         my $self = shift;
5340         unless (defined $can_do_switch) {
5341                 my $pool = SVN::Pool->new;
5342                 my $rep = eval {
5343                         $self->do_switch(1, '', 0, $self->{url},
5344                                          SVN::Delta::Editor->new, $pool);
5345                 };
5346                 if ($@) {
5347                         $can_do_switch = 0;
5348                 } else {
5349                         $rep->abort_report($pool);
5350                         $can_do_switch = 1;
5351                 }
5352                 $pool->clear;
5353         }
5354         $can_do_switch;
5355 }
5356
5357 sub skip_unknown_revs {
5358         my ($err) = @_;
5359         my $errno = $err->apr_err();
5360         # Maybe the branch we're tracking didn't
5361         # exist when the repo started, so it's
5362         # not an error if it doesn't, just continue
5363         #
5364         # Wonderfully consistent library, eh?
5365         # 160013 - svn:// and file://
5366         # 175002 - http(s)://
5367         # 175007 - http(s):// (this repo required authorization, too...)
5368         #   More codes may be discovered later...
5369         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5370                 my $err_key = $err->expanded_message;
5371                 # revision numbers change every time, filter them out
5372                 $err_key =~ s/\d+/\0/g;
5373                 $err_key = "$errno\0$err_key";
5374                 unless ($ignored_err{$err_key}) {
5375                         warn "W: Ignoring error from SVN, path probably ",
5376                              "does not exist: ($errno): ",
5377                              $err->expanded_message,"\n";
5378                         warn "W: Do not be alarmed at the above message ",
5379                              "git-svn is just searching aggressively for ",
5380                              "old history.\n",
5381                              "This may take a while on large repositories\n";
5382                         $ignored_err{$err_key} = 1;
5383                 }
5384                 return;
5385         }
5386         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5387 }
5388
5389 package Git::SVN::Log;
5390 use strict;
5391 use warnings;
5392 use POSIX qw/strftime/;
5393 use Time::Local;
5394 use constant commit_log_separator => ('-' x 72) . "\n";
5395 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5396             %rusers $show_commit $incremental/;
5397 my $l_fmt;
5398
5399 sub cmt_showable {
5400         my ($c) = @_;
5401         return 1 if defined $c->{r};
5402
5403         # big commit message got truncated by the 16k pretty buffer in rev-list
5404         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5405                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5406                 @{$c->{l}} = ();
5407                 my @log = command(qw/cat-file commit/, $c->{c});
5408
5409                 # shift off the headers
5410                 shift @log while ($log[0] ne '');
5411                 shift @log;
5412
5413                 # TODO: make $c->{l} not have a trailing newline in the future
5414                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5415
5416                 (undef, $c->{r}, undef) = ::extract_metadata(
5417                                 (grep(/^git-svn-id: /, @log))[-1]);
5418         }
5419         return defined $c->{r};
5420 }
5421
5422 sub log_use_color {
5423         return $color || Git->repository->get_colorbool('color.diff');
5424 }
5425
5426 sub git_svn_log_cmd {
5427         my ($r_min, $r_max, @args) = @_;
5428         my $head = 'HEAD';
5429         my (@files, @log_opts);
5430         foreach my $x (@args) {
5431                 if ($x eq '--' || @files) {
5432                         push @files, $x;
5433                 } else {
5434                         if (::verify_ref("$x^0")) {
5435                                 $head = $x;
5436                         } else {
5437                                 push @log_opts, $x;
5438                         }
5439                 }
5440         }
5441
5442         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5443         $gs ||= Git::SVN->_new;
5444         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5445                    $gs->refname);
5446         push @cmd, '-r' unless $non_recursive;
5447         push @cmd, qw/--raw --name-status/ if $verbose;
5448         push @cmd, '--color' if log_use_color();
5449         push @cmd, @log_opts;
5450         if (defined $r_max && $r_max == $r_min) {
5451                 push @cmd, '--max-count=1';
5452                 if (my $c = $gs->rev_map_get($r_max)) {
5453                         push @cmd, $c;
5454                 }
5455         } elsif (defined $r_max) {
5456                 if ($r_max < $r_min) {
5457                         ($r_min, $r_max) = ($r_max, $r_min);
5458                 }
5459                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5460                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5461                 # If there are no commits in the range, both $c_max and $c_min
5462                 # will be undefined.  If there is at least 1 commit in the
5463                 # range, both will be defined.
5464                 return () if !defined $c_min || !defined $c_max;
5465                 if ($c_min eq $c_max) {
5466                         push @cmd, '--max-count=1', $c_min;
5467                 } else {
5468                         push @cmd, '--boundary', "$c_min..$c_max";
5469                 }
5470         }
5471         return (@cmd, @files);
5472 }
5473
5474 # adapted from pager.c
5475 sub config_pager {
5476         if (! -t *STDOUT) {
5477                 $ENV{GIT_PAGER_IN_USE} = 'false';
5478                 $pager = undef;
5479                 return;
5480         }
5481         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5482         if ($pager eq 'cat') {
5483                 $pager = undef;
5484         }
5485         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5486 }
5487
5488 sub run_pager {
5489         return unless defined $pager;
5490         pipe my ($rfd, $wfd) or return;
5491         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5492         if (!$pid) {
5493                 open STDOUT, '>&', $wfd or
5494                                      ::fatal "Can't redirect to stdout: $!";
5495                 return;
5496         }
5497         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5498         $ENV{LESS} ||= 'FRSX';
5499         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5500 }
5501
5502 sub format_svn_date {
5503         # some systmes don't handle or mishandle %z, so be creative.
5504         my $t = shift || time;
5505         my $gm = timelocal(gmtime($t));
5506         my $sign = qw( + + - )[ $t <=> $gm ];
5507         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5508         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5509 }
5510
5511 sub parse_git_date {
5512         my ($t, $tz) = @_;
5513         # Date::Parse isn't in the standard Perl distro :(
5514         if ($tz =~ s/^\+//) {
5515                 $t += tz_to_s_offset($tz);
5516         } elsif ($tz =~ s/^\-//) {
5517                 $t -= tz_to_s_offset($tz);
5518         }
5519         return $t;
5520 }
5521
5522 sub set_local_timezone {
5523         if (defined $TZ) {
5524                 $ENV{TZ} = $TZ;
5525         } else {
5526                 delete $ENV{TZ};
5527         }
5528 }
5529
5530 sub tz_to_s_offset {
5531         my ($tz) = @_;
5532         $tz =~ s/(\d\d)$//;
5533         return ($1 * 60) + ($tz * 3600);
5534 }
5535
5536 sub get_author_info {
5537         my ($dest, $author, $t, $tz) = @_;
5538         $author =~ s/(?:^\s*|\s*$)//g;
5539         $dest->{a_raw} = $author;
5540         my $au;
5541         if ($::_authors) {
5542                 $au = $rusers{$author} || undef;
5543         }
5544         if (!$au) {
5545                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5546         }
5547         $dest->{t} = $t;
5548         $dest->{tz} = $tz;
5549         $dest->{a} = $au;
5550         $dest->{t_utc} = parse_git_date($t, $tz);
5551 }
5552
5553 sub process_commit {
5554         my ($c, $r_min, $r_max, $defer) = @_;
5555         if (defined $r_min && defined $r_max) {
5556                 if ($r_min == $c->{r} && $r_min == $r_max) {
5557                         show_commit($c);
5558                         return 0;
5559                 }
5560                 return 1 if $r_min == $r_max;
5561                 if ($r_min < $r_max) {
5562                         # we need to reverse the print order
5563                         return 0 if (defined $limit && --$limit < 0);
5564                         push @$defer, $c;
5565                         return 1;
5566                 }
5567                 if ($r_min != $r_max) {
5568                         return 1 if ($r_min < $c->{r});
5569                         return 1 if ($r_max > $c->{r});
5570                 }
5571         }
5572         return 0 if (defined $limit && --$limit < 0);
5573         show_commit($c);
5574         return 1;
5575 }
5576
5577 sub show_commit {
5578         my $c = shift;
5579         if ($oneline) {
5580                 my $x = "\n";
5581                 if (my $l = $c->{l}) {
5582                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5583                         $x = $l->[0];
5584                 }
5585                 $l_fmt ||= 'A' . length($c->{r});
5586                 print 'r',pack($l_fmt, $c->{r}),' | ';
5587                 print "$c->{c} | " if $show_commit;
5588                 print $x;
5589         } else {
5590                 show_commit_normal($c);
5591         }
5592 }
5593
5594 sub show_commit_changed_paths {
5595         my ($c) = @_;
5596         return unless $c->{changed};
5597         print "Changed paths:\n", @{$c->{changed}};
5598 }
5599
5600 sub show_commit_normal {
5601         my ($c) = @_;
5602         print commit_log_separator, "r$c->{r} | ";
5603         print "$c->{c} | " if $show_commit;
5604         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5605         my $nr_line = 0;
5606
5607         if (my $l = $c->{l}) {
5608                 while ($l->[$#$l] eq "\n" && $#$l > 0
5609                                           && $l->[($#$l - 1)] eq "\n") {
5610                         pop @$l;
5611                 }
5612                 $nr_line = scalar @$l;
5613                 if (!$nr_line) {
5614                         print "1 line\n\n\n";
5615                 } else {
5616                         if ($nr_line == 1) {
5617                                 $nr_line = '1 line';
5618                         } else {
5619                                 $nr_line .= ' lines';
5620                         }
5621                         print $nr_line, "\n";
5622                         show_commit_changed_paths($c);
5623                         print "\n";
5624                         print $_ foreach @$l;
5625                 }
5626         } else {
5627                 print "1 line\n";
5628                 show_commit_changed_paths($c);
5629                 print "\n";
5630
5631         }
5632         foreach my $x (qw/raw stat diff/) {
5633                 if ($c->{$x}) {
5634                         print "\n";
5635                         print $_ foreach @{$c->{$x}}
5636                 }
5637         }
5638 }
5639
5640 sub cmd_show_log {
5641         my (@args) = @_;
5642         my ($r_min, $r_max);
5643         my $r_last = -1; # prevent dupes
5644         set_local_timezone();
5645         if (defined $::_revision) {
5646                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5647                         ($r_min, $r_max) = ($1, $2);
5648                 } elsif ($::_revision =~ /^\d+$/) {
5649                         $r_min = $r_max = $::_revision;
5650                 } else {
5651                         ::fatal "-r$::_revision is not supported, use ",
5652                                 "standard 'git log' arguments instead";
5653                 }
5654         }
5655
5656         config_pager();
5657         @args = git_svn_log_cmd($r_min, $r_max, @args);
5658         if (!@args) {
5659                 print commit_log_separator unless $incremental || $oneline;
5660                 return;
5661         }
5662         my $log = command_output_pipe(@args);
5663         run_pager();
5664         my (@k, $c, $d, $stat);
5665         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5666         while (<$log>) {
5667                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5668                         my $cmt = $1;
5669                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5670                                 $r_last = $c->{r};
5671                                 process_commit($c, $r_min, $r_max, \@k) or
5672                                                                 goto out;
5673                         }
5674                         $d = undef;
5675                         $c = { c => $cmt };
5676                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5677                         get_author_info($c, $1, $2, $3);
5678                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5679                         # ignore
5680                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5681                         push @{$c->{raw}}, $_;
5682                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5683                         # we could add $SVN->{svn_path} here, but that requires
5684                         # remote access at the moment (repo_path_split)...
5685                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5686                         push @{$c->{changed}}, $_;
5687                 } elsif (/^${esc_color}diff /o) {
5688                         $d = 1;
5689                         push @{$c->{diff}}, $_;
5690                 } elsif ($d) {
5691                         push @{$c->{diff}}, $_;
5692                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5693                           $esc_color*[\+\-]*$esc_color$/x) {
5694                         $stat = 1;
5695                         push @{$c->{stat}}, $_;
5696                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5697                         push @{$c->{stat}}, $_;
5698                         $stat = undef;
5699                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5700                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5701                 } elsif (s/^${esc_color}    //o) {
5702                         push @{$c->{l}}, $_;
5703                 }
5704         }
5705         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5706                 $r_last = $c->{r};
5707                 process_commit($c, $r_min, $r_max, \@k);
5708         }
5709         if (@k) {
5710                 ($r_min, $r_max) = ($r_max, $r_min);
5711                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5712         }
5713 out:
5714         close $log;
5715         print commit_log_separator unless $incremental || $oneline;
5716 }
5717
5718 sub cmd_blame {
5719         my $path = pop;
5720
5721         config_pager();
5722         run_pager();
5723
5724         my ($fh, $ctx, $rev);
5725
5726         if ($_git_format) {
5727                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5728                 while (my $line = <$fh>) {
5729                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5730                                 # Uncommitted edits show up as a rev ID of
5731                                 # all zeros, which we can't look up with
5732                                 # cmt_metadata
5733                                 if ($1 !~ /^0+$/) {
5734                                         (undef, $rev, undef) =
5735                                                 ::cmt_metadata($1);
5736                                         $rev = '0' if (!$rev);
5737                                 } else {
5738                                         $rev = '0';
5739                                 }
5740                                 $rev = sprintf('%-10s', $rev);
5741                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5742                         }
5743                         print $line;
5744                 }
5745         } else {
5746                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5747                                                   '--', $path);
5748                 my ($sha1);
5749                 my %authors;
5750                 my @buffer;
5751                 my %dsha; #distinct sha keys
5752
5753                 while (my $line = <$fh>) {
5754                         push @buffer, $line;
5755                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5756                                 $dsha{$1} = 1;
5757                         }
5758                 }
5759
5760                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5761
5762                 foreach my $line (@buffer) {
5763                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5764                                 $rev = $s2r->{$1};
5765                                 $rev = '0' if (!$rev)
5766                         }
5767                         elsif ($line =~ /^author (.*)/) {
5768                                 $authors{$rev} = $1;
5769                                 $authors{$rev} =~ s/\s/_/g;
5770                         }
5771                         elsif ($line =~ /^\t(.*)$/) {
5772                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5773                         }
5774                 }
5775         }
5776         command_close_pipe($fh, $ctx);
5777 }
5778
5779 package Git::SVN::Migration;
5780 # these version numbers do NOT correspond to actual version numbers
5781 # of git nor git-svn.  They are just relative.
5782 #
5783 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5784 #
5785 # v1 layout: .git/$id/info/url, refs/remotes/$id
5786 #
5787 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5788 #
5789 # v3 layout: .git/svn/$id, refs/remotes/$id
5790 #            - info/url may remain for backwards compatibility
5791 #            - this is what we migrate up to this layout automatically,
5792 #            - this will be used by git svn init on single branches
5793 # v3.1 layout (auto migrated):
5794 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5795 #              for backwards compatibility
5796 #
5797 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5798 #            - this is only created for newly multi-init-ed
5799 #              repositories.  Similar in spirit to the
5800 #              --use-separate-remotes option in git-clone (now default)
5801 #            - we do not automatically migrate to this (following
5802 #              the example set by core git)
5803 #
5804 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5805 #            - newer, more-efficient format that uses 24-bytes per record
5806 #              with no filler space.
5807 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5808 #            - This is a one-way migration, repositories updated to the
5809 #              new format will not be able to use old git-svn without
5810 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5811 #              possible if noMetadata or useSvmProps are set; but should
5812 #              be no problem for users that use the (sensible) defaults.
5813 use strict;
5814 use warnings;
5815 use Carp qw/croak/;
5816 use File::Path qw/mkpath/;
5817 use File::Basename qw/dirname basename/;
5818 use vars qw/$_minimize/;
5819
5820 sub migrate_from_v0 {
5821         my $git_dir = $ENV{GIT_DIR};
5822         return undef unless -d $git_dir;
5823         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5824         my $migrated = 0;
5825         while (<$fh>) {
5826                 chomp;
5827                 my ($id, $orig_ref) = ($_, $_);
5828                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5829                 next unless -f "$git_dir/$id/info/url";
5830                 my $new_ref = "refs/remotes/$id";
5831                 if (::verify_ref("$new_ref^0")) {
5832                         print STDERR "W: $orig_ref is probably an old ",
5833                                      "branch used by an ancient version of ",
5834                                      "git-svn.\n",
5835                                      "However, $new_ref also exists.\n",
5836                                      "We will not be able ",
5837                                      "to use this branch until this ",
5838                                      "ambiguity is resolved.\n";
5839                         next;
5840                 }
5841                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5842                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5843                 command_noisy('update-ref', $new_ref, $orig_ref);
5844                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5845                 $migrated++;
5846         }
5847         command_close_pipe($fh, $ctx);
5848         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5849         $migrated;
5850 }
5851
5852 sub migrate_from_v1 {
5853         my $git_dir = $ENV{GIT_DIR};
5854         my $migrated = 0;
5855         return $migrated unless -d $git_dir;
5856         my $svn_dir = "$git_dir/svn";
5857
5858         # just in case somebody used 'svn' as their $id at some point...
5859         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5860
5861         print STDERR "Migrating from a git-svn v1 layout...\n";
5862         mkpath([$svn_dir]);
5863         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5864                      "$svn_dir\n\t(required for this version ",
5865                      "($::VERSION) of git-svn) does not exist.\n";
5866         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5867         while (<$fh>) {
5868                 my $x = $_;
5869                 next unless $x =~ s#^refs/remotes/##;
5870                 chomp $x;
5871                 next unless -f "$git_dir/$x/info/url";
5872                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5873                 next unless $u;
5874                 my $dn = dirname("$git_dir/svn/$x");
5875                 mkpath([$dn]) unless -d $dn;
5876                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5877                         mkpath(["$git_dir/svn/svn"]);
5878                         print STDERR " - $git_dir/$x/info => ",
5879                                         "$git_dir/svn/$x/info\n";
5880                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5881                                croak "$!: $x";
5882                         # don't worry too much about these, they probably
5883                         # don't exist with repos this old (save for index,
5884                         # and we can easily regenerate that)
5885                         foreach my $f (qw/unhandled.log index .rev_db/) {
5886                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5887                         }
5888                 } else {
5889                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5890                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5891                                croak "$!: $x";
5892                 }
5893                 $migrated++;
5894         }
5895         command_close_pipe($fh, $ctx);
5896         print STDERR "Done migrating from a git-svn v1 layout\n";
5897         $migrated;
5898 }
5899
5900 sub read_old_urls {
5901         my ($l_map, $pfx, $path) = @_;
5902         my @dir;
5903         foreach (<$path/*>) {
5904                 if (-r "$_/info/url") {
5905                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5906                         my $ref_id = $pfx . basename $_;
5907                         my $url = ::file_to_s("$_/info/url");
5908                         $l_map->{$ref_id} = $url;
5909                 } elsif (-d $_) {
5910                         push @dir, $_;
5911                 }
5912         }
5913         foreach (@dir) {
5914                 my $x = $_;
5915                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5916                 read_old_urls($l_map, $x, $_);
5917         }
5918 }
5919
5920 sub migrate_from_v2 {
5921         my @cfg = command(qw/config -l/);
5922         return if grep /^svn-remote\..+\.url=/, @cfg;
5923         my %l_map;
5924         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5925         my $migrated = 0;
5926
5927         foreach my $ref_id (sort keys %l_map) {
5928                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5929                 if ($@) {
5930                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5931                 }
5932                 $migrated++;
5933         }
5934         $migrated;
5935 }
5936
5937 sub minimize_connections {
5938         my $r = Git::SVN::read_all_remotes();
5939         my $new_urls = {};
5940         my $root_repos = {};
5941         foreach my $repo_id (keys %$r) {
5942                 my $url = $r->{$repo_id}->{url} or next;
5943                 my $fetch = $r->{$repo_id}->{fetch} or next;
5944                 my $ra = Git::SVN::Ra->new($url);
5945
5946                 # skip existing cases where we already connect to the root
5947                 if (($ra->{url} eq $ra->{repos_root}) ||
5948                     ($ra->{repos_root} eq $repo_id)) {
5949                         $root_repos->{$ra->{url}} = $repo_id;
5950                         next;
5951                 }
5952
5953                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5954                 my $root_path = $ra->{url};
5955                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5956                 foreach my $path (keys %$fetch) {
5957                         my $ref_id = $fetch->{$path};
5958                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5959
5960                         # make sure we can read when connecting to
5961                         # a higher level of a repository
5962                         my ($last_rev, undef) = $gs->last_rev_commit;
5963                         if (!defined $last_rev) {
5964                                 $last_rev = eval {
5965                                         $root_ra->get_latest_revnum;
5966                                 };
5967                                 next if $@;
5968                         }
5969                         my $new = $root_path;
5970                         $new .= length $path ? "/$path" : '';
5971                         eval {
5972                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5973                                                   0, 0, 1, sub { });
5974                         };
5975                         next if $@;
5976                         $new_urls->{$ra->{repos_root}}->{$new} =
5977                                 { ref_id => $ref_id,
5978                                   old_repo_id => $repo_id,
5979                                   old_path => $path };
5980                 }
5981         }
5982
5983         my @emptied;
5984         foreach my $url (keys %$new_urls) {
5985                 # see if we can re-use an existing [svn-remote "repo_id"]
5986                 # instead of creating a(n ugly) new section:
5987                 my $repo_id = $root_repos->{$url} || $url;
5988
5989                 my $fetch = $new_urls->{$url};
5990                 foreach my $path (keys %$fetch) {
5991                         my $x = $fetch->{$path};
5992                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5993                         my $pfx = "svn-remote.$x->{old_repo_id}";
5994
5995                         my $old_fetch = quotemeta("$x->{old_path}:".
5996                                                   "$x->{ref_id}");
5997                         command_noisy(qw/config --unset/,
5998                                       "$pfx.fetch", '^'. $old_fetch . '$');
5999                         delete $r->{$x->{old_repo_id}}->
6000                                {fetch}->{$x->{old_path}};
6001                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6002                                 command_noisy(qw/config --unset/,
6003                                               "$pfx.url");
6004                                 push @emptied, $x->{old_repo_id}
6005                         }
6006                 }
6007         }
6008         if (@emptied) {
6009                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6010                 print STDERR <<EOF;
6011 The following [svn-remote] sections in your config file ($file) are empty
6012 and can be safely removed:
6013 EOF
6014                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6015         }
6016 }
6017
6018 sub migration_check {
6019         migrate_from_v0();
6020         migrate_from_v1();
6021         migrate_from_v2();
6022         minimize_connections() if $_minimize;
6023 }
6024
6025 package Git::IndexInfo;
6026 use strict;
6027 use warnings;
6028 use Git qw/command_input_pipe command_close_pipe/;
6029
6030 sub new {
6031         my ($class) = @_;
6032         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6033         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6034 }
6035
6036 sub remove {
6037         my ($self, $path) = @_;
6038         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6039                 return ++$self->{nr};
6040         }
6041         undef;
6042 }
6043
6044 sub update {
6045         my ($self, $mode, $hash, $path) = @_;
6046         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6047                 return ++$self->{nr};
6048         }
6049         undef;
6050 }
6051
6052 sub DESTROY {
6053         my ($self) = @_;
6054         command_close_pipe($self->{gui}, $self->{ctx});
6055 }
6056
6057 package Git::SVN::GlobSpec;
6058 use strict;
6059 use warnings;
6060
6061 sub new {
6062         my ($class, $glob, $pattern_ok) = @_;
6063         my $re = $glob;
6064         $re =~ s!/+$!!g; # no need for trailing slashes
6065         my (@left, @right, @patterns);
6066         my $state = "left";
6067         my $die_msg = "Only one set of wildcard directories " .
6068                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6069         for my $part (split(m|/|, $glob)) {
6070                 if ($part =~ /\*/ && $part ne "*") {
6071                         die "Invalid pattern in '$glob': $part\n";
6072                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6073                          $part !~ /^\{[^{}]+\}/) {
6074                         die "Invalid pattern in '$glob': $part\n";
6075                 }
6076                 if ($part eq "*") {
6077                         die $die_msg if $state eq "right";
6078                         $state = "pattern";
6079                         push(@patterns, "[^/]*");
6080                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6081                         die $die_msg if $state eq "right";
6082                         $state = "pattern";
6083                         my $p = quotemeta($1);
6084                         $p =~ s/\\,/|/g;
6085                         push(@patterns, "(?:$p)");
6086                 } else {
6087                         if ($state eq "left") {
6088                                 push(@left, $part);
6089                         } else {
6090                                 push(@right, $part);
6091                                 $state = "right";
6092                         }
6093                 }
6094         }
6095         my $depth = @patterns;
6096         if ($depth == 0) {
6097                 die "One '*' is needed in glob: '$glob'\n";
6098         }
6099         my $left = join('/', @left);
6100         my $right = join('/', @right);
6101         $re = join('/', @patterns);
6102         $re = join('\/',
6103                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6104         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6105         bless { left => $left, right => $right, left_regex => $left_re,
6106                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6107 }
6108
6109 sub full_path {
6110         my ($self, $path) = @_;
6111         return (length $self->{left} ? "$self->{left}/" : '') .
6112                $path . (length $self->{right} ? "/$self->{right}" : '');
6113 }
6114
6115 __END__
6116
6117 Data structures:
6118
6119
6120 $remotes = { # returned by read_all_remotes()
6121         'svn' => {
6122                 # svn-remote.svn.url=https://svn.musicpd.org
6123                 url => 'https://svn.musicpd.org',
6124                 # svn-remote.svn.fetch=mpd/trunk:trunk
6125                 fetch => {
6126                         'mpd/trunk' => 'trunk',
6127                 },
6128                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6129                 tags => {
6130                         path => {
6131                                 left => 'mpd/tags',
6132                                 right => '',
6133                                 regex => qr!mpd/tags/([^/]+)$!,
6134                                 glob => 'tags/*',
6135                         },
6136                         ref => {
6137                                 left => 'tags',
6138                                 right => '',
6139                                 regex => qr!tags/([^/]+)$!,
6140                                 glob => 'tags/*',
6141                         },
6142                 }
6143         }
6144 };
6145
6146 $log_entry hashref as returned by libsvn_log_entry()
6147 {
6148         log => 'whitespace-formatted log entry
6149 ',                                              # trailing newline is preserved
6150         revision => '8',                        # integer
6151         date => '2004-02-24T17:01:44.108345Z',  # commit date
6152         author => 'committer name'
6153 };
6154
6155
6156 # this is generated by generate_diff();
6157 @mods = array of diff-index line hashes, each element represents one line
6158         of diff-index output
6159
6160 diff-index line ($m hash)
6161 {
6162         mode_a => first column of diff-index output, no leading ':',
6163         mode_b => second column of diff-index output,
6164         sha1_b => sha1sum of the final blob,
6165         chg => change type [MCRADT],
6166         file_a => original file name of a file (iff chg is 'C' or 'R')
6167         file_b => new/current file name of a file (any chg)
6168 }
6169 ;
6170
6171 # retval of read_url_paths{,_all}();
6172 $l_map = {
6173         # repository root url
6174         'https://svn.musicpd.org' => {
6175                 # repository path               # GIT_SVN_ID
6176                 'mpd/trunk'             =>      'trunk',
6177                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6178         },
6179 }
6180
6181 Notes:
6182         I don't trust the each() function on unless I created %hash myself
6183         because the internal iterator may not have started at base.