git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $SVN_URL $SVN_INFO $SVN_WC $SVN_UUID
   8                 $GIT_SVN_INDEX $GIT_SVN
   9                 $GIT_DIR $GIT_SVN_DIR $REVDB/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Cwd qw/abs_path/;
  14 $GIT_DIR = abs_path($ENV{GIT_DIR} || '.git');
  15 $ENV{GIT_DIR} = $GIT_DIR;
  16
  17 my $LC_ALL = $ENV{LC_ALL};
  18 my $TZ = $ENV{TZ};
  19 # make sure the svn binary gives consistent output between locales and TZs:
  20 $ENV{TZ} = 'UTC';
  21 $ENV{LC_ALL} = 'C';
  22 $| = 1; # unbuffer STDOUT
  23
  24 # properties that we do not log:
  25 my %SKIP = ( 'svn:wc:ra_dav:version-url' => 1,
  26              'svn:special' => 1,
  27              'svn:executable' => 1,
  28              'svn:entry:committed-rev' => 1,
  29              'svn:entry:last-author' => 1,
  30              'svn:entry:uuid' => 1,
  31              'svn:entry:committed-date' => 1,
  32 );
  33
  34 sub fatal (@) { print STDERR @_; exit 1 }
  35 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  36 require SVN::Ra;
  37 require SVN::Delta;
  38 if ($SVN::Core::VERSION lt '1.1.0') {
  39         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  40 }
  41 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  42 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  43 *SVN::Git::Fetcher::process_rm = *process_rm;
  44 use Carp qw/croak/;
  45 use IO::File qw//;
  46 use File::Basename qw/dirname basename/;
  47 use File::Path qw/mkpath/;
  48 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  49 use POSIX qw/strftime/;
  50 use IPC::Open3;
  51 use Memoize;
  52 use Git qw/command command_oneline command_noisy
  53            command_output_pipe command_input_pipe command_close_pipe/;
  54 memoize('revisions_eq');
  55 memoize('cmt_metadata');
  56 memoize('get_commit_time');
  57
  58 my ($SVN);
  59
  60 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  61 my $sha1 = qr/[a-f\d]{40}/;
  62 my $sha1_short = qr/[a-f\d]{4,40}/;
  63 my $_esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
  64 my ($_revision,$_stdin,$_no_ignore_ext,$_no_stop_copy,$_help,$_rmdir,$_edit,
  65         $_find_copies_harder, $_l, $_cp_similarity, $_cp_remote,
  66         $_repack, $_repack_nr, $_repack_flags, $_q,
  67         $_message, $_file, $_follow_parent, $_no_metadata,
  68         $_template, $_shared, $_no_default_regex, $_no_graft_copy,
  69         $_limit, $_verbose, $_incremental, $_oneline, $_l_fmt, $_show_commit,
  70         $_version, $_upgrade, $_authors, $_branch_all_refs, @_opt_m,
  71         $_merge, $_strategy, $_dry_run, $_ignore_nodate, $_non_recursive,
  72         $_username, $_config_dir, $_no_auth_cache, $_xfer_delta,
  73         $_pager, $_color);
  74 my (@_branch_from, %tree_map, %users, %rusers, %equiv);
  75 my ($_svn_can_do_switch);
  76 my @repo_path_split_cache;
  77
  78 my %fc_opts = ( 'no-ignore-externals' => \$_no_ignore_ext,
  79                 'branch|b=s' => \@_branch_from,
  80                 'follow-parent|follow' => \$_follow_parent,
  81                 'branch-all-refs|B' => \$_branch_all_refs,
  82                 'authors-file|A=s' => \$_authors,
  83                 'repack:i' => \$_repack,
  84                 'no-metadata' => \$_no_metadata,
  85                 'quiet|q' => \$_q,
  86                 'username=s' => \$_username,
  87                 'config-dir=s' => \$_config_dir,
  88                 'no-auth-cache' => \$_no_auth_cache,
  89                 'ignore-nodate' => \$_ignore_nodate,
  90                 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags);
  91
  92 my ($_trunk, $_tags, $_branches);
  93 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  94                 'tags|t=s' => \$_tags,
  95                 'branches|b=s' => \$_branches );
  96 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  97 my %cmt_opts = ( 'edit|e' => \$_edit,
  98                 'rmdir' => \$_rmdir,
  99                 'find-copies-harder' => \$_find_copies_harder,
 100                 'l=i' => \$_l,
 101                 'copy-similarity|C=i'=> \$_cp_similarity
 102 );
 103
 104 my %cmd = (
 105         fetch => [ \&fetch, "Download new revisions from SVN",
 106                         { 'revision|r=s' => \$_revision, %fc_opts } ],
 107         init => [ \&init, "Initialize a repo for tracking" .
 108                           " (requires URL argument)",
 109                           \%init_opts ],
 110         dcommit => [ \&dcommit, 'Commit several diffs to merge with upstream',
 111                         { 'merge|m|M' => \$_merge,
 112                           'strategy|s=s' => \$_strategy,
 113                           'dry-run|n' => \$_dry_run,
 114                         %cmt_opts } ],
 115         'set-tree' => [ \&commit, "Set an SVN repository to a git tree-ish",
 116                         {       'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 117         'show-ignore' => [ \&show_ignore, "Show svn:ignore listings",
 118                         { 'revision|r=i' => \$_revision } ],
 119         rebuild => [ \&rebuild, "Rebuild git-svn metadata (after git clone)",
 120                         { 'no-ignore-externals' => \$_no_ignore_ext,
 121                           'copy-remote|remote=s' => \$_cp_remote,
 122                           'upgrade' => \$_upgrade } ],
 123         'graft-branches' => [ \&graft_branches,
 124                         'Detect merges/branches from already imported history',
 125                         { 'merge-rx|m' => \@_opt_m,
 126                           'branch|b=s' => \@_branch_from,
 127                           'branch-all-refs|B' => \$_branch_all_refs,
 128                           'no-default-regex' => \$_no_default_regex,
 129                           'no-graft-copy' => \$_no_graft_copy } ],
 130         'multi-init' => [ \&multi_init,
 131                         'Initialize multiple trees (like git-svnimport)',
 132                         { %multi_opts, %init_opts,
 133                          'revision|r=i' => \$_revision,
 134                          'username=s' => \$_username,
 135                          'config-dir=s' => \$_config_dir,
 136                          'no-auth-cache' => \$_no_auth_cache,
 137                         } ],
 138         'multi-fetch' => [ \&multi_fetch,
 139                         'Fetch multiple trees (like git-svnimport)',
 140                         \%fc_opts ],
 141         'log' => [ \&show_log, 'Show commit logs',
 142                         { 'limit=i' => \$_limit,
 143                           'revision|r=s' => \$_revision,
 144                           'verbose|v' => \$_verbose,
 145                           'incremental' => \$_incremental,
 146                           'oneline' => \$_oneline,
 147                           'show-commit' => \$_show_commit,
 148                           'non-recursive' => \$_non_recursive,
 149                           'authors-file|A=s' => \$_authors,
 150                           'color' => \$_color,
 151                           'pager=s' => \$_pager,
 152                         } ],
 153         'commit-diff' => [ \&commit_diff, 'Commit a diff between two trees',
 154                         { 'message|m=s' => \$_message,
 155                           'file|F=s' => \$_file,
 156                           'revision|r=s' => \$_revision,
 157                         %cmt_opts } ],
 158 );
 159
 160 my $cmd;
 161 for (my $i = 0; $i < @ARGV; $i++) {
 162         if (defined $cmd{$ARGV[$i]}) {
 163                 $cmd = $ARGV[$i];
 164                 splice @ARGV, $i, 1;
 165                 last;
 166         }
 167 };
 168
 169 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 170
 171 read_repo_config(\%opts);
 172 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
 173                                 'version|V' => \$_version,
 174                                 'id|i=s' => \$GIT_SVN);
 175 exit 1 if (!$rv && $cmd ne 'log');
 176
 177 set_default_vals();
 178 usage(0) if $_help;
 179 version() if $_version;
 180 usage(1) unless defined $cmd;
 181 init_vars();
 182 load_authors() if $_authors;
 183 load_all_refs() if $_branch_all_refs;
 184 migration_check() unless $cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/;
 185 $cmd{$cmd}->[0]->(@ARGV);
 186 exit 0;
 187
 188 ####################### primary functions ######################
 189 sub usage {
 190         my $exit = shift || 0;
 191         my $fd = $exit ? \*STDERR : \*STDOUT;
 192         print $fd <<"";
 193 git-svn - bidirectional operations between a single Subversion tree and git
 194 Usage: $0 <command> [options] [arguments]\n
 195
 196         print $fd "Available commands:\n" unless $cmd;
 197
 198         foreach (sort keys %cmd) {
 199                 next if $cmd && $cmd ne $_;
 200                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 201                 foreach (keys %{$cmd{$_}->[2]}) {
 202                         # prints out arguments as they should be passed:
 203                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 204                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 205                                                         "--$_" : "-$_" }
 206                                                 split /\|/,$_)," $x\n";
 207                 }
 208         }
 209         print $fd <<"";
 210 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 211 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 212 one git repository and want to keep them separate.  See git-svn(1) for more
 213 information.
 214
 215         exit $exit;
 216 }
 217
 218 sub version {
 219         print "git-svn version $VERSION\n";
 220         exit 0;
 221 }
 222
 223 sub rebuild {
 224         if (!verify_ref("refs/remotes/$GIT_SVN^0")) {
 225                 copy_remote_ref();
 226         }
 227         $SVN_URL = shift or undef;
 228         my $newest_rev = 0;
 229         if ($_upgrade) {
 230                 command_noisy('update-ref',"refs/remotes/$GIT_SVN","
 231                               $GIT_SVN-HEAD");
 232         } else {
 233                 check_upgrade_needed();
 234         }
 235
 236         my ($rev_list, $ctx) = command_output_pipe("rev-list",
 237                                                    "refs/remotes/$GIT_SVN");
 238         my $latest;
 239         while (<$rev_list>) {
 240                 chomp;
 241                 my $c = $_;
 242                 croak "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
 243                 my @commit = grep(/^git-svn-id: /,
 244                                   command(qw/cat-file commit/, $c));
 245                 next if (!@commit); # skip merges
 246                 my ($url, $rev, $uuid) = extract_metadata($commit[$#commit]);
 247                 if (!defined $rev || !$uuid) {
 248                         croak "Unable to extract revision or UUID from ",
 249                                 "$c, $commit[$#commit]\n";
 250                 }
 251
 252                 # if we merged or otherwise started elsewhere, this is
 253                 # how we break out of it
 254                 next if (defined $SVN_UUID && ($uuid ne $SVN_UUID));
 255                 next if (defined $SVN_URL && defined $url && ($url ne $SVN_URL));
 256
 257                 unless (defined $latest) {
 258                         if (!$SVN_URL && !$url) {
 259                                 croak "SVN repository location required: $url\n";
 260                         }
 261                         $SVN_URL ||= $url;
 262                         $SVN_UUID ||= $uuid;
 263                         setup_git_svn();
 264                         $latest = $rev;
 265                 }
 266                 revdb_set($REVDB, $rev, $c);
 267                 print "r$rev = $c\n";
 268                 $newest_rev = $rev if ($rev > $newest_rev);
 269         }
 270         command_close_pipe($rev_list, $ctx);
 271 }
 272
 273 sub init {
 274         my $url = shift or die "SVN repository location required " .
 275                                 "as a command-line argument\n";
 276         $url =~ s!/+$!!; # strip trailing slash
 277
 278         if (my $repo_path = shift) {
 279                 unless (-d $repo_path) {
 280                         mkpath([$repo_path]);
 281                 }
 282                 $GIT_DIR = $ENV{GIT_DIR} = $repo_path . "/.git";
 283                 init_vars();
 284         }
 285
 286         $SVN_URL = $url;
 287         unless (-d $GIT_DIR) {
 288                 my @init_db = ('init-db');
 289                 push @init_db, "--template=$_template" if defined $_template;
 290                 push @init_db, "--shared" if defined $_shared;
 291                 command_noisy(@init_db);
 292         }
 293         setup_git_svn();
 294 }
 295
 296 sub fetch {
 297         check_upgrade_needed();
 298         $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
 299         my $ret = fetch_lib(@_);
 300         if ($ret->{commit} && !verify_ref('refs/heads/master^0')) {
 301                 command_noisy(qw(update-ref refs/heads/master),$ret->{commit});
 302         }
 303         return $ret;
 304 }
 305
 306 sub fetch_lib {
 307         my (@parents) = @_;
 308         $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
 309         $SVN ||= libsvn_connect($SVN_URL);
 310         my ($last_rev, $last_commit) = svn_grab_base_rev();
 311         my ($base, $head) = libsvn_parse_revision($last_rev);
 312         if ($base > $head) {
 313                 return { revision => $last_rev, commit => $last_commit }
 314         }
 315         my $index = set_index($GIT_SVN_INDEX);
 316
 317         # limit ourselves and also fork() since get_log won't release memory
 318         # after processing a revision and SVN stuff seems to leak
 319         my $inc = 1000;
 320         my ($min, $max) = ($base, $head < $base+$inc ? $head : $base+$inc);
 321         read_uuid();
 322         if (defined $last_commit) {
 323                 unless (-e $GIT_SVN_INDEX) {
 324                         command_noisy('read-tree', $last_commit);
 325                 }
 326                 my $x = command_oneline('write-tree');
 327                 my ($y) = (command(qw/cat-file commit/, $last_commit)
 328                                                         =~ /^tree ($sha1)/m);
 329                 if ($y ne $x) {
 330                         unlink $GIT_SVN_INDEX or croak $!;
 331                         command_noisy('read-tree', $last_commit);
 332                 }
 333                 $x = command_oneline('write-tree');
 334                 if ($y ne $x) {
 335                         print STDERR "trees ($last_commit) $y != $x\n",
 336                                  "Something is seriously wrong...\n";
 337                 }
 338         }
 339         while (1) {
 340                 # fork, because using SVN::Pool with get_log() still doesn't
 341                 # seem to help enough to keep memory usage down.
 342                 defined(my $pid = fork) or croak $!;
 343                 if (!$pid) {
 344                         $SVN::Error::handler = \&libsvn_skip_unknown_revs;
 345
 346                         # Yes I'm perfectly aware that the fourth argument
 347                         # below is the limit revisions number.  Unfortunately
 348                         # performance sucks with it enabled, so it's much
 349                         # faster to fetch revision ranges instead of relying
 350                         # on the limiter.
 351                         libsvn_get_log(libsvn_dup_ra($SVN), [''],
 352                                         $min, $max, 0, 1, 1,
 353                                 sub {
 354                                         my $log_msg;
 355                                         if ($last_commit) {
 356                                                 $log_msg = libsvn_fetch(
 357                                                         $last_commit, @_);
 358                                                 $last_commit = git_commit(
 359                                                         $log_msg,
 360                                                         $last_commit,
 361                                                         @parents);
 362                                         } else {
 363                                                 $log_msg = libsvn_new_tree(@_);
 364                                                 $last_commit = git_commit(
 365                                                         $log_msg, @parents);
 366                                         }
 367                                 });
 368                         exit 0;
 369                 }
 370                 waitpid $pid, 0;
 371                 croak $? if $?;
 372                 ($last_rev, $last_commit) = svn_grab_base_rev();
 373                 last if ($max >= $head);
 374                 $min = $max + 1;
 375                 $max += $inc;
 376                 $max = $head if ($max > $head);
 377                 $SVN = libsvn_connect($SVN_URL);
 378         }
 379         restore_index($index);
 380         return { revision => $last_rev, commit => $last_commit };
 381 }
 382
 383 sub commit {
 384         my (@commits) = @_;
 385         check_upgrade_needed();
 386         if ($_stdin || !@commits) {
 387                 print "Reading from stdin...\n";
 388                 @commits = ();
 389                 while (<STDIN>) {
 390                         if (/\b($sha1_short)\b/o) {
 391                                 unshift @commits, $1;
 392                         }
 393                 }
 394         }
 395         my @revs;
 396         foreach my $c (@commits) {
 397                 my @tmp = command('rev-parse',$c);
 398                 if (scalar @tmp == 1) {
 399                         push @revs, $tmp[0];
 400                 } elsif (scalar @tmp > 1) {
 401                         push @revs, reverse(command('rev-list',@tmp));
 402                 } else {
 403                         die "Failed to rev-parse $c\n";
 404                 }
 405         }
 406         commit_lib(@revs);
 407         print "Done committing ",scalar @revs," revisions to SVN\n";
 408 }
 409
 410 sub commit_lib {
 411         my (@revs) = @_;
 412         my ($r_last, $cmt_last) = svn_grab_base_rev();
 413         defined $r_last or die "Must have an existing revision to commit\n";
 414         my $fetched = fetch();
 415         if ($r_last != $fetched->{revision}) {
 416                 print STDERR "There are new revisions that were fetched ",
 417                                 "and need to be merged (or acknowledged) ",
 418                                 "before committing.\n",
 419                                 "last rev: $r_last\n",
 420                                 " current: $fetched->{revision}\n";
 421                 exit 1;
 422         }
 423         read_uuid();
 424         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
 425         my $commit_msg = "$GIT_SVN_DIR/.svn-commit.tmp.$$";
 426
 427         my $repo;
 428         set_svn_commit_env();
 429         foreach my $c (@revs) {
 430                 my $log_msg = get_commit_message($c, $commit_msg);
 431
 432                 # fork for each commit because there's a memory leak I
 433                 # can't track down... (it's probably in the SVN code)
 434                 defined(my $pid = open my $fh, '-|') or croak $!;
 435                 if (!$pid) {
 436                         my $ed = SVN::Git::Editor->new(
 437                                         {       r => $r_last,
 438                                                 ra => libsvn_dup_ra($SVN),
 439                                                 c => $c,
 440                                                 svn_path => $SVN->{svn_path},
 441                                         },
 442                                         $SVN->get_commit_editor(
 443                                                 $log_msg->{msg},
 444                                                 sub {
 445                                                         libsvn_commit_cb(
 446                                                                 @_, $c,
 447                                                                 $log_msg->{msg},
 448                                                                 $r_last,
 449                                                                 $cmt_last)
 450                                                 },
 451                                                 @lock)
 452                                         );
 453                         my $mods = libsvn_checkout_tree($cmt_last, $c, $ed);
 454                         if (@$mods == 0) {
 455                                 print "No changes\nr$r_last = $cmt_last\n";
 456                                 $ed->abort_edit;
 457                         } else {
 458                                 $ed->close_edit;
 459                         }
 460                         exit 0;
 461                 }
 462                 my ($r_new, $cmt_new, $no);
 463                 while (<$fh>) {
 464                         print $_;
 465                         chomp;
 466                         if (/^r(\d+) = ($sha1)$/o) {
 467                                 ($r_new, $cmt_new) = ($1, $2);
 468                         } elsif ($_ eq 'No changes') {
 469                                 $no = 1;
 470                         }
 471                 }
 472                 close $fh or exit 1;
 473                 if (! defined $r_new && ! defined $cmt_new) {
 474                         unless ($no) {
 475                                 die "Failed to parse revision information\n";
 476                         }
 477                 } else {
 478                         ($r_last, $cmt_last) = ($r_new, $cmt_new);
 479                 }
 480         }
 481         $ENV{LC_ALL} = 'C';
 482         unlink $commit_msg;
 483 }
 484
 485 sub dcommit {
 486         my $head = shift || 'HEAD';
 487         my $gs = "refs/remotes/$GIT_SVN";
 488         my @refs = command(qw/rev-list --no-merges/, "$gs..$head");
 489         my $last_rev;
 490         foreach my $d (reverse @refs) {
 491                 if (!verify_ref("$d~1")) {
 492                         die "Commit $d\n",
 493                             "has no parent commit, and therefore ",
 494                             "nothing to diff against.\n",
 495                             "You should be working from a repository ",
 496                             "originally created by git-svn\n";
 497                 }
 498                 unless (defined $last_rev) {
 499                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 500                         unless (defined $last_rev) {
 501                                 die "Unable to extract revision information ",
 502                                     "from commit $d~1\n";
 503                         }
 504                 }
 505                 if ($_dry_run) {
 506                         print "diff-tree $d~1 $d\n";
 507                 } else {
 508                         if (my $r = commit_diff("$d~1", $d, undef, $last_rev)) {
 509                                 $last_rev = $r;
 510                         } # else: no changes, same $last_rev
 511                 }
 512         }
 513         return if $_dry_run;
 514         fetch();
 515         my @diff = command('diff-tree', $head, $gs, '--');
 516         my @finish;
 517         if (@diff) {
 518                 @finish = qw/rebase/;
 519                 push @finish, qw/--merge/ if $_merge;
 520                 push @finish, "--strategy=$_strategy" if $_strategy;
 521                 print STDERR "W: $head and $gs differ, using @finish:\n", @diff;
 522         } else {
 523                 print "No changes between current $head and $gs\n",
 524                       "Resetting to the latest $gs\n";
 525                 @finish = qw/reset --mixed/;
 526         }
 527         command_noisy(@finish, $gs);
 528 }
 529
 530 sub show_ignore {
 531         $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
 532         my $repo;
 533         $SVN ||= libsvn_connect($SVN_URL);
 534         my $r = defined $_revision ? $_revision : $SVN->get_latest_revnum;
 535         libsvn_traverse_ignore(\*STDOUT, $SVN->{svn_path}, $r);
 536 }
 537
 538 sub graft_branches {
 539         my $gr_file = "$GIT_DIR/info/grafts";
 540         my ($grafts, $comments) = read_grafts($gr_file);
 541         my $gr_sha1;
 542
 543         if (%$grafts) {
 544                 # temporarily disable our grafts file to make this idempotent
 545                 chomp($gr_sha1 = command(qw/hash-object -w/,$gr_file));
 546                 rename $gr_file, "$gr_file~$gr_sha1" or croak $!;
 547         }
 548
 549         my $l_map = read_url_paths();
 550         my @re = map { qr/$_/is } @_opt_m if @_opt_m;
 551         unless ($_no_default_regex) {
 552                 push @re, (qr/\b(?:merge|merging|merged)\s+with\s+([\w\.\-]+)/i,
 553                         qr/\b(?:merge|merging|merged)\s+([\w\.\-]+)/i,
 554                         qr/\b(?:from|of)\s+([\w\.\-]+)/i );
 555         }
 556         foreach my $u (keys %$l_map) {
 557                 if (@re) {
 558                         foreach my $p (keys %{$l_map->{$u}}) {
 559                                 graft_merge_msg($grafts,$l_map,$u,$p,@re);
 560                         }
 561                 }
 562                 unless ($_no_graft_copy) {
 563                         graft_file_copy_lib($grafts,$l_map,$u);
 564                 }
 565         }
 566         graft_tree_joins($grafts);
 567
 568         write_grafts($grafts, $comments, $gr_file);
 569         unlink "$gr_file~$gr_sha1" if $gr_sha1;
 570 }
 571
 572 sub multi_init {
 573         my $url = shift;
 574         $_trunk ||= 'trunk';
 575         $_trunk =~ s#/+$##;
 576         $url =~ s#/+$## if $url;
 577         if ($_trunk !~ m#^[a-z\+]+://#) {
 578                 $_trunk = '/' . $_trunk if ($_trunk !~ m#^/#);
 579                 unless ($url) {
 580                         print STDERR "E: '$_trunk' is not a complete URL ",
 581                                 "and a separate URL is not specified\n";
 582                         exit 1;
 583                 }
 584                 $_trunk = $url . $_trunk;
 585         }
 586         my $ch_id;
 587         if ($GIT_SVN eq 'git-svn') {
 588                 $ch_id = 1;
 589                 $GIT_SVN = $ENV{GIT_SVN_ID} = 'trunk';
 590         }
 591         init_vars();
 592         unless (-d $GIT_SVN_DIR) {
 593                 print "GIT_SVN_ID set to 'trunk' for $_trunk\n" if $ch_id;
 594                 init($_trunk);
 595                 command_noisy('repo-config', 'svn.trunk', $_trunk);
 596         }
 597         complete_url_ls_init($url, $_branches, '--branches/-b', '');
 598         complete_url_ls_init($url, $_tags, '--tags/-t', 'tags/');
 599 }
 600
 601 sub multi_fetch {
 602         # try to do trunk first, since branches/tags
 603         # may be descended from it.
 604         if (-e "$GIT_DIR/svn/trunk/info/url") {
 605                 fetch_child_id('trunk', @_);
 606         }
 607         rec_fetch('', "$GIT_DIR/svn", @_);
 608 }
 609
 610 sub show_log {
 611         my (@args) = @_;
 612         my ($r_min, $r_max);
 613         my $r_last = -1; # prevent dupes
 614         rload_authors() if $_authors;
 615         if (defined $TZ) {
 616                 $ENV{TZ} = $TZ;
 617         } else {
 618                 delete $ENV{TZ};
 619         }
 620         if (defined $_revision) {
 621                 if ($_revision =~ /^(\d+):(\d+)$/) {
 622                         ($r_min, $r_max) = ($1, $2);
 623                 } elsif ($_revision =~ /^\d+$/) {
 624                         $r_min = $r_max = $_revision;
 625                 } else {
 626                         print STDERR "-r$_revision is not supported, use ",
 627                                 "standard \'git log\' arguments instead\n";
 628                         exit 1;
 629                 }
 630         }
 631
 632         config_pager();
 633         @args = (git_svn_log_cmd($r_min, $r_max), @args);
 634         my $log = command_output_pipe(@args);
 635         run_pager();
 636         my (@k, $c, $d);
 637
 638         while (<$log>) {
 639                 if (/^${_esc_color}commit ($sha1_short)/o) {
 640                         my $cmt = $1;
 641                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
 642                                 $r_last = $c->{r};
 643                                 process_commit($c, $r_min, $r_max, \@k) or
 644                                                                 goto out;
 645                         }
 646                         $d = undef;
 647                         $c = { c => $cmt };
 648                 } elsif (/^${_esc_color}author (.+) (\d+) ([\-\+]?\d+)$/) {
 649                         get_author_info($c, $1, $2, $3);
 650                 } elsif (/^${_esc_color}(?:tree|parent|committer) /) {
 651                         # ignore
 652                 } elsif (/^${_esc_color}:\d{6} \d{6} $sha1_short/o) {
 653                         push @{$c->{raw}}, $_;
 654                 } elsif (/^${_esc_color}[ACRMDT]\t/) {
 655                         # we could add $SVN->{svn_path} here, but that requires
 656                         # remote access at the moment (repo_path_split)...
 657                         s#^(${_esc_color})([ACRMDT])\t#$1   $2 #;
 658                         push @{$c->{changed}}, $_;
 659                 } elsif (/^${_esc_color}diff /) {
 660                         $d = 1;
 661                         push @{$c->{diff}}, $_;
 662                 } elsif ($d) {
 663                         push @{$c->{diff}}, $_;
 664                 } elsif (/^${_esc_color}    (git-svn-id:.+)$/) {
 665                         ($c->{url}, $c->{r}, undef) = extract_metadata($1);
 666                 } elsif (s/^${_esc_color}    //) {
 667                         push @{$c->{l}}, $_;
 668                 }
 669         }
 670         if ($c && defined $c->{r} && $c->{r} != $r_last) {
 671                 $r_last = $c->{r};
 672                 process_commit($c, $r_min, $r_max, \@k);
 673         }
 674         if (@k) {
 675                 my $swap = $r_max;
 676                 $r_max = $r_min;
 677                 $r_min = $swap;
 678                 process_commit($_, $r_min, $r_max) foreach reverse @k;
 679         }
 680 out:
 681         eval { command_close_pipe($log) };
 682         print '-' x72,"\n" unless $_incremental || $_oneline;
 683 }
 684
 685 sub commit_diff_usage {
 686         print STDERR "Usage: $0 commit-diff <tree-ish> <tree-ish> [<URL>]\n";
 687         exit 1
 688 }
 689
 690 sub commit_diff {
 691         my $ta = shift or commit_diff_usage();
 692         my $tb = shift or commit_diff_usage();
 693         if (!eval { $SVN_URL = shift || file_to_s("$GIT_SVN_DIR/info/url") }) {
 694                 print STDERR "Needed URL or usable git-svn id command-line\n";
 695                 commit_diff_usage();
 696         }
 697         my $r = shift;
 698         unless (defined $r) {
 699                 if (defined $_revision) {
 700                         $r = $_revision
 701                 } else {
 702                         die "-r|--revision is a required argument\n";
 703                 }
 704         }
 705         if (defined $_message && defined $_file) {
 706                 print STDERR "Both --message/-m and --file/-F specified ",
 707                                 "for the commit message.\n",
 708                                 "I have no idea what you mean\n";
 709                 exit 1;
 710         }
 711         if (defined $_file) {
 712                 $_message = file_to_s($_file);
 713         } else {
 714                 $_message ||= get_commit_message($tb,
 715                                         "$GIT_DIR/.svn-commit.tmp.$$")->{msg};
 716         }
 717         $SVN ||= libsvn_connect($SVN_URL);
 718         if ($r eq 'HEAD') {
 719                 $r = $SVN->get_latest_revnum;
 720         } elsif ($r !~ /^\d+$/) {
 721                 die "revision argument: $r not understood by git-svn\n";
 722         }
 723         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
 724         my $rev_committed;
 725         my $ed = SVN::Git::Editor->new({        r => $r,
 726                                                 ra => libsvn_dup_ra($SVN),
 727                                                 c => $tb,
 728                                                 svn_path => $SVN->{svn_path}
 729                                         },
 730                                 $SVN->get_commit_editor($_message,
 731                                         sub {
 732                                                 $rev_committed = $_[0];
 733                                                 print "Committed $_[0]\n";
 734                                         }, @lock)
 735                                 );
 736         eval {
 737                 my $mods = libsvn_checkout_tree($ta, $tb, $ed);
 738                 if (@$mods == 0) {
 739                         print "No changes\n$ta == $tb\n";
 740                         $ed->abort_edit;
 741                 } else {
 742                         $ed->close_edit;
 743                 }
 744         };
 745         fatal "$@\n" if $@;
 746         $_message = $_file = undef;
 747         return $rev_committed;
 748 }
 749
 750 ########################### utility functions #########################
 751
 752 sub cmt_showable {
 753         my ($c) = @_;
 754         return 1 if defined $c->{r};
 755         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
 756                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
 757                 my @msg = command(qw/cat-file commit/, $c->{c});
 758                 shift @msg while ($msg[0] ne "\n");
 759                 shift @msg;
 760                 @{$c->{l}} = grep !/^git-svn-id: /, @msg;
 761
 762                 (undef, $c->{r}, undef) = extract_metadata(
 763                                 (grep(/^git-svn-id: /, @msg))[-1]);
 764         }
 765         return defined $c->{r};
 766 }
 767
 768 sub log_use_color {
 769         return 1 if $_color;
 770         my ($dc, $dcvar);
 771         $dcvar = 'color.diff';
 772         $dc = `git-repo-config --get $dcvar`;
 773         if ($dc eq '') {
 774                 # nothing at all; fallback to "diff.color"
 775                 $dcvar = 'diff.color';
 776                 $dc = `git-repo-config --get $dcvar`;
 777         }
 778         chomp($dc);
 779         if ($dc eq 'auto') {
 780                 my $pc;
 781                 $pc = `git-repo-config --get color.pager`;
 782                 if ($pc eq '') {
 783                         # does not have it -- fallback to pager.color
 784                         $pc = `git-repo-config --bool --get pager.color`;
 785                 }
 786                 else {
 787                         $pc = `git-repo-config --bool --get color.pager`;
 788                         if ($?) {
 789                                 $pc = 'false';
 790                         }
 791                 }
 792                 chomp($pc);
 793                 if (-t *STDOUT || (defined $_pager && $pc eq 'true')) {
 794                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
 795                 }
 796                 return 0;
 797         }
 798         return 0 if $dc eq 'never';
 799         return 1 if $dc eq 'always';
 800         chomp($dc = `git-repo-config --bool --get $dcvar`);
 801         return ($dc eq 'true');
 802 }
 803
 804 sub git_svn_log_cmd {
 805         my ($r_min, $r_max) = @_;
 806         my @cmd = (qw/log --abbrev-commit --pretty=raw
 807                         --default/, "refs/remotes/$GIT_SVN");
 808         push @cmd, '-r' unless $_non_recursive;
 809         push @cmd, qw/--raw --name-status/ if $_verbose;
 810         push @cmd, '--color' if log_use_color();
 811         return @cmd unless defined $r_max;
 812         if ($r_max == $r_min) {
 813                 push @cmd, '--max-count=1';
 814                 if (my $c = revdb_get($REVDB, $r_max)) {
 815                         push @cmd, $c;
 816                 }
 817         } else {
 818                 my ($c_min, $c_max);
 819                 $c_max = revdb_get($REVDB, $r_max);
 820                 $c_min = revdb_get($REVDB, $r_min);
 821                 if (defined $c_min && defined $c_max) {
 822                         if ($r_max > $r_max) {
 823                                 push @cmd, "$c_min..$c_max";
 824                         } else {
 825                                 push @cmd, "$c_max..$c_min";
 826                         }
 827                 } elsif ($r_max > $r_min) {
 828                         push @cmd, $c_max;
 829                 } else {
 830                         push @cmd, $c_min;
 831                 }
 832         }
 833         return @cmd;
 834 }
 835
 836 sub fetch_child_id {
 837         my $id = shift;
 838         print "Fetching $id\n";
 839         my $ref = "$GIT_DIR/refs/remotes/$id";
 840         defined(my $pid = open my $fh, '-|') or croak $!;
 841         if (!$pid) {
 842                 $_repack = undef;
 843                 $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
 844                 init_vars();
 845                 fetch(@_);
 846                 exit 0;
 847         }
 848         while (<$fh>) {
 849                 print $_;
 850                 check_repack() if (/^r\d+ = $sha1/);
 851         }
 852         close $fh or croak $?;
 853 }
 854
 855 sub rec_fetch {
 856         my ($pfx, $p, @args) = @_;
 857         my @dir;
 858         foreach (sort <$p/*>) {
 859                 if (-r "$_/info/url") {
 860                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
 861                         my $id = $pfx . basename $_;
 862                         next if $id eq 'trunk';
 863                         fetch_child_id($id, @args);
 864                 } elsif (-d $_) {
 865                         push @dir, $_;
 866                 }
 867         }
 868         foreach (@dir) {
 869                 my $x = $_;
 870                 $x =~ s!^\Q$GIT_DIR\E/svn/!!;
 871                 rec_fetch($x, $_);
 872         }
 873 }
 874
 875 sub complete_url_ls_init {
 876         my ($url, $var, $switch, $pfx) = @_;
 877         unless ($var) {
 878                 print STDERR "W: $switch not specified\n";
 879                 return;
 880         }
 881         $var =~ s#/+$##;
 882         if ($var !~ m#^[a-z\+]+://#) {
 883                 $var = '/' . $var if ($var !~ m#^/#);
 884                 unless ($url) {
 885                         print STDERR "E: '$var' is not a complete URL ",
 886                                 "and a separate URL is not specified\n";
 887                         exit 1;
 888                 }
 889                 $var = $url . $var;
 890         }
 891         my @ls = libsvn_ls_fullurl($var);
 892         my $old = $GIT_SVN;
 893         defined(my $pid = fork) or croak $!;
 894         if (!$pid) {
 895                 foreach my $u (map { "$var/$_" } (grep m!/$!, @ls)) {
 896                         $u =~ s#/+$##;
 897                         if ($u !~ m!\Q$var\E/(.+)$!) {
 898                                 print STDERR "W: Unrecognized URL: $u\n";
 899                                 die "This should never happen\n";
 900                         }
 901                         # don't try to init already existing refs
 902                         my $id = $pfx.$1;
 903                         $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
 904                         init_vars();
 905                         unless (-d $GIT_SVN_DIR) {
 906                                 print "init $u => $id\n";
 907                                 init($u);
 908                         }
 909                 }
 910                 exit 0;
 911         }
 912         waitpid $pid, 0;
 913         croak $? if $?;
 914         my ($n) = ($switch =~ /^--(\w+)/);
 915         command_noisy('repo-config', "svn.$n", $var);
 916 }
 917
 918 sub common_prefix {
 919         my $paths = shift;
 920         my %common;
 921         foreach (@$paths) {
 922                 my @tmp = split m#/#, $_;
 923                 my $p = '';
 924                 while (my $x = shift @tmp) {
 925                         $p .= "/$x";
 926                         $common{$p} ||= 0;
 927                         $common{$p}++;
 928                 }
 929         }
 930         foreach (sort {length $b <=> length $a} keys %common) {
 931                 if ($common{$_} == @$paths) {
 932                         return $_;
 933                 }
 934         }
 935         return '';
 936 }
 937
 938 # grafts set here are 'stronger' in that they're based on actual tree
 939 # matches, and won't be deleted from merge-base checking in write_grafts()
 940 sub graft_tree_joins {
 941         my $grafts = shift;
 942         map_tree_joins() if (@_branch_from && !%tree_map);
 943         return unless %tree_map;
 944
 945         git_svn_each(sub {
 946                 my $i = shift;
 947                 my @args = (qw/rev-list --pretty=raw/, "refs/remotes/$i");
 948                 my ($fh, $ctx) = command_output_pipe(@args);
 949                 while (<$fh>) {
 950                         next unless /^commit ($sha1)$/o;
 951                         my $c = $1;
 952                         my ($t) = (<$fh> =~ /^tree ($sha1)$/o);
 953                         next unless $tree_map{$t};
 954
 955                         my $l;
 956                         do {
 957                                 $l = readline $fh;
 958                         } until ($l =~ /^committer (?:.+) (\d+) ([\-\+]?\d+)$/);
 959
 960                         my ($s, $tz) = ($1, $2);
 961                         if ($tz =~ s/^\+//) {
 962                                 $s += tz_to_s_offset($tz);
 963                         } elsif ($tz =~ s/^\-//) {
 964                                 $s -= tz_to_s_offset($tz);
 965                         }
 966
 967                         my ($url_a, $r_a, $uuid_a) = cmt_metadata($c);
 968
 969                         foreach my $p (@{$tree_map{$t}}) {
 970                                 next if $p eq $c;
 971                                 my $mb = eval { command('merge-base', $c, $p) };
 972                                 next unless ($@ || $?);
 973                                 if (defined $r_a) {
 974                                         # see if SVN says it's a relative
 975                                         my ($url_b, $r_b, $uuid_b) =
 976                                                         cmt_metadata($p);
 977                                         next if (defined $url_b &&
 978                                                         defined $url_a &&
 979                                                         ($url_a eq $url_b) &&
 980                                                         ($uuid_a eq $uuid_b));
 981                                         if ($uuid_a eq $uuid_b) {
 982                                                 if ($r_b < $r_a) {
 983                                                         $grafts->{$c}->{$p} = 2;
 984                                                         next;
 985                                                 } elsif ($r_b > $r_a) {
 986                                                         $grafts->{$p}->{$c} = 2;
 987                                                         next;
 988                                                 }
 989                                         }
 990                                 }
 991                                 my $ct = get_commit_time($p);
 992                                 if ($ct < $s) {
 993                                         $grafts->{$c}->{$p} = 2;
 994                                 } elsif ($ct > $s) {
 995                                         $grafts->{$p}->{$c} = 2;
 996                                 }
 997                                 # what should we do when $ct == $s ?
 998                         }
 999                 }
1000                 command_close_pipe($fh, $ctx);
1001         });
1002 }
1003
1004 sub graft_file_copy_lib {
1005         my ($grafts, $l_map, $u) = @_;
1006         my $tree_paths = $l_map->{$u};
1007         my $pfx = common_prefix([keys %$tree_paths]);
1008         my ($repo, $path) = repo_path_split($u.$pfx);
1009         $SVN = libsvn_connect($repo);
1010
1011         my ($base, $head) = libsvn_parse_revision();
1012         my $inc = 1000;
1013         my ($min, $max) = ($base, $head < $base+$inc ? $head : $base+$inc);
1014         my $eh = $SVN::Error::handler;
1015         $SVN::Error::handler = \&libsvn_skip_unknown_revs;
1016         while (1) {
1017                 my $pool = SVN::Pool->new;
1018                 libsvn_get_log(libsvn_dup_ra($SVN), [$path],
1019                                $min, $max, 0, 2, 1,
1020                         sub {
1021                                 libsvn_graft_file_copies($grafts, $tree_paths,
1022                                                         $path, @_);
1023                         }, $pool);
1024                 $pool->clear;
1025                 last if ($max >= $head);
1026                 $min = $max + 1;
1027                 $max += $inc;
1028                 $max = $head if ($max > $head);
1029         }
1030         $SVN::Error::handler = $eh;
1031 }
1032
1033 sub process_merge_msg_matches {
1034         my ($grafts, $l_map, $u, $p, $c, @matches) = @_;
1035         my (@strong, @weak);
1036         foreach (@matches) {
1037                 # merging with ourselves is not interesting
1038                 next if $_ eq $p;
1039                 if ($l_map->{$u}->{$_}) {
1040                         push @strong, $_;
1041                 } else {
1042                         push @weak, $_;
1043                 }
1044         }
1045         foreach my $w (@weak) {
1046                 last if @strong;
1047                 # no exact match, use branch name as regexp.
1048                 my $re = qr/\Q$w\E/i;
1049                 foreach (keys %{$l_map->{$u}}) {
1050                         if (/$re/) {
1051                                 push @strong, $l_map->{$u}->{$_};
1052                                 last;
1053                         }
1054                 }
1055                 last if @strong;
1056                 $w = basename($w);
1057                 $re = qr/\Q$w\E/i;
1058                 foreach (keys %{$l_map->{$u}}) {
1059                         if (/$re/) {
1060                                 push @strong, $l_map->{$u}->{$_};
1061                                 last;
1062                         }
1063                 }
1064         }
1065         my ($rev) = ($c->{m} =~ /^git-svn-id:\s(?:\S+?)\@(\d+)
1066                                         \s(?:[a-f\d\-]+)$/xsm);
1067         unless (defined $rev) {
1068                 ($rev) = ($c->{m} =~/^git-svn-id:\s(\d+)
1069                                         \@(?:[a-f\d\-]+)/xsm);
1070                 return unless defined $rev;
1071         }
1072         foreach my $m (@strong) {
1073                 my ($r0, $s0) = find_rev_before($rev, $m, 1);
1074                 $grafts->{$c->{c}}->{$s0} = 1 if defined $s0;
1075         }
1076 }
1077
1078 sub graft_merge_msg {
1079         my ($grafts, $l_map, $u, $p, @re) = @_;
1080
1081         my $x = $l_map->{$u}->{$p};
1082         my $rl = rev_list_raw($x);
1083         while (my $c = next_rev_list_entry($rl)) {
1084                 foreach my $re (@re) {
1085                         my (@br) = ($c->{m} =~ /$re/g);
1086                         next unless @br;
1087                         process_merge_msg_matches($grafts,$l_map,$u,$p,$c,@br);
1088                 }
1089         }
1090 }
1091
1092 sub read_uuid {
1093         return if $SVN_UUID;
1094         my $pool = SVN::Pool->new;
1095         $SVN_UUID = $SVN->get_uuid($pool);
1096         $pool->clear;
1097 }
1098
1099 sub verify_ref {
1100         my ($ref) = @_;
1101         eval { command_oneline([ 'rev-parse', $ref ], { STDERR => 0 }) };
1102 }
1103
1104 sub repo_path_split {
1105         my $full_url = shift;
1106         $full_url =~ s#/+$##;
1107
1108         foreach (@repo_path_split_cache) {
1109                 if ($full_url =~ s#$_##) {
1110                         my $u = $1;
1111                         $full_url =~ s#^/+##;
1112                         return ($u, $full_url);
1113                 }
1114         }
1115         my $tmp = libsvn_connect($full_url);
1116         return ($tmp->{repos_root}, $tmp->{svn_path});
1117 }
1118
1119 sub setup_git_svn {
1120         defined $SVN_URL or croak "SVN repository location required\n";
1121         unless (-d $GIT_DIR) {
1122                 croak "GIT_DIR=$GIT_DIR does not exist!\n";
1123         }
1124         mkpath([$GIT_SVN_DIR]);
1125         mkpath(["$GIT_SVN_DIR/info"]);
1126         open my $fh, '>>',$REVDB or croak $!;
1127         close $fh;
1128         s_to_file($SVN_URL,"$GIT_SVN_DIR/info/url");
1129
1130 }
1131
1132 sub get_tree_from_treeish {
1133         my ($treeish) = @_;
1134         croak "Not a sha1: $treeish\n" unless $treeish =~ /^$sha1$/o;
1135         my $type = command_oneline(qw/cat-file -t/, $treeish);
1136         my $expected;
1137         while ($type eq 'tag') {
1138                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1139         }
1140         if ($type eq 'commit') {
1141                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1142                                                     $treeish))[0];
1143                 ($expected) = ($expected =~ /^tree ($sha1)$/);
1144                 die "Unable to get tree from $treeish\n" unless $expected;
1145         } elsif ($type eq 'tree') {
1146                 $expected = $treeish;
1147         } else {
1148                 die "$treeish is a $type, expected tree, tag or commit\n";
1149         }
1150         return $expected;
1151 }
1152
1153 sub get_diff {
1154         my ($from, $treeish) = @_;
1155         print "diff-tree $from $treeish\n";
1156         my @diff_tree = qw(diff-tree -z -r);
1157         if ($_cp_similarity) {
1158                 push @diff_tree, "-C$_cp_similarity";
1159         } else {
1160                 push @diff_tree, '-C';
1161         }
1162         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
1163         push @diff_tree, "-l$_l" if defined $_l;
1164         push @diff_tree, $from, $treeish;
1165         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1166         local $/ = "\0";
1167         my $state = 'meta';
1168         my @mods;
1169         while (<$diff_fh>) {
1170                 chomp $_; # this gets rid of the trailing "\0"
1171                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1172                                         $sha1\s($sha1)\s([MTCRAD])\d*$/xo) {
1173                         push @mods, {   mode_a => $1, mode_b => $2,
1174                                         sha1_b => $3, chg => $4 };
1175                         if ($4 =~ /^(?:C|R)$/) {
1176                                 $state = 'file_a';
1177                         } else {
1178                                 $state = 'file_b';
1179                         }
1180                 } elsif ($state eq 'file_a') {
1181                         my $x = $mods[$#mods] or croak "Empty array\n";
1182                         if ($x->{chg} !~ /^(?:C|R)$/) {
1183                                 croak "Error parsing $_, $x->{chg}\n";
1184                         }
1185                         $x->{file_a} = $_;
1186                         $state = 'file_b';
1187                 } elsif ($state eq 'file_b') {
1188                         my $x = $mods[$#mods] or croak "Empty array\n";
1189                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1190                                 croak "Error parsing $_, $x->{chg}\n";
1191                         }
1192                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1193                                 croak "Error parsing $_, $x->{chg}\n";
1194                         }
1195                         $x->{file_b} = $_;
1196                         $state = 'meta';
1197                 } else {
1198                         croak "Error parsing $_\n";
1199                 }
1200         }
1201         command_close_pipe($diff_fh, $ctx);
1202         return \@mods;
1203 }
1204
1205 sub libsvn_checkout_tree {
1206         my ($from, $treeish, $ed) = @_;
1207         my $mods = get_diff($from, $treeish);
1208         return $mods unless (scalar @$mods);
1209         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
1210         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
1211                 my $f = $m->{chg};
1212                 if (defined $o{$f}) {
1213                         $ed->$f($m, $_q);
1214                 } else {
1215                         croak "Invalid change type: $f\n";
1216                 }
1217         }
1218         $ed->rmdirs($_q) if $_rmdir;
1219         return $mods;
1220 }
1221
1222 sub get_commit_message {
1223         my ($commit, $commit_msg) = (@_);
1224         my %log_msg = ( msg => '' );
1225         open my $msg, '>', $commit_msg or croak $!;
1226
1227         my $type = command_oneline(qw/cat-file -t/, $commit);
1228         if ($type eq 'commit' || $type eq 'tag') {
1229                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1230                                                          $type, $commit);
1231                 my $in_msg = 0;
1232                 while (<$msg_fh>) {
1233                         if (!$in_msg) {
1234                                 $in_msg = 1 if (/^\s*$/);
1235                         } elsif (/^git-svn-id: /) {
1236                                 # skip this, we regenerate the correct one
1237                                 # on re-fetch anyways
1238                         } else {
1239                                 print $msg $_ or croak $!;
1240                         }
1241                 }
1242                 command_close_pipe($msg_fh, $ctx);
1243         }
1244         close $msg or croak $!;
1245
1246         if ($_edit || ($type eq 'tree')) {
1247                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1248                 system($editor, $commit_msg);
1249         }
1250
1251         # file_to_s removes all trailing newlines, so just use chomp() here:
1252         open $msg, '<', $commit_msg or croak $!;
1253         { local $/; chomp($log_msg{msg} = <$msg>); }
1254         close $msg or croak $!;
1255
1256         return \%log_msg;
1257 }
1258
1259 sub set_svn_commit_env {
1260         if (defined $LC_ALL) {
1261                 $ENV{LC_ALL} = $LC_ALL;
1262         } else {
1263                 delete $ENV{LC_ALL};
1264         }
1265 }
1266
1267 sub rev_list_raw {
1268         my ($fh, $c) = command_output_pipe(qw/rev-list --pretty=raw/, @_);
1269         return { fh => $fh, ctx => $c, t => { } };
1270 }
1271
1272 sub next_rev_list_entry {
1273         my $rl = shift;
1274         my $fh = $rl->{fh};
1275         my $x = $rl->{t};
1276         while (<$fh>) {
1277                 if (/^commit ($sha1)$/o) {
1278                         if ($x->{c}) {
1279                                 $rl->{t} = { c => $1 };
1280                                 return $x;
1281                         } else {
1282                                 $x->{c} = $1;
1283                         }
1284                 } elsif (/^parent ($sha1)$/o) {
1285                         $x->{p}->{$1} = 1;
1286                 } elsif (s/^    //) {
1287                         $x->{m} ||= '';
1288                         $x->{m} .= $_;
1289                 }
1290         }
1291         command_close_pipe($fh, $rl->{ctx});
1292         return ($x != $rl->{t}) ? $x : undef;
1293 }
1294
1295 sub s_to_file {
1296         my ($str, $file, $mode) = @_;
1297         open my $fd,'>',$file or croak $!;
1298         print $fd $str,"\n" or croak $!;
1299         close $fd or croak $!;
1300         chmod ($mode &~ umask, $file) if (defined $mode);
1301 }
1302
1303 sub file_to_s {
1304         my $file = shift;
1305         open my $fd,'<',$file or croak "$!: file: $file\n";
1306         local $/;
1307         my $ret = <$fd>;
1308         close $fd or croak $!;
1309         $ret =~ s/\s*$//s;
1310         return $ret;
1311 }
1312
1313 sub assert_revision_unknown {
1314         my $r = shift;
1315         if (my $c = revdb_get($REVDB, $r)) {
1316                 croak "$r = $c already exists! Why are we refetching it?";
1317         }
1318 }
1319
1320 sub git_commit {
1321         my ($log_msg, @parents) = @_;
1322         assert_revision_unknown($log_msg->{revision});
1323         map_tree_joins() if (@_branch_from && !%tree_map);
1324
1325         my (@tmp_parents, @exec_parents, %seen_parent);
1326         if (my $lparents = $log_msg->{parents}) {
1327                 @tmp_parents = @$lparents
1328         }
1329         # commit parents can be conditionally bound to a particular
1330         # svn revision via: "svn_revno=commit_sha1", filter them out here:
1331         foreach my $p (@parents) {
1332                 next unless defined $p;
1333                 if ($p =~ /^(\d+)=($sha1_short)$/o) {
1334                         if ($1 == $log_msg->{revision}) {
1335                                 push @tmp_parents, $2;
1336                         }
1337                 } else {
1338                         push @tmp_parents, $p if $p =~ /$sha1_short/o;
1339                 }
1340         }
1341         my $tree = $log_msg->{tree};
1342         if (!defined $tree) {
1343                 my $index = set_index($GIT_SVN_INDEX);
1344                 $tree = command_oneline('write-tree');
1345                 croak $? if $?;
1346                 restore_index($index);
1347         }
1348         # just in case we clobber the existing ref, we still want that ref
1349         # as our parent:
1350         if (my $cur = verify_ref("refs/remotes/$GIT_SVN^0")) {
1351                 chomp $cur;
1352                 push @tmp_parents, $cur;
1353         }
1354
1355         if (exists $tree_map{$tree}) {
1356                 foreach my $p (@{$tree_map{$tree}}) {
1357                         my $skip;
1358                         foreach (@tmp_parents) {
1359                                 # see if a common parent is found
1360                                 my $mb = eval { command('merge-base', $_, $p) };
1361                                 next if ($@ || $?);
1362                                 $skip = 1;
1363                                 last;
1364                         }
1365                         next if $skip;
1366                         my ($url_p, $r_p, $uuid_p) = cmt_metadata($p);
1367                         next if (($SVN_UUID eq $uuid_p) &&
1368                                                 ($log_msg->{revision} > $r_p));
1369                         next if (defined $url_p && defined $SVN_URL &&
1370                                                 ($SVN_UUID eq $uuid_p) &&
1371                                                 ($url_p eq $SVN_URL));
1372                         push @tmp_parents, $p;
1373                 }
1374         }
1375         foreach (@tmp_parents) {
1376                 next if $seen_parent{$_};
1377                 $seen_parent{$_} = 1;
1378                 push @exec_parents, $_;
1379                 # MAXPARENT is defined to 16 in commit-tree.c:
1380                 last if @exec_parents > 16;
1381         }
1382
1383         set_commit_env($log_msg);
1384         my @exec = ('git-commit-tree', $tree);
1385         push @exec, '-p', $_  foreach @exec_parents;
1386         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1387                                                                 or croak $!;
1388         print $msg_fh $log_msg->{msg} or croak $!;
1389         unless ($_no_metadata) {
1390                 print $msg_fh "\ngit-svn-id: $SVN_URL\@$log_msg->{revision}",
1391                                         " $SVN_UUID\n" or croak $!;
1392         }
1393         $msg_fh->flush == 0 or croak $!;
1394         close $msg_fh or croak $!;
1395         chomp(my $commit = do { local $/; <$out_fh> });
1396         close $out_fh or croak $!;
1397         waitpid $pid, 0;
1398         croak $? if $?;
1399         if ($commit !~ /^$sha1$/o) {
1400                 die "Failed to commit, invalid sha1: $commit\n";
1401         }
1402         command_noisy('update-ref',"refs/remotes/$GIT_SVN",$commit);
1403         revdb_set($REVDB, $log_msg->{revision}, $commit);
1404
1405         # this output is read via pipe, do not change:
1406         print "r$log_msg->{revision} = $commit\n";
1407         check_repack();
1408         return $commit;
1409 }
1410
1411 sub check_repack {
1412         if ($_repack && (--$_repack_nr == 0)) {
1413                 $_repack_nr = $_repack;
1414                 # repack doesn't use any arguments with spaces in them, does it?
1415                 command_noisy('repack', split(/\s+/, $_repack_flags));
1416         }
1417 }
1418
1419 sub set_commit_env {
1420         my ($log_msg) = @_;
1421         my $author = $log_msg->{author};
1422         if (!defined $author || length $author == 0) {
1423                 $author = '(no author)';
1424         }
1425         my ($name,$email) = defined $users{$author} ?  @{$users{$author}}
1426                                 : ($author,"$author\@$SVN_UUID");
1427         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1428         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1429         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_msg->{date};
1430 }
1431
1432 sub check_upgrade_needed {
1433         if (!-r $REVDB) {
1434                 -d $GIT_SVN_DIR or mkpath([$GIT_SVN_DIR]);
1435                 open my $fh, '>>',$REVDB or croak $!;
1436                 close $fh;
1437         }
1438         return unless eval {
1439                 command([qw/rev-parse --verify/,"$GIT_SVN-HEAD^0"],
1440                         {STDERR => 0});
1441         };
1442         my $head = eval { command('rev-parse',"refs/remotes/$GIT_SVN") };
1443         if ($@ || !$head) {
1444                 print STDERR "Please run: $0 rebuild --upgrade\n";
1445                 exit 1;
1446         }
1447 }
1448
1449 # fills %tree_map with a reverse mapping of trees to commits.  Useful
1450 # for finding parents to commit on.
1451 sub map_tree_joins {
1452         my %seen;
1453         foreach my $br (@_branch_from) {
1454                 my $pipe = command_output_pipe(qw/rev-list
1455                                             --topo-order --pretty=raw/, $br);
1456                 while (<$pipe>) {
1457                         if (/^commit ($sha1)$/o) {
1458                                 my $commit = $1;
1459
1460                                 # if we've seen a commit,
1461                                 # we've seen its parents
1462                                 last if $seen{$commit};
1463                                 my ($tree) = (<$pipe> =~ /^tree ($sha1)$/o);
1464                                 unless (defined $tree) {
1465                                         die "Failed to parse commit $commit\n";
1466                                 }
1467                                 push @{$tree_map{$tree}}, $commit;
1468                                 $seen{$commit} = 1;
1469                         }
1470                 }
1471                 eval { command_close_pipe($pipe) };
1472         }
1473 }
1474
1475 sub load_all_refs {
1476         if (@_branch_from) {
1477                 print STDERR '--branch|-b parameters are ignored when ',
1478                         "--branch-all-refs|-B is passed\n";
1479         }
1480
1481         # don't worry about rev-list on non-commit objects/tags,
1482         # it shouldn't blow up if a ref is a blob or tree...
1483         @_branch_from = command(qw/rev-parse --symbolic --all/);
1484 }
1485
1486 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1487 sub load_authors {
1488         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1489         while (<$authors>) {
1490                 chomp;
1491                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1492                 my ($user, $name, $email) = ($1, $2, $3);
1493                 $users{$user} = [$name, $email];
1494         }
1495         close $authors or croak $!;
1496 }
1497
1498 sub rload_authors {
1499         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1500         while (<$authors>) {
1501                 chomp;
1502                 next unless /^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/;
1503                 my ($user, $name, $email) = ($1, $2, $3);
1504                 $rusers{"$name <$email>"} = $user;
1505         }
1506         close $authors or croak $!;
1507 }
1508
1509 sub git_svn_each {
1510         my $sub = shift;
1511         foreach (command(qw/rev-parse --symbolic --all/)) {
1512                 next unless s#^refs/remotes/##;
1513                 chomp $_;
1514                 next unless -f "$GIT_DIR/svn/$_/info/url";
1515                 &$sub($_);
1516         }
1517 }
1518
1519 sub migrate_revdb {
1520         git_svn_each(sub {
1521                 my $id = shift;
1522                 defined(my $pid = fork) or croak $!;
1523                 if (!$pid) {
1524                         $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
1525                         init_vars();
1526                         exit 0 if -r $REVDB;
1527                         print "Upgrading svn => git mapping...\n";
1528                         -d $GIT_SVN_DIR or mkpath([$GIT_SVN_DIR]);
1529                         open my $fh, '>>',$REVDB or croak $!;
1530                         close $fh;
1531                         rebuild();
1532                         print "Done upgrading. You may now delete the ",
1533                                 "deprecated $GIT_SVN_DIR/revs directory\n";
1534                         exit 0;
1535                 }
1536                 waitpid $pid, 0;
1537                 croak $? if $?;
1538         });
1539 }
1540
1541 sub migration_check {
1542         migrate_revdb() unless (-e $REVDB);
1543         return if (-d "$GIT_DIR/svn" || !-d $GIT_DIR);
1544         print "Upgrading repository...\n";
1545         unless (-d "$GIT_DIR/svn") {
1546                 mkdir "$GIT_DIR/svn" or croak $!;
1547         }
1548         print "Data from a previous version of git-svn exists, but\n\t",
1549                                 "$GIT_SVN_DIR\n\t(required for this version ",
1550                                 "($VERSION) of git-svn) does not.\n";
1551
1552         foreach my $x (command(qw/rev-parse --symbolic --all/)) {
1553                 next unless $x =~ s#^refs/remotes/##;
1554                 chomp $x;
1555                 next unless -f "$GIT_DIR/$x/info/url";
1556                 my $u = eval { file_to_s("$GIT_DIR/$x/info/url") };
1557                 next unless $u;
1558                 my $dn = dirname("$GIT_DIR/svn/$x");
1559                 mkpath([$dn]) unless -d $dn;
1560                 rename "$GIT_DIR/$x", "$GIT_DIR/svn/$x" or croak "$!: $x";
1561         }
1562         migrate_revdb() if (-d $GIT_SVN_DIR && !-w $REVDB);
1563         print "Done upgrading.\n";
1564 }
1565
1566 sub find_rev_before {
1567         my ($r, $id, $eq_ok) = @_;
1568         my $f = "$GIT_DIR/svn/$id/.rev_db";
1569         return (undef,undef) unless -r $f;
1570         --$r unless $eq_ok;
1571         while ($r > 0) {
1572                 if (my $c = revdb_get($f, $r)) {
1573                         return ($r, $c);
1574                 }
1575                 --$r;
1576         }
1577         return (undef, undef);
1578 }
1579
1580 sub init_vars {
1581         $GIT_SVN ||= $ENV{GIT_SVN_ID} || 'git-svn';
1582         $GIT_SVN_DIR = "$GIT_DIR/svn/$GIT_SVN";
1583         $REVDB = "$GIT_SVN_DIR/.rev_db";
1584         $GIT_SVN_INDEX = "$GIT_SVN_DIR/index";
1585         $SVN_URL = undef;
1586         $SVN_WC = "$GIT_SVN_DIR/tree";
1587         %tree_map = ();
1588 }
1589
1590 # convert GetOpt::Long specs for use by git-repo-config
1591 sub read_repo_config {
1592         return unless -d $GIT_DIR;
1593         my $opts = shift;
1594         foreach my $o (keys %$opts) {
1595                 my $v = $opts->{$o};
1596                 my ($key) = ($o =~ /^([a-z\-]+)/);
1597                 $key =~ s/-//g;
1598                 my $arg = 'git-repo-config';
1599                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1600                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1601                 if (ref $v eq 'ARRAY') {
1602                         chomp(my @tmp = `$arg --get-all svn.$key`);
1603                         @$v = @tmp if @tmp;
1604                 } else {
1605                         chomp(my $tmp = `$arg --get svn.$key`);
1606                         if ($tmp && !($arg =~ / --bool / && $tmp eq 'false')) {
1607                                 $$v = $tmp;
1608                         }
1609                 }
1610         }
1611 }
1612
1613 sub set_default_vals {
1614         if (defined $_repack) {
1615                 $_repack = 1000 if ($_repack <= 0);
1616                 $_repack_nr = $_repack;
1617                 $_repack_flags ||= '-d';
1618         }
1619 }
1620
1621 sub read_grafts {
1622         my $gr_file = shift;
1623         my ($grafts, $comments) = ({}, {});
1624         if (open my $fh, '<', $gr_file) {
1625                 my @tmp;
1626                 while (<$fh>) {
1627                         if (/^($sha1)\s+/) {
1628                                 my $c = $1;
1629                                 if (@tmp) {
1630                                         @{$comments->{$c}} = @tmp;
1631                                         @tmp = ();
1632                                 }
1633                                 foreach my $p (split /\s+/, $_) {
1634                                         $grafts->{$c}->{$p} = 1;
1635                                 }
1636                         } else {
1637                                 push @tmp, $_;
1638                         }
1639                 }
1640                 close $fh or croak $!;
1641                 @{$comments->{'END'}} = @tmp if @tmp;
1642         }
1643         return ($grafts, $comments);
1644 }
1645
1646 sub write_grafts {
1647         my ($grafts, $comments, $gr_file) = @_;
1648
1649         open my $fh, '>', $gr_file or croak $!;
1650         foreach my $c (sort keys %$grafts) {
1651                 if ($comments->{$c}) {
1652                         print $fh $_ foreach @{$comments->{$c}};
1653                 }
1654                 my $p = $grafts->{$c};
1655                 my %x; # real parents
1656                 delete $p->{$c}; # commits are not self-reproducing...
1657                 my $ch = command_output_pipe(qw/cat-file commit/, $c);
1658                 while (<$ch>) {
1659                         if (/^parent ($sha1)/) {
1660                                 $x{$1} = $p->{$1} = 1;
1661                         } else {
1662                                 last unless /^\S/;
1663                         }
1664                 }
1665                 eval { command_close_pipe($ch) }; # breaking the pipe
1666
1667                 # if real parents are the only ones in the grafts, drop it
1668                 next if join(' ',sort keys %$p) eq join(' ',sort keys %x);
1669
1670                 my (@ip, @jp, $mb);
1671                 my %del = %x;
1672                 @ip = @jp = keys %$p;
1673                 foreach my $i (@ip) {
1674                         next if $del{$i} || $p->{$i} == 2;
1675                         foreach my $j (@jp) {
1676                                 next if $i eq $j || $del{$j} || $p->{$j} == 2;
1677                                 $mb = eval { command('merge-base', $i, $j) };
1678                                 next unless $mb;
1679                                 chomp $mb;
1680                                 next if $x{$mb};
1681                                 if ($mb eq $j) {
1682                                         delete $p->{$i};
1683                                         $del{$i} = 1;
1684                                 } elsif ($mb eq $i) {
1685                                         delete $p->{$j};
1686                                         $del{$j} = 1;
1687                                 }
1688                         }
1689                 }
1690
1691                 # if real parents are the only ones in the grafts, drop it
1692                 next if join(' ',sort keys %$p) eq join(' ',sort keys %x);
1693
1694                 print $fh $c, ' ', join(' ', sort keys %$p),"\n";
1695         }
1696         if ($comments->{'END'}) {
1697                 print $fh $_ foreach @{$comments->{'END'}};
1698         }
1699         close $fh or croak $!;
1700 }
1701
1702 sub read_url_paths_all {
1703         my ($l_map, $pfx, $p) = @_;
1704         my @dir;
1705         foreach (<$p/*>) {
1706                 if (-r "$_/info/url") {
1707                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
1708                         my $id = $pfx . basename $_;
1709                         my $url = file_to_s("$_/info/url");
1710                         my ($u, $p) = repo_path_split($url);
1711                         $l_map->{$u}->{$p} = $id;
1712                 } elsif (-d $_) {
1713                         push @dir, $_;
1714                 }
1715         }
1716         foreach (@dir) {
1717                 my $x = $_;
1718                 $x =~ s!^\Q$GIT_DIR\E/svn/!!o;
1719                 read_url_paths_all($l_map, $x, $_);
1720         }
1721 }
1722
1723 # this one only gets ids that have been imported, not new ones
1724 sub read_url_paths {
1725         my $l_map = {};
1726         git_svn_each(sub { my $x = shift;
1727                         my $url = file_to_s("$GIT_DIR/svn/$x/info/url");
1728                         my ($u, $p) = repo_path_split($url);
1729                         $l_map->{$u}->{$p} = $x;
1730                         });
1731         return $l_map;
1732 }
1733
1734 sub extract_metadata {
1735         my $id = shift or return (undef, undef, undef);
1736         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
1737                                                         \s([a-f\d\-]+)$/x);
1738         if (!defined $rev || !$uuid || !$url) {
1739                 # some of the original repositories I made had
1740                 # identifiers like this:
1741                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1742         }
1743         return ($url, $rev, $uuid);
1744 }
1745
1746 sub cmt_metadata {
1747         return extract_metadata((grep(/^git-svn-id: /,
1748                 command(qw/cat-file commit/, shift)))[-1]);
1749 }
1750
1751 sub get_commit_time {
1752         my $cmt = shift;
1753         my $fh = command_output_pipe(qw/rev-list --pretty=raw -n1/, $cmt);
1754         while (<$fh>) {
1755                 /^committer\s(?:.+) (\d+) ([\-\+]?\d+)$/ or next;
1756                 my ($s, $tz) = ($1, $2);
1757                 if ($tz =~ s/^\+//) {
1758                         $s += tz_to_s_offset($tz);
1759                 } elsif ($tz =~ s/^\-//) {
1760                         $s -= tz_to_s_offset($tz);
1761                 }
1762                 eval { command_close_pipe($fh) };
1763                 return $s;
1764         }
1765         die "Can't get commit time for commit: $cmt\n";
1766 }
1767
1768 sub tz_to_s_offset {
1769         my ($tz) = @_;
1770         $tz =~ s/(\d\d)$//;
1771         return ($1 * 60) + ($tz * 3600);
1772 }
1773
1774 # adapted from pager.c
1775 sub config_pager {
1776         $_pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
1777         if (!defined $_pager) {
1778                 $_pager = 'less';
1779         } elsif (length $_pager == 0 || $_pager eq 'cat') {
1780                 $_pager = undef;
1781         }
1782 }
1783
1784 sub run_pager {
1785         return unless -t *STDOUT;
1786         pipe my $rfd, my $wfd or return;
1787         defined(my $pid = fork) or croak $!;
1788         if (!$pid) {
1789                 open STDOUT, '>&', $wfd or croak $!;
1790                 return;
1791         }
1792         open STDIN, '<&', $rfd or croak $!;
1793         $ENV{LESS} ||= 'FRSX';
1794         exec $_pager or croak "Can't run pager: $! ($_pager)\n";
1795 }
1796
1797 sub get_author_info {
1798         my ($dest, $author, $t, $tz) = @_;
1799         $author =~ s/(?:^\s*|\s*$)//g;
1800         $dest->{a_raw} = $author;
1801         my $_a;
1802         if ($_authors) {
1803                 $_a = $rusers{$author} || undef;
1804         }
1805         if (!$_a) {
1806                 ($_a) = ($author =~ /<([^>]+)\@[^>]+>$/);
1807         }
1808         $dest->{t} = $t;
1809         $dest->{tz} = $tz;
1810         $dest->{a} = $_a;
1811         # Date::Parse isn't in the standard Perl distro :(
1812         if ($tz =~ s/^\+//) {
1813                 $t += tz_to_s_offset($tz);
1814         } elsif ($tz =~ s/^\-//) {
1815                 $t -= tz_to_s_offset($tz);
1816         }
1817         $dest->{t_utc} = $t;
1818 }
1819
1820 sub process_commit {
1821         my ($c, $r_min, $r_max, $defer) = @_;
1822         if (defined $r_min && defined $r_max) {
1823                 if ($r_min == $c->{r} && $r_min == $r_max) {
1824                         show_commit($c);
1825                         return 0;
1826                 }
1827                 return 1 if $r_min == $r_max;
1828                 if ($r_min < $r_max) {
1829                         # we need to reverse the print order
1830                         return 0 if (defined $_limit && --$_limit < 0);
1831                         push @$defer, $c;
1832                         return 1;
1833                 }
1834                 if ($r_min != $r_max) {
1835                         return 1 if ($r_min < $c->{r});
1836                         return 1 if ($r_max > $c->{r});
1837                 }
1838         }
1839         return 0 if (defined $_limit && --$_limit < 0);
1840         show_commit($c);
1841         return 1;
1842 }
1843
1844 sub show_commit {
1845         my $c = shift;
1846         if ($_oneline) {
1847                 my $x = "\n";
1848                 if (my $l = $c->{l}) {
1849                         while ($l->[0] =~ /^\s*$/) { shift @$l }
1850                         $x = $l->[0];
1851                 }
1852                 $_l_fmt ||= 'A' . length($c->{r});
1853                 print 'r',pack($_l_fmt, $c->{r}),' | ';
1854                 print "$c->{c} | " if $_show_commit;
1855                 print $x;
1856         } else {
1857                 show_commit_normal($c);
1858         }
1859 }
1860
1861 sub show_commit_changed_paths {
1862         my ($c) = @_;
1863         return unless $c->{changed};
1864         print "Changed paths:\n", @{$c->{changed}};
1865 }
1866
1867 sub show_commit_normal {
1868         my ($c) = @_;
1869         print '-' x72, "\nr$c->{r} | ";
1870         print "$c->{c} | " if $_show_commit;
1871         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
1872                                  localtime($c->{t_utc})), ' | ';
1873         my $nr_line = 0;
1874
1875         if (my $l = $c->{l}) {
1876                 while ($l->[$#$l] eq "\n" && $#$l > 0
1877                                           && $l->[($#$l - 1)] eq "\n") {
1878                         pop @$l;
1879                 }
1880                 $nr_line = scalar @$l;
1881                 if (!$nr_line) {
1882                         print "1 line\n\n\n";
1883                 } else {
1884                         if ($nr_line == 1) {
1885                                 $nr_line = '1 line';
1886                         } else {
1887                                 $nr_line .= ' lines';
1888                         }
1889                         print $nr_line, "\n";
1890                         show_commit_changed_paths($c);
1891                         print "\n";
1892                         print $_ foreach @$l;
1893                 }
1894         } else {
1895                 print "1 line\n";
1896                 show_commit_changed_paths($c);
1897                 print "\n";
1898
1899         }
1900         foreach my $x (qw/raw diff/) {
1901                 if ($c->{$x}) {
1902                         print "\n";
1903                         print $_ foreach @{$c->{$x}}
1904                 }
1905         }
1906 }
1907
1908 sub _simple_prompt {
1909         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1910         $may_save = undef if $_no_auth_cache;
1911         $default_username = $_username if defined $_username;
1912         if (defined $default_username && length $default_username) {
1913                 if (defined $realm && length $realm) {
1914                         print "Authentication realm: $realm\n";
1915                 }
1916                 $cred->username($default_username);
1917         } else {
1918                 _username_prompt($cred, $realm, $may_save, $pool);
1919         }
1920         $cred->password(_read_password("Password for '" .
1921                                        $cred->username . "': ", $realm));
1922         $cred->may_save($may_save);
1923         $SVN::_Core::SVN_NO_ERROR;
1924 }
1925
1926 sub _ssl_server_trust_prompt {
1927         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1928         $may_save = undef if $_no_auth_cache;
1929         print "Error validating server certificate for '$realm':\n";
1930         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1931                 print " - The certificate is not issued by a trusted ",
1932                       "authority. Use the\n",
1933                       "   fingerprint to validate the certificate manually!\n";
1934         }
1935         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1936                 print " - The certificate hostname does not match.\n";
1937         }
1938         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1939                 print " - The certificate is not yet valid.\n";
1940         }
1941         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1942                 print " - The certificate has expired.\n";
1943         }
1944         if ($failures & $SVN::Auth::SSL::OTHER) {
1945                 print " - The certificate has an unknown error.\n";
1946         }
1947         printf( "Certificate information:\n".
1948                 " - Hostname: %s\n".
1949                 " - Valid: from %s until %s\n".
1950                 " - Issuer: %s\n".
1951                 " - Fingerprint: %s\n",
1952                 map $cert_info->$_, qw(hostname valid_from valid_until
1953                                        issuer_dname fingerprint) );
1954         my $choice;
1955 prompt:
1956         print $may_save ?
1957               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1958               "(R)eject or accept (t)emporarily? ";
1959         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1960         if ($choice =~ /^t$/i) {
1961                 $cred->may_save(undef);
1962         } elsif ($choice =~ /^r$/i) {
1963                 return -1;
1964         } elsif ($may_save && $choice =~ /^p$/i) {
1965                 $cred->may_save($may_save);
1966         } else {
1967                 goto prompt;
1968         }
1969         $cred->accepted_failures($failures);
1970         $SVN::_Core::SVN_NO_ERROR;
1971 }
1972
1973 sub _ssl_client_cert_prompt {
1974         my ($cred, $realm, $may_save, $pool) = @_;
1975         $may_save = undef if $_no_auth_cache;
1976         print "Client certificate filename: ";
1977         chomp(my $filename = <STDIN>);
1978         $cred->cert_file($filename);
1979         $cred->may_save($may_save);
1980         $SVN::_Core::SVN_NO_ERROR;
1981 }
1982
1983 sub _ssl_client_cert_pw_prompt {
1984         my ($cred, $realm, $may_save, $pool) = @_;
1985         $may_save = undef if $_no_auth_cache;
1986         $cred->password(_read_password("Password: ", $realm));
1987         $cred->may_save($may_save);
1988         $SVN::_Core::SVN_NO_ERROR;
1989 }
1990
1991 sub _username_prompt {
1992         my ($cred, $realm, $may_save, $pool) = @_;
1993         $may_save = undef if $_no_auth_cache;
1994         if (defined $realm && length $realm) {
1995                 print "Authentication realm: $realm\n";
1996         }
1997         my $username;
1998         if (defined $_username) {
1999                 $username = $_username;
2000         } else {
2001                 print "Username: ";
2002                 chomp($username = <STDIN>);
2003         }
2004         $cred->username($username);
2005         $cred->may_save($may_save);
2006         $SVN::_Core::SVN_NO_ERROR;
2007 }
2008
2009 sub _read_password {
2010         my ($prompt, $realm) = @_;
2011         print $prompt;
2012         require Term::ReadKey;
2013         Term::ReadKey::ReadMode('noecho');
2014         my $password = '';
2015         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2016                 last if $key =~ /[\012\015]/; # \n\r
2017                 $password .= $key;
2018         }
2019         Term::ReadKey::ReadMode('restore');
2020         print "\n";
2021         $password;
2022 }
2023
2024 sub libsvn_connect {
2025         my ($url) = @_;
2026         SVN::_Core::svn_config_ensure($_config_dir, undef);
2027         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2028             SVN::Client::get_simple_provider(),
2029             SVN::Client::get_ssl_server_trust_file_provider(),
2030             SVN::Client::get_simple_prompt_provider(
2031               \&_simple_prompt, 2),
2032             SVN::Client::get_ssl_client_cert_prompt_provider(
2033               \&_ssl_client_cert_prompt, 2),
2034             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2035               \&_ssl_client_cert_pw_prompt, 2),
2036             SVN::Client::get_username_provider(),
2037             SVN::Client::get_ssl_server_trust_prompt_provider(
2038               \&_ssl_server_trust_prompt),
2039             SVN::Client::get_username_prompt_provider(
2040               \&_username_prompt, 2),
2041           ]);
2042         my $config = SVN::Core::config_get_config($_config_dir);
2043         my $ra = SVN::Ra->new(url => $url, auth => $baton,
2044                               config => $config,
2045                               pool => SVN::Pool->new,
2046                               auth_provider_callbacks => $callbacks);
2047
2048         my $df = $ENV{GIT_SVN_DELTA_FETCH};
2049         if (defined $df) {
2050                 $_xfer_delta = $df;
2051         } else {
2052                 $_xfer_delta = ($url =~ m#^file://#) ? undef : 1;
2053         }
2054         $ra->{svn_path} = $url;
2055         $ra->{repos_root} = $ra->get_repos_root;
2056         $ra->{svn_path} =~ s#^\Q$ra->{repos_root}\E/*##;
2057         push @repo_path_split_cache, qr/^(\Q$ra->{repos_root}\E)/;
2058         return $ra;
2059 }
2060
2061 sub libsvn_can_do_switch {
2062         unless (defined $_svn_can_do_switch) {
2063                 my $pool = SVN::Pool->new;
2064                 my $rep = eval {
2065                         $SVN->do_switch(1, '', 0, $SVN->{url},
2066                                         SVN::Delta::Editor->new, $pool);
2067                 };
2068                 if ($@) {
2069                         $_svn_can_do_switch = 0;
2070                 } else {
2071                         $rep->abort_report($pool);
2072                         $_svn_can_do_switch = 1;
2073                 }
2074                 $pool->clear;
2075         }
2076         $_svn_can_do_switch;
2077 }
2078
2079 sub libsvn_dup_ra {
2080         my ($ra) = @_;
2081         SVN::Ra->new(map { $_ => $ra->{$_} } qw/config url
2082                      auth auth_provider_callbacks repos_root svn_path/);
2083 }
2084
2085 sub libsvn_get_file {
2086         my ($gui, $f, $rev, $chg, $untracked) = @_;
2087         $f =~ s#^/##;
2088         print "\t$chg\t$f\n" unless $_q;
2089
2090         my ($hash, $pid, $in, $out);
2091         my $pool = SVN::Pool->new;
2092         defined($pid = open3($in, $out, '>&STDERR',
2093                                 qw/git-hash-object -w --stdin/)) or croak $!;
2094         # redirect STDOUT for SVN 1.1.x compatibility
2095         open my $stdout, '>&', \*STDOUT or croak $!;
2096         open STDOUT, '>&', $in or croak $!;
2097         my ($r, $props) = $SVN->get_file($f, $rev, \*STDOUT, $pool);
2098         $in->flush == 0 or croak $!;
2099         open STDOUT, '>&', $stdout or croak $!;
2100         close $in or croak $!;
2101         close $stdout or croak $!;
2102         $pool->clear;
2103         chomp($hash = do { local $/; <$out> });
2104         close $out or croak $!;
2105         waitpid $pid, 0;
2106         $hash =~ /^$sha1$/o or die "not a sha1: $hash\n";
2107
2108         my $mode = exists $props->{'svn:executable'} ? '100755' : '100644';
2109         if (exists $props->{'svn:special'}) {
2110                 $mode = '120000';
2111                 my $link = `git-cat-file blob $hash`; # no chomping symlinks
2112                 $link =~ s/^link // or die "svn:special file with contents: <",
2113                                                 $link, "> is not understood\n";
2114                 defined($pid = open3($in, $out, '>&STDERR',
2115                                 qw/git-hash-object -w --stdin/)) or croak $!;
2116                 print $in $link;
2117                 $in->flush == 0 or croak $!;
2118                 close $in or croak $!;
2119                 chomp($hash = do { local $/; <$out> });
2120                 close $out or croak $!;
2121                 waitpid $pid, 0;
2122                 $hash =~ /^$sha1$/o or die "not a sha1: $hash\n";
2123         }
2124         %{$untracked->{file_prop}->{$f}} = %$props;
2125         print $gui $mode,' ',$hash,"\t",$f,"\0" or croak $!;
2126 }
2127
2128 sub uri_encode {
2129         my ($f) = @_;
2130         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2131         $f
2132 }
2133
2134 sub uri_decode {
2135         my ($f) = @_;
2136         $f =~ tr/+/ /;
2137         $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
2138         $f
2139 }
2140
2141 sub libsvn_log_entry {
2142         my ($rev, $author, $date, $msg, $parents, $untracked) = @_;
2143         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2144                                          (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x)
2145                                 or die "Unable to parse date: $date\n";
2146         if (defined $author && length $author > 0 &&
2147             defined $_authors && ! defined $users{$author}) {
2148                 die "Author: $author not defined in $_authors file\n";
2149         }
2150         $msg = '' if ($rev == 0 && !defined $msg);
2151
2152         open my $un, '>>', "$GIT_SVN_DIR/unhandled.log" or croak $!;
2153         my $h;
2154         print $un "r$rev\n" or croak $!;
2155         $h = $untracked->{empty};
2156         foreach (sort keys %$h) {
2157                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2158                 print $un "  $act: ", uri_encode($_), "\n" or croak $!;
2159                 warn "W: $act: $_\n";
2160         }
2161         foreach my $t (qw/dir_prop file_prop/) {
2162                 $h = $untracked->{$t} or next;
2163                 foreach my $path (sort keys %$h) {
2164                         my $ppath = $path eq '' ? '.' : $path;
2165                         foreach my $prop (sort keys %{$h->{$path}}) {
2166                                 next if $SKIP{$prop};
2167                                 my $v = $h->{$path}->{$prop};
2168                                 if (defined $v) {
2169                                         print $un "  +$t: ",
2170                                                   uri_encode($ppath), ' ',
2171                                                   uri_encode($prop), ' ',
2172                                                   uri_encode($v), "\n"
2173                                                   or croak $!;
2174                                 } else {
2175                                         print $un "  -$t: ",
2176                                                   uri_encode($ppath), ' ',
2177                                                   uri_encode($prop), "\n"
2178                                                   or croak $!;
2179                                 }
2180                         }
2181                 }
2182         }
2183         foreach my $t (qw/absent_file absent_directory/) {
2184                 $h = $untracked->{$t} or next;
2185                 foreach my $parent (sort keys %$h) {
2186                         foreach my $path (sort @{$h->{$parent}}) {
2187                                 print $un "  $t: ",
2188                                       uri_encode("$parent/$path"), "\n"
2189                                       or croak $!;
2190                                 warn "W: $t: $parent/$path ",
2191                                      "Insufficient permissions?\n";
2192                         }
2193                 }
2194         }
2195
2196         # revprops (make this optional? it's an extra network trip...)
2197         my $pool = SVN::Pool->new;
2198         my $rp = $SVN->rev_proplist($rev, $pool);
2199         foreach (sort keys %$rp) {
2200                 next if /^svn:(?:author|date|log)$/;
2201                 print $un "  rev_prop: ", uri_encode($_), ' ',
2202                           uri_encode($rp->{$_}), "\n";
2203         }
2204         $pool->clear;
2205         close $un or croak $!;
2206
2207         { revision => $rev, date => "+0000 $Y-$m-$d $H:$M:$S",
2208           author => $author, msg => $msg."\n", parents => $parents || [],
2209           revprops => $rp }
2210 }
2211
2212 sub process_rm {
2213         my ($gui, $last_commit, $f, $q) = @_;
2214         # remove entire directories.
2215         if (command('ls-tree',$last_commit,'--',$f) =~ /^040000 tree/) {
2216                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2217                                                      -r --name-only -z/,
2218                                                      $last_commit,'--',$f);
2219                 local $/ = "\0";
2220                 while (<$ls>) {
2221                         print $gui '0 ',0 x 40,"\t",$_ or croak $!;
2222                         print "\tD\t$_\n" unless $q;
2223                 }
2224                 print "\tD\t$f/\n" unless $q;
2225                 command_close_pipe($ls, $ctx);
2226                 return $SVN::Node::dir;
2227         } else {
2228                 print $gui '0 ',0 x 40,"\t",$f,"\0" or croak $!;
2229                 print "\tD\t$f\n" unless $q;
2230                 return $SVN::Node::file;
2231         }
2232 }
2233
2234 sub libsvn_fetch {
2235         $_xfer_delta ? libsvn_fetch_delta(@_) : libsvn_fetch_full(@_);
2236 }
2237
2238 sub libsvn_fetch_delta {
2239         my ($last_commit, $paths, $rev, $author, $date, $msg) = @_;
2240         my $pool = SVN::Pool->new;
2241         my $ed = SVN::Git::Fetcher->new({ c => $last_commit, q => $_q });
2242         my $reporter = $SVN->do_update($rev, '', 1, $ed, $pool);
2243         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2244         my (undef, $last_rev, undef) = cmt_metadata($last_commit);
2245         $reporter->set_path('', $last_rev, 0, @lock, $pool);
2246         $reporter->finish_report($pool);
2247         $pool->clear;
2248         unless ($ed->{git_commit_ok}) {
2249                 die "SVN connection failed somewhere...\n";
2250         }
2251         libsvn_log_entry($rev, $author, $date, $msg, [$last_commit], $ed);
2252 }
2253
2254 sub libsvn_fetch_full {
2255         my ($last_commit, $paths, $rev, $author, $date, $msg) = @_;
2256         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2257         my %amr;
2258         my $ut = { empty => {}, dir_prop => {}, file_prop => {} };
2259         my $p = $SVN->{svn_path};
2260         foreach my $f (keys %$paths) {
2261                 my $m = $paths->{$f}->action();
2262                 if (length $p) {
2263                         $f =~ s#^/\Q$p\E/##;
2264                         next if $f =~ m#^/#;
2265                 } else {
2266                         $f =~ s#^/##;
2267                 }
2268                 if ($m =~ /^[DR]$/) {
2269                         my $t = process_rm($gui, $last_commit, $f, $_q);
2270                         if ($m eq 'D') {
2271                                 $ut->{empty}->{$f} = 0 if $t == $SVN::Node::dir;
2272                                 next;
2273                         }
2274                         # 'R' can be file replacements, too, right?
2275                 }
2276                 my $pool = SVN::Pool->new;
2277                 my $t = $SVN->check_path($f, $rev, $pool);
2278                 if ($t == $SVN::Node::file) {
2279                         if ($m =~ /^[AMR]$/) {
2280                                 $amr{$f} = $m;
2281                         } else {
2282                                 die "Unrecognized action: $m, ($f r$rev)\n";
2283                         }
2284                 } elsif ($t == $SVN::Node::dir && $m =~ /^[AR]$/) {
2285                         my @traversed = ();
2286                         libsvn_traverse($gui, '', $f, $rev, \@traversed, $ut);
2287                         if (@traversed) {
2288                                 foreach (@traversed) {
2289                                         $amr{$_} = $m;
2290                                 }
2291                         } else {
2292                                 my ($dir, $file) = ($f =~ m#^(.*?)/?([^/]+)$#);
2293                                 delete $ut->{empty}->{$dir};
2294                                 $ut->{empty}->{$f} = 1;
2295                         }
2296                 }
2297                 $pool->clear;
2298         }
2299         foreach (keys %amr) {
2300                 libsvn_get_file($gui, $_, $rev, $amr{$_}, $ut);
2301                 my ($d) = ($_ =~ m#^(.*?)/?(?:[^/]+)$#);
2302                 delete $ut->{empty}->{$d};
2303         }
2304         unless (exists $ut->{dir_prop}->{''}) {
2305                 my $pool = SVN::Pool->new;
2306                 my (undef, undef, $props) = $SVN->get_dir('', $rev, $pool);
2307                 %{$ut->{dir_prop}->{''}} = %$props;
2308                 $pool->clear;
2309         }
2310         command_close_pipe($gui, $ctx);
2311         libsvn_log_entry($rev, $author, $date, $msg, [$last_commit], $ut);
2312 }
2313
2314 sub svn_grab_base_rev {
2315         my $c = eval { command_oneline([qw/rev-parse --verify/,
2316                                         "refs/remotes/$GIT_SVN^0"],
2317                                         { STDERR => 0 }) };
2318         if (defined $c && length $c) {
2319                 my ($url, $rev, $uuid) = cmt_metadata($c);
2320                 return ($rev, $c) if defined $rev;
2321         }
2322         if ($_no_metadata) {
2323                 my $offset = -41; # from tail
2324                 my $rl;
2325                 open my $fh, '<', $REVDB or
2326                         die "--no-metadata specified and $REVDB not readable\n";
2327                 seek $fh, $offset, 2;
2328                 $rl = readline $fh;
2329                 defined $rl or return (undef, undef);
2330                 chomp $rl;
2331                 while ($c ne $rl && tell $fh != 0) {
2332                         $offset -= 41;
2333                         seek $fh, $offset, 2;
2334                         $rl = readline $fh;
2335                         defined $rl or return (undef, undef);
2336                         chomp $rl;
2337                 }
2338                 my $rev = tell $fh;
2339                 croak $! if ($rev < -1);
2340                 $rev =  ($rev - 41) / 41;
2341                 close $fh or croak $!;
2342                 return ($rev, $c);
2343         }
2344         return (undef, undef);
2345 }
2346
2347 sub libsvn_parse_revision {
2348         my $base = shift;
2349         my $head = $SVN->get_latest_revnum();
2350         if (!defined $_revision || $_revision eq 'BASE:HEAD') {
2351                 return ($base + 1, $head) if (defined $base);
2352                 return (0, $head);
2353         }
2354         return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
2355         return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
2356         if ($_revision =~ /^BASE:(\d+)$/) {
2357                 return ($base + 1, $1) if (defined $base);
2358                 return (0, $head);
2359         }
2360         return ($1, $head) if ($_revision =~ /^(\d+):HEAD$/);
2361         die "revision argument: $_revision not understood by git-svn\n",
2362                 "Try using the command-line svn client instead\n";
2363 }
2364
2365 sub libsvn_traverse {
2366         my ($gui, $pfx, $path, $rev, $files, $untracked) = @_;
2367         my $cwd = length $pfx ? "$pfx/$path" : $path;
2368         my $pool = SVN::Pool->new;
2369         $cwd =~ s#^\Q$SVN->{svn_path}\E##;
2370         my $nr = 0;
2371         my ($dirent, $r, $props) = $SVN->get_dir($cwd, $rev, $pool);
2372         %{$untracked->{dir_prop}->{$cwd}} = %$props;
2373         foreach my $d (keys %$dirent) {
2374                 my $t = $dirent->{$d}->kind;
2375                 if ($t == $SVN::Node::dir) {
2376                         my $i = libsvn_traverse($gui, $cwd, $d, $rev,
2377                                                 $files, $untracked);
2378                         if ($i) {
2379                                 $nr += $i;
2380                         } else {
2381                                 $untracked->{empty}->{"$cwd/$d"} = 1;
2382                         }
2383                 } elsif ($t == $SVN::Node::file) {
2384                         $nr++;
2385                         my $file = "$cwd/$d";
2386                         if (defined $files) {
2387                                 push @$files, $file;
2388                         } else {
2389                                 libsvn_get_file($gui, $file, $rev, 'A',
2390                                                 $untracked);
2391                                 my ($dir) = ($file =~ m#^(.*?)/?(?:[^/]+)$#);
2392                                 delete $untracked->{empty}->{$dir};
2393                         }
2394                 }
2395         }
2396         $pool->clear;
2397         $nr;
2398 }
2399
2400 sub libsvn_traverse_ignore {
2401         my ($fh, $path, $r) = @_;
2402         $path =~ s#^/+##g;
2403         my $pool = SVN::Pool->new;
2404         my ($dirent, undef, $props) = $SVN->get_dir($path, $r, $pool);
2405         my $p = $path;
2406         $p =~ s#^\Q$SVN->{svn_path}\E/##;
2407         print $fh length $p ? "\n# $p\n" : "\n# /\n";
2408         if (my $s = $props->{'svn:ignore'}) {
2409                 $s =~ s/[\r\n]+/\n/g;
2410                 chomp $s;
2411                 if (length $p == 0) {
2412                         $s =~ s#\n#\n/$p#g;
2413                         print $fh "/$s\n";
2414                 } else {
2415                         $s =~ s#\n#\n/$p/#g;
2416                         print $fh "/$p/$s\n";
2417                 }
2418         }
2419         foreach (sort keys %$dirent) {
2420                 next if $dirent->{$_}->kind != $SVN::Node::dir;
2421                 libsvn_traverse_ignore($fh, "$path/$_", $r);
2422         }
2423         $pool->clear;
2424 }
2425
2426 sub revisions_eq {
2427         my ($path, $r0, $r1) = @_;
2428         return 1 if $r0 == $r1;
2429         my $nr = 0;
2430         # should be OK to use Pool here (r1 - r0) should be small
2431         my $pool = SVN::Pool->new;
2432         libsvn_get_log($SVN, [$path], $r0, $r1,
2433                         0, 0, 1, sub {$nr++}, $pool);
2434         $pool->clear;
2435         return 0 if ($nr > 1);
2436         return 1;
2437 }
2438
2439 sub libsvn_find_parent_branch {
2440         my ($paths, $rev, $author, $date, $msg) = @_;
2441         my $svn_path = '/'.$SVN->{svn_path};
2442
2443         # look for a parent from another branch:
2444         my $i = $paths->{$svn_path} or return;
2445         my $branch_from = $i->copyfrom_path or return;
2446         my $r = $i->copyfrom_rev;
2447         print STDERR  "Found possible branch point: ",
2448                                 "$branch_from => $svn_path, $r\n";
2449         $branch_from =~ s#^/##;
2450         my $l_map = {};
2451         read_url_paths_all($l_map, '', "$GIT_DIR/svn");
2452         my $url = $SVN->{repos_root};
2453         defined $l_map->{$url} or return;
2454         my $id = $l_map->{$url}->{$branch_from};
2455         if (!defined $id && $_follow_parent) {
2456                 print STDERR "Following parent: $branch_from\@$r\n";
2457                 # auto create a new branch and follow it
2458                 $id = basename($branch_from);
2459                 $id .= '@'.$r if -r "$GIT_DIR/svn/$id";
2460                 while (-r "$GIT_DIR/svn/$id") {
2461                         # just grow a tail if we're not unique enough :x
2462                         $id .= '-';
2463                 }
2464         }
2465         return unless defined $id;
2466
2467         my ($r0, $parent) = find_rev_before($r,$id,1);
2468         if ($_follow_parent && (!defined $r0 || !defined $parent)) {
2469                 defined(my $pid = fork) or croak $!;
2470                 if (!$pid) {
2471                         $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
2472                         init_vars();
2473                         $SVN_URL = "$url/$branch_from";
2474                         $SVN = undef;
2475                         setup_git_svn();
2476                         # we can't assume SVN_URL exists at r+1:
2477                         $_revision = "0:$r";
2478                         fetch_lib();
2479                         exit 0;
2480                 }
2481                 waitpid $pid, 0;
2482                 croak $? if $?;
2483                 ($r0, $parent) = find_rev_before($r,$id,1);
2484         }
2485         return unless (defined $r0 && defined $parent);
2486         if (revisions_eq($branch_from, $r0, $r)) {
2487                 unlink $GIT_SVN_INDEX;
2488                 print STDERR "Found branch parent: ($GIT_SVN) $parent\n";
2489                 command_noisy('read-tree', $parent);
2490                 unless (libsvn_can_do_switch()) {
2491                         return libsvn_fetch_full($parent, $paths, $rev,
2492                                                 $author, $date, $msg);
2493                 }
2494                 # do_switch works with svn/trunk >= r22312, but that is not
2495                 # included with SVN 1.4.2 (the latest version at the moment),
2496                 # so we can't rely on it.
2497                 my $ra = libsvn_connect("$url/$branch_from");
2498                 my $ed = SVN::Git::Fetcher->new({c => $parent, q => $_q });
2499                 my $pool = SVN::Pool->new;
2500                 my $reporter = $ra->do_switch($rev, '', 1, $SVN->{url},
2501                                               $ed, $pool);
2502                 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2503                 $reporter->set_path('', $r0, 0, @lock, $pool);
2504                 $reporter->finish_report($pool);
2505                 $pool->clear;
2506                 unless ($ed->{git_commit_ok}) {
2507                         die "SVN connection failed somewhere...\n";
2508                 }
2509                 return libsvn_log_entry($rev, $author, $date, $msg, [$parent]);
2510         }
2511         print STDERR "Nope, branch point not imported or unknown\n";
2512         return undef;
2513 }
2514
2515 sub libsvn_get_log {
2516         my ($ra, @args) = @_;
2517         $args[4]-- if $args[4] && $_xfer_delta && ! $_follow_parent;
2518         if ($SVN::Core::VERSION le '1.2.0') {
2519                 splice(@args, 3, 1);
2520         }
2521         $ra->get_log(@args);
2522 }
2523
2524 sub libsvn_new_tree {
2525         if (my $log_entry = libsvn_find_parent_branch(@_)) {
2526                 return $log_entry;
2527         }
2528         my ($paths, $rev, $author, $date, $msg) = @_;
2529         my $ut;
2530         if ($_xfer_delta) {
2531                 my $pool = SVN::Pool->new;
2532                 my $ed = SVN::Git::Fetcher->new({q => $_q});
2533                 my $reporter = $SVN->do_update($rev, '', 1, $ed, $pool);
2534                 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2535                 $reporter->set_path('', $rev, 1, @lock, $pool);
2536                 $reporter->finish_report($pool);
2537                 $pool->clear;
2538                 unless ($ed->{git_commit_ok}) {
2539                         die "SVN connection failed somewhere...\n";
2540                 }
2541                 $ut = $ed;
2542         } else {
2543                 $ut = { empty => {}, dir_prop => {}, file_prop => {} };
2544                 my ($gui, $ctx) = command_input_pipe(qw/update-index
2545                                                      -z --index-info/);
2546                 libsvn_traverse($gui, '', $SVN->{svn_path}, $rev, undef, $ut);
2547                 command_close_pipe($gui, $ctx);
2548         }
2549         libsvn_log_entry($rev, $author, $date, $msg, [], $ut);
2550 }
2551
2552 sub find_graft_path_commit {
2553         my ($tree_paths, $p1, $r1) = @_;
2554         foreach my $x (keys %$tree_paths) {
2555                 next unless ($p1 =~ /^\Q$x\E/);
2556                 my $i = $tree_paths->{$x};
2557                 my ($r0, $parent) = find_rev_before($r1,$i,1);
2558                 return $parent if (defined $r0 && $r0 == $r1);
2559                 print STDERR "r$r1 of $i not imported\n";
2560                 next;
2561         }
2562         return undef;
2563 }
2564
2565 sub find_graft_path_parents {
2566         my ($grafts, $tree_paths, $c, $p0, $r0) = @_;
2567         foreach my $x (keys %$tree_paths) {
2568                 next unless ($p0 =~ /^\Q$x\E/);
2569                 my $i = $tree_paths->{$x};
2570                 my ($r, $parent) = find_rev_before($r0, $i, 1);
2571                 if (defined $r && defined $parent && revisions_eq($x,$r,$r0)) {
2572                         my ($url_b, undef, $uuid_b) = cmt_metadata($c);
2573                         my ($url_a, undef, $uuid_a) = cmt_metadata($parent);
2574                         next if ($url_a && $url_b && $url_a eq $url_b &&
2575                                                         $uuid_b eq $uuid_a);
2576                         $grafts->{$c}->{$parent} = 1;
2577                 }
2578         }
2579 }
2580
2581 sub libsvn_graft_file_copies {
2582         my ($grafts, $tree_paths, $path, $paths, $rev) = @_;
2583         foreach (keys %$paths) {
2584                 my $i = $paths->{$_};
2585                 my ($m, $p0, $r0) = ($i->action, $i->copyfrom_path,
2586                                         $i->copyfrom_rev);
2587                 next unless (defined $p0 && defined $r0);
2588
2589                 my $p1 = $_;
2590                 $p1 =~ s#^/##;
2591                 $p0 =~ s#^/##;
2592                 my $c = find_graft_path_commit($tree_paths, $p1, $rev);
2593                 next unless $c;
2594                 find_graft_path_parents($grafts, $tree_paths, $c, $p0, $r0);
2595         }
2596 }
2597
2598 sub set_index {
2599         my $old = $ENV{GIT_INDEX_FILE};
2600         $ENV{GIT_INDEX_FILE} = shift;
2601         return $old;
2602 }
2603
2604 sub restore_index {
2605         my ($old) = @_;
2606         if (defined $old) {
2607                 $ENV{GIT_INDEX_FILE} = $old;
2608         } else {
2609                 delete $ENV{GIT_INDEX_FILE};
2610         }
2611 }
2612
2613 sub libsvn_commit_cb {
2614         my ($rev, $date, $committer, $c, $msg, $r_last, $cmt_last) = @_;
2615         if ($_optimize_commits && $rev == ($r_last + 1)) {
2616                 my $log = libsvn_log_entry($rev,$committer,$date,$msg);
2617                 $log->{tree} = get_tree_from_treeish($c);
2618                 my $cmt = git_commit($log, $cmt_last, $c);
2619                 my @diff = command('diff-tree', $cmt, $c);
2620                 if (@diff) {
2621                         print STDERR "Trees differ: $cmt $c\n",
2622                                         join('',@diff),"\n";
2623                         exit 1;
2624                 }
2625         } else {
2626                 fetch("$rev=$c");
2627         }
2628 }
2629
2630 sub libsvn_ls_fullurl {
2631         my $fullurl = shift;
2632         my $ra = libsvn_connect($fullurl);
2633         my @ret;
2634         my $pool = SVN::Pool->new;
2635         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
2636         my ($dirent, undef, undef) = $ra->get_dir('', $r, $pool);
2637         foreach my $d (keys %$dirent) {
2638                 if ($dirent->{$d}->kind == $SVN::Node::dir) {
2639                         push @ret, "$d/"; # add '/' for compat with cli svn
2640                 }
2641         }
2642         $pool->clear;
2643         return @ret;
2644 }
2645
2646
2647 sub libsvn_skip_unknown_revs {
2648         my $err = shift;
2649         my $errno = $err->apr_err();
2650         # Maybe the branch we're tracking didn't
2651         # exist when the repo started, so it's
2652         # not an error if it doesn't, just continue
2653         #
2654         # Wonderfully consistent library, eh?
2655         # 160013 - svn:// and file://
2656         # 175002 - http(s)://
2657         # 175007 - http(s):// (this repo required authorization, too...)
2658         #   More codes may be discovered later...
2659         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2660                 return;
2661         }
2662         croak "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2663 };
2664
2665 # Tie::File seems to be prone to offset errors if revisions get sparse,
2666 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2667 # one of my favorite modules is out :<  Next up would be one of the DBM
2668 # modules, but I'm not sure which is most portable...  So I'll just
2669 # go with something that's plain-text, but still capable of
2670 # being randomly accessed.  So here's my ultra-simple fixed-width
2671 # database.  All records are 40 characters + "\n", so it's easy to seek
2672 # to a revision: (41 * rev) is the byte offset.
2673 # A record of 40 0s denotes an empty revision.
2674 # And yes, it's still pretty fast (faster than Tie::File).
2675 sub revdb_set {
2676         my ($file, $rev, $commit) = @_;
2677         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
2678         open my $fh, '+<', $file or croak $!;
2679         my $offset = $rev * 41;
2680         # assume that append is the common case:
2681         seek $fh, 0, 2 or croak $!;
2682         my $pos = tell $fh;
2683         if ($pos < $offset) {
2684                 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41);
2685         }
2686         seek $fh, $offset, 0 or croak $!;
2687         print $fh $commit,"\n";
2688         close $fh or croak $!;
2689 }
2690
2691 sub revdb_get {
2692         my ($file, $rev) = @_;
2693         my $ret;
2694         my $offset = $rev * 41;
2695         open my $fh, '<', $file or croak $!;
2696         seek $fh, $offset, 0;
2697         if (tell $fh == $offset) {
2698                 $ret = readline $fh;
2699                 if (defined $ret) {
2700                         chomp $ret;
2701                         $ret = undef if ($ret =~ /^0{40}$/);
2702                 }
2703         }
2704         close $fh or croak $!;
2705         return $ret;
2706 }
2707
2708 sub copy_remote_ref {
2709         my $origin = $_cp_remote ? $_cp_remote : 'origin';
2710         my $ref = "refs/remotes/$GIT_SVN";
2711         if (command('ls-remote', $origin, $ref)) {
2712                 command_noisy('fetch', $origin, "$ref:$ref");
2713         } elsif ($_cp_remote && !$_upgrade) {
2714                 die "Unable to find remote reference: ",
2715                                 "refs/remotes/$GIT_SVN on $origin\n";
2716         }
2717 }
2718
2719 {
2720         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2721                                 $SVN::Node::dir.$SVN::Node::unknown.
2722                                 $SVN::Node::none.$SVN::Node::file.
2723                                 $SVN::Node::dir.$SVN::Node::unknown.
2724                                 $SVN::Auth::SSL::CNMISMATCH.
2725                                 $SVN::Auth::SSL::NOTYETVALID.
2726                                 $SVN::Auth::SSL::EXPIRED.
2727                                 $SVN::Auth::SSL::UNKNOWNCA.
2728                                 $SVN::Auth::SSL::OTHER;
2729 }
2730
2731 package SVN::Git::Fetcher;
2732 use vars qw/@ISA/;
2733 use strict;
2734 use warnings;
2735 use Carp qw/croak/;
2736 use IO::File qw//;
2737 use Git qw/command command_oneline command_noisy
2738            command_output_pipe command_input_pipe command_close_pipe/;
2739
2740 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2741 sub new {
2742         my ($class, $git_svn) = @_;
2743         my $self = SVN::Delta::Editor->new;
2744         bless $self, $class;
2745         $self->{c} = $git_svn->{c} if exists $git_svn->{c};
2746         $self->{q} = $git_svn->{q};
2747         $self->{empty} = {};
2748         $self->{dir_prop} = {};
2749         $self->{file_prop} = {};
2750         $self->{absent_dir} = {};
2751         $self->{absent_file} = {};
2752         ($self->{gui}, $self->{ctx}) = command_input_pipe(
2753                                              qw/update-index -z --index-info/);
2754         require Digest::MD5;
2755         $self;
2756 }
2757
2758 sub open_root {
2759         { path => '' };
2760 }
2761
2762 sub open_directory {
2763         my ($self, $path, $pb, $rev) = @_;
2764         { path => $path };
2765 }
2766
2767 sub delete_entry {
2768         my ($self, $path, $rev, $pb) = @_;
2769         my $t = process_rm($self->{gui}, $self->{c}, $path, $self->{q});
2770         $self->{empty}->{$path} = 0 if $t == $SVN::Node::dir;
2771         undef;
2772 }
2773
2774 sub open_file {
2775         my ($self, $path, $pb, $rev) = @_;
2776         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--',$path)
2777                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2778         unless (defined $mode && defined $blob) {
2779                 die "$path was not found in commit $self->{c} (r$rev)\n";
2780         }
2781         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2782           pool => SVN::Pool->new, action => 'M' };
2783 }
2784
2785 sub add_file {
2786         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2787         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2788         delete $self->{empty}->{$dir};
2789         { path => $path, mode_a => 100644, mode_b => 100644,
2790           pool => SVN::Pool->new, action => 'A' };
2791 }
2792
2793 sub add_directory {
2794         my ($self, $path, $cp_path, $cp_rev) = @_;
2795         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2796         delete $self->{empty}->{$dir};
2797         $self->{empty}->{$path} = 1;
2798         { path => $path };
2799 }
2800
2801 sub change_dir_prop {
2802         my ($self, $db, $prop, $value) = @_;
2803         $self->{dir_prop}->{$db->{path}} ||= {};
2804         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2805         undef;
2806 }
2807
2808 sub absent_directory {
2809         my ($self, $path, $pb) = @_;
2810         $self->{absent_dir}->{$pb->{path}} ||= [];
2811         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2812         undef;
2813 }
2814
2815 sub absent_file {
2816         my ($self, $path, $pb) = @_;
2817         $self->{absent_file}->{$pb->{path}} ||= [];
2818         push @{$self->{absent_file}->{$pb->{path}}}, $path;
2819         undef;
2820 }
2821
2822 sub change_file_prop {
2823         my ($self, $fb, $prop, $value) = @_;
2824         if ($prop eq 'svn:executable') {
2825                 if ($fb->{mode_b} != 120000) {
2826                         $fb->{mode_b} = defined $value ? 100755 : 100644;
2827                 }
2828         } elsif ($prop eq 'svn:special') {
2829                 $fb->{mode_b} = defined $value ? 120000 : 100644;
2830         } else {
2831                 $self->{file_prop}->{$fb->{path}} ||= {};
2832                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2833         }
2834         undef;
2835 }
2836
2837 sub apply_textdelta {
2838         my ($self, $fb, $exp) = @_;
2839         my $fh = IO::File->new_tmpfile;
2840         $fh->autoflush(1);
2841         # $fh gets auto-closed() by SVN::TxDelta::apply(),
2842         # (but $base does not,) so dup() it for reading in close_file
2843         open my $dup, '<&', $fh or croak $!;
2844         my $base = IO::File->new_tmpfile;
2845         $base->autoflush(1);
2846         if ($fb->{blob}) {
2847                 defined (my $pid = fork) or croak $!;
2848                 if (!$pid) {
2849                         open STDOUT, '>&', $base or croak $!;
2850                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2851                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2852                 }
2853                 waitpid $pid, 0;
2854                 croak $? if $?;
2855
2856                 if (defined $exp) {
2857                         seek $base, 0, 0 or croak $!;
2858                         my $md5 = Digest::MD5->new;
2859                         $md5->addfile($base);
2860                         my $got = $md5->hexdigest;
2861                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2862                             "expected: $exp\n",
2863                             "     got: $got\n" if ($got ne $exp);
2864                 }
2865         }
2866         seek $base, 0, 0 or croak $!;
2867         $fb->{fh} = $dup;
2868         $fb->{base} = $base;
2869         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2870 }
2871
2872 sub close_file {
2873         my ($self, $fb, $exp) = @_;
2874         my $hash;
2875         my $path = $fb->{path};
2876         if (my $fh = $fb->{fh}) {
2877                 seek($fh, 0, 0) or croak $!;
2878                 my $md5 = Digest::MD5->new;
2879                 $md5->addfile($fh);
2880                 my $got = $md5->hexdigest;
2881                 die "Checksum mismatch: $path\n",
2882                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
2883                 seek($fh, 0, 0) or croak $!;
2884                 if ($fb->{mode_b} == 120000) {
2885                         read($fh, my $buf, 5) == 5 or croak $!;
2886                         $buf eq 'link ' or die "$path has mode 120000",
2887                                                "but is not a link\n";
2888                 }
2889                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2890                 if (!$pid) {
2891                         open STDIN, '<&', $fh or croak $!;
2892                         exec qw/git-hash-object -w --stdin/ or croak $!;
2893                 }
2894                 chomp($hash = do { local $/; <$out> });
2895                 close $out or croak $!;
2896                 close $fh or croak $!;
2897                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2898                 close $fb->{base} or croak $!;
2899         } else {
2900                 $hash = $fb->{blob} or die "no blob information\n";
2901         }
2902         $fb->{pool}->clear;
2903         my $gui = $self->{gui};
2904         print $gui "$fb->{mode_b} $hash\t$path\0" or croak $!;
2905         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
2906         undef;
2907 }
2908
2909 sub abort_edit {
2910         my $self = shift;
2911         eval { command_close_pipe($self->{gui}, $self->{ctx}) };
2912         $self->SUPER::abort_edit(@_);
2913 }
2914
2915 sub close_edit {
2916         my $self = shift;
2917         command_close_pipe($self->{gui}, $self->{ctx});
2918         $self->{git_commit_ok} = 1;
2919         $self->SUPER::close_edit(@_);
2920 }
2921
2922 package SVN::Git::Editor;
2923 use vars qw/@ISA/;
2924 use strict;
2925 use warnings;
2926 use Carp qw/croak/;
2927 use IO::File;
2928 use Git qw/command command_oneline command_noisy
2929            command_output_pipe command_input_pipe command_close_pipe/;
2930
2931 sub new {
2932         my $class = shift;
2933         my $git_svn = shift;
2934         my $self = SVN::Delta::Editor->new(@_);
2935         bless $self, $class;
2936         foreach (qw/svn_path c r ra /) {
2937                 die "$_ required!\n" unless (defined $git_svn->{$_});
2938                 $self->{$_} = $git_svn->{$_};
2939         }
2940         $self->{pool} = SVN::Pool->new;
2941         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2942         $self->{rm} = { };
2943         require Digest::MD5;
2944         return $self;
2945 }
2946
2947 sub split_path {
2948         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2949 }
2950
2951 sub repo_path {
2952         (defined $_[1] && length $_[1]) ? $_[1] : ''
2953 }
2954
2955 sub url_path {
2956         my ($self, $path) = @_;
2957         $self->{ra}->{url} . '/' . $self->repo_path($path);
2958 }
2959
2960 sub rmdirs {
2961         my ($self, $q) = @_;
2962         my $rm = $self->{rm};
2963         delete $rm->{''}; # we never delete the url we're tracking
2964         return unless %$rm;
2965
2966         foreach (keys %$rm) {
2967                 my @d = split m#/#, $_;
2968                 my $c = shift @d;
2969                 $rm->{$c} = 1;
2970                 while (@d) {
2971                         $c .= '/' . shift @d;
2972                         $rm->{$c} = 1;
2973                 }
2974         }
2975         delete $rm->{$self->{svn_path}};
2976         delete $rm->{''}; # we never delete the url we're tracking
2977         return unless %$rm;
2978
2979         my ($fh, $ctx) = command_output_pipe(
2980                                    qw/ls-tree --name-only -r -z/, $self->{c});
2981         local $/ = "\0";
2982         while (<$fh>) {
2983                 chomp;
2984                 my @dn = split m#/#, $_;
2985                 while (pop @dn) {
2986                         delete $rm->{join '/', @dn};
2987                 }
2988                 unless (%$rm) {
2989                         eval { command_close_pipe($fh) };
2990                         return;
2991                 }
2992         }
2993         command_close_pipe($fh, $ctx);
2994
2995         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2996         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2997                 $self->close_directory($bat->{$d}, $p);
2998                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2999                 print "\tD+\t/$d/\n" unless $q;
3000                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3001                 delete $bat->{$d};
3002         }
3003 }
3004
3005 sub open_or_add_dir {
3006         my ($self, $full_path, $baton) = @_;
3007         my $p = SVN::Pool->new;
3008         my $t = $self->{ra}->check_path($full_path, $self->{r}, $p);
3009         $p->clear;
3010         if ($t == $SVN::Node::none) {
3011                 return $self->add_directory($full_path, $baton,
3012                                                 undef, -1, $self->{pool});
3013         } elsif ($t == $SVN::Node::dir) {
3014                 return $self->open_directory($full_path, $baton,
3015                                                 $self->{r}, $self->{pool});
3016         }
3017         print STDERR "$full_path already exists in repository at ",
3018                 "r$self->{r} and it is not a directory (",
3019                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3020         exit 1;
3021 }
3022
3023 sub ensure_path {
3024         my ($self, $path) = @_;
3025         my $bat = $self->{bat};
3026         $path = $self->repo_path($path);
3027         return $bat->{''} unless (length $path);
3028         my @p = split m#/+#, $path;
3029         my $c = shift @p;
3030         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3031         while (@p) {
3032                 my $c0 = $c;
3033                 $c .= '/' . shift @p;
3034                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3035         }
3036         return $bat->{$c};
3037 }
3038
3039 sub A {
3040         my ($self, $m, $q) = @_;
3041         my ($dir, $file) = split_path($m->{file_b});
3042         my $pbat = $self->ensure_path($dir);
3043         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3044                                         undef, -1);
3045         print "\tA\t$m->{file_b}\n" unless $q;
3046         $self->chg_file($fbat, $m);
3047         $self->close_file($fbat,undef,$self->{pool});
3048 }
3049
3050 sub C {
3051         my ($self, $m, $q) = @_;
3052         my ($dir, $file) = split_path($m->{file_b});
3053         my $pbat = $self->ensure_path($dir);
3054         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3055                                 $self->url_path($m->{file_a}), $self->{r});
3056         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $q;
3057         $self->chg_file($fbat, $m);
3058         $self->close_file($fbat,undef,$self->{pool});
3059 }
3060
3061 sub delete_entry {
3062         my ($self, $path, $pbat) = @_;
3063         my $rpath = $self->repo_path($path);
3064         my ($dir, $file) = split_path($rpath);
3065         $self->{rm}->{$dir} = 1;
3066         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3067 }
3068
3069 sub R {
3070         my ($self, $m, $q) = @_;
3071         my ($dir, $file) = split_path($m->{file_b});
3072         my $pbat = $self->ensure_path($dir);
3073         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3074                                 $self->url_path($m->{file_a}), $self->{r});
3075         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $q;
3076         $self->chg_file($fbat, $m);
3077         $self->close_file($fbat,undef,$self->{pool});
3078
3079         ($dir, $file) = split_path($m->{file_a});
3080         $pbat = $self->ensure_path($dir);
3081         $self->delete_entry($m->{file_a}, $pbat);
3082 }
3083
3084 sub M {
3085         my ($self, $m, $q) = @_;
3086         my ($dir, $file) = split_path($m->{file_b});
3087         my $pbat = $self->ensure_path($dir);
3088         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3089                                 $pbat,$self->{r},$self->{pool});
3090         print "\t$m->{chg}\t$m->{file_b}\n" unless $q;
3091         $self->chg_file($fbat, $m);
3092         $self->close_file($fbat,undef,$self->{pool});
3093 }
3094
3095 sub T { shift->M(@_) }
3096
3097 sub change_file_prop {
3098         my ($self, $fbat, $pname, $pval) = @_;
3099         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3100 }
3101
3102 sub chg_file {
3103         my ($self, $fbat, $m) = @_;
3104         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3105                 $self->change_file_prop($fbat,'svn:executable','*');
3106         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3107                 $self->change_file_prop($fbat,'svn:executable',undef);
3108         }
3109         my $fh = IO::File->new_tmpfile or croak $!;
3110         if ($m->{mode_b} =~ /^120/) {
3111                 print $fh 'link ' or croak $!;
3112                 $self->change_file_prop($fbat,'svn:special','*');
3113         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3114                 $self->change_file_prop($fbat,'svn:special',undef);
3115         }
3116         defined(my $pid = fork) or croak $!;
3117         if (!$pid) {
3118                 open STDOUT, '>&', $fh or croak $!;
3119                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3120         }
3121         waitpid $pid, 0;
3122         croak $? if $?;
3123         $fh->flush == 0 or croak $!;
3124         seek $fh, 0, 0 or croak $!;
3125
3126         my $md5 = Digest::MD5->new;
3127         $md5->addfile($fh) or croak $!;
3128         seek $fh, 0, 0 or croak $!;
3129
3130         my $exp = $md5->hexdigest;
3131         my $pool = SVN::Pool->new;
3132         my $atd = $self->apply_textdelta($fbat, undef, $pool);
3133         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3134         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3135         $pool->clear;
3136
3137         close $fh or croak $!;
3138 }
3139
3140 sub D {
3141         my ($self, $m, $q) = @_;
3142         my ($dir, $file) = split_path($m->{file_b});
3143         my $pbat = $self->ensure_path($dir);
3144         print "\tD\t$m->{file_b}\n" unless $q;
3145         $self->delete_entry($m->{file_b}, $pbat);
3146 }
3147
3148 sub close_edit {
3149         my ($self) = @_;
3150         my ($p,$bat) = ($self->{pool}, $self->{bat});
3151         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3152                 $self->close_directory($bat->{$_}, $p);
3153         }
3154         $self->SUPER::close_edit($p);
3155         $p->clear;
3156 }
3157
3158 sub abort_edit {
3159         my ($self) = @_;
3160         $self->SUPER::abort_edit($self->{pool});
3161         $self->{pool}->clear;
3162 }
3163
3164 __END__
3165
3166 Data structures:
3167
3168 $log_msg hashref as returned by libsvn_log_entry()
3169 {
3170         msg => 'whitespace-formatted log entry
3171 ',                                              # trailing newline is preserved
3172         revision => '8',                        # integer
3173         date => '2004-02-24T17:01:44.108345Z',  # commit date
3174         author => 'committer name'
3175 };
3176
3177 @mods = array of diff-index line hashes, each element represents one line
3178         of diff-index output
3179
3180 diff-index line ($m hash)
3181 {
3182         mode_a => first column of diff-index output, no leading ':',
3183         mode_b => second column of diff-index output,
3184         sha1_b => sha1sum of the final blob,
3185         chg => change type [MCRADT],
3186         file_a => original file name of a file (iff chg is 'C' or 'R')
3187         file_b => new/current file name of a file (any chg)
3188 }
3189 ;
3190
3191 # retval of read_url_paths{,_all}();
3192 $l_map = {
3193         # repository root url
3194         'https://svn.musicpd.org' => {
3195                 # repository path               # GIT_SVN_ID
3196                 'mpd/trunk'             =>      'trunk',
3197                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
3198         },
3199 }
3200
3201 Notes:
3202         I don't trust the each() function on unless I created %hash myself
3203         because the internal iterator may not have started at base.