git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22
  23 $Git::SVN::Log::TZ = $ENV{TZ};
  24 $ENV{TZ} = 'UTC';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use Digest::MD5;
  39 use IO::File qw//;
  40 use File::Basename qw/dirname basename/;
  41 use File::Path qw/mkpath/;
  42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43 use IPC::Open3;
  44 use Git;
  45
  46 BEGIN {
  47         # import functions from Git into our packages, en masse
  48         no strict 'refs';
  49         foreach (qw/command command_oneline command_noisy command_output_pipe
  50                     command_input_pipe command_close_pipe/) {
  51                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                         __PACKAGE__) {
  54                         *{"${package}::$_"} = \&{"Git::$_"};
  55                 }
  56         }
  57 }
  58
  59 my ($SVN);
  60
  61 $sha1 = qr/[a-f\d]{40}/;
  62 $sha1_short = qr/[a-f\d]{4,40}/;
  63 my ($_stdin, $_help, $_edit,
  64         $_message, $_file,
  65         $_template, $_shared,
  66         $_version, $_fetch_all, $_no_rebase,
  67         $_merge, $_strategy, $_dry_run, $_local,
  68         $_prefix, $_no_checkout, $_url, $_verbose);
  69 $Git::SVN::_follow_parent = 1;
  70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  71                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  72                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  74                 'authors-file|A=s' => \$_authors,
  75                 'repack:i' => \$Git::SVN::_repack,
  76                 'noMetadata' => \$Git::SVN::_no_metadata,
  77                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  78                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  79                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  80                 'no-checkout' => \$_no_checkout,
  81                 'quiet|q' => \$_q,
  82                 'repack-flags|repack-args|repack-opts=s' =>
  83                    \$Git::SVN::_repack_flags,
  84                 'use-log-author' => \$Git::SVN::_use_log_author,
  85                 %remote_opts );
  86
  87 my ($_trunk, $_tags, $_branches, $_stdlayout);
  88 my %icv;
  89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  90                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  91                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  92                   'stdlayout|s' => \$_stdlayout,
  93                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  94                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  95                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  96                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  97                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  98                   %remote_opts );
  99 my %cmt_opts = ( 'edit|e' => \$_edit,
 100                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 101                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 102                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 103                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 104 );
 105
 106 my %cmd = (
 107         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 108                         { 'revision|r=s' => \$_revision,
 109                           'fetch-all|all' => \$_fetch_all,
 110                            %fc_opts } ],
 111         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 112                         { 'revision|r=s' => \$_revision,
 113                            %fc_opts, %init_opts } ],
 114         init => [ \&cmd_init, "Initialize a repo for tracking" .
 115                           " (requires URL argument)",
 116                           \%init_opts ],
 117         'multi-init' => [ \&cmd_multi_init,
 118                           "Deprecated alias for ".
 119                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 120                           \%init_opts ],
 121         dcommit => [ \&cmd_dcommit,
 122                      'Commit several diffs to merge with upstream',
 123                         { 'merge|m|M' => \$_merge,
 124                           'strategy|s=s' => \$_strategy,
 125                           'verbose|v' => \$_verbose,
 126                           'dry-run|n' => \$_dry_run,
 127                           'fetch-all|all' => \$_fetch_all,
 128                           'no-rebase' => \$_no_rebase,
 129                         %cmt_opts, %fc_opts } ],
 130         'set-tree' => [ \&cmd_set_tree,
 131                         "Set an SVN repository to a git tree-ish",
 132                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 133         'create-ignore' => [ \&cmd_create_ignore,
 134                              'Create a .gitignore per svn:ignore',
 135                              { 'revision|r=i' => \$_revision
 136                              } ],
 137         'propget' => [ \&cmd_propget,
 138                        'Print the value of a property on a file or directory',
 139                        { 'revision|r=i' => \$_revision } ],
 140         'proplist' => [ \&cmd_proplist,
 141                        'List all properties of a file or directory',
 142                        { 'revision|r=i' => \$_revision } ],
 143         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 144                         { 'revision|r=i' => \$_revision
 145                         } ],
 146         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 147                         { 'revision|r=i' => \$_revision
 148                         } ],
 149         'multi-fetch' => [ \&cmd_multi_fetch,
 150                            "Deprecated alias for $0 fetch --all",
 151                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 152         'migrate' => [ sub { },
 153                        # no-op, we automatically run this anyways,
 154                        'Migrate configuration/metadata/layout from
 155                         previous versions of git-svn',
 156                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 157                          %remote_opts } ],
 158         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 159                         { 'limit=i' => \$Git::SVN::Log::limit,
 160                           'revision|r=s' => \$_revision,
 161                           'verbose|v' => \$Git::SVN::Log::verbose,
 162                           'incremental' => \$Git::SVN::Log::incremental,
 163                           'oneline' => \$Git::SVN::Log::oneline,
 164                           'show-commit' => \$Git::SVN::Log::show_commit,
 165                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 166                           'authors-file|A=s' => \$_authors,
 167                           'color' => \$Git::SVN::Log::color,
 168                           'pager=s' => \$Git::SVN::Log::pager
 169                         } ],
 170         'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
 171                         {} ],
 172         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 173                         { 'merge|m|M' => \$_merge,
 174                           'verbose|v' => \$_verbose,
 175                           'strategy|s=s' => \$_strategy,
 176                           'local|l' => \$_local,
 177                           'fetch-all|all' => \$_fetch_all,
 178                           %fc_opts } ],
 179         'commit-diff' => [ \&cmd_commit_diff,
 180                            'Commit a diff between two trees',
 181                         { 'message|m=s' => \$_message,
 182                           'file|F=s' => \$_file,
 183                           'revision|r=s' => \$_revision,
 184                         %cmt_opts } ],
 185         'info' => [ \&cmd_info,
 186                     "Show info about the latest SVN revision
 187                      on the current branch",
 188                     { 'url' => \$_url, } ],
 189         'blame' => [ \&Git::SVN::Log::cmd_blame,
 190                     "Show what revision and author last modified each line of a file",
 191                     {} ],
 192 );
 193
 194 my $cmd;
 195 for (my $i = 0; $i < @ARGV; $i++) {
 196         if (defined $cmd{$ARGV[$i]}) {
 197                 $cmd = $ARGV[$i];
 198                 splice @ARGV, $i, 1;
 199                 last;
 200         }
 201 };
 202
 203 # make sure we're always running at the top-level working directory
 204 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 205         unless (-d $ENV{GIT_DIR}) {
 206                 if ($git_dir_user_set) {
 207                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 208                             "but it is not a directory\n";
 209                 }
 210                 my $git_dir = delete $ENV{GIT_DIR};
 211                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 212                 unless (length $cdup) {
 213                         die "Already at toplevel, but $git_dir ",
 214                             "not found '$cdup'\n";
 215                 }
 216                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 217                 unless (-d $git_dir) {
 218                         die "$git_dir still not found after going to ",
 219                             "'$cdup'\n";
 220                 }
 221                 $ENV{GIT_DIR} = $git_dir;
 222         }
 223 }
 224
 225 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 226
 227 read_repo_config(\%opts);
 228 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 229 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 230                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 231                     'id|i=s' => \$Git::SVN::default_ref_id,
 232                     'svn-remote|remote|R=s' => sub {
 233                        $Git::SVN::no_reuse_existing = 1;
 234                        $Git::SVN::default_repo_id = $_[1] });
 235 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 236
 237 usage(0) if $_help;
 238 version() if $_version;
 239 usage(1) unless defined $cmd;
 240 load_authors() if $_authors;
 241
 242 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 243         Git::SVN::Migration::migration_check();
 244 }
 245 Git::SVN::init_vars();
 246 eval {
 247         Git::SVN::verify_remotes_sanity();
 248         $cmd{$cmd}->[0]->(@ARGV);
 249 };
 250 fatal $@ if $@;
 251 post_fetch_checkout();
 252 exit 0;
 253
 254 ####################### primary functions ######################
 255 sub usage {
 256         my $exit = shift || 0;
 257         my $fd = $exit ? \*STDERR : \*STDOUT;
 258         print $fd <<"";
 259 git-svn - bidirectional operations between a single Subversion tree and git
 260 Usage: $0 <command> [options] [arguments]\n
 261
 262         print $fd "Available commands:\n" unless $cmd;
 263
 264         foreach (sort keys %cmd) {
 265                 next if $cmd && $cmd ne $_;
 266                 next if /^multi-/; # don't show deprecated commands
 267                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 268                 foreach (sort keys %{$cmd{$_}->[2]}) {
 269                         # mixed-case options are for .git/config only
 270                         next if /[A-Z]/ && /^[a-z]+$/i;
 271                         # prints out arguments as they should be passed:
 272                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 273                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 274                                                         "--$_" : "-$_" }
 275                                                 split /\|/,$_)," $x\n";
 276                 }
 277         }
 278         print $fd <<"";
 279 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 280 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 281 one git repository and want to keep them separate.  See git-svn(1) for more
 282 information.
 283
 284         exit $exit;
 285 }
 286
 287 sub version {
 288         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 289         exit 0;
 290 }
 291
 292 sub do_git_init_db {
 293         unless (-d $ENV{GIT_DIR}) {
 294                 my @init_db = ('init');
 295                 push @init_db, "--template=$_template" if defined $_template;
 296                 if (defined $_shared) {
 297                         if ($_shared =~ /[a-z]/) {
 298                                 push @init_db, "--shared=$_shared";
 299                         } else {
 300                                 push @init_db, "--shared";
 301                         }
 302                 }
 303                 command_noisy(@init_db);
 304         }
 305         my $set;
 306         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 307         foreach my $i (keys %icv) {
 308                 die "'$set' and '$i' cannot both be set\n" if $set;
 309                 next unless defined $icv{$i};
 310                 command_noisy('config', "$pfx.$i", $icv{$i});
 311                 $set = $i;
 312         }
 313 }
 314
 315 sub init_subdir {
 316         my $repo_path = shift or return;
 317         mkpath([$repo_path]) unless -d $repo_path;
 318         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 319         $ENV{GIT_DIR} = '.git';
 320 }
 321
 322 sub cmd_clone {
 323         my ($url, $path) = @_;
 324         if (!defined $path &&
 325             (defined $_trunk || defined $_branches || defined $_tags ||
 326              defined $_stdlayout) &&
 327             $url !~ m#^[a-z\+]+://#) {
 328                 $path = $url;
 329         }
 330         $path = basename($url) if !defined $path || !length $path;
 331         cmd_init($url, $path);
 332         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 333 }
 334
 335 sub cmd_init {
 336         if (defined $_stdlayout) {
 337                 $_trunk = 'trunk' if (!defined $_trunk);
 338                 $_tags = 'tags' if (!defined $_tags);
 339                 $_branches = 'branches' if (!defined $_branches);
 340         }
 341         if (defined $_trunk || defined $_branches || defined $_tags) {
 342                 return cmd_multi_init(@_);
 343         }
 344         my $url = shift or die "SVN repository location required ",
 345                                "as a command-line argument\n";
 346         init_subdir(@_);
 347         do_git_init_db();
 348
 349         Git::SVN->init($url);
 350 }
 351
 352 sub cmd_fetch {
 353         if (grep /^\d+=./, @_) {
 354                 die "'<rev>=<commit>' fetch arguments are ",
 355                     "no longer supported.\n";
 356         }
 357         my ($remote) = @_;
 358         if (@_ > 1) {
 359                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 360         }
 361         $remote ||= $Git::SVN::default_repo_id;
 362         if ($_fetch_all) {
 363                 cmd_multi_fetch();
 364         } else {
 365                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 366         }
 367 }
 368
 369 sub cmd_set_tree {
 370         my (@commits) = @_;
 371         if ($_stdin || !@commits) {
 372                 print "Reading from stdin...\n";
 373                 @commits = ();
 374                 while (<STDIN>) {
 375                         if (/\b($sha1_short)\b/o) {
 376                                 unshift @commits, $1;
 377                         }
 378                 }
 379         }
 380         my @revs;
 381         foreach my $c (@commits) {
 382                 my @tmp = command('rev-parse',$c);
 383                 if (scalar @tmp == 1) {
 384                         push @revs, $tmp[0];
 385                 } elsif (scalar @tmp > 1) {
 386                         push @revs, reverse(command('rev-list',@tmp));
 387                 } else {
 388                         fatal "Failed to rev-parse $c";
 389                 }
 390         }
 391         my $gs = Git::SVN->new;
 392         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 393         $gs->fetch;
 394         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 395                 fatal "There are new revisions that were fetched ",
 396                       "and need to be merged (or acknowledged) ",
 397                       "before committing.\nlast rev: $r_last\n",
 398                       " current: $gs->{last_rev}";
 399         }
 400         $gs->set_tree($_) foreach @revs;
 401         print "Done committing ",scalar @revs," revisions to SVN\n";
 402         unlink $gs->{index};
 403 }
 404
 405 sub cmd_dcommit {
 406         my $head = shift;
 407         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 408                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 409                 . "or stash them with `git stash'.\n";
 410         $head ||= 'HEAD';
 411         my @refs;
 412         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 413         print "Committing to $url ...\n";
 414         unless ($gs) {
 415                 die "Unable to determine upstream SVN information from ",
 416                     "$head history\n";
 417         }
 418         my $last_rev;
 419         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 420         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 421                 warn "Attempting to commit more than one change while ",
 422                      "--no-rebase is enabled.\n",
 423                      "If these changes depend on each other, re-running ",
 424                      "without --no-rebase may be required."
 425         }
 426         while (1) {
 427                 my $d = shift @$linear_refs or last;
 428                 unless (defined $last_rev) {
 429                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 430                         unless (defined $last_rev) {
 431                                 fatal "Unable to extract revision information ",
 432                                       "from commit $d~1";
 433                         }
 434                 }
 435                 if ($_dry_run) {
 436                         print "diff-tree $d~1 $d\n";
 437                 } else {
 438                         my $cmt_rev;
 439                         my %ed_opts = ( r => $last_rev,
 440                                         log => get_commit_entry($d)->{log},
 441                                         ra => Git::SVN::Ra->new($gs->full_url),
 442                                         config => SVN::Core::config_get_config(
 443                                                 $Git::SVN::Ra::config_dir
 444                                         ),
 445                                         tree_a => "$d~1",
 446                                         tree_b => $d,
 447                                         editor_cb => sub {
 448                                                print "Committed r$_[0]\n";
 449                                                $cmt_rev = $_[0];
 450                                         },
 451                                         svn_path => '');
 452                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 453                                 print "No changes\n$d~1 == $d\n";
 454                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 455                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 456                                                                $parents->{$d};
 457                         }
 458                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 459                         $last_rev = $cmt_rev;
 460                         next if $_no_rebase;
 461
 462                         # we always want to rebase against the current HEAD,
 463                         # not any head that was passed to us
 464                         my @diff = command('diff-tree', $d,
 465                                            $gs->refname, '--');
 466                         my @finish;
 467                         if (@diff) {
 468                                 @finish = rebase_cmd();
 469                                 print STDERR "W: $d and ", $gs->refname,
 470                                              " differ, using @finish:\n",
 471                                              join("\n", @diff), "\n";
 472                         } else {
 473                                 print "No changes between current HEAD and ",
 474                                       $gs->refname,
 475                                       "\nResetting to the latest ",
 476                                       $gs->refname, "\n";
 477                                 @finish = qw/reset --mixed/;
 478                         }
 479                         command_noisy(@finish, $gs->refname);
 480                         if (@diff) {
 481                                 @refs = ();
 482                                 my ($url_, $rev_, $uuid_, $gs_) =
 483                                               working_head_info($head, \@refs);
 484                                 my ($linear_refs_, $parents_) =
 485                                               linearize_history($gs_, \@refs);
 486                                 if (scalar(@$linear_refs) !=
 487                                     scalar(@$linear_refs_)) {
 488                                         fatal "# of revisions changed ",
 489                                           "\nbefore:\n",
 490                                           join("\n", @$linear_refs),
 491                                           "\n\nafter:\n",
 492                                           join("\n", @$linear_refs_), "\n",
 493                                           'If you are attempting to commit ',
 494                                           "merges, try running:\n\t",
 495                                           'git rebase --interactive',
 496                                           '--preserve-merges ',
 497                                           $gs->refname,
 498                                           "\nBefore dcommitting";
 499                                 }
 500                                 if ($url_ ne $url) {
 501                                         fatal "URL mismatch after rebase: ",
 502                                               "$url_ != $url";
 503                                 }
 504                                 if ($uuid_ ne $uuid) {
 505                                         fatal "uuid mismatch after rebase: ",
 506                                               "$uuid_ != $uuid";
 507                                 }
 508                                 # remap parents
 509                                 my (%p, @l, $i);
 510                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 511                                         my $new = $linear_refs_->[$i] or next;
 512                                         $p{$new} =
 513                                                 $parents->{$linear_refs->[$i]};
 514                                         push @l, $new;
 515                                 }
 516                                 $parents = \%p;
 517                                 $linear_refs = \@l;
 518                         }
 519                 }
 520         }
 521         unlink $gs->{index};
 522 }
 523
 524 sub cmd_find_rev {
 525         my $revision_or_hash = shift;
 526         my $result;
 527         if ($revision_or_hash =~ /^r\d+$/) {
 528                 my $head = shift;
 529                 $head ||= 'HEAD';
 530                 my @refs;
 531                 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
 532                 unless ($gs) {
 533                         die "Unable to determine upstream SVN information from ",
 534                             "$head history\n";
 535                 }
 536                 my $desired_revision = substr($revision_or_hash, 1);
 537                 $result = $gs->rev_map_get($desired_revision);
 538         } else {
 539                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 540                 $result = $rev;
 541         }
 542         print "$result\n" if $result;
 543 }
 544
 545 sub cmd_rebase {
 546         command_noisy(qw/update-index --refresh/);
 547         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 548         unless ($gs) {
 549                 die "Unable to determine upstream SVN information from ",
 550                     "working tree history\n";
 551         }
 552         if (command(qw/diff-index HEAD --/)) {
 553                 print STDERR "Cannot rebase with uncommited changes:\n";
 554                 command_noisy('status');
 555                 exit 1;
 556         }
 557         unless ($_local) {
 558                 # rebase will checkout for us, so no need to do it explicitly
 559                 $_no_checkout = 'true';
 560                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 561         }
 562         command_noisy(rebase_cmd(), $gs->refname);
 563 }
 564
 565 sub cmd_show_ignore {
 566         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 567         $gs ||= Git::SVN->new;
 568         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 569         $gs->prop_walk($gs->{path}, $r, sub {
 570                 my ($gs, $path, $props) = @_;
 571                 print STDOUT "\n# $path\n";
 572                 my $s = $props->{'svn:ignore'} or return;
 573                 $s =~ s/[\r\n]+/\n/g;
 574                 chomp $s;
 575                 $s =~ s#^#$path#gm;
 576                 print STDOUT "$s\n";
 577         });
 578 }
 579
 580 sub cmd_show_externals {
 581         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 582         $gs ||= Git::SVN->new;
 583         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 584         $gs->prop_walk($gs->{path}, $r, sub {
 585                 my ($gs, $path, $props) = @_;
 586                 print STDOUT "\n# $path\n";
 587                 my $s = $props->{'svn:externals'} or return;
 588                 $s =~ s/[\r\n]+/\n/g;
 589                 chomp $s;
 590                 $s =~ s#^#$path#gm;
 591                 print STDOUT "$s\n";
 592         });
 593 }
 594
 595 sub cmd_create_ignore {
 596         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 597         $gs ||= Git::SVN->new;
 598         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 599         $gs->prop_walk($gs->{path}, $r, sub {
 600                 my ($gs, $path, $props) = @_;
 601                 # $path is of the form /path/to/dir/
 602                 my $ignore = '.' . $path . '.gitignore';
 603                 my $s = $props->{'svn:ignore'} or return;
 604                 open(GITIGNORE, '>', $ignore)
 605                   or fatal("Failed to open `$ignore' for writing: $!");
 606                 $s =~ s/[\r\n]+/\n/g;
 607                 chomp $s;
 608                 # Prefix all patterns so that the ignore doesn't apply
 609                 # to sub-directories.
 610                 $s =~ s#^#/#gm;
 611                 print GITIGNORE "$s\n";
 612                 close(GITIGNORE)
 613                   or fatal("Failed to close `$ignore': $!");
 614                 command_noisy('add', $ignore);
 615         });
 616 }
 617
 618 sub canonicalize_path {
 619         my ($path) = @_;
 620         my $dot_slash_added = 0;
 621         if (substr($path, 0, 1) ne "/") {
 622                 $path = "./" . $path;
 623                 $dot_slash_added = 1;
 624         }
 625         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 626         # good reason), so let's do this manually.
 627         $path =~ s#/+#/#g;
 628         $path =~ s#/\.(?:/|$)#/#g;
 629         $path =~ s#/[^/]+/\.\.##g;
 630         $path =~ s#/$##g;
 631         $path =~ s#^\./## if $dot_slash_added;
 632         return $path;
 633 }
 634
 635 # get_svnprops(PATH)
 636 # ------------------
 637 # Helper for cmd_propget and cmd_proplist below.
 638 sub get_svnprops {
 639         my $path = shift;
 640         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 641         $gs ||= Git::SVN->new;
 642
 643         # prefix THE PATH by the sub-directory from which the user
 644         # invoked us.
 645         $path = $cmd_dir_prefix . $path;
 646         fatal("No such file or directory: $path") unless -e $path;
 647         my $is_dir = -d $path ? 1 : 0;
 648         $path = $gs->{path} . '/' . $path;
 649
 650         # canonicalize the path (otherwise libsvn will abort or fail to
 651         # find the file)
 652         $path = canonicalize_path($path);
 653
 654         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 655         my $props;
 656         if ($is_dir) {
 657                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 658         }
 659         else {
 660                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 661         }
 662         return $props;
 663 }
 664
 665 # cmd_propget (PROP, PATH)
 666 # ------------------------
 667 # Print the SVN property PROP for PATH.
 668 sub cmd_propget {
 669         my ($prop, $path) = @_;
 670         $path = '.' if not defined $path;
 671         usage(1) if not defined $prop;
 672         my $props = get_svnprops($path);
 673         if (not defined $props->{$prop}) {
 674                 fatal("`$path' does not have a `$prop' SVN property.");
 675         }
 676         print $props->{$prop} . "\n";
 677 }
 678
 679 # cmd_proplist (PATH)
 680 # -------------------
 681 # Print the list of SVN properties for PATH.
 682 sub cmd_proplist {
 683         my $path = shift;
 684         $path = '.' if not defined $path;
 685         my $props = get_svnprops($path);
 686         print "Properties on '$path':\n";
 687         foreach (sort keys %{$props}) {
 688                 print "  $_\n";
 689         }
 690 }
 691
 692 sub cmd_multi_init {
 693         my $url = shift;
 694         unless (defined $_trunk || defined $_branches || defined $_tags) {
 695                 usage(1);
 696         }
 697
 698         # there are currently some bugs that prevent multi-init/multi-fetch
 699         # setups from working well without this.
 700         $Git::SVN::_minimize_url = 1;
 701
 702         $_prefix = '' unless defined $_prefix;
 703         if (defined $url) {
 704                 $url =~ s#/+$##;
 705                 init_subdir(@_);
 706         }
 707         do_git_init_db();
 708         if (defined $_trunk) {
 709                 my $trunk_ref = $_prefix . 'trunk';
 710                 # try both old-style and new-style lookups:
 711                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 712                 unless ($gs_trunk) {
 713                         my ($trunk_url, $trunk_path) =
 714                                               complete_svn_url($url, $_trunk);
 715                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 716                                                    undef, $trunk_ref);
 717                 }
 718         }
 719         return unless defined $_branches || defined $_tags;
 720         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 721         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 722         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 723 }
 724
 725 sub cmd_multi_fetch {
 726         my $remotes = Git::SVN::read_all_remotes();
 727         foreach my $repo_id (sort keys %$remotes) {
 728                 if ($remotes->{$repo_id}->{url}) {
 729                         Git::SVN::fetch_all($repo_id, $remotes);
 730                 }
 731         }
 732 }
 733
 734 # this command is special because it requires no metadata
 735 sub cmd_commit_diff {
 736         my ($ta, $tb, $url) = @_;
 737         my $usage = "Usage: $0 commit-diff -r<revision> ".
 738                     "<tree-ish> <tree-ish> [<URL>]";
 739         fatal($usage) if (!defined $ta || !defined $tb);
 740         my $svn_path;
 741         if (!defined $url) {
 742                 my $gs = eval { Git::SVN->new };
 743                 if (!$gs) {
 744                         fatal("Needed URL or usable git-svn --id in ",
 745                               "the command-line\n", $usage);
 746                 }
 747                 $url = $gs->{url};
 748                 $svn_path = $gs->{path};
 749         }
 750         unless (defined $_revision) {
 751                 fatal("-r|--revision is a required argument\n", $usage);
 752         }
 753         if (defined $_message && defined $_file) {
 754                 fatal("Both --message/-m and --file/-F specified ",
 755                       "for the commit message.\n",
 756                       "I have no idea what you mean");
 757         }
 758         if (defined $_file) {
 759                 $_message = file_to_s($_file);
 760         } else {
 761                 $_message ||= get_commit_entry($tb)->{log};
 762         }
 763         my $ra ||= Git::SVN::Ra->new($url);
 764         $svn_path ||= $ra->{svn_path};
 765         my $r = $_revision;
 766         if ($r eq 'HEAD') {
 767                 $r = $ra->get_latest_revnum;
 768         } elsif ($r !~ /^\d+$/) {
 769                 die "revision argument: $r not understood by git-svn\n";
 770         }
 771         my %ed_opts = ( r => $r,
 772                         log => $_message,
 773                         ra => $ra,
 774                         tree_a => $ta,
 775                         tree_b => $tb,
 776                         editor_cb => sub { print "Committed r$_[0]\n" },
 777                         svn_path => $svn_path );
 778         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 779                 print "No changes\n$ta == $tb\n";
 780         }
 781 }
 782
 783 sub cmd_info {
 784         my $path = canonicalize_path(shift or ".");
 785         unless (scalar(@_) == 0) {
 786                 die "Too many arguments specified\n";
 787         }
 788
 789         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 790
 791         if (!$file_type && !$diff_status) {
 792                 print STDERR "$path:  (Not a versioned resource)\n\n";
 793                 return;
 794         }
 795
 796         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 797         unless ($gs) {
 798                 die "Unable to determine upstream SVN information from ",
 799                     "working tree history\n";
 800         }
 801         my $full_url = $url . ($path eq "." ? "" : "/$path");
 802
 803         if ($_url) {
 804                 print $full_url, "\n";
 805                 return;
 806         }
 807
 808         my $result = "Path: $path\n";
 809         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 810         $result .= "URL: " . $full_url . "\n";
 811
 812         eval {
 813                 my $repos_root = $gs->repos_root;
 814                 Git::SVN::remove_username($repos_root);
 815                 $result .= "Repository Root: $repos_root\n";
 816         };
 817         if ($@) {
 818                 $result .= "Repository Root: (offline)\n";
 819         }
 820         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
 821         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 822
 823         $result .= "Node Kind: " .
 824                    ($file_type eq "dir" ? "directory" : "file") . "\n";
 825
 826         my $schedule = $diff_status eq "A"
 827                        ? "add"
 828                        : ($diff_status eq "D" ? "delete" : "normal");
 829         $result .= "Schedule: $schedule\n";
 830
 831         if ($diff_status eq "A") {
 832                 print $result, "\n";
 833                 return;
 834         }
 835
 836         my ($lc_author, $lc_rev, $lc_date_utc);
 837         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
 838         my $log = command_output_pipe(@args);
 839         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 840         while (<$log>) {
 841                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 842                         $lc_author = $1;
 843                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 844                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 845                         (undef, $lc_rev, undef) = ::extract_metadata($1);
 846                 }
 847         }
 848         close $log;
 849
 850         Git::SVN::Log::set_local_timezone();
 851
 852         $result .= "Last Changed Author: $lc_author\n";
 853         $result .= "Last Changed Rev: $lc_rev\n";
 854         $result .= "Last Changed Date: " .
 855                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 856
 857         if ($file_type ne "dir") {
 858                 my $text_last_updated_date =
 859                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 860                 $result .=
 861                     "Text Last Updated: " .
 862                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
 863                     "\n";
 864                 my $checksum;
 865                 if ($diff_status eq "D") {
 866                         my ($fh, $ctx) =
 867                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
 868                         if ($file_type eq "link") {
 869                                 my $file_name = <$fh>;
 870                                 $checksum = md5sum("link $file_name");
 871                         } else {
 872                                 $checksum = md5sum($fh);
 873                         }
 874                         command_close_pipe($fh, $ctx);
 875                 } elsif ($file_type eq "link") {
 876                         my $file_name =
 877                             command(qw(cat-file blob), "HEAD:$path");
 878                         $checksum =
 879                             md5sum("link " . $file_name);
 880                 } else {
 881                         open FILE, "<", $path or die $!;
 882                         $checksum = md5sum(\*FILE);
 883                         close FILE or die $!;
 884                 }
 885                 $result .= "Checksum: " . $checksum . "\n";
 886         }
 887
 888         print $result, "\n";
 889 }
 890
 891 ########################### utility functions #########################
 892
 893 sub rebase_cmd {
 894         my @cmd = qw/rebase/;
 895         push @cmd, '-v' if $_verbose;
 896         push @cmd, qw/--merge/ if $_merge;
 897         push @cmd, "--strategy=$_strategy" if $_strategy;
 898         @cmd;
 899 }
 900
 901 sub post_fetch_checkout {
 902         return if $_no_checkout;
 903         my $gs = $Git::SVN::_head or return;
 904         return if verify_ref('refs/heads/master^0');
 905
 906         my $valid_head = verify_ref('HEAD^0');
 907         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 908         return if ($valid_head || !verify_ref('HEAD^0'));
 909
 910         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 911         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 912         return if -f $index;
 913
 914         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
 915         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 916         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 917         print STDERR "Checked out HEAD:\n  ",
 918                      $gs->full_url, " r", $gs->last_rev, "\n";
 919 }
 920
 921 sub complete_svn_url {
 922         my ($url, $path) = @_;
 923         $path =~ s#/+$##;
 924         if ($path !~ m#^[a-z\+]+://#) {
 925                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 926                         fatal("E: '$path' is not a complete URL ",
 927                               "and a separate URL is not specified");
 928                 }
 929                 return ($url, $path);
 930         }
 931         return ($path, '');
 932 }
 933
 934 sub complete_url_ls_init {
 935         my ($ra, $repo_path, $switch, $pfx) = @_;
 936         unless ($repo_path) {
 937                 print STDERR "W: $switch not specified\n";
 938                 return;
 939         }
 940         $repo_path =~ s#/+$##;
 941         if ($repo_path =~ m#^[a-z\+]+://#) {
 942                 $ra = Git::SVN::Ra->new($repo_path);
 943                 $repo_path = '';
 944         } else {
 945                 $repo_path =~ s#^/+##;
 946                 unless ($ra) {
 947                         fatal("E: '$repo_path' is not a complete URL ",
 948                               "and a separate URL is not specified");
 949                 }
 950         }
 951         my $url = $ra->{url};
 952         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 953         my $k = "svn-remote.$gs->{repo_id}.url";
 954         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 955         if ($orig_url && ($orig_url ne $gs->{url})) {
 956                 die "$k already set: $orig_url\n",
 957                     "wanted to set to: $gs->{url}\n";
 958         }
 959         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 960         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 961         $remote_path =~ s#/+#/#g;
 962         $remote_path =~ s#^/##g;
 963         my ($n) = ($switch =~ /^--(\w+)/);
 964         if (length $pfx && $pfx !~ m#/$#) {
 965                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 966         }
 967         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 968                                 "$remote_path:refs/remotes/$pfx*");
 969 }
 970
 971 sub verify_ref {
 972         my ($ref) = @_;
 973         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 974                                { STDERR => 0 }); };
 975 }
 976
 977 sub get_tree_from_treeish {
 978         my ($treeish) = @_;
 979         # $treeish can be a symbolic ref, too:
 980         my $type = command_oneline(qw/cat-file -t/, $treeish);
 981         my $expected;
 982         while ($type eq 'tag') {
 983                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 984         }
 985         if ($type eq 'commit') {
 986                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 987                                                     $treeish))[0];
 988                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 989                 die "Unable to get tree from $treeish\n" unless $expected;
 990         } elsif ($type eq 'tree') {
 991                 $expected = $treeish;
 992         } else {
 993                 die "$treeish is a $type, expected tree, tag or commit\n";
 994         }
 995         return $expected;
 996 }
 997
 998 sub get_commit_entry {
 999         my ($treeish) = shift;
1000         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1001         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1002         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1003         open my $log_fh, '>', $commit_editmsg or croak $!;
1004
1005         my $type = command_oneline(qw/cat-file -t/, $treeish);
1006         if ($type eq 'commit' || $type eq 'tag') {
1007                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1008                                                          $type, $treeish);
1009                 my $in_msg = 0;
1010                 while (<$msg_fh>) {
1011                         if (!$in_msg) {
1012                                 $in_msg = 1 if (/^\s*$/);
1013                         } elsif (/^git-svn-id: /) {
1014                                 # skip this for now, we regenerate the
1015                                 # correct one on re-fetch anyways
1016                                 # TODO: set *:merge properties or like...
1017                         } else {
1018                                 print $log_fh $_ or croak $!;
1019                         }
1020                 }
1021                 command_close_pipe($msg_fh, $ctx);
1022         }
1023         close $log_fh or croak $!;
1024
1025         if ($_edit || ($type eq 'tree')) {
1026                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1027                 # TODO: strip out spaces, comments, like git-commit.sh
1028                 system($editor, $commit_editmsg);
1029         }
1030         rename $commit_editmsg, $commit_msg or croak $!;
1031         open $log_fh, '<', $commit_msg or croak $!;
1032         { local $/; chomp($log_entry{log} = <$log_fh>); }
1033         close $log_fh or croak $!;
1034         unlink $commit_msg;
1035         \%log_entry;
1036 }
1037
1038 sub s_to_file {
1039         my ($str, $file, $mode) = @_;
1040         open my $fd,'>',$file or croak $!;
1041         print $fd $str,"\n" or croak $!;
1042         close $fd or croak $!;
1043         chmod ($mode &~ umask, $file) if (defined $mode);
1044 }
1045
1046 sub file_to_s {
1047         my $file = shift;
1048         open my $fd,'<',$file or croak "$!: file: $file\n";
1049         local $/;
1050         my $ret = <$fd>;
1051         close $fd or croak $!;
1052         $ret =~ s/\s*$//s;
1053         return $ret;
1054 }
1055
1056 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1057 sub load_authors {
1058         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1059         my $log = $cmd eq 'log';
1060         while (<$authors>) {
1061                 chomp;
1062                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1063                 my ($user, $name, $email) = ($1, $2, $3);
1064                 if ($log) {
1065                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1066                 } else {
1067                         $users{$user} = [$name, $email];
1068                 }
1069         }
1070         close $authors or croak $!;
1071 }
1072
1073 # convert GetOpt::Long specs for use by git-config
1074 sub read_repo_config {
1075         return unless -d $ENV{GIT_DIR};
1076         my $opts = shift;
1077         my @config_only;
1078         foreach my $o (keys %$opts) {
1079                 # if we have mixedCase and a long option-only, then
1080                 # it's a config-only variable that we don't need for
1081                 # the command-line.
1082                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1083                 my $v = $opts->{$o};
1084                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1085                 $key =~ s/-//g;
1086                 my $arg = 'git-config';
1087                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1088                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1089                 if (ref $v eq 'ARRAY') {
1090                         chomp(my @tmp = `$arg --get-all svn.$key`);
1091                         @$v = @tmp if @tmp;
1092                 } else {
1093                         chomp(my $tmp = `$arg --get svn.$key`);
1094                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1095                                 $$v = $tmp;
1096                         }
1097                 }
1098         }
1099         delete @$opts{@config_only} if @config_only;
1100 }
1101
1102 sub extract_metadata {
1103         my $id = shift or return (undef, undef, undef);
1104         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1105                                                         \s([a-f\d\-]+)$/x);
1106         if (!defined $rev || !$uuid || !$url) {
1107                 # some of the original repositories I made had
1108                 # identifiers like this:
1109                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1110         }
1111         return ($url, $rev, $uuid);
1112 }
1113
1114 sub cmt_metadata {
1115         return extract_metadata((grep(/^git-svn-id: /,
1116                 command(qw/cat-file commit/, shift)))[-1]);
1117 }
1118
1119 sub working_head_info {
1120         my ($head, $refs) = @_;
1121         my @args = ('log', '--no-color', '--first-parent');
1122         my ($fh, $ctx) = command_output_pipe(@args, $head);
1123         my $hash;
1124         my %max;
1125         while (<$fh>) {
1126                 if ( m{^commit ($::sha1)$} ) {
1127                         unshift @$refs, $hash if $hash and $refs;
1128                         $hash = $1;
1129                         next;
1130                 }
1131                 next unless s{^\s*(git-svn-id:)}{$1};
1132                 my ($url, $rev, $uuid) = extract_metadata($_);
1133                 if (defined $url && defined $rev) {
1134                         next if $max{$url} and $max{$url} < $rev;
1135                         if (my $gs = Git::SVN->find_by_url($url)) {
1136                                 my $c = $gs->rev_map_get($rev);
1137                                 if ($c && $c eq $hash) {
1138                                         close $fh; # break the pipe
1139                                         return ($url, $rev, $uuid, $gs);
1140                                 } else {
1141                                         $max{$url} ||= $gs->rev_map_max;
1142                                 }
1143                         }
1144                 }
1145         }
1146         command_close_pipe($fh, $ctx);
1147         (undef, undef, undef, undef);
1148 }
1149
1150 sub read_commit_parents {
1151         my ($parents, $c) = @_;
1152         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1153         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1154         @{$parents->{$c}} = split(/ /, $p);
1155 }
1156
1157 sub linearize_history {
1158         my ($gs, $refs) = @_;
1159         my %parents;
1160         foreach my $c (@$refs) {
1161                 read_commit_parents(\%parents, $c);
1162         }
1163
1164         my @linear_refs;
1165         my %skip = ();
1166         my $last_svn_commit = $gs->last_commit;
1167         foreach my $c (reverse @$refs) {
1168                 next if $c eq $last_svn_commit;
1169                 last if $skip{$c};
1170
1171                 unshift @linear_refs, $c;
1172                 $skip{$c} = 1;
1173
1174                 # we only want the first parent to diff against for linear
1175                 # history, we save the rest to inject when we finalize the
1176                 # svn commit
1177                 my $fp_a = verify_ref("$c~1");
1178                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1179                 if (!$fp_a || !$fp_b) {
1180                         die "Commit $c\n",
1181                             "has no parent commit, and therefore ",
1182                             "nothing to diff against.\n",
1183                             "You should be working from a repository ",
1184                             "originally created by git-svn\n";
1185                 }
1186                 if ($fp_a ne $fp_b) {
1187                         die "$c~1 = $fp_a, however parsing commit $c ",
1188                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1189                 }
1190
1191                 foreach my $p (@{$parents{$c}}) {
1192                         $skip{$p} = 1;
1193                 }
1194         }
1195         (\@linear_refs, \%parents);
1196 }
1197
1198 sub find_file_type_and_diff_status {
1199         my ($path) = @_;
1200         return ('dir', '') if $path eq '.';
1201
1202         my $diff_output =
1203             command_oneline(qw(diff --cached --name-status --), $path) || "";
1204         my $diff_status = (split(' ', $diff_output))[0] || "";
1205
1206         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1207
1208         return (undef, undef) if !$diff_status && !$ls_tree;
1209
1210         if ($diff_status eq "A") {
1211                 return ("link", $diff_status) if -l $path;
1212                 return ("dir", $diff_status) if -d $path;
1213                 return ("file", $diff_status);
1214         }
1215
1216         my $mode = (split(' ', $ls_tree))[0] || "";
1217
1218         return ("link", $diff_status) if $mode eq "120000";
1219         return ("dir", $diff_status) if $mode eq "040000";
1220         return ("file", $diff_status);
1221 }
1222
1223 sub md5sum {
1224         my $arg = shift;
1225         my $ref = ref $arg;
1226         my $md5 = Digest::MD5->new();
1227         if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1228                 $md5->addfile($arg) or croak $!;
1229         } elsif ($ref eq 'SCALAR') {
1230                 $md5->add($$arg) or croak $!;
1231         } elsif (!$ref) {
1232                 $md5->add($arg) or croak $!;
1233         } else {
1234                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1235         }
1236         return $md5->hexdigest();
1237 }
1238
1239 package Git::SVN;
1240 use strict;
1241 use warnings;
1242 use Fcntl qw/:DEFAULT :seek/;
1243 use constant rev_map_fmt => 'NH40';
1244 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1245             $_repack $_repack_flags $_use_svm_props $_head
1246             $_use_svnsync_props $no_reuse_existing $_minimize_url
1247             $_use_log_author/;
1248 use Carp qw/croak/;
1249 use File::Path qw/mkpath/;
1250 use File::Copy qw/copy/;
1251 use IPC::Open3;
1252
1253 my ($_gc_nr, $_gc_period);
1254
1255 # properties that we do not log:
1256 my %SKIP_PROP;
1257 BEGIN {
1258         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1259                                         svn:special svn:executable
1260                                         svn:entry:committed-rev
1261                                         svn:entry:last-author
1262                                         svn:entry:uuid
1263                                         svn:entry:committed-date/;
1264
1265         # some options are read globally, but can be overridden locally
1266         # per [svn-remote "..."] section.  Command-line options will *NOT*
1267         # override options set in an [svn-remote "..."] section
1268         no strict 'refs';
1269         for my $option (qw/follow_parent no_metadata use_svm_props
1270                            use_svnsync_props/) {
1271                 my $key = $option;
1272                 $key =~ tr/_//d;
1273                 my $prop = "-$option";
1274                 *$option = sub {
1275                         my ($self) = @_;
1276                         return $self->{$prop} if exists $self->{$prop};
1277                         my $k = "svn-remote.$self->{repo_id}.$key";
1278                         eval { command_oneline(qw/config --get/, $k) };
1279                         if ($@) {
1280                                 $self->{$prop} = ${"Git::SVN::_$option"};
1281                         } else {
1282                                 my $v = command_oneline(qw/config --bool/,$k);
1283                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1284                         }
1285                         return $self->{$prop};
1286                 }
1287         }
1288 }
1289
1290 my (%LOCKFILES, %INDEX_FILES);
1291 END {
1292         unlink keys %LOCKFILES if %LOCKFILES;
1293         unlink keys %INDEX_FILES if %INDEX_FILES;
1294 }
1295
1296 sub resolve_local_globs {
1297         my ($url, $fetch, $glob_spec) = @_;
1298         return unless defined $glob_spec;
1299         my $ref = $glob_spec->{ref};
1300         my $path = $glob_spec->{path};
1301         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1302                 next unless m#^refs/remotes/$ref->{regex}$#;
1303                 my $p = $1;
1304                 my $pathname = desanitize_refname($path->full_path($p));
1305                 my $refname = desanitize_refname($ref->full_path($p));
1306                 if (my $existing = $fetch->{$pathname}) {
1307                         if ($existing ne $refname) {
1308                                 die "Refspec conflict:\n",
1309                                     "existing: refs/remotes/$existing\n",
1310                                     " globbed: refs/remotes/$refname\n";
1311                         }
1312                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1313                         $u =~ s!^\Q$url\E(/|$)!! or die
1314                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1315                         if ($pathname ne $u) {
1316                                 warn "W: Refspec glob conflict ",
1317                                      "(ref: refs/remotes/$refname):\n",
1318                                      "expected path: $pathname\n",
1319                                      "    real path: $u\n",
1320                                      "Continuing ahead with $u\n";
1321                                 next;
1322                         }
1323                 } else {
1324                         $fetch->{$pathname} = $refname;
1325                 }
1326         }
1327 }
1328
1329 sub parse_revision_argument {
1330         my ($base, $head) = @_;
1331         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1332                 return ($base, $head);
1333         }
1334         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1335         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1336         return ($head, $head) if ($::_revision eq 'HEAD');
1337         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1338         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1339         die "revision argument: $::_revision not understood by git-svn\n";
1340 }
1341
1342 sub fetch_all {
1343         my ($repo_id, $remotes) = @_;
1344         if (ref $repo_id) {
1345                 my $gs = $repo_id;
1346                 $repo_id = undef;
1347                 $repo_id = $gs->{repo_id};
1348         }
1349         $remotes ||= read_all_remotes();
1350         my $remote = $remotes->{$repo_id} or
1351                      die "[svn-remote \"$repo_id\"] unknown\n";
1352         my $fetch = $remote->{fetch};
1353         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1354         my (@gs, @globs);
1355         my $ra = Git::SVN::Ra->new($url);
1356         my $uuid = $ra->get_uuid;
1357         my $head = $ra->get_latest_revnum;
1358         my $base = defined $fetch ? $head : 0;
1359
1360         # read the max revs for wildcard expansion (branches/*, tags/*)
1361         foreach my $t (qw/branches tags/) {
1362                 defined $remote->{$t} or next;
1363                 push @globs, $remote->{$t};
1364                 my $max_rev = eval { tmp_config(qw/--int --get/,
1365                                          "svn-remote.$repo_id.${t}-maxRev") };
1366                 if (defined $max_rev && ($max_rev < $base)) {
1367                         $base = $max_rev;
1368                 } elsif (!defined $max_rev) {
1369                         $base = 0;
1370                 }
1371         }
1372
1373         if ($fetch) {
1374                 foreach my $p (sort keys %$fetch) {
1375                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1376                         my $lr = $gs->rev_map_max;
1377                         if (defined $lr) {
1378                                 $base = $lr if ($lr < $base);
1379                         }
1380                         push @gs, $gs;
1381                 }
1382         }
1383
1384         ($base, $head) = parse_revision_argument($base, $head);
1385         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1386 }
1387
1388 sub read_all_remotes {
1389         my $r = {};
1390         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1391                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1392                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1393                         $local_ref =~ s{^/}{};
1394                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1395                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1396                         $r->{$1}->{url} = $2;
1397                 } elsif (m!^(.+)\.(branches|tags)=
1398                            (.*):refs/remotes/(.+)\s*$/!x) {
1399                         my ($p, $g) = ($3, $4);
1400                         my $rs = $r->{$1}->{$2} = {
1401                                           t => $2,
1402                                           remote => $1,
1403                                           path => Git::SVN::GlobSpec->new($p),
1404                                           ref => Git::SVN::GlobSpec->new($g) };
1405                         if (length($rs->{ref}->{right}) != 0) {
1406                                 die "The '*' glob character must be the last ",
1407                                     "character of '$g'\n";
1408                         }
1409                 }
1410         }
1411         $r;
1412 }
1413
1414 sub init_vars {
1415         $_gc_nr = $_gc_period = 1000;
1416         if (defined $_repack || defined $_repack_flags) {
1417                warn "Repack options are obsolete; they have no effect.\n";
1418         }
1419 }
1420
1421 sub verify_remotes_sanity {
1422         return unless -d $ENV{GIT_DIR};
1423         my %seen;
1424         foreach (command(qw/config -l/)) {
1425                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1426                         if ($seen{$1}) {
1427                                 die "Remote ref refs/remote/$1 is tracked by",
1428                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1429                                     "Please resolve this ambiguity in ",
1430                                     "your git configuration file before ",
1431                                     "continuing\n";
1432                         }
1433                         $seen{$1} = $_;
1434                 }
1435         }
1436 }
1437
1438 # we allow more chars than remotes2config.sh...
1439 sub sanitize_remote_name {
1440         my ($name) = @_;
1441         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1442         $name;
1443 }
1444
1445 sub find_existing_remote {
1446         my ($url, $remotes) = @_;
1447         return undef if $no_reuse_existing;
1448         my $existing;
1449         foreach my $repo_id (keys %$remotes) {
1450                 my $u = $remotes->{$repo_id}->{url} or next;
1451                 next if $u ne $url;
1452                 $existing = $repo_id;
1453                 last;
1454         }
1455         $existing;
1456 }
1457
1458 sub init_remote_config {
1459         my ($self, $url, $no_write) = @_;
1460         $url =~ s!/+$!!; # strip trailing slash
1461         my $r = read_all_remotes();
1462         my $existing = find_existing_remote($url, $r);
1463         if ($existing) {
1464                 unless ($no_write) {
1465                         print STDERR "Using existing ",
1466                                      "[svn-remote \"$existing\"]\n";
1467                 }
1468                 $self->{repo_id} = $existing;
1469         } elsif ($_minimize_url) {
1470                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1471                 $existing = find_existing_remote($min_url, $r);
1472                 if ($existing) {
1473                         unless ($no_write) {
1474                                 print STDERR "Using existing ",
1475                                              "[svn-remote \"$existing\"]\n";
1476                         }
1477                         $self->{repo_id} = $existing;
1478                 }
1479                 if ($min_url ne $url) {
1480                         unless ($no_write) {
1481                                 print STDERR "Using higher level of URL: ",
1482                                              "$url => $min_url\n";
1483                         }
1484                         my $old_path = $self->{path};
1485                         $self->{path} = $url;
1486                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1487                         if (length $old_path) {
1488                                 $self->{path} .= "/$old_path";
1489                         }
1490                         $url = $min_url;
1491                 }
1492         }
1493         my $orig_url;
1494         if (!$existing) {
1495                 # verify that we aren't overwriting anything:
1496                 $orig_url = eval {
1497                         command_oneline('config', '--get',
1498                                         "svn-remote.$self->{repo_id}.url")
1499                 };
1500                 if ($orig_url && ($orig_url ne $url)) {
1501                         die "svn-remote.$self->{repo_id}.url already set: ",
1502                             "$orig_url\nwanted to set to: $url\n";
1503                 }
1504         }
1505         my ($xrepo_id, $xpath) = find_ref($self->refname);
1506         if (defined $xpath) {
1507                 die "svn-remote.$xrepo_id.fetch already set to track ",
1508                     "$xpath:refs/remotes/", $self->refname, "\n";
1509         }
1510         unless ($no_write) {
1511                 command_noisy('config',
1512                               "svn-remote.$self->{repo_id}.url", $url);
1513                 $self->{path} =~ s{^/}{};
1514                 command_noisy('config', '--add',
1515                               "svn-remote.$self->{repo_id}.fetch",
1516                               "$self->{path}:".$self->refname);
1517         }
1518         $self->{url} = $url;
1519 }
1520
1521 sub find_by_url { # repos_root and, path are optional
1522         my ($class, $full_url, $repos_root, $path) = @_;
1523
1524         return undef unless defined $full_url;
1525         remove_username($full_url);
1526         remove_username($repos_root) if defined $repos_root;
1527         my $remotes = read_all_remotes();
1528         if (defined $full_url && defined $repos_root && !defined $path) {
1529                 $path = $full_url;
1530                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1531         }
1532         foreach my $repo_id (keys %$remotes) {
1533                 my $u = $remotes->{$repo_id}->{url} or next;
1534                 remove_username($u);
1535                 next if defined $repos_root && $repos_root ne $u;
1536
1537                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1538                 foreach (qw/branches tags/) {
1539                         resolve_local_globs($u, $fetch,
1540                                             $remotes->{$repo_id}->{$_});
1541                 }
1542                 my $p = $path;
1543                 my $rwr = rewrite_root({repo_id => $repo_id});
1544                 unless (defined $p) {
1545                         $p = $full_url;
1546                         my $z = $u;
1547                         if ($rwr) {
1548                                 $z = $rwr;
1549                         }
1550                         $p =~ s#^\Q$z\E(?:/|$)## or next;
1551                 }
1552                 foreach my $f (keys %$fetch) {
1553                         next if $f ne $p;
1554                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1555                 }
1556         }
1557         undef;
1558 }
1559
1560 sub init {
1561         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1562         my $self = _new($class, $repo_id, $ref_id, $path);
1563         if (defined $url) {
1564                 $self->init_remote_config($url, $no_write);
1565         }
1566         $self;
1567 }
1568
1569 sub find_ref {
1570         my ($ref_id) = @_;
1571         foreach (command(qw/config -l/)) {
1572                 next unless m!^svn-remote\.(.+)\.fetch=
1573                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1574                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1575                 if ($ref eq $ref_id) {
1576                         $path = '' if ($path =~ m#^\./?#);
1577                         return ($repo_id, $path);
1578                 }
1579         }
1580         (undef, undef, undef);
1581 }
1582
1583 sub new {
1584         my ($class, $ref_id, $repo_id, $path) = @_;
1585         if (defined $ref_id && !defined $repo_id && !defined $path) {
1586                 ($repo_id, $path) = find_ref($ref_id);
1587                 if (!defined $repo_id) {
1588                         die "Could not find a \"svn-remote.*.fetch\" key ",
1589                             "in the repository configuration matching: ",
1590                             "refs/remotes/$ref_id\n";
1591                 }
1592         }
1593         my $self = _new($class, $repo_id, $ref_id, $path);
1594         if (!defined $self->{path} || !length $self->{path}) {
1595                 my $fetch = command_oneline('config', '--get',
1596                                             "svn-remote.$repo_id.fetch",
1597                                             ":refs/remotes/$ref_id\$") or
1598                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1599                          "\":refs/remotes/$ref_id\$\" in config\n";
1600                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1601         }
1602         $self->{url} = command_oneline('config', '--get',
1603                                        "svn-remote.$repo_id.url") or
1604                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1605         $self->rebuild;
1606         $self;
1607 }
1608
1609 sub refname {
1610         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1611
1612         # It cannot end with a slash /, we'll throw up on this because
1613         # SVN can't have directories with a slash in their name, either:
1614         if ($refname =~ m{/$}) {
1615                 die "ref: '$refname' ends with a trailing slash, this is ",
1616                     "not permitted by git nor Subversion\n";
1617         }
1618
1619         # It cannot have ASCII control character space, tilde ~, caret ^,
1620         # colon :, question-mark ?, asterisk *, space, or open bracket [
1621         # anywhere.
1622         #
1623         # Additionally, % must be escaped because it is used for escaping
1624         # and we want our escaped refname to be reversible
1625         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1626
1627         # no slash-separated component can begin with a dot .
1628         # /.* becomes /%2E*
1629         $refname =~ s{/\.}{/%2E}g;
1630
1631         # It cannot have two consecutive dots .. anywhere
1632         # .. becomes %2E%2E
1633         $refname =~ s{\.\.}{%2E%2E}g;
1634
1635         return $refname;
1636 }
1637
1638 sub desanitize_refname {
1639         my ($refname) = @_;
1640         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1641         return $refname;
1642 }
1643
1644 sub svm_uuid {
1645         my ($self) = @_;
1646         return $self->{svm}->{uuid} if $self->svm;
1647         $self->ra;
1648         unless ($self->{svm}) {
1649                 die "SVM UUID not cached, and reading remotely failed\n";
1650         }
1651         $self->{svm}->{uuid};
1652 }
1653
1654 sub svm {
1655         my ($self) = @_;
1656         return $self->{svm} if $self->{svm};
1657         my $svm;
1658         # see if we have it in our config, first:
1659         eval {
1660                 my $section = "svn-remote.$self->{repo_id}";
1661                 $svm = {
1662                   source => tmp_config('--get', "$section.svm-source"),
1663                   uuid => tmp_config('--get', "$section.svm-uuid"),
1664                   replace => tmp_config('--get', "$section.svm-replace"),
1665                 }
1666         };
1667         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1668                 $self->{svm} = $svm;
1669         }
1670         $self->{svm};
1671 }
1672
1673 sub _set_svm_vars {
1674         my ($self, $ra) = @_;
1675         return $ra if $self->svm;
1676
1677         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1678                     "(svm:source, svm:uuid) ",
1679                     "from the following URLs:\n" );
1680         sub read_svm_props {
1681                 my ($self, $ra, $path, $r) = @_;
1682                 my $props = ($ra->get_dir($path, $r))[2];
1683                 my $src = $props->{'svm:source'};
1684                 my $uuid = $props->{'svm:uuid'};
1685                 return undef if (!$src || !$uuid);
1686
1687                 chomp($src, $uuid);
1688
1689                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1690                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1691
1692                 # the '!' is used to mark the repos_root!/relative/path
1693                 $src =~ s{/?!/?}{/};
1694                 $src =~ s{/+$}{}; # no trailing slashes please
1695                 # username is of no interest
1696                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1697
1698                 my $replace = $ra->{url};
1699                 $replace .= "/$path" if length $path;
1700
1701                 my $section = "svn-remote.$self->{repo_id}";
1702                 tmp_config("$section.svm-source", $src);
1703                 tmp_config("$section.svm-replace", $replace);
1704                 tmp_config("$section.svm-uuid", $uuid);
1705                 $self->{svm} = {
1706                         source => $src,
1707                         uuid => $uuid,
1708                         replace => $replace
1709                 };
1710         }
1711
1712         my $r = $ra->get_latest_revnum;
1713         my $path = $self->{path};
1714         my %tried;
1715         while (length $path) {
1716                 unless ($tried{"$self->{url}/$path"}) {
1717                         return $ra if $self->read_svm_props($ra, $path, $r);
1718                         $tried{"$self->{url}/$path"} = 1;
1719                 }
1720                 $path =~ s#/?[^/]+$##;
1721         }
1722         die "Path: '$path' should be ''\n" if $path ne '';
1723         return $ra if $self->read_svm_props($ra, $path, $r);
1724         $tried{"$self->{url}/$path"} = 1;
1725
1726         if ($ra->{repos_root} eq $self->{url}) {
1727                 die @err, (map { "  $_\n" } keys %tried), "\n";
1728         }
1729
1730         # nope, make sure we're connected to the repository root:
1731         my $ok;
1732         my @tried_b;
1733         $path = $ra->{svn_path};
1734         $ra = Git::SVN::Ra->new($ra->{repos_root});
1735         while (length $path) {
1736                 unless ($tried{"$ra->{url}/$path"}) {
1737                         $ok = $self->read_svm_props($ra, $path, $r);
1738                         last if $ok;
1739                         $tried{"$ra->{url}/$path"} = 1;
1740                 }
1741                 $path =~ s#/?[^/]+$##;
1742         }
1743         die "Path: '$path' should be ''\n" if $path ne '';
1744         $ok ||= $self->read_svm_props($ra, $path, $r);
1745         $tried{"$ra->{url}/$path"} = 1;
1746         if (!$ok) {
1747                 die @err, (map { "  $_\n" } keys %tried), "\n";
1748         }
1749         Git::SVN::Ra->new($self->{url});
1750 }
1751
1752 sub svnsync {
1753         my ($self) = @_;
1754         return $self->{svnsync} if $self->{svnsync};
1755
1756         if ($self->no_metadata) {
1757                 die "Can't have both 'noMetadata' and ",
1758                     "'useSvnsyncProps' options set!\n";
1759         }
1760         if ($self->rewrite_root) {
1761                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1762                     "options set!\n";
1763         }
1764
1765         my $svnsync;
1766         # see if we have it in our config, first:
1767         eval {
1768                 my $section = "svn-remote.$self->{repo_id}";
1769
1770                 my $url = tmp_config('--get', "$section.svnsync-url");
1771                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1772                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1773
1774                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1775                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1776                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1777
1778                 $svnsync = { url => $url, uuid => $uuid }
1779         };
1780         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1781                 return $self->{svnsync} = $svnsync;
1782         }
1783
1784         my $err = "useSvnsyncProps set, but failed to read " .
1785                   "svnsync property: svn:sync-from-";
1786         my $rp = $self->ra->rev_proplist(0);
1787
1788         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1789         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1790                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1791
1792         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1793         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1794                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1795
1796         my $section = "svn-remote.$self->{repo_id}";
1797         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1798         tmp_config('--add', "$section.svnsync-url", $url);
1799         return $self->{svnsync} = { url => $url, uuid => $uuid };
1800 }
1801
1802 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1803 # remote lookup (useful for 'git svn log').
1804 sub ra_uuid {
1805         my ($self) = @_;
1806         unless ($self->{ra_uuid}) {
1807                 my $key = "svn-remote.$self->{repo_id}.uuid";
1808                 my $uuid = eval { tmp_config('--get', $key) };
1809                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1810                         $self->{ra_uuid} = $uuid;
1811                 } else {
1812                         die "ra_uuid called without URL\n" unless $self->{url};
1813                         $self->{ra_uuid} = $self->ra->get_uuid;
1814                         tmp_config('--add', $key, $self->{ra_uuid});
1815                 }
1816         }
1817         $self->{ra_uuid};
1818 }
1819
1820 sub _set_repos_root {
1821         my ($self, $repos_root) = @_;
1822         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1823         $repos_root ||= $self->ra->{repos_root};
1824         tmp_config($k, $repos_root);
1825         $repos_root;
1826 }
1827
1828 sub repos_root {
1829         my ($self) = @_;
1830         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1831         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1832 }
1833
1834 sub ra {
1835         my ($self) = shift;
1836         my $ra = Git::SVN::Ra->new($self->{url});
1837         $self->_set_repos_root($ra->{repos_root});
1838         if ($self->use_svm_props && !$self->{svm}) {
1839                 if ($self->no_metadata) {
1840                         die "Can't have both 'noMetadata' and ",
1841                             "'useSvmProps' options set!\n";
1842                 } elsif ($self->use_svnsync_props) {
1843                         die "Can't have both 'useSvnsyncProps' and ",
1844                             "'useSvmProps' options set!\n";
1845                 }
1846                 $ra = $self->_set_svm_vars($ra);
1847                 $self->{-want_revprops} = 1;
1848         }
1849         $ra;
1850 }
1851
1852 sub rel_path {
1853         my ($self) = @_;
1854         my $repos_root = $self->ra->{repos_root};
1855         return $self->{path} if ($self->{url} eq $repos_root);
1856         my $url = $self->{url} .
1857                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1858         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1859         $url;
1860 }
1861
1862 # prop_walk(PATH, REV, SUB)
1863 # -------------------------
1864 # Recursively traverse PATH at revision REV and invoke SUB for each
1865 # directory that contains a SVN property.  SUB will be invoked as
1866 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
1867 # Git::SVN, `path' the path to the directory where the properties
1868 # `props' were found.  The `path' will be relative to point of checkout,
1869 # that is, if url://repo/trunk is the current Git branch, and that
1870 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1871 # as `path' (note the trailing `/').
1872 sub prop_walk {
1873         my ($self, $path, $rev, $sub) = @_;
1874
1875         $path =~ s#^/##;
1876         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1877         $path =~ s#^/*#/#g;
1878         my $p = $path;
1879         # Strip the irrelevant part of the path.
1880         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1881         # Ensure the path is terminated by a `/'.
1882         $p =~ s#/*$#/#;
1883
1884         # The properties contain all the internal SVN stuff nobody
1885         # (usually) cares about.
1886         my $interesting_props = 0;
1887         foreach (keys %{$props}) {
1888                 # If it doesn't start with `svn:', it must be a
1889                 # user-defined property.
1890                 ++$interesting_props and next if $_ !~ /^svn:/;
1891                 # FIXME: Fragile, if SVN adds new public properties,
1892                 # this needs to be updated.
1893                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1894                                                  |eol-style|mime-type
1895                                                  |externals|needs-lock)$/x;
1896         }
1897         &$sub($self, $p, $props) if $interesting_props;
1898
1899         foreach (sort keys %$dirent) {
1900                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1901                 $self->prop_walk($path . '/' . $_, $rev, $sub);
1902         }
1903 }
1904
1905 sub last_rev { ($_[0]->last_rev_commit)[0] }
1906 sub last_commit { ($_[0]->last_rev_commit)[1] }
1907
1908 # returns the newest SVN revision number and newest commit SHA1
1909 sub last_rev_commit {
1910         my ($self) = @_;
1911         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1912                 return ($self->{last_rev}, $self->{last_commit});
1913         }
1914         my $c = ::verify_ref($self->refname.'^0');
1915         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1916                 my $rev = (::cmt_metadata($c))[1];
1917                 if (defined $rev) {
1918                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1919                         return ($rev, $c);
1920                 }
1921         }
1922         my $map_path = $self->map_path;
1923         unless (-e $map_path) {
1924                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1925                 return (undef, undef);
1926         }
1927         my ($rev, $commit) = $self->rev_map_max(1);
1928         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1929         return ($rev, $commit);
1930 }
1931
1932 sub get_fetch_range {
1933         my ($self, $min, $max) = @_;
1934         $max ||= $self->ra->get_latest_revnum;
1935         $min ||= $self->rev_map_max;
1936         (++$min, $max);
1937 }
1938
1939 sub tmp_config {
1940         my (@args) = @_;
1941         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1942         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1943         if (! -f $config && -f $old_def_config) {
1944                 rename $old_def_config, $config or
1945                        die "Failed rename $old_def_config => $config: $!\n";
1946         }
1947         my $old_config = $ENV{GIT_CONFIG};
1948         $ENV{GIT_CONFIG} = $config;
1949         $@ = undef;
1950         my @ret = eval {
1951                 unless (-f $config) {
1952                         mkfile($config);
1953                         open my $fh, '>', $config or
1954                             die "Can't open $config: $!\n";
1955                         print $fh "; This file is used internally by ",
1956                                   "git-svn\n" or die
1957                                   "Couldn't write to $config: $!\n";
1958                         print $fh "; You should not have to edit it\n" or
1959                               die "Couldn't write to $config: $!\n";
1960                         close $fh or die "Couldn't close $config: $!\n";
1961                 }
1962                 command('config', @args);
1963         };
1964         my $err = $@;
1965         if (defined $old_config) {
1966                 $ENV{GIT_CONFIG} = $old_config;
1967         } else {
1968                 delete $ENV{GIT_CONFIG};
1969         }
1970         die $err if $err;
1971         wantarray ? @ret : $ret[0];
1972 }
1973
1974 sub tmp_index_do {
1975         my ($self, $sub) = @_;
1976         my $old_index = $ENV{GIT_INDEX_FILE};
1977         $ENV{GIT_INDEX_FILE} = $self->{index};
1978         $@ = undef;
1979         my @ret = eval {
1980                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1981                 mkpath([$dir]) unless -d $dir;
1982                 &$sub;
1983         };
1984         my $err = $@;
1985         if (defined $old_index) {
1986                 $ENV{GIT_INDEX_FILE} = $old_index;
1987         } else {
1988                 delete $ENV{GIT_INDEX_FILE};
1989         }
1990         die $err if $err;
1991         wantarray ? @ret : $ret[0];
1992 }
1993
1994 sub assert_index_clean {
1995         my ($self, $treeish) = @_;
1996
1997         $self->tmp_index_do(sub {
1998                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1999                 my $x = command_oneline('write-tree');
2000                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2001                            /^tree ($::sha1)/mo);
2002                 return if $y eq $x;
2003
2004                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2005                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2006                 command_noisy('read-tree', $treeish);
2007                 $x = command_oneline('write-tree');
2008                 if ($y ne $x) {
2009                         ::fatal "trees ($treeish) $y != $x\n",
2010                                 "Something is seriously wrong...";
2011                 }
2012         });
2013 }
2014
2015 sub get_commit_parents {
2016         my ($self, $log_entry) = @_;
2017         my (%seen, @ret, @tmp);
2018         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2019         if (my $ip = $self->{inject_parents}) {
2020                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2021                         push @tmp, $commit;
2022                 }
2023         }
2024         if (my $cur = ::verify_ref($self->refname.'^0')) {
2025                 push @tmp, $cur;
2026         }
2027         if (my $ipd = $self->{inject_parents_dcommit}) {
2028                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2029                         push @tmp, @$commit;
2030                 }
2031         }
2032         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2033         while (my $p = shift @tmp) {
2034                 next if $seen{$p};
2035                 $seen{$p} = 1;
2036                 push @ret, $p;
2037                 # MAXPARENT is defined to 16 in commit-tree.c:
2038                 last if @ret >= 16;
2039         }
2040         if (@tmp) {
2041                 die "r$log_entry->{revision}: No room for parents:\n\t",
2042                     join("\n\t", @tmp), "\n";
2043         }
2044         @ret;
2045 }
2046
2047 sub rewrite_root {
2048         my ($self) = @_;
2049         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2050         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2051         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2052         if ($rwr) {
2053                 $rwr =~ s#/+$##;
2054                 if ($rwr !~ m#^[a-z\+]+://#) {
2055                         die "$rwr is not a valid URL (key: $k)\n";
2056                 }
2057         }
2058         $self->{-rewrite_root} = $rwr;
2059 }
2060
2061 sub metadata_url {
2062         my ($self) = @_;
2063         ($self->rewrite_root || $self->{url}) .
2064            (length $self->{path} ? '/' . $self->{path} : '');
2065 }
2066
2067 sub full_url {
2068         my ($self) = @_;
2069         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2070 }
2071
2072
2073 sub set_commit_header_env {
2074         my ($log_entry) = @_;
2075         my %env;
2076         foreach my $ned (qw/NAME EMAIL DATE/) {
2077                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2078                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2079                 }
2080         }
2081
2082         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2083         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2084         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2085
2086         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2087                                                 ? $log_entry->{commit_name}
2088                                                 : $log_entry->{name};
2089         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2090                                                 ? $log_entry->{commit_email}
2091                                                 : $log_entry->{email};
2092         \%env;
2093 }
2094
2095 sub restore_commit_header_env {
2096         my ($env) = @_;
2097         foreach my $ned (qw/NAME EMAIL DATE/) {
2098                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2099                         my $k = "GIT_${ac}_${ned}";
2100                         if (defined $env->{$k}) {
2101                                 $ENV{$k} = $env->{$k};
2102                         } else {
2103                                 delete $ENV{$k};
2104                         }
2105                 }
2106         }
2107 }
2108
2109 sub gc {
2110         command_noisy('gc', '--auto');
2111 };
2112
2113 sub do_git_commit {
2114         my ($self, $log_entry) = @_;
2115         my $lr = $self->last_rev;
2116         if (defined $lr && $lr >= $log_entry->{revision}) {
2117                 die "Last fetched revision of ", $self->refname,
2118                     " was r$lr, but we are about to fetch: ",
2119                     "r$log_entry->{revision}!\n";
2120         }
2121         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2122                 croak "$log_entry->{revision} = $c already exists! ",
2123                       "Why are we refetching it?\n";
2124         }
2125         my $old_env = set_commit_header_env($log_entry);
2126         my $tree = $log_entry->{tree};
2127         if (!defined $tree) {
2128                 $tree = $self->tmp_index_do(sub {
2129                                             command_oneline('write-tree') });
2130         }
2131         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2132
2133         my @exec = ('git-commit-tree', $tree);
2134         foreach ($self->get_commit_parents($log_entry)) {
2135                 push @exec, '-p', $_;
2136         }
2137         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2138                                                                    or croak $!;
2139         print $msg_fh $log_entry->{log} or croak $!;
2140         restore_commit_header_env($old_env);
2141         unless ($self->no_metadata) {
2142                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2143                               or croak $!;
2144         }
2145         $msg_fh->flush == 0 or croak $!;
2146         close $msg_fh or croak $!;
2147         chomp(my $commit = do { local $/; <$out_fh> });
2148         close $out_fh or croak $!;
2149         waitpid $pid, 0;
2150         croak $? if $?;
2151         if ($commit !~ /^$::sha1$/o) {
2152                 die "Failed to commit, invalid sha1: $commit\n";
2153         }
2154
2155         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2156
2157         $self->{last_rev} = $log_entry->{revision};
2158         $self->{last_commit} = $commit;
2159         print "r$log_entry->{revision}";
2160         if (defined $log_entry->{svm_revision}) {
2161                  print " (\@$log_entry->{svm_revision})";
2162                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2163                                    0, $self->svm_uuid);
2164         }
2165         print " = $commit ($self->{ref_id})\n";
2166         if (--$_gc_nr == 0) {
2167                 $_gc_nr = $_gc_period;
2168                 gc();
2169         }
2170         return $commit;
2171 }
2172
2173 sub match_paths {
2174         my ($self, $paths, $r) = @_;
2175         return 1 if $self->{path} eq '';
2176         if (my $path = $paths->{"/$self->{path}"}) {
2177                 return ($path->{action} eq 'D') ? 0 : 1;
2178         }
2179         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2180         if (grep /$self->{path_regex}/, keys %$paths) {
2181                 return 1;
2182         }
2183         my $c = '';
2184         foreach (split m#/#, $self->{path}) {
2185                 $c .= "/$_";
2186                 next unless ($paths->{$c} &&
2187                              ($paths->{$c}->{action} =~ /^[AR]$/));
2188                 if ($self->ra->check_path($self->{path}, $r) ==
2189                     $SVN::Node::dir) {
2190                         return 1;
2191                 }
2192         }
2193         return 0;
2194 }
2195
2196 sub find_parent_branch {
2197         my ($self, $paths, $rev) = @_;
2198         return undef unless $self->follow_parent;
2199         unless (defined $paths) {
2200                 my $err_handler = $SVN::Error::handler;
2201                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2202                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2203                                    $paths =
2204                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
2205                 $SVN::Error::handler = $err_handler;
2206         }
2207         return undef unless defined $paths;
2208
2209         # look for a parent from another branch:
2210         my @b_path_components = split m#/#, $self->rel_path;
2211         my @a_path_components;
2212         my $i;
2213         while (@b_path_components) {
2214                 $i = $paths->{'/'.join('/', @b_path_components)};
2215                 last if $i && defined $i->{copyfrom_path};
2216                 unshift(@a_path_components, pop(@b_path_components));
2217         }
2218         return undef unless defined $i && defined $i->{copyfrom_path};
2219         my $branch_from = $i->{copyfrom_path};
2220         if (@a_path_components) {
2221                 print STDERR "branch_from: $branch_from => ";
2222                 $branch_from .= '/'.join('/', @a_path_components);
2223                 print STDERR $branch_from, "\n";
2224         }
2225         my $r = $i->{copyfrom_rev};
2226         my $repos_root = $self->ra->{repos_root};
2227         my $url = $self->ra->{url};
2228         my $new_url = $repos_root . $branch_from;
2229         print STDERR  "Found possible branch point: ",
2230                       "$new_url => ", $self->full_url, ", $r\n";
2231         $branch_from =~ s#^/##;
2232         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2233         unless ($gs) {
2234                 my $ref_id = $self->{ref_id};
2235                 $ref_id =~ s/\@\d+$//;
2236                 $ref_id .= "\@$r";
2237                 # just grow a tail if we're not unique enough :x
2238                 $ref_id .= '-' while find_ref($ref_id);
2239                 print STDERR "Initializing parent: $ref_id\n";
2240                 my ($u, $p) = ($new_url, '');
2241                 if ($u =~ s#^\Q$url\E(/|$)##) {
2242                         $p = $u;
2243                         $u = $url;
2244                 }
2245                 $gs = Git::SVN->init($u, $p, $self->{repo_id}, $ref_id, 1);
2246         }
2247         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2248         if (!defined $r0 || !defined $parent) {
2249                 my ($base, $head) = parse_revision_argument(0, $r);
2250                 if ($base <= $r) {
2251                         $gs->fetch($base, $r);
2252                 }
2253                 ($r0, $parent) = $gs->last_rev_commit;
2254         }
2255         if (defined $r0 && defined $parent) {
2256                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2257                 my $ed;
2258                 if ($self->ra->can_do_switch) {
2259                         $self->assert_index_clean($parent);
2260                         print STDERR "Following parent with do_switch\n";
2261                         # do_switch works with svn/trunk >= r22312, but that
2262                         # is not included with SVN 1.4.3 (the latest version
2263                         # at the moment), so we can't rely on it
2264                         $self->{last_commit} = $parent;
2265                         $ed = SVN::Git::Fetcher->new($self);
2266                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2267                                               $self->full_url, $ed)
2268                           or die "SVN connection failed somewhere...\n";
2269                 } elsif ($self->ra->trees_match($new_url, $r0,
2270                                                 $self->full_url, $rev)) {
2271                         print STDERR "Trees match:\n",
2272                                      "  $new_url\@$r0\n",
2273                                      "  ${\$self->full_url}\@$rev\n",
2274                                      "Following parent with no changes\n";
2275                         $self->tmp_index_do(sub {
2276                             command_noisy('read-tree', $parent);
2277                         });
2278                         $self->{last_commit} = $parent;
2279                 } else {
2280                         print STDERR "Following parent with do_update\n";
2281                         $ed = SVN::Git::Fetcher->new($self);
2282                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2283                           or die "SVN connection failed somewhere...\n";
2284                 }
2285                 print STDERR "Successfully followed parent\n";
2286                 return $self->make_log_entry($rev, [$parent], $ed);
2287         }
2288         return undef;
2289 }
2290
2291 sub do_fetch {
2292         my ($self, $paths, $rev) = @_;
2293         my $ed;
2294         my ($last_rev, @parents);
2295         if (my $lc = $self->last_commit) {
2296                 # we can have a branch that was deleted, then re-added
2297                 # under the same name but copied from another path, in
2298                 # which case we'll have multiple parents (we don't
2299                 # want to break the original ref, nor lose copypath info):
2300                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2301                         push @{$log_entry->{parents}}, $lc;
2302                         return $log_entry;
2303                 }
2304                 $ed = SVN::Git::Fetcher->new($self);
2305                 $last_rev = $self->{last_rev};
2306                 $ed->{c} = $lc;
2307                 @parents = ($lc);
2308         } else {
2309                 $last_rev = $rev;
2310                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2311                         return $log_entry;
2312                 }
2313                 $ed = SVN::Git::Fetcher->new($self);
2314         }
2315         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2316                 die "SVN connection failed somewhere...\n";
2317         }
2318         $self->make_log_entry($rev, \@parents, $ed);
2319 }
2320
2321 sub get_untracked {
2322         my ($self, $ed) = @_;
2323         my @out;
2324         my $h = $ed->{empty};
2325         foreach (sort keys %$h) {
2326                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2327                 push @out, "  $act: " . uri_encode($_);
2328                 warn "W: $act: $_\n";
2329         }
2330         foreach my $t (qw/dir_prop file_prop/) {
2331                 $h = $ed->{$t} or next;
2332                 foreach my $path (sort keys %$h) {
2333                         my $ppath = $path eq '' ? '.' : $path;
2334                         foreach my $prop (sort keys %{$h->{$path}}) {
2335                                 next if $SKIP_PROP{$prop};
2336                                 my $v = $h->{$path}->{$prop};
2337                                 my $t_ppath_prop = "$t: " .
2338                                                     uri_encode($ppath) . ' ' .
2339                                                     uri_encode($prop);
2340                                 if (defined $v) {
2341                                         push @out, "  +$t_ppath_prop " .
2342                                                    uri_encode($v);
2343                                 } else {
2344                                         push @out, "  -$t_ppath_prop";
2345                                 }
2346                         }
2347                 }
2348         }
2349         foreach my $t (qw/absent_file absent_directory/) {
2350                 $h = $ed->{$t} or next;
2351                 foreach my $parent (sort keys %$h) {
2352                         foreach my $path (sort @{$h->{$parent}}) {
2353                                 push @out, "  $t: " .
2354                                            uri_encode("$parent/$path");
2355                                 warn "W: $t: $parent/$path ",
2356                                      "Insufficient permissions?\n";
2357                         }
2358                 }
2359         }
2360         \@out;
2361 }
2362
2363 sub parse_svn_date {
2364         my $date = shift || return '+0000 1970-01-01 00:00:00';
2365         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2366                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2367                                          croak "Unable to parse date: $date\n";
2368         "+0000 $Y-$m-$d $H:$M:$S";
2369 }
2370
2371 sub check_author {
2372         my ($author) = @_;
2373         if (!defined $author || length $author == 0) {
2374                 $author = '(no author)';
2375         }
2376         if (defined $::_authors && ! defined $::users{$author}) {
2377                 die "Author: $author not defined in $::_authors file\n";
2378         }
2379         $author;
2380 }
2381
2382 sub make_log_entry {
2383         my ($self, $rev, $parents, $ed) = @_;
2384         my $untracked = $self->get_untracked($ed);
2385
2386         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2387         print $un "r$rev\n" or croak $!;
2388         print $un $_, "\n" foreach @$untracked;
2389         my %log_entry = ( parents => $parents || [], revision => $rev,
2390                           log => '');
2391
2392         my $headrev;
2393         my $logged = delete $self->{logged_rev_props};
2394         if (!$logged || $self->{-want_revprops}) {
2395                 my $rp = $self->ra->rev_proplist($rev);
2396                 foreach (sort keys %$rp) {
2397                         my $v = $rp->{$_};
2398                         if (/^svn:(author|date|log)$/) {
2399                                 $log_entry{$1} = $v;
2400                         } elsif ($_ eq 'svm:headrev') {
2401                                 $headrev = $v;
2402                         } else {
2403                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2404                                           uri_encode($v), "\n";
2405                         }
2406                 }
2407         } else {
2408                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2409         }
2410         close $un or croak $!;
2411
2412         $log_entry{date} = parse_svn_date($log_entry{date});
2413         $log_entry{log} .= "\n";
2414         my $author = $log_entry{author} = check_author($log_entry{author});
2415         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2416                                                        : ($author, undef);
2417
2418         my ($commit_name, $commit_email) = ($name, $email);
2419         if ($_use_log_author) {
2420                 my $name_field;
2421                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2422                         $name_field = $1;
2423                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2424                         $name_field = $1;
2425                 }
2426                 if (!defined $name_field) {
2427                         #
2428                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2429                         ($name, $email) = ($1, $2);
2430                 } elsif ($name_field =~ /(.*)@/) {
2431                         ($name, $email) = ($1, $name_field);
2432                 } else {
2433                         ($name, $email) = ($name_field, 'unknown');
2434                 }
2435         }
2436         if (defined $headrev && $self->use_svm_props) {
2437                 if ($self->rewrite_root) {
2438                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2439                             "options set!\n";
2440                 }
2441                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2442                 # we don't want "SVM: initializing mirror for junk" ...
2443                 return undef if $r == 0;
2444                 my $svm = $self->svm;
2445                 if ($uuid ne $svm->{uuid}) {
2446                         die "UUID mismatch on SVM path:\n",
2447                             "expected: $svm->{uuid}\n",
2448                             "     got: $uuid\n";
2449                 }
2450                 my $full_url = $self->full_url;
2451                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2452                              die "Failed to replace '$svm->{replace}' with ",
2453                                  "'$svm->{source}' in $full_url\n";
2454                 # throw away username for storing in records
2455                 remove_username($full_url);
2456                 $log_entry{metadata} = "$full_url\@$r $uuid";
2457                 $log_entry{svm_revision} = $r;
2458                 $email ||= "$author\@$uuid";
2459                 $commit_email ||= "$author\@$uuid";
2460         } elsif ($self->use_svnsync_props) {
2461                 my $full_url = $self->svnsync->{url};
2462                 $full_url .= "/$self->{path}" if length $self->{path};
2463                 remove_username($full_url);
2464                 my $uuid = $self->svnsync->{uuid};
2465                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2466                 $email ||= "$author\@$uuid";
2467                 $commit_email ||= "$author\@$uuid";
2468         } else {
2469                 my $url = $self->metadata_url;
2470                 remove_username($url);
2471                 $log_entry{metadata} = "$url\@$rev " .
2472                                        $self->ra->get_uuid;
2473                 $email ||= "$author\@" . $self->ra->get_uuid;
2474                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2475         }
2476         $log_entry{name} = $name;
2477         $log_entry{email} = $email;
2478         $log_entry{commit_name} = $commit_name;
2479         $log_entry{commit_email} = $commit_email;
2480         \%log_entry;
2481 }
2482
2483 sub fetch {
2484         my ($self, $min_rev, $max_rev, @parents) = @_;
2485         my ($last_rev, $last_commit) = $self->last_rev_commit;
2486         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2487         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2488 }
2489
2490 sub set_tree_cb {
2491         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2492         $self->{inject_parents} = { $rev => $tree };
2493         $self->fetch(undef, undef);
2494 }
2495
2496 sub set_tree {
2497         my ($self, $tree) = (shift, shift);
2498         my $log_entry = ::get_commit_entry($tree);
2499         unless ($self->{last_rev}) {
2500                 fatal("Must have an existing revision to commit");
2501         }
2502         my %ed_opts = ( r => $self->{last_rev},
2503                         log => $log_entry->{log},
2504                         ra => $self->ra,
2505                         tree_a => $self->{last_commit},
2506                         tree_b => $tree,
2507                         editor_cb => sub {
2508                                $self->set_tree_cb($log_entry, $tree, @_) },
2509                         svn_path => $self->{path} );
2510         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2511                 print "No changes\nr$self->{last_rev} = $tree\n";
2512         }
2513 }
2514
2515 sub rebuild_from_rev_db {
2516         my ($self, $path) = @_;
2517         my $r = -1;
2518         open my $fh, '<', $path or croak "open: $!";
2519         while (<$fh>) {
2520                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2521                 chomp($_);
2522                 ++$r;
2523                 next if $_ eq ('0' x 40);
2524                 $self->rev_map_set($r, $_);
2525                 print "r$r = $_\n";
2526         }
2527         close $fh or croak "close: $!";
2528         unlink $path or croak "unlink: $!";
2529 }
2530
2531 sub rebuild {
2532         my ($self) = @_;
2533         my $map_path = $self->map_path;
2534         return if (-e $map_path && ! -z $map_path);
2535         return unless ::verify_ref($self->refname.'^0');
2536         if ($self->use_svm_props || $self->no_metadata) {
2537                 my $rev_db = $self->rev_db_path;
2538                 $self->rebuild_from_rev_db($rev_db);
2539                 if ($self->use_svm_props) {
2540                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2541                         $self->rebuild_from_rev_db($svm_rev_db);
2542                 }
2543                 $self->unlink_rev_db_symlink;
2544                 return;
2545         }
2546         print "Rebuilding $map_path ...\n";
2547         my ($log, $ctx) =
2548             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2549                                 $self->refname, '--');
2550         my $full_url = $self->full_url;
2551         remove_username($full_url);
2552         my $svn_uuid = $self->ra_uuid;
2553         my $c;
2554         while (<$log>) {
2555                 if ( m{^commit ($::sha1)$} ) {
2556                         $c = $1;
2557                         next;
2558                 }
2559                 next unless s{^\s*(git-svn-id:)}{$1};
2560                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2561                 remove_username($url);
2562
2563                 # ignore merges (from set-tree)
2564                 next if (!defined $rev || !$uuid);
2565
2566                 # if we merged or otherwise started elsewhere, this is
2567                 # how we break out of it
2568                 if (($uuid ne $svn_uuid) ||
2569                     ($full_url && $url && ($url ne $full_url))) {
2570                         next;
2571                 }
2572
2573                 $self->rev_map_set($rev, $c);
2574                 print "r$rev = $c\n";
2575         }
2576         command_close_pipe($log, $ctx);
2577         print "Done rebuilding $map_path\n";
2578         my $rev_db_path = $self->rev_db_path;
2579         if (-f $self->rev_db_path) {
2580                 unlink $self->rev_db_path or croak "unlink: $!";
2581         }
2582         $self->unlink_rev_db_symlink;
2583 }
2584
2585 # rev_map:
2586 # Tie::File seems to be prone to offset errors if revisions get sparse,
2587 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2588 # one of my favorite modules is out :<  Next up would be one of the DBM
2589 # modules, but I'm not sure which is most portable...
2590 #
2591 # This is the replacement for the rev_db format, which was too big
2592 # and inefficient for large repositories with a lot of sparse history
2593 # (mainly tags)
2594 #
2595 # The format is this:
2596 #   - 24 bytes for every record,
2597 #     * 4 bytes for the integer representing an SVN revision number
2598 #     * 20 bytes representing the sha1 of a git commit
2599 #   - No empty padding records like the old format
2600 #     (except the last record, which can be overwritten)
2601 #   - new records are written append-only since SVN revision numbers
2602 #     increase monotonically
2603 #   - lookups on SVN revision number are done via a binary search
2604 #   - Piping the file to xxd -c24 is a good way of dumping it for
2605 #     viewing or editing (piped back through xxd -r), should the need
2606 #     ever arise.
2607 #   - The last record can be padding revision with an all-zero sha1
2608 #     This is used to optimize fetch performance when using multiple
2609 #     "fetch" directives in .git/config
2610 #
2611 # These files are disposable unless noMetadata or useSvmProps is set
2612
2613 sub _rev_map_set {
2614         my ($fh, $rev, $commit) = @_;
2615
2616         my $size = (stat($fh))[7];
2617         ($size % 24) == 0 or croak "inconsistent size: $size";
2618
2619         my $wr_offset = 0;
2620         if ($size > 0) {
2621                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2622                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2623                 $read == 24 or croak "read only $read bytes (!= 24)";
2624                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2625                 if ($last_commit eq ('0' x40)) {
2626                         if ($size >= 48) {
2627                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2628                                 $read = sysread($fh, $buf, 24) or
2629                                     croak "read: $!";
2630                                 $read == 24 or
2631                                     croak "read only $read bytes (!= 24)";
2632                                 ($last_rev, $last_commit) =
2633                                     unpack(rev_map_fmt, $buf);
2634                                 if ($last_commit eq ('0' x40)) {
2635                                         croak "inconsistent .rev_map\n";
2636                                 }
2637                         }
2638                         if ($last_rev >= $rev) {
2639                                 croak "last_rev is higher!: $last_rev >= $rev";
2640                         }
2641                         $wr_offset = -24;
2642                 }
2643         }
2644         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2645         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2646           croak "write: $!";
2647 }
2648
2649 sub mkfile {
2650         my ($path) = @_;
2651         unless (-e $path) {
2652                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2653                 mkpath([$dir]) unless -d $dir;
2654                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2655                 close $fh or die "Couldn't close (create) $path: $!\n";
2656         }
2657 }
2658
2659 sub rev_map_set {
2660         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2661         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2662         my $db = $self->map_path($uuid);
2663         my $db_lock = "$db.lock";
2664         my $sig;
2665         if ($update_ref) {
2666                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2667                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2668         }
2669         mkfile($db);
2670
2671         $LOCKFILES{$db_lock} = 1;
2672         my $sync;
2673         # both of these options make our .rev_db file very, very important
2674         # and we can't afford to lose it because rebuild() won't work
2675         if ($self->use_svm_props || $self->no_metadata) {
2676                 $sync = 1;
2677                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2678                                            "Failed to copy: ",
2679                                            "$db => $db_lock ($!)\n";
2680         } else {
2681                 rename $db, $db_lock or die "rev_map_set(@_): ",
2682                                             "Failed to rename: ",
2683                                             "$db => $db_lock ($!)\n";
2684         }
2685
2686         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2687              or croak "Couldn't open $db_lock: $!\n";
2688         _rev_map_set($fh, $rev, $commit);
2689         if ($sync) {
2690                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2691                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2692         }
2693         close $fh or croak $!;
2694         if ($update_ref) {
2695                 $_head = $self;
2696                 command_noisy('update-ref', '-m', "r$rev",
2697                               $self->refname, $commit);
2698         }
2699         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2700                                     "$db_lock => $db ($!)\n";
2701         delete $LOCKFILES{$db_lock};
2702         if ($update_ref) {
2703                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2704                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2705                 kill $sig, $$ if defined $sig;
2706         }
2707 }
2708
2709 # If want_commit, this will return an array of (rev, commit) where
2710 # commit _must_ be a valid commit in the archive.
2711 # Otherwise, it'll return the max revision (whether or not the
2712 # commit is valid or just a 0x40 placeholder).
2713 sub rev_map_max {
2714         my ($self, $want_commit) = @_;
2715         $self->rebuild;
2716         my $map_path = $self->map_path;
2717         stat $map_path or return $want_commit ? (0, undef) : 0;
2718         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2719         my $size = (stat($fh))[7];
2720         ($size % 24) == 0 or croak "inconsistent size: $size";
2721
2722         if ($size == 0) {
2723                 close $fh or croak "close: $!";
2724                 return $want_commit ? (0, undef) : 0;
2725         }
2726
2727         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2728         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2729         my ($r, $c) = unpack(rev_map_fmt, $buf);
2730         if ($want_commit && $c eq ('0' x40)) {
2731                 if ($size < 48) {
2732                         return $want_commit ? (0, undef) : 0;
2733                 }
2734                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2735                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2736                 ($r, $c) = unpack(rev_map_fmt, $buf);
2737                 if ($c eq ('0'x40)) {
2738                         croak "Penultimate record is all-zeroes in $map_path";
2739                 }
2740         }
2741         close $fh or croak "close: $!";
2742         $want_commit ? ($r, $c) : $r;
2743 }
2744
2745 sub rev_map_get {
2746         my ($self, $rev, $uuid) = @_;
2747         my $map_path = $self->map_path($uuid);
2748         return undef unless -e $map_path;
2749
2750         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2751         my $size = (stat($fh))[7];
2752         ($size % 24) == 0 or croak "inconsistent size: $size";
2753
2754         if ($size == 0) {
2755                 close $fh or croak "close: $fh";
2756                 return undef;
2757         }
2758
2759         my ($l, $u) = (0, $size - 24);
2760         my ($r, $c, $buf);
2761
2762         while ($l <= $u) {
2763                 my $i = int(($l/24 + $u/24) / 2) * 24;
2764                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2765                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2766                 my ($r, $c) = unpack('NH40', $buf);
2767
2768                 if ($r < $rev) {
2769                         $l = $i + 24;
2770                 } elsif ($r > $rev) {
2771                         $u = $i - 24;
2772                 } else { # $r == $rev
2773                         close($fh) or croak "close: $!";
2774                         return $c eq ('0' x 40) ? undef : $c;
2775                 }
2776         }
2777         close($fh) or croak "close: $!";
2778         undef;
2779 }
2780
2781 # Finds the first svn revision that exists on (if $eq_ok is true) or
2782 # before $rev for the current branch.  It will not search any lower
2783 # than $min_rev.  Returns the git commit hash and svn revision number
2784 # if found, else (undef, undef).
2785 sub find_rev_before {
2786         my ($self, $rev, $eq_ok, $min_rev) = @_;
2787         --$rev unless $eq_ok;
2788         $min_rev ||= 1;
2789         while ($rev >= $min_rev) {
2790                 if (my $c = $self->rev_map_get($rev)) {
2791                         return ($rev, $c);
2792                 }
2793                 --$rev;
2794         }
2795         return (undef, undef);
2796 }
2797
2798 # Finds the first svn revision that exists on (if $eq_ok is true) or
2799 # after $rev for the current branch.  It will not search any higher
2800 # than $max_rev.  Returns the git commit hash and svn revision number
2801 # if found, else (undef, undef).
2802 sub find_rev_after {
2803         my ($self, $rev, $eq_ok, $max_rev) = @_;
2804         ++$rev unless $eq_ok;
2805         $max_rev ||= $self->rev_map_max;
2806         while ($rev <= $max_rev) {
2807                 if (my $c = $self->rev_map_get($rev)) {
2808                         return ($rev, $c);
2809                 }
2810                 ++$rev;
2811         }
2812         return (undef, undef);
2813 }
2814
2815 sub _new {
2816         my ($class, $repo_id, $ref_id, $path) = @_;
2817         unless (defined $repo_id && length $repo_id) {
2818                 $repo_id = $Git::SVN::default_repo_id;
2819         }
2820         unless (defined $ref_id && length $ref_id) {
2821                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2822         }
2823         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2824         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2825         $_[3] = $path = '' unless (defined $path);
2826         mkpath(["$ENV{GIT_DIR}/svn"]);
2827         bless {
2828                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2829                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2830                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2831 }
2832
2833 # for read-only access of old .rev_db formats
2834 sub unlink_rev_db_symlink {
2835         my ($self) = @_;
2836         my $link = $self->rev_db_path;
2837         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2838         if (-l $link) {
2839                 unlink $link or croak "unlink: $link failed!";
2840         }
2841 }
2842
2843 sub rev_db_path {
2844         my ($self, $uuid) = @_;
2845         my $db_path = $self->map_path($uuid);
2846         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2847             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2848         $db_path;
2849 }
2850
2851 # the new replacement for .rev_db
2852 sub map_path {
2853         my ($self, $uuid) = @_;
2854         $uuid ||= $self->ra_uuid;
2855         "$self->{map_root}.$uuid";
2856 }
2857
2858 sub uri_encode {
2859         my ($f) = @_;
2860         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2861         $f
2862 }
2863
2864 sub remove_username {
2865         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2866 }
2867
2868 package Git::SVN::Prompt;
2869 use strict;
2870 use warnings;
2871 require SVN::Core;
2872 use vars qw/$_no_auth_cache $_username/;
2873
2874 sub simple {
2875         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2876         $may_save = undef if $_no_auth_cache;
2877         $default_username = $_username if defined $_username;
2878         if (defined $default_username && length $default_username) {
2879                 if (defined $realm && length $realm) {
2880                         print STDERR "Authentication realm: $realm\n";
2881                         STDERR->flush;
2882                 }
2883                 $cred->username($default_username);
2884         } else {
2885                 username($cred, $realm, $may_save, $pool);
2886         }
2887         $cred->password(_read_password("Password for '" .
2888                                        $cred->username . "': ", $realm));
2889         $cred->may_save($may_save);
2890         $SVN::_Core::SVN_NO_ERROR;
2891 }
2892
2893 sub ssl_server_trust {
2894         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2895         $may_save = undef if $_no_auth_cache;
2896         print STDERR "Error validating server certificate for '$realm':\n";
2897         {
2898                 no warnings 'once';
2899                 # All variables SVN::Auth::SSL::* are used only once,
2900                 # so we're shutting up Perl warnings about this.
2901                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2902                         print STDERR " - The certificate is not issued ",
2903                             "by a trusted authority. Use the\n",
2904                             "   fingerprint to validate ",
2905                             "the certificate manually!\n";
2906                 }
2907                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2908                         print STDERR " - The certificate hostname ",
2909                             "does not match.\n";
2910                 }
2911                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2912                         print STDERR " - The certificate is not yet valid.\n";
2913                 }
2914                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2915                         print STDERR " - The certificate has expired.\n";
2916                 }
2917                 if ($failures & $SVN::Auth::SSL::OTHER) {
2918                         print STDERR " - The certificate has ",
2919                             "an unknown error.\n";
2920                 }
2921         } # no warnings 'once'
2922         printf STDERR
2923                 "Certificate information:\n".
2924                 " - Hostname: %s\n".
2925                 " - Valid: from %s until %s\n".
2926                 " - Issuer: %s\n".
2927                 " - Fingerprint: %s\n",
2928                 map $cert_info->$_, qw(hostname valid_from valid_until
2929                                        issuer_dname fingerprint);
2930         my $choice;
2931 prompt:
2932         print STDERR $may_save ?
2933               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2934               "(R)eject or accept (t)emporarily? ";
2935         STDERR->flush;
2936         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2937         if ($choice =~ /^t$/i) {
2938                 $cred->may_save(undef);
2939         } elsif ($choice =~ /^r$/i) {
2940                 return -1;
2941         } elsif ($may_save && $choice =~ /^p$/i) {
2942                 $cred->may_save($may_save);
2943         } else {
2944                 goto prompt;
2945         }
2946         $cred->accepted_failures($failures);
2947         $SVN::_Core::SVN_NO_ERROR;
2948 }
2949
2950 sub ssl_client_cert {
2951         my ($cred, $realm, $may_save, $pool) = @_;
2952         $may_save = undef if $_no_auth_cache;
2953         print STDERR "Client certificate filename: ";
2954         STDERR->flush;
2955         chomp(my $filename = <STDIN>);
2956         $cred->cert_file($filename);
2957         $cred->may_save($may_save);
2958         $SVN::_Core::SVN_NO_ERROR;
2959 }
2960
2961 sub ssl_client_cert_pw {
2962         my ($cred, $realm, $may_save, $pool) = @_;
2963         $may_save = undef if $_no_auth_cache;
2964         $cred->password(_read_password("Password: ", $realm));
2965         $cred->may_save($may_save);
2966         $SVN::_Core::SVN_NO_ERROR;
2967 }
2968
2969 sub username {
2970         my ($cred, $realm, $may_save, $pool) = @_;
2971         $may_save = undef if $_no_auth_cache;
2972         if (defined $realm && length $realm) {
2973                 print STDERR "Authentication realm: $realm\n";
2974         }
2975         my $username;
2976         if (defined $_username) {
2977                 $username = $_username;
2978         } else {
2979                 print STDERR "Username: ";
2980                 STDERR->flush;
2981                 chomp($username = <STDIN>);
2982         }
2983         $cred->username($username);
2984         $cred->may_save($may_save);
2985         $SVN::_Core::SVN_NO_ERROR;
2986 }
2987
2988 sub _read_password {
2989         my ($prompt, $realm) = @_;
2990         print STDERR $prompt;
2991         STDERR->flush;
2992         require Term::ReadKey;
2993         Term::ReadKey::ReadMode('noecho');
2994         my $password = '';
2995         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2996                 last if $key =~ /[\012\015]/; # \n\r
2997                 $password .= $key;
2998         }
2999         Term::ReadKey::ReadMode('restore');
3000         print STDERR "\n";
3001         STDERR->flush;
3002         $password;
3003 }
3004
3005 package SVN::Git::Fetcher;
3006 use vars qw/@ISA/;
3007 use strict;
3008 use warnings;
3009 use Carp qw/croak/;
3010 use IO::File qw//;
3011
3012 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3013 sub new {
3014         my ($class, $git_svn) = @_;
3015         my $self = SVN::Delta::Editor->new;
3016         bless $self, $class;
3017         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3018         $self->{empty} = {};
3019         $self->{dir_prop} = {};
3020         $self->{file_prop} = {};
3021         $self->{absent_dir} = {};
3022         $self->{absent_file} = {};
3023         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3024         $self;
3025 }
3026
3027 sub set_path_strip {
3028         my ($self, $path) = @_;
3029         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3030 }
3031
3032 sub open_root {
3033         { path => '' };
3034 }
3035
3036 sub open_directory {
3037         my ($self, $path, $pb, $rev) = @_;
3038         { path => $path };
3039 }
3040
3041 sub git_path {
3042         my ($self, $path) = @_;
3043         if ($self->{path_strip}) {
3044                 $path =~ s!$self->{path_strip}!! or
3045                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3046         }
3047         $path;
3048 }
3049
3050 sub delete_entry {
3051         my ($self, $path, $rev, $pb) = @_;
3052
3053         my $gpath = $self->git_path($path);
3054         return undef if ($gpath eq '');
3055
3056         # remove entire directories.
3057         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3058                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3059                                                      -r --name-only -z/,
3060                                                      $self->{c}, '--', $gpath);
3061                 local $/ = "\0";
3062                 while (<$ls>) {
3063                         chomp;
3064                         $self->{gii}->remove($_);
3065                         print "\tD\t$_\n" unless $::_q;
3066                 }
3067                 print "\tD\t$gpath/\n" unless $::_q;
3068                 command_close_pipe($ls, $ctx);
3069                 $self->{empty}->{$path} = 0
3070         } else {
3071                 $self->{gii}->remove($gpath);
3072                 print "\tD\t$gpath\n" unless $::_q;
3073         }
3074         undef;
3075 }
3076
3077 sub open_file {
3078         my ($self, $path, $pb, $rev) = @_;
3079         my $gpath = $self->git_path($path);
3080         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3081                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3082         unless (defined $mode && defined $blob) {
3083                 die "$path was not found in commit $self->{c} (r$rev)\n";
3084         }
3085         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3086           pool => SVN::Pool->new, action => 'M' };
3087 }
3088
3089 sub add_file {
3090         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3091         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3092         delete $self->{empty}->{$dir};
3093         { path => $path, mode_a => 100644, mode_b => 100644,
3094           pool => SVN::Pool->new, action => 'A' };
3095 }
3096
3097 sub add_directory {
3098         my ($self, $path, $cp_path, $cp_rev) = @_;
3099         my $gpath = $self->git_path($path);
3100         if ($gpath eq '') {
3101                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3102                                                      -r --name-only -z/,
3103                                                      $self->{c});
3104                 local $/ = "\0";
3105                 while (<$ls>) {
3106                         chomp;
3107                         $self->{gii}->remove($_);
3108                         print "\tD\t$_\n" unless $::_q;
3109                 }
3110                 command_close_pipe($ls, $ctx);
3111                 $self->{empty}->{$path} = 0;
3112         }
3113         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3114         delete $self->{empty}->{$dir};
3115         $self->{empty}->{$path} = 1;
3116         { path => $path };
3117 }
3118
3119 sub change_dir_prop {
3120         my ($self, $db, $prop, $value) = @_;
3121         $self->{dir_prop}->{$db->{path}} ||= {};
3122         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3123         undef;
3124 }
3125
3126 sub absent_directory {
3127         my ($self, $path, $pb) = @_;
3128         $self->{absent_dir}->{$pb->{path}} ||= [];
3129         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3130         undef;
3131 }
3132
3133 sub absent_file {
3134         my ($self, $path, $pb) = @_;
3135         $self->{absent_file}->{$pb->{path}} ||= [];
3136         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3137         undef;
3138 }
3139
3140 sub change_file_prop {
3141         my ($self, $fb, $prop, $value) = @_;
3142         if ($prop eq 'svn:executable') {
3143                 if ($fb->{mode_b} != 120000) {
3144                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3145                 }
3146         } elsif ($prop eq 'svn:special') {
3147                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3148         } else {
3149                 $self->{file_prop}->{$fb->{path}} ||= {};
3150                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3151         }
3152         undef;
3153 }
3154
3155 sub apply_textdelta {
3156         my ($self, $fb, $exp) = @_;
3157         my $fh = IO::File->new_tmpfile;
3158         $fh->autoflush(1);
3159         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3160         # (but $base does not,) so dup() it for reading in close_file
3161         open my $dup, '<&', $fh or croak $!;
3162         my $base = IO::File->new_tmpfile;
3163         $base->autoflush(1);
3164         if ($fb->{blob}) {
3165                 defined (my $pid = fork) or croak $!;
3166                 if (!$pid) {
3167                         open STDOUT, '>&', $base or croak $!;
3168                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3169                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3170                 }
3171                 waitpid $pid, 0;
3172                 croak $? if $?;
3173
3174                 if (defined $exp) {
3175                         seek $base, 0, 0 or croak $!;
3176                         my $got = ::md5sum($base);
3177                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3178                             "expected: $exp\n",
3179                             "     got: $got\n" if ($got ne $exp);
3180                 }
3181         }
3182         seek $base, 0, 0 or croak $!;
3183         $fb->{fh} = $dup;
3184         $fb->{base} = $base;
3185         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3186 }
3187
3188 sub close_file {
3189         my ($self, $fb, $exp) = @_;
3190         my $hash;
3191         my $path = $self->git_path($fb->{path});
3192         if (my $fh = $fb->{fh}) {
3193                 if (defined $exp) {
3194                         seek($fh, 0, 0) or croak $!;
3195                         my $got = ::md5sum($fh);
3196                         if ($got ne $exp) {
3197                                 die "Checksum mismatch: $path\n",
3198                                     "expected: $exp\n    got: $got\n";
3199                         }
3200                 }
3201                 sysseek($fh, 0, 0) or croak $!;
3202                 if ($fb->{mode_b} == 120000) {
3203                         eval {
3204                                 sysread($fh, my $buf, 5) == 5 or croak $!;
3205                                 $buf eq 'link ' or die "$path has mode 120000",
3206                                                        " but is not a link";
3207                         };
3208                         if ($@) {
3209                                 warn "$@\n";
3210                                 sysseek($fh, 0, 0) or croak $!;
3211                         }
3212                 }
3213                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3214                 if (!$pid) {
3215                         open STDIN, '<&', $fh or croak $!;
3216                         exec qw/git-hash-object -w --stdin/ or croak $!;
3217                 }
3218                 chomp($hash = do { local $/; <$out> });
3219                 close $out or croak $!;
3220                 close $fh or croak $!;
3221                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3222                 close $fb->{base} or croak $!;
3223         } else {
3224                 $hash = $fb->{blob} or die "no blob information\n";
3225         }
3226         $fb->{pool}->clear;
3227         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3228         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3229         undef;
3230 }
3231
3232 sub abort_edit {
3233         my $self = shift;
3234         $self->{nr} = $self->{gii}->{nr};
3235         delete $self->{gii};
3236         $self->SUPER::abort_edit(@_);
3237 }
3238
3239 sub close_edit {
3240         my $self = shift;
3241         $self->{git_commit_ok} = 1;
3242         $self->{nr} = $self->{gii}->{nr};
3243         delete $self->{gii};
3244         $self->SUPER::close_edit(@_);
3245 }
3246
3247 package SVN::Git::Editor;
3248 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3249 use strict;
3250 use warnings;
3251 use Carp qw/croak/;
3252 use IO::File;
3253
3254 sub new {
3255         my ($class, $opts) = @_;
3256         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3257                 die "$_ required!\n" unless (defined $opts->{$_});
3258         }
3259
3260         my $pool = SVN::Pool->new;
3261         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3262         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3263                                      $opts->{r}, $mods);
3264
3265         # $opts->{ra} functions should not be used after this:
3266         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3267                                                 $opts->{editor_cb}, $pool);
3268         my $self = SVN::Delta::Editor->new(@ce, $pool);
3269         bless $self, $class;
3270         foreach (qw/svn_path r tree_a tree_b/) {
3271                 $self->{$_} = $opts->{$_};
3272         }
3273         $self->{url} = $opts->{ra}->{url};
3274         $self->{mods} = $mods;
3275         $self->{types} = $types;
3276         $self->{pool} = $pool;
3277         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3278         $self->{rm} = { };
3279         $self->{path_prefix} = length $self->{svn_path} ?
3280                                "$self->{svn_path}/" : '';
3281         return $self;
3282 }
3283
3284 sub generate_diff {
3285         my ($tree_a, $tree_b) = @_;
3286         my @diff_tree = qw(diff-tree -z -r);
3287         if ($_cp_similarity) {
3288                 push @diff_tree, "-C$_cp_similarity";
3289         } else {
3290                 push @diff_tree, '-C';
3291         }
3292         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3293         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3294         push @diff_tree, $tree_a, $tree_b;
3295         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3296         local $/ = "\0";
3297         my $state = 'meta';
3298         my @mods;
3299         while (<$diff_fh>) {
3300                 chomp $_; # this gets rid of the trailing "\0"
3301                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3302                                         $::sha1\s($::sha1)\s
3303                                         ([MTCRAD])\d*$/xo) {
3304                         push @mods, {   mode_a => $1, mode_b => $2,
3305                                         sha1_b => $3, chg => $4 };
3306                         if ($4 =~ /^(?:C|R)$/) {
3307                                 $state = 'file_a';
3308                         } else {
3309                                 $state = 'file_b';
3310                         }
3311                 } elsif ($state eq 'file_a') {
3312                         my $x = $mods[$#mods] or croak "Empty array\n";
3313                         if ($x->{chg} !~ /^(?:C|R)$/) {
3314                                 croak "Error parsing $_, $x->{chg}\n";
3315                         }
3316                         $x->{file_a} = $_;
3317                         $state = 'file_b';
3318                 } elsif ($state eq 'file_b') {
3319                         my $x = $mods[$#mods] or croak "Empty array\n";
3320                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3321                                 croak "Error parsing $_, $x->{chg}\n";
3322                         }
3323                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3324                                 croak "Error parsing $_, $x->{chg}\n";
3325                         }
3326                         $x->{file_b} = $_;
3327                         $state = 'meta';
3328                 } else {
3329                         croak "Error parsing $_\n";
3330                 }
3331         }
3332         command_close_pipe($diff_fh, $ctx);
3333         \@mods;
3334 }
3335
3336 sub check_diff_paths {
3337         my ($ra, $pfx, $rev, $mods) = @_;
3338         my %types;
3339         $pfx .= '/' if length $pfx;
3340
3341         sub type_diff_paths {
3342                 my ($ra, $types, $path, $rev) = @_;
3343                 my @p = split m#/+#, $path;
3344                 my $c = shift @p;
3345                 unless (defined $types->{$c}) {
3346                         $types->{$c} = $ra->check_path($c, $rev);
3347                 }
3348                 while (@p) {
3349                         $c .= '/' . shift @p;
3350                         next if defined $types->{$c};
3351                         $types->{$c} = $ra->check_path($c, $rev);
3352                 }
3353         }
3354
3355         foreach my $m (@$mods) {
3356                 foreach my $f (qw/file_a file_b/) {
3357                         next unless defined $m->{$f};
3358                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3359                         if (length $pfx.$dir && ! defined $types{$dir}) {
3360                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3361                         }
3362                 }
3363         }
3364         \%types;
3365 }
3366
3367 sub split_path {
3368         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3369 }
3370
3371 sub repo_path {
3372         my ($self, $path) = @_;
3373         $self->{path_prefix}.(defined $path ? $path : '');
3374 }
3375
3376 sub url_path {
3377         my ($self, $path) = @_;
3378         if ($self->{url} =~ m#^https?://#) {
3379                 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3380         }
3381         $self->{url} . '/' . $self->repo_path($path);
3382 }
3383
3384 sub rmdirs {
3385         my ($self) = @_;
3386         my $rm = $self->{rm};
3387         delete $rm->{''}; # we never delete the url we're tracking
3388         return unless %$rm;
3389
3390         foreach (keys %$rm) {
3391                 my @d = split m#/#, $_;
3392                 my $c = shift @d;
3393                 $rm->{$c} = 1;
3394                 while (@d) {
3395                         $c .= '/' . shift @d;
3396                         $rm->{$c} = 1;
3397                 }
3398         }
3399         delete $rm->{$self->{svn_path}};
3400         delete $rm->{''}; # we never delete the url we're tracking
3401         return unless %$rm;
3402
3403         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3404                                              $self->{tree_b});
3405         local $/ = "\0";
3406         while (<$fh>) {
3407                 chomp;
3408                 my @dn = split m#/#, $_;
3409                 while (pop @dn) {
3410                         delete $rm->{join '/', @dn};
3411                 }
3412                 unless (%$rm) {
3413                         close $fh;
3414                         return;
3415                 }
3416         }
3417         command_close_pipe($fh, $ctx);
3418
3419         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3420         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3421                 $self->close_directory($bat->{$d}, $p);
3422                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3423                 print "\tD+\t$d/\n" unless $::_q;
3424                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3425                 delete $bat->{$d};
3426         }
3427 }
3428
3429 sub open_or_add_dir {
3430         my ($self, $full_path, $baton) = @_;
3431         my $t = $self->{types}->{$full_path};
3432         if (!defined $t) {
3433                 die "$full_path not known in r$self->{r} or we have a bug!\n";
3434         }
3435         {
3436                 no warnings 'once';
3437                 # SVN::Node::none and SVN::Node::file are used only once,
3438                 # so we're shutting up Perl's warnings about them.
3439                 if ($t == $SVN::Node::none) {
3440                         return $self->add_directory($full_path, $baton,
3441                             undef, -1, $self->{pool});
3442                 } elsif ($t == $SVN::Node::dir) {
3443                         return $self->open_directory($full_path, $baton,
3444                             $self->{r}, $self->{pool});
3445                 } # no warnings 'once'
3446                 print STDERR "$full_path already exists in repository at ",
3447                     "r$self->{r} and it is not a directory (",
3448                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3449         } # no warnings 'once'
3450         exit 1;
3451 }
3452
3453 sub ensure_path {
3454         my ($self, $path) = @_;
3455         my $bat = $self->{bat};
3456         my $repo_path = $self->repo_path($path);
3457         return $bat->{''} unless (length $repo_path);
3458         my @p = split m#/+#, $repo_path;
3459         my $c = shift @p;
3460         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3461         while (@p) {
3462                 my $c0 = $c;
3463                 $c .= '/' . shift @p;
3464                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3465         }
3466         return $bat->{$c};
3467 }
3468
3469 sub A {
3470         my ($self, $m) = @_;
3471         my ($dir, $file) = split_path($m->{file_b});
3472         my $pbat = $self->ensure_path($dir);
3473         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3474                                         undef, -1);
3475         print "\tA\t$m->{file_b}\n" unless $::_q;
3476         $self->chg_file($fbat, $m);
3477         $self->close_file($fbat,undef,$self->{pool});
3478 }
3479
3480 sub C {
3481         my ($self, $m) = @_;
3482         my ($dir, $file) = split_path($m->{file_b});
3483         my $pbat = $self->ensure_path($dir);
3484         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3485                                 $self->url_path($m->{file_a}), $self->{r});
3486         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3487         $self->chg_file($fbat, $m);
3488         $self->close_file($fbat,undef,$self->{pool});
3489 }
3490
3491 sub delete_entry {
3492         my ($self, $path, $pbat) = @_;
3493         my $rpath = $self->repo_path($path);
3494         my ($dir, $file) = split_path($rpath);
3495         $self->{rm}->{$dir} = 1;
3496         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3497 }
3498
3499 sub R {
3500         my ($self, $m) = @_;
3501         my ($dir, $file) = split_path($m->{file_b});
3502         my $pbat = $self->ensure_path($dir);
3503         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3504                                 $self->url_path($m->{file_a}), $self->{r});
3505         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3506         $self->chg_file($fbat, $m);
3507         $self->close_file($fbat,undef,$self->{pool});
3508
3509         ($dir, $file) = split_path($m->{file_a});
3510         $pbat = $self->ensure_path($dir);
3511         $self->delete_entry($m->{file_a}, $pbat);
3512 }
3513
3514 sub M {
3515         my ($self, $m) = @_;
3516         my ($dir, $file) = split_path($m->{file_b});
3517         my $pbat = $self->ensure_path($dir);
3518         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3519                                 $pbat,$self->{r},$self->{pool});
3520         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3521         $self->chg_file($fbat, $m);
3522         $self->close_file($fbat,undef,$self->{pool});
3523 }
3524
3525 sub T { shift->M(@_) }
3526
3527 sub change_file_prop {
3528         my ($self, $fbat, $pname, $pval) = @_;
3529         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3530 }
3531
3532 sub chg_file {
3533         my ($self, $fbat, $m) = @_;
3534         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3535                 $self->change_file_prop($fbat,'svn:executable','*');
3536         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3537                 $self->change_file_prop($fbat,'svn:executable',undef);
3538         }
3539         my $fh = IO::File->new_tmpfile or croak $!;
3540         if ($m->{mode_b} =~ /^120/) {
3541                 print $fh 'link ' or croak $!;
3542                 $self->change_file_prop($fbat,'svn:special','*');
3543         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3544                 $self->change_file_prop($fbat,'svn:special',undef);
3545         }
3546         defined(my $pid = fork) or croak $!;
3547         if (!$pid) {
3548                 open STDOUT, '>&', $fh or croak $!;
3549                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3550         }
3551         waitpid $pid, 0;
3552         croak $? if $?;
3553         $fh->flush == 0 or croak $!;
3554         seek $fh, 0, 0 or croak $!;
3555
3556         my $exp = ::md5sum($fh);
3557         seek $fh, 0, 0 or croak $!;
3558
3559         my $pool = SVN::Pool->new;
3560         my $atd = $self->apply_textdelta($fbat, undef, $pool);
3561         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3562         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3563         $pool->clear;
3564
3565         close $fh or croak $!;
3566 }
3567
3568 sub D {
3569         my ($self, $m) = @_;
3570         my ($dir, $file) = split_path($m->{file_b});
3571         my $pbat = $self->ensure_path($dir);
3572         print "\tD\t$m->{file_b}\n" unless $::_q;
3573         $self->delete_entry($m->{file_b}, $pbat);
3574 }
3575
3576 sub close_edit {
3577         my ($self) = @_;
3578         my ($p,$bat) = ($self->{pool}, $self->{bat});
3579         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3580                 next if $_ eq '';
3581                 $self->close_directory($bat->{$_}, $p);
3582         }
3583         $self->close_directory($bat->{''}, $p);
3584         $self->SUPER::close_edit($p);
3585         $p->clear;
3586 }
3587
3588 sub abort_edit {
3589         my ($self) = @_;
3590         $self->SUPER::abort_edit($self->{pool});
3591 }
3592
3593 sub DESTROY {
3594         my $self = shift;
3595         $self->SUPER::DESTROY(@_);
3596         $self->{pool}->clear;
3597 }
3598
3599 # this drives the editor
3600 sub apply_diff {
3601         my ($self) = @_;
3602         my $mods = $self->{mods};
3603         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3604         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3605                 my $f = $m->{chg};
3606                 if (defined $o{$f}) {
3607                         $self->$f($m);
3608                 } else {
3609                         fatal("Invalid change type: $f");
3610                 }
3611         }
3612         $self->rmdirs if $_rmdir;
3613         if (@$mods == 0) {
3614                 $self->abort_edit;
3615         } else {
3616                 $self->close_edit;
3617         }
3618         return scalar @$mods;
3619 }
3620
3621 package Git::SVN::Ra;
3622 use vars qw/@ISA $config_dir $_log_window_size/;
3623 use strict;
3624 use warnings;
3625 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3626
3627 BEGIN {
3628         # enforce temporary pool usage for some simple functions
3629         no strict 'refs';
3630         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3631                 my $SUPER = "SUPER::$f";
3632                 *$f = sub {
3633                         my $self = shift;
3634                         my $pool = SVN::Pool->new;
3635                         my @ret = $self->$SUPER(@_,$pool);
3636                         $pool->clear;
3637                         wantarray ? @ret : $ret[0];
3638                 };
3639         }
3640 }
3641
3642 sub _auth_providers () {
3643         [
3644           SVN::Client::get_simple_provider(),
3645           SVN::Client::get_ssl_server_trust_file_provider(),
3646           SVN::Client::get_simple_prompt_provider(
3647             \&Git::SVN::Prompt::simple, 2),
3648           SVN::Client::get_ssl_client_cert_file_provider(),
3649           SVN::Client::get_ssl_client_cert_prompt_provider(
3650             \&Git::SVN::Prompt::ssl_client_cert, 2),
3651           SVN::Client::get_ssl_client_cert_pw_file_provider(),
3652           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3653             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3654           SVN::Client::get_username_provider(),
3655           SVN::Client::get_ssl_server_trust_prompt_provider(
3656             \&Git::SVN::Prompt::ssl_server_trust),
3657           SVN::Client::get_username_prompt_provider(
3658             \&Git::SVN::Prompt::username, 2)
3659         ]
3660 }
3661
3662 sub escape_uri_only {
3663         my ($uri) = @_;
3664         my @tmp;
3665         foreach (split m{/}, $uri) {
3666                 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3667                 push @tmp, $_;
3668         }
3669         join('/', @tmp);
3670 }
3671
3672 sub escape_url {
3673         my ($url) = @_;
3674         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3675                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3676                 $url = "$scheme://$domain$uri";
3677         }
3678         $url;
3679 }
3680
3681 sub new {
3682         my ($class, $url) = @_;
3683         $url =~ s!/+$!!;
3684         return $RA if ($RA && $RA->{url} eq $url);
3685
3686         SVN::_Core::svn_config_ensure($config_dir, undef);
3687         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3688         my $config = SVN::Core::config_get_config($config_dir);
3689         $RA = undef;
3690         my $dont_store_passwords = 1;
3691         my $conf_t = ${$config}{'config'};
3692         {
3693                 no warnings 'once';
3694                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3695                 # produces warnings that variables are used only once.
3696                 # I had not found the better way to shut them up, so
3697                 # the warnings of type 'once' are disabled in this block.
3698                 if (SVN::_Core::svn_config_get_bool($conf_t,
3699                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3700                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3701                     1) == 0) {
3702                         SVN::_Core::svn_auth_set_parameter($baton,
3703                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3704                             bless (\$dont_store_passwords, "_p_void"));
3705                 }
3706                 if (SVN::_Core::svn_config_get_bool($conf_t,
3707                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3708                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3709                     1) == 0) {
3710                         $Git::SVN::Prompt::_no_auth_cache = 1;
3711                 }
3712         } # no warnings 'once'
3713         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3714                               config => $config,
3715                               pool => SVN::Pool->new,
3716                               auth_provider_callbacks => $callbacks);
3717         $self->{url} = $url;
3718         $self->{svn_path} = $url;
3719         $self->{repos_root} = $self->get_repos_root;
3720         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3721         $self->{cache} = { check_path => { r => 0, data => {} },
3722                            get_dir => { r => 0, data => {} } };
3723         $RA = bless $self, $class;
3724 }
3725
3726 sub check_path {
3727         my ($self, $path, $r) = @_;
3728         my $cache = $self->{cache}->{check_path};
3729         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3730                 return $cache->{data}->{$path};
3731         }
3732         my $pool = SVN::Pool->new;
3733         my $t = $self->SUPER::check_path($path, $r, $pool);
3734         $pool->clear;
3735         if ($r != $cache->{r}) {
3736                 %{$cache->{data}} = ();
3737                 $cache->{r} = $r;
3738         }
3739         $cache->{data}->{$path} = $t;
3740 }
3741
3742 sub get_dir {
3743         my ($self, $dir, $r) = @_;
3744         my $cache = $self->{cache}->{get_dir};
3745         if ($r == $cache->{r}) {
3746                 if (my $x = $cache->{data}->{$dir}) {
3747                         return wantarray ? @$x : $x->[0];
3748                 }
3749         }
3750         my $pool = SVN::Pool->new;
3751         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3752         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3753         $pool->clear;
3754         if ($r != $cache->{r}) {
3755                 %{$cache->{data}} = ();
3756                 $cache->{r} = $r;
3757         }
3758         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3759         wantarray ? (\%dirents, $r, $props) : \%dirents;
3760 }
3761
3762 sub DESTROY {
3763         # do not call the real DESTROY since we store ourselves in $RA
3764 }
3765
3766 sub get_log {
3767         my ($self, @args) = @_;
3768         my $pool = SVN::Pool->new;
3769         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3770         my $ret = $self->SUPER::get_log(@args, $pool);
3771         $pool->clear;
3772         $ret;
3773 }
3774
3775 sub trees_match {
3776         my ($self, $url1, $rev1, $url2, $rev2) = @_;
3777         my $ctx = SVN::Client->new(auth => _auth_providers);
3778         my $out = IO::File->new_tmpfile;
3779
3780         # older SVN (1.1.x) doesn't take $pool as the last parameter for
3781         # $ctx->diff(), so we'll create a default one
3782         my $pool = SVN::Pool->new_default_sub;
3783
3784         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3785         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3786         $out->flush;
3787         my $ret = (($out->stat)[7] == 0);
3788         close $out or croak $!;
3789
3790         $ret;
3791 }
3792
3793 sub get_commit_editor {
3794         my ($self, $log, $cb, $pool) = @_;
3795         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3796         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3797 }
3798
3799 sub gs_do_update {
3800         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3801         my $new = ($rev_a == $rev_b);
3802         my $path = $gs->{path};
3803
3804         if ($new && -e $gs->{index}) {
3805                 unlink $gs->{index} or die
3806                   "Couldn't unlink index: $gs->{index}: $!\n";
3807         }
3808         my $pool = SVN::Pool->new;
3809         $editor->set_path_strip($path);
3810         my (@pc) = split m#/#, $path;
3811         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3812                                         1, $editor, $pool);
3813         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3814
3815         # Since we can't rely on svn_ra_reparent being available, we'll
3816         # just have to do some magic with set_path to make it so
3817         # we only want a partial path.
3818         my $sp = '';
3819         my $final = join('/', @pc);
3820         while (@pc) {
3821                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3822                 $sp .= '/' if length $sp;
3823                 $sp .= shift @pc;
3824         }
3825         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3826
3827         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3828
3829         $reporter->finish_report($pool);
3830         $pool->clear;
3831         $editor->{git_commit_ok};
3832 }
3833
3834 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3835 # svn_ra_reparent didn't work before 1.4)
3836 sub gs_do_switch {
3837         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3838         my $path = $gs->{path};
3839         my $pool = SVN::Pool->new;
3840
3841         my $full_url = $self->{url};
3842         my $old_url = $full_url;
3843         $full_url .= '/' . escape_uri_only($path) if length $path;
3844         my ($ra, $reparented);
3845         if ($old_url ne $full_url) {
3846                 if ($old_url !~ m#^svn(\+ssh)?://#) {
3847                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3848                                                   $pool);
3849                         $self->{url} = $full_url;
3850                         $reparented = 1;
3851                 } else {
3852                         $_[0] = undef;
3853                         $self = undef;
3854                         $RA = undef;
3855                         $ra = Git::SVN::Ra->new($full_url);
3856                         $ra_invalid = 1;
3857                 }
3858         }
3859         $ra ||= $self;
3860         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3861         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3862         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3863         $reporter->finish_report($pool);
3864
3865         if ($reparented) {
3866                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3867                 $self->{url} = $old_url;
3868         }
3869
3870         $pool->clear;
3871         $editor->{git_commit_ok};
3872 }
3873
3874 sub longest_common_path {
3875         my ($gsv, $globs) = @_;
3876         my %common;
3877         my $common_max = scalar @$gsv;
3878
3879         foreach my $gs (@$gsv) {
3880                 my @tmp = split m#/#, $gs->{path};
3881                 my $p = '';
3882                 foreach (@tmp) {
3883                         $p .= length($p) ? "/$_" : $_;
3884                         $common{$p} ||= 0;
3885                         $common{$p}++;
3886                 }
3887         }
3888         $globs ||= [];
3889         $common_max += scalar @$globs;
3890         foreach my $glob (@$globs) {
3891                 my @tmp = split m#/#, $glob->{path}->{left};
3892                 my $p = '';
3893                 foreach (@tmp) {
3894                         $p .= length($p) ? "/$_" : $_;
3895                         $common{$p} ||= 0;
3896                         $common{$p}++;
3897                 }
3898         }
3899
3900         my $longest_path = '';
3901         foreach (sort {length $b <=> length $a} keys %common) {
3902                 if ($common{$_} == $common_max) {
3903                         $longest_path = $_;
3904                         last;
3905                 }
3906         }
3907         $longest_path;
3908 }
3909
3910 sub gs_fetch_loop_common {
3911         my ($self, $base, $head, $gsv, $globs) = @_;
3912         return if ($base > $head);
3913         my $inc = $_log_window_size;
3914         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3915         my $longest_path = longest_common_path($gsv, $globs);
3916         my $ra_url = $self->{url};
3917         while (1) {
3918                 my %revs;
3919                 my $err;
3920                 my $err_handler = $SVN::Error::handler;
3921                 $SVN::Error::handler = sub {
3922                         ($err) = @_;
3923                         skip_unknown_revs($err);
3924                 };
3925                 sub _cb {
3926                         my ($paths, $r, $author, $date, $log) = @_;
3927                         [ dup_changed_paths($paths),
3928                           { author => $author, date => $date, log => $log } ];
3929                 }
3930                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3931                                sub { $revs{$_[1]} = _cb(@_) });
3932                 if ($err && $max >= $head) {
3933                         print STDERR "Path '$longest_path' ",
3934                                      "was probably deleted:\n",
3935                                      $err->expanded_message,
3936                                      "\nWill attempt to follow ",
3937                                      "revisions r$min .. r$max ",
3938                                      "committed before the deletion\n";
3939                         my $hi = $max;
3940                         while (--$hi >= $min) {
3941                                 my $ok;
3942                                 $self->get_log([$longest_path], $min, $hi,
3943                                                0, 1, 1, sub {
3944                                                $ok ||= $_[1];
3945                                                $revs{$_[1]} = _cb(@_) });
3946                                 if ($ok) {
3947                                         print STDERR "r$min .. r$ok OK\n";
3948                                         last;
3949                                 }
3950                         }
3951                 }
3952                 $SVN::Error::handler = $err_handler;
3953
3954                 my %exists = map { $_->{path} => $_ } @$gsv;
3955                 foreach my $r (sort {$a <=> $b} keys %revs) {
3956                         my ($paths, $logged) = @{$revs{$r}};
3957
3958                         foreach my $gs ($self->match_globs(\%exists, $paths,
3959                                                            $globs, $r)) {
3960                                 if ($gs->rev_map_max >= $r) {
3961                                         next;
3962                                 }
3963                                 next unless $gs->match_paths($paths, $r);
3964                                 $gs->{logged_rev_props} = $logged;
3965                                 if (my $last_commit = $gs->last_commit) {
3966                                         $gs->assert_index_clean($last_commit);
3967                                 }
3968                                 my $log_entry = $gs->do_fetch($paths, $r);
3969                                 if ($log_entry) {
3970                                         $gs->do_git_commit($log_entry);
3971                                 }
3972                                 $INDEX_FILES{$gs->{index}} = 1;
3973                         }
3974                         foreach my $g (@$globs) {
3975                                 my $k = "svn-remote.$g->{remote}." .
3976                                         "$g->{t}-maxRev";
3977                                 Git::SVN::tmp_config($k, $r);
3978                         }
3979                         if ($ra_invalid) {
3980                                 $_[0] = undef;
3981                                 $self = undef;
3982                                 $RA = undef;
3983                                 $self = Git::SVN::Ra->new($ra_url);
3984                                 $ra_invalid = undef;
3985                         }
3986                 }
3987                 # pre-fill the .rev_db since it'll eventually get filled in
3988                 # with '0' x40 if something new gets committed
3989                 foreach my $gs (@$gsv) {
3990                         next if $gs->rev_map_max >= $max;
3991                         next if defined $gs->rev_map_get($max);
3992                         $gs->rev_map_set($max, 0 x40);
3993                 }
3994                 foreach my $g (@$globs) {
3995                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3996                         Git::SVN::tmp_config($k, $max);
3997                 }
3998                 last if $max >= $head;
3999                 $min = $max + 1;
4000                 $max += $inc;
4001                 $max = $head if ($max > $head);
4002         }
4003         Git::SVN::gc();
4004 }
4005
4006 sub match_globs {
4007         my ($self, $exists, $paths, $globs, $r) = @_;
4008
4009         sub get_dir_check {
4010                 my ($self, $exists, $g, $r) = @_;
4011                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4012                 return unless scalar @x == 3;
4013                 my $dirents = $x[0];
4014                 foreach my $de (keys %$dirents) {
4015                         next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4016                         my $p = $g->{path}->full_path($de);
4017                         next if $exists->{$p};
4018                         next if (length $g->{path}->{right} &&
4019                                  ($self->check_path($p, $r) !=
4020                                   $SVN::Node::dir));
4021                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4022                                          $g->{ref}->full_path($de), 1);
4023                 }
4024         }
4025         foreach my $g (@$globs) {
4026                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4027                         if ($path->{action} =~ /^[AR]$/) {
4028                                 get_dir_check($self, $exists, $g, $r);
4029                         }
4030                 }
4031                 foreach (keys %$paths) {
4032                         if (/$g->{path}->{left_regex}/ &&
4033                             !/$g->{path}->{regex}/) {
4034                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4035                                 get_dir_check($self, $exists, $g, $r);
4036                         }
4037                         next unless /$g->{path}->{regex}/;
4038                         my $p = $1;
4039                         my $pathname = $g->{path}->full_path($p);
4040                         next if $exists->{$pathname};
4041                         next if ($self->check_path($pathname, $r) !=
4042                                  $SVN::Node::dir);
4043                         $exists->{$pathname} = Git::SVN->init(
4044                                               $self->{url}, $pathname, undef,
4045                                               $g->{ref}->full_path($p), 1);
4046                 }
4047                 my $c = '';
4048                 foreach (split m#/#, $g->{path}->{left}) {
4049                         $c .= "/$_";
4050                         next unless ($paths->{$c} &&
4051                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4052                         get_dir_check($self, $exists, $g, $r);
4053                 }
4054         }
4055         values %$exists;
4056 }
4057
4058 sub minimize_url {
4059         my ($self) = @_;
4060         return $self->{url} if ($self->{url} eq $self->{repos_root});
4061         my $url = $self->{repos_root};
4062         my @components = split(m!/!, $self->{svn_path});
4063         my $c = '';
4064         do {
4065                 $url .= "/$c" if length $c;
4066                 eval { (ref $self)->new($url)->get_latest_revnum };
4067         } while ($@ && ($c = shift @components));
4068         $url;
4069 }
4070
4071 sub can_do_switch {
4072         my $self = shift;
4073         unless (defined $can_do_switch) {
4074                 my $pool = SVN::Pool->new;
4075                 my $rep = eval {
4076                         $self->do_switch(1, '', 0, $self->{url},
4077                                          SVN::Delta::Editor->new, $pool);
4078                 };
4079                 if ($@) {
4080                         $can_do_switch = 0;
4081                 } else {
4082                         $rep->abort_report($pool);
4083                         $can_do_switch = 1;
4084                 }
4085                 $pool->clear;
4086         }
4087         $can_do_switch;
4088 }
4089
4090 sub skip_unknown_revs {
4091         my ($err) = @_;
4092         my $errno = $err->apr_err();
4093         # Maybe the branch we're tracking didn't
4094         # exist when the repo started, so it's
4095         # not an error if it doesn't, just continue
4096         #
4097         # Wonderfully consistent library, eh?
4098         # 160013 - svn:// and file://
4099         # 175002 - http(s)://
4100         # 175007 - http(s):// (this repo required authorization, too...)
4101         #   More codes may be discovered later...
4102         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4103                 my $err_key = $err->expanded_message;
4104                 # revision numbers change every time, filter them out
4105                 $err_key =~ s/\d+/\0/g;
4106                 $err_key = "$errno\0$err_key";
4107                 unless ($ignored_err{$err_key}) {
4108                         warn "W: Ignoring error from SVN, path probably ",
4109                              "does not exist: ($errno): ",
4110                              $err->expanded_message,"\n";
4111                         warn "W: Do not be alarmed at the above message ",
4112                              "git-svn is just searching aggressively for ",
4113                              "old history.\n",
4114                              "This may take a while on large repositories\n";
4115                         $ignored_err{$err_key} = 1;
4116                 }
4117                 return;
4118         }
4119         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4120 }
4121
4122 # svn_log_changed_path_t objects passed to get_log are likely to be
4123 # overwritten even if only the refs are copied to an external variable,
4124 # so we should dup the structures in their entirety.  Using an externally
4125 # passed pool (instead of our temporary and quickly cleared pool in
4126 # Git::SVN::Ra) does not help matters at all...
4127 sub dup_changed_paths {
4128         my ($paths) = @_;
4129         return undef unless $paths;
4130         my %ret;
4131         foreach my $p (keys %$paths) {
4132                 my $i = $paths->{$p};
4133                 my %s = map { $_ => $i->$_ }
4134                               qw/copyfrom_path copyfrom_rev action/;
4135                 $ret{$p} = \%s;
4136         }
4137         \%ret;
4138 }
4139
4140 package Git::SVN::Log;
4141 use strict;
4142 use warnings;
4143 use POSIX qw/strftime/;
4144 use constant commit_log_separator => ('-' x 72) . "\n";
4145 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4146             %rusers $show_commit $incremental/;
4147 my $l_fmt;
4148
4149 sub cmt_showable {
4150         my ($c) = @_;
4151         return 1 if defined $c->{r};
4152
4153         # big commit message got truncated by the 16k pretty buffer in rev-list
4154         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4155                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4156                 @{$c->{l}} = ();
4157                 my @log = command(qw/cat-file commit/, $c->{c});
4158
4159                 # shift off the headers
4160                 shift @log while ($log[0] ne '');
4161                 shift @log;
4162
4163                 # TODO: make $c->{l} not have a trailing newline in the future
4164                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4165
4166                 (undef, $c->{r}, undef) = ::extract_metadata(
4167                                 (grep(/^git-svn-id: /, @log))[-1]);
4168         }
4169         return defined $c->{r};
4170 }
4171
4172 sub log_use_color {
4173         return $color || Git->repository->get_colorbool('color.diff');
4174 }
4175
4176 sub git_svn_log_cmd {
4177         my ($r_min, $r_max, @args) = @_;
4178         my $head = 'HEAD';
4179         my (@files, @log_opts);
4180         foreach my $x (@args) {
4181                 if ($x eq '--' || @files) {
4182                         push @files, $x;
4183                 } else {
4184                         if (::verify_ref("$x^0")) {
4185                                 $head = $x;
4186                         } else {
4187                                 push @log_opts, $x;
4188                         }
4189                 }
4190         }
4191
4192         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4193         $gs ||= Git::SVN->_new;
4194         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4195                    $gs->refname);
4196         push @cmd, '-r' unless $non_recursive;
4197         push @cmd, qw/--raw --name-status/ if $verbose;
4198         push @cmd, '--color' if log_use_color();
4199         push @cmd, @log_opts;
4200         if (defined $r_max && $r_max == $r_min) {
4201                 push @cmd, '--max-count=1';
4202                 if (my $c = $gs->rev_map_get($r_max)) {
4203                         push @cmd, $c;
4204                 }
4205         } elsif (defined $r_max) {
4206                 if ($r_max < $r_min) {
4207                         ($r_min, $r_max) = ($r_max, $r_min);
4208                 }
4209                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4210                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4211                 # If there are no commits in the range, both $c_max and $c_min
4212                 # will be undefined.  If there is at least 1 commit in the
4213                 # range, both will be defined.
4214                 return () if !defined $c_min || !defined $c_max;
4215                 if ($c_min eq $c_max) {
4216                         push @cmd, '--max-count=1', $c_min;
4217                 } else {
4218                         push @cmd, '--boundary', "$c_min..$c_max";
4219                 }
4220         }
4221         return (@cmd, @files);
4222 }
4223
4224 # adapted from pager.c
4225 sub config_pager {
4226         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4227         if (!defined $pager) {
4228                 $pager = 'less';
4229         } elsif (length $pager == 0 || $pager eq 'cat') {
4230                 $pager = undef;
4231         }
4232         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4233 }
4234
4235 sub run_pager {
4236         return unless -t *STDOUT && defined $pager;
4237         pipe my $rfd, my $wfd or return;
4238         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4239         if (!$pid) {
4240                 open STDOUT, '>&', $wfd or
4241                                      ::fatal "Can't redirect to stdout: $!";
4242                 return;
4243         }
4244         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4245         $ENV{LESS} ||= 'FRSX';
4246         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4247 }
4248
4249 sub format_svn_date {
4250         return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4251 }
4252
4253 sub parse_git_date {
4254         my ($t, $tz) = @_;
4255         # Date::Parse isn't in the standard Perl distro :(
4256         if ($tz =~ s/^\+//) {
4257                 $t += tz_to_s_offset($tz);
4258         } elsif ($tz =~ s/^\-//) {
4259                 $t -= tz_to_s_offset($tz);
4260         }
4261         return $t;
4262 }
4263
4264 sub set_local_timezone {
4265         if (defined $TZ) {
4266                 $ENV{TZ} = $TZ;
4267         } else {
4268                 delete $ENV{TZ};
4269         }
4270 }
4271
4272 sub tz_to_s_offset {
4273         my ($tz) = @_;
4274         $tz =~ s/(\d\d)$//;
4275         return ($1 * 60) + ($tz * 3600);
4276 }
4277
4278 sub get_author_info {
4279         my ($dest, $author, $t, $tz) = @_;
4280         $author =~ s/(?:^\s*|\s*$)//g;
4281         $dest->{a_raw} = $author;
4282         my $au;
4283         if ($::_authors) {
4284                 $au = $rusers{$author} || undef;
4285         }
4286         if (!$au) {
4287                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4288         }
4289         $dest->{t} = $t;
4290         $dest->{tz} = $tz;
4291         $dest->{a} = $au;
4292         $dest->{t_utc} = parse_git_date($t, $tz);
4293 }
4294
4295 sub process_commit {
4296         my ($c, $r_min, $r_max, $defer) = @_;
4297         if (defined $r_min && defined $r_max) {
4298                 if ($r_min == $c->{r} && $r_min == $r_max) {
4299                         show_commit($c);
4300                         return 0;
4301                 }
4302                 return 1 if $r_min == $r_max;
4303                 if ($r_min < $r_max) {
4304                         # we need to reverse the print order
4305                         return 0 if (defined $limit && --$limit < 0);
4306                         push @$defer, $c;
4307                         return 1;
4308                 }
4309                 if ($r_min != $r_max) {
4310                         return 1 if ($r_min < $c->{r});
4311                         return 1 if ($r_max > $c->{r});
4312                 }
4313         }
4314         return 0 if (defined $limit && --$limit < 0);
4315         show_commit($c);
4316         return 1;
4317 }
4318
4319 sub show_commit {
4320         my $c = shift;
4321         if ($oneline) {
4322                 my $x = "\n";
4323                 if (my $l = $c->{l}) {
4324                         while ($l->[0] =~ /^\s*$/) { shift @$l }
4325                         $x = $l->[0];
4326                 }
4327                 $l_fmt ||= 'A' . length($c->{r});
4328                 print 'r',pack($l_fmt, $c->{r}),' | ';
4329                 print "$c->{c} | " if $show_commit;
4330                 print $x;
4331         } else {
4332                 show_commit_normal($c);
4333         }
4334 }
4335
4336 sub show_commit_changed_paths {
4337         my ($c) = @_;
4338         return unless $c->{changed};
4339         print "Changed paths:\n", @{$c->{changed}};
4340 }
4341
4342 sub show_commit_normal {
4343         my ($c) = @_;
4344         print commit_log_separator, "r$c->{r} | ";
4345         print "$c->{c} | " if $show_commit;
4346         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4347         my $nr_line = 0;
4348
4349         if (my $l = $c->{l}) {
4350                 while ($l->[$#$l] eq "\n" && $#$l > 0
4351                                           && $l->[($#$l - 1)] eq "\n") {
4352                         pop @$l;
4353                 }
4354                 $nr_line = scalar @$l;
4355                 if (!$nr_line) {
4356                         print "1 line\n\n\n";
4357                 } else {
4358                         if ($nr_line == 1) {
4359                                 $nr_line = '1 line';
4360                         } else {
4361                                 $nr_line .= ' lines';
4362                         }
4363                         print $nr_line, "\n";
4364                         show_commit_changed_paths($c);
4365                         print "\n";
4366                         print $_ foreach @$l;
4367                 }
4368         } else {
4369                 print "1 line\n";
4370                 show_commit_changed_paths($c);
4371                 print "\n";
4372
4373         }
4374         foreach my $x (qw/raw stat diff/) {
4375                 if ($c->{$x}) {
4376                         print "\n";
4377                         print $_ foreach @{$c->{$x}}
4378                 }
4379         }
4380 }
4381
4382 sub cmd_show_log {
4383         my (@args) = @_;
4384         my ($r_min, $r_max);
4385         my $r_last = -1; # prevent dupes
4386         set_local_timezone();
4387         if (defined $::_revision) {
4388                 if ($::_revision =~ /^(\d+):(\d+)$/) {
4389                         ($r_min, $r_max) = ($1, $2);
4390                 } elsif ($::_revision =~ /^\d+$/) {
4391                         $r_min = $r_max = $::_revision;
4392                 } else {
4393                         ::fatal "-r$::_revision is not supported, use ",
4394                                 "standard 'git log' arguments instead";
4395                 }
4396         }
4397
4398         config_pager();
4399         @args = git_svn_log_cmd($r_min, $r_max, @args);
4400         if (!@args) {
4401                 print commit_log_separator unless $incremental || $oneline;
4402                 return;
4403         }
4404         my $log = command_output_pipe(@args);
4405         run_pager();
4406         my (@k, $c, $d, $stat);
4407         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4408         while (<$log>) {
4409                 if (/^${esc_color}commit -?($::sha1_short)/o) {
4410                         my $cmt = $1;
4411                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4412                                 $r_last = $c->{r};
4413                                 process_commit($c, $r_min, $r_max, \@k) or
4414                                                                 goto out;
4415                         }
4416                         $d = undef;
4417                         $c = { c => $cmt };
4418                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4419                         get_author_info($c, $1, $2, $3);
4420                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4421                         # ignore
4422                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4423                         push @{$c->{raw}}, $_;
4424                 } elsif (/^${esc_color}[ACRMDT]\t/) {
4425                         # we could add $SVN->{svn_path} here, but that requires
4426                         # remote access at the moment (repo_path_split)...
4427                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4428                         push @{$c->{changed}}, $_;
4429                 } elsif (/^${esc_color}diff /o) {
4430                         $d = 1;
4431                         push @{$c->{diff}}, $_;
4432                 } elsif ($d) {
4433                         push @{$c->{diff}}, $_;
4434                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4435                           $esc_color*[\+\-]*$esc_color$/x) {
4436                         $stat = 1;
4437                         push @{$c->{stat}}, $_;
4438                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4439                         push @{$c->{stat}}, $_;
4440                         $stat = undef;
4441                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4442                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4443                 } elsif (s/^${esc_color}    //o) {
4444                         push @{$c->{l}}, $_;
4445                 }
4446         }
4447         if ($c && defined $c->{r} && $c->{r} != $r_last) {
4448                 $r_last = $c->{r};
4449                 process_commit($c, $r_min, $r_max, \@k);
4450         }
4451         if (@k) {
4452                 ($r_min, $r_max) = ($r_max, $r_min);
4453                 process_commit($_, $r_min, $r_max) foreach reverse @k;
4454         }
4455 out:
4456         close $log;
4457         print commit_log_separator unless $incremental || $oneline;
4458 }
4459
4460 sub cmd_blame {
4461         my $path = shift;
4462
4463         config_pager();
4464         run_pager();
4465
4466         my ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4467         while (my $line = <$fh>) {
4468                 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4469                         my (undef, $rev, undef) = ::cmt_metadata($1);
4470                         $rev = sprintf('%-10s', $rev);
4471                         $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4472                 }
4473                 print $line;
4474         }
4475         command_close_pipe($fh, $ctx);
4476 }
4477
4478 package Git::SVN::Migration;
4479 # these version numbers do NOT correspond to actual version numbers
4480 # of git nor git-svn.  They are just relative.
4481 #
4482 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4483 #
4484 # v1 layout: .git/$id/info/url, refs/remotes/$id
4485 #
4486 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4487 #
4488 # v3 layout: .git/svn/$id, refs/remotes/$id
4489 #            - info/url may remain for backwards compatibility
4490 #            - this is what we migrate up to this layout automatically,
4491 #            - this will be used by git svn init on single branches
4492 # v3.1 layout (auto migrated):
4493 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4494 #              for backwards compatibility
4495 #
4496 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4497 #            - this is only created for newly multi-init-ed
4498 #              repositories.  Similar in spirit to the
4499 #              --use-separate-remotes option in git-clone (now default)
4500 #            - we do not automatically migrate to this (following
4501 #              the example set by core git)
4502 #
4503 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4504 #            - newer, more-efficient format that uses 24-bytes per record
4505 #              with no filler space.
4506 #            - use xxd -c24 < .rev_map.$UUID to view and debug
4507 #            - This is a one-way migration, repositories updated to the
4508 #              new format will not be able to use old git-svn without
4509 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
4510 #              possible if noMetadata or useSvmProps are set; but should
4511 #              be no problem for users that use the (sensible) defaults.
4512 use strict;
4513 use warnings;
4514 use Carp qw/croak/;
4515 use File::Path qw/mkpath/;
4516 use File::Basename qw/dirname basename/;
4517 use vars qw/$_minimize/;
4518
4519 sub migrate_from_v0 {
4520         my $git_dir = $ENV{GIT_DIR};
4521         return undef unless -d $git_dir;
4522         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4523         my $migrated = 0;
4524         while (<$fh>) {
4525                 chomp;
4526                 my ($id, $orig_ref) = ($_, $_);
4527                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4528                 next unless -f "$git_dir/$id/info/url";
4529                 my $new_ref = "refs/remotes/$id";
4530                 if (::verify_ref("$new_ref^0")) {
4531                         print STDERR "W: $orig_ref is probably an old ",
4532                                      "branch used by an ancient version of ",
4533                                      "git-svn.\n",
4534                                      "However, $new_ref also exists.\n",
4535                                      "We will not be able ",
4536                                      "to use this branch until this ",
4537                                      "ambiguity is resolved.\n";
4538                         next;
4539                 }
4540                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4541                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4542                 command_noisy('update-ref', $new_ref, $orig_ref);
4543                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4544                 $migrated++;
4545         }
4546         command_close_pipe($fh, $ctx);
4547         print STDERR "Done migrating from v0 layout...\n" if $migrated;
4548         $migrated;
4549 }
4550
4551 sub migrate_from_v1 {
4552         my $git_dir = $ENV{GIT_DIR};
4553         my $migrated = 0;
4554         return $migrated unless -d $git_dir;
4555         my $svn_dir = "$git_dir/svn";
4556
4557         # just in case somebody used 'svn' as their $id at some point...
4558         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4559
4560         print STDERR "Migrating from a git-svn v1 layout...\n";
4561         mkpath([$svn_dir]);
4562         print STDERR "Data from a previous version of git-svn exists, but\n\t",
4563                      "$svn_dir\n\t(required for this version ",
4564                      "($::VERSION) of git-svn) does not. exist\n";
4565         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4566         while (<$fh>) {
4567                 my $x = $_;
4568                 next unless $x =~ s#^refs/remotes/##;
4569                 chomp $x;
4570                 next unless -f "$git_dir/$x/info/url";
4571                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4572                 next unless $u;
4573                 my $dn = dirname("$git_dir/svn/$x");
4574                 mkpath([$dn]) unless -d $dn;
4575                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4576                         mkpath(["$git_dir/svn/svn"]);
4577                         print STDERR " - $git_dir/$x/info => ",
4578                                         "$git_dir/svn/$x/info\n";
4579                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4580                                croak "$!: $x";
4581                         # don't worry too much about these, they probably
4582                         # don't exist with repos this old (save for index,
4583                         # and we can easily regenerate that)
4584                         foreach my $f (qw/unhandled.log index .rev_db/) {
4585                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4586                         }
4587                 } else {
4588                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4589                         rename "$git_dir/$x", "$git_dir/svn/$x" or
4590                                croak "$!: $x";
4591                 }
4592                 $migrated++;
4593         }
4594         command_close_pipe($fh, $ctx);
4595         print STDERR "Done migrating from a git-svn v1 layout\n";
4596         $migrated;
4597 }
4598
4599 sub read_old_urls {
4600         my ($l_map, $pfx, $path) = @_;
4601         my @dir;
4602         foreach (<$path/*>) {
4603                 if (-r "$_/info/url") {
4604                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4605                         my $ref_id = $pfx . basename $_;
4606                         my $url = ::file_to_s("$_/info/url");
4607                         $l_map->{$ref_id} = $url;
4608                 } elsif (-d $_) {
4609                         push @dir, $_;
4610                 }
4611         }
4612         foreach (@dir) {
4613                 my $x = $_;
4614                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4615                 read_old_urls($l_map, $x, $_);
4616         }
4617 }
4618
4619 sub migrate_from_v2 {
4620         my @cfg = command(qw/config -l/);
4621         return if grep /^svn-remote\..+\.url=/, @cfg;
4622         my %l_map;
4623         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4624         my $migrated = 0;
4625
4626         foreach my $ref_id (sort keys %l_map) {
4627                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4628                 if ($@) {
4629                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4630                 }
4631                 $migrated++;
4632         }
4633         $migrated;
4634 }
4635
4636 sub minimize_connections {
4637         my $r = Git::SVN::read_all_remotes();
4638         my $new_urls = {};
4639         my $root_repos = {};
4640         foreach my $repo_id (keys %$r) {
4641                 my $url = $r->{$repo_id}->{url} or next;
4642                 my $fetch = $r->{$repo_id}->{fetch} or next;
4643                 my $ra = Git::SVN::Ra->new($url);
4644
4645                 # skip existing cases where we already connect to the root
4646                 if (($ra->{url} eq $ra->{repos_root}) ||
4647                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4648                      $repo_id)) {
4649                         $root_repos->{$ra->{url}} = $repo_id;
4650                         next;
4651                 }
4652
4653                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4654                 my $root_path = $ra->{url};
4655                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4656                 foreach my $path (keys %$fetch) {
4657                         my $ref_id = $fetch->{$path};
4658                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4659
4660                         # make sure we can read when connecting to
4661                         # a higher level of a repository
4662                         my ($last_rev, undef) = $gs->last_rev_commit;
4663                         if (!defined $last_rev) {
4664                                 $last_rev = eval {
4665                                         $root_ra->get_latest_revnum;
4666                                 };
4667                                 next if $@;
4668                         }
4669                         my $new = $root_path;
4670                         $new .= length $path ? "/$path" : '';
4671                         eval {
4672                                 $root_ra->get_log([$new], $last_rev, $last_rev,
4673                                                   0, 0, 1, sub { });
4674                         };
4675                         next if $@;
4676                         $new_urls->{$ra->{repos_root}}->{$new} =
4677                                 { ref_id => $ref_id,
4678                                   old_repo_id => $repo_id,
4679                                   old_path => $path };
4680                 }
4681         }
4682
4683         my @emptied;
4684         foreach my $url (keys %$new_urls) {
4685                 # see if we can re-use an existing [svn-remote "repo_id"]
4686                 # instead of creating a(n ugly) new section:
4687                 my $repo_id = $root_repos->{$url} ||
4688                               Git::SVN::sanitize_remote_name($url);
4689
4690                 my $fetch = $new_urls->{$url};
4691                 foreach my $path (keys %$fetch) {
4692                         my $x = $fetch->{$path};
4693                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4694                         my $pfx = "svn-remote.$x->{old_repo_id}";
4695
4696                         my $old_fetch = quotemeta("$x->{old_path}:".
4697                                                   "refs/remotes/$x->{ref_id}");
4698                         command_noisy(qw/config --unset/,
4699                                       "$pfx.fetch", '^'. $old_fetch . '$');
4700                         delete $r->{$x->{old_repo_id}}->
4701                                {fetch}->{$x->{old_path}};
4702                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4703                                 command_noisy(qw/config --unset/,
4704                                               "$pfx.url");
4705                                 push @emptied, $x->{old_repo_id}
4706                         }
4707                 }
4708         }
4709         if (@emptied) {
4710                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4711                            "$ENV{GIT_DIR}/config";
4712                 print STDERR <<EOF;
4713 The following [svn-remote] sections in your config file ($file) are empty
4714 and can be safely removed:
4715 EOF
4716                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4717         }
4718 }
4719
4720 sub migration_check {
4721         migrate_from_v0();
4722         migrate_from_v1();
4723         migrate_from_v2();
4724         minimize_connections() if $_minimize;
4725 }
4726
4727 package Git::IndexInfo;
4728 use strict;
4729 use warnings;
4730 use Git qw/command_input_pipe command_close_pipe/;
4731
4732 sub new {
4733         my ($class) = @_;
4734         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4735         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4736 }
4737
4738 sub remove {
4739         my ($self, $path) = @_;
4740         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4741                 return ++$self->{nr};
4742         }
4743         undef;
4744 }
4745
4746 sub update {
4747         my ($self, $mode, $hash, $path) = @_;
4748         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4749                 return ++$self->{nr};
4750         }
4751         undef;
4752 }
4753
4754 sub DESTROY {
4755         my ($self) = @_;
4756         command_close_pipe($self->{gui}, $self->{ctx});
4757 }
4758
4759 package Git::SVN::GlobSpec;
4760 use strict;
4761 use warnings;
4762
4763 sub new {
4764         my ($class, $glob) = @_;
4765         my $re = $glob;
4766         $re =~ s!/+$!!g; # no need for trailing slashes
4767         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4768         my ($left, $right) = ($1, $2);
4769         if ($nr > 1) {
4770                 die "Only one '*' wildcard expansion ",
4771                     "is supported (got $nr): '$glob'\n";
4772         } elsif ($nr == 0) {
4773                 die "One '*' is needed for glob: '$glob'\n";
4774         }
4775         $re = quotemeta($left) . $re . quotemeta($right);
4776         if (length $left && !($left =~ s!/+$!!g)) {
4777                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4778         }
4779         if (length $right && !($right =~ s!^/+!!g)) {
4780                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4781         }
4782         my $left_re = qr/^\/\Q$left\E(\/|$)/;
4783         bless { left => $left, right => $right, left_regex => $left_re,
4784                 regex => qr/$re/, glob => $glob }, $class;
4785 }
4786
4787 sub full_path {
4788         my ($self, $path) = @_;
4789         return (length $self->{left} ? "$self->{left}/" : '') .
4790                $path . (length $self->{right} ? "/$self->{right}" : '');
4791 }
4792
4793 __END__
4794
4795 Data structures:
4796
4797
4798 $remotes = { # returned by read_all_remotes()
4799         'svn' => {
4800                 # svn-remote.svn.url=https://svn.musicpd.org
4801                 url => 'https://svn.musicpd.org',
4802                 # svn-remote.svn.fetch=mpd/trunk:trunk
4803                 fetch => {
4804                         'mpd/trunk' => 'trunk',
4805                 },
4806                 # svn-remote.svn.tags=mpd/tags/*:tags/*
4807                 tags => {
4808                         path => {
4809                                 left => 'mpd/tags',
4810                                 right => '',
4811                                 regex => qr!mpd/tags/([^/]+)$!,
4812                                 glob => 'tags/*',
4813                         },
4814                         ref => {
4815                                 left => 'tags',
4816                                 right => '',
4817                                 regex => qr!tags/([^/]+)$!,
4818                                 glob => 'tags/*',
4819                         },
4820                 }
4821         }
4822 };
4823
4824 $log_entry hashref as returned by libsvn_log_entry()
4825 {
4826         log => 'whitespace-formatted log entry
4827 ',                                              # trailing newline is preserved
4828         revision => '8',                        # integer
4829         date => '2004-02-24T17:01:44.108345Z',  # commit date
4830         author => 'committer name'
4831 };
4832
4833
4834 # this is generated by generate_diff();
4835 @mods = array of diff-index line hashes, each element represents one line
4836         of diff-index output
4837
4838 diff-index line ($m hash)
4839 {
4840         mode_a => first column of diff-index output, no leading ':',
4841         mode_b => second column of diff-index output,
4842         sha1_b => sha1sum of the final blob,
4843         chg => change type [MCRADT],
4844         file_a => original file name of a file (iff chg is 'C' or 'R')
4845         file_b => new/current file name of a file (any chg)
4846 }
4847 ;
4848
4849 # retval of read_url_paths{,_all}();
4850 $l_map = {
4851         # repository root url
4852         'https://svn.musicpd.org' => {
4853                 # repository path               # GIT_SVN_ID
4854                 'mpd/trunk'             =>      'trunk',
4855                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
4856         },
4857 }
4858
4859 Notes:
4860         I don't trust the each() function on unless I created %hash myself
4861         because the internal iterator may not have started at base.