git.oblomov.eu Git - git/blob - perl/Git/SVN.pm

   1 package Git::SVN;
   2 use strict;
   3 use warnings;
   4 use Fcntl qw/:DEFAULT :seek/;
   5 use constant rev_map_fmt => 'NH40';
   6 use vars qw/$_no_metadata
   7             $_repack $_repack_flags $_use_svm_props $_head
   8             $_use_svnsync_props $no_reuse_existing
   9             $_use_log_author $_add_author_from $_localtime/;
  10 use Carp qw/croak/;
  11 use File::Path qw/mkpath/;
  12 use IPC::Open3;
  13 use Memoize;  # core since 5.8.0, Jul 2002
  14 use POSIX qw(:signal_h);
  15 use Time::Local;
  16
  17 use Git qw(
  18     command
  19     command_oneline
  20     command_noisy
  21     command_output_pipe
  22     command_close_pipe
  23     get_tz_offset
  24 );
  25 use Git::SVN::Utils qw(
  26         fatal
  27         can_compress
  28         join_paths
  29         canonicalize_path
  30         canonicalize_url
  31         add_path_to_url
  32 );
  33
  34 my $memo_backend;
  35 our $_follow_parent  = 1;
  36 our $_minimize_url   = 'unset';
  37 our $default_repo_id = 'svn';
  38 our $default_ref_id  = $ENV{GIT_SVN_ID} || 'git-svn';
  39
  40 my ($_gc_nr, $_gc_period);
  41
  42 # properties that we do not log:
  43 my %SKIP_PROP;
  44 BEGIN {
  45         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
  46                                         svn:special svn:executable
  47                                         svn:entry:committed-rev
  48                                         svn:entry:last-author
  49                                         svn:entry:uuid
  50                                         svn:entry:committed-date/;
  51
  52         # some options are read globally, but can be overridden locally
  53         # per [svn-remote "..."] section.  Command-line options will *NOT*
  54         # override options set in an [svn-remote "..."] section
  55         no strict 'refs';
  56         for my $option (qw/follow_parent no_metadata use_svm_props
  57                            use_svnsync_props/) {
  58                 my $key = $option;
  59                 $key =~ tr/_//d;
  60                 my $prop = "-$option";
  61                 *$option = sub {
  62                         my ($self) = @_;
  63                         return $self->{$prop} if exists $self->{$prop};
  64                         my $k = "svn-remote.$self->{repo_id}.$key";
  65                         eval { command_oneline(qw/config --get/, $k) };
  66                         if ($@) {
  67                                 $self->{$prop} = ${"Git::SVN::_$option"};
  68                         } else {
  69                                 my $v = command_oneline(qw/config --bool/,$k);
  70                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
  71                         }
  72                         return $self->{$prop};
  73                 }
  74         }
  75 }
  76
  77
  78 my (%LOCKFILES, %INDEX_FILES);
  79 END {
  80         unlink keys %LOCKFILES if %LOCKFILES;
  81         unlink keys %INDEX_FILES if %INDEX_FILES;
  82 }
  83
  84 sub resolve_local_globs {
  85         my ($url, $fetch, $glob_spec) = @_;
  86         return unless defined $glob_spec;
  87         my $ref = $glob_spec->{ref};
  88         my $path = $glob_spec->{path};
  89         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
  90                 next unless m#^$ref->{regex}$#;
  91                 my $p = $1;
  92                 my $pathname = desanitize_refname($path->full_path($p));
  93                 my $refname = desanitize_refname($ref->full_path($p));
  94                 if (my $existing = $fetch->{$pathname}) {
  95                         if ($existing ne $refname) {
  96                                 die "Refspec conflict:\n",
  97                                     "existing: $existing\n",
  98                                     " globbed: $refname\n";
  99                         }
 100                         my $u = (::cmt_metadata("$refname"))[0];
 101                         if (!defined($u)) {
 102                                 warn
 103 "W: $refname: no associated commit metadata from SVN, skipping\n";
 104                                 next;
 105                         }
 106                         $u =~ s!^\Q$url\E(/|$)!! or die
 107                           "$refname: '$url' not found in '$u'\n";
 108                         if ($pathname ne $u) {
 109                                 warn "W: Refspec glob conflict ",
 110                                      "(ref: $refname):\n",
 111                                      "expected path: $pathname\n",
 112                                      "    real path: $u\n",
 113                                      "Continuing ahead with $u\n";
 114                                 next;
 115                         }
 116                 } else {
 117                         $fetch->{$pathname} = $refname;
 118                 }
 119         }
 120 }
 121
 122 sub parse_revision_argument {
 123         my ($base, $head) = @_;
 124         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 125                 return ($base, $head);
 126         }
 127         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 128         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 129         return ($head, $head) if ($::_revision eq 'HEAD');
 130         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
 131         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 132         die "revision argument: $::_revision not understood by git-svn\n";
 133 }
 134
 135 sub fetch_all {
 136         my ($repo_id, $remotes) = @_;
 137         if (ref $repo_id) {
 138                 my $gs = $repo_id;
 139                 $repo_id = undef;
 140                 $repo_id = $gs->{repo_id};
 141         }
 142         $remotes ||= read_all_remotes();
 143         my $remote = $remotes->{$repo_id} or
 144                      die "[svn-remote \"$repo_id\"] unknown\n";
 145         my $fetch = $remote->{fetch};
 146         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
 147         my (@gs, @globs);
 148         my $ra = Git::SVN::Ra->new($url);
 149         my $uuid = $ra->get_uuid;
 150         my $head = $ra->get_latest_revnum;
 151
 152         # ignore errors, $head revision may not even exist anymore
 153         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
 154         warn "W: $@\n" if $@;
 155
 156         my $base = defined $fetch ? $head : 0;
 157
 158         # read the max revs for wildcard expansion (branches/*, tags/*)
 159         foreach my $t (qw/branches tags/) {
 160                 defined $remote->{$t} or next;
 161                 push @globs, @{$remote->{$t}};
 162
 163                 my $max_rev = eval { tmp_config(qw/--int --get/,
 164                                          "svn-remote.$repo_id.${t}-maxRev") };
 165                 if (defined $max_rev && ($max_rev < $base)) {
 166                         $base = $max_rev;
 167                 } elsif (!defined $max_rev) {
 168                         $base = 0;
 169                 }
 170         }
 171
 172         if ($fetch) {
 173                 foreach my $p (sort keys %$fetch) {
 174                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 175                         my $lr = $gs->rev_map_max;
 176                         if (defined $lr) {
 177                                 $base = $lr if ($lr < $base);
 178                         }
 179                         push @gs, $gs;
 180                 }
 181         }
 182
 183         ($base, $head) = parse_revision_argument($base, $head);
 184         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
 185 }
 186
 187 sub read_all_remotes {
 188         my $r = {};
 189         my $use_svm_props = eval { command_oneline(qw/config --bool
 190             svn.useSvmProps/) };
 191         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
 192         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
 193         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 194                 if (m!^(.+)\.fetch=$svn_refspec$!) {
 195                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
 196                         die("svn-remote.$remote: remote ref '$remote_ref' "
 197                             . "must start with 'refs/'\n")
 198                                 unless $remote_ref =~ m{^refs/};
 199                         $local_ref = uri_decode($local_ref);
 200                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
 201                         $r->{$remote}->{svm} = {} if $use_svm_props;
 202                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
 203                         $r->{$1}->{svm} = {};
 204                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 205                         $r->{$1}->{url} = canonicalize_url($2);
 206                 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
 207                         $r->{$1}->{pushurl} = canonicalize_url($2);
 208                 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
 209                         $r->{$1}->{ignore_refs_regex} = $2;
 210                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
 211                         my ($remote, $t, $local_ref, $remote_ref) =
 212                                                              ($1, $2, $3, $4);
 213                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
 214                             . "must start with 'refs/'\n")
 215                                 unless $remote_ref =~ m{^refs/};
 216                         $local_ref = uri_decode($local_ref);
 217
 218                         require Git::SVN::GlobSpec;
 219                         my $rs = {
 220                             t => $t,
 221                             remote => $remote,
 222                             path => Git::SVN::GlobSpec->new($local_ref, 1),
 223                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
 224                         if (length($rs->{ref}->{right}) != 0) {
 225                                 die "The '*' glob character must be the last ",
 226                                     "character of '$remote_ref'\n";
 227                         }
 228                         push @{ $r->{$remote}->{$t} }, $rs;
 229                 }
 230         }
 231
 232         map {
 233                 if (defined $r->{$_}->{svm}) {
 234                         my $svm;
 235                         eval {
 236                                 my $section = "svn-remote.$_";
 237                                 $svm = {
 238                                         source => tmp_config('--get',
 239                                             "$section.svm-source"),
 240                                         replace => tmp_config('--get',
 241                                             "$section.svm-replace"),
 242                                 }
 243                         };
 244                         $r->{$_}->{svm} = $svm;
 245                 }
 246         } keys %$r;
 247
 248         foreach my $remote (keys %$r) {
 249                 foreach ( grep { defined $_ }
 250                           map { $r->{$remote}->{$_} } qw(branches tags) ) {
 251                         foreach my $rs ( @$_ ) {
 252                                 $rs->{ignore_refs_regex} =
 253                                     $r->{$remote}->{ignore_refs_regex};
 254                         }
 255                 }
 256         }
 257
 258         $r;
 259 }
 260
 261 sub init_vars {
 262         $_gc_nr = $_gc_period = 1000;
 263         if (defined $_repack || defined $_repack_flags) {
 264                warn "Repack options are obsolete; they have no effect.\n";
 265         }
 266 }
 267
 268 sub verify_remotes_sanity {
 269         return unless -d $ENV{GIT_DIR};
 270         my %seen;
 271         foreach (command(qw/config -l/)) {
 272                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 273                         if ($seen{$1}) {
 274                                 die "Remote ref refs/remote/$1 is tracked by",
 275                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 276                                     "Please resolve this ambiguity in ",
 277                                     "your git configuration file before ",
 278                                     "continuing\n";
 279                         }
 280                         $seen{$1} = $_;
 281                 }
 282         }
 283 }
 284
 285 sub find_existing_remote {
 286         my ($url, $remotes) = @_;
 287         return undef if $no_reuse_existing;
 288         my $existing;
 289         foreach my $repo_id (keys %$remotes) {
 290                 my $u = $remotes->{$repo_id}->{url} or next;
 291                 next if $u ne $url;
 292                 $existing = $repo_id;
 293                 last;
 294         }
 295         $existing;
 296 }
 297
 298 sub init_remote_config {
 299         my ($self, $url, $no_write) = @_;
 300         $url = canonicalize_url($url);
 301         my $r = read_all_remotes();
 302         my $existing = find_existing_remote($url, $r);
 303         if ($existing) {
 304                 unless ($no_write) {
 305                         print STDERR "Using existing ",
 306                                      "[svn-remote \"$existing\"]\n";
 307                 }
 308                 $self->{repo_id} = $existing;
 309         } elsif ($_minimize_url) {
 310                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 311                 $existing = find_existing_remote($min_url, $r);
 312                 if ($existing) {
 313                         unless ($no_write) {
 314                                 print STDERR "Using existing ",
 315                                              "[svn-remote \"$existing\"]\n";
 316                         }
 317                         $self->{repo_id} = $existing;
 318                 }
 319                 if ($min_url ne $url) {
 320                         unless ($no_write) {
 321                                 print STDERR "Using higher level of URL: ",
 322                                              "$url => $min_url\n";
 323                         }
 324                         my $old_path = $self->path;
 325                         $url =~ s!^\Q$min_url\E(/|$)!!;
 326                         $url = join_paths($url, $old_path);
 327                         $self->path($url);
 328                         $url = $min_url;
 329                 }
 330         }
 331         my $orig_url;
 332         if (!$existing) {
 333                 # verify that we aren't overwriting anything:
 334                 $orig_url = eval {
 335                         command_oneline('config', '--get',
 336                                         "svn-remote.$self->{repo_id}.url")
 337                 };
 338                 if ($orig_url && ($orig_url ne $url)) {
 339                         die "svn-remote.$self->{repo_id}.url already set: ",
 340                             "$orig_url\nwanted to set to: $url\n";
 341                 }
 342         }
 343         my ($xrepo_id, $xpath) = find_ref($self->refname);
 344         if (!$no_write && defined $xpath) {
 345                 die "svn-remote.$xrepo_id.fetch already set to track ",
 346                     "$xpath:", $self->refname, "\n";
 347         }
 348         unless ($no_write) {
 349                 command_noisy('config',
 350                               "svn-remote.$self->{repo_id}.url", $url);
 351                 my $path = $self->path;
 352                 $path =~ s{^/}{};
 353                 $path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
 354                 $self->path($path);
 355                 command_noisy('config', '--add',
 356                               "svn-remote.$self->{repo_id}.fetch",
 357                               $self->path.":".$self->refname);
 358         }
 359         $self->url($url);
 360 }
 361
 362 sub find_by_url { # repos_root and, path are optional
 363         my ($class, $full_url, $repos_root, $path) = @_;
 364
 365         $full_url = canonicalize_url($full_url);
 366
 367         return undef unless defined $full_url;
 368         remove_username($full_url);
 369         remove_username($repos_root) if defined $repos_root;
 370         my $remotes = read_all_remotes();
 371         if (defined $full_url && defined $repos_root && !defined $path) {
 372                 $path = $full_url;
 373                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
 374         }
 375         foreach my $repo_id (keys %$remotes) {
 376                 my $u = $remotes->{$repo_id}->{url} or next;
 377                 remove_username($u);
 378                 next if defined $repos_root && $repos_root ne $u;
 379
 380                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
 381                 foreach my $t (qw/branches tags/) {
 382                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
 383                                 resolve_local_globs($u, $fetch, $globspec);
 384                         }
 385                 }
 386                 my $p = $path;
 387                 my $rwr = rewrite_root({repo_id => $repo_id});
 388                 my $svm = $remotes->{$repo_id}->{svm}
 389                         if defined $remotes->{$repo_id}->{svm};
 390                 unless (defined $p) {
 391                         $p = $full_url;
 392                         my $z = $u;
 393                         my $prefix = '';
 394                         if ($rwr) {
 395                                 $z = $rwr;
 396                                 remove_username($z);
 397                         } elsif (defined $svm) {
 398                                 $z = $svm->{source};
 399                                 $prefix = $svm->{replace};
 400                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
 401                                 $prefix =~ s#/$##;
 402                         }
 403                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
 404                 }
 405
 406                 # remote fetch paths are not URI escaped.  Decode ours
 407                 # so they match
 408                 $p = uri_decode($p);
 409
 410                 foreach my $f (keys %$fetch) {
 411                         next if $f ne $p;
 412                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
 413                 }
 414         }
 415         undef;
 416 }
 417
 418 sub init {
 419         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
 420         my $self = _new($class, $repo_id, $ref_id, $path);
 421         if (defined $url) {
 422                 $self->init_remote_config($url, $no_write);
 423         }
 424         $self;
 425 }
 426
 427 sub find_ref {
 428         my ($ref_id) = @_;
 429         foreach (command(qw/config -l/)) {
 430                 next unless m!^svn-remote\.(.+)\.fetch=
 431                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
 432                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 433                 if ($ref eq $ref_id) {
 434                         $path = '' if ($path =~ m#^\./?#);
 435                         return ($repo_id, $path);
 436                 }
 437         }
 438         (undef, undef, undef);
 439 }
 440
 441 sub new {
 442         my ($class, $ref_id, $repo_id, $path) = @_;
 443         if (defined $ref_id && !defined $repo_id && !defined $path) {
 444                 ($repo_id, $path) = find_ref($ref_id);
 445                 if (!defined $repo_id) {
 446                         die "Could not find a \"svn-remote.*.fetch\" key ",
 447                             "in the repository configuration matching: ",
 448                             "$ref_id\n";
 449                 }
 450         }
 451         my $self = _new($class, $repo_id, $ref_id, $path);
 452         if (!defined $self->path || !length $self->path) {
 453                 my $fetch = command_oneline('config', '--get',
 454                                             "svn-remote.$repo_id.fetch",
 455                                             ":$ref_id\$") or
 456                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 457                          "\":$ref_id\$\" in config\n";
 458                 my($path) = split(/\s*:\s*/, $fetch);
 459                 $self->path($path);
 460         }
 461         {
 462                 my $path = $self->path;
 463                 $path =~ s{\A/}{};
 464                 $path =~ s{/\z}{};
 465                 $self->path($path);
 466         }
 467         my $url = command_oneline('config', '--get',
 468                                   "svn-remote.$repo_id.url") or
 469                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 470         $self->url($url);
 471         $self->{pushurl} = eval { command_oneline('config', '--get',
 472                                   "svn-remote.$repo_id.pushurl") };
 473         $self->rebuild;
 474         $self;
 475 }
 476
 477 sub refname {
 478         my ($refname) = $_[0]->{ref_id} ;
 479
 480         # It cannot end with a slash /, we'll throw up on this because
 481         # SVN can't have directories with a slash in their name, either:
 482         if ($refname =~ m{/$}) {
 483                 die "ref: '$refname' ends with a trailing slash; this is ",
 484                     "not permitted by git or Subversion\n";
 485         }
 486
 487         # It cannot have ASCII control character space, tilde ~, caret ^,
 488         # colon :, question-mark ?, asterisk *, space, or open bracket [
 489         # anywhere.
 490         #
 491         # Additionally, % must be escaped because it is used for escaping
 492         # and we want our escaped refname to be reversible
 493         $refname =~ s{([ \%~\^:\?\*\[\t\\])}{sprintf('%%%02X',ord($1))}eg;
 494
 495         # no slash-separated component can begin with a dot .
 496         # /.* becomes /%2E*
 497         $refname =~ s{/\.}{/%2E}g;
 498
 499         # It cannot have two consecutive dots .. anywhere
 500         # .. becomes %2E%2E
 501         $refname =~ s{\.\.}{%2E%2E}g;
 502
 503         # trailing dots and .lock are not allowed
 504         # .$ becomes %2E and .lock becomes %2Elock
 505         $refname =~ s{\.(?=$|lock$)}{%2E};
 506
 507         # the sequence @{ is used to access the reflog
 508         # @{ becomes %40{
 509         $refname =~ s{\@\{}{%40\{}g;
 510
 511         return $refname;
 512 }
 513
 514 sub desanitize_refname {
 515         my ($refname) = @_;
 516         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
 517         return $refname;
 518 }
 519
 520 sub svm_uuid {
 521         my ($self) = @_;
 522         return $self->{svm}->{uuid} if $self->svm;
 523         $self->ra;
 524         unless ($self->{svm}) {
 525                 die "SVM UUID not cached, and reading remotely failed\n";
 526         }
 527         $self->{svm}->{uuid};
 528 }
 529
 530 sub svm {
 531         my ($self) = @_;
 532         return $self->{svm} if $self->{svm};
 533         my $svm;
 534         # see if we have it in our config, first:
 535         eval {
 536                 my $section = "svn-remote.$self->{repo_id}";
 537                 $svm = {
 538                   source => tmp_config('--get', "$section.svm-source"),
 539                   uuid => tmp_config('--get', "$section.svm-uuid"),
 540                   replace => tmp_config('--get', "$section.svm-replace"),
 541                 }
 542         };
 543         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
 544                 $self->{svm} = $svm;
 545         }
 546         $self->{svm};
 547 }
 548
 549 sub _set_svm_vars {
 550         my ($self, $ra) = @_;
 551         return $ra if $self->svm;
 552
 553         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
 554                     "(svm:source, svm:uuid) ",
 555                     "from the following URLs:\n" );
 556         sub read_svm_props {
 557                 my ($self, $ra, $path, $r) = @_;
 558                 my $props = ($ra->get_dir($path, $r))[2];
 559                 my $src = $props->{'svm:source'};
 560                 my $uuid = $props->{'svm:uuid'};
 561                 return undef if (!$src || !$uuid);
 562
 563                 chomp($src, $uuid);
 564
 565                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
 566                     or die "doesn't look right - svm:uuid is '$uuid'\n";
 567
 568                 # the '!' is used to mark the repos_root!/relative/path
 569                 $src =~ s{/?!/?}{/};
 570                 $src =~ s{/+$}{}; # no trailing slashes please
 571                 # username is of no interest
 572                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
 573
 574                 my $replace = add_path_to_url($ra->url, $path);
 575
 576                 my $section = "svn-remote.$self->{repo_id}";
 577                 tmp_config("$section.svm-source", $src);
 578                 tmp_config("$section.svm-replace", $replace);
 579                 tmp_config("$section.svm-uuid", $uuid);
 580                 $self->{svm} = {
 581                         source => $src,
 582                         uuid => $uuid,
 583                         replace => $replace
 584                 };
 585         }
 586
 587         my $r = $ra->get_latest_revnum;
 588         my $path = $self->path;
 589         my %tried;
 590         while (length $path) {
 591                 my $try = add_path_to_url($self->url, $path);
 592                 unless ($tried{$try}) {
 593                         return $ra if $self->read_svm_props($ra, $path, $r);
 594                         $tried{$try} = 1;
 595                 }
 596                 $path =~ s#/?[^/]+$##;
 597         }
 598         die "Path: '$path' should be ''\n" if $path ne '';
 599         return $ra if $self->read_svm_props($ra, $path, $r);
 600         $tried{ add_path_to_url($self->url, $path) } = 1;
 601
 602         if ($ra->{repos_root} eq $self->url) {
 603                 die @err, (map { "  $_\n" } keys %tried), "\n";
 604         }
 605
 606         # nope, make sure we're connected to the repository root:
 607         my $ok;
 608         my @tried_b;
 609         $path = $ra->{svn_path};
 610         $ra = Git::SVN::Ra->new($ra->{repos_root});
 611         while (length $path) {
 612                 my $try = add_path_to_url($ra->url, $path);
 613                 unless ($tried{$try}) {
 614                         $ok = $self->read_svm_props($ra, $path, $r);
 615                         last if $ok;
 616                         $tried{$try} = 1;
 617                 }
 618                 $path =~ s#/?[^/]+$##;
 619         }
 620         die "Path: '$path' should be ''\n" if $path ne '';
 621         $ok ||= $self->read_svm_props($ra, $path, $r);
 622         $tried{ add_path_to_url($ra->url, $path) } = 1;
 623         if (!$ok) {
 624                 die @err, (map { "  $_\n" } keys %tried), "\n";
 625         }
 626         Git::SVN::Ra->new($self->url);
 627 }
 628
 629 sub svnsync {
 630         my ($self) = @_;
 631         return $self->{svnsync} if $self->{svnsync};
 632
 633         if ($self->no_metadata) {
 634                 die "Can't have both 'noMetadata' and ",
 635                     "'useSvnsyncProps' options set!\n";
 636         }
 637         if ($self->rewrite_root) {
 638                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
 639                     "options set!\n";
 640         }
 641         if ($self->rewrite_uuid) {
 642                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
 643                     "options set!\n";
 644         }
 645
 646         my $svnsync;
 647         # see if we have it in our config, first:
 648         eval {
 649                 my $section = "svn-remote.$self->{repo_id}";
 650
 651                 my $url = tmp_config('--get', "$section.svnsync-url");
 652                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
 653                    die "doesn't look right - svn:sync-from-url is '$url'\n";
 654
 655                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
 656                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
 657                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
 658
 659                 $svnsync = { url => $url, uuid => $uuid }
 660         };
 661         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
 662                 return $self->{svnsync} = $svnsync;
 663         }
 664
 665         my $err = "useSvnsyncProps set, but failed to read " .
 666                   "svnsync property: svn:sync-from-";
 667         my $rp = $self->ra->rev_proplist(0);
 668
 669         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
 670         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
 671                    die "doesn't look right - svn:sync-from-url is '$url'\n";
 672
 673         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
 674         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
 675                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
 676
 677         my $section = "svn-remote.$self->{repo_id}";
 678         tmp_config('--add', "$section.svnsync-uuid", $uuid);
 679         tmp_config('--add', "$section.svnsync-url", $url);
 680         return $self->{svnsync} = { url => $url, uuid => $uuid };
 681 }
 682
 683 # this allows us to memoize our SVN::Ra UUID locally and avoid a
 684 # remote lookup (useful for 'git svn log').
 685 sub ra_uuid {
 686         my ($self) = @_;
 687         unless ($self->{ra_uuid}) {
 688                 my $key = "svn-remote.$self->{repo_id}.uuid";
 689                 my $uuid = eval { tmp_config('--get', $key) };
 690                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
 691                         $self->{ra_uuid} = $uuid;
 692                 } else {
 693                         die "ra_uuid called without URL\n" unless $self->url;
 694                         $self->{ra_uuid} = $self->ra->get_uuid;
 695                         tmp_config('--add', $key, $self->{ra_uuid});
 696                 }
 697         }
 698         $self->{ra_uuid};
 699 }
 700
 701 sub _set_repos_root {
 702         my ($self, $repos_root) = @_;
 703         my $k = "svn-remote.$self->{repo_id}.reposRoot";
 704         $repos_root ||= $self->ra->{repos_root};
 705         tmp_config($k, $repos_root);
 706         $repos_root;
 707 }
 708
 709 sub repos_root {
 710         my ($self) = @_;
 711         my $k = "svn-remote.$self->{repo_id}.reposRoot";
 712         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
 713 }
 714
 715 sub ra {
 716         my ($self) = shift;
 717         my $ra = Git::SVN::Ra->new($self->url);
 718         $self->_set_repos_root($ra->{repos_root});
 719         if ($self->use_svm_props && !$self->{svm}) {
 720                 if ($self->no_metadata) {
 721                         die "Can't have both 'noMetadata' and ",
 722                             "'useSvmProps' options set!\n";
 723                 } elsif ($self->use_svnsync_props) {
 724                         die "Can't have both 'useSvnsyncProps' and ",
 725                             "'useSvmProps' options set!\n";
 726                 }
 727                 $ra = $self->_set_svm_vars($ra);
 728                 $self->{-want_revprops} = 1;
 729         }
 730         $ra;
 731 }
 732
 733 # prop_walk(PATH, REV, SUB)
 734 # -------------------------
 735 # Recursively traverse PATH at revision REV and invoke SUB for each
 736 # directory that contains a SVN property.  SUB will be invoked as
 737 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
 738 # Git::SVN, `path' the path to the directory where the properties
 739 # `props' were found.  The `path' will be relative to point of checkout,
 740 # that is, if url://repo/trunk is the current Git branch, and that
 741 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
 742 # as `path' (note the trailing `/').
 743 sub prop_walk {
 744         my ($self, $path, $rev, $sub) = @_;
 745
 746         $path =~ s#^/##;
 747         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
 748         $path =~ s#^/*#/#g;
 749         my $p = $path;
 750         # Strip the irrelevant part of the path.
 751         $p =~ s#^/+\Q@{[$self->path]}\E(/|$)#/#;
 752         # Ensure the path is terminated by a `/'.
 753         $p =~ s#/*$#/#;
 754
 755         # The properties contain all the internal SVN stuff nobody
 756         # (usually) cares about.
 757         my $interesting_props = 0;
 758         foreach (keys %{$props}) {
 759                 # If it doesn't start with `svn:', it must be a
 760                 # user-defined property.
 761                 ++$interesting_props and next if $_ !~ /^svn:/;
 762                 # FIXME: Fragile, if SVN adds new public properties,
 763                 # this needs to be updated.
 764                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
 765                                                  |eol-style|mime-type
 766                                                  |externals|needs-lock)$/x;
 767         }
 768         &$sub($self, $p, $props) if $interesting_props;
 769
 770         foreach (sort keys %$dirent) {
 771                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
 772                 $self->prop_walk($self->path . $p . $_, $rev, $sub);
 773         }
 774 }
 775
 776 sub last_rev { ($_[0]->last_rev_commit)[0] }
 777 sub last_commit { ($_[0]->last_rev_commit)[1] }
 778
 779 # returns the newest SVN revision number and newest commit SHA1
 780 sub last_rev_commit {
 781         my ($self) = @_;
 782         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 783                 return ($self->{last_rev}, $self->{last_commit});
 784         }
 785         my $c = ::verify_ref($self->refname.'^0');
 786         if ($c && !$self->use_svm_props && !$self->no_metadata) {
 787                 my $rev = (::cmt_metadata($c))[1];
 788                 if (defined $rev) {
 789                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 790                         return ($rev, $c);
 791                 }
 792         }
 793         my $map_path = $self->map_path;
 794         unless (-e $map_path) {
 795                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
 796                 return (undef, undef);
 797         }
 798         my ($rev, $commit) = $self->rev_map_max(1);
 799         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
 800         return ($rev, $commit);
 801 }
 802
 803 sub get_fetch_range {
 804         my ($self, $min, $max) = @_;
 805         $max ||= $self->ra->get_latest_revnum;
 806         $min ||= $self->rev_map_max;
 807         (++$min, $max);
 808 }
 809
 810 sub svn_dir {
 811         command_oneline(qw(rev-parse --git-path svn));
 812 }
 813
 814 sub tmp_config {
 815         my (@args) = @_;
 816         my $svn_dir = svn_dir();
 817         my $old_def_config = "$svn_dir/config";
 818         my $config = "$svn_dir/.metadata";
 819         if (! -f $config && -f $old_def_config) {
 820                 rename $old_def_config, $config or
 821                        die "Failed rename $old_def_config => $config: $!\n";
 822         }
 823         my $old_config = $ENV{GIT_CONFIG};
 824         $ENV{GIT_CONFIG} = $config;
 825         $@ = undef;
 826         my @ret = eval {
 827                 unless (-f $config) {
 828                         mkfile($config);
 829                         open my $fh, '>', $config or
 830                             die "Can't open $config: $!\n";
 831                         print $fh "; This file is used internally by ",
 832                                   "git-svn\n" or die
 833                                   "Couldn't write to $config: $!\n";
 834                         print $fh "; You should not have to edit it\n" or
 835                               die "Couldn't write to $config: $!\n";
 836                         close $fh or die "Couldn't close $config: $!\n";
 837                 }
 838                 command('config', @args);
 839         };
 840         my $err = $@;
 841         if (defined $old_config) {
 842                 $ENV{GIT_CONFIG} = $old_config;
 843         } else {
 844                 delete $ENV{GIT_CONFIG};
 845         }
 846         die $err if $err;
 847         wantarray ? @ret : $ret[0];
 848 }
 849
 850 sub tmp_index_do {
 851         my ($self, $sub) = @_;
 852         my $old_index = $ENV{GIT_INDEX_FILE};
 853         $ENV{GIT_INDEX_FILE} = $self->{index};
 854         $@ = undef;
 855         my @ret = eval {
 856                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
 857                 mkpath([$dir]) unless -d $dir;
 858                 &$sub;
 859         };
 860         my $err = $@;
 861         if (defined $old_index) {
 862                 $ENV{GIT_INDEX_FILE} = $old_index;
 863         } else {
 864                 delete $ENV{GIT_INDEX_FILE};
 865         }
 866         die $err if $err;
 867         wantarray ? @ret : $ret[0];
 868 }
 869
 870 sub assert_index_clean {
 871         my ($self, $treeish) = @_;
 872
 873         $self->tmp_index_do(sub {
 874                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 875                 my $x = command_oneline('write-tree');
 876                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 877                            /^tree ($::sha1)/mo);
 878                 return if $y eq $x;
 879
 880                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
 881                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
 882                 command_noisy('read-tree', $treeish);
 883                 $x = command_oneline('write-tree');
 884                 if ($y ne $x) {
 885                         fatal "trees ($treeish) $y != $x\n",
 886                               "Something is seriously wrong...";
 887                 }
 888         });
 889 }
 890
 891 sub get_commit_parents {
 892         my ($self, $log_entry) = @_;
 893         my (%seen, @ret, @tmp);
 894         # legacy support for 'set-tree'; this is only used by set_tree_cb:
 895         if (my $ip = $self->{inject_parents}) {
 896                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
 897                         push @tmp, $commit;
 898                 }
 899         }
 900         if (my $cur = ::verify_ref($self->refname.'^0')) {
 901                 push @tmp, $cur;
 902         }
 903         if (my $ipd = $self->{inject_parents_dcommit}) {
 904                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
 905                         push @tmp, @$commit;
 906                 }
 907         }
 908         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
 909         while (my $p = shift @tmp) {
 910                 next if $seen{$p};
 911                 $seen{$p} = 1;
 912                 push @ret, $p;
 913         }
 914         @ret;
 915 }
 916
 917 sub rewrite_root {
 918         my ($self) = @_;
 919         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
 920         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
 921         my $rwr = eval { command_oneline(qw/config --get/, $k) };
 922         if ($rwr) {
 923                 $rwr =~ s#/+$##;
 924                 if ($rwr !~ m#^[a-z\+]+://#) {
 925                         die "$rwr is not a valid URL (key: $k)\n";
 926                 }
 927         }
 928         $self->{-rewrite_root} = $rwr;
 929 }
 930
 931 sub rewrite_uuid {
 932         my ($self) = @_;
 933         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
 934         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
 935         my $rwid = eval { command_oneline(qw/config --get/, $k) };
 936         if ($rwid) {
 937                 $rwid =~ s#/+$##;
 938                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
 939                         die "$rwid is not a valid UUID (key: $k)\n";
 940                 }
 941         }
 942         $self->{-rewrite_uuid} = $rwid;
 943 }
 944
 945 sub metadata_url {
 946         my ($self) = @_;
 947         my $url = $self->rewrite_root || $self->url;
 948         return canonicalize_url( add_path_to_url( $url, $self->path ) );
 949 }
 950
 951 sub full_url {
 952         my ($self) = @_;
 953         return canonicalize_url( add_path_to_url( $self->url, $self->path ) );
 954 }
 955
 956 sub full_pushurl {
 957         my ($self) = @_;
 958         if ($self->{pushurl}) {
 959                 return canonicalize_url( add_path_to_url( $self->{pushurl}, $self->path ) );
 960         } else {
 961                 return $self->full_url;
 962         }
 963 }
 964
 965 sub set_commit_header_env {
 966         my ($log_entry) = @_;
 967         my %env;
 968         foreach my $ned (qw/NAME EMAIL DATE/) {
 969                 foreach my $ac (qw/AUTHOR COMMITTER/) {
 970                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
 971                 }
 972         }
 973
 974         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
 975         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
 976         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
 977
 978         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
 979                                                 ? $log_entry->{commit_name}
 980                                                 : $log_entry->{name};
 981         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
 982                                                 ? $log_entry->{commit_email}
 983                                                 : $log_entry->{email};
 984         \%env;
 985 }
 986
 987 sub restore_commit_header_env {
 988         my ($env) = @_;
 989         foreach my $ned (qw/NAME EMAIL DATE/) {
 990                 foreach my $ac (qw/AUTHOR COMMITTER/) {
 991                         my $k = "GIT_${ac}_${ned}";
 992                         if (defined $env->{$k}) {
 993                                 $ENV{$k} = $env->{$k};
 994                         } else {
 995                                 delete $ENV{$k};
 996                         }
 997                 }
 998         }
 999 }
