git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 $Git::SVN::Log::TZ = $ENV{TZ};
  25 $ENV{TZ} = 'UTC';
  26 $| = 1; # unbuffer STDOUT
  27
  28 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  29 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  30 require SVN::Ra;
  31 require SVN::Delta;
  32 if ($SVN::Core::VERSION lt '1.1.0') {
  33         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  34 }
  35 my $can_compress = eval { require Compress::Zlib; 1};
  36 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  37 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  38 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  39 use Carp qw/croak/;
  40 use Digest::MD5;
  41 use IO::File qw//;
  42 use File::Basename qw/dirname basename/;
  43 use File::Path qw/mkpath/;
  44 use File::Spec;
  45 use File::Find;
  46 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  47 use IPC::Open3;
  48 use Git;
  49
  50 BEGIN {
  51         # import functions from Git into our packages, en masse
  52         no strict 'refs';
  53         foreach (qw/command command_oneline command_noisy command_output_pipe
  54                     command_input_pipe command_close_pipe
  55                     command_bidi_pipe command_close_bidi_pipe/) {
  56                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  57                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  58                         __PACKAGE__) {
  59                         *{"${package}::$_"} = \&{"Git::$_"};
  60                 }
  61         }
  62 }
  63
  64 my ($SVN);
  65
  66 $sha1 = qr/[a-f\d]{40}/;
  67 $sha1_short = qr/[a-f\d]{4,40}/;
  68 my ($_stdin, $_help, $_edit,
  69         $_message, $_file, $_branch_dest,
  70         $_template, $_shared,
  71         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  72         $_merge, $_strategy, $_dry_run, $_local,
  73         $_prefix, $_no_checkout, $_url, $_verbose,
  74         $_git_format, $_commit_url, $_tag);
  75 $Git::SVN::_follow_parent = 1;
  76 $_q ||= 0;
  77 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  78                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  79                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  80                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  81 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  82                 'authors-file|A=s' => \$_authors,
  83                 'authors-prog=s' => \$_authors_prog,
  84                 'repack:i' => \$Git::SVN::_repack,
  85                 'noMetadata' => \$Git::SVN::_no_metadata,
  86                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  87                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  88                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  89                 'no-checkout' => \$_no_checkout,
  90                 'quiet|q+' => \$_q,
  91                 'repack-flags|repack-args|repack-opts=s' =>
  92                    \$Git::SVN::_repack_flags,
  93                 'use-log-author' => \$Git::SVN::_use_log_author,
  94                 'add-author-from' => \$Git::SVN::_add_author_from,
  95                 'localtime' => \$Git::SVN::_localtime,
  96                 %remote_opts );
  97
  98 my ($_trunk, @_tags, @_branches, $_stdlayout);
  99 my %icv;
 100 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 101                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 102                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 103                   'stdlayout|s' => \$_stdlayout,
 104                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 105                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 106                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 107                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 108                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 109                   %remote_opts );
 110 my %cmt_opts = ( 'edit|e' => \$_edit,
 111                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 112                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 113                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 114                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 115 );
 116
 117 my %cmd = (
 118         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 119                         { 'revision|r=s' => \$_revision,
 120                           'fetch-all|all' => \$_fetch_all,
 121                           'parent|p' => \$_fetch_parent,
 122                            %fc_opts } ],
 123         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 124                         { 'revision|r=s' => \$_revision,
 125                            %fc_opts, %init_opts } ],
 126         init => [ \&cmd_init, "Initialize a repo for tracking" .
 127                           " (requires URL argument)",
 128                           \%init_opts ],
 129         'multi-init' => [ \&cmd_multi_init,
 130                           "Deprecated alias for ".
 131                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 132                           \%init_opts ],
 133         dcommit => [ \&cmd_dcommit,
 134                      'Commit several diffs to merge with upstream',
 135                         { 'merge|m|M' => \$_merge,
 136                           'strategy|s=s' => \$_strategy,
 137                           'verbose|v' => \$_verbose,
 138                           'dry-run|n' => \$_dry_run,
 139                           'fetch-all|all' => \$_fetch_all,
 140                           'commit-url=s' => \$_commit_url,
 141                           'revision|r=i' => \$_revision,
 142                           'no-rebase' => \$_no_rebase,
 143                         %cmt_opts, %fc_opts } ],
 144         branch => [ \&cmd_branch,
 145                     'Create a branch in the SVN repository',
 146                     { 'message|m=s' => \$_message,
 147                       'destination|d=s' => \$_branch_dest,
 148                       'dry-run|n' => \$_dry_run,
 149                       'tag|t' => \$_tag } ],
 150         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 151                  'Create a tag in the SVN repository',
 152                  { 'message|m=s' => \$_message,
 153                    'destination|d=s' => \$_branch_dest,
 154                    'dry-run|n' => \$_dry_run } ],
 155         'set-tree' => [ \&cmd_set_tree,
 156                         "Set an SVN repository to a git tree-ish",
 157                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 158         'create-ignore' => [ \&cmd_create_ignore,
 159                              'Create a .gitignore per svn:ignore',
 160                              { 'revision|r=i' => \$_revision
 161                              } ],
 162         'propget' => [ \&cmd_propget,
 163                        'Print the value of a property on a file or directory',
 164                        { 'revision|r=i' => \$_revision } ],
 165         'proplist' => [ \&cmd_proplist,
 166                        'List all properties of a file or directory',
 167                        { 'revision|r=i' => \$_revision } ],
 168         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 169                         { 'revision|r=i' => \$_revision
 170                         } ],
 171         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 172                         { 'revision|r=i' => \$_revision
 173                         } ],
 174         'multi-fetch' => [ \&cmd_multi_fetch,
 175                            "Deprecated alias for $0 fetch --all",
 176                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 177         'migrate' => [ sub { },
 178                        # no-op, we automatically run this anyways,
 179                        'Migrate configuration/metadata/layout from
 180                         previous versions of git-svn',
 181                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 182                          %remote_opts } ],
 183         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 184                         { 'limit=i' => \$Git::SVN::Log::limit,
 185                           'revision|r=s' => \$_revision,
 186                           'verbose|v' => \$Git::SVN::Log::verbose,
 187                           'incremental' => \$Git::SVN::Log::incremental,
 188                           'oneline' => \$Git::SVN::Log::oneline,
 189                           'show-commit' => \$Git::SVN::Log::show_commit,
 190                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 191                           'authors-file|A=s' => \$_authors,
 192                           'color' => \$Git::SVN::Log::color,
 193                           'pager=s' => \$Git::SVN::Log::pager
 194                         } ],
 195         'find-rev' => [ \&cmd_find_rev,
 196                         "Translate between SVN revision numbers and tree-ish",
 197                         {} ],
 198         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 199                         { 'merge|m|M' => \$_merge,
 200                           'verbose|v' => \$_verbose,
 201                           'strategy|s=s' => \$_strategy,
 202                           'local|l' => \$_local,
 203                           'fetch-all|all' => \$_fetch_all,
 204                           'dry-run|n' => \$_dry_run,
 205                           %fc_opts } ],
 206         'commit-diff' => [ \&cmd_commit_diff,
 207                            'Commit a diff between two trees',
 208                         { 'message|m=s' => \$_message,
 209                           'file|F=s' => \$_file,
 210                           'revision|r=s' => \$_revision,
 211                         %cmt_opts } ],
 212         'info' => [ \&cmd_info,
 213                     "Show info about the latest SVN revision
 214                      on the current branch",
 215                     { 'url' => \$_url, } ],
 216         'blame' => [ \&Git::SVN::Log::cmd_blame,
 217                     "Show what revision and author last modified each line of a file",
 218                     { 'git-format' => \$_git_format } ],
 219         'reset' => [ \&cmd_reset,
 220                      "Undo fetches back to the specified SVN revision",
 221                      { 'revision|r=s' => \$_revision,
 222                        'parent|p' => \$_fetch_parent } ],
 223         'gc' => [ \&cmd_gc,
 224                   "Compress unhandled.log files in .git/svn and remove " .
 225                   "index files in .git/svn",
 226                 {} ],
 227 );
 228
 229 my $cmd;
 230 for (my $i = 0; $i < @ARGV; $i++) {
 231         if (defined $cmd{$ARGV[$i]}) {
 232                 $cmd = $ARGV[$i];
 233                 splice @ARGV, $i, 1;
 234                 last;
 235         } elsif ($ARGV[$i] eq 'help') {
 236                 $cmd = $ARGV[$i+1];
 237                 usage(0);
 238         }
 239 };
 240
 241 # make sure we're always running at the top-level working directory
 242 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 243         unless (-d $ENV{GIT_DIR}) {
 244                 if ($git_dir_user_set) {
 245                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 246                             "but it is not a directory\n";
 247                 }
 248                 my $git_dir = delete $ENV{GIT_DIR};
 249                 my $cdup = undef;
 250                 git_cmd_try {
 251                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 252                         $git_dir = '.' unless ($cdup);
 253                         chomp $cdup if ($cdup);
 254                         $cdup = "." unless ($cdup && length $cdup);
 255                 } "Already at toplevel, but $git_dir not found\n";
 256                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 257                 unless (-d $git_dir) {
 258                         die "$git_dir still not found after going to ",
 259                             "'$cdup'\n";
 260                 }
 261                 $ENV{GIT_DIR} = $git_dir;
 262         }
 263         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 264 }
 265
 266 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 267
 268 read_repo_config(\%opts);
 269 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 270         Getopt::Long::Configure('pass_through');
 271 }
 272 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 273                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 274                     'id|i=s' => \$Git::SVN::default_ref_id,
 275                     'svn-remote|remote|R=s' => sub {
 276                        $Git::SVN::no_reuse_existing = 1;
 277                        $Git::SVN::default_repo_id = $_[1] });
 278 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 279
 280 usage(0) if $_help;
 281 version() if $_version;
 282 usage(1) unless defined $cmd;
 283 load_authors() if $_authors;
 284 if (defined $_authors_prog) {
 285         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 286 }
 287
 288 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 289         Git::SVN::Migration::migration_check();
 290 }
 291 Git::SVN::init_vars();
 292 eval {
 293         Git::SVN::verify_remotes_sanity();
 294         $cmd{$cmd}->[0]->(@ARGV);
 295 };
 296 fatal $@ if $@;
 297 post_fetch_checkout();
 298 exit 0;
 299
 300 ####################### primary functions ######################
 301 sub usage {
 302         my $exit = shift || 0;
 303         my $fd = $exit ? \*STDERR : \*STDOUT;
 304         print $fd <<"";
 305 git-svn - bidirectional operations between a single Subversion tree and git
 306 Usage: git svn <command> [options] [arguments]\n
 307
 308         print $fd "Available commands:\n" unless $cmd;
 309
 310         foreach (sort keys %cmd) {
 311                 next if $cmd && $cmd ne $_;
 312                 next if /^multi-/; # don't show deprecated commands
 313                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 314                 foreach (sort keys %{$cmd{$_}->[2]}) {
 315                         # mixed-case options are for .git/config only
 316                         next if /[A-Z]/ && /^[a-z]+$/i;
 317                         # prints out arguments as they should be passed:
 318                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 319                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 320                                                         "--$_" : "-$_" }
 321                                                 split /\|/,$_)," $x\n";
 322                 }
 323         }
 324         print $fd <<"";
 325 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 326 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 327 one git repository and want to keep them separate.  See git-svn(1) for more
 328 information.
 329
 330         exit $exit;
 331 }
 332
 333 sub version {
 334         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 335         exit 0;
 336 }
 337
 338 sub do_git_init_db {
 339         unless (-d $ENV{GIT_DIR}) {
 340                 my @init_db = ('init');
 341                 push @init_db, "--template=$_template" if defined $_template;
 342                 if (defined $_shared) {
 343                         if ($_shared =~ /[a-z]/) {
 344                                 push @init_db, "--shared=$_shared";
 345                         } else {
 346                                 push @init_db, "--shared";
 347                         }
 348                 }
 349                 command_noisy(@init_db);
 350                 $_repository = Git->repository(Repository => ".git");
 351         }
 352         command_noisy('config', 'core.autocrlf', 'false');
 353         my $set;
 354         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 355         foreach my $i (keys %icv) {
 356                 die "'$set' and '$i' cannot both be set\n" if $set;
 357                 next unless defined $icv{$i};
 358                 command_noisy('config', "$pfx.$i", $icv{$i});
 359                 $set = $i;
 360         }
 361         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 362         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 363                 if defined $$ignore_regex;
 364 }
 365
 366 sub init_subdir {
 367         my $repo_path = shift or return;
 368         mkpath([$repo_path]) unless -d $repo_path;
 369         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 370         $ENV{GIT_DIR} = '.git';
 371         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 372 }
 373
 374 sub cmd_clone {
 375         my ($url, $path) = @_;
 376         if (!defined $path &&
 377             (defined $_trunk || @_branches || @_tags ||
 378              defined $_stdlayout) &&
 379             $url !~ m#^[a-z\+]+://#) {
 380                 $path = $url;
 381         }
 382         $path = basename($url) if !defined $path || !length $path;
 383         cmd_init($url, $path);
 384         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 385         command_oneline('config', 'svn.authorsfile', $_authors) if $_authors;
 386 }
 387
 388 sub cmd_init {
 389         if (defined $_stdlayout) {
 390                 $_trunk = 'trunk' if (!defined $_trunk);
 391                 @_tags = 'tags' if (! @_tags);
 392                 @_branches = 'branches' if (! @_branches);
 393         }
 394         if (defined $_trunk || @_branches || @_tags) {
 395                 return cmd_multi_init(@_);
 396         }
 397         my $url = shift or die "SVN repository location required ",
 398                                "as a command-line argument\n";
 399         $url = canonicalize_url($url);
 400         init_subdir(@_);
 401         do_git_init_db();
 402
 403         if ($Git::SVN::_minimize_url eq 'unset') {
 404                 $Git::SVN::_minimize_url = 0;
 405         }
 406
 407         Git::SVN->init($url);
 408 }
 409
 410 sub cmd_fetch {
 411         if (grep /^\d+=./, @_) {
 412                 die "'<rev>=<commit>' fetch arguments are ",
 413                     "no longer supported.\n";
 414         }
 415         my ($remote) = @_;
 416         if (@_ > 1) {
 417                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 418         }
 419         if ($_fetch_parent) {
 420                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 421                 unless ($gs) {
 422                         die "Unable to determine upstream SVN information from ",
 423                             "working tree history\n";
 424                 }
 425                 # just fetch, don't checkout.
 426                 $_no_checkout = 'true';
 427                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 428         } elsif ($_fetch_all) {
 429                 cmd_multi_fetch();
 430         } else {
 431                 $remote ||= $Git::SVN::default_repo_id;
 432                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 433         }
 434 }
 435
 436 sub cmd_set_tree {
 437         my (@commits) = @_;
 438         if ($_stdin || !@commits) {
 439                 print "Reading from stdin...\n";
 440                 @commits = ();
 441                 while (<STDIN>) {
 442                         if (/\b($sha1_short)\b/o) {
 443                                 unshift @commits, $1;
 444                         }
 445                 }
 446         }
 447         my @revs;
 448         foreach my $c (@commits) {
 449                 my @tmp = command('rev-parse',$c);
 450                 if (scalar @tmp == 1) {
 451                         push @revs, $tmp[0];
 452                 } elsif (scalar @tmp > 1) {
 453                         push @revs, reverse(command('rev-list',@tmp));
 454                 } else {
 455                         fatal "Failed to rev-parse $c";
 456                 }
 457         }
 458         my $gs = Git::SVN->new;
 459         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 460         $gs->fetch;
 461         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 462                 fatal "There are new revisions that were fetched ",
 463                       "and need to be merged (or acknowledged) ",
 464                       "before committing.\nlast rev: $r_last\n",
 465                       " current: $gs->{last_rev}";
 466         }
 467         $gs->set_tree($_) foreach @revs;
 468         print "Done committing ",scalar @revs," revisions to SVN\n";
 469         unlink $gs->{index};
 470 }
 471
 472 sub cmd_dcommit {
 473         my $head = shift;
 474         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 475                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 476                 . "or stash them with `git stash'.\n";
 477         $head ||= 'HEAD';
 478
 479         my $old_head;
 480         if ($head ne 'HEAD') {
 481                 $old_head = eval {
 482                         command_oneline([qw/symbolic-ref -q HEAD/])
 483                 };
 484                 if ($old_head) {
 485                         $old_head =~ s{^refs/heads/}{};
 486                 } else {
 487                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 488                 }
 489                 command(['checkout', $head], STDERR => 0);
 490         }
 491
 492         my @refs;
 493         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 494         unless ($gs) {
 495                 die "Unable to determine upstream SVN information from ",
 496                     "$head history.\nPerhaps the repository is empty.";
 497         }
 498
 499         if (defined $_commit_url) {
 500                 $url = $_commit_url;
 501         } else {
 502                 $url = eval { command_oneline('config', '--get',
 503                               "svn-remote.$gs->{repo_id}.commiturl") };
 504                 if (!$url) {
 505                         $url = $gs->full_url
 506                 }
 507         }
 508
 509         my $last_rev = $_revision if defined $_revision;
 510         if ($url) {
 511                 print "Committing to $url ...\n";
 512         }
 513         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 514         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 515                 warn "Attempting to commit more than one change while ",
 516                      "--no-rebase is enabled.\n",
 517                      "If these changes depend on each other, re-running ",
 518                      "without --no-rebase may be required."
 519         }
 520         my $expect_url = $url;
 521         Git::SVN::remove_username($expect_url);
 522         while (1) {
 523                 my $d = shift @$linear_refs or last;
 524                 unless (defined $last_rev) {
 525                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 526                         unless (defined $last_rev) {
 527                                 fatal "Unable to extract revision information ",
 528                                       "from commit $d~1";
 529                         }
 530                 }
 531                 if ($_dry_run) {
 532                         print "diff-tree $d~1 $d\n";
 533                 } else {
 534                         my $cmt_rev;
 535                         my %ed_opts = ( r => $last_rev,
 536                                         log => get_commit_entry($d)->{log},
 537                                         ra => Git::SVN::Ra->new($url),
 538                                         config => SVN::Core::config_get_config(
 539                                                 $Git::SVN::Ra::config_dir
 540                                         ),
 541                                         tree_a => "$d~1",
 542                                         tree_b => $d,
 543                                         editor_cb => sub {
 544                                                print "Committed r$_[0]\n";
 545                                                $cmt_rev = $_[0];
 546                                         },
 547                                         svn_path => '');
 548                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 549                                 print "No changes\n$d~1 == $d\n";
 550                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 551                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 552                                                                $parents->{$d};
 553                         }
 554                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 555                         $last_rev = $cmt_rev;
 556                         next if $_no_rebase;
 557
 558                         # we always want to rebase against the current HEAD,
 559                         # not any head that was passed to us
 560                         my @diff = command('diff-tree', $d,
 561                                            $gs->refname, '--');
 562                         my @finish;
 563                         if (@diff) {
 564                                 @finish = rebase_cmd();
 565                                 print STDERR "W: $d and ", $gs->refname,
 566                                              " differ, using @finish:\n",
 567                                              join("\n", @diff), "\n";
 568                         } else {
 569                                 print "No changes between current HEAD and ",
 570                                       $gs->refname,
 571                                       "\nResetting to the latest ",
 572                                       $gs->refname, "\n";
 573                                 @finish = qw/reset --mixed/;
 574                         }
 575                         command_noisy(@finish, $gs->refname);
 576                         if (@diff) {
 577                                 @refs = ();
 578                                 my ($url_, $rev_, $uuid_, $gs_) =
 579                                               working_head_info('HEAD', \@refs);
 580                                 my ($linear_refs_, $parents_) =
 581                                               linearize_history($gs_, \@refs);
 582                                 if (scalar(@$linear_refs) !=
 583                                     scalar(@$linear_refs_)) {
 584                                         fatal "# of revisions changed ",
 585                                           "\nbefore:\n",
 586                                           join("\n", @$linear_refs),
 587                                           "\n\nafter:\n",
 588                                           join("\n", @$linear_refs_), "\n",
 589                                           'If you are attempting to commit ',
 590                                           "merges, try running:\n\t",
 591                                           'git rebase --interactive',
 592                                           '--preserve-merges ',
 593                                           $gs->refname,
 594                                           "\nBefore dcommitting";
 595                                 }
 596                                 if ($url_ ne $expect_url) {
 597                                         fatal "URL mismatch after rebase: ",
 598                                               "$url_ != $expect_url";
 599                                 }
 600                                 if ($uuid_ ne $uuid) {
 601                                         fatal "uuid mismatch after rebase: ",
 602                                               "$uuid_ != $uuid";
 603                                 }
 604                                 # remap parents
 605                                 my (%p, @l, $i);
 606                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 607                                         my $new = $linear_refs_->[$i] or next;
 608                                         $p{$new} =
 609                                                 $parents->{$linear_refs->[$i]};
 610                                         push @l, $new;
 611                                 }
 612                                 $parents = \%p;
 613                                 $linear_refs = \@l;
 614                         }
 615                 }
 616         }
 617
 618         if ($old_head) {
 619                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 620                 my $new_is_symbolic = eval {
 621                         command_oneline(qw/symbolic-ref -q HEAD/);
 622                 };
 623                 if ($new_is_symbolic) {
 624                         print "dcommitted the branch ", $head, "\n";
 625                 } else {
 626                         print "dcommitted on a detached HEAD because you gave ",
 627                               "a revision argument.\n",
 628                               "The rewritten commit is: ", $new_head, "\n";
 629                 }
 630                 command(['checkout', $old_head], STDERR => 0);
 631         }
 632
 633         unlink $gs->{index};
 634 }
 635
 636 sub cmd_branch {
 637         my ($branch_name, $head) = @_;
 638
 639         unless (defined $branch_name && length $branch_name) {
 640                 die(($_tag ? "tag" : "branch") . " name required\n");
 641         }
 642         $head ||= 'HEAD';
 643
 644         my ($src, $rev, undef, $gs) = working_head_info($head);
 645
 646         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 647         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 648         my $glob;
 649         if ($#{$allglobs} == 0) {
 650                 $glob = $allglobs->[0];
 651         } else {
 652                 unless(defined $_branch_dest) {
 653                         die "Multiple ",
 654                             $_tag ? "tag" : "branch",
 655                             " paths defined for Subversion repository.\n",
 656                             "You must specify where you want to create the ",
 657                             $_tag ? "tag" : "branch",
 658                             " with the --destination argument.\n";
 659                 }
 660                 foreach my $g (@{$allglobs}) {
 661                         # SVN::Git::Editor could probably be moved to Git.pm..
 662                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 663                         if ($_branch_dest =~ /$re/) {
 664                                 $glob = $g;
 665                                 last;
 666                         }
 667                 }
 668                 unless (defined $glob) {
 669                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 670                         foreach my $g (@{$allglobs}) {
 671                                 $g->{path}->{left} =~ /$dest_re/ or next;
 672                                 if (defined $glob) {
 673                                         die "Ambiguous destination: ",
 674                                             $_branch_dest, "\nmatches both '",
 675                                             $glob->{path}->{left}, "' and '",
 676                                             $g->{path}->{left}, "'\n";
 677                                 }
 678                                 $glob = $g;
 679                         }
 680                         unless (defined $glob) {
 681                                 die "Unknown ",
 682                                     $_tag ? "tag" : "branch",
 683                                     " destination $_branch_dest\n";
 684                         }
 685                 }
 686         }
 687         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 688         my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 689
 690         my $ctx = SVN::Client->new(
 691                 auth    => Git::SVN::Ra::_auth_providers(),
 692                 log_msg => sub {
 693                         ${ $_[0] } = defined $_message
 694                                 ? $_message
 695                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 696                                 . $branch_name;
 697                 },
 698         );
 699
 700         eval {
 701                 $ctx->ls($dst, 'HEAD', 0);
 702         } and die "branch ${branch_name} already exists\n";
 703
 704         print "Copying ${src} at r${rev} to ${dst}...\n";
 705         $ctx->copy($src, $rev, $dst)
 706                 unless $_dry_run;
 707
 708         $gs->fetch_all;
 709 }
 710
 711 sub cmd_find_rev {
 712         my $revision_or_hash = shift or die "SVN or git revision required ",
 713                                             "as a command-line argument\n";
 714         my $result;
 715         if ($revision_or_hash =~ /^r\d+$/) {
 716                 my $head = shift;
 717                 $head ||= 'HEAD';
 718                 my @refs;
 719                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 720                 unless ($gs) {
 721                         die "Unable to determine upstream SVN information from ",
 722                             "$head history\n";
 723                 }
 724                 my $desired_revision = substr($revision_or_hash, 1);
 725                 $result = $gs->rev_map_get($desired_revision, $uuid);
 726         } else {
 727                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 728                 $result = $rev;
 729         }
 730         print "$result\n" if $result;
 731 }
 732
 733 sub cmd_rebase {
 734         command_noisy(qw/update-index --refresh/);
 735         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 736         unless ($gs) {
 737                 die "Unable to determine upstream SVN information from ",
 738                     "working tree history\n";
 739         }
 740         if ($_dry_run) {
 741                 print "Remote Branch: " . $gs->refname . "\n";
 742                 print "SVN URL: " . $url . "\n";
 743                 return;
 744         }
 745         if (command(qw/diff-index HEAD --/)) {
 746                 print STDERR "Cannot rebase with uncommited changes:\n";
 747                 command_noisy('status');
 748                 exit 1;
 749         }
 750         unless ($_local) {
 751                 # rebase will checkout for us, so no need to do it explicitly
 752                 $_no_checkout = 'true';
 753                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 754         }
 755         command_noisy(rebase_cmd(), $gs->refname);
 756 }
 757
 758 sub cmd_show_ignore {
 759         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 760         $gs ||= Git::SVN->new;
 761         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 762         $gs->prop_walk($gs->{path}, $r, sub {
 763                 my ($gs, $path, $props) = @_;
 764                 print STDOUT "\n# $path\n";
 765                 my $s = $props->{'svn:ignore'} or return;
 766                 $s =~ s/[\r\n]+/\n/g;
 767                 chomp $s;
 768                 $s =~ s#^#$path#gm;
 769                 print STDOUT "$s\n";
 770         });
 771 }
 772
 773 sub cmd_show_externals {
 774         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 775         $gs ||= Git::SVN->new;
 776         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 777         $gs->prop_walk($gs->{path}, $r, sub {
 778                 my ($gs, $path, $props) = @_;
 779                 print STDOUT "\n# $path\n";
 780                 my $s = $props->{'svn:externals'} or return;
 781                 $s =~ s/[\r\n]+/\n/g;
 782                 chomp $s;
 783                 $s =~ s#^#$path#gm;
 784                 print STDOUT "$s\n";
 785         });
 786 }
 787
 788 sub cmd_create_ignore {
 789         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 790         $gs ||= Git::SVN->new;
 791         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 792         $gs->prop_walk($gs->{path}, $r, sub {
 793                 my ($gs, $path, $props) = @_;
 794                 # $path is of the form /path/to/dir/
 795                 $path = '.' . $path;
 796                 # SVN can have attributes on empty directories,
 797                 # which git won't track
 798                 mkpath([$path]) unless -d $path;
 799                 my $ignore = $path . '.gitignore';
 800                 my $s = $props->{'svn:ignore'} or return;
 801                 open(GITIGNORE, '>', $ignore)
 802                   or fatal("Failed to open `$ignore' for writing: $!");
 803                 $s =~ s/[\r\n]+/\n/g;
 804                 chomp $s;
 805                 # Prefix all patterns so that the ignore doesn't apply
 806                 # to sub-directories.
 807                 $s =~ s#^#/#gm;
 808                 print GITIGNORE "$s\n";
 809                 close(GITIGNORE)
 810                   or fatal("Failed to close `$ignore': $!");
 811                 command_noisy('add', '-f', $ignore);
 812         });
 813 }
 814
 815 sub canonicalize_path {
 816         my ($path) = @_;
 817         my $dot_slash_added = 0;
 818         if (substr($path, 0, 1) ne "/") {
 819                 $path = "./" . $path;
 820                 $dot_slash_added = 1;
 821         }
 822         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 823         # good reason), so let's do this manually.
 824         $path =~ s#/+#/#g;
 825         $path =~ s#/\.(?:/|$)#/#g;
 826         $path =~ s#/[^/]+/\.\.##g;
 827         $path =~ s#/$##g;
 828         $path =~ s#^\./## if $dot_slash_added;
 829         $path =~ s#^/##;
 830         $path =~ s#^\.$##;
 831         return $path;
 832 }
 833
 834 sub canonicalize_url {
 835         my ($url) = @_;
 836         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 837         return $url;
 838 }
 839
 840 # get_svnprops(PATH)
 841 # ------------------
 842 # Helper for cmd_propget and cmd_proplist below.
 843 sub get_svnprops {
 844         my $path = shift;
 845         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 846         $gs ||= Git::SVN->new;
 847
 848         # prefix THE PATH by the sub-directory from which the user
 849         # invoked us.
 850         $path = $cmd_dir_prefix . $path;
 851         fatal("No such file or directory: $path") unless -e $path;
 852         my $is_dir = -d $path ? 1 : 0;
 853         $path = $gs->{path} . '/' . $path;
 854
 855         # canonicalize the path (otherwise libsvn will abort or fail to
 856         # find the file)
 857         $path = canonicalize_path($path);
 858
 859         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 860         my $props;
 861         if ($is_dir) {
 862                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 863         }
 864         else {
 865                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 866         }
 867         return $props;
 868 }
 869
 870 # cmd_propget (PROP, PATH)
 871 # ------------------------
 872 # Print the SVN property PROP for PATH.
 873 sub cmd_propget {
 874         my ($prop, $path) = @_;
 875         $path = '.' if not defined $path;
 876         usage(1) if not defined $prop;
 877         my $props = get_svnprops($path);
 878         if (not defined $props->{$prop}) {
 879                 fatal("`$path' does not have a `$prop' SVN property.");
 880         }
 881         print $props->{$prop} . "\n";
 882 }
 883
 884 # cmd_proplist (PATH)
 885 # -------------------
 886 # Print the list of SVN properties for PATH.
 887 sub cmd_proplist {
 888         my $path = shift;
 889         $path = '.' if not defined $path;
 890         my $props = get_svnprops($path);
 891         print "Properties on '$path':\n";
 892         foreach (sort keys %{$props}) {
 893                 print "  $_\n";
 894         }
 895 }
 896
 897 sub cmd_multi_init {
 898         my $url = shift;
 899         unless (defined $_trunk || @_branches || @_tags) {
 900                 usage(1);
 901         }
 902
 903         $_prefix = '' unless defined $_prefix;
 904         if (defined $url) {
 905                 $url = canonicalize_url($url);
 906                 init_subdir(@_);
 907         }
 908         do_git_init_db();
 909         if (defined $_trunk) {
 910                 my $trunk_ref = $_prefix . 'trunk';
 911                 # try both old-style and new-style lookups:
 912                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 913                 unless ($gs_trunk) {
 914                         my ($trunk_url, $trunk_path) =
 915                                               complete_svn_url($url, $_trunk);
 916                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 917                                                    undef, $trunk_ref);
 918                 }
 919         }
 920         return unless @_branches || @_tags;
 921         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 922         foreach my $path (@_branches) {
 923                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 924         }
 925         foreach my $path (@_tags) {
 926                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 927         }
 928 }
 929
 930 sub cmd_multi_fetch {
 931         my $remotes = Git::SVN::read_all_remotes();
 932         foreach my $repo_id (sort keys %$remotes) {
 933                 if ($remotes->{$repo_id}->{url}) {
 934                         Git::SVN::fetch_all($repo_id, $remotes);
 935                 }
 936         }
 937 }
 938
 939 # this command is special because it requires no metadata
 940 sub cmd_commit_diff {
 941         my ($ta, $tb, $url) = @_;
 942         my $usage = "Usage: $0 commit-diff -r<revision> ".
 943                     "<tree-ish> <tree-ish> [<URL>]";
 944         fatal($usage) if (!defined $ta || !defined $tb);
 945         my $svn_path = '';
 946         if (!defined $url) {
 947                 my $gs = eval { Git::SVN->new };
 948                 if (!$gs) {
 949                         fatal("Needed URL or usable git-svn --id in ",
 950                               "the command-line\n", $usage);
 951                 }
 952                 $url = $gs->{url};
 953                 $svn_path = $gs->{path};
 954         }
 955         unless (defined $_revision) {
 956                 fatal("-r|--revision is a required argument\n", $usage);
 957         }
 958         if (defined $_message && defined $_file) {
 959                 fatal("Both --message/-m and --file/-F specified ",
 960                       "for the commit message.\n",
 961                       "I have no idea what you mean");
 962         }
 963         if (defined $_file) {
 964                 $_message = file_to_s($_file);
 965         } else {
 966                 $_message ||= get_commit_entry($tb)->{log};
 967         }
 968         my $ra ||= Git::SVN::Ra->new($url);
 969         my $r = $_revision;
 970         if ($r eq 'HEAD') {
 971                 $r = $ra->get_latest_revnum;
 972         } elsif ($r !~ /^\d+$/) {
 973                 die "revision argument: $r not understood by git-svn\n";
 974         }
 975         my %ed_opts = ( r => $r,
 976                         log => $_message,
 977                         ra => $ra,
 978                         tree_a => $ta,
 979                         tree_b => $tb,
 980                         editor_cb => sub { print "Committed r$_[0]\n" },
 981                         svn_path => $svn_path );
 982         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 983                 print "No changes\n$ta == $tb\n";
 984         }
 985 }
 986
 987 sub escape_uri_only {
 988         my ($uri) = @_;
 989         my @tmp;
 990         foreach (split m{/}, $uri) {
 991                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
 992                 push @tmp, $_;
 993         }
 994         join('/', @tmp);
 995 }
 996
 997 sub escape_url {
 998         my ($url) = @_;
 999         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1000                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1001                 $url = "$scheme://$domain$uri";
1002         }
1003         $url;
1004 }
1005
1006 sub cmd_info {
1007         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1008         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1009         if (exists $_[1]) {
1010                 die "Too many arguments specified\n";
1011         }
1012
1013         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1014
1015         if (!$file_type && !$diff_status) {
1016                 print STDERR "svn: '$path' is not under version control\n";
1017                 exit 1;
1018         }
1019
1020         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1021         unless ($gs) {
1022                 die "Unable to determine upstream SVN information from ",
1023                     "working tree history\n";
1024         }
1025
1026         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1027         $path = "." if $path eq "";
1028
1029         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1030
1031         if ($_url) {
1032                 print escape_url($full_url), "\n";
1033                 return;
1034         }
1035
1036         my $result = "Path: $path\n";
1037         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1038         $result .= "URL: " . escape_url($full_url) . "\n";
1039
1040         eval {
1041                 my $repos_root = $gs->repos_root;
1042                 Git::SVN::remove_username($repos_root);
1043                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1044         };
1045         if ($@) {
1046                 $result .= "Repository Root: (offline)\n";
1047         }
1048         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1049                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1050         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1051
1052         $result .= "Node Kind: " .
1053                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1054
1055         my $schedule = $diff_status eq "A"
1056                        ? "add"
1057                        : ($diff_status eq "D" ? "delete" : "normal");
1058         $result .= "Schedule: $schedule\n";
1059
1060         if ($diff_status eq "A") {
1061                 print $result, "\n";
1062                 return;
1063         }
1064
1065         my ($lc_author, $lc_rev, $lc_date_utc);
1066         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1067         my $log = command_output_pipe(@args);
1068         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1069         while (<$log>) {
1070                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1071                         $lc_author = $1;
1072                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1073                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1074                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1075                 }
1076         }
1077         close $log;
1078
1079         Git::SVN::Log::set_local_timezone();
1080
1081         $result .= "Last Changed Author: $lc_author\n";
1082         $result .= "Last Changed Rev: $lc_rev\n";
1083         $result .= "Last Changed Date: " .
1084                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1085
1086         if ($file_type ne "dir") {
1087                 my $text_last_updated_date =
1088                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1089                 $result .=
1090                     "Text Last Updated: " .
1091                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1092                     "\n";
1093                 my $checksum;
1094                 if ($diff_status eq "D") {
1095                         my ($fh, $ctx) =
1096                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1097                         if ($file_type eq "link") {
1098                                 my $file_name = <$fh>;
1099                                 $checksum = md5sum("link $file_name");
1100                         } else {
1101                                 $checksum = md5sum($fh);
1102                         }
1103                         command_close_pipe($fh, $ctx);
1104                 } elsif ($file_type eq "link") {
1105                         my $file_name =
1106                             command(qw(cat-file blob), "HEAD:$path");
1107                         $checksum =
1108                             md5sum("link " . $file_name);
1109                 } else {
1110                         open FILE, "<", $path or die $!;
1111                         $checksum = md5sum(\*FILE);
1112                         close FILE or die $!;
1113                 }
1114                 $result .= "Checksum: " . $checksum . "\n";
1115         }
1116
1117         print $result, "\n";
1118 }
1119
1120 sub cmd_reset {
1121         my $target = shift || $_revision or die "SVN revision required\n";
1122         $target = $1 if $target =~ /^r(\d+)$/;
1123         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1124         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1125         unless ($gs) {
1126                 die "Unable to determine upstream SVN information from ".
1127                     "history\n";
1128         }
1129         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1130         $gs->rev_map_set($r, $c, 'reset', $uuid);
1131         print "r$r = $c ($gs->{ref_id})\n";
1132 }
1133
1134 sub cmd_gc {
1135         if (!$can_compress) {
1136                 warn "Compress::Zlib could not be found; unhandled.log " .
1137                      "files will not be compressed.\n";
1138         }
1139         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1140 }
1141
1142 ########################### utility functions #########################
1143
1144 sub rebase_cmd {
1145         my @cmd = qw/rebase/;
1146         push @cmd, '-v' if $_verbose;
1147         push @cmd, qw/--merge/ if $_merge;
1148         push @cmd, "--strategy=$_strategy" if $_strategy;
1149         @cmd;
1150 }
1151
1152 sub post_fetch_checkout {
1153         return if $_no_checkout;
1154         my $gs = $Git::SVN::_head or return;
1155         return if verify_ref('refs/heads/master^0');
1156
1157         my $valid_head = verify_ref('HEAD^0');
1158         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1159         return if ($valid_head || !verify_ref('HEAD^0'));
1160
1161         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1162         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1163         return if -f $index;
1164
1165         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1166         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1167         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1168         print STDERR "Checked out HEAD:\n  ",
1169                      $gs->full_url, " r", $gs->last_rev, "\n";
1170 }
1171
1172 sub complete_svn_url {
1173         my ($url, $path) = @_;
1174         $path =~ s#/+$##;
1175         if ($path !~ m#^[a-z\+]+://#) {
1176                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1177                         fatal("E: '$path' is not a complete URL ",
1178                               "and a separate URL is not specified");
1179                 }
1180                 return ($url, $path);
1181         }
1182         return ($path, '');
1183 }
1184
1185 sub complete_url_ls_init {
1186         my ($ra, $repo_path, $switch, $pfx) = @_;
1187         unless ($repo_path) {
1188                 print STDERR "W: $switch not specified\n";
1189                 return;
1190         }
1191         $repo_path =~ s#/+$##;
1192         if ($repo_path =~ m#^[a-z\+]+://#) {
1193                 $ra = Git::SVN::Ra->new($repo_path);
1194                 $repo_path = '';
1195         } else {
1196                 $repo_path =~ s#^/+##;
1197                 unless ($ra) {
1198                         fatal("E: '$repo_path' is not a complete URL ",
1199                               "and a separate URL is not specified");
1200                 }
1201         }
1202         my $url = $ra->{url};
1203         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1204         my $k = "svn-remote.$gs->{repo_id}.url";
1205         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1206         if ($orig_url && ($orig_url ne $gs->{url})) {
1207                 die "$k already set: $orig_url\n",
1208                     "wanted to set to: $gs->{url}\n";
1209         }
1210         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1211         my $remote_path = "$gs->{path}/$repo_path";
1212         $remote_path =~ s#/+#/#g;
1213         $remote_path =~ s#^/##g;
1214         $remote_path .= "/*" if $remote_path !~ /\*/;
1215         my ($n) = ($switch =~ /^--(\w+)/);
1216         if (length $pfx && $pfx !~ m#/$#) {
1217                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1218         }
1219         command_noisy('config',
1220                       '--add',
1221                       "svn-remote.$gs->{repo_id}.$n",
1222                       "$remote_path:refs/remotes/$pfx*" .
1223                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1224 }
1225
1226 sub verify_ref {
1227         my ($ref) = @_;
1228         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1229                                { STDERR => 0 }); };
1230 }
1231
1232 sub get_tree_from_treeish {
1233         my ($treeish) = @_;
1234         # $treeish can be a symbolic ref, too:
1235         my $type = command_oneline(qw/cat-file -t/, $treeish);
1236         my $expected;
1237         while ($type eq 'tag') {
1238                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1239         }
1240         if ($type eq 'commit') {
1241                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1242                                                     $treeish))[0];
1243                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1244                 die "Unable to get tree from $treeish\n" unless $expected;
1245         } elsif ($type eq 'tree') {
1246                 $expected = $treeish;
1247         } else {
1248                 die "$treeish is a $type, expected tree, tag or commit\n";
1249         }
1250         return $expected;
1251 }
1252
1253 sub get_commit_entry {
1254         my ($treeish) = shift;
1255         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1256         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1257         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1258         open my $log_fh, '>', $commit_editmsg or croak $!;
1259
1260         my $type = command_oneline(qw/cat-file -t/, $treeish);
1261         if ($type eq 'commit' || $type eq 'tag') {
1262                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1263                                                          $type, $treeish);
1264                 my $in_msg = 0;
1265                 my $author;
1266                 my $saw_from = 0;
1267                 my $msgbuf = "";
1268                 while (<$msg_fh>) {
1269                         if (!$in_msg) {
1270                                 $in_msg = 1 if (/^\s*$/);
1271                                 $author = $1 if (/^author (.*>)/);
1272                         } elsif (/^git-svn-id: /) {
1273                                 # skip this for now, we regenerate the
1274                                 # correct one on re-fetch anyways
1275                                 # TODO: set *:merge properties or like...
1276                         } else {
1277                                 if (/^From:/ || /^Signed-off-by:/) {
1278                                         $saw_from = 1;
1279                                 }
1280                                 $msgbuf .= $_;
1281                         }
1282                 }
1283                 $msgbuf =~ s/\s+$//s;
1284                 if ($Git::SVN::_add_author_from && defined($author)
1285                     && !$saw_from) {
1286                         $msgbuf .= "\n\nFrom: $author";
1287                 }
1288                 print $log_fh $msgbuf or croak $!;
1289                 command_close_pipe($msg_fh, $ctx);
1290         }
1291         close $log_fh or croak $!;
1292
1293         if ($_edit || ($type eq 'tree')) {
1294                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1295                 # TODO: strip out spaces, comments, like git-commit.sh
1296                 system($editor, $commit_editmsg);
1297         }
1298         rename $commit_editmsg, $commit_msg or croak $!;
1299         {
1300                 require Encode;
1301                 # SVN requires messages to be UTF-8 when entering the repo
1302                 local $/;
1303                 open $log_fh, '<', $commit_msg or croak $!;
1304                 binmode $log_fh;
1305                 chomp($log_entry{log} = <$log_fh>);
1306
1307                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1308                 my $msg = $log_entry{log};
1309
1310                 eval { $msg = Encode::decode($enc, $msg, 1) };
1311                 if ($@) {
1312                         die "Could not decode as $enc:\n", $msg,
1313                             "\nPerhaps you need to set i18n.commitencoding\n";
1314                 }
1315
1316                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1317                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1318
1319                 $log_entry{log} = $msg;
1320
1321                 close $log_fh or croak $!;
1322         }
1323         unlink $commit_msg;
1324         \%log_entry;
1325 }
1326
1327 sub s_to_file {
1328         my ($str, $file, $mode) = @_;
1329         open my $fd,'>',$file or croak $!;
1330         print $fd $str,"\n" or croak $!;
1331         close $fd or croak $!;
1332         chmod ($mode &~ umask, $file) if (defined $mode);
1333 }
1334
1335 sub file_to_s {
1336         my $file = shift;
1337         open my $fd,'<',$file or croak "$!: file: $file\n";
1338         local $/;
1339         my $ret = <$fd>;
1340         close $fd or croak $!;
1341         $ret =~ s/\s*$//s;
1342         return $ret;
1343 }
1344
1345 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1346 sub load_authors {
1347         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1348         my $log = $cmd eq 'log';
1349         while (<$authors>) {
1350                 chomp;
1351                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1352                 my ($user, $name, $email) = ($1, $2, $3);
1353                 if ($log) {
1354                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1355                 } else {
1356                         $users{$user} = [$name, $email];
1357                 }
1358         }
1359         close $authors or croak $!;
1360 }
1361
1362 # convert GetOpt::Long specs for use by git-config
1363 sub read_repo_config {
1364         return unless -d $ENV{GIT_DIR};
1365         my $opts = shift;
1366         my @config_only;
1367         foreach my $o (keys %$opts) {
1368                 # if we have mixedCase and a long option-only, then
1369                 # it's a config-only variable that we don't need for
1370                 # the command-line.
1371                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1372                 my $v = $opts->{$o};
1373                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1374                 $key =~ s/-//g;
1375                 my $arg = 'git config';
1376                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1377                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1378                 if (ref $v eq 'ARRAY') {
1379                         chomp(my @tmp = `$arg --get-all svn.$key`);
1380                         @$v = @tmp if @tmp;
1381                 } else {
1382                         chomp(my $tmp = `$arg --get svn.$key`);
1383                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1384                                 $$v = $tmp;
1385                         }
1386                 }
1387         }
1388         delete @$opts{@config_only} if @config_only;
1389 }
1390
1391 sub extract_metadata {
1392         my $id = shift or return (undef, undef, undef);
1393         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1394                                                         \s([a-f\d\-]+)$/ix);
1395         if (!defined $rev || !$uuid || !$url) {
1396                 # some of the original repositories I made had
1397                 # identifiers like this:
1398                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1399         }
1400         return ($url, $rev, $uuid);
1401 }
1402
1403 sub cmt_metadata {
1404         return extract_metadata((grep(/^git-svn-id: /,
1405                 command(qw/cat-file commit/, shift)))[-1]);
1406 }
1407
1408 sub cmt_sha2rev_batch {
1409         my %s2r;
1410         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1411         my $list = shift;
1412
1413         foreach my $sha (@{$list}) {
1414                 my $first = 1;
1415                 my $size = 0;
1416                 print $out $sha, "\n";
1417
1418                 while (my $line = <$in>) {
1419                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1420                                 last;
1421                         } elsif ($first &&
1422                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1423                                 $first = 0;
1424                                 $size = $1;
1425                                 next;
1426                         } elsif ($line =~ /^(git-svn-id: )/) {
1427                                 my (undef, $rev, undef) =
1428                                                       extract_metadata($line);
1429                                 $s2r{$sha} = $rev;
1430                         }
1431
1432                         $size -= length($line);
1433                         last if ($size == 0);
1434                 }
1435         }
1436
1437         command_close_bidi_pipe($pid, $in, $out, $ctx);
1438
1439         return \%s2r;
1440 }
1441
1442 sub working_head_info {
1443         my ($head, $refs) = @_;
1444         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1445         my ($fh, $ctx) = command_output_pipe(@args, $head);
1446         my $hash;
1447         my %max;
1448         while (<$fh>) {
1449                 if ( m{^commit ($::sha1)$} ) {
1450                         unshift @$refs, $hash if $hash and $refs;
1451                         $hash = $1;
1452                         next;
1453                 }
1454                 next unless s{^\s*(git-svn-id:)}{$1};
1455                 my ($url, $rev, $uuid) = extract_metadata($_);
1456                 if (defined $url && defined $rev) {
1457                         next if $max{$url} and $max{$url} < $rev;
1458                         if (my $gs = Git::SVN->find_by_url($url)) {
1459                                 my $c = $gs->rev_map_get($rev, $uuid);
1460                                 if ($c && $c eq $hash) {
1461                                         close $fh; # break the pipe
1462                                         return ($url, $rev, $uuid, $gs);
1463                                 } else {
1464                                         $max{$url} ||= $gs->rev_map_max;
1465                                 }
1466                         }
1467                 }
1468         }
1469         command_close_pipe($fh, $ctx);
1470         (undef, undef, undef, undef);
1471 }
1472
1473 sub read_commit_parents {
1474         my ($parents, $c) = @_;
1475         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1476         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1477         @{$parents->{$c}} = split(/ /, $p);
1478 }
1479
1480 sub linearize_history {
1481         my ($gs, $refs) = @_;
1482         my %parents;
1483         foreach my $c (@$refs) {
1484                 read_commit_parents(\%parents, $c);
1485         }
1486
1487         my @linear_refs;
1488         my %skip = ();
1489         my $last_svn_commit = $gs->last_commit;
1490         foreach my $c (reverse @$refs) {
1491                 next if $c eq $last_svn_commit;
1492                 last if $skip{$c};
1493
1494                 unshift @linear_refs, $c;
1495                 $skip{$c} = 1;
1496
1497                 # we only want the first parent to diff against for linear
1498                 # history, we save the rest to inject when we finalize the
1499                 # svn commit
1500                 my $fp_a = verify_ref("$c~1");
1501                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1502                 if (!$fp_a || !$fp_b) {
1503                         die "Commit $c\n",
1504                             "has no parent commit, and therefore ",
1505                             "nothing to diff against.\n",
1506                             "You should be working from a repository ",
1507                             "originally created by git-svn\n";
1508                 }
1509                 if ($fp_a ne $fp_b) {
1510                         die "$c~1 = $fp_a, however parsing commit $c ",
1511                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1512                 }
1513
1514                 foreach my $p (@{$parents{$c}}) {
1515                         $skip{$p} = 1;
1516                 }
1517         }
1518         (\@linear_refs, \%parents);
1519 }
1520
1521 sub find_file_type_and_diff_status {
1522         my ($path) = @_;
1523         return ('dir', '') if $path eq '';
1524
1525         my $diff_output =
1526             command_oneline(qw(diff --cached --name-status --), $path) || "";
1527         my $diff_status = (split(' ', $diff_output))[0] || "";
1528
1529         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1530
1531         return (undef, undef) if !$diff_status && !$ls_tree;
1532
1533         if ($diff_status eq "A") {
1534                 return ("link", $diff_status) if -l $path;
1535                 return ("dir", $diff_status) if -d $path;
1536                 return ("file", $diff_status);
1537         }
1538
1539         my $mode = (split(' ', $ls_tree))[0] || "";
1540
1541         return ("link", $diff_status) if $mode eq "120000";
1542         return ("dir", $diff_status) if $mode eq "040000";
1543         return ("file", $diff_status);
1544 }
1545
1546 sub md5sum {
1547         my $arg = shift;
1548         my $ref = ref $arg;
1549         my $md5 = Digest::MD5->new();
1550         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1551                 $md5->addfile($arg) or croak $!;
1552         } elsif ($ref eq 'SCALAR') {
1553                 $md5->add($$arg) or croak $!;
1554         } elsif (!$ref) {
1555                 $md5->add($arg) or croak $!;
1556         } else {
1557                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1558         }
1559         return $md5->hexdigest();
1560 }
1561
1562 sub gc_directory {
1563         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1564                 my $out_filename = $_ . ".gz";
1565                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1566                 binmode $in_fh;
1567                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1568                                 die "Unable to open $out_filename: $!\n";
1569
1570                 my $res;
1571                 while ($res = sysread($in_fh, my $str, 1024)) {
1572                         $gz->gzwrite($str) or
1573                                 die "Unable to write: ".$gz->gzerror()."!\n";
1574                 }
1575                 unlink $_ or die "unlink $File::Find::name: $!\n";
1576         } elsif (-f $_ && basename($_) eq "index") {
1577                 unlink $_ or die "unlink $_: $!\n";
1578         }
1579 }
1580
1581 package Git::SVN;
1582 use strict;
1583 use warnings;
1584 use Fcntl qw/:DEFAULT :seek/;
1585 use constant rev_map_fmt => 'NH40';
1586 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1587             $_repack $_repack_flags $_use_svm_props $_head
1588             $_use_svnsync_props $no_reuse_existing $_minimize_url
1589             $_use_log_author $_add_author_from $_localtime/;
1590 use Carp qw/croak/;
1591 use File::Path qw/mkpath/;
1592 use File::Copy qw/copy/;
1593 use IPC::Open3;
1594
1595 my ($_gc_nr, $_gc_period);
1596
1597 # properties that we do not log:
1598 my %SKIP_PROP;
1599 BEGIN {
1600         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1601                                         svn:special svn:executable
1602                                         svn:entry:committed-rev
1603                                         svn:entry:last-author
1604                                         svn:entry:uuid
1605                                         svn:entry:committed-date/;
1606
1607         # some options are read globally, but can be overridden locally
1608         # per [svn-remote "..."] section.  Command-line options will *NOT*
1609         # override options set in an [svn-remote "..."] section
1610         no strict 'refs';
1611         for my $option (qw/follow_parent no_metadata use_svm_props
1612                            use_svnsync_props/) {
1613                 my $key = $option;
1614                 $key =~ tr/_//d;
1615                 my $prop = "-$option";
1616                 *$option = sub {
1617                         my ($self) = @_;
1618                         return $self->{$prop} if exists $self->{$prop};
1619                         my $k = "svn-remote.$self->{repo_id}.$key";
1620                         eval { command_oneline(qw/config --get/, $k) };
1621                         if ($@) {
1622                                 $self->{$prop} = ${"Git::SVN::_$option"};
1623                         } else {
1624                                 my $v = command_oneline(qw/config --bool/,$k);
1625                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1626                         }
1627                         return $self->{$prop};
1628                 }
1629         }
1630 }
1631
1632
1633 my (%LOCKFILES, %INDEX_FILES);
1634 END {
1635         unlink keys %LOCKFILES if %LOCKFILES;
1636         unlink keys %INDEX_FILES if %INDEX_FILES;
1637 }
1638
1639 sub resolve_local_globs {
1640         my ($url, $fetch, $glob_spec) = @_;
1641         return unless defined $glob_spec;
1642         my $ref = $glob_spec->{ref};
1643         my $path = $glob_spec->{path};
1644         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1645                 next unless m#^refs/remotes/$ref->{regex}$#;
1646                 my $p = $1;
1647                 my $pathname = desanitize_refname($path->full_path($p));
1648                 my $refname = desanitize_refname($ref->full_path($p));
1649                 if (my $existing = $fetch->{$pathname}) {
1650                         if ($existing ne $refname) {
1651                                 die "Refspec conflict:\n",
1652                                     "existing: refs/remotes/$existing\n",
1653                                     " globbed: refs/remotes/$refname\n";
1654                         }
1655                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1656                         $u =~ s!^\Q$url\E(/|$)!! or die
1657                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1658                         if ($pathname ne $u) {
1659                                 warn "W: Refspec glob conflict ",
1660                                      "(ref: refs/remotes/$refname):\n",
1661                                      "expected path: $pathname\n",
1662                                      "    real path: $u\n",
1663                                      "Continuing ahead with $u\n";
1664                                 next;
1665                         }
1666                 } else {
1667                         $fetch->{$pathname} = $refname;
1668                 }
1669         }
1670 }
1671
1672 sub parse_revision_argument {
1673         my ($base, $head) = @_;
1674         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1675                 return ($base, $head);
1676         }
1677         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1678         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1679         return ($head, $head) if ($::_revision eq 'HEAD');
1680         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1681         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1682         die "revision argument: $::_revision not understood by git-svn\n";
1683 }
1684
1685 sub fetch_all {
1686         my ($repo_id, $remotes) = @_;
1687         if (ref $repo_id) {
1688                 my $gs = $repo_id;
1689                 $repo_id = undef;
1690                 $repo_id = $gs->{repo_id};
1691         }
1692         $remotes ||= read_all_remotes();
1693         my $remote = $remotes->{$repo_id} or
1694                      die "[svn-remote \"$repo_id\"] unknown\n";
1695         my $fetch = $remote->{fetch};
1696         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1697         my (@gs, @globs);
1698         my $ra = Git::SVN::Ra->new($url);
1699         my $uuid = $ra->get_uuid;
1700         my $head = $ra->get_latest_revnum;
1701         $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1702         my $base = defined $fetch ? $head : 0;
1703
1704         # read the max revs for wildcard expansion (branches/*, tags/*)
1705         foreach my $t (qw/branches tags/) {
1706                 defined $remote->{$t} or next;
1707                 push @globs, @{$remote->{$t}};
1708
1709                 my $max_rev = eval { tmp_config(qw/--int --get/,
1710                                          "svn-remote.$repo_id.${t}-maxRev") };
1711                 if (defined $max_rev && ($max_rev < $base)) {
1712                         $base = $max_rev;
1713                 } elsif (!defined $max_rev) {
1714                         $base = 0;
1715                 }
1716         }
1717
1718         if ($fetch) {
1719                 foreach my $p (sort keys %$fetch) {
1720                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1721                         my $lr = $gs->rev_map_max;
1722                         if (defined $lr) {
1723                                 $base = $lr if ($lr < $base);
1724                         }
1725                         push @gs, $gs;
1726                 }
1727         }
1728
1729         ($base, $head) = parse_revision_argument($base, $head);
1730         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1731 }
1732
1733 sub read_all_remotes {
1734         my $r = {};
1735         my $use_svm_props = eval { command_oneline(qw/config --bool
1736             svn.useSvmProps/) };
1737         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1738         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1739                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1740                         my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1741                         die("svn-remote.$remote: remote ref '$_remote_ref' "
1742                             . "must start with 'refs/remotes/'\n")
1743                                 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1744                         my $remote_ref = $1;
1745                         $local_ref =~ s{^/}{};
1746                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1747                         $r->{$remote}->{svm} = {} if $use_svm_props;
1748                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1749                         $r->{$1}->{svm} = {};
1750                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1751                         $r->{$1}->{url} = $2;
1752                 } elsif (m!^(.+)\.(branches|tags)=
1753                            (.*):refs/remotes/(.+)\s*$/!x) {
1754                         my ($p, $g) = ($3, $4);
1755                         my $rs = {
1756                             t => $2,
1757                             remote => $1,
1758                             path => Git::SVN::GlobSpec->new($p),
1759                             ref => Git::SVN::GlobSpec->new($g) };
1760                         if (length($rs->{ref}->{right}) != 0) {
1761                                 die "The '*' glob character must be the last ",
1762                                     "character of '$g'\n";
1763                         }
1764                         push @{ $r->{$1}->{$2} }, $rs;
1765                 }
1766         }
1767
1768         map {
1769                 if (defined $r->{$_}->{svm}) {
1770                         my $svm;
1771                         eval {
1772                                 my $section = "svn-remote.$_";
1773                                 $svm = {
1774                                         source => tmp_config('--get',
1775                                             "$section.svm-source"),
1776                                         replace => tmp_config('--get',
1777                                             "$section.svm-replace"),
1778                                 }
1779                         };
1780                         $r->{$_}->{svm} = $svm;
1781                 }
1782         } keys %$r;
1783
1784         $r;
1785 }
1786
1787 sub init_vars {
1788         $_gc_nr = $_gc_period = 1000;
1789         if (defined $_repack || defined $_repack_flags) {
1790                warn "Repack options are obsolete; they have no effect.\n";
1791         }
1792 }
1793
1794 sub verify_remotes_sanity {
1795         return unless -d $ENV{GIT_DIR};
1796         my %seen;
1797         foreach (command(qw/config -l/)) {
1798                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1799                         if ($seen{$1}) {
1800                                 die "Remote ref refs/remote/$1 is tracked by",
1801                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1802                                     "Please resolve this ambiguity in ",
1803                                     "your git configuration file before ",
1804                                     "continuing\n";
1805                         }
1806                         $seen{$1} = $_;
1807                 }
1808         }
1809 }
1810
1811 sub find_existing_remote {
1812         my ($url, $remotes) = @_;
1813         return undef if $no_reuse_existing;
1814         my $existing;
1815         foreach my $repo_id (keys %$remotes) {
1816                 my $u = $remotes->{$repo_id}->{url} or next;
1817                 next if $u ne $url;
1818                 $existing = $repo_id;
1819                 last;
1820         }
1821         $existing;
1822 }
1823
1824 sub init_remote_config {
1825         my ($self, $url, $no_write) = @_;
1826         $url =~ s!/+$!!; # strip trailing slash
1827         my $r = read_all_remotes();
1828         my $existing = find_existing_remote($url, $r);
1829         if ($existing) {
1830                 unless ($no_write) {
1831                         print STDERR "Using existing ",
1832                                      "[svn-remote \"$existing\"]\n";
1833                 }
1834                 $self->{repo_id} = $existing;
1835         } elsif ($_minimize_url) {
1836                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1837                 $existing = find_existing_remote($min_url, $r);
1838                 if ($existing) {
1839                         unless ($no_write) {
1840                                 print STDERR "Using existing ",
1841                                              "[svn-remote \"$existing\"]\n";
1842                         }
1843                         $self->{repo_id} = $existing;
1844                 }
1845                 if ($min_url ne $url) {
1846                         unless ($no_write) {
1847                                 print STDERR "Using higher level of URL: ",
1848                                              "$url => $min_url\n";
1849                         }
1850                         my $old_path = $self->{path};
1851                         $self->{path} = $url;
1852                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1853                         if (length $old_path) {
1854                                 $self->{path} .= "/$old_path";
1855                         }
1856                         $url = $min_url;
1857                 }
1858         }
1859         my $orig_url;
1860         if (!$existing) {
1861                 # verify that we aren't overwriting anything:
1862                 $orig_url = eval {
1863                         command_oneline('config', '--get',
1864                                         "svn-remote.$self->{repo_id}.url")
1865                 };
1866                 if ($orig_url && ($orig_url ne $url)) {
1867                         die "svn-remote.$self->{repo_id}.url already set: ",
1868                             "$orig_url\nwanted to set to: $url\n";
1869                 }
1870         }
1871         my ($xrepo_id, $xpath) = find_ref($self->refname);
1872         if (defined $xpath) {
1873                 die "svn-remote.$xrepo_id.fetch already set to track ",
1874                     "$xpath:refs/remotes/", $self->refname, "\n";
1875         }
1876         unless ($no_write) {
1877                 command_noisy('config',
1878                               "svn-remote.$self->{repo_id}.url", $url);
1879                 $self->{path} =~ s{^/}{};
1880                 command_noisy('config', '--add',
1881                               "svn-remote.$self->{repo_id}.fetch",
1882                               "$self->{path}:".$self->refname);
1883         }
1884         $self->{url} = $url;
1885 }
1886
1887 sub find_by_url { # repos_root and, path are optional
1888         my ($class, $full_url, $repos_root, $path) = @_;
1889
1890         return undef unless defined $full_url;
1891         remove_username($full_url);
1892         remove_username($repos_root) if defined $repos_root;
1893         my $remotes = read_all_remotes();
1894         if (defined $full_url && defined $repos_root && !defined $path) {
1895                 $path = $full_url;
1896                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1897         }
1898         foreach my $repo_id (keys %$remotes) {
1899                 my $u = $remotes->{$repo_id}->{url} or next;
1900                 remove_username($u);
1901                 next if defined $repos_root && $repos_root ne $u;
1902
1903                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1904                 foreach my $t (qw/branches tags/) {
1905                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1906                                 resolve_local_globs($u, $fetch, $globspec);
1907                         }
1908                 }
1909                 my $p = $path;
1910                 my $rwr = rewrite_root({repo_id => $repo_id});
1911                 my $svm = $remotes->{$repo_id}->{svm}
1912                         if defined $remotes->{$repo_id}->{svm};
1913                 unless (defined $p) {
1914                         $p = $full_url;
1915                         my $z = $u;
1916                         my $prefix = '';
1917                         if ($rwr) {
1918                                 $z = $rwr;
1919                                 remove_username($z);
1920                         } elsif (defined $svm) {
1921                                 $z = $svm->{source};
1922                                 $prefix = $svm->{replace};
1923                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
1924                                 $prefix =~ s#/$##;
1925                         }
1926                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1927                 }
1928                 foreach my $f (keys %$fetch) {
1929                         next if $f ne $p;
1930                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1931                 }
1932         }
1933         undef;
1934 }
1935
1936 sub init {
1937         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1938         my $self = _new($class, $repo_id, $ref_id, $path);
1939         if (defined $url) {
1940                 $self->init_remote_config($url, $no_write);
1941         }
1942         $self;
1943 }
1944
1945 sub find_ref {
1946         my ($ref_id) = @_;
1947         foreach (command(qw/config -l/)) {
1948                 next unless m!^svn-remote\.(.+)\.fetch=
1949                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1950                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1951                 if ($ref eq $ref_id) {
1952                         $path = '' if ($path =~ m#^\./?#);
1953                         return ($repo_id, $path);
1954                 }
1955         }
1956         (undef, undef, undef);
1957 }
1958
1959 sub new {
1960         my ($class, $ref_id, $repo_id, $path) = @_;
1961         if (defined $ref_id && !defined $repo_id && !defined $path) {
1962                 ($repo_id, $path) = find_ref($ref_id);
1963                 if (!defined $repo_id) {
1964                         die "Could not find a \"svn-remote.*.fetch\" key ",
1965                             "in the repository configuration matching: ",
1966                             "refs/remotes/$ref_id\n";
1967                 }
1968         }
1969         my $self = _new($class, $repo_id, $ref_id, $path);
1970         if (!defined $self->{path} || !length $self->{path}) {
1971                 my $fetch = command_oneline('config', '--get',
1972                                             "svn-remote.$repo_id.fetch",
1973                                             ":refs/remotes/$ref_id\$") or
1974                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1975                          "\":refs/remotes/$ref_id\$\" in config\n";
1976                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1977         }
1978         $self->{url} = command_oneline('config', '--get',
1979                                        "svn-remote.$repo_id.url") or
1980                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1981         $self->rebuild;
1982         $self;
1983 }
1984
1985 sub refname {
1986         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1987
1988         # It cannot end with a slash /, we'll throw up on this because
1989         # SVN can't have directories with a slash in their name, either:
1990         if ($refname =~ m{/$}) {
1991                 die "ref: '$refname' ends with a trailing slash, this is ",
1992                     "not permitted by git nor Subversion\n";
1993         }
1994
1995         # It cannot have ASCII control character space, tilde ~, caret ^,
1996         # colon :, question-mark ?, asterisk *, space, or open bracket [
1997         # anywhere.
1998         #
1999         # Additionally, % must be escaped because it is used for escaping
2000         # and we want our escaped refname to be reversible
2001         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2002
2003         # no slash-separated component can begin with a dot .
2004         # /.* becomes /%2E*
2005         $refname =~ s{/\.}{/%2E}g;
2006
2007         # It cannot have two consecutive dots .. anywhere
2008         # .. becomes %2E%2E
2009         $refname =~ s{\.\.}{%2E%2E}g;
2010
2011         return $refname;
2012 }
2013
2014 sub desanitize_refname {
2015         my ($refname) = @_;
2016         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2017         return $refname;
2018 }
2019
2020 sub svm_uuid {
2021         my ($self) = @_;
2022         return $self->{svm}->{uuid} if $self->svm;
2023         $self->ra;
2024         unless ($self->{svm}) {
2025                 die "SVM UUID not cached, and reading remotely failed\n";
2026         }
2027         $self->{svm}->{uuid};
2028 }
2029
2030 sub svm {
2031         my ($self) = @_;
2032         return $self->{svm} if $self->{svm};
2033         my $svm;
2034         # see if we have it in our config, first:
2035         eval {
2036                 my $section = "svn-remote.$self->{repo_id}";
2037                 $svm = {
2038                   source => tmp_config('--get', "$section.svm-source"),
2039                   uuid => tmp_config('--get', "$section.svm-uuid"),
2040                   replace => tmp_config('--get', "$section.svm-replace"),
2041                 }
2042         };
2043         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2044                 $self->{svm} = $svm;
2045         }
2046         $self->{svm};
2047 }
2048
2049 sub _set_svm_vars {
2050         my ($self, $ra) = @_;
2051         return $ra if $self->svm;
2052
2053         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2054                     "(svm:source, svm:uuid) ",
2055                     "from the following URLs:\n" );
2056         sub read_svm_props {
2057                 my ($self, $ra, $path, $r) = @_;
2058                 my $props = ($ra->get_dir($path, $r))[2];
2059                 my $src = $props->{'svm:source'};
2060                 my $uuid = $props->{'svm:uuid'};
2061                 return undef if (!$src || !$uuid);
2062
2063                 chomp($src, $uuid);
2064
2065                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2066                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2067
2068                 # the '!' is used to mark the repos_root!/relative/path
2069                 $src =~ s{/?!/?}{/};
2070                 $src =~ s{/+$}{}; # no trailing slashes please
2071                 # username is of no interest
2072                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2073
2074                 my $replace = $ra->{url};
2075                 $replace .= "/$path" if length $path;
2076
2077                 my $section = "svn-remote.$self->{repo_id}";
2078                 tmp_config("$section.svm-source", $src);
2079                 tmp_config("$section.svm-replace", $replace);
2080                 tmp_config("$section.svm-uuid", $uuid);
2081                 $self->{svm} = {
2082                         source => $src,
2083                         uuid => $uuid,
2084                         replace => $replace
2085                 };
2086         }
2087
2088         my $r = $ra->get_latest_revnum;
2089         my $path = $self->{path};
2090         my %tried;
2091         while (length $path) {
2092                 unless ($tried{"$self->{url}/$path"}) {
2093                         return $ra if $self->read_svm_props($ra, $path, $r);
2094                         $tried{"$self->{url}/$path"} = 1;
2095                 }
2096                 $path =~ s#/?[^/]+$##;
2097         }
2098         die "Path: '$path' should be ''\n" if $path ne '';
2099         return $ra if $self->read_svm_props($ra, $path, $r);
2100         $tried{"$self->{url}/$path"} = 1;
2101
2102         if ($ra->{repos_root} eq $self->{url}) {
2103                 die @err, (map { "  $_\n" } keys %tried), "\n";
2104         }
2105
2106         # nope, make sure we're connected to the repository root:
2107         my $ok;
2108         my @tried_b;
2109         $path = $ra->{svn_path};
2110         $ra = Git::SVN::Ra->new($ra->{repos_root});
2111         while (length $path) {
2112                 unless ($tried{"$ra->{url}/$path"}) {
2113                         $ok = $self->read_svm_props($ra, $path, $r);
2114                         last if $ok;
2115                         $tried{"$ra->{url}/$path"} = 1;
2116                 }
2117                 $path =~ s#/?[^/]+$##;
2118         }
2119         die "Path: '$path' should be ''\n" if $path ne '';
2120         $ok ||= $self->read_svm_props($ra, $path, $r);
2121         $tried{"$ra->{url}/$path"} = 1;
2122         if (!$ok) {
2123                 die @err, (map { "  $_\n" } keys %tried), "\n";
2124         }
2125         Git::SVN::Ra->new($self->{url});
2126 }
2127
2128 sub svnsync {
2129         my ($self) = @_;
2130         return $self->{svnsync} if $self->{svnsync};
2131
2132         if ($self->no_metadata) {
2133                 die "Can't have both 'noMetadata' and ",
2134                     "'useSvnsyncProps' options set!\n";
2135         }
2136         if ($self->rewrite_root) {
2137                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2138                     "options set!\n";
2139         }
2140
2141         my $svnsync;
2142         # see if we have it in our config, first:
2143         eval {
2144                 my $section = "svn-remote.$self->{repo_id}";
2145
2146                 my $url = tmp_config('--get', "$section.svnsync-url");
2147                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2148                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2149
2150                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2151                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2152                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2153
2154                 $svnsync = { url => $url, uuid => $uuid }
2155         };
2156         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2157                 return $self->{svnsync} = $svnsync;
2158         }
2159
2160         my $err = "useSvnsyncProps set, but failed to read " .
2161                   "svnsync property: svn:sync-from-";
2162         my $rp = $self->ra->rev_proplist(0);
2163
2164         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2165         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2166                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2167
2168         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2169         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2170                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2171
2172         my $section = "svn-remote.$self->{repo_id}";
2173         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2174         tmp_config('--add', "$section.svnsync-url", $url);
2175         return $self->{svnsync} = { url => $url, uuid => $uuid };
2176 }
2177
2178 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2179 # remote lookup (useful for 'git svn log').
2180 sub ra_uuid {
2181         my ($self) = @_;
2182         unless ($self->{ra_uuid}) {
2183                 my $key = "svn-remote.$self->{repo_id}.uuid";
2184                 my $uuid = eval { tmp_config('--get', $key) };
2185                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2186                         $self->{ra_uuid} = $uuid;
2187                 } else {
2188                         die "ra_uuid called without URL\n" unless $self->{url};
2189                         $self->{ra_uuid} = $self->ra->get_uuid;
2190                         tmp_config('--add', $key, $self->{ra_uuid});
2191                 }
2192         }
2193         $self->{ra_uuid};
2194 }
2195
2196 sub _set_repos_root {
2197         my ($self, $repos_root) = @_;
2198         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2199         $repos_root ||= $self->ra->{repos_root};
2200         tmp_config($k, $repos_root);
2201         $repos_root;
2202 }
2203
2204 sub repos_root {
2205         my ($self) = @_;
2206         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2207         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2208 }
2209
2210 sub ra {
2211         my ($self) = shift;
2212         my $ra = Git::SVN::Ra->new($self->{url});
2213         $self->_set_repos_root($ra->{repos_root});
2214         if ($self->use_svm_props && !$self->{svm}) {
2215                 if ($self->no_metadata) {
2216                         die "Can't have both 'noMetadata' and ",
2217                             "'useSvmProps' options set!\n";
2218                 } elsif ($self->use_svnsync_props) {
2219                         die "Can't have both 'useSvnsyncProps' and ",
2220                             "'useSvmProps' options set!\n";
2221                 }
2222                 $ra = $self->_set_svm_vars($ra);
2223                 $self->{-want_revprops} = 1;
2224         }
2225         $ra;
2226 }
2227
2228 # prop_walk(PATH, REV, SUB)
2229 # -------------------------
2230 # Recursively traverse PATH at revision REV and invoke SUB for each
2231 # directory that contains a SVN property.  SUB will be invoked as
2232 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2233 # Git::SVN, `path' the path to the directory where the properties
2234 # `props' were found.  The `path' will be relative to point of checkout,
2235 # that is, if url://repo/trunk is the current Git branch, and that
2236 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2237 # as `path' (note the trailing `/').
2238 sub prop_walk {
2239         my ($self, $path, $rev, $sub) = @_;
2240
2241         $path =~ s#^/##;
2242         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2243         $path =~ s#^/*#/#g;
2244         my $p = $path;
2245         # Strip the irrelevant part of the path.
2246         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2247         # Ensure the path is terminated by a `/'.
2248         $p =~ s#/*$#/#;
2249
2250         # The properties contain all the internal SVN stuff nobody
2251         # (usually) cares about.
2252         my $interesting_props = 0;
2253         foreach (keys %{$props}) {
2254                 # If it doesn't start with `svn:', it must be a
2255                 # user-defined property.
2256                 ++$interesting_props and next if $_ !~ /^svn:/;
2257                 # FIXME: Fragile, if SVN adds new public properties,
2258                 # this needs to be updated.
2259                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2260                                                  |eol-style|mime-type
2261                                                  |externals|needs-lock)$/x;
2262         }
2263         &$sub($self, $p, $props) if $interesting_props;
2264
2265         foreach (sort keys %$dirent) {
2266                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2267                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2268         }
2269 }
2270
2271 sub last_rev { ($_[0]->last_rev_commit)[0] }
2272 sub last_commit { ($_[0]->last_rev_commit)[1] }
2273
2274 # returns the newest SVN revision number and newest commit SHA1
2275 sub last_rev_commit {
2276         my ($self) = @_;
2277         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2278                 return ($self->{last_rev}, $self->{last_commit});
2279         }
2280         my $c = ::verify_ref($self->refname.'^0');
2281         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2282                 my $rev = (::cmt_metadata($c))[1];
2283                 if (defined $rev) {
2284                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2285                         return ($rev, $c);
2286                 }
2287         }
2288         my $map_path = $self->map_path;
2289         unless (-e $map_path) {
2290                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2291                 return (undef, undef);
2292         }
2293         my ($rev, $commit) = $self->rev_map_max(1);
2294         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2295         return ($rev, $commit);
2296 }
2297
2298 sub get_fetch_range {
2299         my ($self, $min, $max) = @_;
2300         $max ||= $self->ra->get_latest_revnum;
2301         $min ||= $self->rev_map_max;
2302         (++$min, $max);
2303 }
2304
2305 sub tmp_config {
2306         my (@args) = @_;
2307         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2308         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2309         if (! -f $config && -f $old_def_config) {
2310                 rename $old_def_config, $config or
2311                        die "Failed rename $old_def_config => $config: $!\n";
2312         }
2313         my $old_config = $ENV{GIT_CONFIG};
2314         $ENV{GIT_CONFIG} = $config;
2315         $@ = undef;
2316         my @ret = eval {
2317                 unless (-f $config) {
2318                         mkfile($config);
2319                         open my $fh, '>', $config or
2320                             die "Can't open $config: $!\n";
2321                         print $fh "; This file is used internally by ",
2322                                   "git-svn\n" or die
2323                                   "Couldn't write to $config: $!\n";
2324                         print $fh "; You should not have to edit it\n" or
2325                               die "Couldn't write to $config: $!\n";
2326                         close $fh or die "Couldn't close $config: $!\n";
2327                 }
2328                 command('config', @args);
2329         };
2330         my $err = $@;
2331         if (defined $old_config) {
2332                 $ENV{GIT_CONFIG} = $old_config;
2333         } else {
2334                 delete $ENV{GIT_CONFIG};
2335         }
2336         die $err if $err;
2337         wantarray ? @ret : $ret[0];
2338 }
2339
2340 sub tmp_index_do {
2341         my ($self, $sub) = @_;
2342         my $old_index = $ENV{GIT_INDEX_FILE};
2343         $ENV{GIT_INDEX_FILE} = $self->{index};
2344         $@ = undef;
2345         my @ret = eval {
2346                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2347                 mkpath([$dir]) unless -d $dir;
2348                 &$sub;
2349         };
2350         my $err = $@;
2351         if (defined $old_index) {
2352                 $ENV{GIT_INDEX_FILE} = $old_index;
2353         } else {
2354                 delete $ENV{GIT_INDEX_FILE};
2355         }
2356         die $err if $err;
2357         wantarray ? @ret : $ret[0];
2358 }
2359
2360 sub assert_index_clean {
2361         my ($self, $treeish) = @_;
2362
2363         $self->tmp_index_do(sub {
2364                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2365                 my $x = command_oneline('write-tree');
2366                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2367                            /^tree ($::sha1)/mo);
2368                 return if $y eq $x;
2369
2370                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2371                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2372                 command_noisy('read-tree', $treeish);
2373                 $x = command_oneline('write-tree');
2374                 if ($y ne $x) {
2375                         ::fatal "trees ($treeish) $y != $x\n",
2376                                 "Something is seriously wrong...";
2377                 }
2378         });
2379 }
2380
2381 sub get_commit_parents {
2382         my ($self, $log_entry) = @_;
2383         my (%seen, @ret, @tmp);
2384         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2385         if (my $ip = $self->{inject_parents}) {
2386                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2387                         push @tmp, $commit;
2388                 }
2389         }
2390         if (my $cur = ::verify_ref($self->refname.'^0')) {
2391                 push @tmp, $cur;
2392         }
2393         if (my $ipd = $self->{inject_parents_dcommit}) {
2394                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2395                         push @tmp, @$commit;
2396                 }
2397         }
2398         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2399         while (my $p = shift @tmp) {
2400                 next if $seen{$p};
2401                 $seen{$p} = 1;
2402                 push @ret, $p;
2403                 # MAXPARENT is defined to 16 in commit-tree.c:
2404                 last if @ret >= 16;
2405         }
2406         if (@tmp) {
2407                 die "r$log_entry->{revision}: No room for parents:\n\t",
2408                     join("\n\t", @tmp), "\n";
2409         }
2410         @ret;
2411 }
2412
2413 sub rewrite_root {
2414         my ($self) = @_;
2415         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2416         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2417         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2418         if ($rwr) {
2419                 $rwr =~ s#/+$##;
2420                 if ($rwr !~ m#^[a-z\+]+://#) {
2421                         die "$rwr is not a valid URL (key: $k)\n";
2422                 }
2423         }
2424         $self->{-rewrite_root} = $rwr;
2425 }
2426
2427 sub metadata_url {
2428         my ($self) = @_;
2429         ($self->rewrite_root || $self->{url}) .
2430            (length $self->{path} ? '/' . $self->{path} : '');
2431 }
2432
2433 sub full_url {
2434         my ($self) = @_;
2435         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2436 }
2437
2438
2439 sub set_commit_header_env {
2440         my ($log_entry) = @_;
2441         my %env;
2442         foreach my $ned (qw/NAME EMAIL DATE/) {
2443                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2444                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2445                 }
2446         }
2447
2448         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2449         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2450         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2451
2452         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2453                                                 ? $log_entry->{commit_name}
2454                                                 : $log_entry->{name};
2455         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2456                                                 ? $log_entry->{commit_email}
2457                                                 : $log_entry->{email};
2458         \%env;
2459 }
2460
2461 sub restore_commit_header_env {
2462         my ($env) = @_;
2463         foreach my $ned (qw/NAME EMAIL DATE/) {
2464                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2465                         my $k = "GIT_${ac}_${ned}";
2466                         if (defined $env->{$k}) {
2467                                 $ENV{$k} = $env->{$k};
2468                         } else {
2469                                 delete $ENV{$k};
2470                         }
2471                 }
2472         }
2473 }
2474
2475 sub gc {
2476         command_noisy('gc', '--auto');
2477 };
2478
2479 sub do_git_commit {
2480         my ($self, $log_entry) = @_;
2481         my $lr = $self->last_rev;
2482         if (defined $lr && $lr >= $log_entry->{revision}) {
2483                 die "Last fetched revision of ", $self->refname,
2484                     " was r$lr, but we are about to fetch: ",
2485                     "r$log_entry->{revision}!\n";
2486         }
2487         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2488                 croak "$log_entry->{revision} = $c already exists! ",
2489                       "Why are we refetching it?\n";
2490         }
2491         my $old_env = set_commit_header_env($log_entry);
2492         my $tree = $log_entry->{tree};
2493         if (!defined $tree) {
2494                 $tree = $self->tmp_index_do(sub {
2495                                             command_oneline('write-tree') });
2496         }
2497         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2498
2499         my @exec = ('git', 'commit-tree', $tree);
2500         foreach ($self->get_commit_parents($log_entry)) {
2501                 push @exec, '-p', $_;
2502         }
2503         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2504                                                                    or croak $!;
2505         binmode $msg_fh;
2506
2507         # we always get UTF-8 from SVN, but we may want our commits in
2508         # a different encoding.
2509         if (my $enc = Git::config('i18n.commitencoding')) {
2510                 require Encode;
2511                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2512         }
2513         print $msg_fh $log_entry->{log} or croak $!;
2514         restore_commit_header_env($old_env);
2515         unless ($self->no_metadata) {
2516                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2517                               or croak $!;
2518         }
2519         $msg_fh->flush == 0 or croak $!;
2520         close $msg_fh or croak $!;
2521         chomp(my $commit = do { local $/; <$out_fh> });
2522         close $out_fh or croak $!;
2523         waitpid $pid, 0;
2524         croak $? if $?;
2525         if ($commit !~ /^$::sha1$/o) {
2526                 die "Failed to commit, invalid sha1: $commit\n";
2527         }
2528
2529         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2530
2531         $self->{last_rev} = $log_entry->{revision};
2532         $self->{last_commit} = $commit;
2533         print "r$log_entry->{revision}" unless $::_q > 1;
2534         if (defined $log_entry->{svm_revision}) {
2535                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2536                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2537                                    0, $self->svm_uuid);
2538         }
2539         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2540         if (--$_gc_nr == 0) {
2541                 $_gc_nr = $_gc_period;
2542                 gc();
2543         }
2544         return $commit;
2545 }
2546
2547 sub match_paths {
2548         my ($self, $paths, $r) = @_;
2549         return 1 if $self->{path} eq '';
2550         if (my $path = $paths->{"/$self->{path}"}) {
2551                 return ($path->{action} eq 'D') ? 0 : 1;
2552         }
2553         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2554         if (grep /$self->{path_regex}/, keys %$paths) {
2555                 return 1;
2556         }
2557         my $c = '';
2558         foreach (split m#/#, $self->{path}) {
2559                 $c .= "/$_";
2560                 next unless ($paths->{$c} &&
2561                              ($paths->{$c}->{action} =~ /^[AR]$/));
2562                 if ($self->ra->check_path($self->{path}, $r) ==
2563                     $SVN::Node::dir) {
2564                         return 1;
2565                 }
2566         }
2567         return 0;
2568 }
2569
2570 sub find_parent_branch {
2571         my ($self, $paths, $rev) = @_;
2572         return undef unless $self->follow_parent;
2573         unless (defined $paths) {
2574                 my $err_handler = $SVN::Error::handler;
2575                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2576                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2577                                    sub { $paths = $_[0] });
2578                 $SVN::Error::handler = $err_handler;
2579         }
2580         return undef unless defined $paths;
2581
2582         # look for a parent from another branch:
2583         my @b_path_components = split m#/#, $self->{path};
2584         my @a_path_components;
2585         my $i;
2586         while (@b_path_components) {
2587                 $i = $paths->{'/'.join('/', @b_path_components)};
2588                 last if $i && defined $i->{copyfrom_path};
2589                 unshift(@a_path_components, pop(@b_path_components));
2590         }
2591         return undef unless defined $i && defined $i->{copyfrom_path};
2592         my $branch_from = $i->{copyfrom_path};
2593         if (@a_path_components) {
2594                 print STDERR "branch_from: $branch_from => ";
2595                 $branch_from .= '/'.join('/', @a_path_components);
2596                 print STDERR $branch_from, "\n";
2597         }
2598         my $r = $i->{copyfrom_rev};
2599         my $repos_root = $self->ra->{repos_root};
2600         my $url = $self->ra->{url};
2601         my $new_url = $url . $branch_from;
2602         print STDERR  "Found possible branch point: ",
2603                       "$new_url => ", $self->full_url, ", $r\n";
2604         $branch_from =~ s#^/##;
2605         my $gs = $self->other_gs($new_url, $url,
2606                                  $branch_from, $r, $self->{ref_id});
2607         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2608         {
2609                 my ($base, $head);
2610                 if (!defined $r0 || !defined $parent) {
2611                         ($base, $head) = parse_revision_argument(0, $r);
2612                 } else {
2613                         if ($r0 < $r) {
2614                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2615                                         0, 1, sub { $base = $_[1] - 1 });
2616                         }
2617                 }
2618                 if (defined $base && $base <= $r) {
2619                         $gs->fetch($base, $r);
2620                 }
2621                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2622         }
2623         if (defined $r0 && defined $parent) {
2624                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2625                 my $ed;
2626                 if ($self->ra->can_do_switch) {
2627                         $self->assert_index_clean($parent);
2628                         print STDERR "Following parent with do_switch\n";
2629                         # do_switch works with svn/trunk >= r22312, but that
2630                         # is not included with SVN 1.4.3 (the latest version
2631                         # at the moment), so we can't rely on it
2632                         $self->{last_rev} = $r0;
2633                         $self->{last_commit} = $parent;
2634                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2635                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2636                                               $self->full_url, $ed)
2637                           or die "SVN connection failed somewhere...\n";
2638                 } elsif ($self->ra->trees_match($new_url, $r0,
2639                                                 $self->full_url, $rev)) {
2640                         print STDERR "Trees match:\n",
2641                                      "  $new_url\@$r0\n",
2642                                      "  ${\$self->full_url}\@$rev\n",
2643                                      "Following parent with no changes\n";
2644                         $self->tmp_index_do(sub {
2645                             command_noisy('read-tree', $parent);
2646                         });
2647                         $self->{last_commit} = $parent;
2648                 } else {
2649                         print STDERR "Following parent with do_update\n";
2650                         $ed = SVN::Git::Fetcher->new($self);
2651                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2652                           or die "SVN connection failed somewhere...\n";
2653                 }
2654                 print STDERR "Successfully followed parent\n";
2655                 return $self->make_log_entry($rev, [$parent], $ed);
2656         }
2657         return undef;
2658 }
2659
2660 sub do_fetch {
2661         my ($self, $paths, $rev) = @_;
2662         my $ed;
2663         my ($last_rev, @parents);
2664         if (my $lc = $self->last_commit) {
2665                 # we can have a branch that was deleted, then re-added
2666                 # under the same name but copied from another path, in
2667                 # which case we'll have multiple parents (we don't
2668                 # want to break the original ref, nor lose copypath info):
2669                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2670                         push @{$log_entry->{parents}}, $lc;
2671                         return $log_entry;
2672                 }
2673                 $ed = SVN::Git::Fetcher->new($self);
2674                 $last_rev = $self->{last_rev};
2675                 $ed->{c} = $lc;
2676                 @parents = ($lc);
2677         } else {
2678                 $last_rev = $rev;
2679                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2680                         return $log_entry;
2681                 }
2682                 $ed = SVN::Git::Fetcher->new($self);
2683         }
2684         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2685                 die "SVN connection failed somewhere...\n";
2686         }
2687         $self->make_log_entry($rev, \@parents, $ed);
2688 }
2689
2690 sub get_untracked {
2691         my ($self, $ed) = @_;
2692         my @out;
2693         my $h = $ed->{empty};
2694         foreach (sort keys %$h) {
2695                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2696                 push @out, "  $act: " . uri_encode($_);
2697                 warn "W: $act: $_\n";
2698         }
2699         foreach my $t (qw/dir_prop file_prop/) {
2700                 $h = $ed->{$t} or next;
2701                 foreach my $path (sort keys %$h) {
2702                         my $ppath = $path eq '' ? '.' : $path;
2703                         foreach my $prop (sort keys %{$h->{$path}}) {
2704                                 next if $SKIP_PROP{$prop};
2705                                 my $v = $h->{$path}->{$prop};
2706                                 my $t_ppath_prop = "$t: " .
2707                                                     uri_encode($ppath) . ' ' .
2708                                                     uri_encode($prop);
2709                                 if (defined $v) {
2710                                         push @out, "  +$t_ppath_prop " .
2711                                                    uri_encode($v);
2712                                 } else {
2713                                         push @out, "  -$t_ppath_prop";
2714                                 }
2715                         }
2716                 }
2717         }
2718         foreach my $t (qw/absent_file absent_directory/) {
2719                 $h = $ed->{$t} or next;
2720                 foreach my $parent (sort keys %$h) {
2721                         foreach my $path (sort @{$h->{$parent}}) {
2722                                 push @out, "  $t: " .
2723                                            uri_encode("$parent/$path");
2724                                 warn "W: $t: $parent/$path ",
2725                                      "Insufficient permissions?\n";
2726                         }
2727                 }
2728         }
2729         \@out;
2730 }
2731
2732 # parse_svn_date(DATE)
2733 # --------------------
2734 # Given a date (in UTC) from Subversion, return a string in the format
2735 # "<TZ Offset> <local date/time>" that Git will use.
2736 #
2737 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2738 # is true we'll convert it to the local timezone instead.
2739 sub parse_svn_date {
2740         my $date = shift || return '+0000 1970-01-01 00:00:00';
2741         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2742                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2743                                          croak "Unable to parse date: $date\n";
2744         my $parsed_date;    # Set next.
2745
2746         if ($Git::SVN::_localtime) {
2747                 # Translate the Subversion datetime to an epoch time.
2748                 # Begin by switching ourselves to $date's timezone, UTC.
2749                 my $old_env_TZ = $ENV{TZ};
2750                 $ENV{TZ} = 'UTC';
2751
2752                 my $epoch_in_UTC =
2753                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2754
2755                 # Determine our local timezone (including DST) at the
2756                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2757                 # value of TZ, if any, at the time we were run.
2758                 if (defined $Git::SVN::Log::TZ) {
2759                         $ENV{TZ} = $Git::SVN::Log::TZ;
2760                 } else {
2761                         delete $ENV{TZ};
2762                 }
2763
2764                 my $our_TZ =
2765                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2766
2767                 # This converts $epoch_in_UTC into our local timezone.
2768                 my ($sec, $min, $hour, $mday, $mon, $year,
2769                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2770
2771                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2772                                        $our_TZ, $year + 1900, $mon + 1,
2773                                        $mday, $hour, $min, $sec);
2774
2775                 # Reset us to the timezone in effect when we entered
2776                 # this routine.
2777                 if (defined $old_env_TZ) {
2778                         $ENV{TZ} = $old_env_TZ;
2779                 } else {
2780                         delete $ENV{TZ};
2781                 }
2782         } else {
2783                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2784         }
2785
2786         return $parsed_date;
2787 }
2788
2789 sub other_gs {
2790         my ($self, $new_url, $url,
2791             $branch_from, $r, $old_ref_id) = @_;
2792         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2793         unless ($gs) {
2794                 my $ref_id = $old_ref_id;
2795                 $ref_id =~ s/\@\d+$//;
2796                 $ref_id .= "\@$r";
2797                 # just grow a tail if we're not unique enough :x
2798                 $ref_id .= '-' while find_ref($ref_id);
2799                 print STDERR "Initializing parent: $ref_id\n";
2800                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2801                 if ($u =~ s#^\Q$url\E(/|$)##) {
2802                         $p = $u;
2803                         $u = $url;
2804                         $repo_id = $self->{repo_id};
2805                 }
2806                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2807         }
2808         $gs
2809 }
2810
2811 sub call_authors_prog {
2812         my ($orig_author) = @_;
2813         my $author = `$::_authors_prog $orig_author`;
2814         if ($? != 0) {
2815                 die "$::_authors_prog failed with exit code $?\n"
2816         }
2817         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2818                 my ($name, $email) = ($1, $2);
2819                 $email = undef if length $2 == 0;
2820                 return [$name, $email];
2821         } else {
2822                 die "Author: $orig_author: $::_authors_prog returned "
2823                         . "invalid author format: $author\n";
2824         }
2825 }
2826
2827 sub check_author {
2828         my ($author) = @_;
2829         if (!defined $author || length $author == 0) {
2830                 $author = '(no author)';
2831         }
2832         if (!defined $::users{$author}) {
2833                 if (defined $::_authors_prog) {
2834                         $::users{$author} = call_authors_prog($author);
2835                 } elsif (defined $::_authors) {
2836                         die "Author: $author not defined in $::_authors file\n";
2837                 }
2838         }
2839         $author;
2840 }
2841
2842 sub make_log_entry {
2843         my ($self, $rev, $parents, $ed) = @_;
2844         my $untracked = $self->get_untracked($ed);
2845
2846         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2847         print $un "r$rev\n" or croak $!;
2848         print $un $_, "\n" foreach @$untracked;
2849         my %log_entry = ( parents => $parents || [], revision => $rev,
2850                           log => '');
2851
2852         my $headrev;
2853         my $logged = delete $self->{logged_rev_props};
2854         if (!$logged || $self->{-want_revprops}) {
2855                 my $rp = $self->ra->rev_proplist($rev);
2856                 foreach (sort keys %$rp) {
2857                         my $v = $rp->{$_};
2858                         if (/^svn:(author|date|log)$/) {
2859                                 $log_entry{$1} = $v;
2860                         } elsif ($_ eq 'svm:headrev') {
2861                                 $headrev = $v;
2862                         } else {
2863                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2864                                           uri_encode($v), "\n";
2865                         }
2866                 }
2867         } else {
2868                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2869         }
2870         close $un or croak $!;
2871
2872         $log_entry{date} = parse_svn_date($log_entry{date});
2873         $log_entry{log} .= "\n";
2874         my $author = $log_entry{author} = check_author($log_entry{author});
2875         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2876                                                        : ($author, undef);
2877
2878         my ($commit_name, $commit_email) = ($name, $email);
2879         if ($_use_log_author) {
2880                 my $name_field;
2881                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2882                         $name_field = $1;
2883                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2884                         $name_field = $1;
2885                 }
2886                 if (!defined $name_field) {
2887                         if (!defined $email) {
2888                                 $email = $name;
2889                         }
2890                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2891                         ($name, $email) = ($1, $2);
2892                 } elsif ($name_field =~ /(.*)@/) {
2893                         ($name, $email) = ($1, $name_field);
2894                 } else {
2895                         ($name, $email) = ($name_field, $name_field);
2896                 }
2897         }
2898         if (defined $headrev && $self->use_svm_props) {
2899                 if ($self->rewrite_root) {
2900                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2901                             "options set!\n";
2902                 }
2903                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2904                 # we don't want "SVM: initializing mirror for junk" ...
2905                 return undef if $r == 0;
2906                 my $svm = $self->svm;
2907                 if ($uuid ne $svm->{uuid}) {
2908                         die "UUID mismatch on SVM path:\n",
2909                             "expected: $svm->{uuid}\n",
2910                             "     got: $uuid\n";
2911                 }
2912                 my $full_url = $self->full_url;
2913                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2914                              die "Failed to replace '$svm->{replace}' with ",
2915                                  "'$svm->{source}' in $full_url\n";
2916                 # throw away username for storing in records
2917                 remove_username($full_url);
2918                 $log_entry{metadata} = "$full_url\@$r $uuid";
2919                 $log_entry{svm_revision} = $r;
2920                 $email ||= "$author\@$uuid";
2921                 $commit_email ||= "$author\@$uuid";
2922         } elsif ($self->use_svnsync_props) {
2923                 my $full_url = $self->svnsync->{url};
2924                 $full_url .= "/$self->{path}" if length $self->{path};
2925                 remove_username($full_url);
2926                 my $uuid = $self->svnsync->{uuid};
2927                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2928                 $email ||= "$author\@$uuid";
2929                 $commit_email ||= "$author\@$uuid";
2930         } else {
2931                 my $url = $self->metadata_url;
2932                 remove_username($url);
2933                 $log_entry{metadata} = "$url\@$rev " .
2934                                        $self->ra->get_uuid;
2935                 $email ||= "$author\@" . $self->ra->get_uuid;
2936                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2937         }
2938         $log_entry{name} = $name;
2939         $log_entry{email} = $email;
2940         $log_entry{commit_name} = $commit_name;
2941         $log_entry{commit_email} = $commit_email;
2942         \%log_entry;
2943 }
2944
2945 sub fetch {
2946         my ($self, $min_rev, $max_rev, @parents) = @_;
2947         my ($last_rev, $last_commit) = $self->last_rev_commit;
2948         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2949         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2950 }
2951
2952 sub set_tree_cb {
2953         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2954         $self->{inject_parents} = { $rev => $tree };
2955         $self->fetch(undef, undef);
2956 }
2957
2958 sub set_tree {
2959         my ($self, $tree) = (shift, shift);
2960         my $log_entry = ::get_commit_entry($tree);
2961         unless ($self->{last_rev}) {
2962                 ::fatal("Must have an existing revision to commit");
2963         }
2964         my %ed_opts = ( r => $self->{last_rev},
2965                         log => $log_entry->{log},
2966                         ra => $self->ra,
2967                         tree_a => $self->{last_commit},
2968                         tree_b => $tree,
2969                         editor_cb => sub {
2970                                $self->set_tree_cb($log_entry, $tree, @_) },
2971                         svn_path => $self->{path} );
2972         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2973                 print "No changes\nr$self->{last_rev} = $tree\n";
2974         }
2975 }
2976
2977 sub rebuild_from_rev_db {
2978         my ($self, $path) = @_;
2979         my $r = -1;
2980         open my $fh, '<', $path or croak "open: $!";
2981         binmode $fh or croak "binmode: $!";
2982         while (<$fh>) {
2983                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2984                 chomp($_);
2985                 ++$r;
2986                 next if $_ eq ('0' x 40);
2987                 $self->rev_map_set($r, $_);
2988                 print "r$r = $_\n";
2989         }
2990         close $fh or croak "close: $!";
2991         unlink $path or croak "unlink: $!";
2992 }
2993
2994 sub rebuild {
2995         my ($self) = @_;
2996         my $map_path = $self->map_path;
2997         my $partial = (-e $map_path && ! -z $map_path);
2998         return unless ::verify_ref($self->refname.'^0');
2999         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3000                 my $rev_db = $self->rev_db_path;
3001                 $self->rebuild_from_rev_db($rev_db);
3002                 if ($self->use_svm_props) {
3003                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3004                         $self->rebuild_from_rev_db($svm_rev_db);
3005                 }
3006                 $self->unlink_rev_db_symlink;
3007                 return;
3008         }
3009         print "Rebuilding $map_path ...\n" if (!$partial);
3010         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3011                 (undef, undef));
3012         my ($log, $ctx) =
3013             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3014                                 ($head ? "$head.." : "") . $self->refname,
3015                                 '--');
3016         my $metadata_url = $self->metadata_url;
3017         remove_username($metadata_url);
3018         my $svn_uuid = $self->ra_uuid;
3019         my $c;
3020         while (<$log>) {
3021                 if ( m{^commit ($::sha1)$} ) {
3022                         $c = $1;
3023                         next;
3024                 }
3025                 next unless s{^\s*(git-svn-id:)}{$1};
3026                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3027                 remove_username($url);
3028
3029                 # ignore merges (from set-tree)
3030                 next if (!defined $rev || !$uuid);
3031
3032                 # if we merged or otherwise started elsewhere, this is
3033                 # how we break out of it
3034                 if (($uuid ne $svn_uuid) ||
3035                     ($metadata_url && $url && ($url ne $metadata_url))) {
3036                         next;
3037                 }
3038                 if ($partial && $head) {
3039                         print "Partial-rebuilding $map_path ...\n";
3040                         print "Currently at $base_rev = $head\n";
3041                         $head = undef;
3042                 }
3043
3044                 $self->rev_map_set($rev, $c);
3045                 print "r$rev = $c\n";
3046         }
3047         command_close_pipe($log, $ctx);
3048         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3049         my $rev_db_path = $self->rev_db_path;
3050         if (-f $self->rev_db_path) {
3051                 unlink $self->rev_db_path or croak "unlink: $!";
3052         }
3053         $self->unlink_rev_db_symlink;
3054 }
3055
3056 # rev_map:
3057 # Tie::File seems to be prone to offset errors if revisions get sparse,
3058 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3059 # one of my favorite modules is out :<  Next up would be one of the DBM
3060 # modules, but I'm not sure which is most portable...
3061 #
3062 # This is the replacement for the rev_db format, which was too big
3063 # and inefficient for large repositories with a lot of sparse history
3064 # (mainly tags)
3065 #
3066 # The format is this:
3067 #   - 24 bytes for every record,
3068 #     * 4 bytes for the integer representing an SVN revision number
3069 #     * 20 bytes representing the sha1 of a git commit
3070 #   - No empty padding records like the old format
3071 #     (except the last record, which can be overwritten)
3072 #   - new records are written append-only since SVN revision numbers
3073 #     increase monotonically
3074 #   - lookups on SVN revision number are done via a binary search
3075 #   - Piping the file to xxd -c24 is a good way of dumping it for
3076 #     viewing or editing (piped back through xxd -r), should the need
3077 #     ever arise.
3078 #   - The last record can be padding revision with an all-zero sha1
3079 #     This is used to optimize fetch performance when using multiple
3080 #     "fetch" directives in .git/config
3081 #
3082 # These files are disposable unless noMetadata or useSvmProps is set
3083
3084 sub _rev_map_set {
3085         my ($fh, $rev, $commit) = @_;
3086
3087         binmode $fh or croak "binmode: $!";
3088         my $size = (stat($fh))[7];
3089         ($size % 24) == 0 or croak "inconsistent size: $size";
3090
3091         my $wr_offset = 0;
3092         if ($size > 0) {
3093                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3094                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3095                 $read == 24 or croak "read only $read bytes (!= 24)";
3096                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3097                 if ($last_commit eq ('0' x40)) {
3098                         if ($size >= 48) {
3099                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3100                                 $read = sysread($fh, $buf, 24) or
3101                                     croak "read: $!";
3102                                 $read == 24 or
3103                                     croak "read only $read bytes (!= 24)";
3104                                 ($last_rev, $last_commit) =
3105                                     unpack(rev_map_fmt, $buf);
3106                                 if ($last_commit eq ('0' x40)) {
3107                                         croak "inconsistent .rev_map\n";
3108                                 }
3109                         }
3110                         if ($last_rev >= $rev) {
3111                                 croak "last_rev is higher!: $last_rev >= $rev";
3112                         }
3113                         $wr_offset = -24;
3114                 }
3115         }
3116         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3117         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3118           croak "write: $!";
3119 }
3120
3121 sub _rev_map_reset {
3122         my ($fh, $rev, $commit) = @_;
3123         my $c = _rev_map_get($fh, $rev);
3124         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3125         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3126         truncate $fh, $offset or croak "truncate: $!";
3127 }
3128
3129 sub mkfile {
3130         my ($path) = @_;
3131         unless (-e $path) {
3132                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3133                 mkpath([$dir]) unless -d $dir;
3134                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3135                 close $fh or die "Couldn't close (create) $path: $!\n";
3136         }
3137 }
3138
3139 sub rev_map_set {
3140         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3141         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3142         my $db = $self->map_path($uuid);
3143         my $db_lock = "$db.lock";
3144         my $sig;
3145         $update_ref ||= 0;
3146         if ($update_ref) {
3147                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3148                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3149         }
3150         mkfile($db);
3151
3152         $LOCKFILES{$db_lock} = 1;
3153         my $sync;
3154         # both of these options make our .rev_db file very, very important
3155         # and we can't afford to lose it because rebuild() won't work
3156         if ($self->use_svm_props || $self->no_metadata) {
3157                 $sync = 1;
3158                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3159                                            "Failed to copy: ",
3160                                            "$db => $db_lock ($!)\n";
3161         } else {
3162                 rename $db, $db_lock or die "rev_map_set(@_): ",
3163                                             "Failed to rename: ",
3164                                             "$db => $db_lock ($!)\n";
3165         }
3166
3167         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3168              or croak "Couldn't open $db_lock: $!\n";
3169         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3170                                  _rev_map_set($fh, $rev, $commit);
3171         if ($sync) {
3172                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3173                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3174         }
3175         close $fh or croak $!;
3176         if ($update_ref) {
3177                 $_head = $self;
3178                 my $note = "";
3179                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3180                 command_noisy('update-ref', '-m', "r$rev$note",
3181                               $self->refname, $commit);
3182         }
3183         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3184                                     "$db_lock => $db ($!)\n";
3185         delete $LOCKFILES{$db_lock};
3186         if ($update_ref) {
3187                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3188                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3189                 kill $sig, $$ if defined $sig;
3190         }
3191 }
3192
3193 # If want_commit, this will return an array of (rev, commit) where
3194 # commit _must_ be a valid commit in the archive.
3195 # Otherwise, it'll return the max revision (whether or not the
3196 # commit is valid or just a 0x40 placeholder).
3197 sub rev_map_max {
3198         my ($self, $want_commit) = @_;
3199         $self->rebuild;
3200         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3201         $want_commit ? ($r, $c) : $r;
3202 }
3203
3204 sub rev_map_max_norebuild {
3205         my ($self, $want_commit) = @_;
3206         my $map_path = $self->map_path;
3207         stat $map_path or return $want_commit ? (0, undef) : 0;
3208         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3209         binmode $fh or croak "binmode: $!";
3210         my $size = (stat($fh))[7];
3211         ($size % 24) == 0 or croak "inconsistent size: $size";
3212
3213         if ($size == 0) {
3214                 close $fh or croak "close: $!";
3215                 return $want_commit ? (0, undef) : 0;
3216         }
3217
3218         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3219         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3220         my ($r, $c) = unpack(rev_map_fmt, $buf);
3221         if ($want_commit && $c eq ('0' x40)) {
3222                 if ($size < 48) {
3223                         return $want_commit ? (0, undef) : 0;
3224                 }
3225                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3226                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3227                 ($r, $c) = unpack(rev_map_fmt, $buf);
3228                 if ($c eq ('0'x40)) {
3229                         croak "Penultimate record is all-zeroes in $map_path";
3230                 }
3231         }
3232         close $fh or croak "close: $!";
3233         $want_commit ? ($r, $c) : $r;
3234 }
3235
3236 sub rev_map_get {
3237         my ($self, $rev, $uuid) = @_;
3238         my $map_path = $self->map_path($uuid);
3239         return undef unless -e $map_path;
3240
3241         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3242         my $c = _rev_map_get($fh, $rev);
3243         close($fh) or croak "close: $!";
3244         $c
3245 }
3246
3247 sub _rev_map_get {
3248         my ($fh, $rev) = @_;
3249
3250         binmode $fh or croak "binmode: $!";
3251         my $size = (stat($fh))[7];
3252         ($size % 24) == 0 or croak "inconsistent size: $size";
3253
3254         if ($size == 0) {
3255                 return undef;
3256         }
3257
3258         my ($l, $u) = (0, $size - 24);
3259         my ($r, $c, $buf);
3260
3261         while ($l <= $u) {
3262                 my $i = int(($l/24 + $u/24) / 2) * 24;
3263                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3264                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3265                 my ($r, $c) = unpack('NH40', $buf);
3266
3267                 if ($r < $rev) {
3268                         $l = $i + 24;
3269                 } elsif ($r > $rev) {
3270                         $u = $i - 24;
3271                 } else { # $r == $rev
3272                         return $c eq ('0' x 40) ? undef : $c;
3273                 }
3274         }
3275         undef;
3276 }
3277
3278 # Finds the first svn revision that exists on (if $eq_ok is true) or
3279 # before $rev for the current branch.  It will not search any lower
3280 # than $min_rev.  Returns the git commit hash and svn revision number
3281 # if found, else (undef, undef).
3282 sub find_rev_before {
3283         my ($self, $rev, $eq_ok, $min_rev) = @_;
3284         --$rev unless $eq_ok;
3285         $min_rev ||= 1;
3286         my $max_rev = $self->rev_map_max;
3287         $rev = $max_rev if ($rev > $max_rev);
3288         while ($rev >= $min_rev) {
3289                 if (my $c = $self->rev_map_get($rev)) {
3290                         return ($rev, $c);
3291                 }
3292                 --$rev;
3293         }
3294         return (undef, undef);
3295 }
3296
3297 # Finds the first svn revision that exists on (if $eq_ok is true) or
3298 # after $rev for the current branch.  It will not search any higher
3299 # than $max_rev.  Returns the git commit hash and svn revision number
3300 # if found, else (undef, undef).
3301 sub find_rev_after {
3302         my ($self, $rev, $eq_ok, $max_rev) = @_;
3303         ++$rev unless $eq_ok;
3304         $max_rev ||= $self->rev_map_max;
3305         while ($rev <= $max_rev) {
3306                 if (my $c = $self->rev_map_get($rev)) {
3307                         return ($rev, $c);
3308                 }
3309                 ++$rev;
3310         }
3311         return (undef, undef);
3312 }
3313
3314 sub _new {
3315         my ($class, $repo_id, $ref_id, $path) = @_;
3316         unless (defined $repo_id && length $repo_id) {
3317                 $repo_id = $Git::SVN::default_repo_id;
3318         }
3319         unless (defined $ref_id && length $ref_id) {
3320                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
3321         }
3322         $_[1] = $repo_id;
3323         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3324         $_[3] = $path = '' unless (defined $path);
3325         mkpath(["$ENV{GIT_DIR}/svn"]);
3326         bless {
3327                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3328                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3329                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3330 }
3331
3332 # for read-only access of old .rev_db formats
3333 sub unlink_rev_db_symlink {
3334         my ($self) = @_;
3335         my $link = $self->rev_db_path;
3336         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3337         if (-l $link) {
3338                 unlink $link or croak "unlink: $link failed!";
3339         }
3340 }
3341
3342 sub rev_db_path {
3343         my ($self, $uuid) = @_;
3344         my $db_path = $self->map_path($uuid);
3345         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3346             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3347         $db_path;
3348 }
3349
3350 # the new replacement for .rev_db
3351 sub map_path {
3352         my ($self, $uuid) = @_;
3353         $uuid ||= $self->ra_uuid;
3354         "$self->{map_root}.$uuid";
3355 }
3356
3357 sub uri_encode {
3358         my ($f) = @_;
3359         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3360         $f
3361 }
3362
3363 sub remove_username {
3364         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3365 }
3366
3367 package Git::SVN::Prompt;
3368 use strict;
3369 use warnings;
3370 require SVN::Core;
3371 use vars qw/$_no_auth_cache $_username/;
3372
3373 sub simple {
3374         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3375         $may_save = undef if $_no_auth_cache;
3376         $default_username = $_username if defined $_username;
3377         if (defined $default_username && length $default_username) {
3378                 if (defined $realm && length $realm) {
3379                         print STDERR "Authentication realm: $realm\n";
3380                         STDERR->flush;
3381                 }
3382                 $cred->username($default_username);
3383         } else {
3384                 username($cred, $realm, $may_save, $pool);
3385         }
3386         $cred->password(_read_password("Password for '" .
3387                                        $cred->username . "': ", $realm));
3388         $cred->may_save($may_save);
3389         $SVN::_Core::SVN_NO_ERROR;
3390 }
3391
3392 sub ssl_server_trust {
3393         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3394         $may_save = undef if $_no_auth_cache;
3395         print STDERR "Error validating server certificate for '$realm':\n";
3396         {
3397                 no warnings 'once';
3398                 # All variables SVN::Auth::SSL::* are used only once,
3399                 # so we're shutting up Perl warnings about this.
3400                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3401                         print STDERR " - The certificate is not issued ",
3402                             "by a trusted authority. Use the\n",
3403                             "   fingerprint to validate ",
3404                             "the certificate manually!\n";
3405                 }
3406                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3407                         print STDERR " - The certificate hostname ",
3408                             "does not match.\n";
3409                 }
3410                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3411                         print STDERR " - The certificate is not yet valid.\n";
3412                 }
3413                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3414                         print STDERR " - The certificate has expired.\n";
3415                 }
3416                 if ($failures & $SVN::Auth::SSL::OTHER) {
3417                         print STDERR " - The certificate has ",
3418                             "an unknown error.\n";
3419                 }
3420         } # no warnings 'once'
3421         printf STDERR
3422                 "Certificate information:\n".
3423                 " - Hostname: %s\n".
3424                 " - Valid: from %s until %s\n".
3425                 " - Issuer: %s\n".
3426                 " - Fingerprint: %s\n",
3427                 map $cert_info->$_, qw(hostname valid_from valid_until
3428                                        issuer_dname fingerprint);
3429         my $choice;
3430 prompt:
3431         print STDERR $may_save ?
3432               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3433               "(R)eject or accept (t)emporarily? ";
3434         STDERR->flush;
3435         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3436         if ($choice =~ /^t$/i) {
3437                 $cred->may_save(undef);
3438         } elsif ($choice =~ /^r$/i) {
3439                 return -1;
3440         } elsif ($may_save && $choice =~ /^p$/i) {
3441                 $cred->may_save($may_save);
3442         } else {
3443                 goto prompt;
3444         }
3445         $cred->accepted_failures($failures);
3446         $SVN::_Core::SVN_NO_ERROR;
3447 }
3448
3449 sub ssl_client_cert {
3450         my ($cred, $realm, $may_save, $pool) = @_;
3451         $may_save = undef if $_no_auth_cache;
3452         print STDERR "Client certificate filename: ";
3453         STDERR->flush;
3454         chomp(my $filename = <STDIN>);
3455         $cred->cert_file($filename);
3456         $cred->may_save($may_save);
3457         $SVN::_Core::SVN_NO_ERROR;
3458 }
3459
3460 sub ssl_client_cert_pw {
3461         my ($cred, $realm, $may_save, $pool) = @_;
3462         $may_save = undef if $_no_auth_cache;
3463         $cred->password(_read_password("Password: ", $realm));
3464         $cred->may_save($may_save);
3465         $SVN::_Core::SVN_NO_ERROR;
3466 }
3467
3468 sub username {
3469         my ($cred, $realm, $may_save, $pool) = @_;
3470         $may_save = undef if $_no_auth_cache;
3471         if (defined $realm && length $realm) {
3472                 print STDERR "Authentication realm: $realm\n";
3473         }
3474         my $username;
3475         if (defined $_username) {
3476                 $username = $_username;
3477         } else {
3478                 print STDERR "Username: ";
3479                 STDERR->flush;
3480                 chomp($username = <STDIN>);
3481         }
3482         $cred->username($username);
3483         $cred->may_save($may_save);
3484         $SVN::_Core::SVN_NO_ERROR;
3485 }
3486
3487 sub _read_password {
3488         my ($prompt, $realm) = @_;
3489         print STDERR $prompt;
3490         STDERR->flush;
3491         require Term::ReadKey;
3492         Term::ReadKey::ReadMode('noecho');
3493         my $password = '';
3494         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3495                 last if $key =~ /[\012\015]/; # \n\r
3496                 $password .= $key;
3497         }
3498         Term::ReadKey::ReadMode('restore');
3499         print STDERR "\n";
3500         STDERR->flush;
3501         $password;
3502 }
3503
3504 package SVN::Git::Fetcher;
3505 use vars qw/@ISA/;
3506 use strict;
3507 use warnings;
3508 use Carp qw/croak/;
3509 use File::Temp qw/tempfile/;
3510 use IO::File qw//;
3511 use vars qw/$_ignore_regex/;
3512
3513 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3514 sub new {
3515         my ($class, $git_svn, $switch_path) = @_;
3516         my $self = SVN::Delta::Editor->new;
3517         bless $self, $class;
3518         if (exists $git_svn->{last_commit}) {
3519                 $self->{c} = $git_svn->{last_commit};
3520                 $self->{empty_symlinks} =
3521                                   _mark_empty_symlinks($git_svn, $switch_path);
3522         }
3523         $self->{ignore_regex} = eval { command_oneline('config', '--get',
3524                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3525         $self->{empty} = {};
3526         $self->{dir_prop} = {};
3527         $self->{file_prop} = {};
3528         $self->{absent_dir} = {};
3529         $self->{absent_file} = {};
3530         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3531         $self;
3532 }
3533
3534 # this uses the Ra object, so it must be called before do_{switch,update},
3535 # not inside them (when the Git::SVN::Fetcher object is passed) to
3536 # do_{switch,update}
3537 sub _mark_empty_symlinks {
3538         my ($git_svn, $switch_path) = @_;
3539         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3540         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3541
3542         my %ret;
3543         my ($rev, $cmt) = $git_svn->last_rev_commit;
3544         return {} unless ($rev && $cmt);
3545
3546         # allow the warning to be printed for each revision we fetch to
3547         # ensure the user sees it.  The user can also disable the workaround
3548         # on the repository even while git svn is running and the next
3549         # revision fetched will skip this expensive function.
3550         my $printed_warning;
3551         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3552         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3553         local $/ = "\0";
3554         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3555         $pfx .= '/' if length($pfx);
3556         while (<$ls>) {
3557                 chomp;
3558                 s/\A100644 blob $empty_blob\t//o or next;
3559                 unless ($printed_warning) {
3560                         print STDERR "Scanning for empty symlinks, ",
3561                                      "this may take a while if you have ",
3562                                      "many empty files\n",
3563                                      "You may disable this with `",
3564                                      "git config svn.brokenSymlinkWorkaround ",
3565                                      "false'.\n",
3566                                      "This may be done in a different ",
3567                                      "terminal without restarting ",
3568                                      "git svn\n";
3569                         $printed_warning = 1;
3570                 }
3571                 my $path = $_;
3572                 my (undef, $props) =
3573                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
3574                 if ($props->{'svn:special'}) {
3575                         $ret{$path} = 1;
3576                 }
3577         }
3578         command_close_pipe($ls, $ctx);
3579         \%ret;
3580 }
3581
3582 # returns true if a given path is inside a ".git" directory
3583 sub in_dot_git {
3584         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3585 }
3586
3587 # return value: 0 -- don't ignore, 1 -- ignore
3588 sub is_path_ignored {
3589         my ($self, $path) = @_;
3590         return 1 if in_dot_git($path);
3591         return 1 if defined($self->{ignore_regex}) &&
3592                     $path =~ m!$self->{ignore_regex}!;
3593         return 0 unless defined($_ignore_regex);
3594         return 1 if $path =~ m!$_ignore_regex!o;
3595         return 0;
3596 }
3597
3598 sub set_path_strip {
3599         my ($self, $path) = @_;
3600         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3601 }
3602
3603 sub open_root {
3604         { path => '' };
3605 }
3606
3607 sub open_directory {
3608         my ($self, $path, $pb, $rev) = @_;
3609         { path => $path };
3610 }
3611
3612 sub git_path {
3613         my ($self, $path) = @_;
3614         if ($self->{path_strip}) {
3615                 $path =~ s!$self->{path_strip}!! or
3616                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3617         }
3618         $path;
3619 }
3620
3621 sub delete_entry {
3622         my ($self, $path, $rev, $pb) = @_;
3623         return undef if $self->is_path_ignored($path);
3624
3625         my $gpath = $self->git_path($path);
3626         return undef if ($gpath eq '');
3627
3628         # remove entire directories.
3629         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3630                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3631         if ($tree) {
3632                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3633                                                      -r --name-only -z/,
3634                                                      $tree);
3635                 local $/ = "\0";
3636                 while (<$ls>) {
3637                         chomp;
3638                         my $rmpath = "$gpath/$_";
3639                         $self->{gii}->remove($rmpath);
3640                         print "\tD\t$rmpath\n" unless $::_q;
3641                 }
3642                 print "\tD\t$gpath/\n" unless $::_q;
3643                 command_close_pipe($ls, $ctx);
3644                 $self->{empty}->{$path} = 0
3645         } else {
3646                 $self->{gii}->remove($gpath);
3647                 print "\tD\t$gpath\n" unless $::_q;
3648         }
3649         undef;
3650 }
3651
3652 sub open_file {
3653         my ($self, $path, $pb, $rev) = @_;
3654         my ($mode, $blob);
3655
3656         goto out if $self->is_path_ignored($path);
3657
3658         my $gpath = $self->git_path($path);
3659         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3660                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3661         unless (defined $mode && defined $blob) {
3662                 die "$path was not found in commit $self->{c} (r$rev)\n";
3663         }
3664         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3665                 $mode = '120000';
3666         }
3667 out:
3668         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3669           pool => SVN::Pool->new, action => 'M' };
3670 }
3671
3672 sub add_file {
3673         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3674         my $mode;
3675
3676         if (!$self->is_path_ignored($path)) {
3677                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3678                 delete $self->{empty}->{$dir};
3679                 $mode = '100644';
3680         }
3681         { path => $path, mode_a => $mode, mode_b => $mode,
3682           pool => SVN::Pool->new, action => 'A' };
3683 }
3684
3685 sub add_directory {
3686         my ($self, $path, $cp_path, $cp_rev) = @_;
3687         goto out if $self->is_path_ignored($path);
3688         my $gpath = $self->git_path($path);
3689         if ($gpath eq '') {
3690                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3691                                                      -r --name-only -z/,
3692                                                      $self->{c});
3693                 local $/ = "\0";
3694                 while (<$ls>) {
3695                         chomp;
3696                         $self->{gii}->remove($_);
3697                         print "\tD\t$_\n" unless $::_q;
3698                 }
3699                 command_close_pipe($ls, $ctx);
3700                 $self->{empty}->{$path} = 0;
3701         }
3702         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3703         delete $self->{empty}->{$dir};
3704         $self->{empty}->{$path} = 1;
3705 out:
3706         { path => $path };
3707 }
3708
3709 sub change_dir_prop {
3710         my ($self, $db, $prop, $value) = @_;
3711         return undef if $self->is_path_ignored($db->{path});
3712         $self->{dir_prop}->{$db->{path}} ||= {};
3713         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3714         undef;
3715 }
3716
3717 sub absent_directory {
3718         my ($self, $path, $pb) = @_;
3719         return undef if $self->is_path_ignored($path);
3720         $self->{absent_dir}->{$pb->{path}} ||= [];
3721         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3722         undef;
3723 }
3724
3725 sub absent_file {
3726         my ($self, $path, $pb) = @_;
3727         return undef if $self->is_path_ignored($path);
3728         $self->{absent_file}->{$pb->{path}} ||= [];
3729         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3730         undef;
3731 }
3732
3733 sub change_file_prop {
3734         my ($self, $fb, $prop, $value) = @_;
3735         return undef if $self->is_path_ignored($fb->{path});
3736         if ($prop eq 'svn:executable') {
3737                 if ($fb->{mode_b} != 120000) {
3738                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3739                 }
3740         } elsif ($prop eq 'svn:special') {
3741                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3742         } else {
3743                 $self->{file_prop}->{$fb->{path}} ||= {};
3744                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3745         }
3746         undef;
3747 }
3748
3749 sub apply_textdelta {
3750         my ($self, $fb, $exp) = @_;
3751         return undef if $self->is_path_ignored($fb->{path});
3752         my $fh = $::_repository->temp_acquire('svn_delta');
3753         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3754         # (but $base does not,) so dup() it for reading in close_file
3755         open my $dup, '<&', $fh or croak $!;
3756         my $base = $::_repository->temp_acquire('git_blob');
3757
3758         if ($fb->{blob}) {
3759                 my ($base_is_link, $size);
3760
3761                 if ($fb->{mode_a} eq '120000' &&
3762                     ! $self->{empty_symlinks}->{$fb->{path}}) {
3763                         print $base 'link ' or die "print $!\n";
3764                         $base_is_link = 1;
3765                 }
3766         retry:
3767                 $size = $::_repository->cat_blob($fb->{blob}, $base);
3768                 die "Failed to read object $fb->{blob}" if ($size < 0);
3769
3770                 if (defined $exp) {
3771                         seek $base, 0, 0 or croak $!;
3772                         my $got = ::md5sum($base);
3773                         if ($got ne $exp) {
3774                                 my $err = "Checksum mismatch: ".
3775                                        "$fb->{path} $fb->{blob}\n" .
3776                                        "expected: $exp\n" .
3777                                        "     got: $got\n";
3778                                 if ($base_is_link) {
3779                                         warn $err,
3780                                              "Retrying... (possibly ",
3781                                              "a bad symlink from SVN)\n";
3782                                         $::_repository->temp_reset($base);
3783                                         $base_is_link = 0;
3784                                         goto retry;
3785                                 }
3786                                 die $err;
3787                         }
3788                 }
3789         }
3790         seek $base, 0, 0 or croak $!;
3791         $fb->{fh} = $fh;
3792         $fb->{base} = $base;
3793         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3794 }
3795
3796 sub close_file {
3797         my ($self, $fb, $exp) = @_;
3798         return undef if $self->is_path_ignored($fb->{path});
3799
3800         my $hash;
3801         my $path = $self->git_path($fb->{path});
3802         if (my $fh = $fb->{fh}) {
3803                 if (defined $exp) {
3804                         seek($fh, 0, 0) or croak $!;
3805                         my $got = ::md5sum($fh);
3806                         if ($got ne $exp) {
3807                                 die "Checksum mismatch: $path\n",
3808                                     "expected: $exp\n    got: $got\n";
3809                         }
3810                 }
3811                 if ($fb->{mode_b} == 120000) {
3812                         sysseek($fh, 0, 0) or croak $!;
3813                         my $rd = sysread($fh, my $buf, 5);
3814
3815                         if (!defined $rd) {
3816                                 croak "sysread: $!\n";
3817                         } elsif ($rd == 0) {
3818                                 warn "$path has mode 120000",
3819                                      " but it points to nothing\n",
3820                                      "converting to an empty file with mode",
3821                                      " 100644\n";
3822                                 $fb->{mode_b} = '100644';
3823                         } elsif ($buf ne 'link ') {
3824                                 warn "$path has mode 120000",
3825                                      " but is not a link\n";
3826                         } else {
3827                                 my $tmp_fh = $::_repository->temp_acquire(
3828                                         'svn_hash');
3829                                 my $res;
3830                                 while ($res = sysread($fh, my $str, 1024)) {
3831                                         my $out = syswrite($tmp_fh, $str, $res);
3832                                         defined($out) && $out == $res
3833                                                 or croak("write ",
3834                                                         Git::temp_path($tmp_fh),
3835                                                         ": $!\n");
3836                                 }
3837                                 defined $res or croak $!;
3838
3839                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3840                                 Git::temp_release($tmp_fh, 1);
3841                         }
3842                 }
3843
3844                 $hash = $::_repository->hash_and_insert_object(
3845                                 Git::temp_path($fh));
3846                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3847
3848                 Git::temp_release($fb->{base}, 1);
3849                 Git::temp_release($fh, 1);
3850         } else {
3851                 $hash = $fb->{blob} or die "no blob information\n";
3852         }
3853         $fb->{pool}->clear;
3854         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3855         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3856         undef;
3857 }
3858
3859 sub abort_edit {
3860         my $self = shift;
3861         $self->{nr} = $self->{gii}->{nr};
3862         delete $self->{gii};
3863         $self->SUPER::abort_edit(@_);
3864 }
3865
3866 sub close_edit {
3867         my $self = shift;
3868         $self->{git_commit_ok} = 1;
3869         $self->{nr} = $self->{gii}->{nr};
3870         delete $self->{gii};
3871         $self->SUPER::close_edit(@_);
3872 }
3873
3874 package SVN::Git::Editor;
3875 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3876 use strict;
3877 use warnings;
3878 use Carp qw/croak/;
3879 use IO::File;
3880
3881 sub new {
3882         my ($class, $opts) = @_;
3883         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3884                 die "$_ required!\n" unless (defined $opts->{$_});
3885         }
3886
3887         my $pool = SVN::Pool->new;
3888         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3889         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3890                                      $opts->{r}, $mods);
3891
3892         # $opts->{ra} functions should not be used after this:
3893         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3894                                                 $opts->{editor_cb}, $pool);
3895         my $self = SVN::Delta::Editor->new(@ce, $pool);
3896         bless $self, $class;
3897         foreach (qw/svn_path r tree_a tree_b/) {
3898                 $self->{$_} = $opts->{$_};
3899         }
3900         $self->{url} = $opts->{ra}->{url};
3901         $self->{mods} = $mods;
3902         $self->{types} = $types;
3903         $self->{pool} = $pool;
3904         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3905         $self->{rm} = { };
3906         $self->{path_prefix} = length $self->{svn_path} ?
3907                                "$self->{svn_path}/" : '';
3908         $self->{config} = $opts->{config};
3909         return $self;
3910 }
3911
3912 sub generate_diff {
3913         my ($tree_a, $tree_b) = @_;
3914         my @diff_tree = qw(diff-tree -z -r);
3915         if ($_cp_similarity) {
3916                 push @diff_tree, "-C$_cp_similarity";
3917         } else {
3918                 push @diff_tree, '-C';
3919         }
3920         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3921         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3922         push @diff_tree, $tree_a, $tree_b;
3923         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3924         local $/ = "\0";
3925         my $state = 'meta';
3926         my @mods;
3927         while (<$diff_fh>) {
3928                 chomp $_; # this gets rid of the trailing "\0"
3929                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3930                                         ($::sha1)\s($::sha1)\s
3931                                         ([MTCRAD])\d*$/xo) {
3932                         push @mods, {   mode_a => $1, mode_b => $2,
3933                                         sha1_a => $3, sha1_b => $4,
3934                                         chg => $5 };
3935                         if ($5 =~ /^(?:C|R)$/) {
3936                                 $state = 'file_a';
3937                         } else {
3938                                 $state = 'file_b';
3939                         }
3940                 } elsif ($state eq 'file_a') {
3941                         my $x = $mods[$#mods] or croak "Empty array\n";
3942                         if ($x->{chg} !~ /^(?:C|R)$/) {
3943                                 croak "Error parsing $_, $x->{chg}\n";
3944                         }
3945                         $x->{file_a} = $_;
3946                         $state = 'file_b';
3947                 } elsif ($state eq 'file_b') {
3948                         my $x = $mods[$#mods] or croak "Empty array\n";
3949                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3950                                 croak "Error parsing $_, $x->{chg}\n";
3951                         }
3952                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3953                                 croak "Error parsing $_, $x->{chg}\n";
3954                         }
3955                         $x->{file_b} = $_;
3956                         $state = 'meta';
3957                 } else {
3958                         croak "Error parsing $_\n";
3959                 }
3960         }
3961         command_close_pipe($diff_fh, $ctx);
3962         \@mods;
3963 }
3964
3965 sub check_diff_paths {
3966         my ($ra, $pfx, $rev, $mods) = @_;
3967         my %types;
3968         $pfx .= '/' if length $pfx;
3969
3970         sub type_diff_paths {
3971                 my ($ra, $types, $path, $rev) = @_;
3972                 my @p = split m#/+#, $path;
3973                 my $c = shift @p;
3974                 unless (defined $types->{$c}) {
3975                         $types->{$c} = $ra->check_path($c, $rev);
3976                 }
3977                 while (@p) {
3978                         $c .= '/' . shift @p;
3979                         next if defined $types->{$c};
3980                         $types->{$c} = $ra->check_path($c, $rev);
3981                 }
3982         }
3983
3984         foreach my $m (@$mods) {
3985                 foreach my $f (qw/file_a file_b/) {
3986                         next unless defined $m->{$f};
3987                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3988                         if (length $pfx.$dir && ! defined $types{$dir}) {
3989                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3990                         }
3991                 }
3992         }
3993         \%types;
3994 }
3995
3996 sub split_path {
3997         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3998 }
3999
4000 sub repo_path {
4001         my ($self, $path) = @_;
4002         $self->{path_prefix}.(defined $path ? $path : '');
4003 }
4004
4005 sub url_path {
4006         my ($self, $path) = @_;
4007         if ($self->{url} =~ m#^https?://#) {
4008                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4009         }
4010         $self->{url} . '/' . $self->repo_path($path);
4011 }
4012
4013 sub rmdirs {
4014         my ($self) = @_;
4015         my $rm = $self->{rm};
4016         delete $rm->{''}; # we never delete the url we're tracking
4017         return unless %$rm;
4018
4019         foreach (keys %$rm) {
4020                 my @d = split m#/#, $_;
4021                 my $c = shift @d;
4022                 $rm->{$c} = 1;
4023                 while (@d) {
4024                         $c .= '/' . shift @d;
4025                         $rm->{$c} = 1;
4026                 }
4027         }
4028         delete $rm->{$self->{svn_path}};
4029         delete $rm->{''}; # we never delete the url we're tracking
4030         return unless %$rm;
4031
4032         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4033                                              $self->{tree_b});
4034         local $/ = "\0";
4035         while (<$fh>) {
4036                 chomp;
4037                 my @dn = split m#/#, $_;
4038                 while (pop @dn) {
4039                         delete $rm->{join '/', @dn};
4040                 }
4041                 unless (%$rm) {
4042                         close $fh;
4043                         return;
4044                 }
4045         }
4046         command_close_pipe($fh, $ctx);
4047
4048         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4049         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4050                 $self->close_directory($bat->{$d}, $p);
4051                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4052                 print "\tD+\t$d/\n" unless $::_q;
4053                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4054                 delete $bat->{$d};
4055         }
4056 }
4057
4058 sub open_or_add_dir {
4059         my ($self, $full_path, $baton) = @_;
4060         my $t = $self->{types}->{$full_path};
4061         if (!defined $t) {
4062                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4063         }
4064         {
4065                 no warnings 'once';
4066                 # SVN::Node::none and SVN::Node::file are used only once,
4067                 # so we're shutting up Perl's warnings about them.
4068                 if ($t == $SVN::Node::none) {
4069                         return $self->add_directory($full_path, $baton,
4070                             undef, -1, $self->{pool});
4071                 } elsif ($t == $SVN::Node::dir) {
4072                         return $self->open_directory($full_path, $baton,
4073                             $self->{r}, $self->{pool});
4074                 } # no warnings 'once'
4075                 print STDERR "$full_path already exists in repository at ",
4076                     "r$self->{r} and it is not a directory (",
4077                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4078         } # no warnings 'once'
4079         exit 1;
4080 }
4081
4082 sub ensure_path {
4083         my ($self, $path) = @_;
4084         my $bat = $self->{bat};
4085         my $repo_path = $self->repo_path($path);
4086         return $bat->{''} unless (length $repo_path);
4087         my @p = split m#/+#, $repo_path;
4088         my $c = shift @p;
4089         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4090         while (@p) {
4091                 my $c0 = $c;
4092                 $c .= '/' . shift @p;
4093                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4094         }
4095         return $bat->{$c};
4096 }
4097
4098 # Subroutine to convert a globbing pattern to a regular expression.
4099 # From perl cookbook.
4100 sub glob2pat {
4101         my $globstr = shift;
4102         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4103         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4104         return '^' . $globstr . '$';
4105 }
4106
4107 sub check_autoprop {
4108         my ($self, $pattern, $properties, $file, $fbat) = @_;
4109         # Convert the globbing pattern to a regular expression.
4110         my $regex = glob2pat($pattern);
4111         # Check if the pattern matches the file name.
4112         if($file =~ m/($regex)/) {
4113                 # Parse the list of properties to set.
4114                 my @props = split(/;/, $properties);
4115                 foreach my $prop (@props) {
4116                         # Parse 'name=value' syntax and set the property.
4117                         if ($prop =~ /([^=]+)=(.*)/) {
4118                                 my ($n,$v) = ($1,$2);
4119                                 for ($n, $v) {
4120                                         s/^\s+//; s/\s+$//;
4121                                 }
4122                                 $self->change_file_prop($fbat, $n, $v);
4123                         }
4124                 }
4125         }
4126 }
4127
4128 sub apply_autoprops {
4129         my ($self, $file, $fbat) = @_;
4130         my $conf_t = ${$self->{config}}{'config'};
4131         no warnings 'once';
4132         # Check [miscellany]/enable-auto-props in svn configuration.
4133         if (SVN::_Core::svn_config_get_bool(
4134                 $conf_t,
4135                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4136                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4137                 0)) {
4138                 # Auto-props are enabled.  Enumerate them to look for matches.
4139                 my $callback = sub {
4140                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4141                 };
4142                 SVN::_Core::svn_config_enumerate(
4143                         $conf_t,
4144                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4145                         $callback);
4146         }
4147 }
4148
4149 sub A {
4150         my ($self, $m) = @_;
4151         my ($dir, $file) = split_path($m->{file_b});
4152         my $pbat = $self->ensure_path($dir);
4153         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4154                                         undef, -1);
4155         print "\tA\t$m->{file_b}\n" unless $::_q;
4156         $self->apply_autoprops($file, $fbat);
4157         $self->chg_file($fbat, $m);
4158         $self->close_file($fbat,undef,$self->{pool});
4159 }
4160
4161 sub C {
4162         my ($self, $m) = @_;
4163         my ($dir, $file) = split_path($m->{file_b});
4164         my $pbat = $self->ensure_path($dir);
4165         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4166                                 $self->url_path($m->{file_a}), $self->{r});
4167         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4168         $self->chg_file($fbat, $m);
4169         $self->close_file($fbat,undef,$self->{pool});
4170 }
4171
4172 sub delete_entry {
4173         my ($self, $path, $pbat) = @_;
4174         my $rpath = $self->repo_path($path);
4175         my ($dir, $file) = split_path($rpath);
4176         $self->{rm}->{$dir} = 1;
4177         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4178 }
4179
4180 sub R {
4181         my ($self, $m) = @_;
4182         my ($dir, $file) = split_path($m->{file_b});
4183         my $pbat = $self->ensure_path($dir);
4184         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4185                                 $self->url_path($m->{file_a}), $self->{r});
4186         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4187         $self->apply_autoprops($file, $fbat);
4188         $self->chg_file($fbat, $m);
4189         $self->close_file($fbat,undef,$self->{pool});
4190
4191         ($dir, $file) = split_path($m->{file_a});
4192         $pbat = $self->ensure_path($dir);
4193         $self->delete_entry($m->{file_a}, $pbat);
4194 }
4195
4196 sub M {
4197         my ($self, $m) = @_;
4198         my ($dir, $file) = split_path($m->{file_b});
4199         my $pbat = $self->ensure_path($dir);
4200         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4201                                 $pbat,$self->{r},$self->{pool});
4202         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4203         $self->chg_file($fbat, $m);
4204         $self->close_file($fbat,undef,$self->{pool});
4205 }
4206
4207 sub T { shift->M(@_) }
4208
4209 sub change_file_prop {
4210         my ($self, $fbat, $pname, $pval) = @_;
4211         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4212 }
4213
4214 sub _chg_file_get_blob ($$$$) {
4215         my ($self, $fbat, $m, $which) = @_;
4216         my $fh = $::_repository->temp_acquire("git_blob_$which");
4217         if ($m->{"mode_$which"} =~ /^120/) {
4218                 print $fh 'link ' or croak $!;
4219                 $self->change_file_prop($fbat,'svn:special','*');
4220         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4221                 $self->change_file_prop($fbat,'svn:special',undef);
4222         }
4223         my $blob = $m->{"sha1_$which"};
4224         return ($fh,) if ($blob =~ /^0{40}$/);
4225         my $size = $::_repository->cat_blob($blob, $fh);
4226         croak "Failed to read object $blob" if ($size < 0);
4227         $fh->flush == 0 or croak $!;
4228         seek $fh, 0, 0 or croak $!;
4229
4230         my $exp = ::md5sum($fh);
4231         seek $fh, 0, 0 or croak $!;
4232         return ($fh, $exp);
4233 }
4234
4235 sub chg_file {
4236         my ($self, $fbat, $m) = @_;
4237         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4238                 $self->change_file_prop($fbat,'svn:executable','*');
4239         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4240                 $self->change_file_prop($fbat,'svn:executable',undef);
4241         }
4242         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4243         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4244         my $pool = SVN::Pool->new;
4245         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4246         if (-s $fh_a) {
4247                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4248                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4249                 if (defined $res) {
4250                         die "Unexpected result from send_txstream: $res\n",
4251                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4252                 }
4253         } else {
4254                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4255                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4256                     if ($got ne $exp_b);
4257         }
4258         Git::temp_release($fh_b, 1);
4259         Git::temp_release($fh_a, 1);
4260         $pool->clear;
4261 }
4262
4263 sub D {
4264         my ($self, $m) = @_;
4265         my ($dir, $file) = split_path($m->{file_b});
4266         my $pbat = $self->ensure_path($dir);
4267         print "\tD\t$m->{file_b}\n" unless $::_q;
4268         $self->delete_entry($m->{file_b}, $pbat);
4269 }
4270
4271 sub close_edit {
4272         my ($self) = @_;
4273         my ($p,$bat) = ($self->{pool}, $self->{bat});
4274         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4275                 next if $_ eq '';
4276                 $self->close_directory($bat->{$_}, $p);
4277         }
4278         $self->close_directory($bat->{''}, $p);
4279         $self->SUPER::close_edit($p);
4280         $p->clear;
4281 }
4282
4283 sub abort_edit {
4284         my ($self) = @_;
4285         $self->SUPER::abort_edit($self->{pool});
4286 }
4287
4288 sub DESTROY {
4289         my $self = shift;
4290         $self->SUPER::DESTROY(@_);
4291         $self->{pool}->clear;
4292 }
4293
4294 # this drives the editor
4295 sub apply_diff {
4296         my ($self) = @_;
4297         my $mods = $self->{mods};
4298         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4299         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4300                 my $f = $m->{chg};
4301                 if (defined $o{$f}) {
4302                         $self->$f($m);
4303                 } else {
4304                         fatal("Invalid change type: $f");
4305                 }
4306         }
4307         $self->rmdirs if $_rmdir;
4308         if (@$mods == 0) {
4309                 $self->abort_edit;
4310         } else {
4311                 $self->close_edit;
4312         }
4313         return scalar @$mods;
4314 }
4315
4316 package Git::SVN::Ra;
4317 use vars qw/@ISA $config_dir $_log_window_size/;
4318 use strict;
4319 use warnings;
4320 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4321
4322 BEGIN {
4323         # enforce temporary pool usage for some simple functions
4324         no strict 'refs';
4325         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4326                       get_file/) {
4327                 my $SUPER = "SUPER::$f";
4328                 *$f = sub {
4329                         my $self = shift;
4330                         my $pool = SVN::Pool->new;
4331                         my @ret = $self->$SUPER(@_,$pool);
4332                         $pool->clear;
4333                         wantarray ? @ret : $ret[0];
4334                 };
4335         }
4336 }
4337
4338 sub _auth_providers () {
4339         [
4340           SVN::Client::get_simple_provider(),
4341           SVN::Client::get_ssl_server_trust_file_provider(),
4342           SVN::Client::get_simple_prompt_provider(
4343             \&Git::SVN::Prompt::simple, 2),
4344           SVN::Client::get_ssl_client_cert_file_provider(),
4345           SVN::Client::get_ssl_client_cert_prompt_provider(
4346             \&Git::SVN::Prompt::ssl_client_cert, 2),
4347           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4348           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4349             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4350           SVN::Client::get_username_provider(),
4351           SVN::Client::get_ssl_server_trust_prompt_provider(
4352             \&Git::SVN::Prompt::ssl_server_trust),
4353           SVN::Client::get_username_prompt_provider(
4354             \&Git::SVN::Prompt::username, 2)
4355         ]
4356 }
4357
4358 sub escape_uri_only {
4359         my ($uri) = @_;
4360         my @tmp;
4361         foreach (split m{/}, $uri) {
4362                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4363                 push @tmp, $_;
4364         }
4365         join('/', @tmp);
4366 }
4367
4368 sub escape_url {
4369         my ($url) = @_;
4370         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4371                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4372                 $url = "$scheme://$domain$uri";
4373         }
4374         $url;
4375 }
4376
4377 sub new {
4378         my ($class, $url) = @_;
4379         $url =~ s!/+$!!;
4380         return $RA if ($RA && $RA->{url} eq $url);
4381
4382         SVN::_Core::svn_config_ensure($config_dir, undef);
4383         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4384         my $config = SVN::Core::config_get_config($config_dir);
4385         $RA = undef;
4386         my $dont_store_passwords = 1;
4387         my $conf_t = ${$config}{'config'};
4388         {
4389                 no warnings 'once';
4390                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4391                 # produces warnings that variables are used only once.
4392                 # I had not found the better way to shut them up, so
4393                 # the warnings of type 'once' are disabled in this block.
4394                 if (SVN::_Core::svn_config_get_bool($conf_t,
4395                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4396                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4397                     1) == 0) {
4398                         SVN::_Core::svn_auth_set_parameter($baton,
4399                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4400                             bless (\$dont_store_passwords, "_p_void"));
4401                 }
4402                 if (SVN::_Core::svn_config_get_bool($conf_t,
4403                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4404                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4405                     1) == 0) {
4406                         $Git::SVN::Prompt::_no_auth_cache = 1;
4407                 }
4408         } # no warnings 'once'
4409         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4410                               config => $config,
4411                               pool => SVN::Pool->new,
4412                               auth_provider_callbacks => $callbacks);
4413         $self->{url} = $url;
4414         $self->{svn_path} = $url;
4415         $self->{repos_root} = $self->get_repos_root;
4416         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4417         $self->{cache} = { check_path => { r => 0, data => {} },
4418                            get_dir => { r => 0, data => {} } };
4419         $RA = bless $self, $class;
4420 }
4421
4422 sub check_path {
4423         my ($self, $path, $r) = @_;
4424         my $cache = $self->{cache}->{check_path};
4425         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4426                 return $cache->{data}->{$path};
4427         }
4428         my $pool = SVN::Pool->new;
4429         my $t = $self->SUPER::check_path($path, $r, $pool);
4430         $pool->clear;
4431         if ($r != $cache->{r}) {
4432                 %{$cache->{data}} = ();
4433                 $cache->{r} = $r;
4434         }
4435         $cache->{data}->{$path} = $t;
4436 }
4437
4438 sub get_dir {
4439         my ($self, $dir, $r) = @_;
4440         my $cache = $self->{cache}->{get_dir};
4441         if ($r == $cache->{r}) {
4442                 if (my $x = $cache->{data}->{$dir}) {
4443                         return wantarray ? @$x : $x->[0];
4444                 }
4445         }
4446         my $pool = SVN::Pool->new;
4447         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4448         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4449         $pool->clear;
4450         if ($r != $cache->{r}) {
4451                 %{$cache->{data}} = ();
4452                 $cache->{r} = $r;
4453         }
4454         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4455         wantarray ? (\%dirents, $r, $props) : \%dirents;
4456 }
4457
4458 sub DESTROY {
4459         # do not call the real DESTROY since we store ourselves in $RA
4460 }
4461
4462 # get_log(paths, start, end, limit,
4463 #         discover_changed_paths, strict_node_history, receiver)
4464 sub get_log {
4465         my ($self, @args) = @_;
4466         my $pool = SVN::Pool->new;
4467
4468         # svn_log_changed_path_t objects passed to get_log are likely to be
4469         # overwritten even if only the refs are copied to an external variable,
4470         # so we should dup the structures in their entirety.  Using an
4471         # externally passed pool (instead of our temporary and quickly cleared
4472         # pool in Git::SVN::Ra) does not help matters at all...
4473         my $receiver = pop @args;
4474         my $prefix = "/".$self->{svn_path};
4475         $prefix =~ s#/+($)##;
4476         my $prefix_regex = qr#^\Q$prefix\E#;
4477         push(@args, sub {
4478                 my ($paths) = $_[0];
4479                 return &$receiver(@_) unless $paths;
4480                 $_[0] = ();
4481                 foreach my $p (keys %$paths) {
4482                         my $i = $paths->{$p};
4483                         # Make path relative to our url, not repos_root
4484                         $p =~ s/$prefix_regex//;
4485                         my %s = map { $_ => $i->$_; }
4486                                 qw/copyfrom_path copyfrom_rev action/;
4487                         if ($s{'copyfrom_path'}) {
4488                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4489                         }
4490                         $_[0]{$p} = \%s;
4491                 }
4492                 &$receiver(@_);
4493         });
4494
4495
4496         # the limit parameter was not supported in SVN 1.1.x, so we
4497         # drop it.  Therefore, the receiver callback passed to it
4498         # is made aware of this limitation by being wrapped if
4499         # the limit passed to is being wrapped.
4500         if ($SVN::Core::VERSION le '1.2.0') {
4501                 my $limit = splice(@args, 3, 1);
4502                 if ($limit > 0) {
4503                         my $receiver = pop @args;
4504                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4505                 }
4506         }
4507         my $ret = $self->SUPER::get_log(@args, $pool);
4508         $pool->clear;
4509         $ret;
4510 }
4511
4512 sub trees_match {
4513         my ($self, $url1, $rev1, $url2, $rev2) = @_;
4514         my $ctx = SVN::Client->new(auth => _auth_providers);
4515         my $out = IO::File->new_tmpfile;
4516
4517         # older SVN (1.1.x) doesn't take $pool as the last parameter for
4518         # $ctx->diff(), so we'll create a default one
4519         my $pool = SVN::Pool->new_default_sub;
4520
4521         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4522         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4523         $out->flush;
4524         my $ret = (($out->stat)[7] == 0);
4525         close $out or croak $!;
4526
4527         $ret;
4528 }
4529
4530 sub get_commit_editor {
4531         my ($self, $log, $cb, $pool) = @_;
4532         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4533         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4534 }
4535
4536 sub gs_do_update {
4537         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4538         my $new = ($rev_a == $rev_b);
4539         my $path = $gs->{path};
4540
4541         if ($new && -e $gs->{index}) {
4542                 unlink $gs->{index} or die
4543                   "Couldn't unlink index: $gs->{index}: $!\n";
4544         }
4545         my $pool = SVN::Pool->new;
4546         $editor->set_path_strip($path);
4547         my (@pc) = split m#/#, $path;
4548         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4549                                         1, $editor, $pool);
4550         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4551
4552         # Since we can't rely on svn_ra_reparent being available, we'll
4553         # just have to do some magic with set_path to make it so
4554         # we only want a partial path.
4555         my $sp = '';
4556         my $final = join('/', @pc);
4557         while (@pc) {
4558                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4559                 $sp .= '/' if length $sp;
4560                 $sp .= shift @pc;
4561         }
4562         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4563
4564         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4565
4566         $reporter->finish_report($pool);
4567         $pool->clear;
4568         $editor->{git_commit_ok};
4569 }
4570
4571 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4572 # svn_ra_reparent didn't work before 1.4)
4573 sub gs_do_switch {
4574         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4575         my $path = $gs->{path};
4576         my $pool = SVN::Pool->new;
4577
4578         my $full_url = $self->{url};
4579         my $old_url = $full_url;
4580         $full_url .= '/' . $path if length $path;
4581         my ($ra, $reparented);
4582
4583         if ($old_url =~ m#^svn(\+ssh)?://# ||
4584             ($full_url =~ m#^https?://# &&
4585              escape_url($full_url) ne $full_url)) {
4586                 $_[0] = undef;
4587                 $self = undef;
4588                 $RA = undef;
4589                 $ra = Git::SVN::Ra->new($full_url);
4590                 $ra_invalid = 1;
4591         } elsif ($old_url ne $full_url) {
4592                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4593                 $self->{url} = $full_url;
4594                 $reparented = 1;
4595         }
4596
4597         $ra ||= $self;
4598         $url_b = escape_url($url_b);
4599         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4600         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4601         $reporter->set_path('', $rev_a, 0, @lock, $pool);
4602         $reporter->finish_report($pool);
4603
4604         if ($reparented) {
4605                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4606                 $self->{url} = $old_url;
4607         }
4608
4609         $pool->clear;
4610         $editor->{git_commit_ok};
4611 }
4612
4613 sub longest_common_path {
4614         my ($gsv, $globs) = @_;
4615         my %common;
4616         my $common_max = scalar @$gsv;
4617
4618         foreach my $gs (@$gsv) {
4619                 my @tmp = split m#/#, $gs->{path};
4620                 my $p = '';
4621                 foreach (@tmp) {
4622                         $p .= length($p) ? "/$_" : $_;
4623                         $common{$p} ||= 0;
4624                         $common{$p}++;
4625                 }
4626         }
4627         $globs ||= [];
4628         $common_max += scalar @$globs;
4629         foreach my $glob (@$globs) {
4630                 my @tmp = split m#/#, $glob->{path}->{left};
4631                 my $p = '';
4632                 foreach (@tmp) {
4633                         $p .= length($p) ? "/$_" : $_;
4634                         $common{$p} ||= 0;
4635                         $common{$p}++;
4636                 }
4637         }
4638
4639         my $longest_path = '';
4640         foreach (sort {length $b <=> length $a} keys %common) {
4641                 if ($common{$_} == $common_max) {
4642                         $longest_path = $_;
4643                         last;
4644                 }
4645         }
4646         $longest_path;
4647 }
4648
4649 sub gs_fetch_loop_common {
4650         my ($self, $base, $head, $gsv, $globs) = @_;
4651         return if ($base > $head);
4652         my $inc = $_log_window_size;
4653         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4654         my $longest_path = longest_common_path($gsv, $globs);
4655         my $ra_url = $self->{url};
4656         my $find_trailing_edge;
4657         while (1) {
4658                 my %revs;
4659                 my $err;
4660                 my $err_handler = $SVN::Error::handler;
4661                 $SVN::Error::handler = sub {
4662                         ($err) = @_;
4663                         skip_unknown_revs($err);
4664                 };
4665                 sub _cb {
4666                         my ($paths, $r, $author, $date, $log) = @_;
4667                         [ $paths,
4668                           { author => $author, date => $date, log => $log } ];
4669                 }
4670                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4671                                sub { $revs{$_[1]} = _cb(@_) });
4672                 if ($err) {
4673                         print "Checked through r$max\r";
4674                 } else {
4675                         $find_trailing_edge = 1;
4676                 }
4677                 if ($err and $find_trailing_edge) {
4678                         print STDERR "Path '$longest_path' ",
4679                                      "was probably deleted:\n",
4680                                      $err->expanded_message,
4681                                      "\nWill attempt to follow ",
4682                                      "revisions r$min .. r$max ",
4683                                      "committed before the deletion\n";
4684                         my $hi = $max;
4685                         while (--$hi >= $min) {
4686                                 my $ok;
4687                                 $self->get_log([$longest_path], $min, $hi,
4688                                                0, 1, 1, sub {
4689                                                $ok = $_[1];
4690                                                $revs{$_[1]} = _cb(@_) });
4691                                 if ($ok) {
4692                                         print STDERR "r$min .. r$ok OK\n";
4693                                         last;
4694                                 }
4695                         }
4696                         $find_trailing_edge = 0;
4697                 }
4698                 $SVN::Error::handler = $err_handler;
4699
4700                 my %exists = map { $_->{path} => $_ } @$gsv;
4701                 foreach my $r (sort {$a <=> $b} keys %revs) {
4702                         my ($paths, $logged) = @{$revs{$r}};
4703
4704                         foreach my $gs ($self->match_globs(\%exists, $paths,
4705                                                            $globs, $r)) {
4706                                 if ($gs->rev_map_max >= $r) {
4707                                         next;
4708                                 }
4709                                 next unless $gs->match_paths($paths, $r);
4710                                 $gs->{logged_rev_props} = $logged;
4711                                 if (my $last_commit = $gs->last_commit) {
4712                                         $gs->assert_index_clean($last_commit);
4713                                 }
4714                                 my $log_entry = $gs->do_fetch($paths, $r);
4715                                 if ($log_entry) {
4716                                         $gs->do_git_commit($log_entry);
4717                                 }
4718                                 $INDEX_FILES{$gs->{index}} = 1;
4719                         }
4720                         foreach my $g (@$globs) {
4721                                 my $k = "svn-remote.$g->{remote}." .
4722                                         "$g->{t}-maxRev";
4723                                 Git::SVN::tmp_config($k, $r);
4724                         }
4725                         if ($ra_invalid) {
4726                                 $_[0] = undef;
4727                                 $self = undef;
4728                                 $RA = undef;
4729                                 $self = Git::SVN::Ra->new($ra_url);
4730                                 $ra_invalid = undef;
4731                         }
4732                 }
4733                 # pre-fill the .rev_db since it'll eventually get filled in
4734                 # with '0' x40 if something new gets committed
4735                 foreach my $gs (@$gsv) {
4736                         next if $gs->rev_map_max >= $max;
4737                         next if defined $gs->rev_map_get($max);
4738                         $gs->rev_map_set($max, 0 x40);
4739                 }
4740                 foreach my $g (@$globs) {
4741                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4742                         Git::SVN::tmp_config($k, $max);
4743                 }
4744                 last if $max >= $head;
4745                 $min = $max + 1;
4746                 $max += $inc;
4747                 $max = $head if ($max > $head);
4748         }
4749         Git::SVN::gc();
4750 }
4751
4752 sub get_dir_globbed {
4753         my ($self, $left, $depth, $r) = @_;
4754
4755         my @x = eval { $self->get_dir($left, $r) };
4756         return unless scalar @x == 3;
4757         my $dirents = $x[0];
4758         my @finalents;
4759         foreach my $de (keys %$dirents) {
4760                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4761                 if ($depth > 1) {
4762                         my @args = ("$left/$de", $depth - 1, $r);
4763                         foreach my $dir ($self->get_dir_globbed(@args)) {
4764                                 push @finalents, "$de/$dir";
4765                         }
4766                 } else {
4767                         push @finalents, $de;
4768                 }
4769         }
4770         @finalents;
4771 }
4772
4773 sub match_globs {
4774         my ($self, $exists, $paths, $globs, $r) = @_;
4775
4776         sub get_dir_check {
4777                 my ($self, $exists, $g, $r) = @_;
4778
4779                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4780                                                   $g->{path}->{depth},
4781                                                   $r);
4782
4783                 foreach my $de (@dirs) {
4784                         my $p = $g->{path}->full_path($de);
4785                         next if $exists->{$p};
4786                         next if (length $g->{path}->{right} &&
4787                                  ($self->check_path($p, $r) !=
4788                                   $SVN::Node::dir));
4789                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4790                                          $g->{ref}->full_path($de), 1);
4791                 }
4792         }
4793         foreach my $g (@$globs) {
4794                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4795                         if ($path->{action} =~ /^[AR]$/) {
4796                                 get_dir_check($self, $exists, $g, $r);
4797                         }
4798                 }
4799                 foreach (keys %$paths) {
4800                         if (/$g->{path}->{left_regex}/ &&
4801                             !/$g->{path}->{regex}/) {
4802                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4803                                 get_dir_check($self, $exists, $g, $r);
4804                         }
4805                         next unless /$g->{path}->{regex}/;
4806                         my $p = $1;
4807                         my $pathname = $g->{path}->full_path($p);
4808                         next if $exists->{$pathname};
4809                         next if ($self->check_path($pathname, $r) !=
4810                                  $SVN::Node::dir);
4811                         $exists->{$pathname} = Git::SVN->init(
4812                                               $self->{url}, $pathname, undef,
4813                                               $g->{ref}->full_path($p), 1);
4814                 }
4815                 my $c = '';
4816                 foreach (split m#/#, $g->{path}->{left}) {
4817                         $c .= "/$_";
4818                         next unless ($paths->{$c} &&
4819                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4820                         get_dir_check($self, $exists, $g, $r);
4821                 }
4822         }
4823         values %$exists;
4824 }
4825
4826 sub minimize_url {
4827         my ($self) = @_;
4828         return $self->{url} if ($self->{url} eq $self->{repos_root});
4829         my $url = $self->{repos_root};
4830         my @components = split(m!/!, $self->{svn_path});
4831         my $c = '';
4832         do {
4833                 $url .= "/$c" if length $c;
4834                 eval {
4835                         my $ra = (ref $self)->new($url);
4836                         my $latest = $ra->get_latest_revnum;
4837                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
4838                 };
4839         } while ($@ && ($c = shift @components));
4840         $url;
4841 }
4842
4843 sub can_do_switch {
4844         my $self = shift;
4845         unless (defined $can_do_switch) {
4846                 my $pool = SVN::Pool->new;
4847                 my $rep = eval {
4848                         $self->do_switch(1, '', 0, $self->{url},
4849                                          SVN::Delta::Editor->new, $pool);
4850                 };
4851                 if ($@) {
4852                         $can_do_switch = 0;
4853                 } else {
4854                         $rep->abort_report($pool);
4855                         $can_do_switch = 1;
4856                 }
4857                 $pool->clear;
4858         }
4859         $can_do_switch;
4860 }
4861
4862 sub skip_unknown_revs {
4863         my ($err) = @_;
4864         my $errno = $err->apr_err();
4865         # Maybe the branch we're tracking didn't
4866         # exist when the repo started, so it's
4867         # not an error if it doesn't, just continue
4868         #
4869         # Wonderfully consistent library, eh?
4870         # 160013 - svn:// and file://
4871         # 175002 - http(s)://
4872         # 175007 - http(s):// (this repo required authorization, too...)
4873         #   More codes may be discovered later...
4874         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4875                 my $err_key = $err->expanded_message;
4876                 # revision numbers change every time, filter them out
4877                 $err_key =~ s/\d+/\0/g;
4878                 $err_key = "$errno\0$err_key";
4879                 unless ($ignored_err{$err_key}) {
4880                         warn "W: Ignoring error from SVN, path probably ",
4881                              "does not exist: ($errno): ",
4882                              $err->expanded_message,"\n";
4883                         warn "W: Do not be alarmed at the above message ",
4884                              "git-svn is just searching aggressively for ",
4885                              "old history.\n",
4886                              "This may take a while on large repositories\n";
4887                         $ignored_err{$err_key} = 1;
4888                 }
4889                 return;
4890         }
4891         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4892 }
4893
4894 package Git::SVN::Log;
4895 use strict;
4896 use warnings;
4897 use POSIX qw/strftime/;
4898 use Time::Local;
4899 use constant commit_log_separator => ('-' x 72) . "\n";
4900 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4901             %rusers $show_commit $incremental/;
4902 my $l_fmt;
4903
4904 sub cmt_showable {
4905         my ($c) = @_;
4906         return 1 if defined $c->{r};
4907
4908         # big commit message got truncated by the 16k pretty buffer in rev-list
4909         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4910                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4911                 @{$c->{l}} = ();
4912                 my @log = command(qw/cat-file commit/, $c->{c});
4913
4914                 # shift off the headers
4915                 shift @log while ($log[0] ne '');
4916                 shift @log;
4917
4918                 # TODO: make $c->{l} not have a trailing newline in the future
4919                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4920
4921                 (undef, $c->{r}, undef) = ::extract_metadata(
4922                                 (grep(/^git-svn-id: /, @log))[-1]);
4923         }
4924         return defined $c->{r};
4925 }
4926
4927 sub log_use_color {
4928         return $color || Git->repository->get_colorbool('color.diff');
4929 }
4930
4931 sub git_svn_log_cmd {
4932         my ($r_min, $r_max, @args) = @_;
4933         my $head = 'HEAD';
4934         my (@files, @log_opts);
4935         foreach my $x (@args) {
4936                 if ($x eq '--' || @files) {
4937                         push @files, $x;
4938                 } else {
4939                         if (::verify_ref("$x^0")) {
4940                                 $head = $x;
4941                         } else {
4942                                 push @log_opts, $x;
4943                         }
4944                 }
4945         }
4946
4947         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4948         $gs ||= Git::SVN->_new;
4949         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4950                    $gs->refname);
4951         push @cmd, '-r' unless $non_recursive;
4952         push @cmd, qw/--raw --name-status/ if $verbose;
4953         push @cmd, '--color' if log_use_color();
4954         push @cmd, @log_opts;
4955         if (defined $r_max && $r_max == $r_min) {
4956                 push @cmd, '--max-count=1';
4957                 if (my $c = $gs->rev_map_get($r_max)) {
4958                         push @cmd, $c;
4959                 }
4960         } elsif (defined $r_max) {
4961                 if ($r_max < $r_min) {
4962                         ($r_min, $r_max) = ($r_max, $r_min);
4963                 }
4964                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4965                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4966                 # If there are no commits in the range, both $c_max and $c_min
4967                 # will be undefined.  If there is at least 1 commit in the
4968                 # range, both will be defined.
4969                 return () if !defined $c_min || !defined $c_max;
4970                 if ($c_min eq $c_max) {
4971                         push @cmd, '--max-count=1', $c_min;
4972                 } else {
4973                         push @cmd, '--boundary', "$c_min..$c_max";
4974                 }
4975         }
4976         return (@cmd, @files);
4977 }
4978
4979 # adapted from pager.c
4980 sub config_pager {
4981         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4982         if (!defined $pager) {
4983                 $pager = 'less';
4984         } elsif (length $pager == 0 || $pager eq 'cat') {
4985                 $pager = undef;
4986         }
4987         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4988 }
4989
4990 sub run_pager {
4991         return unless -t *STDOUT && defined $pager;
4992         pipe my ($rfd, $wfd) or return;
4993         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4994         if (!$pid) {
4995                 open STDOUT, '>&', $wfd or
4996                                      ::fatal "Can't redirect to stdout: $!";
4997                 return;
4998         }
4999         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5000         $ENV{LESS} ||= 'FRSX';
5001         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5002 }
5003
5004 sub format_svn_date {
5005         # some systmes don't handle or mishandle %z, so be creative.
5006         my $t = shift || time;
5007         my $gm = timelocal(gmtime($t));
5008         my $sign = qw( + + - )[ $t <=> $gm ];
5009         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5010         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5011 }
5012
5013 sub parse_git_date {
5014         my ($t, $tz) = @_;
5015         # Date::Parse isn't in the standard Perl distro :(
5016         if ($tz =~ s/^\+//) {
5017                 $t += tz_to_s_offset($tz);
5018         } elsif ($tz =~ s/^\-//) {
5019                 $t -= tz_to_s_offset($tz);
5020         }
5021         return $t;
5022 }
5023
5024 sub set_local_timezone {
5025         if (defined $TZ) {
5026                 $ENV{TZ} = $TZ;
5027         } else {
5028                 delete $ENV{TZ};
5029         }
5030 }
5031
5032 sub tz_to_s_offset {
5033         my ($tz) = @_;
5034         $tz =~ s/(\d\d)$//;
5035         return ($1 * 60) + ($tz * 3600);
5036 }
5037
5038 sub get_author_info {
5039         my ($dest, $author, $t, $tz) = @_;
5040         $author =~ s/(?:^\s*|\s*$)//g;
5041         $dest->{a_raw} = $author;
5042         my $au;
5043         if ($::_authors) {
5044                 $au = $rusers{$author} || undef;
5045         }
5046         if (!$au) {
5047                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5048         }
5049         $dest->{t} = $t;
5050         $dest->{tz} = $tz;
5051         $dest->{a} = $au;
5052         $dest->{t_utc} = parse_git_date($t, $tz);
5053 }
5054
5055 sub process_commit {
5056         my ($c, $r_min, $r_max, $defer) = @_;
5057         if (defined $r_min && defined $r_max) {
5058                 if ($r_min == $c->{r} && $r_min == $r_max) {
5059                         show_commit($c);
5060                         return 0;
5061                 }
5062                 return 1 if $r_min == $r_max;
5063                 if ($r_min < $r_max) {
5064                         # we need to reverse the print order
5065                         return 0 if (defined $limit && --$limit < 0);
5066                         push @$defer, $c;
5067                         return 1;
5068                 }
5069                 if ($r_min != $r_max) {
5070                         return 1 if ($r_min < $c->{r});
5071                         return 1 if ($r_max > $c->{r});
5072                 }
5073         }
5074         return 0 if (defined $limit && --$limit < 0);
5075         show_commit($c);
5076         return 1;
5077 }
5078
5079 sub show_commit {
5080         my $c = shift;
5081         if ($oneline) {
5082                 my $x = "\n";
5083                 if (my $l = $c->{l}) {
5084                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5085                         $x = $l->[0];
5086                 }
5087                 $l_fmt ||= 'A' . length($c->{r});
5088                 print 'r',pack($l_fmt, $c->{r}),' | ';
5089                 print "$c->{c} | " if $show_commit;
5090                 print $x;
5091         } else {
5092                 show_commit_normal($c);
5093         }
5094 }
5095
5096 sub show_commit_changed_paths {
5097         my ($c) = @_;
5098         return unless $c->{changed};
5099         print "Changed paths:\n", @{$c->{changed}};
5100 }
5101
5102 sub show_commit_normal {
5103         my ($c) = @_;
5104         print commit_log_separator, "r$c->{r} | ";
5105         print "$c->{c} | " if $show_commit;
5106         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5107         my $nr_line = 0;
5108
5109         if (my $l = $c->{l}) {
5110                 while ($l->[$#$l] eq "\n" && $#$l > 0
5111                                           && $l->[($#$l - 1)] eq "\n") {
5112                         pop @$l;
5113                 }
5114                 $nr_line = scalar @$l;
5115                 if (!$nr_line) {
5116                         print "1 line\n\n\n";
5117                 } else {
5118                         if ($nr_line == 1) {
5119                                 $nr_line = '1 line';
5120                         } else {
5121                                 $nr_line .= ' lines';
5122                         }
5123                         print $nr_line, "\n";
5124                         show_commit_changed_paths($c);
5125                         print "\n";
5126                         print $_ foreach @$l;
5127                 }
5128         } else {
5129                 print "1 line\n";
5130                 show_commit_changed_paths($c);
5131                 print "\n";
5132
5133         }
5134         foreach my $x (qw/raw stat diff/) {
5135                 if ($c->{$x}) {
5136                         print "\n";
5137                         print $_ foreach @{$c->{$x}}
5138                 }
5139         }
5140 }
5141
5142 sub cmd_show_log {
5143         my (@args) = @_;
5144         my ($r_min, $r_max);
5145         my $r_last = -1; # prevent dupes
5146         set_local_timezone();
5147         if (defined $::_revision) {
5148                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5149                         ($r_min, $r_max) = ($1, $2);
5150                 } elsif ($::_revision =~ /^\d+$/) {
5151                         $r_min = $r_max = $::_revision;
5152                 } else {
5153                         ::fatal "-r$::_revision is not supported, use ",
5154                                 "standard 'git log' arguments instead";
5155                 }
5156         }
5157
5158         config_pager();
5159         @args = git_svn_log_cmd($r_min, $r_max, @args);
5160         if (!@args) {
5161                 print commit_log_separator unless $incremental || $oneline;
5162                 return;
5163         }
5164         my $log = command_output_pipe(@args);
5165         run_pager();
5166         my (@k, $c, $d, $stat);
5167         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5168         while (<$log>) {
5169                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5170                         my $cmt = $1;
5171                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5172                                 $r_last = $c->{r};
5173                                 process_commit($c, $r_min, $r_max, \@k) or
5174                                                                 goto out;
5175                         }
5176                         $d = undef;
5177                         $c = { c => $cmt };
5178                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5179                         get_author_info($c, $1, $2, $3);
5180                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5181                         # ignore
5182                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5183                         push @{$c->{raw}}, $_;
5184                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5185                         # we could add $SVN->{svn_path} here, but that requires
5186                         # remote access at the moment (repo_path_split)...
5187                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5188                         push @{$c->{changed}}, $_;
5189                 } elsif (/^${esc_color}diff /o) {
5190                         $d = 1;
5191                         push @{$c->{diff}}, $_;
5192                 } elsif ($d) {
5193                         push @{$c->{diff}}, $_;
5194                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5195                           $esc_color*[\+\-]*$esc_color$/x) {
5196                         $stat = 1;
5197                         push @{$c->{stat}}, $_;
5198                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5199                         push @{$c->{stat}}, $_;
5200                         $stat = undef;
5201                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5202                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5203                 } elsif (s/^${esc_color}    //o) {
5204                         push @{$c->{l}}, $_;
5205                 }
5206         }
5207         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5208                 $r_last = $c->{r};
5209                 process_commit($c, $r_min, $r_max, \@k);
5210         }
5211         if (@k) {
5212                 ($r_min, $r_max) = ($r_max, $r_min);
5213                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5214         }
5215 out:
5216         close $log;
5217         print commit_log_separator unless $incremental || $oneline;
5218 }
5219
5220 sub cmd_blame {
5221         my $path = pop;
5222
5223         config_pager();
5224         run_pager();
5225
5226         my ($fh, $ctx, $rev);
5227
5228         if ($_git_format) {
5229                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5230                 while (my $line = <$fh>) {
5231                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5232                                 # Uncommitted edits show up as a rev ID of
5233                                 # all zeros, which we can't look up with
5234                                 # cmt_metadata
5235                                 if ($1 !~ /^0+$/) {
5236                                         (undef, $rev, undef) =
5237                                                 ::cmt_metadata($1);
5238                                         $rev = '0' if (!$rev);
5239                                 } else {
5240                                         $rev = '0';
5241                                 }
5242                                 $rev = sprintf('%-10s', $rev);
5243                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5244                         }
5245                         print $line;
5246                 }
5247         } else {
5248                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5249                                                   '--', $path);
5250                 my ($sha1);
5251                 my %authors;
5252                 my @buffer;
5253                 my %dsha; #distinct sha keys
5254
5255                 while (my $line = <$fh>) {
5256                         push @buffer, $line;
5257                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5258                                 $dsha{$1} = 1;
5259                         }
5260                 }
5261
5262                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5263
5264                 foreach my $line (@buffer) {
5265                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5266                                 $rev = $s2r->{$1};
5267                                 $rev = '0' if (!$rev)
5268                         }
5269                         elsif ($line =~ /^author (.*)/) {
5270                                 $authors{$rev} = $1;
5271                                 $authors{$rev} =~ s/\s/_/g;
5272                         }
5273                         elsif ($line =~ /^\t(.*)$/) {
5274                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5275                         }
5276                 }
5277         }
5278         command_close_pipe($fh, $ctx);
5279 }
5280
5281 package Git::SVN::Migration;
5282 # these version numbers do NOT correspond to actual version numbers
5283 # of git nor git-svn.  They are just relative.
5284 #
5285 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5286 #
5287 # v1 layout: .git/$id/info/url, refs/remotes/$id
5288 #
5289 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5290 #
5291 # v3 layout: .git/svn/$id, refs/remotes/$id
5292 #            - info/url may remain for backwards compatibility
5293 #            - this is what we migrate up to this layout automatically,
5294 #            - this will be used by git svn init on single branches
5295 # v3.1 layout (auto migrated):
5296 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5297 #              for backwards compatibility
5298 #
5299 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5300 #            - this is only created for newly multi-init-ed
5301 #              repositories.  Similar in spirit to the
5302 #              --use-separate-remotes option in git-clone (now default)
5303 #            - we do not automatically migrate to this (following
5304 #              the example set by core git)
5305 #
5306 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5307 #            - newer, more-efficient format that uses 24-bytes per record
5308 #              with no filler space.
5309 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5310 #            - This is a one-way migration, repositories updated to the
5311 #              new format will not be able to use old git-svn without
5312 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5313 #              possible if noMetadata or useSvmProps are set; but should
5314 #              be no problem for users that use the (sensible) defaults.
5315 use strict;
5316 use warnings;
5317 use Carp qw/croak/;
5318 use File::Path qw/mkpath/;
5319 use File::Basename qw/dirname basename/;
5320 use vars qw/$_minimize/;
5321
5322 sub migrate_from_v0 {
5323         my $git_dir = $ENV{GIT_DIR};
5324         return undef unless -d $git_dir;
5325         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5326         my $migrated = 0;
5327         while (<$fh>) {
5328                 chomp;
5329                 my ($id, $orig_ref) = ($_, $_);
5330                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5331                 next unless -f "$git_dir/$id/info/url";
5332                 my $new_ref = "refs/remotes/$id";
5333                 if (::verify_ref("$new_ref^0")) {
5334                         print STDERR "W: $orig_ref is probably an old ",
5335                                      "branch used by an ancient version of ",
5336                                      "git-svn.\n",
5337                                      "However, $new_ref also exists.\n",
5338                                      "We will not be able ",
5339                                      "to use this branch until this ",
5340                                      "ambiguity is resolved.\n";
5341                         next;
5342                 }
5343                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5344                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5345                 command_noisy('update-ref', $new_ref, $orig_ref);
5346                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5347                 $migrated++;
5348         }
5349         command_close_pipe($fh, $ctx);
5350         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5351         $migrated;
5352 }
5353
5354 sub migrate_from_v1 {
5355         my $git_dir = $ENV{GIT_DIR};
5356         my $migrated = 0;
5357         return $migrated unless -d $git_dir;
5358         my $svn_dir = "$git_dir/svn";
5359
5360         # just in case somebody used 'svn' as their $id at some point...
5361         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5362
5363         print STDERR "Migrating from a git-svn v1 layout...\n";
5364         mkpath([$svn_dir]);
5365         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5366                      "$svn_dir\n\t(required for this version ",
5367                      "($::VERSION) of git-svn) does not exist.\n";
5368         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5369         while (<$fh>) {
5370                 my $x = $_;
5371                 next unless $x =~ s#^refs/remotes/##;
5372                 chomp $x;
5373                 next unless -f "$git_dir/$x/info/url";
5374                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5375                 next unless $u;
5376                 my $dn = dirname("$git_dir/svn/$x");
5377                 mkpath([$dn]) unless -d $dn;
5378                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5379                         mkpath(["$git_dir/svn/svn"]);
5380                         print STDERR " - $git_dir/$x/info => ",
5381                                         "$git_dir/svn/$x/info\n";
5382                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5383                                croak "$!: $x";
5384                         # don't worry too much about these, they probably
5385                         # don't exist with repos this old (save for index,
5386                         # and we can easily regenerate that)
5387                         foreach my $f (qw/unhandled.log index .rev_db/) {
5388                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5389                         }
5390                 } else {
5391                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5392                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5393                                croak "$!: $x";
5394                 }
5395                 $migrated++;
5396         }
5397         command_close_pipe($fh, $ctx);
5398         print STDERR "Done migrating from a git-svn v1 layout\n";
5399         $migrated;
5400 }
5401
5402 sub read_old_urls {
5403         my ($l_map, $pfx, $path) = @_;
5404         my @dir;
5405         foreach (<$path/*>) {
5406                 if (-r "$_/info/url") {
5407                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5408                         my $ref_id = $pfx . basename $_;
5409                         my $url = ::file_to_s("$_/info/url");
5410                         $l_map->{$ref_id} = $url;
5411                 } elsif (-d $_) {
5412                         push @dir, $_;
5413                 }
5414         }
5415         foreach (@dir) {
5416                 my $x = $_;
5417                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5418                 read_old_urls($l_map, $x, $_);
5419         }
5420 }
5421
5422 sub migrate_from_v2 {
5423         my @cfg = command(qw/config -l/);
5424         return if grep /^svn-remote\..+\.url=/, @cfg;
5425         my %l_map;
5426         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5427         my $migrated = 0;
5428
5429         foreach my $ref_id (sort keys %l_map) {
5430                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5431                 if ($@) {
5432                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5433                 }
5434                 $migrated++;
5435         }
5436         $migrated;
5437 }
5438
5439 sub minimize_connections {
5440         my $r = Git::SVN::read_all_remotes();
5441         my $new_urls = {};
5442         my $root_repos = {};
5443         foreach my $repo_id (keys %$r) {
5444                 my $url = $r->{$repo_id}->{url} or next;
5445                 my $fetch = $r->{$repo_id}->{fetch} or next;
5446                 my $ra = Git::SVN::Ra->new($url);
5447
5448                 # skip existing cases where we already connect to the root
5449                 if (($ra->{url} eq $ra->{repos_root}) ||
5450                     ($ra->{repos_root} eq $repo_id)) {
5451                         $root_repos->{$ra->{url}} = $repo_id;
5452                         next;
5453                 }
5454
5455                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5456                 my $root_path = $ra->{url};
5457                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5458                 foreach my $path (keys %$fetch) {
5459                         my $ref_id = $fetch->{$path};
5460                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5461
5462                         # make sure we can read when connecting to
5463                         # a higher level of a repository
5464                         my ($last_rev, undef) = $gs->last_rev_commit;
5465                         if (!defined $last_rev) {
5466                                 $last_rev = eval {
5467                                         $root_ra->get_latest_revnum;
5468                                 };
5469                                 next if $@;
5470                         }
5471                         my $new = $root_path;
5472                         $new .= length $path ? "/$path" : '';
5473                         eval {
5474                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5475                                                   0, 0, 1, sub { });
5476                         };
5477                         next if $@;
5478                         $new_urls->{$ra->{repos_root}}->{$new} =
5479                                 { ref_id => $ref_id,
5480                                   old_repo_id => $repo_id,
5481                                   old_path => $path };
5482                 }
5483         }
5484
5485         my @emptied;
5486         foreach my $url (keys %$new_urls) {
5487                 # see if we can re-use an existing [svn-remote "repo_id"]
5488                 # instead of creating a(n ugly) new section:
5489                 my $repo_id = $root_repos->{$url} || $url;
5490
5491                 my $fetch = $new_urls->{$url};
5492                 foreach my $path (keys %$fetch) {
5493                         my $x = $fetch->{$path};
5494                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5495                         my $pfx = "svn-remote.$x->{old_repo_id}";
5496
5497                         my $old_fetch = quotemeta("$x->{old_path}:".
5498                                                   "refs/remotes/$x->{ref_id}");
5499                         command_noisy(qw/config --unset/,
5500                                       "$pfx.fetch", '^'. $old_fetch . '$');
5501                         delete $r->{$x->{old_repo_id}}->
5502                                {fetch}->{$x->{old_path}};
5503                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5504                                 command_noisy(qw/config --unset/,
5505                                               "$pfx.url");
5506                                 push @emptied, $x->{old_repo_id}
5507                         }
5508                 }
5509         }
5510         if (@emptied) {
5511                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5512                 print STDERR <<EOF;
5513 The following [svn-remote] sections in your config file ($file) are empty
5514 and can be safely removed:
5515 EOF
5516                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5517         }
5518 }
5519
5520 sub migration_check {
5521         migrate_from_v0();
5522         migrate_from_v1();
5523         migrate_from_v2();
5524         minimize_connections() if $_minimize;
5525 }
5526
5527 package Git::IndexInfo;
5528 use strict;
5529 use warnings;
5530 use Git qw/command_input_pipe command_close_pipe/;
5531
5532 sub new {
5533         my ($class) = @_;
5534         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5535         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5536 }
5537
5538 sub remove {
5539         my ($self, $path) = @_;
5540         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5541                 return ++$self->{nr};
5542         }
5543         undef;
5544 }
5545
5546 sub update {
5547         my ($self, $mode, $hash, $path) = @_;
5548         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5549                 return ++$self->{nr};
5550         }
5551         undef;
5552 }
5553
5554 sub DESTROY {
5555         my ($self) = @_;
5556         command_close_pipe($self->{gui}, $self->{ctx});
5557 }
5558
5559 package Git::SVN::GlobSpec;
5560 use strict;
5561 use warnings;
5562
5563 sub new {
5564         my ($class, $glob) = @_;
5565         my $re = $glob;
5566         $re =~ s!/+$!!g; # no need for trailing slashes
5567         $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5568         my $temp = $re;
5569         my ($left, $right) = ($1, $3);
5570         $re = $2;
5571         my $depth = $re =~ tr/*/*/;
5572         if ($depth != $temp =~ tr/*/*/) {
5573                 die "Only one set of wildcard directories " .
5574                         "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5575         }
5576         if ($depth == 0) {
5577                 die "One '*' is needed for glob: '$glob'\n";
5578         }
5579         $re =~ s!\*!\[^/\]*!g;
5580         $re = quotemeta($left) . "($re)" . quotemeta($right);
5581         if (length $left && !($left =~ s!/+$!!g)) {
5582                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5583         }
5584         if (length $right && !($right =~ s!^/+!!g)) {
5585                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5586         }
5587         my $left_re = qr/^\/\Q$left\E(\/|$)/;
5588         bless { left => $left, right => $right, left_regex => $left_re,
5589                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5590 }
5591
5592 sub full_path {
5593         my ($self, $path) = @_;
5594         return (length $self->{left} ? "$self->{left}/" : '') .
5595                $path . (length $self->{right} ? "/$self->{right}" : '');
5596 }
5597
5598 __END__
5599
5600 Data structures:
5601
5602
5603 $remotes = { # returned by read_all_remotes()
5604         'svn' => {
5605                 # svn-remote.svn.url=https://svn.musicpd.org
5606                 url => 'https://svn.musicpd.org',
5607                 # svn-remote.svn.fetch=mpd/trunk:trunk
5608                 fetch => {
5609                         'mpd/trunk' => 'trunk',
5610                 },
5611                 # svn-remote.svn.tags=mpd/tags/*:tags/*
5612                 tags => {
5613                         path => {
5614                                 left => 'mpd/tags',
5615                                 right => '',
5616                                 regex => qr!mpd/tags/([^/]+)$!,
5617                                 glob => 'tags/*',
5618                         },
5619                         ref => {
5620                                 left => 'tags',
5621                                 right => '',
5622                                 regex => qr!tags/([^/]+)$!,
5623                                 glob => 'tags/*',
5624                         },
5625                 }
5626         }
5627 };
5628
5629 $log_entry hashref as returned by libsvn_log_entry()
5630 {
5631         log => 'whitespace-formatted log entry
5632 ',                                              # trailing newline is preserved
5633         revision => '8',                        # integer
5634         date => '2004-02-24T17:01:44.108345Z',  # commit date
5635         author => 'committer name'
5636 };
5637
5638
5639 # this is generated by generate_diff();
5640 @mods = array of diff-index line hashes, each element represents one line
5641         of diff-index output
5642
5643 diff-index line ($m hash)
5644 {
5645         mode_a => first column of diff-index output, no leading ':',
5646         mode_b => second column of diff-index output,
5647         sha1_b => sha1sum of the final blob,
5648         chg => change type [MCRADT],
5649         file_a => original file name of a file (iff chg is 'C' or 'R')
5650         file_b => new/current file name of a file (any chg)
5651 }
5652 ;
5653
5654 # retval of read_url_paths{,_all}();
5655 $l_map = {
5656         # repository root url
5657         'https://svn.musicpd.org' => {
5658                 # repository path               # GIT_SVN_ID
5659                 'mpd/trunk'             =>      'trunk',
5660                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5661         },
5662 }
5663
5664 Notes:
5665         I don't trust the each() function on unless I created %hash myself
5666         because the internal iterator may not have started at base.