git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 # Verify the user input
 464
 465 foreach my $entry (@initial_to) {
 466         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 467 }
 468
 469 foreach my $entry (@initial_cc) {
 470         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 471 }
 472
 473 foreach my $entry (@bcclist) {
 474         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 475 }
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return split_addrs($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490 my %parse_alias = (
 491         # multiline formats can be supported in the future
 492         mutt => sub { my $fh = shift; while (<$fh>) {
 493                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 494                         my ($alias, $addr) = ($1, $2);
 495                         $addr =~ s/#.*$//; # mutt allows # comments
 496                          # commas delimit multiple addresses
 497                         $aliases{$alias} = [ split_addrs($addr) ];
 498                 }}},
 499         mailrc => sub { my $fh = shift; while (<$fh>) {
 500                 if (/^alias\s+(\S+)\s+(.*)$/) {
 501                         # spaces delimit multiple addresses
 502                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 503                 }}},
 504         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 505                 for (my $x = ''; defined($x); $x = $_) {
 506                         chomp $x;
 507                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 508                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 509                         $aliases{$1} = [ split_addrs($2) ];
 510                 }},
 511         elm => sub  { my $fh = shift;
 512                       while (<$fh>) {
 513                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 514                               my ($alias, $addr) = ($1, $2);
 515                                $aliases{$alias} = [ split_addrs($addr) ];
 516                           }
 517                       } },
 518
 519         sendmail => sub { my $fh = shift; while (<$fh>) {
 520                 if (/^\s*(?:#.*)?$/) {
 521                 } elsif (/"/) {
 522                         print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 523                 } elsif (/^\s|\\$/) {
 524                         print STDERR "warning: sendmail continuation line is not supported: $_\n";
 525                 } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 526                         my ($alias, $addr) = ($1, $2);
 527                         $aliases{$alias} = [ split_addrs($addr) ];
 528                 } else {
 529                         print STDERR "warning: sendmail line is not recognized: $_\n";
 530                 }}},
 531
 532         gnus => sub { my $fh = shift; while (<$fh>) {
 533                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 534                         $aliases{$1} = [ $2 ];
 535                 }}}
 536 );
 537
 538 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 539         foreach my $file (@alias_files) {
 540                 open my $fh, '<', $file or die "opening $file: $!\n";
 541                 $parse_alias{$aliasfiletype}->($fh);
 542                 close $fh;
 543         }
 544 }
 545
 546 ($sender) = expand_aliases($sender) if defined $sender;
 547
 548 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 549 # $f is a revision list specification to be passed to format-patch.
 550 sub is_format_patch_arg {
 551         return unless $repo;
 552         my $f = shift;
 553         try {
 554                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 555                 if (defined($format_patch)) {
 556                         return $format_patch;
 557                 }
 558                 die(<<EOF);
 559 File '$f' exists but it could also be the range of commits
 560 to produce patches for.  Please disambiguate by...
 561
 562     * Saying "./$f" if you mean a file; or
 563     * Giving --format-patch option if you mean a range.
 564 EOF
 565         } catch Git::Error::Command with {
 566                 # Not a valid revision.  Treat it as a filename.
 567                 return 0;
 568         }
 569 }
 570
 571 # Now that all the defaults are set, process the rest of the command line
 572 # arguments and collect up the files that need to be processed.
 573 my @rev_list_opts;
 574 while (defined(my $f = shift @ARGV)) {
 575         if ($f eq "--") {
 576                 push @rev_list_opts, "--", @ARGV;
 577                 @ARGV = ();
 578         } elsif (-d $f and !is_format_patch_arg($f)) {
 579                 opendir my $dh, $f
 580                         or die "Failed to opendir $f: $!";
 581
 582                 push @files, grep { -f $_ } map { catfile($f, $_) }
 583                                 sort readdir $dh;
 584                 closedir $dh;
 585         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 586                 push @files, $f;
 587         } else {
 588                 push @rev_list_opts, $f;
 589         }
 590 }
 591
 592 if (@rev_list_opts) {
 593         die "Cannot run git format-patch from outside a repository\n"
 594                 unless $repo;
 595         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 596 }
 597
 598 if ($validate) {
 599         foreach my $f (@files) {
 600                 unless (-p $f) {
 601                         my $error = validate_patch($f);
 602                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 603                 }
 604         }
 605 }
 606
 607 if (@files) {
 608         unless ($quiet) {
 609                 print $_,"\n" for (@files);
 610         }
 611 } else {
 612         print STDERR "\nNo patch files specified!\n\n";
 613         usage();
 614 }
 615
 616 sub get_patch_subject {
 617         my $fn = shift;
 618         open (my $fh, '<', $fn);
 619         while (my $line = <$fh>) {
 620                 next unless ($line =~ /^Subject: (.*)$/);
 621                 close $fh;
 622                 return "GIT: $1\n";
 623         }
 624         close $fh;
 625         die "No subject line in $fn ?";
 626 }
 627
 628 if ($compose) {
 629         # Note that this does not need to be secure, but we will make a small
 630         # effort to have it be unique
 631         $compose_filename = ($repo ?
 632                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 633                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 634         open my $c, ">", $compose_filename
 635                 or die "Failed to open for writing $compose_filename: $!";
 636
 637
 638         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 639         my $tpl_subject = $initial_subject || '';
 640         my $tpl_reply_to = $initial_reply_to || '';
 641
 642         print $c <<EOT;
 643 From $tpl_sender # This line is ignored.
 644 GIT: Lines beginning in "GIT:" will be removed.
 645 GIT: Consider including an overall diffstat or table of contents
 646 GIT: for the patch you are writing.
 647 GIT:
 648 GIT: Clear the body content if you don't wish to send a summary.
 649 From: $tpl_sender
 650 Subject: $tpl_subject
 651 In-Reply-To: $tpl_reply_to
 652
 653 EOT
 654         for my $f (@files) {
 655                 print $c get_patch_subject($f);
 656         }
 657         close $c;
 658
 659         if ($annotate) {
 660                 do_edit($compose_filename, @files);
 661         } else {
 662                 do_edit($compose_filename);
 663         }
 664
 665         open my $c2, ">", $compose_filename . ".final"
 666                 or die "Failed to open $compose_filename.final : " . $!;
 667
 668         open $c, "<", $compose_filename
 669                 or die "Failed to open $compose_filename : " . $!;
 670
 671         my $need_8bit_cte = file_has_nonascii($compose_filename);
 672         my $in_body = 0;
 673         my $summary_empty = 1;
 674         if (!defined $compose_encoding) {
 675                 $compose_encoding = "UTF-8";
 676         }
 677         while(<$c>) {
 678                 next if m/^GIT:/;
 679                 if ($in_body) {
 680                         $summary_empty = 0 unless (/^\n$/);
 681                 } elsif (/^\n$/) {
 682                         $in_body = 1;
 683                         if ($need_8bit_cte) {
 684                                 print $c2 "MIME-Version: 1.0\n",
 685                                          "Content-Type: text/plain; ",
 686                                            "charset=$compose_encoding\n",
 687                                          "Content-Transfer-Encoding: 8bit\n";
 688                         }
 689                 } elsif (/^MIME-Version:/i) {
 690                         $need_8bit_cte = 0;
 691                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 692                         $initial_subject = $1;
 693                         my $subject = $initial_subject;
 694                         $_ = "Subject: " .
 695                                 quote_subject($subject, $compose_encoding) .
 696                                 "\n";
 697                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 698                         $initial_reply_to = $1;
 699                         next;
 700                 } elsif (/^From:\s*(.+)\s*$/i) {
 701                         $sender = $1;
 702                         next;
 703                 } elsif (/^(?:To|Cc|Bcc):/i) {
 704                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 705                         next;
 706                 }
 707                 print $c2 $_;
 708         }
 709         close $c;
 710         close $c2;
 711
 712         if ($summary_empty) {
 713                 print "Summary email is empty, skipping it\n";
 714                 $compose = -1;
 715         }
 716 } elsif ($annotate) {
 717         do_edit(@files);
 718 }
 719
 720 sub ask {
 721         my ($prompt, %arg) = @_;
 722         my $valid_re = $arg{valid_re};
 723         my $default = $arg{default};
 724         my $confirm_only = $arg{confirm_only};
 725         my $resp;
 726         my $i = 0;
 727         return defined $default ? $default : undef
 728                 unless defined $term->IN and defined fileno($term->IN) and
 729                        defined $term->OUT and defined fileno($term->OUT);
 730         while ($i++ < 10) {
 731                 $resp = $term->readline($prompt);
 732                 if (!defined $resp) { # EOF
 733                         print "\n";
 734                         return defined $default ? $default : undef;
 735                 }
 736                 if ($resp eq '' and defined $default) {
 737                         return $default;
 738                 }
 739                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 740                         return $resp;
 741                 }
 742                 if ($confirm_only) {
 743                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 744                         if (defined $yesno && $yesno =~ /y/i) {
 745                                 return $resp;
 746                         }
 747                 }
 748         }
 749         return;
 750 }
 751
 752 my %broken_encoding;
 753
 754 sub file_declares_8bit_cte {
 755         my $fn = shift;
 756         open (my $fh, '<', $fn);
 757         while (my $line = <$fh>) {
 758                 last if ($line =~ /^$/);
 759                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 760         }
 761         close $fh;
 762         return 0;
 763 }
 764
 765 foreach my $f (@files) {
 766         next unless (body_or_subject_has_nonascii($f)
 767                      && !file_declares_8bit_cte($f));
 768         $broken_encoding{$f} = 1;
 769 }
 770
 771 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 772         print "The following files are 8bit, but do not declare " .
 773                 "a Content-Transfer-Encoding.\n";
 774         foreach my $f (sort keys %broken_encoding) {
 775                 print "    $f\n";
 776         }
 777         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 778                                   valid_re => qr/.{4}/, confirm_only => 1,
 779                                   default => "UTF-8");
 780 }
 781
 782 if (!$force) {
 783         for my $f (@files) {
 784                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 785                         die "Refusing to send because the patch\n\t$f\n"
 786                                 . "has the template subject '*** SUBJECT HERE ***'. "
 787                                 . "Pass --force if you really want to send.\n";
 788                 }
 789         }
 790 }
 791
 792 if (!defined $sender) {
 793         $sender = $repoauthor || $repocommitter || '';
 794 }
 795
 796 # $sender could be an already sanitized address
 797 # (e.g. sendemail.from could be manually sanitized by user).
 798 # But it's a no-op to run sanitize_address on an already sanitized address.
 799 $sender = sanitize_address($sender);
 800
 801 my $prompting = 0;
 802 if (!@initial_to && !defined $to_cmd) {
 803         my $to = ask("Who should the emails be sent to (if any)? ",
 804                      default => "",
 805                      valid_re => qr/\@.*\./, confirm_only => 1);
 806         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 807         $prompting++;
 808 }
 809
 810 sub expand_aliases {
 811         return map { expand_one_alias($_) } @_;
 812 }
 813
 814 my %EXPANDED_ALIASES;
 815 sub expand_one_alias {
 816         my $alias = shift;
 817         if ($EXPANDED_ALIASES{$alias}) {
 818                 die "fatal: alias '$alias' expands to itself\n";
 819         }
 820         local $EXPANDED_ALIASES{$alias} = 1;
 821         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 822 }
 823
 824 @initial_to = expand_aliases(@initial_to);
 825 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 826 @initial_cc = expand_aliases(@initial_cc);
 827 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 828 @bcclist = expand_aliases(@bcclist);
 829 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 830
 831 if ($thread && !defined $initial_reply_to && $prompting) {
 832         $initial_reply_to = ask(
 833                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 834                 default => "",
 835                 valid_re => qr/\@.*\./, confirm_only => 1);
 836 }
 837 if (defined $initial_reply_to) {
 838         $initial_reply_to =~ s/^\s*<?//;
 839         $initial_reply_to =~ s/>?\s*$//;
 840         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 841 }
 842
 843 if (!defined $smtp_server) {
 844         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 845                 if (-x $_) {
 846                         $smtp_server = $_;
 847                         last;
 848                 }
 849         }
 850         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 851 }
 852
 853 if ($compose && $compose > 0) {
 854         @files = ($compose_filename . ".final", @files);
 855 }
 856
 857 # Variables we set as part of the loop over files
 858 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 859         $needs_confirm, $message_num, $ask_default);
 860
 861 sub extract_valid_address {
 862         my $address = shift;
 863         my $local_part_regexp = qr/[^<>"\s@]+/;
 864         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 865
 866         # check for a local address:
 867         return $address if ($address =~ /^($local_part_regexp)$/);
 868
 869         $address =~ s/^\s*<(.*)>\s*$/$1/;
 870         if ($have_email_valid) {
 871                 return scalar Email::Valid->address($address);
 872         }
 873
 874         # less robust/correct than the monster regexp in Email::Valid,
 875         # but still does a 99% job, and one less dependency
 876         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 877         return;
 878 }
 879
 880 sub extract_valid_address_or_die {
 881         my $address = shift;
 882         $address = extract_valid_address($address);
 883         die "error: unable to extract a valid address from: $address\n"
 884                 if !$address;
 885         return $address;
 886 }
 887
 888 sub validate_address {
 889         my $address = shift;
 890         while (!extract_valid_address($address)) {
 891                 print STDERR "error: unable to extract a valid address from: $address\n";
 892                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 893                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 894                         default => 'q');
 895                 if (/^d/i) {
 896                         return undef;
 897                 } elsif (/^q/i) {
 898                         cleanup_compose_files();
 899                         exit(0);
 900                 }
 901                 $address = ask("Who should the email be sent to (if any)? ",
 902                         default => "",
 903                         valid_re => qr/\@.*\./, confirm_only => 1);
 904         }
 905         return $address;
 906 }
 907
 908 sub validate_address_list {
 909         return (grep { defined $_ }
 910                 map { validate_address($_) } @_);
 911 }
 912
 913 # Usually don't need to change anything below here.
 914
 915 # we make a "fake" message id by taking the current number
 916 # of seconds since the beginning of Unix time and tacking on
 917 # a random number to the end, in case we are called quicker than
 918 # 1 second since the last time we were called.
 919
 920 # We'll setup a template for the message id, using the "from" address:
 921
 922 my ($message_id_stamp, $message_id_serial);
 923 sub make_message_id {
 924         my $uniq;
 925         if (!defined $message_id_stamp) {
 926                 $message_id_stamp = sprintf("%s-%s", time, $$);
 927                 $message_id_serial = 0;
 928         }
 929         $message_id_serial++;
 930         $uniq = "$message_id_stamp-$message_id_serial";
 931
 932         my $du_part;
 933         for ($sender, $repocommitter, $repoauthor) {
 934                 $du_part = extract_valid_address(sanitize_address($_));
 935                 last if (defined $du_part and $du_part ne '');
 936         }
 937         if (not defined $du_part or $du_part eq '') {
 938                 require Sys::Hostname;
 939                 $du_part = 'user@' . Sys::Hostname::hostname();
 940         }
 941         my $message_id_template = "<%s-git-send-email-%s>";
 942         $message_id = sprintf($message_id_template, $uniq, $du_part);
 943         #print "new message id = $message_id\n"; # Was useful for debugging
 944 }
 945
 946
 947
 948 $time = time - scalar $#files;
 949
 950 sub unquote_rfc2047 {
 951         local ($_) = @_;
 952         my $charset;
 953         my $sep = qr/[ \t]+/;
 954         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 955                 my @words = split $sep, $&;
 956                 foreach (@words) {
 957                         m/$re_encoded_word/;
 958                         $charset = $1;
 959                         my $encoding = $2;
 960                         my $text = $3;
 961                         if ($encoding eq 'q' || $encoding eq 'Q') {
 962                                 $_ = $text;
 963                                 s/_/ /g;
 964                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 965                         } else {
 966                                 # other encodings not supported yet
 967                         }
 968                 }
 969                 join '', @words;
 970         }eg;
 971         return wantarray ? ($_, $charset) : $_;
 972 }
 973
 974 sub quote_rfc2047 {
 975         local $_ = shift;
 976         my $encoding = shift || 'UTF-8';
 977         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 978         s/(.*)/=\?$encoding\?q\?$1\?=/;
 979         return $_;
 980 }
 981
 982 sub is_rfc2047_quoted {
 983         my $s = shift;
 984         length($s) <= 75 &&
 985         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 986 }
 987
 988 sub subject_needs_rfc2047_quoting {
 989         my $s = shift;
 990
 991         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 992 }
 993
 994 sub quote_subject {
 995         local $subject = shift;
 996         my $encoding = shift || 'UTF-8';
 997
 998         if (subject_needs_rfc2047_quoting($subject)) {
 999                 return quote_rfc2047($subject, $encoding);
1000         }
1001         return $subject;
1002 }
1003
1004 # use the simplest quoting being able to handle the recipient
1005 sub sanitize_address {
1006         my ($recipient) = @_;
1007
1008         # remove garbage after email address
1009         $recipient =~ s/(.*>).*$/$1/;
1010
1011         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1012
1013         if (not $recipient_name) {
1014                 return $recipient;
1015         }
1016
1017         # if recipient_name is already quoted, do nothing
1018         if (is_rfc2047_quoted($recipient_name)) {
1019                 return $recipient;
1020         }
1021
1022         # rfc2047 is needed if a non-ascii char is included
1023         if ($recipient_name =~ /[^[:ascii:]]/) {
1024                 $recipient_name =~ s/^"(.*)"$/$1/;
1025                 $recipient_name = quote_rfc2047($recipient_name);
1026         }
1027
1028         # double quotes are needed if specials or CTLs are included
1029         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1030                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1031                 $recipient_name = qq["$recipient_name"];
1032         }
1033
1034         return "$recipient_name $recipient_addr";
1035
1036 }
1037
1038 sub sanitize_address_list {
1039         return (map { sanitize_address($_) } @_);
1040 }
1041
1042 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1043 #
1044 # Tightly configured MTAa require that a caller sends a real DNS
1045 # domain name that corresponds the IP address in the HELO/EHLO
1046 # handshake. This is used to verify the connection and prevent
1047 # spammers from trying to hide their identity. If the DNS and IP don't
1048 # match, the receiveing MTA may deny the connection.
1049 #
1050 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1051 #
1052 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1053 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1054 #
1055 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1056 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1057
1058 sub valid_fqdn {
1059         my $domain = shift;
1060         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1061 }
1062
1063 sub maildomain_net {
1064         my $maildomain;
1065
1066         if (eval { require Net::Domain; 1 }) {
1067                 my $domain = Net::Domain::domainname();
1068                 $maildomain = $domain if valid_fqdn($domain);
1069         }
1070
1071         return $maildomain;
1072 }
1073
1074 sub maildomain_mta {
1075         my $maildomain;
1076
1077         if (eval { require Net::SMTP; 1 }) {
1078                 for my $host (qw(mailhost localhost)) {
1079                         my $smtp = Net::SMTP->new($host);
1080                         if (defined $smtp) {
1081                                 my $domain = $smtp->domain;
1082                                 $smtp->quit;
1083
1084                                 $maildomain = $domain if valid_fqdn($domain);
1085
1086                                 last if $maildomain;
1087                         }
1088                 }
1089         }
1090
1091         return $maildomain;
1092 }
1093
1094 sub maildomain {
1095         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1096 }
1097
1098 sub smtp_host_string {
1099         if (defined $smtp_server_port) {
1100                 return "$smtp_server:$smtp_server_port";
1101         } else {
1102                 return $smtp_server;
1103         }
1104 }
1105
1106 # Returns 1 if authentication succeeded or was not necessary
1107 # (smtp_user was not specified), and 0 otherwise.
1108
1109 sub smtp_auth_maybe {
1110         if (!defined $smtp_authuser || $auth) {
1111                 return 1;
1112         }
1113
1114         # Workaround AUTH PLAIN/LOGIN interaction defect
1115         # with Authen::SASL::Cyrus
1116         eval {
1117                 require Authen::SASL;
1118                 Authen::SASL->import(qw(Perl));
1119         };
1120
1121         # TODO: Authentication may fail not because credentials were
1122         # invalid but due to other reasons, in which we should not
1123         # reject credentials.
1124         $auth = Git::credential({
1125                 'protocol' => 'smtp',
1126                 'host' => smtp_host_string(),
1127                 'username' => $smtp_authuser,
1128                 # if there's no password, "git credential fill" will
1129                 # give us one, otherwise it'll just pass this one.
1130                 'password' => $smtp_authpass
1131         }, sub {
1132                 my $cred = shift;
1133                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1134         });
1135
1136         return $auth;
1137 }
1138
1139 sub ssl_verify_params {
1140         eval {
1141                 require IO::Socket::SSL;
1142                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1143         };
1144         if ($@) {
1145                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1146                 return;
1147         }
1148
1149         if (!defined $smtp_ssl_cert_path) {
1150                 # use the OpenSSL defaults
1151                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1152         }
1153
1154         if ($smtp_ssl_cert_path eq "") {
1155                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1156         } elsif (-d $smtp_ssl_cert_path) {
1157                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1158                         SSL_ca_path => $smtp_ssl_cert_path);
1159         } elsif (-f $smtp_ssl_cert_path) {
1160                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1161                         SSL_ca_file => $smtp_ssl_cert_path);
1162         } else {
1163                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1164                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1165         }
1166 }
1167
1168 sub file_name_is_absolute {
1169         my ($path) = @_;
1170
1171         # msys does not grok DOS drive-prefixes
1172         if ($^O eq 'msys') {
1173                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1174         }
1175
1176         require File::Spec::Functions;
1177         return File::Spec::Functions::file_name_is_absolute($path);
1178 }
1179
1180 # Returns 1 if the message was sent, and 0 otherwise.
1181 # In actuality, the whole program dies when there
1182 # is an error sending a message.
1183
1184 sub send_message {
1185         my @recipients = unique_email_list(@to);
1186         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1187                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1188                     }
1189                @cc);
1190         my $to = join (",\n\t", @recipients);
1191         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1192         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1193         my $date = format_2822_time($time++);
1194         my $gitversion = '@@GIT_VERSION@@';
1195         if ($gitversion =~ m/..GIT_VERSION../) {
1196             $gitversion = Git::version();
1197         }
1198
1199         my $cc = join(",\n\t", unique_email_list(@cc));
1200         my $ccline = "";
1201         if ($cc ne '') {
1202                 $ccline = "\nCc: $cc";
1203         }
1204         make_message_id() unless defined($message_id);
1205
1206         my $header = "From: $sender
1207 To: $to${ccline}
1208 Subject: $subject
1209 Date: $date
1210 Message-Id: $message_id
1211 ";
1212         if ($use_xmailer) {
1213                 $header .= "X-Mailer: git-send-email $gitversion\n";
1214         }
1215         if ($reply_to) {
1216
1217                 $header .= "In-Reply-To: $reply_to\n";
1218                 $header .= "References: $references\n";
1219         }
1220         if (@xh) {
1221                 $header .= join("\n", @xh) . "\n";
1222         }
1223
1224         my @sendmail_parameters = ('-i', @recipients);
1225         my $raw_from = $sender;
1226         if (defined $envelope_sender && $envelope_sender ne "auto") {
1227                 $raw_from = $envelope_sender;
1228         }
1229         $raw_from = extract_valid_address($raw_from);
1230         unshift (@sendmail_parameters,
1231                         '-f', $raw_from) if(defined $envelope_sender);
1232
1233         if ($needs_confirm && !$dry_run) {
1234                 print "\n$header\n";
1235                 if ($needs_confirm eq "inform") {
1236                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1237                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1238                         print "    The Cc list above has been expanded by additional\n";
1239                         print "    addresses found in the patch commit message. By default\n";
1240                         print "    send-email prompts before sending whenever this occurs.\n";
1241                         print "    This behavior is controlled by the sendemail.confirm\n";
1242                         print "    configuration setting.\n";
1243                         print "\n";
1244                         print "    For additional information, run 'git send-email --help'.\n";
1245                         print "    To retain the current behavior, but squelch this message,\n";
1246                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1247                 }
1248                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1249                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1250                          default => $ask_default);
1251                 die "Send this email reply required" unless defined $_;
1252                 if (/^n/i) {
1253                         return 0;
1254                 } elsif (/^q/i) {
1255                         cleanup_compose_files();
1256                         exit(0);
1257                 } elsif (/^a/i) {
1258                         $confirm = 'never';
1259                 }
1260         }
1261
1262         unshift (@sendmail_parameters, @smtp_server_options);
1263
1264         if ($dry_run) {
1265                 # We don't want to send the email.
1266         } elsif (file_name_is_absolute($smtp_server)) {
1267                 my $pid = open my $sm, '|-';
1268                 defined $pid or die $!;
1269                 if (!$pid) {
1270                         exec($smtp_server, @sendmail_parameters) or die $!;
1271                 }
1272                 print $sm "$header\n$message";
1273                 close $sm or die $!;
1274         } else {
1275
1276                 if (!defined $smtp_server) {
1277                         die "The required SMTP server is not properly defined."
1278                 }
1279
1280                 if ($smtp_encryption eq 'ssl') {
1281                         $smtp_server_port ||= 465; # ssmtp
1282                         require Net::SMTP::SSL;
1283                         $smtp_domain ||= maildomain();
1284                         require IO::Socket::SSL;
1285                         # Net::SMTP::SSL->new() does not forward any SSL options
1286                         IO::Socket::SSL::set_client_defaults(
1287                                 ssl_verify_params());
1288                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1289                                                       Hello => $smtp_domain,
1290                                                       Port => $smtp_server_port,
1291                                                       Debug => $debug_net_smtp);
1292                 }
1293                 else {
1294                         require Net::SMTP;
1295                         $smtp_domain ||= maildomain();
1296                         $smtp_server_port ||= 25;
1297                         $smtp ||= Net::SMTP->new($smtp_server,
1298                                                  Hello => $smtp_domain,
1299                                                  Debug => $debug_net_smtp,
1300                                                  Port => $smtp_server_port);
1301                         if ($smtp_encryption eq 'tls' && $smtp) {
1302                                 require Net::SMTP::SSL;
1303                                 $smtp->command('STARTTLS');
1304                                 $smtp->response();
1305                                 if ($smtp->code == 220) {
1306                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1307                                                                           ssl_verify_params())
1308                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1309                                         $smtp_encryption = '';
1310                                         # Send EHLO again to receive fresh
1311                                         # supported commands
1312                                         $smtp->hello($smtp_domain);
1313                                 } else {
1314                                         die "Server does not support STARTTLS! ".$smtp->message;
1315                                 }
1316                         }
1317                 }
1318
1319                 if (!$smtp) {
1320                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1321                             "VALUES: server=$smtp_server ",
1322                             "encryption=$smtp_encryption ",
1323                             "hello=$smtp_domain",
1324                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1325                 }
1326
1327                 smtp_auth_maybe or die $smtp->message;
1328
1329                 $smtp->mail( $raw_from ) or die $smtp->message;
1330                 $smtp->to( @recipients ) or die $smtp->message;
1331                 $smtp->data or die $smtp->message;
1332                 $smtp->datasend("$header\n$message") or die $smtp->message;
1333                 $smtp->dataend() or die $smtp->message;
1334                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1335         }
1336         if ($quiet) {
1337                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1338         } else {
1339                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1340                 if (!file_name_is_absolute($smtp_server)) {
1341                         print "Server: $smtp_server\n";
1342                         print "MAIL FROM:<$raw_from>\n";
1343                         foreach my $entry (@recipients) {
1344                             print "RCPT TO:<$entry>\n";
1345                         }
1346                 } else {
1347                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1348                 }
1349                 print $header, "\n";
1350                 if ($smtp) {
1351                         print "Result: ", $smtp->code, ' ',
1352                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1353                 } else {
1354                         print "Result: OK\n";
1355                 }
1356         }
1357
1358         return 1;
1359 }
1360
1361 $reply_to = $initial_reply_to;
1362 $references = $initial_reply_to || '';
1363 $subject = $initial_subject;
1364 $message_num = 0;
1365
1366 foreach my $t (@files) {
1367         open my $fh, "<", $t or die "can't open file $t";
1368
1369         my $author = undef;
1370         my $sauthor = undef;
1371         my $author_encoding;
1372         my $has_content_type;
1373         my $body_encoding;
1374         my $xfer_encoding;
1375         my $has_mime_version;
1376         @to = ();
1377         @cc = ();
1378         @xh = ();
1379         my $input_format = undef;
1380         my @header = ();
1381         $message = "";
1382         $message_num++;
1383         # First unfold multiline header fields
1384         while(<$fh>) {
1385                 last if /^\s*$/;
1386                 if (/^\s+\S/ and @header) {
1387                         chomp($header[$#header]);
1388                         s/^\s+/ /;
1389                         $header[$#header] .= $_;
1390             } else {
1391                         push(@header, $_);
1392                 }
1393         }
1394         # Now parse the header
1395         foreach(@header) {
1396                 if (/^From /) {
1397                         $input_format = 'mbox';
1398                         next;
1399                 }
1400                 chomp;
1401                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1402                         $input_format = 'mbox';
1403                 }
1404
1405                 if (defined $input_format && $input_format eq 'mbox') {
1406                         if (/^Subject:\s+(.*)$/i) {
1407                                 $subject = $1;
1408                         }
1409                         elsif (/^From:\s+(.*)$/i) {
1410                                 ($author, $author_encoding) = unquote_rfc2047($1);
1411                                 $sauthor = sanitize_address($author);
1412                                 next if $suppress_cc{'author'};
1413                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1414                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1415                                         $1, $_) unless $quiet;
1416                                 push @cc, $1;
1417                         }
1418                         elsif (/^To:\s+(.*)$/i) {
1419                                 foreach my $addr (parse_address_line($1)) {
1420                                         printf("(mbox) Adding to: %s from line '%s'\n",
1421                                                 $addr, $_) unless $quiet;
1422                                         push @to, $addr;
1423                                 }
1424                         }
1425                         elsif (/^Cc:\s+(.*)$/i) {
1426                                 foreach my $addr (parse_address_line($1)) {
1427                                         my $qaddr = unquote_rfc2047($addr);
1428                                         my $saddr = sanitize_address($qaddr);
1429                                         if ($saddr eq $sender) {
1430                                                 next if ($suppress_cc{'self'});
1431                                         } else {
1432                                                 next if ($suppress_cc{'cc'});
1433                                         }
1434                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1435                                                 $addr, $_) unless $quiet;
1436                                         push @cc, $addr;
1437                                 }
1438                         }
1439                         elsif (/^Content-type:/i) {
1440                                 $has_content_type = 1;
1441                                 if (/charset="?([^ "]+)/) {
1442                                         $body_encoding = $1;
1443                                 }
1444                                 push @xh, $_;
1445                         }
1446                         elsif (/^MIME-Version/i) {
1447                                 $has_mime_version = 1;
1448                                 push @xh, $_;
1449                         }
1450                         elsif (/^Message-Id: (.*)/i) {
1451                                 $message_id = $1;
1452                         }
1453                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1454                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1455                         }
1456                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1457                                 push @xh, $_;
1458                         }
1459
1460                 } else {
1461                         # In the traditional
1462                         # "send lots of email" format,
1463                         # line 1 = cc
1464                         # line 2 = subject
1465                         # So let's support that, too.
1466                         $input_format = 'lots';
1467                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1468                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1469                                         $_, $_) unless $quiet;
1470                                 push @cc, $_;
1471                         } elsif (!defined $subject) {
1472                                 $subject = $_;
1473                         }
1474                 }
1475         }
1476         # Now parse the message body
1477         while(<$fh>) {
1478                 $message .=  $_;
1479                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1480                         chomp;
1481                         my ($what, $c) = ($1, $2);
1482                         chomp $c;
1483                         my $sc = sanitize_address($c);
1484                         if ($sc eq $sender) {
1485                                 next if ($suppress_cc{'self'});
1486                         } else {
1487                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1488                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1489                         }
1490                         push @cc, $c;
1491                         printf("(body) Adding cc: %s from line '%s'\n",
1492                                 $c, $_) unless $quiet;
1493                 }
1494         }
1495         close $fh;
1496
1497         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1498                 if defined $to_cmd;
1499         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1500                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1501
1502         if ($broken_encoding{$t} && !$has_content_type) {
1503                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1504                 $has_content_type = 1;
1505                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1506                 $body_encoding = $auto_8bit_encoding;
1507         }
1508
1509         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1510                 $subject = quote_subject($subject, $auto_8bit_encoding);
1511         }
1512
1513         if (defined $sauthor and $sauthor ne $sender) {
1514                 $message = "From: $author\n\n$message";
1515                 if (defined $author_encoding) {
1516                         if ($has_content_type) {
1517                                 if ($body_encoding eq $author_encoding) {
1518                                         # ok, we already have the right encoding
1519                                 }
1520                                 else {
1521                                         # uh oh, we should re-encode
1522                                 }
1523                         }
1524                         else {
1525                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1526                                 $has_content_type = 1;
1527                                 push @xh,
1528                                   "Content-Type: text/plain; charset=$author_encoding";
1529                         }
1530                 }
1531         }
1532         if (defined $target_xfer_encoding) {
1533                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1534                 $message = apply_transfer_encoding(
1535                         $message, $xfer_encoding, $target_xfer_encoding);
1536                 $xfer_encoding = $target_xfer_encoding;
1537         }
1538         if (defined $xfer_encoding) {
1539                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1540         }
1541         if (defined $xfer_encoding or $has_content_type) {
1542                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1543         }
1544
1545         $needs_confirm = (
1546                 $confirm eq "always" or
1547                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1548                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1549         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1550
1551         @to = validate_address_list(sanitize_address_list(@to));
1552         @cc = validate_address_list(sanitize_address_list(@cc));
1553
1554         @to = (@initial_to, @to);
1555         @cc = (@initial_cc, @cc);
1556
1557         if ($message_num == 1) {
1558                 if (defined $cover_cc and $cover_cc) {
1559                         @initial_cc = @cc;
1560                 }
1561                 if (defined $cover_to and $cover_to) {
1562                         @initial_to = @to;
1563                 }
1564         }
1565
1566         my $message_was_sent = send_message();
1567
1568         # set up for the next message
1569         if ($thread && $message_was_sent &&
1570                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1571                 $message_num == 1)) {
1572                 $reply_to = $message_id;
1573                 if (length $references > 0) {
1574                         $references .= "\n $message_id";
1575                 } else {
1576                         $references = "$message_id";
1577                 }
1578         }
1579         $message_id = undef;
1580 }
1581
1582 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1583 # and return a results array
1584 sub recipients_cmd {
1585         my ($prefix, $what, $cmd, $file) = @_;
1586
1587         my @addresses = ();
1588         open my $fh, "-|", "$cmd \Q$file\E"
1589             or die "($prefix) Could not execute '$cmd'";
1590         while (my $address = <$fh>) {
1591                 $address =~ s/^\s*//g;
1592                 $address =~ s/\s*$//g;
1593                 $address = sanitize_address($address);
1594                 next if ($address eq $sender and $suppress_cc{'self'});
1595                 push @addresses, $address;
1596                 printf("($prefix) Adding %s: %s from: '%s'\n",
1597                        $what, $address, $cmd) unless $quiet;
1598                 }
1599         close $fh
1600             or die "($prefix) failed to close pipe to '$cmd'";
1601         return @addresses;
1602 }
1603
1604 cleanup_compose_files();
1605
1606 sub cleanup_compose_files {
1607         unlink($compose_filename, $compose_filename . ".final") if $compose;
1608 }
1609
1610 $smtp->quit if $smtp;
1611
1612 sub apply_transfer_encoding {
1613         my $message = shift;
1614         my $from = shift;
1615         my $to = shift;
1616
1617         return $message if ($from eq $to and $from ne '7bit');
1618
1619         require MIME::QuotedPrint;
1620         require MIME::Base64;
1621
1622         $message = MIME::QuotedPrint::decode($message)
1623                 if ($from eq 'quoted-printable');
1624         $message = MIME::Base64::decode($message)
1625                 if ($from eq 'base64');
1626
1627         die "cannot send message as 7bit"
1628                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1629         return $message
1630                 if ($to eq '7bit' or $to eq '8bit');
1631         return MIME::QuotedPrint::encode($message, "\n", 0)
1632                 if ($to eq 'quoted-printable');
1633         return MIME::Base64::encode($message, "\n")
1634                 if ($to eq 'base64');
1635         die "invalid transfer encoding";
1636 }
1637
1638 sub unique_email_list {
1639         my %seen;
1640         my @emails;
1641
1642         foreach my $entry (@_) {
1643                 my $clean = extract_valid_address_or_die($entry);
1644                 $seen{$clean} ||= 0;
1645                 next if $seen{$clean}++;
1646                 push @emails, $entry;
1647         }
1648         return @emails;
1649 }
1650
1651 sub validate_patch {
1652         my $fn = shift;
1653         open(my $fh, '<', $fn)
1654                 or die "unable to open $fn: $!\n";
1655         while (my $line = <$fh>) {
1656                 if (length($line) > 998) {
1657                         return "$.: patch contains a line longer than 998 characters";
1658                 }
1659         }
1660         return;
1661 }
1662
1663 sub file_has_nonascii {
1664         my $fn = shift;
1665         open(my $fh, '<', $fn)
1666                 or die "unable to open $fn: $!\n";
1667         while (my $line = <$fh>) {
1668                 return 1 if $line =~ /[^[:ascii:]]/;
1669         }
1670         return 0;
1671 }
1672
1673 sub body_or_subject_has_nonascii {
1674         my $fn = shift;
1675         open(my $fh, '<', $fn)
1676                 or die "unable to open $fn: $!\n";
1677         while (my $line = <$fh>) {
1678                 last if $line =~ /^$/;
1679                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1680         }
1681         while (my $line = <$fh>) {
1682                 return 1 if $line =~ /[^[:ascii:]]/;
1683         }
1684         return 0;
1685 }