1000
1001 sub gc {
1002         command_noisy('gc', '--auto');
1003 };
1004
1005 sub do_git_commit {
1006         my ($self, $log_entry) = @_;
1007         my $lr = $self->last_rev;
1008         if (defined $lr && $lr >= $log_entry->{revision}) {
1009                 die "Last fetched revision of ", $self->refname,
1010                     " was r$lr, but we are about to fetch: ",
1011                     "r$log_entry->{revision}!\n";
1012         }
1013         if (my $c = $self->rev_map_get($log_entry->{revision})) {
1014                 croak "$log_entry->{revision} = $c already exists! ",
1015                       "Why are we refetching it?\n";
1016         }
1017         my $old_env = set_commit_header_env($log_entry);
1018         my $tree = $log_entry->{tree};
1019         if (!defined $tree) {
1020                 $tree = $self->tmp_index_do(sub {
1021                                             command_oneline('write-tree') });
1022         }
1023         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1024
1025         my @exec = ('git', 'commit-tree', $tree);
1026         foreach ($self->get_commit_parents($log_entry)) {
1027                 push @exec, '-p', $_;
1028         }
1029         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1030                                                                    or croak $!;
1031         binmode $msg_fh;
1032
1033         # we always get UTF-8 from SVN, but we may want our commits in
1034         # a different encoding.
1035         if (my $enc = Git::config('i18n.commitencoding')) {
1036                 require Encode;
1037                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
1038         }
1039         print $msg_fh $log_entry->{log} or croak $!;
1040         restore_commit_header_env($old_env);
1041         unless ($self->no_metadata) {
1042                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1043                               or croak $!;
1044         }
1045         $msg_fh->flush == 0 or croak $!;
1046         close $msg_fh or croak $!;
1047         chomp(my $commit = do { local $/; <$out_fh> });
1048         close $out_fh or croak $!;
1049         waitpid $pid, 0;
1050         croak $? if $?;
1051         if ($commit !~ /^$::sha1$/o) {
1052                 die "Failed to commit, invalid sha1: $commit\n";
1053         }
1054
1055         $self->rev_map_set($log_entry->{revision}, $commit, 1);
1056
1057         $self->{last_rev} = $log_entry->{revision};
1058         $self->{last_commit} = $commit;
1059         print "r$log_entry->{revision}" unless $::_q > 1;
1060         if (defined $log_entry->{svm_revision}) {
1061                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
1062                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
1063                                    0, $self->svm_uuid);
1064         }
1065         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
1066         if (--$_gc_nr == 0) {
1067                 $_gc_nr = $_gc_period;
1068                 gc();
1069         }
1070         return $commit;
1071 }
1072
1073 sub match_paths {
1074         my ($self, $paths, $r) = @_;
1075         return 1 if $self->path eq '';
1076         if (my $path = $paths->{"/".$self->path}) {
1077                 return ($path->{action} eq 'D') ? 0 : 1;
1078         }
1079         $self->{path_regex} ||= qr{^/\Q@{[$self->path]}\E/};
1080         if (grep /$self->{path_regex}/, keys %$paths) {
1081                 return 1;
1082         }
1083         my $c = '';
1084         foreach (split m#/#, $self->path) {
1085                 $c .= "/$_";
1086                 next unless ($paths->{$c} &&
1087                              ($paths->{$c}->{action} =~ /^[AR]$/));
1088                 if ($self->ra->check_path($self->path, $r) ==
1089                     $SVN::Node::dir) {
1090                         return 1;
1091                 }
1092         }
1093         return 0;
1094 }
1095
1096 sub find_parent_branch {
1097         my ($self, $paths, $rev) = @_;
1098         return undef unless $self->follow_parent;
1099         unless (defined $paths) {
1100                 my $err_handler = $SVN::Error::handler;
1101                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1102                 $self->ra->get_log([$self->path], $rev, $rev, 0, 1, 1,
1103                                    sub { $paths = $_[0] });
1104                 $SVN::Error::handler = $err_handler;
1105         }
1106         return undef unless defined $paths;
1107
1108         # look for a parent from another branch:
1109         my @b_path_components = split m#/#, $self->path;
1110         my @a_path_components;
1111         my $i;
1112         while (@b_path_components) {
1113                 $i = $paths->{'/'.join('/', @b_path_components)};
1114                 last if $i && defined $i->{copyfrom_path};
1115                 unshift(@a_path_components, pop(@b_path_components));
1116         }
1117         return undef unless defined $i && defined $i->{copyfrom_path};
1118         my $branch_from = $i->{copyfrom_path};
1119         if (@a_path_components) {
1120                 print STDERR "branch_from: $branch_from => ";
1121                 $branch_from .= '/'.join('/', @a_path_components);
1122                 print STDERR $branch_from, "\n";
1123         }
1124         my $r = $i->{copyfrom_rev};
1125         my $repos_root = $self->ra->{repos_root};
1126         my $url = $self->ra->url;
1127         my $new_url = canonicalize_url( add_path_to_url( $url, $branch_from ) );
1128         print STDERR  "Found possible branch point: ",
1129                       "$new_url => ", $self->full_url, ", $r\n"
1130                       unless $::_q > 1;
1131         $branch_from =~ s#^/##;
1132         my $gs = $self->other_gs($new_url, $url,
1133                                  $branch_from, $r, $self->{ref_id});
1134         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1135         {
1136                 my ($base, $head);
1137                 if (!defined $r0 || !defined $parent) {
1138                         ($base, $head) = parse_revision_argument(0, $r);
1139                 } else {
1140                         if ($r0 < $r) {
1141                                 $gs->ra->get_log([$gs->path], $r0 + 1, $r, 1,
1142                                         0, 1, sub { $base = $_[1] - 1 });
1143                         }
1144                 }
1145                 if (defined $base && $base <= $r) {
1146                         $gs->fetch($base, $r);
1147                 }
1148                 ($r0, $parent) = $gs->find_rev_before($r, 1);
1149         }
1150         if (defined $r0 && defined $parent) {
1151                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
1152                              unless $::_q > 1;
1153                 my $ed;
1154                 if ($self->ra->can_do_switch) {
1155                         $self->assert_index_clean($parent);
1156                         print STDERR "Following parent with do_switch\n"
1157                                      unless $::_q > 1;
1158                         # do_switch works with svn/trunk >= r22312, but that
1159                         # is not included with SVN 1.4.3 (the latest version
1160                         # at the moment), so we can't rely on it
1161                         $self->{last_rev} = $r0;
1162                         $self->{last_commit} = $parent;
1163                         $ed = Git::SVN::Fetcher->new($self, $gs->path);
1164                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1165                                               $self->full_url, $ed)
1166                           or die "SVN connection failed somewhere...\n";
1167                 } elsif ($self->ra->trees_match($new_url, $r0,
1168                                                 $self->full_url, $rev)) {
1169                         print STDERR "Trees match:\n",
1170                                      "  $new_url\@$r0\n",
1171                                      "  ${\$self->full_url}\@$rev\n",
1172                                      "Following parent with no changes\n"
1173                                      unless $::_q > 1;
1174                         $self->tmp_index_do(sub {
1175                             command_noisy('read-tree', $parent);
1176                         });
1177                         $self->{last_commit} = $parent;
1178                 } else {
1179                         print STDERR "Following parent with do_update\n"
1180                                      unless $::_q > 1;
1181                         $ed = Git::SVN::Fetcher->new($self);
1182                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1183                           or die "SVN connection failed somewhere...\n";
1184                 }
1185                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
1186                 return $self->make_log_entry($rev, [$parent], $ed, $r0, $branch_from);
1187         }
1188         return undef;
1189 }
1190
1191 sub do_fetch {
1192         my ($self, $paths, $rev) = @_;
1193         my $ed;
1194         my ($last_rev, @parents);
1195         if (my $lc = $self->last_commit) {
1196                 # we can have a branch that was deleted, then re-added
1197                 # under the same name but copied from another path, in
1198                 # which case we'll have multiple parents (we don't
1199                 # want to break the original ref or lose copypath info):
1200                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1201                         push @{$log_entry->{parents}}, $lc;
1202                         return $log_entry;
1203                 }
1204                 $ed = Git::SVN::Fetcher->new($self);
1205                 $last_rev = $self->{last_rev};
1206                 $ed->{c} = $lc;
1207                 @parents = ($lc);
1208         } else {
1209                 $last_rev = $rev;
1210                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1211                         return $log_entry;
1212                 }
1213                 $ed = Git::SVN::Fetcher->new($self);
1214         }
1215         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1216                 die "SVN connection failed somewhere...\n";
1217         }
1218         $self->make_log_entry($rev, \@parents, $ed, $last_rev, $self->path);
1219 }
1220
1221 sub mkemptydirs {
1222         my ($self, $r) = @_;
1223
1224         # add/remove/collect a paths table
1225         #
1226         # Paths are split into a tree of nodes, stored as a hash of hashes.
1227         #
1228         # Each node contains a 'path' entry for the path (if any) associated
1229         # with that node and a 'children' entry for any nodes under that
1230         # location.
1231         #
1232         # Removing a path requires a hash lookup for each component then
1233         # dropping that node (and anything under it), which is substantially
1234         # faster than a grep slice into a single hash of paths for large
1235         # numbers of paths.
1236         #
1237         # For a large (200K) number of empty_dir directives this reduces
1238         # scanning time to 3 seconds vs 10 minutes for grep+delete on a single
1239         # hash of paths.
1240         sub add_path {
1241                 my ($paths_table, $path) = @_;
1242                 my $node_ref;
1243
1244                 foreach my $x (split('/', $path)) {
1245                         if (!exists($paths_table->{$x})) {
1246                                 $paths_table->{$x} = { children => {} };
1247                         }
1248
1249                         $node_ref = $paths_table->{$x};
1250                         $paths_table = $paths_table->{$x}->{children};
1251                 }
1252
1253                 $node_ref->{path} = $path;
1254         }
1255
1256         sub remove_path {
1257                 my ($paths_table, $path) = @_;
1258                 my $nodes_ref;
1259                 my $node_name;
1260
1261                 foreach my $x (split('/', $path)) {
1262                         if (!exists($paths_table->{$x})) {
1263                                 return;
1264                         }
1265
1266                         $nodes_ref = $paths_table;
1267                         $node_name = $x;
1268
1269                         $paths_table = $paths_table->{$x}->{children};
1270                 }
1271
1272                 delete($nodes_ref->{$node_name});
1273         }
1274
1275         sub collect_paths {
1276                 my ($paths_table, $paths_ref) = @_;
1277
1278                 foreach my $v (values %$paths_table) {
1279                         my $p = $v->{path};
1280                         my $c = $v->{children};
1281
1282                         collect_paths($c, $paths_ref);
1283
1284                         if (defined($p)) {
1285                                 push(@$paths_ref, $p);
1286                         }
1287                 }
1288         }
1289
1290         sub scan {
1291                 my ($r, $paths_table, $line) = @_;
1292                 if (defined $r && $line =~ /^r(\d+)$/) {
1293                         return 0 if $1 > $r;
1294                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
1295                         add_path($paths_table, $1);
1296                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
1297                         remove_path($paths_table, $1);
1298                 }
1299                 1; # continue
1300         };
1301
1302         my @empty_dirs;
1303         my %paths_table;
1304
1305         my $gz_file = "$self->{dir}/unhandled.log.gz";
1306         if (-f $gz_file) {
1307                 if (!can_compress()) {
1308                         warn "Compress::Zlib could not be found; ",
1309                              "empty directories in $gz_file will not be read\n";
1310                 } else {
1311                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
1312                                 die "Unable to open $gz_file: $!\n";
1313                         my $line;
1314                         while ($gz->gzreadline($line) > 0) {
1315                                 scan($r, \%paths_table, $line) or last;
1316                         }
1317                         $gz->gzclose;
1318                 }
1319         }
1320
1321         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
1322                 binmode $fh or croak "binmode: $!";
1323                 while (<$fh>) {
1324                         scan($r, \%paths_table, $_) or last;
1325                 }
1326                 close $fh;
1327         }
1328
1329         collect_paths(\%paths_table, \@empty_dirs);
1330         my $strip = qr/\A\Q@{[$self->path]}\E(?:\/|$)/;
1331         foreach my $d (sort @empty_dirs) {
1332                 $d = uri_decode($d);
1333                 $d =~ s/$strip//;
1334                 next unless length($d);
1335                 next if -d $d;
1336                 if (-e $d) {
1337                         warn "$d exists but is not a directory\n";
1338                 } else {
1339                         print "creating empty directory: $d\n";
1340                         mkpath([$d]);
1341                 }
1342         }
1343 }
1344
1345 sub get_untracked {
1346         my ($self, $ed) = @_;
1347         my @out;
1348         my $h = $ed->{empty};
1349         foreach (sort keys %$h) {
1350                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1351                 push @out, "  $act: " . uri_encode($_);
1352                 warn "W: $act: $_\n";
1353         }
1354         foreach my $t (qw/dir_prop file_prop/) {
1355                 $h = $ed->{$t} or next;
1356                 foreach my $path (sort keys %$h) {
1357                         my $ppath = $path eq '' ? '.' : $path;
1358                         foreach my $prop (sort keys %{$h->{$path}}) {
1359                                 next if $SKIP_PROP{$prop};
1360                                 my $v = $h->{$path}->{$prop};
1361                                 my $t_ppath_prop = "$t: " .
1362                                                     uri_encode($ppath) . ' ' .
1363                                                     uri_encode($prop);
1364                                 if (defined $v) {
1365                                         push @out, "  +$t_ppath_prop " .
1366                                                    uri_encode($v);
1367                                 } else {
1368                                         push @out, "  -$t_ppath_prop";
1369                                 }
1370                         }
1371                 }
1372         }
1373         foreach my $t (qw/absent_file absent_directory/) {
1374                 $h = $ed->{$t} or next;
1375                 foreach my $parent (sort keys %$h) {
1376                         foreach my $path (sort @{$h->{$parent}}) {
1377                                 push @out, "  $t: " .
1378                                            uri_encode("$parent/$path");
1379                                 warn "W: $t: $parent/$path ",
1380                                      "Insufficient permissions?\n";
1381                         }
1382                 }
1383         }
1384         \@out;
1385 }
1386
1387 # parse_svn_date(DATE)
1388 # --------------------
1389 # Given a date (in UTC) from Subversion, return a string in the format
1390 # "<TZ Offset> <local date/time>" that Git will use.
1391 #
1392 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
1393 # is true we'll convert it to the local timezone instead.
1394 sub parse_svn_date {
1395         my $date = shift || return '+0000 1970-01-01 00:00:00';
1396         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1397                                             (\d\d?)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
1398                                          croak "Unable to parse date: $date\n";
1399         my $parsed_date;    # Set next.
1400
1401         if ($Git::SVN::_localtime) {
1402                 # Translate the Subversion datetime to an epoch time.
1403                 # Begin by switching ourselves to $date's timezone, UTC.
1404                 my $old_env_TZ = $ENV{TZ};
1405                 $ENV{TZ} = 'UTC';
1406
1407                 my $epoch_in_UTC =
1408                     Time::Local::timelocal($S, $M, $H, $d, $m - 1, $Y - 1900);
1409
1410                 # Determine our local timezone (including DST) at the
1411                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
1412                 # value of TZ, if any, at the time we were run.
1413                 if (defined $Git::SVN::Log::TZ) {
1414                         $ENV{TZ} = $Git::SVN::Log::TZ;
1415                 } else {
1416                         delete $ENV{TZ};
1417                 }
1418
1419                 my $our_TZ = get_tz_offset($epoch_in_UTC);
1420
1421                 # This converts $epoch_in_UTC into our local timezone.
1422                 my ($sec, $min, $hour, $mday, $mon, $year,
1423                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
1424
1425                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
1426                                        $our_TZ, $year + 1900, $mon + 1,
1427                                        $mday, $hour, $min, $sec);
1428
1429                 # Reset us to the timezone in effect when we entered
1430                 # this routine.
1431                 if (defined $old_env_TZ) {
1432                         $ENV{TZ} = $old_env_TZ;
1433                 } else {
1434                         delete $ENV{TZ};
1435                 }
1436         } else {
1437                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
1438         }
1439
1440         return $parsed_date;
1441 }
1442
1443 sub other_gs {
1444         my ($self, $new_url, $url,
1445             $branch_from, $r, $old_ref_id) = @_;
1446         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
1447         unless ($gs) {
1448                 my $ref_id = $old_ref_id;
1449                 $ref_id =~ s/\@\d+-*$//;
1450                 $ref_id .= "\@$r";
1451                 # just grow a tail if we're not unique enough :x
1452                 $ref_id .= '-' while find_ref($ref_id);
1453                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
1454                 if ($u =~ s#^\Q$url\E(/|$)##) {
1455                         $p = $u;
1456                         $u = $url;
1457                         $repo_id = $self->{repo_id};
1458                 }
1459                 while (1) {
1460                         # It is possible to tag two different subdirectories at
1461                         # the same revision.  If the url for an existing ref
1462                         # does not match, we must either find a ref with a
1463                         # matching url or create a new ref by growing a tail.
1464                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
1465                         my (undef, $max_commit) = $gs->rev_map_max(1);
1466                         last if (!$max_commit);
1467                         my ($url) = ::cmt_metadata($max_commit);
1468                         last if ($url eq $gs->metadata_url);
1469                         $ref_id .= '-';
1470                 }
1471                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
1472         }
1473         $gs
1474 }
1475
1476 sub call_authors_prog {
1477         my ($orig_author) = @_;
1478         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
1479         my $author = `$::_authors_prog $orig_author`;
1480         if ($? != 0) {
1481                 die "$::_authors_prog failed with exit code $?\n"
1482         }
1483         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
1484                 my ($name, $email) = ($1, $2);
1485                 $email = undef if length $2 == 0;
1486                 return [$name, $email];
1487         } else {
1488                 die "Author: $orig_author: $::_authors_prog returned "
1489                         . "invalid author format: $author\n";
1490         }
1491 }
1492
1493 sub check_author {
1494         my ($author) = @_;
1495         if (!defined $author || length $author == 0) {
1496                 $author = '(no author)';
1497         }
1498         if (!defined $::users{$author}) {
1499                 if (defined $::_authors_prog) {
1500                         $::users{$author} = call_authors_prog($author);
1501                 } elsif (defined $::_authors) {
1502                         die "Author: $author not defined in $::_authors file\n";
1503                 }
1504         }
1505         $author;
1506 }
1507
1508 sub find_extra_svk_parents {
1509         my ($self, $tickets, $parents) = @_;
1510         # aha!  svk:merge property changed...
1511         my @tickets = split "\n", $tickets;
1512         my @known_parents;
1513         for my $ticket ( @tickets ) {
1514                 my ($uuid, $path, $rev) = split /:/, $ticket;
1515                 if ( $uuid eq $self->ra_uuid ) {
1516                         my $repos_root = $self->url;
1517                         my $branch_from = $path;
1518                         $branch_from =~ s{^/}{};
1519                         my $gs = $self->other_gs(add_path_to_url( $repos_root, $branch_from ),
1520                                                  $repos_root,
1521                                                  $branch_from,
1522                                                  $rev,
1523                                                  $self->{ref_id});
1524                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
1525                                 # wahey!  we found it, but it might be
1526                                 # an old one (!)
1527                                 push @known_parents, [ $rev, $commit ];
1528                         }
1529                 }
1530         }
1531         # Ordering matters; highest-numbered commit merge tickets
1532         # first, as they may account for later merge ticket additions
1533         # or changes.
1534         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
1535         for my $parent ( @known_parents ) {
1536                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
1537                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
1538                 my $new;
1539                 while ( <$msg_fh> ) {
1540                         $new=1;last;
1541                 }
1542                 command_close_pipe($msg_fh, $ctx);
1543                 if ( $new ) {
1544                         print STDERR
1545                             "Found merge parent (svk:merge ticket): $parent\n";
1546                         push @$parents, $parent;
1547                 }
1548         }
1549 }
1550
1551 sub lookup_svn_merge {
1552         my $uuid = shift;
1553         my $url = shift;
1554         my $source = shift;
1555         my $revs = shift;
1556
1557         my $path = $source;
1558         $path =~ s{^/}{};
1559         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
1560         if ( !$gs ) {
1561                 warn "Couldn't find revmap for $url$source\n";
1562                 return;
1563         }
1564         my @ranges = split ",", $revs;
1565         my ($tip, $tip_commit);
1566         my @merged_commit_ranges;
1567         # find the tip
1568         for my $range ( @ranges ) {
1569                 if ($range =~ /[*]$/) {
1570                         warn "W: Ignoring partial merge in svn:mergeinfo "
1571                                 ."dirprop: $source:$range\n";
1572                         next;
1573                 }
1574                 my ($bottom, $top) = split "-", $range;
1575                 $top ||= $bottom;
1576                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
1577                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
1578
1579                 unless ($top_commit and $bottom_commit) {
1580                         warn "W: unknown path/rev in svn:mergeinfo "
1581                                 ."dirprop: $source:$range\n";
1582                         next;
1583                 }
1584
1585                 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
1586                         push @merged_commit_ranges,
1587                              "$bottom_commit^..$top_commit";
1588                 } else {
1589                         push @merged_commit_ranges, "$top_commit";
1590                 }
1591
1592                 if ( !defined $tip or $top > $tip ) {
1593                         $tip = $top;
1594                         $tip_commit = $top_commit;
1595                 }
1596         }
1597         return ($tip_commit, @merged_commit_ranges);
1598 }
1599
1600 sub _rev_list {
1601         my ($msg_fh, $ctx) = command_output_pipe(
1602                 "rev-list", @_,
1603                );
1604         my @rv;
1605         while ( <$msg_fh> ) {
1606                 chomp;
1607                 push @rv, $_;
1608         }
1609         command_close_pipe($msg_fh, $ctx);
1610         @rv;
1611 }
1612
1613 sub check_cherry_pick2 {
1614         my $base = shift;
1615         my $tip = shift;
1616         my $parents = shift;
1617         my @ranges = @_;
1618         my %commits = map { $_ => 1 }
1619                 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
1620         for my $range ( @ranges ) {
1621                 delete @commits{_rev_list($range, "--")};
1622         }
1623         for my $commit (keys %commits) {
1624                 if (has_no_changes($commit)) {
1625                         delete $commits{$commit};
1626                 }
1627         }
1628         my @k = (keys %commits);
1629         return (scalar @k, $k[0]);
1630 }
1631
1632 sub has_no_changes {
1633         my $commit = shift;
1634
1635         my @revs = split / /, command_oneline(
1636                 qw(rev-list --parents -1 -m), $commit);
1637
1638         # Commits with no parents, e.g. the start of a partial branch,
1639         # have changes by definition.
1640         return 1 if (@revs < 2);
1641
1642         # Commits with multiple parents, e.g a merge, have no changes
1643         # by definition.
1644         return 0 if (@revs > 2);
1645
1646         return (command_oneline("rev-parse", "$commit^{tree}") eq
1647                 command_oneline("rev-parse", "$commit~1^{tree}"));
1648 }
1649
1650 sub tie_for_persistent_memoization {
1651         my $hash = shift;
1652         my $path = shift;
1653
1654         unless ($memo_backend) {
1655                 if (eval { require Git::SVN::Memoize::YAML; 1}) {
1656                         $memo_backend = 1;
1657                 } else {
1658                         require Memoize::Storable;
1659                         $memo_backend = -1;
1660                 }
1661         }
1662
1663         if ($memo_backend > 0) {
1664                 tie %$hash => 'Git::SVN::Memoize::YAML', "$path.yaml";
1665         } else {
1666                 # first verify that any existing file can actually be loaded
1667                 # (it may have been saved by an incompatible version)
1668                 my $db = "$path.db";
1669                 if (-e $db) {
1670                         use Storable qw(retrieve);
1671
1672                         if (!eval { retrieve($db); 1 }) {
1673                                 unlink $db or die "unlink $db failed: $!";
1674                         }
1675                 }
1676                 tie %$hash => 'Memoize::Storable', $db, 'nstore';
1677         }
1678 }
1679
1680 # The GIT_DIR environment variable is not always set until after the command
1681 # line arguments are processed, so we can't memoize in a BEGIN block.
1682 {
1683         my $memoized = 0;
1684
1685         sub memoize_svn_mergeinfo_functions {
1686                 return if $memoized;
1687                 $memoized = 1;
1688
1689                 my $cache_path = svn_dir() . '/.caches/';
1690                 mkpath([$cache_path]) unless -d $cache_path;
1691
1692                 my %lookup_svn_merge_cache;
1693                 my %check_cherry_pick2_cache;
1694                 my %has_no_changes_cache;
1695
1696                 tie_for_persistent_memoization(\%lookup_svn_merge_cache,
1697                     "$cache_path/lookup_svn_merge");
1698                 memoize 'lookup_svn_merge',
1699                         SCALAR_CACHE => 'FAULT',
1700                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
1701                 ;
1702
1703                 tie_for_persistent_memoization(\%check_cherry_pick2_cache,
1704                     "$cache_path/check_cherry_pick2");
1705                 memoize 'check_cherry_pick2',
1706                         SCALAR_CACHE => 'FAULT',
1707                         LIST_CACHE => ['HASH' => \%check_cherry_pick2_cache],
1708                 ;
1709
1710                 tie_for_persistent_memoization(\%has_no_changes_cache,
1711                     "$cache_path/has_no_changes");
1712                 memoize 'has_no_changes',
1713                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
1714                         LIST_CACHE => 'FAULT',
1715                 ;
1716         }
1717
1718         sub unmemoize_svn_mergeinfo_functions {
1719                 return if not $memoized;
1720                 $memoized = 0;
1721
1722                 Memoize::unmemoize 'lookup_svn_merge';
1723                 Memoize::unmemoize 'check_cherry_pick2';
1724                 Memoize::unmemoize 'has_no_changes';
1725         }
1726
1727         sub clear_memoized_mergeinfo_caches {
1728                 die "Only call this method in non-memoized context" if ($memoized);
1729
1730                 my $cache_path = svn_dir() . '/.caches/';
1731                 return unless -d $cache_path;
1732
1733                 for my $cache_file (("$cache_path/lookup_svn_merge",
1734                                      "$cache_path/check_cherry_pick", # old
1735                                      "$cache_path/check_cherry_pick2",
1736                                      "$cache_path/has_no_changes")) {
1737                         for my $suffix (qw(yaml db)) {
1738                                 my $file = "$cache_file.$suffix";
1739                                 next unless -e $file;
1740                                 unlink($file) or die "unlink($file) failed: $!\n";
1741                         }
1742                 }
1743         }
1744
1745
1746         Memoize::memoize 'Git::SVN::repos_root';
1747 }
1748
1749 END {
1750         # Force cache writeout explicitly instead of waiting for
1751         # global destruction to avoid segfault in Storable:
1752         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
1753         unmemoize_svn_mergeinfo_functions();
1754 }
1755
1756 sub parents_exclude {
1757         my $parents = shift;
1758         my @commits = @_;
1759         return unless @commits;
1760
1761         my @excluded;
1762         my $excluded;
1763         do {
1764                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
1765                 $excluded = command_oneline(@cmd);
1766                 if ( $excluded ) {
1767                         my @new;
1768                         my $found;
1769                         for my $commit ( @commits ) {
1770                                 if ( $commit eq $excluded ) {
1771                                         push @excluded, $commit;
1772                                         $found++;
1773                                 }
1774                                 else {
1775                                         push @new, $commit;
1776                                 }
1777                         }
1778                         die "saw commit '$excluded' in rev-list output, "
1779                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
1780                                         unless $found;
1781                         @commits = @new;
1782                 }
1783         }
1784                 while ($excluded and @commits);
1785
1786         return @excluded;
1787 }
1788
1789 # Compute what's new in svn:mergeinfo.
1790 sub mergeinfo_changes {
1791         my ($self, $old_path, $old_rev, $path, $rev, $mergeinfo_prop) = @_;
1792         my %minfo = map {split ":", $_ } split "\n", $mergeinfo_prop;
1793         my $old_minfo = {};
1794
1795         my $ra = $self->ra;
1796         # Give up if $old_path isn't in the repo.
1797         # This is probably a merge on a subtree.
1798         if ($ra->check_path($old_path, $old_rev) != $SVN::Node::dir) {
1799                 warn "W: ignoring svn:mergeinfo on $old_path, ",
1800                         "directory didn't exist in r$old_rev\n";
1801                 return {};
1802         }
1803         my (undef, undef, $props) = $ra->get_dir($old_path, $old_rev);
1804         if (defined $props->{"svn:mergeinfo"}) {
1805                 my %omi = map {split ":", $_ } split "\n",
1806                         $props->{"svn:mergeinfo"};
1807                 $old_minfo = \%omi;
1808         }
1809
1810         my %changes = ();
1811         foreach my $p (keys %minfo) {
1812                 my $a = $old_minfo->{$p} || "";
1813                 my $b = $minfo{$p};
1814                 # Omit merged branches whose ranges lists are unchanged.
1815                 next if $a eq $b;
1816                 # Remove any common range list prefix.
1817                 ($a ^ $b) =~ /^[\0]*/;
1818                 my $common_prefix = rindex $b, ",", $+[0] - 1;
1819                 $changes{$p} = substr $b, $common_prefix + 1;
1820         }
1821         print STDERR "Checking svn:mergeinfo changes since r$old_rev: ",
1822                 scalar(keys %minfo), " sources, ",
1823                 scalar(keys %changes), " changed\n";
1824
1825         return \%changes;
1826 }
1827
1828 # note: this function should only be called if the various dirprops
1829 # have actually changed
1830 sub find_extra_svn_parents {
1831         my ($self, $mergeinfo, $parents) = @_;
1832         # aha!  svk:merge property changed...
1833
1834         memoize_svn_mergeinfo_functions();
1835
1836         # We first search for merged tips which are not in our
1837         # history.  Then, we figure out which git revisions are in
1838         # that tip, but not this revision.  If all of those revisions
1839         # are now marked as merge, we can add the tip as a parent.
1840         my @merges = sort keys %$mergeinfo;
1841         my @merge_tips;
1842         my $url = $self->url;
1843         my $uuid = $self->ra_uuid;
1844         my @all_ranges;
1845         for my $merge ( @merges ) {
1846                 my ($tip_commit, @ranges) =
1847                         lookup_svn_merge( $uuid, $url,
1848                                           $merge, $mergeinfo->{$merge} );
1849                 unless (!$tip_commit or
1850                                 grep { $_ eq $tip_commit } @$parents ) {
1851                         push @merge_tips, $tip_commit;
1852                         push @all_ranges, @ranges;
1853                 } else {
1854                         push @merge_tips, undef;
1855                 }
1856         }
1857
1858         my %excluded = map { $_ => 1 }
1859                 parents_exclude($parents, grep { defined } @merge_tips);
1860
1861         # check merge tips for new parents
1862         my @new_parents;
1863         for my $merge_tip ( @merge_tips ) {
1864                 my $merge = shift @merges;
1865                 next unless $merge_tip and $excluded{$merge_tip};
1866                 my $spec = "$merge:$mergeinfo->{$merge}";
1867
1868                 # check out 'new' tips
1869                 my $merge_base;
1870                 eval {
1871                         $merge_base = command_oneline(
1872                                 "merge-base",
1873                                 @$parents, $merge_tip,
1874                         );
1875                 };
1876                 if ($@) {
1877                         die "An error occurred during merge-base"
1878                                 unless $@->isa("Git::Error::Command");
1879
1880                         warn "W: Cannot find common ancestor between ".
1881                              "@$parents and $merge_tip. Ignoring merge info.\n";
1882                         next;
1883                 }
1884
1885                 # double check that there are no missing non-merge commits
1886                 my ($ninc, $ifirst) = check_cherry_pick2(
1887                         $merge_base, $merge_tip,
1888                         $parents,
1889                         @all_ranges,
1890                        );
1891
1892                 if ($ninc) {
1893                         warn "W: svn cherry-pick ignored ($spec) - missing " .
1894                                 "$ninc commit(s) (eg $ifirst)\n";
1895                 } else {
1896                         warn "Found merge parent ($spec): ", $merge_tip, "\n";
1897                         push @new_parents, $merge_tip;
1898                 }
1899         }
1900
1901         # cater for merges which merge commits from multiple branches
1902         if ( @new_parents > 1 ) {
1903                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
1904                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
1905                                 next if $i == $j;
1906                                 next unless $new_parents[$i];
1907                                 next unless $new_parents[$j];
1908                                 my $revs = command_oneline(
1909                                         "rev-list", "-1",
1910                                         "$new_parents[$i]..$new_parents[$j]",
1911                                        );
1912                                 if ( !$revs ) {
1913                                         undef($new_parents[$j]);
1914                                 }
1915                         }
1916                 }
1917         }
1918         push @$parents, grep { defined } @new_parents;
1919 }
1920
1921 sub make_log_entry {
1922         my ($self, $rev, $parents, $ed, $parent_rev, $parent_path) = @_;
1923         my $untracked = $self->get_untracked($ed);
1924
1925         my @parents = @$parents;
1926         my $props = $ed->{dir_prop}{$self->path};
1927         if ($self->follow_parent) {
1928                 my $tickets = $props->{"svk:merge"};
1929                 if ($tickets) {
1930                         $self->find_extra_svk_parents($tickets, \@parents);
1931                 }
1932
1933                 my $mergeinfo_prop = $props->{"svn:mergeinfo"};
1934                 if ($mergeinfo_prop) {
1935                         my $mi_changes = $self->mergeinfo_changes(
1936                                                 $parent_path,
1937                                                 $parent_rev,
1938                                                 $self->path,
1939                                                 $rev,
1940                                                 $mergeinfo_prop);
1941                         $self->find_extra_svn_parents($mi_changes, \@parents);
1942                 }
1943         }
1944
1945         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1946         print $un "r$rev\n" or croak $!;
1947         print $un $_, "\n" foreach @$untracked;
1948         my %log_entry = ( parents => \@parents, revision => $rev,
1949                           log => '');
1950
1951         my $headrev;
1952         my $logged = delete $self->{logged_rev_props};
1953         if (!$logged || $self->{-want_revprops}) {
1954                 my $rp = $self->ra->rev_proplist($rev);
1955                 foreach (sort keys %$rp) {
1956                         my $v = $rp->{$_};
1957                         if (/^svn:(author|date|log)$/) {
1958                                 $log_entry{$1} = $v;
1959                         } elsif ($_ eq 'svm:headrev') {
1960                                 $headrev = $v;
1961                         } else {
1962                                 print $un "  rev_prop: ", uri_encode($_), ' ',
1963                                           uri_encode($v), "\n";
1964                         }
1965                 }
1966         } else {
1967                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1968         }
1969         close $un or croak $!;
1970
1971         $log_entry{date} = parse_svn_date($log_entry{date});
1972         $log_entry{log} .= "\n";
1973         my $author = $log_entry{author} = check_author($log_entry{author});
1974         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1975                                                        : ($author, undef);
1976
1977         my ($commit_name, $commit_email) = ($name, $email);
1978         if ($_use_log_author) {
1979                 my $name_field;
1980                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
1981                         $name_field = $1;
1982                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
1983                         $name_field = $1;
1984                 }
1985                 if (!defined $name_field) {
1986                         if (!defined $email) {
1987                                 $email = $name;
1988                         }
1989                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
1990                         ($name, $email) = ($1, $2);
1991                 } elsif ($name_field =~ /(.*)@/) {
1992                         ($name, $email) = ($1, $name_field);
1993                 } else {
1994                         ($name, $email) = ($name_field, $name_field);
1995                 }
1996         }
1997         if (defined $headrev && $self->use_svm_props) {
1998                 if ($self->rewrite_root) {
1999                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2000                             "options set!\n";
2001                 }
2002                 if ($self->rewrite_uuid) {
2003                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
2004                             "options set!\n";
2005                 }
2006                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2007                 # we don't want "SVM: initializing mirror for junk" ...
2008                 return undef if $r == 0;
2009                 my $svm = $self->svm;
2010                 if ($uuid ne $svm->{uuid}) {
2011                         die "UUID mismatch on SVM path:\n",
2012                             "expected: $svm->{uuid}\n",
2013                             "     got: $uuid\n";
2014                 }
2015                 my $full_url = $self->full_url;
2016                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2017                              die "Failed to replace '$svm->{replace}' with ",
2018                                  "'$svm->{source}' in $full_url\n";
2019                 # throw away username for storing in records
2020                 remove_username($full_url);
2021                 $log_entry{metadata} = "$full_url\@$r $uuid";
2022                 $log_entry{svm_revision} = $r;
2023                 $email ||= "$author\@$uuid";
2024                 $commit_email ||= "$author\@$uuid";
2025         } elsif ($self->use_svnsync_props) {
2026                 my $full_url = canonicalize_url(
2027                         add_path_to_url( $self->svnsync->{url}, $self->path )
2028                 );
2029                 remove_username($full_url);
2030                 my $uuid = $self->svnsync->{uuid};
2031                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2032                 $email ||= "$author\@$uuid";
2033                 $commit_email ||= "$author\@$uuid";
2034         } else {
2035                 my $url = $self->metadata_url;
2036                 remove_username($url);
2037                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
2038                 $log_entry{metadata} = "$url\@$rev " . $uuid;
2039                 $email ||= "$author\@" . $uuid;
2040                 $commit_email ||= "$author\@" . $uuid;
2041         }
2042         $log_entry{name} = $name;
2043         $log_entry{email} = $email;
2044         $log_entry{commit_name} = $commit_name;
2045         $log_entry{commit_email} = $commit_email;
2046         \%log_entry;
2047 }
2048
2049 sub fetch {
2050         my ($self, $min_rev, $max_rev, @parents) = @_;
2051         my ($last_rev, $last_commit) = $self->last_rev_commit;
2052         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2053         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2054 }
2055
2056 sub set_tree_cb {
2057         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2058         $self->{inject_parents} = { $rev => $tree };
2059         $self->fetch(undef, undef);
2060 }
2061
2062 sub set_tree {
2063         my ($self, $tree) = (shift, shift);
2064         my $log_entry = ::get_commit_entry($tree);
2065         unless ($self->{last_rev}) {
2066                 fatal("Must have an existing revision to commit");
2067         }
2068         my %ed_opts = ( r => $self->{last_rev},
2069                         log => $log_entry->{log},
2070                         ra => $self->ra,
2071                         tree_a => $self->{last_commit},
2072                         tree_b => $tree,
2073                         editor_cb => sub {
2074                                $self->set_tree_cb($log_entry, $tree, @_) },
2075                         svn_path => $self->path );
2076         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
2077                 print "No changes\nr$self->{last_rev} = $tree\n";
2078         }
2079 }
2080
2081 sub rebuild_from_rev_db {
2082         my ($self, $path) = @_;
2083         my $r = -1;
2084         open my $fh, '<', $path or croak "open: $!";
2085         binmode $fh or croak "binmode: $!";
2086         while (<$fh>) {
2087                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2088                 chomp($_);
2089                 ++$r;
2090                 next if $_ eq ('0' x 40);
2091                 $self->rev_map_set($r, $_);
2092                 print "r$r = $_\n";
2093         }
2094         close $fh or croak "close: $!";
2095         unlink $path or croak "unlink: $!";
2096 }
2097
2098 #define a global associate map to record rebuild status
2099 my %rebuild_status;
2100 #define a global associate map to record rebuild verify status
2101 my %rebuild_verify_status;
2102
2103 sub rebuild {
2104         my ($self) = @_;
2105         my $map_path = $self->map_path;
2106         my $partial = (-e $map_path && ! -z $map_path);
2107         my $verify_key = $self->refname.'^0';
2108         if (!$rebuild_verify_status{$verify_key}) {
2109                 my $verify_result = ::verify_ref($verify_key);
2110                 if ($verify_result) {
2111                         $rebuild_verify_status{$verify_key} = 1;
2112                 }
2113         }
2114         if (!$rebuild_verify_status{$verify_key}) {
2115                 return;
2116         }
2117         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2118                 my $rev_db = $self->rev_db_path;
2119                 $self->rebuild_from_rev_db($rev_db);
2120                 if ($self->use_svm_props) {
2121                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2122                         $self->rebuild_from_rev_db($svm_rev_db);
2123                 }
2124                 $self->unlink_rev_db_symlink;
2125                 return;
2126         }
2127         print "Rebuilding $map_path ...\n" if (!$partial);
2128         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2129                 (undef, undef));
2130         my $key_value = ($head ? "$head.." : "") . $self->refname;
2131         if (exists $rebuild_status{$key_value}) {
2132                 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2133                 my $rev_db_path = $self->rev_db_path;
2134                 if (-f $self->rev_db_path) {
2135                         unlink $self->rev_db_path or croak "unlink: $!";
2136                 }
2137                 $self->unlink_rev_db_symlink;
2138                 return;
2139         }
2140         my ($log, $ctx) =
2141                 command_output_pipe(qw/rev-list --pretty=raw --reverse/,
2142                                 $key_value,
2143                                 '--');
2144         $rebuild_status{$key_value} = 1;
2145         my $metadata_url = $self->metadata_url;
2146         remove_username($metadata_url);
2147         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
2148         my $c;
2149         while (<$log>) {
2150                 if ( m{^commit ($::sha1)$} ) {
2151                         $c = $1;
2152                         next;
2153                 }
2154                 next unless s{^\s*(git-svn-id:)}{$1};
2155                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2156                 remove_username($url);
2157
2158                 # ignore merges (from set-tree)
2159                 next if (!defined $rev || !$uuid);
2160
2161                 # if we merged or otherwise started elsewhere, this is
2162                 # how we break out of it
2163                 if (($uuid ne $svn_uuid) ||
2164                     ($metadata_url && $url && ($url ne $metadata_url))) {
2165                         next;
2166                 }
2167                 if ($partial && $head) {
2168                         print "Partial-rebuilding $map_path ...\n";
2169                         print "Currently at $base_rev = $head\n";
2170                         $head = undef;
2171                 }
2172
2173                 $self->rev_map_set($rev, $c);
2174                 print "r$rev = $c\n";
2175         }
2176         command_close_pipe($log, $ctx);
2177         print "Done rebuilding $map_path\n" if (!$partial || !$head);
2178         my $rev_db_path = $self->rev_db_path;
2179         if (-f $self->rev_db_path) {
2180                 unlink $self->rev_db_path or croak "unlink: $!";
2181         }
2182         $self->unlink_rev_db_symlink;
2183 }
2184
2185 # rev_map:
2186 # Tie::File seems to be prone to offset errors if revisions get sparse,
2187 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2188 # one of my favorite modules is out :<  Next up would be one of the DBM
2189 # modules, but I'm not sure which is most portable...
2190 #
2191 # This is the replacement for the rev_db format, which was too big
2192 # and inefficient for large repositories with a lot of sparse history
2193 # (mainly tags)
2194 #
2195 # The format is this:
2196 #   - 24 bytes for every record,
2197 #     * 4 bytes for the integer representing an SVN revision number
2198 #     * 20 bytes representing the sha1 of a git commit
2199 #   - No empty padding records like the old format
2200 #     (except the last record, which can be overwritten)
2201 #   - new records are written append-only since SVN revision numbers
2202 #     increase monotonically
2203 #   - lookups on SVN revision number are done via a binary search
2204 #   - Piping the file to xxd -c24 is a good way of dumping it for
2205 #     viewing or editing (piped back through xxd -r), should the need
2206 #     ever arise.
2207 #   - The last record can be padding revision with an all-zero sha1
2208 #     This is used to optimize fetch performance when using multiple
2209 #     "fetch" directives in .git/config
2210 #
2211 # These files are disposable unless noMetadata or useSvmProps is set
2212
2213 sub _rev_map_set {
2214         my ($fh, $rev, $commit) = @_;
2215
2216         binmode $fh or croak "binmode: $!";
2217         my $size = (stat($fh))[7];
2218         ($size % 24) == 0 or croak "inconsistent size: $size";
2219
2220         my $wr_offset = 0;
2221         if ($size > 0) {
2222                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2223                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2224                 $read == 24 or croak "read only $read bytes (!= 24)";
2225                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2226                 if ($last_commit eq ('0' x40)) {
2227                         if ($size >= 48) {
2228                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2229                                 $read = sysread($fh, $buf, 24) or
2230                                     croak "read: $!";
2231                                 $read == 24 or
2232                                     croak "read only $read bytes (!= 24)";
2233                                 ($last_rev, $last_commit) =
2234                                     unpack(rev_map_fmt, $buf);
2235                                 if ($last_commit eq ('0' x40)) {
2236                                         croak "inconsistent .rev_map\n";
2237                                 }
2238                         }
2239                         if ($last_rev >= $rev) {
2240                                 croak "last_rev is higher!: $last_rev >= $rev";
2241                         }
2242                         $wr_offset = -24;
2243                 }
2244         }
2245         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2246         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2247           croak "write: $!";
2248 }
2249
2250 sub _rev_map_reset {
2251         my ($fh, $rev, $commit) = @_;
2252         my $c = _rev_map_get($fh, $rev);
2253         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
2254         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
2255         truncate $fh, $offset or croak "truncate: $!";
2256 }
2257
2258 sub mkfile {
2259         my ($path) = @_;
2260         unless (-e $path) {
2261                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2262                 mkpath([$dir]) unless -d $dir;
2263                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2264                 close $fh or die "Couldn't close (create) $path: $!\n";
2265         }
2266 }
2267
2268 sub rev_map_set {
2269         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2270         defined $commit or die "missing arg3\n";
2271         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2272         my $db = $self->map_path($uuid);
2273         my $db_lock = "$db.lock";
2274         my $sigmask;
2275         $update_ref ||= 0;
2276         if ($update_ref) {
2277                 $sigmask = POSIX::SigSet->new();
2278                 my $signew = POSIX::SigSet->new(SIGINT, SIGHUP, SIGTERM,
2279                         SIGALRM, SIGUSR1, SIGUSR2);
2280                 sigprocmask(SIG_BLOCK, $signew, $sigmask) or
2281                         croak "Can't block signals: $!";
2282         }
2283         mkfile($db);
2284
2285         $LOCKFILES{$db_lock} = 1;
2286         my $sync;
2287         # both of these options make our .rev_db file very, very important
2288         # and we can't afford to lose it because rebuild() won't work
2289         if ($self->use_svm_props || $self->no_metadata) {
2290                 require File::Copy;
2291                 $sync = 1;
2292                 File::Copy::copy($db, $db_lock) or die "rev_map_set(@_): ",
2293                                            "Failed to copy: ",
2294                                            "$db => $db_lock ($!)\n";
2295         } else {
2296                 rename $db, $db_lock or die "rev_map_set(@_): ",
2297                                             "Failed to rename: ",
2298                                             "$db => $db_lock ($!)\n";
2299         }
2300
2301         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2302              or croak "Couldn't open $db_lock: $!\n";
2303         if ($update_ref eq 'reset') {
2304                 clear_memoized_mergeinfo_caches();
2305                 _rev_map_reset($fh, $rev, $commit);
2306         } else {
2307                 _rev_map_set($fh, $rev, $commit);
2308         }
2309
2310         if ($sync) {
2311                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2312                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2313         }
2314         close $fh or croak $!;
2315         if ($update_ref) {
2316                 $_head = $self;
2317                 my $note = "";
2318                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
2319                 command_noisy('update-ref', '-m', "r$rev$note",
2320                               $self->refname, $commit);
2321         }
2322         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2323                                     "$db_lock => $db ($!)\n";
2324         delete $LOCKFILES{$db_lock};
2325         if ($update_ref) {
2326                 sigprocmask(SIG_SETMASK, $sigmask) or
2327                         croak "Can't restore signal mask: $!";
2328         }
2329 }
2330
2331 # If want_commit, this will return an array of (rev, commit) where
2332 # commit _must_ be a valid commit in the archive.
2333 # Otherwise, it'll return the max revision (whether or not the
2334 # commit is valid or just a 0x40 placeholder).
2335 sub rev_map_max {
2336         my ($self, $want_commit) = @_;
2337         $self->rebuild;
2338         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2339         $want_commit ? ($r, $c) : $r;
2340 }
2341
2342 sub rev_map_max_norebuild {
2343         my ($self, $want_commit) = @_;
2344         my $map_path = $self->map_path;
2345         stat $map_path or return $want_commit ? (0, undef) : 0;
2346         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2347         binmode $fh or croak "binmode: $!";
2348         my $size = (stat($fh))[7];
2349         ($size % 24) == 0 or croak "inconsistent size: $size";
2350
2351         if ($size == 0) {
2352                 close $fh or croak "close: $!";
2353                 return $want_commit ? (0, undef) : 0;
2354         }
2355
2356         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2357         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2358         my ($r, $c) = unpack(rev_map_fmt, $buf);
2359         if ($want_commit && $c eq ('0' x40)) {
2360                 if ($size < 48) {
2361                         return $want_commit ? (0, undef) : 0;
2362                 }
2363                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2364                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2365                 ($r, $c) = unpack(rev_map_fmt, $buf);
2366                 if ($c eq ('0'x40)) {
2367                         croak "Penultimate record is all-zeroes in $map_path";
2368                 }
2369         }
2370         close $fh or croak "close: $!";
2371         $want_commit ? ($r, $c) : $r;
2372 }
2373
2374 sub rev_map_get {
2375         my ($self, $rev, $uuid) = @_;
2376         my $map_path = $self->map_path($uuid);
2377         return undef unless -e $map_path;
2378
2379         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2380         my $c = _rev_map_get($fh, $rev);
2381         close($fh) or croak "close: $!";
2382         $c
2383 }
2384
2385 sub _rev_map_get {
2386         my ($fh, $rev) = @_;
2387
2388         binmode $fh or croak "binmode: $!";
2389         my $size = (stat($fh))[7];
2390         ($size % 24) == 0 or croak "inconsistent size: $size";
2391
2392         if ($size == 0) {
2393                 return undef;
2394         }
2395
2396         my ($l, $u) = (0, $size - 24);
2397         my ($r, $c, $buf);
2398
2399         while ($l <= $u) {
2400                 my $i = int(($l/24 + $u/24) / 2) * 24;
2401                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2402                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2403                 my ($r, $c) = unpack(rev_map_fmt, $buf);
2404
2405                 if ($r < $rev) {
2406                         $l = $i + 24;
2407                 } elsif ($r > $rev) {
2408                         $u = $i - 24;
2409                 } else { # $r == $rev
2410                         return $c eq ('0' x 40) ? undef : $c;
2411                 }
2412         }
2413         undef;
2414 }
2415
2416 # Finds the first svn revision that exists on (if $eq_ok is true) or
2417 # before $rev for the current branch.  It will not search any lower
2418 # than $min_rev.  Returns the git commit hash and svn revision number
2419 # if found, else (undef, undef).
2420 sub find_rev_before {
2421         my ($self, $rev, $eq_ok, $min_rev) = @_;
2422         --$rev unless $eq_ok;
2423         $min_rev ||= 1;
2424         my $max_rev = $self->rev_map_max;
2425         $rev = $max_rev if ($rev > $max_rev);
2426         while ($rev >= $min_rev) {
2427                 if (my $c = $self->rev_map_get($rev)) {
2428                         return ($rev, $c);
2429                 }
2430                 --$rev;
2431         }
2432         return (undef, undef);
2433 }
2434
2435 # Finds the first svn revision that exists on (if $eq_ok is true) or
2436 # after $rev for the current branch.  It will not search any higher
2437 # than $max_rev.  Returns the git commit hash and svn revision number
2438 # if found, else (undef, undef).
2439 sub find_rev_after {
2440         my ($self, $rev, $eq_ok, $max_rev) = @_;
2441         ++$rev unless $eq_ok;
2442         $max_rev ||= $self->rev_map_max;
2443         while ($rev <= $max_rev) {
2444                 if (my $c = $self->rev_map_get($rev)) {
2445                         return ($rev, $c);
2446                 }
2447                 ++$rev;
2448         }
2449         return (undef, undef);
2450 }
2451
2452 sub _new {
2453         my ($class, $repo_id, $ref_id, $path) = @_;
2454         unless (defined $repo_id && length $repo_id) {
2455                 $repo_id = $default_repo_id;
2456         }
2457         unless (defined $ref_id && length $ref_id) {
2458                 # Access the prefix option from the git-svn main program if it's loaded.
2459                 my $prefix = defined &::opt_prefix ? ::opt_prefix() : "";
2460                 $_[2] = $ref_id =
2461                              "refs/remotes/$prefix$default_ref_id";
2462         }
2463         $_[1] = $repo_id;
2464         my $svn_dir = svn_dir();
2465         my $dir = "$svn_dir/$ref_id";
2466
2467         # Older repos imported by us used $svn_dir/foo instead of
2468         # $svn_dir/refs/remotes/foo when tracking refs/remotes/foo
2469         if ($ref_id =~ m{^refs/remotes/(.+)}) {
2470                 my $old_dir = "$svn_dir/$1";
2471                 if (-d $old_dir && ! -d $dir) {
2472                         $dir = $old_dir;
2473                 }
2474         }
2475
2476         $_[3] = $path = '' unless (defined $path);
2477         mkpath([$dir]);
2478         my $obj = bless {
2479                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2480                 config => "$svn_dir/config",
2481                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2482
2483         # Ensure it gets canonicalized
2484         $obj->path($path);
2485
2486         return $obj;
2487 }
2488
2489 sub path {
2490         my $self = shift;
2491
2492         if (@_) {
2493                 my $path = shift;
2494                 $self->{_path} = canonicalize_path($path);
2495                 return;
2496         }
2497
2498         return $self->{_path};
2499 }
2500
2501 sub url {
2502         my $self = shift;
2503
2504         if (@_) {
2505                 my $url = shift;
2506                 $self->{url} = canonicalize_url($url);
2507                 return;
2508         }
2509
2510         return $self->{url};
2511 }
2512
2513 # for read-only access of old .rev_db formats
2514 sub unlink_rev_db_symlink {
2515         my ($self) = @_;
2516         my $link = $self->rev_db_path;
2517         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2518         if (-l $link) {
2519                 unlink $link or croak "unlink: $link failed!";
2520         }
2521 }
2522
2523 sub rev_db_path {
2524         my ($self, $uuid) = @_;
2525         my $db_path = $self->map_path($uuid);
2526         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2527             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2528         $db_path;
2529 }
2530
2531 # the new replacement for .rev_db
2532 sub map_path {
2533         my ($self, $uuid) = @_;
2534         $uuid ||= $self->ra_uuid;
2535         "$self->{map_root}.$uuid";
2536 }
2537
2538 sub uri_encode {
2539         my ($f) = @_;
2540         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#sprintf("%%%02X",ord($1))#eg;
2541         $f
2542 }
2543
2544 sub uri_decode {
2545         my ($f) = @_;
2546         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
2547         $f
2548 }
2549
2550 sub remove_username {
2551         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2552 }
2553
2554 1;