git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Set lib to alternative name of lib directory (e.g. lib64)
  73 AC_ARG_WITH([lib],
  74  [AS_HELP_STRING([--with-lib=ARG],
  75                  [ARG specifies alternative name for lib directory])],
  76  [if test "$withval" = "no" || test "$withval" = "yes"; then \
  77         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
  78 else \
  79         GIT_CONF_APPEND_LINE(lib=$withval); \
  80 fi; \
  81 ],[])
  82 #
  83 # Define SHELL_PATH to provide path to shell.
  84 GIT_ARG_SET_PATH(shell)
  85 #
  86 # Define PERL_PATH to provide path to Perl.
  87 GIT_ARG_SET_PATH(perl)
  88 #
  89 # Define ZLIB_PATH to provide path to zlib.
  90 GIT_ARG_SET_PATH(zlib)
  91 #
  92 # Declare the with-tcltk/without-tcltk options.
  93 AC_ARG_WITH(tcltk,
  94 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  95 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  96 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  97 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  98 GIT_PARSE_WITH(tcltk))
  99 #
 100
 101
 102 ## Checks for programs.
 103 AC_MSG_NOTICE([CHECKS for programs])
 104 #
 105 AC_PROG_CC([cc gcc])
 106 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 107 AC_CHECK_TOOLS(AR, [gar ar], :)
 108 AC_CHECK_PROGS(TAR, [gtar tar])
 109 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 110 # or will be empty otherwise.
 111 if test -z "$NO_TCLTK"; then
 112   if test "$with_tcltk" = ""; then
 113   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 114     TCLTK_PATH=wish
 115     AC_SUBST(TCLTK_PATH)
 116   elif test "$with_tcltk" = "yes"; then
 117   # Tcl/Tk check requested.
 118     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 119   else
 120     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 121     TCLTK_PATH="$with_tcltk"
 122     AC_SUBST(TCLTK_PATH)
 123   fi
 124 fi
 125 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 126 if test -n "$ASCIIDOC"; then
 127         AC_MSG_CHECKING([for asciidoc version])
 128         asciidoc_version=`$ASCIIDOC --version 2>&1`
 129         case "${asciidoc_version}" in
 130         asciidoc' '8*)
 131                 ASCIIDOC8=YesPlease
 132                 AC_MSG_RESULT([${asciidoc_version} > 7])
 133                 ;;
 134         asciidoc' '7*)
 135                 ASCIIDOC8=
 136                 AC_MSG_RESULT([${asciidoc_version}])
 137                 ;;
 138         *)
 139                 ASCIIDOC8=
 140                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 141                 ;;
 142         esac
 143 fi
 144 AC_SUBST(ASCIIDOC8)
 145
 146
 147 ## Checks for libraries.
 148 AC_MSG_NOTICE([CHECKS for libraries])
 149 #
 150 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 151 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 152 AC_CHECK_LIB([crypto], [SHA1_Init],
 153 [NEEDS_SSL_WITH_CRYPTO=],
 154 [AC_CHECK_LIB([ssl], [SHA1_Init],
 155  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 156   NEEDS_SSL_WITH_CRYPTO=],
 157  [NO_OPENSSL=YesPlease])])
 158 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 159 AC_SUBST(NO_OPENSSL)
 160 #
 161 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 162 # git-http-push are not built, and you cannot use http:// and https://
 163 # transports.
 164 AC_CHECK_LIB([curl], [curl_global_init],
 165 [NO_CURL=],
 166 [NO_CURL=YesPlease])
 167 AC_SUBST(NO_CURL)
 168 #
 169 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 170 # not built, and you cannot push using http:// and https:// transports.
 171 AC_CHECK_LIB([expat], [XML_ParserCreate],
 172 [NO_EXPAT=],
 173 [NO_EXPAT=YesPlease])
 174 AC_SUBST(NO_EXPAT)
 175 #
 176 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 177 # some Solaris installations).
 178 # Define NO_ICONV if neither libc nor libiconv support iconv.
 179 AC_DEFUN([ICONVTEST_SRC], [
 180 #include <iconv.h>
 181
 182 int main(void)
 183 {
 184         iconv_open("", "");
 185         return 0;
 186 }
 187 ])
 188 AC_MSG_CHECKING([for iconv in -lc])
 189 AC_LINK_IFELSE(ICONVTEST_SRC,
 190         [AC_MSG_RESULT([yes])
 191         NEEDS_LIBICONV=],
 192         [AC_MSG_RESULT([no])
 193         old_LIBS="$LIBS"
 194         LIBS="$LIBS -liconv"
 195         AC_MSG_CHECKING([for iconv in -liconv])
 196         AC_LINK_IFELSE(ICONVTEST_SRC,
 197                 [AC_MSG_RESULT([yes])
 198                 NEEDS_LIBICONV=YesPlease],
 199                 [AC_MSG_RESULT([no])
 200                 NO_ICONV=YesPlease])
 201         LIBS="$old_LIBS"])
 202 AC_SUBST(NEEDS_LIBICONV)
 203 AC_SUBST(NO_ICONV)
 204 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 205 #
 206 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 207 AC_DEFUN([ZLIBTEST_SRC], [
 208 #include <zlib.h>
 209
 210 int main(void)
 211 {
 212         deflateBound(0, 0);
 213         return 0;
 214 }
 215 ])
 216 AC_MSG_CHECKING([for deflateBound in -lz])
 217 old_LIBS="$LIBS"
 218 LIBS="$LIBS -lz"
 219 AC_LINK_IFELSE(ZLIBTEST_SRC,
 220         [AC_MSG_RESULT([yes])],
 221         [AC_MSG_RESULT([no])
 222         NO_DEFLATE_BOUND=yes])
 223 LIBS="$old_LIBS"
 224 AC_SUBST(NO_DEFLATE_BOUND)
 225 #
 226 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 227 # Patrick Mauritz).
 228 AC_CHECK_LIB([c], [socket],
 229 [NEEDS_SOCKET=],
 230 [NEEDS_SOCKET=YesPlease])
 231 AC_SUBST(NEEDS_SOCKET)
 232 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 233
 234
 235 ## Checks for header files.
 236 AC_MSG_NOTICE([CHECKS for header files])
 237 #
 238 # Define OLD_ICONV if your library has an old iconv(), where the second
 239 # (input buffer pointer) parameter is declared with type (const char **).
 240 AC_DEFUN([OLDICONVTEST_SRC], [[
 241 #include <iconv.h>
 242
 243 extern size_t iconv(iconv_t cd,
 244                     char **inbuf, size_t *inbytesleft,
 245                     char **outbuf, size_t *outbytesleft);
 246
 247 int main(void)
 248 {
 249         return 0;
 250 }
 251 ]])
 252 AC_MSG_CHECKING([for old iconv()])
 253 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 254         [AC_MSG_RESULT([no])],
 255         [AC_MSG_RESULT([yes])
 256         OLD_ICONV=UnfortunatelyYes])
 257 AC_SUBST(OLD_ICONV)
 258
 259
 260 ## Checks for typedefs, structures, and compiler characteristics.
 261 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 262 #
 263 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 264 AC_CHECK_MEMBER(struct dirent.d_ino,
 265 [NO_D_INO_IN_DIRENT=],
 266 [NO_D_INO_IN_DIRENT=YesPlease],
 267 [#include <dirent.h>])
 268 AC_SUBST(NO_D_INO_IN_DIRENT)
 269 #
 270 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 271 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 272 AC_CHECK_MEMBER(struct dirent.d_type,
 273 [NO_D_TYPE_IN_DIRENT=],
 274 [NO_D_TYPE_IN_DIRENT=YesPlease],
 275 [#include <dirent.h>])
 276 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 277 #
 278 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 279 # sockaddr_storage.
 280 AC_CHECK_TYPE(struct sockaddr_storage,
 281 [NO_SOCKADDR_STORAGE=],
 282 [NO_SOCKADDR_STORAGE=YesPlease],[
 283 #include <sys/types.h>
 284 #include <sys/socket.h>
 285 ])
 286 AC_SUBST(NO_SOCKADDR_STORAGE)
 287 #
 288 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 289 AC_CHECK_TYPE([struct addrinfo],[
 290  AC_CHECK_FUNC([getaddrinfo],
 291   [NO_IPV6=],
 292   [NO_IPV6=YesPlease])
 293 ],[NO_IPV6=YesPlease],[
 294 #include <sys/types.h>
 295 #include <sys/socket.h>
 296 #include <netdb.h>
 297 ])
 298 AC_SUBST(NO_IPV6)
 299 #
 300 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 301 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 302 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 303 # some C compilers supported these specifiers prior to C99 as an extension.
 304 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 305  [ac_cv_c_c99_format],
 306 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 307 AC_RUN_IFELSE(
 308         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 309                 [[char buf[64];
 310                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 311                   return 1;
 312                 else if (strcmp(buf, "12345"))
 313                   return 2;]])],
 314         [ac_cv_c_c99_format=yes],
 315         [ac_cv_c_c99_format=no])
 316 ])
 317 if test $ac_cv_c_c99_format = no; then
 318         NO_C99_FORMAT=YesPlease
 319 else
 320         NO_C99_FORMAT=
 321 fi
 322 AC_SUBST(NO_C99_FORMAT)
 323
 324
 325 ## Checks for library functions.
 326 ## (in default C library and libraries checked by AC_CHECK_LIB)
 327 AC_MSG_NOTICE([CHECKS for library functions])
 328 #
 329 # Define NO_STRCASESTR if you don't have strcasestr.
 330 AC_CHECK_FUNC(strcasestr,
 331 [NO_STRCASESTR=],
 332 [NO_STRCASESTR=YesPlease])
 333 AC_SUBST(NO_STRCASESTR)
 334 #
 335 # Define NO_MEMMEM if you don't have memmem.
 336 AC_CHECK_FUNC(memmem,
 337 [NO_MEMMEM=],
 338 [NO_MEMMEM=YesPlease])
 339 AC_SUBST(NO_MEMMEM)
 340 #
 341 # Define NO_STRLCPY if you don't have strlcpy.
 342 AC_CHECK_FUNC(strlcpy,
 343 [NO_STRLCPY=],
 344 [NO_STRLCPY=YesPlease])
 345 AC_SUBST(NO_STRLCPY)
 346 #
 347 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 348 AC_CHECK_FUNC(strtoumax,
 349 [NO_STRTOUMAX=],
 350 [NO_STRTOUMAX=YesPlease])
 351 AC_SUBST(NO_STRTOUMAX)
 352 #
 353 # Define NO_SETENV if you don't have setenv in the C library.
 354 AC_CHECK_FUNC(setenv,
 355 [NO_SETENV=],
 356 [NO_SETENV=YesPlease])
 357 AC_SUBST(NO_SETENV)
 358 #
 359 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 360 AC_CHECK_FUNC(unsetenv,
 361 [NO_UNSETENV=],
 362 [NO_UNSETENV=YesPlease])
 363 AC_SUBST(NO_UNSETENV)
 364 #
 365 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 366 AC_CHECK_FUNC(mkdtemp,
 367 [NO_MKDTEMP=],
 368 [NO_MKDTEMP=YesPlease])
 369 AC_SUBST(NO_MKDTEMP)
 370 #
 371 # Define NO_MMAP if you want to avoid mmap.
 372 #
 373 # Define NO_ICONV if your libc does not properly support iconv.
 374
 375
 376 ## Other checks.
 377 # Define USE_PIC if you need the main git objects to be built with -fPIC
 378 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 379 #
 380 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 381 # Enable it on Windows.  By default, symrefs are still used.
 382
 383 ## Site configuration (override autodetection)
 384 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 385 AC_MSG_NOTICE([CHECKS for site configuration])
 386 #
 387 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 388 # tests.  These tests take up a significant amount of the total test time
 389 # but are not needed unless you plan to talk to SVN repos.
 390 #
 391 # Define MOZILLA_SHA1 environment variable when running make to make use of
 392 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 393 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 394 # choice) has very fast version optimized for i586.
 395 #
 396 # Define PPC_SHA1 environment variable when running make to make use of
 397 # a bundled SHA1 routine optimized for PowerPC.
 398 #
 399 # Define ARM_SHA1 environment variable when running make to make use of
 400 # a bundled SHA1 routine optimized for ARM.
 401 #
 402 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 403 # This also implies MOZILLA_SHA1.
 404 #
 405 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 406 # /foo/bar/include and /foo/bar/lib directories.
 407 AC_ARG_WITH(openssl,
 408 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 409 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 410 GIT_PARSE_WITH(openssl))
 411 #
 412 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 413 # git-http-push are not built, and you cannot use http:// and https://
 414 # transports.
 415 #
 416 # Define CURLDIR=/foo/bar if your curl header and library files are in
 417 # /foo/bar/include and /foo/bar/lib directories.
 418 AC_ARG_WITH(curl,
 419 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 420 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 421 GIT_PARSE_WITH(curl))
 422 #
 423 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 424 # not built, and you cannot push using http:// and https:// transports.
 425 #
 426 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 427 # /foo/bar/include and /foo/bar/lib directories.
 428 AC_ARG_WITH(expat,
 429 AS_HELP_STRING([--with-expat],
 430 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 431 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 432 GIT_PARSE_WITH(expat))
 433 #
 434 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 435 # installed in /sw, but don't want GIT to link against any libraries
 436 # installed there.  If defined you may specify your own (or Fink's)
 437 # include directories and library directories by defining CFLAGS
 438 # and LDFLAGS appropriately.
 439 #
 440 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 441 # have DarwinPorts installed in /opt/local, but don't want GIT to
 442 # link against any libraries installed there.  If defined you may
 443 # specify your own (or DarwinPort's) include directories and
 444 # library directories by defining CFLAGS and LDFLAGS appropriately.
 445 #
 446 # Define NO_MMAP if you want to avoid mmap.
 447 #
 448 # Define NO_ICONV if your libc does not properly support iconv.
 449 AC_ARG_WITH(iconv,
 450 AS_HELP_STRING([--without-iconv],
 451 [if your architecture doesn't properly support iconv])
 452 AS_HELP_STRING([--with-iconv=PATH],
 453 [PATH is prefix for libiconv library and headers])
 454 AS_HELP_STRING([],
 455 [used only if you need linking with libiconv]),
 456 GIT_PARSE_WITH(iconv))
 457
 458 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 459 #
 460 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 461 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 462 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 463 # randomly break unless your underlying filesystem supports those sub-second
 464 # times (my ext3 doesn't).
 465 #
 466 # Define USE_STDEV below if you want git to care about the underlying device
 467 # change being considered an inode change from the update-index perspective.
 468
 469
 470 ## Output files
 471 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 472 AC_OUTPUT
 473
 474
 475 ## Cleanup
 476 rm -f "${config_append}"