git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 # Verify the user input
 464
 465 foreach my $entry (@initial_to) {
 466         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 467 }
 468
 469 foreach my $entry (@initial_cc) {
 470         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 471 }
 472
 473 foreach my $entry (@bcclist) {
 474         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 475 }
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return split_addrs($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490 my %parse_alias = (
 491         # multiline formats can be supported in the future
 492         mutt => sub { my $fh = shift; while (<$fh>) {
 493                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 494                         my ($alias, $addr) = ($1, $2);
 495                         $addr =~ s/#.*$//; # mutt allows # comments
 496                          # commas delimit multiple addresses
 497                         $aliases{$alias} = [ split_addrs($addr) ];
 498                 }}},
 499         mailrc => sub { my $fh = shift; while (<$fh>) {
 500                 if (/^alias\s+(\S+)\s+(.*)$/) {
 501                         # spaces delimit multiple addresses
 502                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 503                 }}},
 504         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 505                 for (my $x = ''; defined($x); $x = $_) {
 506                         chomp $x;
 507                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 508                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 509                         $aliases{$1} = [ split_addrs($2) ];
 510                 }},
 511         elm => sub  { my $fh = shift;
 512                       while (<$fh>) {
 513                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 514                               my ($alias, $addr) = ($1, $2);
 515                                $aliases{$alias} = [ split_addrs($addr) ];
 516                           }
 517                       } },
 518
 519         sendmail => sub { my $fh = shift; while (<$fh>) {
 520                 if (/^\s*(?:#.*)?$/) { }
 521
 522                 elsif (/"/) {
 523                         print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 524                 }
 525
 526                 elsif (/^\s|\\$/) {
 527                         print STDERR "warning: sendmail continuation line is not supported: $_\n";
 528                 }
 529
 530                 elsif (/^(\S+?)\s*:\s*(.+)$/) {
 531                         my ($alias, $addr) = ($1, $2);
 532                         $aliases{$alias} = [ split_addrs($addr) ];
 533                 }
 534
 535                 else {
 536                         print STDERR "warning: sendmail line is not recognized: $_\n";
 537                 }}},
 538
 539         gnus => sub { my $fh = shift; while (<$fh>) {
 540                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 541                         $aliases{$1} = [ $2 ];
 542                 }}}
 543 );
 544
 545 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 546         foreach my $file (@alias_files) {
 547                 open my $fh, '<', $file or die "opening $file: $!\n";
 548                 $parse_alias{$aliasfiletype}->($fh);
 549                 close $fh;
 550         }
 551 }
 552
 553 ($sender) = expand_aliases($sender) if defined $sender;
 554
 555 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 556 # $f is a revision list specification to be passed to format-patch.
 557 sub is_format_patch_arg {
 558         return unless $repo;
 559         my $f = shift;
 560         try {
 561                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 562                 if (defined($format_patch)) {
 563                         return $format_patch;
 564                 }
 565                 die(<<EOF);
 566 File '$f' exists but it could also be the range of commits
 567 to produce patches for.  Please disambiguate by...
 568
 569     * Saying "./$f" if you mean a file; or
 570     * Giving --format-patch option if you mean a range.
 571 EOF
 572         } catch Git::Error::Command with {
 573                 # Not a valid revision.  Treat it as a filename.
 574                 return 0;
 575         }
 576 }
 577
 578 # Now that all the defaults are set, process the rest of the command line
 579 # arguments and collect up the files that need to be processed.
 580 my @rev_list_opts;
 581 while (defined(my $f = shift @ARGV)) {
 582         if ($f eq "--") {
 583                 push @rev_list_opts, "--", @ARGV;
 584                 @ARGV = ();
 585         } elsif (-d $f and !is_format_patch_arg($f)) {
 586                 opendir my $dh, $f
 587                         or die "Failed to opendir $f: $!";
 588
 589                 push @files, grep { -f $_ } map { catfile($f, $_) }
 590                                 sort readdir $dh;
 591                 closedir $dh;
 592         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 593                 push @files, $f;
 594         } else {
 595                 push @rev_list_opts, $f;
 596         }
 597 }
 598
 599 if (@rev_list_opts) {
 600         die "Cannot run git format-patch from outside a repository\n"
 601                 unless $repo;
 602         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 603 }
 604
 605 if ($validate) {
 606         foreach my $f (@files) {
 607                 unless (-p $f) {
 608                         my $error = validate_patch($f);
 609                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 610                 }
 611         }
 612 }
 613
 614 if (@files) {
 615         unless ($quiet) {
 616                 print $_,"\n" for (@files);
 617         }
 618 } else {
 619         print STDERR "\nNo patch files specified!\n\n";
 620         usage();
 621 }
 622
 623 sub get_patch_subject {
 624         my $fn = shift;
 625         open (my $fh, '<', $fn);
 626         while (my $line = <$fh>) {
 627                 next unless ($line =~ /^Subject: (.*)$/);
 628                 close $fh;
 629                 return "GIT: $1\n";
 630         }
 631         close $fh;
 632         die "No subject line in $fn ?";
 633 }
 634
 635 if ($compose) {
 636         # Note that this does not need to be secure, but we will make a small
 637         # effort to have it be unique
 638         $compose_filename = ($repo ?
 639                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 640                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 641         open my $c, ">", $compose_filename
 642                 or die "Failed to open for writing $compose_filename: $!";
 643
 644
 645         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 646         my $tpl_subject = $initial_subject || '';
 647         my $tpl_reply_to = $initial_reply_to || '';
 648
 649         print $c <<EOT;
 650 From $tpl_sender # This line is ignored.
 651 GIT: Lines beginning in "GIT:" will be removed.
 652 GIT: Consider including an overall diffstat or table of contents
 653 GIT: for the patch you are writing.
 654 GIT:
 655 GIT: Clear the body content if you don't wish to send a summary.
 656 From: $tpl_sender
 657 Subject: $tpl_subject
 658 In-Reply-To: $tpl_reply_to
 659
 660 EOT
 661         for my $f (@files) {
 662                 print $c get_patch_subject($f);
 663         }
 664         close $c;
 665
 666         if ($annotate) {
 667                 do_edit($compose_filename, @files);
 668         } else {
 669                 do_edit($compose_filename);
 670         }
 671
 672         open my $c2, ">", $compose_filename . ".final"
 673                 or die "Failed to open $compose_filename.final : " . $!;
 674
 675         open $c, "<", $compose_filename
 676                 or die "Failed to open $compose_filename : " . $!;
 677
 678         my $need_8bit_cte = file_has_nonascii($compose_filename);
 679         my $in_body = 0;
 680         my $summary_empty = 1;
 681         if (!defined $compose_encoding) {
 682                 $compose_encoding = "UTF-8";
 683         }
 684         while(<$c>) {
 685                 next if m/^GIT:/;
 686                 if ($in_body) {
 687                         $summary_empty = 0 unless (/^\n$/);
 688                 } elsif (/^\n$/) {
 689                         $in_body = 1;
 690                         if ($need_8bit_cte) {
 691                                 print $c2 "MIME-Version: 1.0\n",
 692                                          "Content-Type: text/plain; ",
 693                                            "charset=$compose_encoding\n",
 694                                          "Content-Transfer-Encoding: 8bit\n";
 695                         }
 696                 } elsif (/^MIME-Version:/i) {
 697                         $need_8bit_cte = 0;
 698                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 699                         $initial_subject = $1;
 700                         my $subject = $initial_subject;
 701                         $_ = "Subject: " .
 702                                 quote_subject($subject, $compose_encoding) .
 703                                 "\n";
 704                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 705                         $initial_reply_to = $1;
 706                         next;
 707                 } elsif (/^From:\s*(.+)\s*$/i) {
 708                         $sender = $1;
 709                         next;
 710                 } elsif (/^(?:To|Cc|Bcc):/i) {
 711                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 712                         next;
 713                 }
 714                 print $c2 $_;
 715         }
 716         close $c;
 717         close $c2;
 718
 719         if ($summary_empty) {
 720                 print "Summary email is empty, skipping it\n";
 721                 $compose = -1;
 722         }
 723 } elsif ($annotate) {
 724         do_edit(@files);
 725 }
 726
 727 sub ask {
 728         my ($prompt, %arg) = @_;
 729         my $valid_re = $arg{valid_re};
 730         my $default = $arg{default};
 731         my $confirm_only = $arg{confirm_only};
 732         my $resp;
 733         my $i = 0;
 734         return defined $default ? $default : undef
 735                 unless defined $term->IN and defined fileno($term->IN) and
 736                        defined $term->OUT and defined fileno($term->OUT);
 737         while ($i++ < 10) {
 738                 $resp = $term->readline($prompt);
 739                 if (!defined $resp) { # EOF
 740                         print "\n";
 741                         return defined $default ? $default : undef;
 742                 }
 743                 if ($resp eq '' and defined $default) {
 744                         return $default;
 745                 }
 746                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 747                         return $resp;
 748                 }
 749                 if ($confirm_only) {
 750                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 751                         if (defined $yesno && $yesno =~ /y/i) {
 752                                 return $resp;
 753                         }
 754                 }
 755         }
 756         return;
 757 }
 758
 759 my %broken_encoding;
 760
 761 sub file_declares_8bit_cte {
 762         my $fn = shift;
 763         open (my $fh, '<', $fn);
 764         while (my $line = <$fh>) {
 765                 last if ($line =~ /^$/);
 766                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 767         }
 768         close $fh;
 769         return 0;
 770 }
 771
 772 foreach my $f (@files) {
 773         next unless (body_or_subject_has_nonascii($f)
 774                      && !file_declares_8bit_cte($f));
 775         $broken_encoding{$f} = 1;
 776 }
 777
 778 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 779         print "The following files are 8bit, but do not declare " .
 780                 "a Content-Transfer-Encoding.\n";
 781         foreach my $f (sort keys %broken_encoding) {
 782                 print "    $f\n";
 783         }
 784         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 785                                   valid_re => qr/.{4}/, confirm_only => 1,
 786                                   default => "UTF-8");
 787 }
 788
 789 if (!$force) {
 790         for my $f (@files) {
 791                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 792                         die "Refusing to send because the patch\n\t$f\n"
 793                                 . "has the template subject '*** SUBJECT HERE ***'. "
 794                                 . "Pass --force if you really want to send.\n";
 795                 }
 796         }
 797 }
 798
 799 if (!defined $sender) {
 800         $sender = $repoauthor || $repocommitter || '';
 801 }
 802
 803 # $sender could be an already sanitized address
 804 # (e.g. sendemail.from could be manually sanitized by user).
 805 # But it's a no-op to run sanitize_address on an already sanitized address.
 806 $sender = sanitize_address($sender);
 807
 808 my $prompting = 0;
 809 if (!@initial_to && !defined $to_cmd) {
 810         my $to = ask("Who should the emails be sent to (if any)? ",
 811                      default => "",
 812                      valid_re => qr/\@.*\./, confirm_only => 1);
 813         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 814         $prompting++;
 815 }
 816
 817 sub expand_aliases {
 818         return map { expand_one_alias($_) } @_;
 819 }
 820
 821 my %EXPANDED_ALIASES;
 822 sub expand_one_alias {
 823         my $alias = shift;
 824         if ($EXPANDED_ALIASES{$alias}) {
 825                 die "fatal: alias '$alias' expands to itself\n";
 826         }
 827         local $EXPANDED_ALIASES{$alias} = 1;
 828         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 829 }
 830
 831 @initial_to = expand_aliases(@initial_to);
 832 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 833 @initial_cc = expand_aliases(@initial_cc);
 834 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 835 @bcclist = expand_aliases(@bcclist);
 836 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 837
 838 if ($thread && !defined $initial_reply_to && $prompting) {
 839         $initial_reply_to = ask(
 840                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 841                 default => "",
 842                 valid_re => qr/\@.*\./, confirm_only => 1);
 843 }
 844 if (defined $initial_reply_to) {
 845         $initial_reply_to =~ s/^\s*<?//;
 846         $initial_reply_to =~ s/>?\s*$//;
 847         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 848 }
 849
 850 if (!defined $smtp_server) {
 851         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 852                 if (-x $_) {
 853                         $smtp_server = $_;
 854                         last;
 855                 }
 856         }
 857         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 858 }
 859
 860 if ($compose && $compose > 0) {
 861         @files = ($compose_filename . ".final", @files);
 862 }
 863
 864 # Variables we set as part of the loop over files
 865 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 866         $needs_confirm, $message_num, $ask_default);
 867
 868 sub extract_valid_address {
 869         my $address = shift;
 870         my $local_part_regexp = qr/[^<>"\s@]+/;
 871         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 872
 873         # check for a local address:
 874         return $address if ($address =~ /^($local_part_regexp)$/);
 875
 876         $address =~ s/^\s*<(.*)>\s*$/$1/;
 877         if ($have_email_valid) {
 878                 return scalar Email::Valid->address($address);
 879         }
 880
 881         # less robust/correct than the monster regexp in Email::Valid,
 882         # but still does a 99% job, and one less dependency
 883         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 884         return;
 885 }
 886
 887 sub extract_valid_address_or_die {
 888         my $address = shift;
 889         $address = extract_valid_address($address);
 890         die "error: unable to extract a valid address from: $address\n"
 891                 if !$address;
 892         return $address;
 893 }
 894
 895 sub validate_address {
 896         my $address = shift;
 897         while (!extract_valid_address($address)) {
 898                 print STDERR "error: unable to extract a valid address from: $address\n";
 899                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 900                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 901                         default => 'q');
 902                 if (/^d/i) {
 903                         return undef;
 904                 } elsif (/^q/i) {
 905                         cleanup_compose_files();
 906                         exit(0);
 907                 }
 908                 $address = ask("Who should the email be sent to (if any)? ",
 909                         default => "",
 910                         valid_re => qr/\@.*\./, confirm_only => 1);
 911         }
 912         return $address;
 913 }
 914
 915 sub validate_address_list {
 916         return (grep { defined $_ }
 917                 map { validate_address($_) } @_);
 918 }
 919
 920 # Usually don't need to change anything below here.
 921
 922 # we make a "fake" message id by taking the current number
 923 # of seconds since the beginning of Unix time and tacking on
 924 # a random number to the end, in case we are called quicker than
 925 # 1 second since the last time we were called.
 926
 927 # We'll setup a template for the message id, using the "from" address:
 928
 929 my ($message_id_stamp, $message_id_serial);
 930 sub make_message_id {
 931         my $uniq;
 932         if (!defined $message_id_stamp) {
 933                 $message_id_stamp = sprintf("%s-%s", time, $$);
 934                 $message_id_serial = 0;
 935         }
 936         $message_id_serial++;
 937         $uniq = "$message_id_stamp-$message_id_serial";
 938
 939         my $du_part;
 940         for ($sender, $repocommitter, $repoauthor) {
 941                 $du_part = extract_valid_address(sanitize_address($_));
 942                 last if (defined $du_part and $du_part ne '');
 943         }
 944         if (not defined $du_part or $du_part eq '') {
 945                 require Sys::Hostname;
 946                 $du_part = 'user@' . Sys::Hostname::hostname();
 947         }
 948         my $message_id_template = "<%s-git-send-email-%s>";
 949         $message_id = sprintf($message_id_template, $uniq, $du_part);
 950         #print "new message id = $message_id\n"; # Was useful for debugging
 951 }
 952
 953
 954
 955 $time = time - scalar $#files;
 956
 957 sub unquote_rfc2047 {
 958         local ($_) = @_;
 959         my $charset;
 960         my $sep = qr/[ \t]+/;
 961         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 962                 my @words = split $sep, $&;
 963                 foreach (@words) {
 964                         m/$re_encoded_word/;
 965                         $charset = $1;
 966                         my $encoding = $2;
 967                         my $text = $3;
 968                         if ($encoding eq 'q' || $encoding eq 'Q') {
 969                                 $_ = $text;
 970                                 s/_/ /g;
 971                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 972                         } else {
 973                                 # other encodings not supported yet
 974                         }
 975                 }
 976                 join '', @words;
 977         }eg;
 978         return wantarray ? ($_, $charset) : $_;
 979 }
 980
 981 sub quote_rfc2047 {
 982         local $_ = shift;
 983         my $encoding = shift || 'UTF-8';
 984         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 985         s/(.*)/=\?$encoding\?q\?$1\?=/;
 986         return $_;
 987 }
 988
 989 sub is_rfc2047_quoted {
 990         my $s = shift;
 991         length($s) <= 75 &&
 992         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 993 }
 994
 995 sub subject_needs_rfc2047_quoting {
 996         my $s = shift;
 997
 998         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 999 }
