git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 # Verify the user input
 464
 465 foreach my $entry (@initial_to) {
 466         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 467 }
 468
 469 foreach my $entry (@initial_cc) {
 470         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 471 }
 472
 473 foreach my $entry (@bcclist) {
 474         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 475 }
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return split_addrs($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 496                 my ($alias, $addr) = ($1, $2);
 497                 $aliases{$alias} = [ split_addrs($addr) ];
 498         } else {
 499                 print STDERR "warning: sendmail line is not recognized: $_\n";
 500         }
 501 }
 502
 503 sub parse_sendmail_aliases {
 504         my $fh = shift;
 505         my $s = '';
 506         while (<$fh>) {
 507                 chomp;
 508                 next if /^\s*$/ || /^\s*#/;
 509                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 510                 parse_sendmail_alias($s) if $s;
 511                 $s = $_;
 512         }
 513         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 514         parse_sendmail_alias($s) if $s;
 515 }
 516
 517 my %parse_alias = (
 518         # multiline formats can be supported in the future
 519         mutt => sub { my $fh = shift; while (<$fh>) {
 520                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 521                         my ($alias, $addr) = ($1, $2);
 522                         $addr =~ s/#.*$//; # mutt allows # comments
 523                          # commas delimit multiple addresses
 524                         $aliases{$alias} = [ split_addrs($addr) ];
 525                 }}},
 526         mailrc => sub { my $fh = shift; while (<$fh>) {
 527                 if (/^alias\s+(\S+)\s+(.*)$/) {
 528                         # spaces delimit multiple addresses
 529                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 530                 }}},
 531         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 532                 for (my $x = ''; defined($x); $x = $_) {
 533                         chomp $x;
 534                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 535                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 536                         $aliases{$1} = [ split_addrs($2) ];
 537                 }},
 538         elm => sub  { my $fh = shift;
 539                       while (<$fh>) {
 540                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 541                               my ($alias, $addr) = ($1, $2);
 542                                $aliases{$alias} = [ split_addrs($addr) ];
 543                           }
 544                       } },
 545         sendmail => \&parse_sendmail_aliases,
 546         gnus => sub { my $fh = shift; while (<$fh>) {
 547                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 548                         $aliases{$1} = [ $2 ];
 549                 }}}
 550 );
 551
 552 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 553         foreach my $file (@alias_files) {
 554                 open my $fh, '<', $file or die "opening $file: $!\n";
 555                 $parse_alias{$aliasfiletype}->($fh);
 556                 close $fh;
 557         }
 558 }
 559
 560 ($sender) = expand_aliases($sender) if defined $sender;
 561
 562 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 563 # $f is a revision list specification to be passed to format-patch.
 564 sub is_format_patch_arg {
 565         return unless $repo;
 566         my $f = shift;
 567         try {
 568                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 569                 if (defined($format_patch)) {
 570                         return $format_patch;
 571                 }
 572                 die(<<EOF);
 573 File '$f' exists but it could also be the range of commits
 574 to produce patches for.  Please disambiguate by...
 575
 576     * Saying "./$f" if you mean a file; or
 577     * Giving --format-patch option if you mean a range.
 578 EOF
 579         } catch Git::Error::Command with {
 580                 # Not a valid revision.  Treat it as a filename.
 581                 return 0;
 582         }
 583 }
 584
 585 # Now that all the defaults are set, process the rest of the command line
 586 # arguments and collect up the files that need to be processed.
 587 my @rev_list_opts;
 588 while (defined(my $f = shift @ARGV)) {
 589         if ($f eq "--") {
 590                 push @rev_list_opts, "--", @ARGV;
 591                 @ARGV = ();
 592         } elsif (-d $f and !is_format_patch_arg($f)) {
 593                 opendir my $dh, $f
 594                         or die "Failed to opendir $f: $!";
 595
 596                 push @files, grep { -f $_ } map { catfile($f, $_) }
 597                                 sort readdir $dh;
 598                 closedir $dh;
 599         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 600                 push @files, $f;
 601         } else {
 602                 push @rev_list_opts, $f;
 603         }
 604 }
 605
 606 if (@rev_list_opts) {
 607         die "Cannot run git format-patch from outside a repository\n"
 608                 unless $repo;
 609         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 610 }
 611
 612 if ($validate) {
 613         foreach my $f (@files) {
 614                 unless (-p $f) {
 615                         my $error = validate_patch($f);
 616                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 617                 }
 618         }
 619 }
 620
 621 if (@files) {
 622         unless ($quiet) {
 623                 print $_,"\n" for (@files);
 624         }
 625 } else {
 626         print STDERR "\nNo patch files specified!\n\n";
 627         usage();
 628 }
 629
 630 sub get_patch_subject {
 631         my $fn = shift;
 632         open (my $fh, '<', $fn);
 633         while (my $line = <$fh>) {
 634                 next unless ($line =~ /^Subject: (.*)$/);
 635                 close $fh;
 636                 return "GIT: $1\n";
 637         }
 638         close $fh;
 639         die "No subject line in $fn ?";
 640 }
 641
 642 if ($compose) {
 643         # Note that this does not need to be secure, but we will make a small
 644         # effort to have it be unique
 645         $compose_filename = ($repo ?
 646                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 647                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 648         open my $c, ">", $compose_filename
 649                 or die "Failed to open for writing $compose_filename: $!";
 650
 651
 652         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 653         my $tpl_subject = $initial_subject || '';
 654         my $tpl_reply_to = $initial_reply_to || '';
 655
 656         print $c <<EOT;
 657 From $tpl_sender # This line is ignored.
 658 GIT: Lines beginning in "GIT:" will be removed.
 659 GIT: Consider including an overall diffstat or table of contents
 660 GIT: for the patch you are writing.
 661 GIT:
 662 GIT: Clear the body content if you don't wish to send a summary.
 663 From: $tpl_sender
 664 Subject: $tpl_subject
 665 In-Reply-To: $tpl_reply_to
 666
 667 EOT
 668         for my $f (@files) {
 669                 print $c get_patch_subject($f);
 670         }
 671         close $c;
 672
 673         if ($annotate) {
 674                 do_edit($compose_filename, @files);
 675         } else {
 676                 do_edit($compose_filename);
 677         }
 678
 679         open my $c2, ">", $compose_filename . ".final"
 680                 or die "Failed to open $compose_filename.final : " . $!;
 681
 682         open $c, "<", $compose_filename
 683                 or die "Failed to open $compose_filename : " . $!;
 684
 685         my $need_8bit_cte = file_has_nonascii($compose_filename);
 686         my $in_body = 0;
 687         my $summary_empty = 1;
 688         if (!defined $compose_encoding) {
 689                 $compose_encoding = "UTF-8";
 690         }
 691         while(<$c>) {
 692                 next if m/^GIT:/;
 693                 if ($in_body) {
 694                         $summary_empty = 0 unless (/^\n$/);
 695                 } elsif (/^\n$/) {
 696                         $in_body = 1;
 697                         if ($need_8bit_cte) {
 698                                 print $c2 "MIME-Version: 1.0\n",
 699                                          "Content-Type: text/plain; ",
 700                                            "charset=$compose_encoding\n",
 701                                          "Content-Transfer-Encoding: 8bit\n";
 702                         }
 703                 } elsif (/^MIME-Version:/i) {
 704                         $need_8bit_cte = 0;
 705                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 706                         $initial_subject = $1;
 707                         my $subject = $initial_subject;
 708                         $_ = "Subject: " .
 709                                 quote_subject($subject, $compose_encoding) .
 710                                 "\n";
 711                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 712                         $initial_reply_to = $1;
 713                         next;
 714                 } elsif (/^From:\s*(.+)\s*$/i) {
 715                         $sender = $1;
 716                         next;
 717                 } elsif (/^(?:To|Cc|Bcc):/i) {
 718                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 719                         next;
 720                 }
 721                 print $c2 $_;
 722         }
 723         close $c;
 724         close $c2;
 725
 726         if ($summary_empty) {
 727                 print "Summary email is empty, skipping it\n";
 728                 $compose = -1;
 729         }
 730 } elsif ($annotate) {
 731         do_edit(@files);
 732 }
 733
 734 sub ask {
 735         my ($prompt, %arg) = @_;
 736         my $valid_re = $arg{valid_re};
 737         my $default = $arg{default};
 738         my $confirm_only = $arg{confirm_only};
 739         my $resp;
 740         my $i = 0;
 741         return defined $default ? $default : undef
 742                 unless defined $term->IN and defined fileno($term->IN) and
 743                        defined $term->OUT and defined fileno($term->OUT);
 744         while ($i++ < 10) {
 745                 $resp = $term->readline($prompt);
 746                 if (!defined $resp) { # EOF
 747                         print "\n";
 748                         return defined $default ? $default : undef;
 749                 }
 750                 if ($resp eq '' and defined $default) {
 751                         return $default;
 752                 }
 753                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 754                         return $resp;
 755                 }
 756                 if ($confirm_only) {
 757                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 758                         if (defined $yesno && $yesno =~ /y/i) {
 759                                 return $resp;
 760                         }
 761                 }
 762         }
 763         return;
 764 }
 765
 766 my %broken_encoding;
 767
 768 sub file_declares_8bit_cte {
 769         my $fn = shift;
 770         open (my $fh, '<', $fn);
 771         while (my $line = <$fh>) {
 772                 last if ($line =~ /^$/);
 773                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 774         }
 775         close $fh;
 776         return 0;
 777 }
 778
 779 foreach my $f (@files) {
 780         next unless (body_or_subject_has_nonascii($f)
 781                      && !file_declares_8bit_cte($f));
 782         $broken_encoding{$f} = 1;
 783 }
 784
 785 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 786         print "The following files are 8bit, but do not declare " .
 787                 "a Content-Transfer-Encoding.\n";
 788         foreach my $f (sort keys %broken_encoding) {
 789                 print "    $f\n";
 790         }
 791         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 792                                   valid_re => qr/.{4}/, confirm_only => 1,
 793                                   default => "UTF-8");
 794 }
 795
 796 if (!$force) {
 797         for my $f (@files) {
 798                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 799                         die "Refusing to send because the patch\n\t$f\n"
 800                                 . "has the template subject '*** SUBJECT HERE ***'. "
 801                                 . "Pass --force if you really want to send.\n";
 802                 }
 803         }
 804 }
 805
 806 if (!defined $sender) {
 807         $sender = $repoauthor || $repocommitter || '';
 808 }
 809
 810 # $sender could be an already sanitized address
 811 # (e.g. sendemail.from could be manually sanitized by user).
 812 # But it's a no-op to run sanitize_address on an already sanitized address.
 813 $sender = sanitize_address($sender);
 814
 815 my $prompting = 0;
 816 if (!@initial_to && !defined $to_cmd) {
 817         my $to = ask("Who should the emails be sent to (if any)? ",
 818                      default => "",
 819                      valid_re => qr/\@.*\./, confirm_only => 1);
 820         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 821         $prompting++;
 822 }
 823
 824 sub expand_aliases {
 825         return map { expand_one_alias($_) } @_;
 826 }
 827
 828 my %EXPANDED_ALIASES;
 829 sub expand_one_alias {
 830         my $alias = shift;
 831         if ($EXPANDED_ALIASES{$alias}) {
 832                 die "fatal: alias '$alias' expands to itself\n";
 833         }
 834         local $EXPANDED_ALIASES{$alias} = 1;
 835         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 836 }
 837
 838 @initial_to = expand_aliases(@initial_to);
 839 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 840 @initial_cc = expand_aliases(@initial_cc);
 841 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 842 @bcclist = expand_aliases(@bcclist);
 843 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 844
 845 if ($thread && !defined $initial_reply_to && $prompting) {
 846         $initial_reply_to = ask(
 847                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 848                 default => "",
 849                 valid_re => qr/\@.*\./, confirm_only => 1);
 850 }
 851 if (defined $initial_reply_to) {
 852         $initial_reply_to =~ s/^\s*<?//;
 853         $initial_reply_to =~ s/>?\s*$//;
 854         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 855 }
 856
 857 if (!defined $smtp_server) {
 858         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 859                 if (-x $_) {
 860                         $smtp_server = $_;
 861                         last;
 862                 }
 863         }
 864         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 865 }
 866
 867 if ($compose && $compose > 0) {
 868         @files = ($compose_filename . ".final", @files);
 869 }
 870
 871 # Variables we set as part of the loop over files
 872 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 873         $needs_confirm, $message_num, $ask_default);
 874
 875 sub extract_valid_address {
 876         my $address = shift;
 877         my $local_part_regexp = qr/[^<>"\s@]+/;
 878         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 879
 880         # check for a local address:
 881         return $address if ($address =~ /^($local_part_regexp)$/);
 882
 883         $address =~ s/^\s*<(.*)>\s*$/$1/;
 884         if ($have_email_valid) {
 885                 return scalar Email::Valid->address($address);
 886         }
 887
 888         # less robust/correct than the monster regexp in Email::Valid,
 889         # but still does a 99% job, and one less dependency
 890         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 891         return;
 892 }
 893
 894 sub extract_valid_address_or_die {
 895         my $address = shift;
 896         $address = extract_valid_address($address);
 897         die "error: unable to extract a valid address from: $address\n"
 898                 if !$address;
 899         return $address;
 900 }
 901
 902 sub validate_address {
 903         my $address = shift;
 904         while (!extract_valid_address($address)) {
 905                 print STDERR "error: unable to extract a valid address from: $address\n";
 906                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 907                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 908                         default => 'q');
 909                 if (/^d/i) {
 910                         return undef;
 911                 } elsif (/^q/i) {
 912                         cleanup_compose_files();
 913                         exit(0);
 914                 }
 915                 $address = ask("Who should the email be sent to (if any)? ",
 916                         default => "",
 917                         valid_re => qr/\@.*\./, confirm_only => 1);
 918         }
 919         return $address;
 920 }
 921
 922 sub validate_address_list {
 923         return (grep { defined $_ }
 924                 map { validate_address($_) } @_);
 925 }
 926
 927 # Usually don't need to change anything below here.
 928
 929 # we make a "fake" message id by taking the current number
 930 # of seconds since the beginning of Unix time and tacking on
 931 # a random number to the end, in case we are called quicker than
 932 # 1 second since the last time we were called.
 933
 934 # We'll setup a template for the message id, using the "from" address:
 935
 936 my ($message_id_stamp, $message_id_serial);
 937 sub make_message_id {
 938         my $uniq;
 939         if (!defined $message_id_stamp) {
 940                 $message_id_stamp = sprintf("%s-%s", time, $$);
 941                 $message_id_serial = 0;
 942         }
 943         $message_id_serial++;
 944         $uniq = "$message_id_stamp-$message_id_serial";
 945
 946         my $du_part;
 947         for ($sender, $repocommitter, $repoauthor) {
 948                 $du_part = extract_valid_address(sanitize_address($_));
 949                 last if (defined $du_part and $du_part ne '');
 950         }
 951         if (not defined $du_part or $du_part eq '') {
 952                 require Sys::Hostname;
 953                 $du_part = 'user@' . Sys::Hostname::hostname();
 954         }
 955         my $message_id_template = "<%s-git-send-email-%s>";
 956         $message_id = sprintf($message_id_template, $uniq, $du_part);
 957         #print "new message id = $message_id\n"; # Was useful for debugging
 958 }
 959
 960
 961
 962 $time = time - scalar $#files;
 963
 964 sub unquote_rfc2047 {
 965         local ($_) = @_;
 966         my $charset;
 967         my $sep = qr/[ \t]+/;
 968         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 969                 my @words = split $sep, $&;
 970                 foreach (@words) {
 971                         m/$re_encoded_word/;
 972                         $charset = $1;
 973                         my $encoding = $2;
 974                         my $text = $3;
 975                         if ($encoding eq 'q' || $encoding eq 'Q') {
 976                                 $_ = $text;
 977                                 s/_/ /g;
 978                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 979                         } else {
 980                                 # other encodings not supported yet
 981                         }
 982                 }
 983                 join '', @words;
 984         }eg;
 985         return wantarray ? ($_, $charset) : $_;
 986 }
 987
 988 sub quote_rfc2047 {
 989         local $_ = shift;
 990         my $encoding = shift || 'UTF-8';
 991         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 992         s/(.*)/=\?$encoding\?q\?$1\?=/;
 993         return $_;
 994 }
 995
 996 sub is_rfc2047_quoted {
 997         my $s = shift;
 998         length($s) <= 75 &&
 999         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1000 }
1001
1002 sub subject_needs_rfc2047_quoting {
1003         my $s = shift;
1004
1005         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1006 }
1007
1008 sub quote_subject {
1009         local $subject = shift;
1010         my $encoding = shift || 'UTF-8';
1011
1012         if (subject_needs_rfc2047_quoting($subject)) {
1013                 return quote_rfc2047($subject, $encoding);
1014         }
1015         return $subject;
1016 }
1017
1018 # use the simplest quoting being able to handle the recipient
1019 sub sanitize_address {
1020         my ($recipient) = @_;
1021
1022         # remove garbage after email address
1023         $recipient =~ s/(.*>).*$/$1/;
1024
1025         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1026
1027         if (not $recipient_name) {
1028                 return $recipient;
1029         }
1030
1031         # if recipient_name is already quoted, do nothing
1032         if (is_rfc2047_quoted($recipient_name)) {
1033                 return $recipient;
1034         }
1035
1036         # rfc2047 is needed if a non-ascii char is included
1037         if ($recipient_name =~ /[^[:ascii:]]/) {
1038                 $recipient_name =~ s/^"(.*)"$/$1/;
1039                 $recipient_name = quote_rfc2047($recipient_name);
1040         }
1041
1042         # double quotes are needed if specials or CTLs are included
1043         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1044                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1045                 $recipient_name = qq["$recipient_name"];
1046         }
1047
1048         return "$recipient_name $recipient_addr";
1049
1050 }
1051
1052 sub sanitize_address_list {
1053         return (map { sanitize_address($_) } @_);
1054 }
1055
1056 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1057 #
1058 # Tightly configured MTAa require that a caller sends a real DNS
1059 # domain name that corresponds the IP address in the HELO/EHLO
1060 # handshake. This is used to verify the connection and prevent
1061 # spammers from trying to hide their identity. If the DNS and IP don't
1062 # match, the receiveing MTA may deny the connection.
1063 #
1064 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1065 #
1066 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1067 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1068 #
1069 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1070 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1071
1072 sub valid_fqdn {
1073         my $domain = shift;
1074         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1075 }
1076
1077 sub maildomain_net {
1078         my $maildomain;
1079
1080         if (eval { require Net::Domain; 1 }) {
1081                 my $domain = Net::Domain::domainname();
1082                 $maildomain = $domain if valid_fqdn($domain);
1083         }
1084
1085         return $maildomain;
1086 }
1087
1088 sub maildomain_mta {
1089         my $maildomain;
1090
1091         if (eval { require Net::SMTP; 1 }) {
1092                 for my $host (qw(mailhost localhost)) {
1093                         my $smtp = Net::SMTP->new($host);
1094                         if (defined $smtp) {
1095                                 my $domain = $smtp->domain;
1096                                 $smtp->quit;
1097
1098                                 $maildomain = $domain if valid_fqdn($domain);
1099
1100                                 last if $maildomain;
1101                         }
1102                 }
1103         }
1104
1105         return $maildomain;
1106 }
1107
1108 sub maildomain {
1109         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1110 }
1111
1112 sub smtp_host_string {
1113         if (defined $smtp_server_port) {
1114                 return "$smtp_server:$smtp_server_port";
1115         } else {
1116                 return $smtp_server;
1117         }
1118 }
1119
1120 # Returns 1 if authentication succeeded or was not necessary
1121 # (smtp_user was not specified), and 0 otherwise.
1122
1123 sub smtp_auth_maybe {
1124         if (!defined $smtp_authuser || $auth) {
1125                 return 1;
1126         }
1127
1128         # Workaround AUTH PLAIN/LOGIN interaction defect
1129         # with Authen::SASL::Cyrus
1130         eval {
1131                 require Authen::SASL;
1132                 Authen::SASL->import(qw(Perl));
1133         };
1134
1135         # TODO: Authentication may fail not because credentials were
1136         # invalid but due to other reasons, in which we should not
1137         # reject credentials.
1138         $auth = Git::credential({
1139                 'protocol' => 'smtp',
1140                 'host' => smtp_host_string(),
1141                 'username' => $smtp_authuser,
1142                 # if there's no password, "git credential fill" will
1143                 # give us one, otherwise it'll just pass this one.
1144                 'password' => $smtp_authpass
1145         }, sub {
1146                 my $cred = shift;
1147                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1148         });
1149
1150         return $auth;
1151 }
1152
1153 sub ssl_verify_params {
1154         eval {
1155                 require IO::Socket::SSL;
1156                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1157         };
1158         if ($@) {
1159                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1160                 return;
1161         }
1162
1163         if (!defined $smtp_ssl_cert_path) {
1164                 # use the OpenSSL defaults
1165                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1166         }
1167
1168         if ($smtp_ssl_cert_path eq "") {
1169                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1170         } elsif (-d $smtp_ssl_cert_path) {
1171                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1172                         SSL_ca_path => $smtp_ssl_cert_path);
1173         } elsif (-f $smtp_ssl_cert_path) {
1174                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1175                         SSL_ca_file => $smtp_ssl_cert_path);
1176         } else {
1177                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1178                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1179         }
1180 }
1181
1182 sub file_name_is_absolute {
1183         my ($path) = @_;
1184
1185         # msys does not grok DOS drive-prefixes
1186         if ($^O eq 'msys') {
1187                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1188         }
1189
1190         require File::Spec::Functions;
1191         return File::Spec::Functions::file_name_is_absolute($path);
1192 }
1193
1194 # Returns 1 if the message was sent, and 0 otherwise.
1195 # In actuality, the whole program dies when there
1196 # is an error sending a message.
1197
1198 sub send_message {
1199         my @recipients = unique_email_list(@to);
1200         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1201                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1202                     }
1203                @cc);
1204         my $to = join (",\n\t", @recipients);
1205         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1206         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1207         my $date = format_2822_time($time++);
1208         my $gitversion = '@@GIT_VERSION@@';
1209         if ($gitversion =~ m/..GIT_VERSION../) {
1210             $gitversion = Git::version();
1211         }
1212
1213         my $cc = join(",\n\t", unique_email_list(@cc));
1214         my $ccline = "";
1215         if ($cc ne '') {
1216                 $ccline = "\nCc: $cc";
1217         }
1218         make_message_id() unless defined($message_id);
1219
1220         my $header = "From: $sender
1221 To: $to${ccline}
1222 Subject: $subject
1223 Date: $date
1224 Message-Id: $message_id
1225 ";
1226         if ($use_xmailer) {
1227                 $header .= "X-Mailer: git-send-email $gitversion\n";
1228         }
1229         if ($reply_to) {
1230
1231                 $header .= "In-Reply-To: $reply_to\n";
1232                 $header .= "References: $references\n";
1233         }
1234         if (@xh) {
1235                 $header .= join("\n", @xh) . "\n";
1236         }
1237
1238         my @sendmail_parameters = ('-i', @recipients);
1239         my $raw_from = $sender;
1240         if (defined $envelope_sender && $envelope_sender ne "auto") {
1241                 $raw_from = $envelope_sender;
1242         }
1243         $raw_from = extract_valid_address($raw_from);
1244         unshift (@sendmail_parameters,
1245                         '-f', $raw_from) if(defined $envelope_sender);
1246
1247         if ($needs_confirm && !$dry_run) {
1248                 print "\n$header\n";
1249                 if ($needs_confirm eq "inform") {
1250                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1251                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1252                         print "    The Cc list above has been expanded by additional\n";
1253                         print "    addresses found in the patch commit message. By default\n";
1254                         print "    send-email prompts before sending whenever this occurs.\n";
1255                         print "    This behavior is controlled by the sendemail.confirm\n";
1256                         print "    configuration setting.\n";
1257                         print "\n";
1258                         print "    For additional information, run 'git send-email --help'.\n";
1259                         print "    To retain the current behavior, but squelch this message,\n";
1260                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1261                 }
1262                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1263                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1264                          default => $ask_default);
1265                 die "Send this email reply required" unless defined $_;
1266                 if (/^n/i) {
1267                         return 0;
1268                 } elsif (/^q/i) {
1269                         cleanup_compose_files();
1270                         exit(0);
1271                 } elsif (/^a/i) {
1272                         $confirm = 'never';
1273                 }
1274         }
1275
1276         unshift (@sendmail_parameters, @smtp_server_options);
1277
1278         if ($dry_run) {
1279                 # We don't want to send the email.
1280         } elsif (file_name_is_absolute($smtp_server)) {
1281                 my $pid = open my $sm, '|-';
1282                 defined $pid or die $!;
1283                 if (!$pid) {
1284                         exec($smtp_server, @sendmail_parameters) or die $!;
1285                 }
1286                 print $sm "$header\n$message";
1287                 close $sm or die $!;
1288         } else {
1289
1290                 if (!defined $smtp_server) {
1291                         die "The required SMTP server is not properly defined."
1292                 }
1293
1294                 if ($smtp_encryption eq 'ssl') {
1295                         $smtp_server_port ||= 465; # ssmtp
1296                         require Net::SMTP::SSL;
1297                         $smtp_domain ||= maildomain();
1298                         require IO::Socket::SSL;
1299                         # Net::SMTP::SSL->new() does not forward any SSL options
1300                         IO::Socket::SSL::set_client_defaults(
1301                                 ssl_verify_params());
1302                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1303                                                       Hello => $smtp_domain,
1304                                                       Port => $smtp_server_port,
1305                                                       Debug => $debug_net_smtp);
1306                 }
1307                 else {
1308                         require Net::SMTP;
1309                         $smtp_domain ||= maildomain();
1310                         $smtp_server_port ||= 25;
1311                         $smtp ||= Net::SMTP->new($smtp_server,
1312                                                  Hello => $smtp_domain,
1313                                                  Debug => $debug_net_smtp,
1314                                                  Port => $smtp_server_port);
1315                         if ($smtp_encryption eq 'tls' && $smtp) {
1316                                 require Net::SMTP::SSL;
1317                                 $smtp->command('STARTTLS');
1318                                 $smtp->response();
1319                                 if ($smtp->code == 220) {
1320                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1321                                                                           ssl_verify_params())
1322                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1323                                         $smtp_encryption = '';
1324                                         # Send EHLO again to receive fresh
1325                                         # supported commands
1326                                         $smtp->hello($smtp_domain);
1327                                 } else {
1328                                         die "Server does not support STARTTLS! ".$smtp->message;
1329                                 }
1330                         }
1331                 }
1332
1333                 if (!$smtp) {
1334                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1335                             "VALUES: server=$smtp_server ",
1336                             "encryption=$smtp_encryption ",
1337                             "hello=$smtp_domain",
1338                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1339                 }
1340
1341                 smtp_auth_maybe or die $smtp->message;
1342
1343                 $smtp->mail( $raw_from ) or die $smtp->message;
1344                 $smtp->to( @recipients ) or die $smtp->message;
1345                 $smtp->data or die $smtp->message;
1346                 $smtp->datasend("$header\n$message") or die $smtp->message;
1347                 $smtp->dataend() or die $smtp->message;
1348                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1349         }
1350         if ($quiet) {
1351                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1352         } else {
1353                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1354                 if (!file_name_is_absolute($smtp_server)) {
1355                         print "Server: $smtp_server\n";
1356                         print "MAIL FROM:<$raw_from>\n";
1357                         foreach my $entry (@recipients) {
1358                             print "RCPT TO:<$entry>\n";
1359                         }
1360                 } else {
1361                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1362                 }
1363                 print $header, "\n";
1364                 if ($smtp) {
1365                         print "Result: ", $smtp->code, ' ',
1366                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1367                 } else {
1368                         print "Result: OK\n";
1369                 }
1370         }
1371
1372         return 1;
1373 }
1374
1375 $reply_to = $initial_reply_to;
1376 $references = $initial_reply_to || '';
1377 $subject = $initial_subject;
1378 $message_num = 0;
1379
1380 foreach my $t (@files) {
1381         open my $fh, "<", $t or die "can't open file $t";
1382
1383         my $author = undef;
1384         my $sauthor = undef;
1385         my $author_encoding;
1386         my $has_content_type;
1387         my $body_encoding;
1388         my $xfer_encoding;
1389         my $has_mime_version;
1390         @to = ();
1391         @cc = ();
1392         @xh = ();
1393         my $input_format = undef;
1394         my @header = ();
1395         $message = "";
1396         $message_num++;
1397         # First unfold multiline header fields
1398         while(<$fh>) {
1399                 last if /^\s*$/;
1400                 if (/^\s+\S/ and @header) {
1401                         chomp($header[$#header]);
1402                         s/^\s+/ /;
1403                         $header[$#header] .= $_;
1404             } else {
1405                         push(@header, $_);
1406                 }
1407         }
1408         # Now parse the header
1409         foreach(@header) {
1410                 if (/^From /) {
1411                         $input_format = 'mbox';
1412                         next;
1413                 }
1414                 chomp;
1415                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1416                         $input_format = 'mbox';
1417                 }
1418
1419                 if (defined $input_format && $input_format eq 'mbox') {
1420                         if (/^Subject:\s+(.*)$/i) {
1421                                 $subject = $1;
1422                         }
1423                         elsif (/^From:\s+(.*)$/i) {
1424                                 ($author, $author_encoding) = unquote_rfc2047($1);
1425                                 $sauthor = sanitize_address($author);
1426                                 next if $suppress_cc{'author'};
1427                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1428                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1429                                         $1, $_) unless $quiet;
1430                                 push @cc, $1;
1431                         }
1432                         elsif (/^To:\s+(.*)$/i) {
1433                                 foreach my $addr (parse_address_line($1)) {
1434                                         printf("(mbox) Adding to: %s from line '%s'\n",
1435                                                 $addr, $_) unless $quiet;
1436                                         push @to, $addr;
1437                                 }
1438                         }
1439                         elsif (/^Cc:\s+(.*)$/i) {
1440                                 foreach my $addr (parse_address_line($1)) {
1441                                         my $qaddr = unquote_rfc2047($addr);
1442                                         my $saddr = sanitize_address($qaddr);
1443                                         if ($saddr eq $sender) {
1444                                                 next if ($suppress_cc{'self'});
1445                                         } else {
1446                                                 next if ($suppress_cc{'cc'});
1447                                         }
1448                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1449                                                 $addr, $_) unless $quiet;
1450                                         push @cc, $addr;
1451                                 }
1452                         }
1453                         elsif (/^Content-type:/i) {
1454                                 $has_content_type = 1;
1455                                 if (/charset="?([^ "]+)/) {
1456                                         $body_encoding = $1;
1457                                 }
1458                                 push @xh, $_;
1459                         }
1460                         elsif (/^MIME-Version/i) {
1461                                 $has_mime_version = 1;
1462                                 push @xh, $_;
1463                         }
1464                         elsif (/^Message-Id: (.*)/i) {
1465                                 $message_id = $1;
1466                         }
1467                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1468                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1469                         }
1470                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1471                                 push @xh, $_;
1472                         }
1473
1474                 } else {
1475                         # In the traditional
1476                         # "send lots of email" format,
1477                         # line 1 = cc
1478                         # line 2 = subject
1479                         # So let's support that, too.
1480                         $input_format = 'lots';
1481                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1482                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1483                                         $_, $_) unless $quiet;
1484                                 push @cc, $_;
1485                         } elsif (!defined $subject) {
1486                                 $subject = $_;
1487                         }
1488                 }
1489         }
1490         # Now parse the message body
1491         while(<$fh>) {
1492                 $message .=  $_;
1493                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1494                         chomp;
1495                         my ($what, $c) = ($1, $2);
1496                         chomp $c;
1497                         my $sc = sanitize_address($c);
1498                         if ($sc eq $sender) {
1499                                 next if ($suppress_cc{'self'});
1500                         } else {
1501                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1502                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1503                         }
1504                         push @cc, $c;
1505                         printf("(body) Adding cc: %s from line '%s'\n",
1506                                 $c, $_) unless $quiet;
1507                 }
1508         }
1509         close $fh;
1510
1511         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1512                 if defined $to_cmd;
1513         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1514                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1515
1516         if ($broken_encoding{$t} && !$has_content_type) {
1517                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1518                 $has_content_type = 1;
1519                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1520                 $body_encoding = $auto_8bit_encoding;
1521         }
1522
1523         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1524                 $subject = quote_subject($subject, $auto_8bit_encoding);
1525         }
1526
1527         if (defined $sauthor and $sauthor ne $sender) {
1528                 $message = "From: $author\n\n$message";
1529                 if (defined $author_encoding) {
1530                         if ($has_content_type) {
1531                                 if ($body_encoding eq $author_encoding) {
1532                                         # ok, we already have the right encoding
1533                                 }
1534                                 else {
1535                                         # uh oh, we should re-encode
1536                                 }
1537                         }
1538                         else {
1539                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1540                                 $has_content_type = 1;
1541                                 push @xh,
1542                                   "Content-Type: text/plain; charset=$author_encoding";
1543                         }
1544                 }
1545         }
1546         if (defined $target_xfer_encoding) {
1547                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1548                 $message = apply_transfer_encoding(
1549                         $message, $xfer_encoding, $target_xfer_encoding);
1550                 $xfer_encoding = $target_xfer_encoding;
1551         }
1552         if (defined $xfer_encoding) {
1553                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1554         }
1555         if (defined $xfer_encoding or $has_content_type) {
1556                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1557         }
1558
1559         $needs_confirm = (
1560                 $confirm eq "always" or
1561                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1562                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1563         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1564
1565         @to = validate_address_list(sanitize_address_list(@to));
1566         @cc = validate_address_list(sanitize_address_list(@cc));
1567
1568         @to = (@initial_to, @to);
1569         @cc = (@initial_cc, @cc);
1570
1571         if ($message_num == 1) {
1572                 if (defined $cover_cc and $cover_cc) {
1573                         @initial_cc = @cc;
1574                 }
1575                 if (defined $cover_to and $cover_to) {
1576                         @initial_to = @to;
1577                 }
1578         }
1579
1580         my $message_was_sent = send_message();
1581
1582         # set up for the next message
1583         if ($thread && $message_was_sent &&
1584                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1585                 $message_num == 1)) {
1586                 $reply_to = $message_id;
1587                 if (length $references > 0) {
1588                         $references .= "\n $message_id";
1589                 } else {
1590                         $references = "$message_id";
1591                 }
1592         }
1593         $message_id = undef;
1594 }
1595
1596 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1597 # and return a results array
1598 sub recipients_cmd {
1599         my ($prefix, $what, $cmd, $file) = @_;
1600
1601         my @addresses = ();
1602         open my $fh, "-|", "$cmd \Q$file\E"
1603             or die "($prefix) Could not execute '$cmd'";
1604         while (my $address = <$fh>) {
1605                 $address =~ s/^\s*//g;
1606                 $address =~ s/\s*$//g;
1607                 $address = sanitize_address($address);
1608                 next if ($address eq $sender and $suppress_cc{'self'});
1609                 push @addresses, $address;
1610                 printf("($prefix) Adding %s: %s from: '%s'\n",
1611                        $what, $address, $cmd) unless $quiet;
1612                 }
1613         close $fh
1614             or die "($prefix) failed to close pipe to '$cmd'";
1615         return @addresses;
1616 }
1617
1618 cleanup_compose_files();
1619
1620 sub cleanup_compose_files {
1621         unlink($compose_filename, $compose_filename . ".final") if $compose;
1622 }
1623
1624 $smtp->quit if $smtp;
1625
1626 sub apply_transfer_encoding {
1627         my $message = shift;
1628         my $from = shift;
1629         my $to = shift;
1630
1631         return $message if ($from eq $to and $from ne '7bit');
1632
1633         require MIME::QuotedPrint;
1634         require MIME::Base64;
1635
1636         $message = MIME::QuotedPrint::decode($message)
1637                 if ($from eq 'quoted-printable');
1638         $message = MIME::Base64::decode($message)
1639                 if ($from eq 'base64');
1640
1641         die "cannot send message as 7bit"
1642                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1643         return $message
1644                 if ($to eq '7bit' or $to eq '8bit');
1645         return MIME::QuotedPrint::encode($message, "\n", 0)
1646                 if ($to eq 'quoted-printable');
1647         return MIME::Base64::encode($message, "\n")
1648                 if ($to eq 'base64');
1649         die "invalid transfer encoding";
1650 }
1651
1652 sub unique_email_list {
1653         my %seen;
1654         my @emails;
1655
1656         foreach my $entry (@_) {
1657                 my $clean = extract_valid_address_or_die($entry);
1658                 $seen{$clean} ||= 0;
1659                 next if $seen{$clean}++;
1660                 push @emails, $entry;
1661         }
1662         return @emails;
1663 }
1664
1665 sub validate_patch {
1666         my $fn = shift;
1667         open(my $fh, '<', $fn)
1668                 or die "unable to open $fn: $!\n";
1669         while (my $line = <$fh>) {
1670                 if (length($line) > 998) {
1671                         return "$.: patch contains a line longer than 998 characters";
1672                 }
1673         }
1674         return;
1675 }
1676
1677 sub file_has_nonascii {
1678         my $fn = shift;
1679         open(my $fh, '<', $fn)
1680                 or die "unable to open $fn: $!\n";
1681         while (my $line = <$fh>) {
1682                 return 1 if $line =~ /[^[:ascii:]]/;
1683         }
1684         return 0;
1685 }
1686
1687 sub body_or_subject_has_nonascii {
1688         my $fn = shift;
1689         open(my $fh, '<', $fn)
1690                 or die "unable to open $fn: $!\n";
1691         while (my $line = <$fh>) {
1692                 last if $line =~ /^$/;
1693                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1694         }
1695         while (my $line = <$fh>) {
1696                 return 1 if $line =~ /[^[:ascii:]]/;
1697         }
1698         return 0;
1699 }