1000
1001 sub quote_subject {
1002         local $subject = shift;
1003         my $encoding = shift || 'UTF-8';
1004
1005         if (subject_needs_rfc2047_quoting($subject)) {
1006                 return quote_rfc2047($subject, $encoding);
1007         }
1008         return $subject;
1009 }
1010
1011 # use the simplest quoting being able to handle the recipient
1012 sub sanitize_address {
1013         my ($recipient) = @_;
1014
1015         # remove garbage after email address
1016         $recipient =~ s/(.*>).*$/$1/;
1017
1018         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1019
1020         if (not $recipient_name) {
1021                 return $recipient;
1022         }
1023
1024         # if recipient_name is already quoted, do nothing
1025         if (is_rfc2047_quoted($recipient_name)) {
1026                 return $recipient;
1027         }
1028
1029         # rfc2047 is needed if a non-ascii char is included
1030         if ($recipient_name =~ /[^[:ascii:]]/) {
1031                 $recipient_name =~ s/^"(.*)"$/$1/;
1032                 $recipient_name = quote_rfc2047($recipient_name);
1033         }
1034
1035         # double quotes are needed if specials or CTLs are included
1036         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1037                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1038                 $recipient_name = qq["$recipient_name"];
1039         }
1040
1041         return "$recipient_name $recipient_addr";
1042
1043 }
1044
1045 sub sanitize_address_list {
1046         return (map { sanitize_address($_) } @_);
1047 }
1048
1049 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1050 #
1051 # Tightly configured MTAa require that a caller sends a real DNS
1052 # domain name that corresponds the IP address in the HELO/EHLO
1053 # handshake. This is used to verify the connection and prevent
1054 # spammers from trying to hide their identity. If the DNS and IP don't
1055 # match, the receiveing MTA may deny the connection.
1056 #
1057 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1058 #
1059 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1060 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1061 #
1062 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1063 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1064
1065 sub valid_fqdn {
1066         my $domain = shift;
1067         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1068 }
1069
1070 sub maildomain_net {
1071         my $maildomain;
1072
1073         if (eval { require Net::Domain; 1 }) {
1074                 my $domain = Net::Domain::domainname();
1075                 $maildomain = $domain if valid_fqdn($domain);
1076         }
1077
1078         return $maildomain;
1079 }
1080
1081 sub maildomain_mta {
1082         my $maildomain;
1083
1084         if (eval { require Net::SMTP; 1 }) {
1085                 for my $host (qw(mailhost localhost)) {
1086                         my $smtp = Net::SMTP->new($host);
1087                         if (defined $smtp) {
1088                                 my $domain = $smtp->domain;
1089                                 $smtp->quit;
1090
1091                                 $maildomain = $domain if valid_fqdn($domain);
1092
1093                                 last if $maildomain;
1094                         }
1095                 }
1096         }
1097
1098         return $maildomain;
1099 }
1100
1101 sub maildomain {
1102         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1103 }
1104
1105 sub smtp_host_string {
1106         if (defined $smtp_server_port) {
1107                 return "$smtp_server:$smtp_server_port";
1108         } else {
1109                 return $smtp_server;
1110         }
1111 }
1112
1113 # Returns 1 if authentication succeeded or was not necessary
1114 # (smtp_user was not specified), and 0 otherwise.
1115
1116 sub smtp_auth_maybe {
1117         if (!defined $smtp_authuser || $auth) {
1118                 return 1;
1119         }
1120
1121         # Workaround AUTH PLAIN/LOGIN interaction defect
1122         # with Authen::SASL::Cyrus
1123         eval {
1124                 require Authen::SASL;
1125                 Authen::SASL->import(qw(Perl));
1126         };
1127
1128         # TODO: Authentication may fail not because credentials were
1129         # invalid but due to other reasons, in which we should not
1130         # reject credentials.
1131         $auth = Git::credential({
1132                 'protocol' => 'smtp',
1133                 'host' => smtp_host_string(),
1134                 'username' => $smtp_authuser,
1135                 # if there's no password, "git credential fill" will
1136                 # give us one, otherwise it'll just pass this one.
1137                 'password' => $smtp_authpass
1138         }, sub {
1139                 my $cred = shift;
1140                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1141         });
1142
1143         return $auth;
1144 }
1145
1146 sub ssl_verify_params {
1147         eval {
1148                 require IO::Socket::SSL;
1149                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1150         };
1151         if ($@) {
1152                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1153                 return;
1154         }
1155
1156         if (!defined $smtp_ssl_cert_path) {
1157                 # use the OpenSSL defaults
1158                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1159         }
1160
1161         if ($smtp_ssl_cert_path eq "") {
1162                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1163         } elsif (-d $smtp_ssl_cert_path) {
1164                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1165                         SSL_ca_path => $smtp_ssl_cert_path);
1166         } elsif (-f $smtp_ssl_cert_path) {
1167                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1168                         SSL_ca_file => $smtp_ssl_cert_path);
1169         } else {
1170                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1171                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1172         }
1173 }
1174
1175 sub file_name_is_absolute {
1176         my ($path) = @_;
1177
1178         # msys does not grok DOS drive-prefixes
1179         if ($^O eq 'msys') {
1180                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1181         }
1182
1183         require File::Spec::Functions;
1184         return File::Spec::Functions::file_name_is_absolute($path);
1185 }
1186
1187 # Returns 1 if the message was sent, and 0 otherwise.
1188 # In actuality, the whole program dies when there
1189 # is an error sending a message.
1190
1191 sub send_message {
1192         my @recipients = unique_email_list(@to);
1193         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1194                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1195                     }
1196                @cc);
1197         my $to = join (",\n\t", @recipients);
1198         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1199         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1200         my $date = format_2822_time($time++);
1201         my $gitversion = '@@GIT_VERSION@@';
1202         if ($gitversion =~ m/..GIT_VERSION../) {
1203             $gitversion = Git::version();
1204         }
1205
1206         my $cc = join(",\n\t", unique_email_list(@cc));
1207         my $ccline = "";
1208         if ($cc ne '') {
1209                 $ccline = "\nCc: $cc";
1210         }
1211         make_message_id() unless defined($message_id);
1212
1213         my $header = "From: $sender
1214 To: $to${ccline}
1215 Subject: $subject
1216 Date: $date
1217 Message-Id: $message_id
1218 ";
1219         if ($use_xmailer) {
1220                 $header .= "X-Mailer: git-send-email $gitversion\n";
1221         }
1222         if ($reply_to) {
1223
1224                 $header .= "In-Reply-To: $reply_to\n";
1225                 $header .= "References: $references\n";
1226         }
1227         if (@xh) {
1228                 $header .= join("\n", @xh) . "\n";
1229         }
1230
1231         my @sendmail_parameters = ('-i', @recipients);
1232         my $raw_from = $sender;
1233         if (defined $envelope_sender && $envelope_sender ne "auto") {
1234                 $raw_from = $envelope_sender;
1235         }
1236         $raw_from = extract_valid_address($raw_from);
1237         unshift (@sendmail_parameters,
1238                         '-f', $raw_from) if(defined $envelope_sender);
1239
1240         if ($needs_confirm && !$dry_run) {
1241                 print "\n$header\n";
1242                 if ($needs_confirm eq "inform") {
1243                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1244                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1245                         print "    The Cc list above has been expanded by additional\n";
1246                         print "    addresses found in the patch commit message. By default\n";
1247                         print "    send-email prompts before sending whenever this occurs.\n";
1248                         print "    This behavior is controlled by the sendemail.confirm\n";
1249                         print "    configuration setting.\n";
1250                         print "\n";
1251                         print "    For additional information, run 'git send-email --help'.\n";
1252                         print "    To retain the current behavior, but squelch this message,\n";
1253                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1254                 }
1255                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1256                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1257                          default => $ask_default);
1258                 die "Send this email reply required" unless defined $_;
1259                 if (/^n/i) {
1260                         return 0;
1261                 } elsif (/^q/i) {
1262                         cleanup_compose_files();
1263                         exit(0);
1264                 } elsif (/^a/i) {
1265                         $confirm = 'never';
1266                 }
1267         }
1268
1269         unshift (@sendmail_parameters, @smtp_server_options);
1270
1271         if ($dry_run) {
1272                 # We don't want to send the email.
1273         } elsif (file_name_is_absolute($smtp_server)) {
1274                 my $pid = open my $sm, '|-';
1275                 defined $pid or die $!;
1276                 if (!$pid) {
1277                         exec($smtp_server, @sendmail_parameters) or die $!;
1278                 }
1279                 print $sm "$header\n$message";
1280                 close $sm or die $!;
1281         } else {
1282
1283                 if (!defined $smtp_server) {
1284                         die "The required SMTP server is not properly defined."
1285                 }
1286
1287                 if ($smtp_encryption eq 'ssl') {
1288                         $smtp_server_port ||= 465; # ssmtp
1289                         require Net::SMTP::SSL;
1290                         $smtp_domain ||= maildomain();
1291                         require IO::Socket::SSL;
1292                         # Net::SMTP::SSL->new() does not forward any SSL options
1293                         IO::Socket::SSL::set_client_defaults(
1294                                 ssl_verify_params());
1295                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1296                                                       Hello => $smtp_domain,
1297                                                       Port => $smtp_server_port,
1298                                                       Debug => $debug_net_smtp);
1299                 }
1300                 else {
1301                         require Net::SMTP;
1302                         $smtp_domain ||= maildomain();
1303                         $smtp_server_port ||= 25;
1304                         $smtp ||= Net::SMTP->new($smtp_server,
1305                                                  Hello => $smtp_domain,
1306                                                  Debug => $debug_net_smtp,
1307                                                  Port => $smtp_server_port);
1308                         if ($smtp_encryption eq 'tls' && $smtp) {
1309                                 require Net::SMTP::SSL;
1310                                 $smtp->command('STARTTLS');
1311                                 $smtp->response();
1312                                 if ($smtp->code == 220) {
1313                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1314                                                                           ssl_verify_params())
1315                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1316                                         $smtp_encryption = '';
1317                                         # Send EHLO again to receive fresh
1318                                         # supported commands
1319                                         $smtp->hello($smtp_domain);
1320                                 } else {
1321                                         die "Server does not support STARTTLS! ".$smtp->message;
1322                                 }
1323                         }
1324                 }
1325
1326                 if (!$smtp) {
1327                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1328                             "VALUES: server=$smtp_server ",
1329                             "encryption=$smtp_encryption ",
1330                             "hello=$smtp_domain",
1331                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1332                 }
1333
1334                 smtp_auth_maybe or die $smtp->message;
1335
1336                 $smtp->mail( $raw_from ) or die $smtp->message;
1337                 $smtp->to( @recipients ) or die $smtp->message;
1338                 $smtp->data or die $smtp->message;
1339                 $smtp->datasend("$header\n$message") or die $smtp->message;
1340                 $smtp->dataend() or die $smtp->message;
1341                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1342         }
1343         if ($quiet) {
1344                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1345         } else {
1346                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1347                 if (!file_name_is_absolute($smtp_server)) {
1348                         print "Server: $smtp_server\n";
1349                         print "MAIL FROM:<$raw_from>\n";
1350                         foreach my $entry (@recipients) {
1351                             print "RCPT TO:<$entry>\n";
1352                         }
1353                 } else {
1354                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1355                 }
1356                 print $header, "\n";
1357                 if ($smtp) {
1358                         print "Result: ", $smtp->code, ' ',
1359                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1360                 } else {
1361                         print "Result: OK\n";
1362                 }
1363         }
1364
1365         return 1;
1366 }
1367
1368 $reply_to = $initial_reply_to;
1369 $references = $initial_reply_to || '';
1370 $subject = $initial_subject;
1371 $message_num = 0;
1372
1373 foreach my $t (@files) {
1374         open my $fh, "<", $t or die "can't open file $t";
1375
1376         my $author = undef;
1377         my $sauthor = undef;
1378         my $author_encoding;
1379         my $has_content_type;
1380         my $body_encoding;
1381         my $xfer_encoding;
1382         my $has_mime_version;
1383         @to = ();
1384         @cc = ();
1385         @xh = ();
1386         my $input_format = undef;
1387         my @header = ();
1388         $message = "";
1389         $message_num++;
1390         # First unfold multiline header fields
1391         while(<$fh>) {
1392                 last if /^\s*$/;
1393                 if (/^\s+\S/ and @header) {
1394                         chomp($header[$#header]);
1395                         s/^\s+/ /;
1396                         $header[$#header] .= $_;
1397             } else {
1398                         push(@header, $_);
1399                 }
1400         }
1401         # Now parse the header
1402         foreach(@header) {
1403                 if (/^From /) {
1404                         $input_format = 'mbox';
1405                         next;
1406                 }
1407                 chomp;
1408                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1409                         $input_format = 'mbox';
1410                 }
1411
1412                 if (defined $input_format && $input_format eq 'mbox') {
1413                         if (/^Subject:\s+(.*)$/i) {
1414                                 $subject = $1;
1415                         }
1416                         elsif (/^From:\s+(.*)$/i) {
1417                                 ($author, $author_encoding) = unquote_rfc2047($1);
1418                                 $sauthor = sanitize_address($author);
1419                                 next if $suppress_cc{'author'};
1420                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1421                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1422                                         $1, $_) unless $quiet;
1423                                 push @cc, $1;
1424                         }
1425                         elsif (/^To:\s+(.*)$/i) {
1426                                 foreach my $addr (parse_address_line($1)) {
1427                                         printf("(mbox) Adding to: %s from line '%s'\n",
1428                                                 $addr, $_) unless $quiet;
1429                                         push @to, $addr;
1430                                 }
1431                         }
1432                         elsif (/^Cc:\s+(.*)$/i) {
1433                                 foreach my $addr (parse_address_line($1)) {
1434                                         my $qaddr = unquote_rfc2047($addr);
1435                                         my $saddr = sanitize_address($qaddr);
1436                                         if ($saddr eq $sender) {
1437                                                 next if ($suppress_cc{'self'});
1438                                         } else {
1439                                                 next if ($suppress_cc{'cc'});
1440                                         }
1441                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1442                                                 $addr, $_) unless $quiet;
1443                                         push @cc, $addr;
1444                                 }
1445                         }
1446                         elsif (/^Content-type:/i) {
1447                                 $has_content_type = 1;
1448                                 if (/charset="?([^ "]+)/) {
1449                                         $body_encoding = $1;
1450                                 }
1451                                 push @xh, $_;
1452                         }
1453                         elsif (/^MIME-Version/i) {
1454                                 $has_mime_version = 1;
1455                                 push @xh, $_;
1456                         }
1457                         elsif (/^Message-Id: (.*)/i) {
1458                                 $message_id = $1;
1459                         }
1460                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1461                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1462                         }
1463                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1464                                 push @xh, $_;
1465                         }
1466
1467                 } else {
1468                         # In the traditional
1469                         # "send lots of email" format,
1470                         # line 1 = cc
1471                         # line 2 = subject
1472                         # So let's support that, too.
1473                         $input_format = 'lots';
1474                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1475                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1476                                         $_, $_) unless $quiet;
1477                                 push @cc, $_;
1478                         } elsif (!defined $subject) {
1479                                 $subject = $_;
1480                         }
1481                 }
1482         }
1483         # Now parse the message body
1484         while(<$fh>) {
1485                 $message .=  $_;
1486                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1487                         chomp;
1488                         my ($what, $c) = ($1, $2);
1489                         chomp $c;
1490                         my $sc = sanitize_address($c);
1491                         if ($sc eq $sender) {
1492                                 next if ($suppress_cc{'self'});
1493                         } else {
1494                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1495                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1496                         }
1497                         push @cc, $c;
1498                         printf("(body) Adding cc: %s from line '%s'\n",
1499                                 $c, $_) unless $quiet;
1500                 }
1501         }
1502         close $fh;
1503
1504         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1505                 if defined $to_cmd;
1506         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1507                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1508
1509         if ($broken_encoding{$t} && !$has_content_type) {
1510                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1511                 $has_content_type = 1;
1512                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1513                 $body_encoding = $auto_8bit_encoding;
1514         }
1515
1516         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1517                 $subject = quote_subject($subject, $auto_8bit_encoding);
1518         }
1519
1520         if (defined $sauthor and $sauthor ne $sender) {
1521                 $message = "From: $author\n\n$message";
1522                 if (defined $author_encoding) {
1523                         if ($has_content_type) {
1524                                 if ($body_encoding eq $author_encoding) {
1525                                         # ok, we already have the right encoding
1526                                 }
1527                                 else {
1528                                         # uh oh, we should re-encode
1529                                 }
1530                         }
1531                         else {
1532                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1533                                 $has_content_type = 1;
1534                                 push @xh,
1535                                   "Content-Type: text/plain; charset=$author_encoding";
1536                         }
1537                 }
1538         }
1539         if (defined $target_xfer_encoding) {
1540                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1541                 $message = apply_transfer_encoding(
1542                         $message, $xfer_encoding, $target_xfer_encoding);
1543                 $xfer_encoding = $target_xfer_encoding;
1544         }
1545         if (defined $xfer_encoding) {
1546                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1547         }
1548         if (defined $xfer_encoding or $has_content_type) {
1549                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1550         }
1551
1552         $needs_confirm = (
1553                 $confirm eq "always" or
1554                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1555                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1556         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1557
1558         @to = validate_address_list(sanitize_address_list(@to));
1559         @cc = validate_address_list(sanitize_address_list(@cc));
1560
1561         @to = (@initial_to, @to);
1562         @cc = (@initial_cc, @cc);
1563
1564         if ($message_num == 1) {
1565                 if (defined $cover_cc and $cover_cc) {
1566                         @initial_cc = @cc;
1567                 }
1568                 if (defined $cover_to and $cover_to) {
1569                         @initial_to = @to;
1570                 }
1571         }
1572
1573         my $message_was_sent = send_message();
1574
1575         # set up for the next message
1576         if ($thread && $message_was_sent &&
1577                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1578                 $message_num == 1)) {
1579                 $reply_to = $message_id;
1580                 if (length $references > 0) {
1581                         $references .= "\n $message_id";
1582                 } else {
1583                         $references = "$message_id";
1584                 }
1585         }
1586         $message_id = undef;
1587 }
1588
1589 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1590 # and return a results array
1591 sub recipients_cmd {
1592         my ($prefix, $what, $cmd, $file) = @_;
1593
1594         my @addresses = ();
1595         open my $fh, "-|", "$cmd \Q$file\E"
1596             or die "($prefix) Could not execute '$cmd'";
1597         while (my $address = <$fh>) {
1598                 $address =~ s/^\s*//g;
1599                 $address =~ s/\s*$//g;
1600                 $address = sanitize_address($address);
1601                 next if ($address eq $sender and $suppress_cc{'self'});
1602                 push @addresses, $address;
1603                 printf("($prefix) Adding %s: %s from: '%s'\n",
1604                        $what, $address, $cmd) unless $quiet;
1605                 }
1606         close $fh
1607             or die "($prefix) failed to close pipe to '$cmd'";
1608         return @addresses;
1609 }
1610
1611 cleanup_compose_files();
1612
1613 sub cleanup_compose_files {
1614         unlink($compose_filename, $compose_filename . ".final") if $compose;
1615 }
1616
1617 $smtp->quit if $smtp;
1618
1619 sub apply_transfer_encoding {
1620         my $message = shift;
1621         my $from = shift;
1622         my $to = shift;
1623
1624         return $message if ($from eq $to and $from ne '7bit');
1625
1626         require MIME::QuotedPrint;
1627         require MIME::Base64;
1628
1629         $message = MIME::QuotedPrint::decode($message)
1630                 if ($from eq 'quoted-printable');
1631         $message = MIME::Base64::decode($message)
1632                 if ($from eq 'base64');
1633
1634         die "cannot send message as 7bit"
1635                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1636         return $message
1637                 if ($to eq '7bit' or $to eq '8bit');
1638         return MIME::QuotedPrint::encode($message, "\n", 0)
1639                 if ($to eq 'quoted-printable');
1640         return MIME::Base64::encode($message, "\n")
1641                 if ($to eq 'base64');
1642         die "invalid transfer encoding";
1643 }
1644
1645 sub unique_email_list {
1646         my %seen;
1647         my @emails;
1648
1649         foreach my $entry (@_) {
1650                 my $clean = extract_valid_address_or_die($entry);
1651                 $seen{$clean} ||= 0;
1652                 next if $seen{$clean}++;
1653                 push @emails, $entry;
1654         }
1655         return @emails;
1656 }
1657
1658 sub validate_patch {
1659         my $fn = shift;
1660         open(my $fh, '<', $fn)
1661                 or die "unable to open $fn: $!\n";
1662         while (my $line = <$fh>) {
1663                 if (length($line) > 998) {
1664                         return "$.: patch contains a line longer than 998 characters";
1665                 }
1666         }
1667         return;
1668 }
1669
1670 sub file_has_nonascii {
1671         my $fn = shift;
1672         open(my $fh, '<', $fn)
1673                 or die "unable to open $fn: $!\n";
1674         while (my $line = <$fh>) {
1675                 return 1 if $line =~ /[^[:ascii:]]/;
1676         }
1677         return 0;
1678 }
1679
1680 sub body_or_subject_has_nonascii {
1681         my $fn = shift;
1682         open(my $fh, '<', $fn)
1683                 or die "unable to open $fn: $!\n";
1684         while (my $line = <$fh>) {
1685                 last if $line =~ /^$/;
1686                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1687         }
1688         while (my $line = <$fh>) {
1689                 return 1 if $line =~ /[^[:ascii:]]/;
1690         }
1691         return 0;
1692 }