git.oblomov.eu Git - git/blob - perl/Git/SVN.pm

   1 package Git::SVN;
   2 use strict;
   3 use warnings;
   4 use Fcntl qw/:DEFAULT :seek/;
   5 use constant rev_map_fmt => 'NH40';
   6 use vars qw/$_no_metadata
   7             $_repack $_repack_flags $_use_svm_props $_head
   8             $_use_svnsync_props $no_reuse_existing
   9             $_use_log_author $_add_author_from $_localtime/;
  10 use Carp qw/croak/;
  11 use File::Path qw/mkpath/;
  12 use File::Copy qw/copy/;
  13 use IPC::Open3;
  14 use Time::Local;
  15 use Memoize;  # core since 5.8.0, Jul 2002
  16 use Memoize::Storable;
  17 use POSIX qw(:signal_h);
  18
  19 use Git qw(
  20     command
  21     command_oneline
  22     command_noisy
  23     command_output_pipe
  24     command_close_pipe
  25 );
  26 use Git::SVN::Utils qw(
  27         fatal
  28         can_compress
  29         join_paths
  30         canonicalize_path
  31         canonicalize_url
  32         add_path_to_url
  33 );
  34
  35 my $can_use_yaml;
  36 BEGIN {
  37         $can_use_yaml = eval { require Git::SVN::Memoize::YAML; 1};
  38 }
  39
  40 our $_follow_parent  = 1;
  41 our $_minimize_url   = 'unset';
  42 our $default_repo_id = 'svn';
  43 our $default_ref_id  = $ENV{GIT_SVN_ID} || 'git-svn';
  44
  45 my ($_gc_nr, $_gc_period);
  46
  47 # properties that we do not log:
  48 my %SKIP_PROP;
  49 BEGIN {
  50         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
  51                                         svn:special svn:executable
  52                                         svn:entry:committed-rev
  53                                         svn:entry:last-author
  54                                         svn:entry:uuid
  55                                         svn:entry:committed-date/;
  56
  57         # some options are read globally, but can be overridden locally
  58         # per [svn-remote "..."] section.  Command-line options will *NOT*
  59         # override options set in an [svn-remote "..."] section
  60         no strict 'refs';
  61         for my $option (qw/follow_parent no_metadata use_svm_props
  62                            use_svnsync_props/) {
  63                 my $key = $option;
  64                 $key =~ tr/_//d;
  65                 my $prop = "-$option";
  66                 *$option = sub {
  67                         my ($self) = @_;
  68                         return $self->{$prop} if exists $self->{$prop};
  69                         my $k = "svn-remote.$self->{repo_id}.$key";
  70                         eval { command_oneline(qw/config --get/, $k) };
  71                         if ($@) {
  72                                 $self->{$prop} = ${"Git::SVN::_$option"};
  73                         } else {
  74                                 my $v = command_oneline(qw/config --bool/,$k);
  75                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
  76                         }
  77                         return $self->{$prop};
  78                 }
  79         }
  80 }
  81
  82
  83 my (%LOCKFILES, %INDEX_FILES);
  84 END {
  85         unlink keys %LOCKFILES if %LOCKFILES;
  86         unlink keys %INDEX_FILES if %INDEX_FILES;
  87 }
  88
  89 sub resolve_local_globs {
  90         my ($url, $fetch, $glob_spec) = @_;
  91         return unless defined $glob_spec;
  92         my $ref = $glob_spec->{ref};
  93         my $path = $glob_spec->{path};
  94         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
  95                 next unless m#^$ref->{regex}$#;
  96                 my $p = $1;
  97                 my $pathname = desanitize_refname($path->full_path($p));
  98                 my $refname = desanitize_refname($ref->full_path($p));
  99                 if (my $existing = $fetch->{$pathname}) {
 100                         if ($existing ne $refname) {
 101                                 die "Refspec conflict:\n",
 102                                     "existing: $existing\n",
 103                                     " globbed: $refname\n";
 104                         }
 105                         my $u = (::cmt_metadata("$refname"))[0];
 106                         $u =~ s!^\Q$url\E(/|$)!! or die
 107                           "$refname: '$url' not found in '$u'\n";
 108                         if ($pathname ne $u) {
 109                                 warn "W: Refspec glob conflict ",
 110                                      "(ref: $refname):\n",
 111                                      "expected path: $pathname\n",
 112                                      "    real path: $u\n",
 113                                      "Continuing ahead with $u\n";
 114                                 next;
 115                         }
 116                 } else {
 117                         $fetch->{$pathname} = $refname;
 118                 }
 119         }
 120 }
 121
 122 sub parse_revision_argument {
 123         my ($base, $head) = @_;
 124         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 125                 return ($base, $head);
 126         }
 127         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 128         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 129         return ($head, $head) if ($::_revision eq 'HEAD');
 130         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
 131         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 132         die "revision argument: $::_revision not understood by git-svn\n";
 133 }
 134
 135 sub fetch_all {
 136         my ($repo_id, $remotes) = @_;
 137         if (ref $repo_id) {
 138                 my $gs = $repo_id;
 139                 $repo_id = undef;
 140                 $repo_id = $gs->{repo_id};
 141         }
 142         $remotes ||= read_all_remotes();
 143         my $remote = $remotes->{$repo_id} or
 144                      die "[svn-remote \"$repo_id\"] unknown\n";
 145         my $fetch = $remote->{fetch};
 146         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
 147         my (@gs, @globs);
 148         my $ra = Git::SVN::Ra->new($url);
 149         my $uuid = $ra->get_uuid;
 150         my $head = $ra->get_latest_revnum;
 151
 152         # ignore errors, $head revision may not even exist anymore
 153         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
 154         warn "W: $@\n" if $@;
 155
 156         my $base = defined $fetch ? $head : 0;
 157
 158         # read the max revs for wildcard expansion (branches/*, tags/*)
 159         foreach my $t (qw/branches tags/) {
 160                 defined $remote->{$t} or next;
 161                 push @globs, @{$remote->{$t}};
 162
 163                 my $max_rev = eval { tmp_config(qw/--int --get/,
 164                                          "svn-remote.$repo_id.${t}-maxRev") };
 165                 if (defined $max_rev && ($max_rev < $base)) {
 166                         $base = $max_rev;
 167                 } elsif (!defined $max_rev) {
 168                         $base = 0;
 169                 }
 170         }
 171
 172         if ($fetch) {
 173                 foreach my $p (sort keys %$fetch) {
 174                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 175                         my $lr = $gs->rev_map_max;
 176                         if (defined $lr) {
 177                                 $base = $lr if ($lr < $base);
 178                         }
 179                         push @gs, $gs;
 180                 }
 181         }
 182
 183         ($base, $head) = parse_revision_argument($base, $head);
 184         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
 185 }
 186
 187 sub read_all_remotes {
 188         my $r = {};
 189         my $use_svm_props = eval { command_oneline(qw/config --bool
 190             svn.useSvmProps/) };
 191         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
 192         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
 193         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 194                 if (m!^(.+)\.fetch=$svn_refspec$!) {
 195                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
 196                         die("svn-remote.$remote: remote ref '$remote_ref' "
 197                             . "must start with 'refs/'\n")
 198                                 unless $remote_ref =~ m{^refs/};
 199                         $local_ref = uri_decode($local_ref);
 200                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
 201                         $r->{$remote}->{svm} = {} if $use_svm_props;
 202                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
 203                         $r->{$1}->{svm} = {};
 204                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 205                         $r->{$1}->{url} = canonicalize_url($2);
 206                 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
 207                         $r->{$1}->{pushurl} = canonicalize_url($2);
 208                 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
 209                         $r->{$1}->{ignore_refs_regex} = $2;
 210                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
 211                         my ($remote, $t, $local_ref, $remote_ref) =
 212                                                              ($1, $2, $3, $4);
 213                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
 214                             . "must start with 'refs/'\n")
 215                                 unless $remote_ref =~ m{^refs/};
 216                         $local_ref = uri_decode($local_ref);
 217
 218                         require Git::SVN::GlobSpec;
 219                         my $rs = {
 220                             t => $t,
 221                             remote => $remote,
 222                             path => Git::SVN::GlobSpec->new($local_ref, 1),
 223                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
 224                         if (length($rs->{ref}->{right}) != 0) {
 225                                 die "The '*' glob character must be the last ",
 226                                     "character of '$remote_ref'\n";
 227                         }
 228                         push @{ $r->{$remote}->{$t} }, $rs;
 229                 }
 230         }
 231
 232         map {
 233                 if (defined $r->{$_}->{svm}) {
 234                         my $svm;
 235                         eval {
 236                                 my $section = "svn-remote.$_";
 237                                 $svm = {
 238                                         source => tmp_config('--get',
 239                                             "$section.svm-source"),
 240                                         replace => tmp_config('--get',
 241                                             "$section.svm-replace"),
 242                                 }
 243                         };
 244                         $r->{$_}->{svm} = $svm;
 245                 }
 246         } keys %$r;
 247
 248         foreach my $remote (keys %$r) {
 249                 foreach ( grep { defined $_ }
 250                           map { $r->{$remote}->{$_} } qw(branches tags) ) {
 251                         foreach my $rs ( @$_ ) {
 252                                 $rs->{ignore_refs_regex} =
 253                                     $r->{$remote}->{ignore_refs_regex};
 254                         }
 255                 }
 256         }
 257
 258         $r;
 259 }
 260
 261 sub init_vars {
 262         $_gc_nr = $_gc_period = 1000;
 263         if (defined $_repack || defined $_repack_flags) {
 264                warn "Repack options are obsolete; they have no effect.\n";
 265         }
 266 }
 267
 268 sub verify_remotes_sanity {
 269         return unless -d $ENV{GIT_DIR};
 270         my %seen;
 271         foreach (command(qw/config -l/)) {
 272                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 273                         if ($seen{$1}) {
 274                                 die "Remote ref refs/remote/$1 is tracked by",
 275                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 276                                     "Please resolve this ambiguity in ",
 277                                     "your git configuration file before ",
 278                                     "continuing\n";
 279                         }
 280                         $seen{$1} = $_;
 281                 }
 282         }
 283 }
 284
 285 sub find_existing_remote {
 286         my ($url, $remotes) = @_;
 287         return undef if $no_reuse_existing;
 288         my $existing;
 289         foreach my $repo_id (keys %$remotes) {
 290                 my $u = $remotes->{$repo_id}->{url} or next;
 291                 next if $u ne $url;
 292                 $existing = $repo_id;
 293                 last;
 294         }
 295         $existing;
 296 }
 297
 298 sub init_remote_config {
 299         my ($self, $url, $no_write) = @_;
 300         $url = canonicalize_url($url);
 301         my $r = read_all_remotes();
 302         my $existing = find_existing_remote($url, $r);
 303         if ($existing) {
 304                 unless ($no_write) {
 305                         print STDERR "Using existing ",
 306                                      "[svn-remote \"$existing\"]\n";
 307                 }
 308                 $self->{repo_id} = $existing;
 309         } elsif ($_minimize_url) {
 310                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 311                 $existing = find_existing_remote($min_url, $r);
 312                 if ($existing) {
 313                         unless ($no_write) {
 314                                 print STDERR "Using existing ",
 315                                              "[svn-remote \"$existing\"]\n";
 316                         }
 317                         $self->{repo_id} = $existing;
 318                 }
 319                 if ($min_url ne $url) {
 320                         unless ($no_write) {
 321                                 print STDERR "Using higher level of URL: ",
 322                                              "$url => $min_url\n";
 323                         }
 324                         my $old_path = $self->path;
 325                         $url =~ s!^\Q$min_url\E(/|$)!!;
 326                         $url = join_paths($url, $old_path);
 327                         $self->path($url);
 328                         $url = $min_url;
 329                 }
 330         }
 331         my $orig_url;
 332         if (!$existing) {
 333                 # verify that we aren't overwriting anything:
 334                 $orig_url = eval {
 335                         command_oneline('config', '--get',
 336                                         "svn-remote.$self->{repo_id}.url")
 337                 };
 338                 if ($orig_url && ($orig_url ne $url)) {
 339                         die "svn-remote.$self->{repo_id}.url already set: ",
 340                             "$orig_url\nwanted to set to: $url\n";
 341                 }
 342         }
 343         my ($xrepo_id, $xpath) = find_ref($self->refname);
 344         if (!$no_write && defined $xpath) {
 345                 die "svn-remote.$xrepo_id.fetch already set to track ",
 346                     "$xpath:", $self->refname, "\n";
 347         }
 348         unless ($no_write) {
 349                 command_noisy('config',
 350                               "svn-remote.$self->{repo_id}.url", $url);
 351                 my $path = $self->path;
 352                 $path =~ s{^/}{};
 353                 $path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
 354                 $self->path($path);
 355                 command_noisy('config', '--add',
 356                               "svn-remote.$self->{repo_id}.fetch",
 357                               $self->path.":".$self->refname);
 358         }
 359         $self->url($url);
 360 }
 361
 362 sub find_by_url { # repos_root and, path are optional
 363         my ($class, $full_url, $repos_root, $path) = @_;
 364
 365         $full_url = canonicalize_url($full_url);
 366
 367         return undef unless defined $full_url;
 368         remove_username($full_url);
 369         remove_username($repos_root) if defined $repos_root;
 370         my $remotes = read_all_remotes();
 371         if (defined $full_url && defined $repos_root && !defined $path) {
 372                 $path = $full_url;
 373                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
 374         }
 375         foreach my $repo_id (keys %$remotes) {
 376                 my $u = $remotes->{$repo_id}->{url} or next;
 377                 remove_username($u);
 378                 next if defined $repos_root && $repos_root ne $u;
 379
 380                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
 381                 foreach my $t (qw/branches tags/) {
 382                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
 383                                 resolve_local_globs($u, $fetch, $globspec);
 384                         }
 385                 }
 386                 my $p = $path;
 387                 my $rwr = rewrite_root({repo_id => $repo_id});
 388                 my $svm = $remotes->{$repo_id}->{svm}
 389                         if defined $remotes->{$repo_id}->{svm};
 390                 unless (defined $p) {
 391                         $p = $full_url;
 392                         my $z = $u;
 393                         my $prefix = '';
 394                         if ($rwr) {
 395                                 $z = $rwr;
 396                                 remove_username($z);
 397                         } elsif (defined $svm) {
 398                                 $z = $svm->{source};
 399                                 $prefix = $svm->{replace};
 400                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
 401                                 $prefix =~ s#/$##;
 402                         }
 403                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
 404                 }
 405
 406                 # remote fetch paths are not URI escaped.  Decode ours
 407                 # so they match
 408                 $p = uri_decode($p);
 409
 410                 foreach my $f (keys %$fetch) {
 411                         next if $f ne $p;
 412                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
 413                 }
 414         }
 415         undef;
 416 }
 417
 418 sub init {
 419         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
 420         my $self = _new($class, $repo_id, $ref_id, $path);
 421         if (defined $url) {
 422                 $self->init_remote_config($url, $no_write);
 423         }
 424         $self;
 425 }
 426
 427 sub find_ref {
 428         my ($ref_id) = @_;
 429         foreach (command(qw/config -l/)) {
 430                 next unless m!^svn-remote\.(.+)\.fetch=
 431                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
 432                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 433                 if ($ref eq $ref_id) {
 434                         $path = '' if ($path =~ m#^\./?#);
 435                         return ($repo_id, $path);
 436                 }
 437         }
 438         (undef, undef, undef);
 439 }
 440
 441 sub new {
 442         my ($class, $ref_id, $repo_id, $path) = @_;
 443         if (defined $ref_id && !defined $repo_id && !defined $path) {
 444                 ($repo_id, $path) = find_ref($ref_id);
 445                 if (!defined $repo_id) {
 446                         die "Could not find a \"svn-remote.*.fetch\" key ",
 447                             "in the repository configuration matching: ",
 448                             "$ref_id\n";
 449                 }
 450         }
 451         my $self = _new($class, $repo_id, $ref_id, $path);
 452         if (!defined $self->path || !length $self->path) {
 453                 my $fetch = command_oneline('config', '--get',
 454                                             "svn-remote.$repo_id.fetch",
 455                                             ":$ref_id\$") or
 456                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 457                          "\":$ref_id\$\" in config\n";
 458                 my($path) = split(/\s*:\s*/, $fetch);
 459                 $self->path($path);
 460         }
 461         {
 462                 my $path = $self->path;
 463                 $path =~ s{\A/}{};
 464                 $path =~ s{/\z}{};
 465                 $self->path($path);
 466         }
 467         my $url = command_oneline('config', '--get',
 468                                   "svn-remote.$repo_id.url") or
 469                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 470         $self->url($url);
 471         $self->{pushurl} = eval { command_oneline('config', '--get',
 472                                   "svn-remote.$repo_id.pushurl") };
 473         $self->rebuild;
 474         $self;
 475 }
 476
 477 sub refname {
 478         my ($refname) = $_[0]->{ref_id} ;
 479
 480         # It cannot end with a slash /, we'll throw up on this because
 481         # SVN can't have directories with a slash in their name, either:
 482         if ($refname =~ m{/$}) {
 483                 die "ref: '$refname' ends with a trailing slash, this is ",
 484                     "not permitted by git nor Subversion\n";
 485         }
 486
 487         # It cannot have ASCII control character space, tilde ~, caret ^,
 488         # colon :, question-mark ?, asterisk *, space, or open bracket [
 489         # anywhere.
 490         #
 491         # Additionally, % must be escaped because it is used for escaping
 492         # and we want our escaped refname to be reversible
 493         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
 494
 495         # no slash-separated component can begin with a dot .
 496         # /.* becomes /%2E*
 497         $refname =~ s{/\.}{/%2E}g;
 498
 499         # It cannot have two consecutive dots .. anywhere
 500         # .. becomes %2E%2E
 501         $refname =~ s{\.\.}{%2E%2E}g;
 502
 503         # trailing dots and .lock are not allowed
 504         # .$ becomes %2E and .lock becomes %2Elock
 505         $refname =~ s{\.(?=$|lock$)}{%2E};
 506
 507         # the sequence @{ is used to access the reflog
 508         # @{ becomes %40{
 509         $refname =~ s{\@\{}{%40\{}g;
 510
 511         return $refname;
 512 }
 513
 514 sub desanitize_refname {
 515         my ($refname) = @_;
 516         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
 517         return $refname;
 518 }
 519
 520 sub svm_uuid {
 521         my ($self) = @_;
 522         return $self->{svm}->{uuid} if $self->svm;
 523         $self->ra;
 524         unless ($self->{svm}) {
 525                 die "SVM UUID not cached, and reading remotely failed\n";
 526         }
 527         $self->{svm}->{uuid};
 528 }
 529
 530 sub svm {
 531         my ($self) = @_;
 532         return $self->{svm} if $self->{svm};
 533         my $svm;
 534         # see if we have it in our config, first:
 535         eval {
 536                 my $section = "svn-remote.$self->{repo_id}";
 537                 $svm = {
 538                   source => tmp_config('--get', "$section.svm-source"),
 539                   uuid => tmp_config('--get', "$section.svm-uuid"),
 540                   replace => tmp_config('--get', "$section.svm-replace"),
 541                 }
 542         };
 543         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
 544                 $self->{svm} = $svm;
 545         }
 546         $self->{svm};
 547 }
 548
 549 sub _set_svm_vars {
 550         my ($self, $ra) = @_;
 551         return $ra if $self->svm;
 552
 553         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
 554                     "(svm:source, svm:uuid) ",
 555                     "from the following URLs:\n" );
 556         sub read_svm_props {
 557                 my ($self, $ra, $path, $r) = @_;
 558                 my $props = ($ra->get_dir($path, $r))[2];
 559                 my $src = $props->{'svm:source'};
 560                 my $uuid = $props->{'svm:uuid'};
 561                 return undef if (!$src || !$uuid);
 562
 563                 chomp($src, $uuid);
 564
 565                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
 566                     or die "doesn't look right - svm:uuid is '$uuid'\n";
 567
 568                 # the '!' is used to mark the repos_root!/relative/path
 569                 $src =~ s{/?!/?}{/};
 570                 $src =~ s{/+$}{}; # no trailing slashes please
 571                 # username is of no interest
 572                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
 573
 574                 my $replace = add_path_to_url($ra->url, $path);
 575
 576                 my $section = "svn-remote.$self->{repo_id}";
 577                 tmp_config("$section.svm-source", $src);
 578                 tmp_config("$section.svm-replace", $replace);
 579                 tmp_config("$section.svm-uuid", $uuid);
 580                 $self->{svm} = {
 581                         source => $src,
 582                         uuid => $uuid,
 583                         replace => $replace
 584                 };
 585         }
 586
 587         my $r = $ra->get_latest_revnum;
 588         my $path = $self->path;
 589         my %tried;
 590         while (length $path) {
 591                 my $try = add_path_to_url($self->url, $path);
 592                 unless ($tried{$try}) {
 593                         return $ra if $self->read_svm_props($ra, $path, $r);
 594                         $tried{$try} = 1;
 595                 }
 596                 $path =~ s#/?[^/]+$##;
 597         }
 598         die "Path: '$path' should be ''\n" if $path ne '';
 599         return $ra if $self->read_svm_props($ra, $path, $r);
 600         $tried{ add_path_to_url($self->url, $path) } = 1;
 601
 602         if ($ra->{repos_root} eq $self->url) {
 603                 die @err, (map { "  $_\n" } keys %tried), "\n";
 604         }
 605
 606         # nope, make sure we're connected to the repository root:
 607         my $ok;
 608         my @tried_b;
 609         $path = $ra->{svn_path};
 610         $ra = Git::SVN::Ra->new($ra->{repos_root});
 611         while (length $path) {
 612                 my $try = add_path_to_url($ra->url, $path);
 613                 unless ($tried{$try}) {
 614                         $ok = $self->read_svm_props($ra, $path, $r);
 615                         last if $ok;
 616                         $tried{$try} = 1;
 617                 }
 618                 $path =~ s#/?[^/]+$##;
 619         }
 620         die "Path: '$path' should be ''\n" if $path ne '';
 621         $ok ||= $self->read_svm_props($ra, $path, $r);
 622         $tried{ add_path_to_url($ra->url, $path) } = 1;
 623         if (!$ok) {
 624                 die @err, (map { "  $_\n" } keys %tried), "\n";
 625         }
 626         Git::SVN::Ra->new($self->url);
 627 }
 628
 629 sub svnsync {
 630         my ($self) = @_;
 631         return $self->{svnsync} if $self->{svnsync};
 632
 633         if ($self->no_metadata) {
 634                 die "Can't have both 'noMetadata' and ",
 635                     "'useSvnsyncProps' options set!\n";
 636         }
 637         if ($self->rewrite_root) {
 638                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
 639                     "options set!\n";
 640         }
 641         if ($self->rewrite_uuid) {
 642                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
 643                     "options set!\n";
 644         }
 645
 646         my $svnsync;
 647         # see if we have it in our config, first:
 648         eval {
 649                 my $section = "svn-remote.$self->{repo_id}";
 650
 651                 my $url = tmp_config('--get', "$section.svnsync-url");
 652                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
 653                    die "doesn't look right - svn:sync-from-url is '$url'\n";
 654
 655                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
 656                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
 657                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
 658
 659                 $svnsync = { url => $url, uuid => $uuid }
 660         };
 661         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
 662                 return $self->{svnsync} = $svnsync;
 663         }
 664
 665         my $err = "useSvnsyncProps set, but failed to read " .
 666                   "svnsync property: svn:sync-from-";
 667         my $rp = $self->ra->rev_proplist(0);
 668
 669         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
 670         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
 671                    die "doesn't look right - svn:sync-from-url is '$url'\n";
 672
 673         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
 674         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
 675                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
 676
 677         my $section = "svn-remote.$self->{repo_id}";
 678         tmp_config('--add', "$section.svnsync-uuid", $uuid);
 679         tmp_config('--add', "$section.svnsync-url", $url);
 680         return $self->{svnsync} = { url => $url, uuid => $uuid };
 681 }
 682
 683 # this allows us to memoize our SVN::Ra UUID locally and avoid a
 684 # remote lookup (useful for 'git svn log').
 685 sub ra_uuid {
 686         my ($self) = @_;
 687         unless ($self->{ra_uuid}) {
 688                 my $key = "svn-remote.$self->{repo_id}.uuid";
 689                 my $uuid = eval { tmp_config('--get', $key) };
 690                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
 691                         $self->{ra_uuid} = $uuid;
 692                 } else {
 693                         die "ra_uuid called without URL\n" unless $self->url;
 694                         $self->{ra_uuid} = $self->ra->get_uuid;
 695                         tmp_config('--add', $key, $self->{ra_uuid});
 696                 }
 697         }
 698         $self->{ra_uuid};
 699 }
 700
 701 sub _set_repos_root {
 702         my ($self, $repos_root) = @_;
 703         my $k = "svn-remote.$self->{repo_id}.reposRoot";
 704         $repos_root ||= $self->ra->{repos_root};
 705         tmp_config($k, $repos_root);
 706         $repos_root;
 707 }
 708
 709 sub repos_root {
 710         my ($self) = @_;
 711         my $k = "svn-remote.$self->{repo_id}.reposRoot";
 712         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
 713 }
 714
 715 sub ra {
 716         my ($self) = shift;
 717         my $ra = Git::SVN::Ra->new($self->url);
 718         $self->_set_repos_root($ra->{repos_root});
 719         if ($self->use_svm_props && !$self->{svm}) {
 720                 if ($self->no_metadata) {
 721                         die "Can't have both 'noMetadata' and ",
 722                             "'useSvmProps' options set!\n";
 723                 } elsif ($self->use_svnsync_props) {
 724                         die "Can't have both 'useSvnsyncProps' and ",
 725                             "'useSvmProps' options set!\n";
 726                 }
 727                 $ra = $self->_set_svm_vars($ra);
 728                 $self->{-want_revprops} = 1;
 729         }
 730         $ra;
 731 }
 732
 733 # prop_walk(PATH, REV, SUB)
 734 # -------------------------
 735 # Recursively traverse PATH at revision REV and invoke SUB for each
 736 # directory that contains a SVN property.  SUB will be invoked as
 737 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
 738 # Git::SVN, `path' the path to the directory where the properties
 739 # `props' were found.  The `path' will be relative to point of checkout,
 740 # that is, if url://repo/trunk is the current Git branch, and that
 741 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
 742 # as `path' (note the trailing `/').
 743 sub prop_walk {
 744         my ($self, $path, $rev, $sub) = @_;
 745
 746         $path =~ s#^/##;
 747         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
 748         $path =~ s#^/*#/#g;
 749         my $p = $path;
 750         # Strip the irrelevant part of the path.
 751         $p =~ s#^/+\Q@{[$self->path]}\E(/|$)#/#;
 752         # Ensure the path is terminated by a `/'.
 753         $p =~ s#/*$#/#;
 754
 755         # The properties contain all the internal SVN stuff nobody
 756         # (usually) cares about.
 757         my $interesting_props = 0;
 758         foreach (keys %{$props}) {
 759                 # If it doesn't start with `svn:', it must be a
 760                 # user-defined property.
 761                 ++$interesting_props and next if $_ !~ /^svn:/;
 762                 # FIXME: Fragile, if SVN adds new public properties,
 763                 # this needs to be updated.
 764                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
 765                                                  |eol-style|mime-type
 766                                                  |externals|needs-lock)$/x;
 767         }
 768         &$sub($self, $p, $props) if $interesting_props;
 769
 770         foreach (sort keys %$dirent) {
 771                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
 772                 $self->prop_walk($self->path . $p . $_, $rev, $sub);
 773         }
 774 }
 775
 776 sub last_rev { ($_[0]->last_rev_commit)[0] }
 777 sub last_commit { ($_[0]->last_rev_commit)[1] }
 778
 779 # returns the newest SVN revision number and newest commit SHA1
 780 sub last_rev_commit {
 781         my ($self) = @_;
 782         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 783                 return ($self->{last_rev}, $self->{last_commit});
 784         }
 785         my $c = ::verify_ref($self->refname.'^0');
 786         if ($c && !$self->use_svm_props && !$self->no_metadata) {
 787                 my $rev = (::cmt_metadata($c))[1];
 788                 if (defined $rev) {
 789                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 790                         return ($rev, $c);
 791                 }
 792         }
 793         my $map_path = $self->map_path;
 794         unless (-e $map_path) {
 795                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
 796                 return (undef, undef);
 797         }
 798         my ($rev, $commit) = $self->rev_map_max(1);
 799         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
 800         return ($rev, $commit);
 801 }
 802
 803 sub get_fetch_range {
 804         my ($self, $min, $max) = @_;
 805         $max ||= $self->ra->get_latest_revnum;
 806         $min ||= $self->rev_map_max;
 807         (++$min, $max);
 808 }
 809
 810 sub tmp_config {
 811         my (@args) = @_;
 812         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
 813         my $config = "$ENV{GIT_DIR}/svn/.metadata";
 814         if (! -f $config && -f $old_def_config) {
 815                 rename $old_def_config, $config or
 816                        die "Failed rename $old_def_config => $config: $!\n";
 817         }
 818         my $old_config = $ENV{GIT_CONFIG};
 819         $ENV{GIT_CONFIG} = $config;
 820         $@ = undef;
 821         my @ret = eval {
 822                 unless (-f $config) {
 823                         mkfile($config);
 824                         open my $fh, '>', $config or
 825                             die "Can't open $config: $!\n";
 826                         print $fh "; This file is used internally by ",
 827                                   "git-svn\n" or die
 828                                   "Couldn't write to $config: $!\n";
 829                         print $fh "; You should not have to edit it\n" or
 830                               die "Couldn't write to $config: $!\n";
 831                         close $fh or die "Couldn't close $config: $!\n";
 832                 }
 833                 command('config', @args);
 834         };
 835         my $err = $@;
 836         if (defined $old_config) {
 837                 $ENV{GIT_CONFIG} = $old_config;
 838         } else {
 839                 delete $ENV{GIT_CONFIG};
 840         }
 841         die $err if $err;
 842         wantarray ? @ret : $ret[0];
 843 }
 844
 845 sub tmp_index_do {
 846         my ($self, $sub) = @_;
 847         my $old_index = $ENV{GIT_INDEX_FILE};
 848         $ENV{GIT_INDEX_FILE} = $self->{index};
 849         $@ = undef;
 850         my @ret = eval {
 851                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
 852                 mkpath([$dir]) unless -d $dir;
 853                 &$sub;
 854         };
 855         my $err = $@;
 856         if (defined $old_index) {
 857                 $ENV{GIT_INDEX_FILE} = $old_index;
 858         } else {
 859                 delete $ENV{GIT_INDEX_FILE};
 860         }
 861         die $err if $err;
 862         wantarray ? @ret : $ret[0];
 863 }
 864
 865 sub assert_index_clean {
 866         my ($self, $treeish) = @_;
 867
 868         $self->tmp_index_do(sub {
 869                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 870                 my $x = command_oneline('write-tree');
 871                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 872                            /^tree ($::sha1)/mo);
 873                 return if $y eq $x;
 874
 875                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
 876                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
 877                 command_noisy('read-tree', $treeish);
 878                 $x = command_oneline('write-tree');
 879                 if ($y ne $x) {
 880                         fatal "trees ($treeish) $y != $x\n",
 881                               "Something is seriously wrong...";
 882                 }
 883         });
 884 }
 885
 886 sub get_commit_parents {
 887         my ($self, $log_entry) = @_;
 888         my (%seen, @ret, @tmp);
 889         # legacy support for 'set-tree'; this is only used by set_tree_cb:
 890         if (my $ip = $self->{inject_parents}) {
 891                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
 892                         push @tmp, $commit;
 893                 }
 894         }
 895         if (my $cur = ::verify_ref($self->refname.'^0')) {
 896                 push @tmp, $cur;
 897         }
 898         if (my $ipd = $self->{inject_parents_dcommit}) {
 899                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
 900                         push @tmp, @$commit;
 901                 }
 902         }
 903         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
 904         while (my $p = shift @tmp) {
 905                 next if $seen{$p};
 906                 $seen{$p} = 1;
 907                 push @ret, $p;
 908         }
 909         @ret;
 910 }
 911
 912 sub rewrite_root {
 913         my ($self) = @_;
 914         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
 915         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
 916         my $rwr = eval { command_oneline(qw/config --get/, $k) };
 917         if ($rwr) {
 918                 $rwr =~ s#/+$##;
 919                 if ($rwr !~ m#^[a-z\+]+://#) {
 920                         die "$rwr is not a valid URL (key: $k)\n";
 921                 }
 922         }
 923         $self->{-rewrite_root} = $rwr;
 924 }
 925
 926 sub rewrite_uuid {
 927         my ($self) = @_;
 928         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
 929         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
 930         my $rwid = eval { command_oneline(qw/config --get/, $k) };
 931         if ($rwid) {
 932                 $rwid =~ s#/+$##;
 933                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
 934                         die "$rwid is not a valid UUID (key: $k)\n";
 935                 }
 936         }
 937         $self->{-rewrite_uuid} = $rwid;
 938 }
 939
 940 sub metadata_url {
 941         my ($self) = @_;
 942         my $url = $self->rewrite_root || $self->url;
 943         return canonicalize_url( add_path_to_url( $url, $self->path ) );
 944 }
 945
 946 sub full_url {
 947         my ($self) = @_;
 948         return canonicalize_url( add_path_to_url( $self->url, $self->path ) );
 949 }
 950
 951 sub full_pushurl {
 952         my ($self) = @_;
 953         if ($self->{pushurl}) {
 954                 return canonicalize_url( add_path_to_url( $self->{pushurl}, $self->path ) );
 955         } else {
 956                 return $self->full_url;
 957         }
 958 }
 959
 960 sub set_commit_header_env {
 961         my ($log_entry) = @_;
 962         my %env;
 963         foreach my $ned (qw/NAME EMAIL DATE/) {
 964                 foreach my $ac (qw/AUTHOR COMMITTER/) {
 965                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
 966                 }
 967         }
 968
 969         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
 970         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
 971         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
 972
 973         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
 974                                                 ? $log_entry->{commit_name}
 975                                                 : $log_entry->{name};
 976         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
 977                                                 ? $log_entry->{commit_email}
 978                                                 : $log_entry->{email};
 979         \%env;
 980 }
 981
 982 sub restore_commit_header_env {
 983         my ($env) = @_;
 984         foreach my $ned (qw/NAME EMAIL DATE/) {
 985                 foreach my $ac (qw/AUTHOR COMMITTER/) {
 986                         my $k = "GIT_${ac}_${ned}";
 987                         if (defined $env->{$k}) {
 988                                 $ENV{$k} = $env->{$k};
 989                         } else {
 990                                 delete $ENV{$k};
 991                         }
 992                 }
 993         }
 994 }
 995
 996 sub gc {
 997         command_noisy('gc', '--auto');
 998 };
 999
1000 sub do_git_commit {
1001         my ($self, $log_entry) = @_;
1002         my $lr = $self->last_rev;
1003         if (defined $lr && $lr >= $log_entry->{revision}) {
1004                 die "Last fetched revision of ", $self->refname,
1005                     " was r$lr, but we are about to fetch: ",
1006                     "r$log_entry->{revision}!\n";
1007         }
1008         if (my $c = $self->rev_map_get($log_entry->{revision})) {
1009                 croak "$log_entry->{revision} = $c already exists! ",
1010                       "Why are we refetching it?\n";
1011         }
1012         my $old_env = set_commit_header_env($log_entry);
1013         my $tree = $log_entry->{tree};
1014         if (!defined $tree) {
1015                 $tree = $self->tmp_index_do(sub {
1016                                             command_oneline('write-tree') });
1017         }
1018         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1019
1020         my @exec = ('git', 'commit-tree', $tree);
1021         foreach ($self->get_commit_parents($log_entry)) {
1022                 push @exec, '-p', $_;
1023         }
1024         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1025                                                                    or croak $!;
1026         binmode $msg_fh;
1027
1028         # we always get UTF-8 from SVN, but we may want our commits in
1029         # a different encoding.
1030         if (my $enc = Git::config('i18n.commitencoding')) {
1031                 require Encode;
1032                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
1033         }
1034         print $msg_fh $log_entry->{log} or croak $!;
1035         restore_commit_header_env($old_env);
1036         unless ($self->no_metadata) {
1037                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1038                               or croak $!;
1039         }
1040         $msg_fh->flush == 0 or croak $!;
1041         close $msg_fh or croak $!;
1042         chomp(my $commit = do { local $/; <$out_fh> });
1043         close $out_fh or croak $!;
1044         waitpid $pid, 0;
1045         croak $? if $?;
1046         if ($commit !~ /^$::sha1$/o) {
1047                 die "Failed to commit, invalid sha1: $commit\n";
1048         }
1049
1050         $self->rev_map_set($log_entry->{revision}, $commit, 1);
1051
1052         $self->{last_rev} = $log_entry->{revision};
1053         $self->{last_commit} = $commit;
1054         print "r$log_entry->{revision}" unless $::_q > 1;
1055         if (defined $log_entry->{svm_revision}) {
1056                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
1057                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
1058                                    0, $self->svm_uuid);
1059         }
1060         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
1061         if (--$_gc_nr == 0) {
1062                 $_gc_nr = $_gc_period;
1063                 gc();
1064         }
1065         return $commit;
1066 }
1067
1068 sub match_paths {
1069         my ($self, $paths, $r) = @_;
1070         return 1 if $self->path eq '';
1071         if (my $path = $paths->{"/".$self->path}) {
1072                 return ($path->{action} eq 'D') ? 0 : 1;
1073         }
1074         $self->{path_regex} ||= qr{^/\Q@{[$self->path]}\E/};
1075         if (grep /$self->{path_regex}/, keys %$paths) {
1076                 return 1;
1077         }
1078         my $c = '';
1079         foreach (split m#/#, $self->path) {
1080                 $c .= "/$_";
1081                 next unless ($paths->{$c} &&
1082                              ($paths->{$c}->{action} =~ /^[AR]$/));
1083                 if ($self->ra->check_path($self->path, $r) ==
1084                     $SVN::Node::dir) {
1085                         return 1;
1086                 }
1087         }
1088         return 0;
1089 }
1090
1091 sub find_parent_branch {
1092         my ($self, $paths, $rev) = @_;
1093         return undef unless $self->follow_parent;
1094         unless (defined $paths) {
1095                 my $err_handler = $SVN::Error::handler;
1096                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1097                 $self->ra->get_log([$self->path], $rev, $rev, 0, 1, 1,
1098                                    sub { $paths = $_[0] });
1099                 $SVN::Error::handler = $err_handler;
1100         }
1101         return undef unless defined $paths;
1102
1103         # look for a parent from another branch:
1104         my @b_path_components = split m#/#, $self->path;
1105         my @a_path_components;
1106         my $i;
1107         while (@b_path_components) {
1108                 $i = $paths->{'/'.join('/', @b_path_components)};
1109                 last if $i && defined $i->{copyfrom_path};
1110                 unshift(@a_path_components, pop(@b_path_components));
1111         }
1112         return undef unless defined $i && defined $i->{copyfrom_path};
1113         my $branch_from = $i->{copyfrom_path};
1114         if (@a_path_components) {
1115                 print STDERR "branch_from: $branch_from => ";
1116                 $branch_from .= '/'.join('/', @a_path_components);
1117                 print STDERR $branch_from, "\n";
1118         }
1119         my $r = $i->{copyfrom_rev};
1120         my $repos_root = $self->ra->{repos_root};
1121         my $url = $self->ra->url;
1122         my $new_url = canonicalize_url( add_path_to_url( $url, $branch_from ) );
1123         print STDERR  "Found possible branch point: ",
1124                       "$new_url => ", $self->full_url, ", $r\n"
1125                       unless $::_q > 1;
1126         $branch_from =~ s#^/##;
1127         my $gs = $self->other_gs($new_url, $url,
1128                                  $branch_from, $r, $self->{ref_id});
1129         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1130         {
1131                 my ($base, $head);
1132                 if (!defined $r0 || !defined $parent) {
1133                         ($base, $head) = parse_revision_argument(0, $r);
1134                 } else {
1135                         if ($r0 < $r) {
1136                                 $gs->ra->get_log([$gs->path], $r0 + 1, $r, 1,
1137                                         0, 1, sub { $base = $_[1] - 1 });
1138                         }
1139                 }
1140                 if (defined $base && $base <= $r) {
1141                         $gs->fetch($base, $r);
1142                 }
1143                 ($r0, $parent) = $gs->find_rev_before($r, 1);
1144         }
1145         if (defined $r0 && defined $parent) {
1146                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
1147                              unless $::_q > 1;
1148                 my $ed;
1149                 if ($self->ra->can_do_switch) {
1150                         $self->assert_index_clean($parent);
1151                         print STDERR "Following parent with do_switch\n"
1152                                      unless $::_q > 1;
1153                         # do_switch works with svn/trunk >= r22312, but that
1154                         # is not included with SVN 1.4.3 (the latest version
1155                         # at the moment), so we can't rely on it
1156                         $self->{last_rev} = $r0;
1157                         $self->{last_commit} = $parent;
1158                         $ed = Git::SVN::Fetcher->new($self, $gs->path);
1159                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1160                                               $self->full_url, $ed)
1161                           or die "SVN connection failed somewhere...\n";
1162                 } elsif ($self->ra->trees_match($new_url, $r0,
1163                                                 $self->full_url, $rev)) {
1164                         print STDERR "Trees match:\n",
1165                                      "  $new_url\@$r0\n",
1166                                      "  ${\$self->full_url}\@$rev\n",
1167                                      "Following parent with no changes\n"
1168                                      unless $::_q > 1;
1169                         $self->tmp_index_do(sub {
1170                             command_noisy('read-tree', $parent);
1171                         });
1172                         $self->{last_commit} = $parent;
1173                 } else {
1174                         print STDERR "Following parent with do_update\n"
1175                                      unless $::_q > 1;
1176                         $ed = Git::SVN::Fetcher->new($self);
1177                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1178                           or die "SVN connection failed somewhere...\n";
1179                 }
1180                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
1181                 return $self->make_log_entry($rev, [$parent], $ed);
1182         }
1183         return undef;
1184 }
1185
1186 sub do_fetch {
1187         my ($self, $paths, $rev) = @_;
1188         my $ed;
1189         my ($last_rev, @parents);
1190         if (my $lc = $self->last_commit) {
1191                 # we can have a branch that was deleted, then re-added
1192                 # under the same name but copied from another path, in
1193                 # which case we'll have multiple parents (we don't
1194                 # want to break the original ref, nor lose copypath info):
1195                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1196                         push @{$log_entry->{parents}}, $lc;
1197                         return $log_entry;
1198                 }
1199                 $ed = Git::SVN::Fetcher->new($self);
1200                 $last_rev = $self->{last_rev};
1201                 $ed->{c} = $lc;
1202                 @parents = ($lc);
1203         } else {
1204                 $last_rev = $rev;
1205                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1206                         return $log_entry;
1207                 }
1208                 $ed = Git::SVN::Fetcher->new($self);
1209         }
1210         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1211                 die "SVN connection failed somewhere...\n";
1212         }
1213         $self->make_log_entry($rev, \@parents, $ed);
1214 }
1215
1216 sub mkemptydirs {
1217         my ($self, $r) = @_;
1218
1219         sub scan {
1220                 my ($r, $empty_dirs, $line) = @_;
1221                 if (defined $r && $line =~ /^r(\d+)$/) {
1222                         return 0 if $1 > $r;
1223                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
1224                         $empty_dirs->{$1} = 1;
1225                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
1226                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
1227                         delete @$empty_dirs{@d};
1228                 }
1229                 1; # continue
1230         };
1231
1232         my %empty_dirs = ();
1233         my $gz_file = "$self->{dir}/unhandled.log.gz";
1234         if (-f $gz_file) {
1235                 if (!can_compress()) {
1236                         warn "Compress::Zlib could not be found; ",
1237                              "empty directories in $gz_file will not be read\n";
1238                 } else {
1239                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
1240                                 die "Unable to open $gz_file: $!\n";
1241                         my $line;
1242                         while ($gz->gzreadline($line) > 0) {
1243                                 scan($r, \%empty_dirs, $line) or last;
1244                         }
1245                         $gz->gzclose;
1246                 }
1247         }
1248
1249         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
1250                 binmode $fh or croak "binmode: $!";
1251                 while (<$fh>) {
1252                         scan($r, \%empty_dirs, $_) or last;
1253                 }
1254                 close $fh;
1255         }
1256
1257         my $strip = qr/\A\Q@{[$self->path]}\E(?:\/|$)/;
1258         foreach my $d (sort keys %empty_dirs) {
1259                 $d = uri_decode($d);
1260                 $d =~ s/$strip//;
1261                 next unless length($d);
1262                 next if -d $d;
1263                 if (-e $d) {
1264                         warn "$d exists but is not a directory\n";
1265                 } else {
1266                         print "creating empty directory: $d\n";
1267                         mkpath([$d]);
1268                 }
1269         }
1270 }
1271
1272 sub get_untracked {
1273         my ($self, $ed) = @_;
1274         my @out;
1275         my $h = $ed->{empty};
1276         foreach (sort keys %$h) {
1277                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1278                 push @out, "  $act: " . uri_encode($_);
1279                 warn "W: $act: $_\n";
1280         }
1281         foreach my $t (qw/dir_prop file_prop/) {
1282                 $h = $ed->{$t} or next;
1283                 foreach my $path (sort keys %$h) {
1284                         my $ppath = $path eq '' ? '.' : $path;
1285                         foreach my $prop (sort keys %{$h->{$path}}) {
1286                                 next if $SKIP_PROP{$prop};
1287                                 my $v = $h->{$path}->{$prop};
1288                                 my $t_ppath_prop = "$t: " .
1289                                                     uri_encode($ppath) . ' ' .
1290                                                     uri_encode($prop);
1291                                 if (defined $v) {
1292                                         push @out, "  +$t_ppath_prop " .
1293                                                    uri_encode($v);
1294                                 } else {
1295                                         push @out, "  -$t_ppath_prop";
1296                                 }
1297                         }
1298                 }
1299         }
1300         foreach my $t (qw/absent_file absent_directory/) {
1301                 $h = $ed->{$t} or next;
1302                 foreach my $parent (sort keys %$h) {
1303                         foreach my $path (sort @{$h->{$parent}}) {
1304                                 push @out, "  $t: " .
1305                                            uri_encode("$parent/$path");
1306                                 warn "W: $t: $parent/$path ",
1307                                      "Insufficient permissions?\n";
1308                         }
1309                 }
1310         }
1311         \@out;
1312 }
1313
1314 sub get_tz {
1315         # some systmes don't handle or mishandle %z, so be creative.
1316         my $t = shift || time;
1317         my $gm = timelocal(gmtime($t));
1318         my $sign = qw( + + - )[ $t <=> $gm ];
1319         return sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
1320 }
1321
1322 # parse_svn_date(DATE)
1323 # --------------------
1324 # Given a date (in UTC) from Subversion, return a string in the format
1325 # "<TZ Offset> <local date/time>" that Git will use.
1326 #
1327 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
1328 # is true we'll convert it to the local timezone instead.
1329 sub parse_svn_date {
1330         my $date = shift || return '+0000 1970-01-01 00:00:00';
1331         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1332                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
1333                                          croak "Unable to parse date: $date\n";
1334         my $parsed_date;    # Set next.
1335
1336         if ($Git::SVN::_localtime) {
1337                 # Translate the Subversion datetime to an epoch time.
1338                 # Begin by switching ourselves to $date's timezone, UTC.
1339                 my $old_env_TZ = $ENV{TZ};
1340                 $ENV{TZ} = 'UTC';
1341
1342                 my $epoch_in_UTC =
1343                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
1344
1345                 # Determine our local timezone (including DST) at the
1346                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
1347                 # value of TZ, if any, at the time we were run.
1348                 if (defined $Git::SVN::Log::TZ) {
1349                         $ENV{TZ} = $Git::SVN::Log::TZ;
1350                 } else {
1351                         delete $ENV{TZ};
1352                 }
1353
1354                 my $our_TZ = get_tz();
1355
1356                 # This converts $epoch_in_UTC into our local timezone.
1357                 my ($sec, $min, $hour, $mday, $mon, $year,
1358                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
1359
1360                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
1361                                        $our_TZ, $year + 1900, $mon + 1,
1362                                        $mday, $hour, $min, $sec);
1363
1364                 # Reset us to the timezone in effect when we entered
1365                 # this routine.
1366                 if (defined $old_env_TZ) {
1367                         $ENV{TZ} = $old_env_TZ;
1368                 } else {
1369                         delete $ENV{TZ};
1370                 }
1371         } else {
1372                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
1373         }
1374
1375         return $parsed_date;
1376 }
1377
1378 sub other_gs {
1379         my ($self, $new_url, $url,
1380             $branch_from, $r, $old_ref_id) = @_;
1381         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
1382         unless ($gs) {
1383                 my $ref_id = $old_ref_id;
1384                 $ref_id =~ s/\@\d+-*$//;
1385                 $ref_id .= "\@$r";
1386                 # just grow a tail if we're not unique enough :x
1387                 $ref_id .= '-' while find_ref($ref_id);
1388                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
1389                 if ($u =~ s#^\Q$url\E(/|$)##) {
1390                         $p = $u;
1391                         $u = $url;
1392                         $repo_id = $self->{repo_id};
1393                 }
1394                 while (1) {
1395                         # It is possible to tag two different subdirectories at
1396                         # the same revision.  If the url for an existing ref
1397                         # does not match, we must either find a ref with a
1398                         # matching url or create a new ref by growing a tail.
1399                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
1400                         my (undef, $max_commit) = $gs->rev_map_max(1);
1401                         last if (!$max_commit);
1402                         my ($url) = ::cmt_metadata($max_commit);
1403                         last if ($url eq $gs->metadata_url);
1404                         $ref_id .= '-';
1405                 }
1406                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
1407         }
1408         $gs
1409 }
1410
1411 sub call_authors_prog {
1412         my ($orig_author) = @_;
1413         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
1414         my $author = `$::_authors_prog $orig_author`;
1415         if ($? != 0) {
1416                 die "$::_authors_prog failed with exit code $?\n"
1417         }
1418         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
1419                 my ($name, $email) = ($1, $2);
1420                 $email = undef if length $2 == 0;
1421                 return [$name, $email];
1422         } else {
1423                 die "Author: $orig_author: $::_authors_prog returned "
1424                         . "invalid author format: $author\n";
1425         }
1426 }
1427
1428 sub check_author {
1429         my ($author) = @_;
1430         if (!defined $author || length $author == 0) {
1431                 $author = '(no author)';
1432         }
1433         if (!defined $::users{$author}) {
1434                 if (defined $::_authors_prog) {
1435                         $::users{$author} = call_authors_prog($author);
1436                 } elsif (defined $::_authors) {
1437                         die "Author: $author not defined in $::_authors file\n";
1438                 }
1439         }
1440         $author;
1441 }
1442
1443 sub find_extra_svk_parents {
1444         my ($self, $ed, $tickets, $parents) = @_;
1445         # aha!  svk:merge property changed...
1446         my @tickets = split "\n", $tickets;
1447         my @known_parents;
1448         for my $ticket ( @tickets ) {
1449                 my ($uuid, $path, $rev) = split /:/, $ticket;
1450                 if ( $uuid eq $self->ra_uuid ) {
1451                         my $repos_root = $self->url;
1452                         my $branch_from = $path;
1453                         $branch_from =~ s{^/}{};
1454                         my $gs = $self->other_gs(add_path_to_url( $repos_root, $branch_from ),
1455                                                  $repos_root,
1456                                                  $branch_from,
1457                                                  $rev,
1458                                                  $self->{ref_id});
1459                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
1460                                 # wahey!  we found it, but it might be
1461                                 # an old one (!)
1462                                 push @known_parents, [ $rev, $commit ];
1463                         }
1464                 }
1465         }
1466         # Ordering matters; highest-numbered commit merge tickets
1467         # first, as they may account for later merge ticket additions
1468         # or changes.
1469         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
1470         for my $parent ( @known_parents ) {
1471                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
1472                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
1473                 my $new;
1474                 while ( <$msg_fh> ) {
1475                         $new=1;last;
1476                 }
1477                 command_close_pipe($msg_fh, $ctx);
1478                 if ( $new ) {
1479                         print STDERR
1480                             "Found merge parent (svk:merge ticket): $parent\n";
1481                         push @$parents, $parent;
1482                 }
1483         }
1484 }
1485
1486 sub lookup_svn_merge {
1487         my $uuid = shift;
1488         my $url = shift;
1489         my $merge = shift;
1490
1491         my ($source, $revs) = split ":", $merge;
1492         my $path = $source;
1493         $path =~ s{^/}{};
1494         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
1495         if ( !$gs ) {
1496                 warn "Couldn't find revmap for $url$source\n";
1497                 return;
1498         }
1499         my @ranges = split ",", $revs;
1500         my ($tip, $tip_commit);
1501         my @merged_commit_ranges;
1502         # find the tip
1503         for my $range ( @ranges ) {
1504                 my ($bottom, $top) = split "-", $range;
1505                 $top ||= $bottom;
1506                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
1507                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
1508
1509                 unless ($top_commit and $bottom_commit) {
1510                         warn "W:unknown path/rev in svn:mergeinfo "
1511                                 ."dirprop: $source:$range\n";
1512                         next;
1513                 }
1514
1515                 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
1516                         push @merged_commit_ranges,
1517                              "$bottom_commit^..$top_commit";
1518                 } else {
1519                         push @merged_commit_ranges, "$top_commit";
1520                 }
1521
1522                 if ( !defined $tip or $top > $tip ) {
1523                         $tip = $top;
1524                         $tip_commit = $top_commit;
1525                 }
1526         }
1527         return ($tip_commit, @merged_commit_ranges);
1528 }
1529
1530 sub _rev_list {
1531         my ($msg_fh, $ctx) = command_output_pipe(
1532                 "rev-list", @_,
1533                );
1534         my @rv;
1535         while ( <$msg_fh> ) {
1536                 chomp;
1537                 push @rv, $_;
1538         }
1539         command_close_pipe($msg_fh, $ctx);
1540         @rv;
1541 }
1542
1543 sub check_cherry_pick {
1544         my $base = shift;
1545         my $tip = shift;
1546         my $parents = shift;
1547         my @ranges = @_;
1548         my %commits = map { $_ => 1 }
1549                 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
1550         for my $range ( @ranges ) {
1551                 delete @commits{_rev_list($range, "--")};
1552         }
1553         for my $commit (keys %commits) {
1554                 if (has_no_changes($commit)) {
1555                         delete $commits{$commit};
1556                 }
1557         }
1558         return (keys %commits);
1559 }
1560
1561 sub has_no_changes {
1562         my $commit = shift;
1563
1564         my @revs = split / /, command_oneline(
1565                 qw(rev-list --parents -1 -m), $commit);
1566
1567         # Commits with no parents, e.g. the start of a partial branch,
1568         # have changes by definition.
1569         return 1 if (@revs < 2);
1570
1571         # Commits with multiple parents, e.g a merge, have no changes
1572         # by definition.
1573         return 0 if (@revs > 2);
1574
1575         return (command_oneline("rev-parse", "$commit^{tree}") eq
1576                 command_oneline("rev-parse", "$commit~1^{tree}"));
1577 }
1578
1579 sub tie_for_persistent_memoization {
1580         my $hash = shift;
1581         my $path = shift;
1582
1583         if ($can_use_yaml) {
1584                 tie %$hash => 'Git::SVN::Memoize::YAML', "$path.yaml";
1585         } else {
1586                 tie %$hash => 'Memoize::Storable', "$path.db", 'nstore';
1587         }
1588 }
1589
1590 # The GIT_DIR environment variable is not always set until after the command
1591 # line arguments are processed, so we can't memoize in a BEGIN block.
1592 {
1593         my $memoized = 0;
1594
1595         sub memoize_svn_mergeinfo_functions {
1596                 return if $memoized;
1597                 $memoized = 1;
1598
1599                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1600                 mkpath([$cache_path]) unless -d $cache_path;
1601
1602                 my %lookup_svn_merge_cache;
1603                 my %check_cherry_pick_cache;
1604                 my %has_no_changes_cache;
1605
1606                 tie_for_persistent_memoization(\%lookup_svn_merge_cache,
1607                     "$cache_path/lookup_svn_merge");
1608                 memoize 'lookup_svn_merge',
1609                         SCALAR_CACHE => 'FAULT',
1610                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
1611                 ;
1612
1613                 tie_for_persistent_memoization(\%check_cherry_pick_cache,
1614                     "$cache_path/check_cherry_pick");
1615                 memoize 'check_cherry_pick',
1616                         SCALAR_CACHE => 'FAULT',
1617                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
1618                 ;
1619
1620                 tie_for_persistent_memoization(\%has_no_changes_cache,
1621                     "$cache_path/has_no_changes");
1622                 memoize 'has_no_changes',
1623                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
1624                         LIST_CACHE => 'FAULT',
1625                 ;
1626         }
1627
1628         sub unmemoize_svn_mergeinfo_functions {
1629                 return if not $memoized;
1630                 $memoized = 0;
1631
1632                 Memoize::unmemoize 'lookup_svn_merge';
1633                 Memoize::unmemoize 'check_cherry_pick';
1634                 Memoize::unmemoize 'has_no_changes';
1635         }
1636
1637         sub clear_memoized_mergeinfo_caches {
1638                 die "Only call this method in non-memoized context" if ($memoized);
1639
1640                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1641                 return unless -d $cache_path;
1642
1643                 for my $cache_file (("$cache_path/lookup_svn_merge",
1644                                      "$cache_path/check_cherry_pick",
1645                                      "$cache_path/has_no_changes")) {
1646                         for my $suffix (qw(yaml db)) {
1647                                 my $file = "$cache_file.$suffix";
1648                                 next unless -e $file;
1649                                 unlink($file) or die "unlink($file) failed: $!\n";
1650                         }
1651                 }
1652         }
1653
1654
1655         Memoize::memoize 'Git::SVN::repos_root';
1656 }
1657
1658 END {
1659         # Force cache writeout explicitly instead of waiting for
1660         # global destruction to avoid segfault in Storable:
1661         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
1662         unmemoize_svn_mergeinfo_functions();
1663 }
1664
1665 sub parents_exclude {
1666         my $parents = shift;
1667         my @commits = @_;
1668         return unless @commits;
1669
1670         my @excluded;
1671         my $excluded;
1672         do {
1673                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
1674                 $excluded = command_oneline(@cmd);
1675                 if ( $excluded ) {
1676                         my @new;
1677                         my $found;
1678                         for my $commit ( @commits ) {
1679                                 if ( $commit eq $excluded ) {
1680                                         push @excluded, $commit;
1681                                         $found++;
1682                                 }
1683                                 else {
1684                                         push @new, $commit;
1685                                 }
1686                         }
1687                         die "saw commit '$excluded' in rev-list output, "
1688                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
1689                                         unless $found;
1690                         @commits = @new;
1691                 }
1692         }
1693                 while ($excluded and @commits);
1694
1695         return @excluded;
1696 }
1697
1698
1699 # note: this function should only be called if the various dirprops
1700 # have actually changed
1701 sub find_extra_svn_parents {
1702         my ($self, $ed, $mergeinfo, $parents) = @_;
1703         # aha!  svk:merge property changed...
1704
1705         memoize_svn_mergeinfo_functions();
1706
1707         # We first search for merged tips which are not in our
1708         # history.  Then, we figure out which git revisions are in
1709         # that tip, but not this revision.  If all of those revisions
1710         # are now marked as merge, we can add the tip as a parent.
1711         my @merges = split "\n", $mergeinfo;
1712         my @merge_tips;
1713         my $url = $self->url;
1714         my $uuid = $self->ra_uuid;
1715         my @all_ranges;
1716         for my $merge ( @merges ) {
1717                 my ($tip_commit, @ranges) =
1718                         lookup_svn_merge( $uuid, $url, $merge );
1719                 unless (!$tip_commit or
1720                                 grep { $_ eq $tip_commit } @$parents ) {
1721                         push @merge_tips, $tip_commit;
1722                         push @all_ranges, @ranges;
1723                 } else {
1724                         push @merge_tips, undef;
1725                 }
1726         }
1727
1728         my %excluded = map { $_ => 1 }
1729                 parents_exclude($parents, grep { defined } @merge_tips);
1730
1731         # check merge tips for new parents
1732         my @new_parents;
1733         for my $merge_tip ( @merge_tips ) {
1734                 my $spec = shift @merges;
1735                 next unless $merge_tip and $excluded{$merge_tip};
1736
1737                 # check out 'new' tips
1738                 my $merge_base;
1739                 eval {
1740                         $merge_base = command_oneline(
1741                                 "merge-base",
1742                                 @$parents, $merge_tip,
1743                         );
1744                 };
1745                 if ($@) {
1746                         die "An error occurred during merge-base"
1747                                 unless $@->isa("Git::Error::Command");
1748
1749                         warn "W: Cannot find common ancestor between ".
1750                              "@$parents and $merge_tip. Ignoring merge info.\n";
1751                         next;
1752                 }
1753
1754                 # double check that there are no missing non-merge commits
1755                 my (@incomplete) = check_cherry_pick(
1756                         $merge_base, $merge_tip,
1757                         $parents,
1758                         @all_ranges,
1759                        );
1760
1761                 if ( @incomplete ) {
1762                         warn "W:svn cherry-pick ignored ($spec) - missing "
1763                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
1764                 } else {
1765                         warn
1766                                 "Found merge parent (svn:mergeinfo prop): ",
1767                                         $merge_tip, "\n";
1768                         push @new_parents, $merge_tip;
1769                 }
1770         }
1771
1772         # cater for merges which merge commits from multiple branches
1773         if ( @new_parents > 1 ) {
1774                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
1775                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
1776                                 next if $i == $j;
1777                                 next unless $new_parents[$i];
1778                                 next unless $new_parents[$j];
1779                                 my $revs = command_oneline(
1780                                         "rev-list", "-1",
1781                                         "$new_parents[$i]..$new_parents[$j]",
1782                                        );
1783                                 if ( !$revs ) {
1784                                         undef($new_parents[$j]);
1785                                 }
1786                         }
1787                 }
1788         }
1789         push @$parents, grep { defined } @new_parents;
1790 }
1791
1792 sub make_log_entry {
1793         my ($self, $rev, $parents, $ed) = @_;
1794         my $untracked = $self->get_untracked($ed);
1795
1796         my @parents = @$parents;
1797         my $ps = $ed->{path_strip} || "";
1798         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
1799                 my $props = $ed->{dir_prop}{$path};
1800                 if ( $props->{"svk:merge"} ) {
1801                         $self->find_extra_svk_parents
1802                                 ($ed, $props->{"svk:merge"}, \@parents);
1803                 }
1804                 if ( $props->{"svn:mergeinfo"} ) {
1805                         $self->find_extra_svn_parents
1806                                 ($ed,
1807                                  $props->{"svn:mergeinfo"},
1808                                  \@parents);
1809                 }
1810         }
1811
1812         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1813         print $un "r$rev\n" or croak $!;
1814         print $un $_, "\n" foreach @$untracked;
1815         my %log_entry = ( parents => \@parents, revision => $rev,
1816                           log => '');
1817
1818         my $headrev;
1819         my $logged = delete $self->{logged_rev_props};
1820         if (!$logged || $self->{-want_revprops}) {
1821                 my $rp = $self->ra->rev_proplist($rev);
1822                 foreach (sort keys %$rp) {
1823                         my $v = $rp->{$_};
1824                         if (/^svn:(author|date|log)$/) {
1825                                 $log_entry{$1} = $v;
1826                         } elsif ($_ eq 'svm:headrev') {
1827                                 $headrev = $v;
1828                         } else {
1829                                 print $un "  rev_prop: ", uri_encode($_), ' ',
1830                                           uri_encode($v), "\n";
1831                         }
1832                 }
1833         } else {
1834                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1835         }
1836         close $un or croak $!;
1837
1838         $log_entry{date} = parse_svn_date($log_entry{date});
1839         $log_entry{log} .= "\n";
1840         my $author = $log_entry{author} = check_author($log_entry{author});
1841         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1842                                                        : ($author, undef);
1843
1844         my ($commit_name, $commit_email) = ($name, $email);
1845         if ($_use_log_author) {
1846                 my $name_field;
1847                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
1848                         $name_field = $1;
1849                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
1850                         $name_field = $1;
1851                 }
1852                 if (!defined $name_field) {
1853                         if (!defined $email) {
1854                                 $email = $name;
1855                         }
1856                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
1857                         ($name, $email) = ($1, $2);
1858                 } elsif ($name_field =~ /(.*)@/) {
1859                         ($name, $email) = ($1, $name_field);
1860                 } else {
1861                         ($name, $email) = ($name_field, $name_field);
1862                 }
1863         }
1864         if (defined $headrev && $self->use_svm_props) {
1865                 if ($self->rewrite_root) {
1866                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1867                             "options set!\n";
1868                 }
1869                 if ($self->rewrite_uuid) {
1870                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
1871                             "options set!\n";
1872                 }
1873                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
1874                 # we don't want "SVM: initializing mirror for junk" ...
1875                 return undef if $r == 0;
1876                 my $svm = $self->svm;
1877                 if ($uuid ne $svm->{uuid}) {
1878                         die "UUID mismatch on SVM path:\n",
1879                             "expected: $svm->{uuid}\n",
1880                             "     got: $uuid\n";
1881                 }
1882                 my $full_url = $self->full_url;
1883                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1884                              die "Failed to replace '$svm->{replace}' with ",
1885                                  "'$svm->{source}' in $full_url\n";
1886                 # throw away username for storing in records
1887                 remove_username($full_url);
1888                 $log_entry{metadata} = "$full_url\@$r $uuid";
1889                 $log_entry{svm_revision} = $r;
1890                 $email ||= "$author\@$uuid";
1891                 $commit_email ||= "$author\@$uuid";
1892         } elsif ($self->use_svnsync_props) {
1893                 my $full_url = canonicalize_url(
1894                         add_path_to_url( $self->svnsync->{url}, $self->path )
1895                 );
1896                 remove_username($full_url);
1897                 my $uuid = $self->svnsync->{uuid};
1898                 $log_entry{metadata} = "$full_url\@$rev $uuid";
1899                 $email ||= "$author\@$uuid";
1900                 $commit_email ||= "$author\@$uuid";
1901         } else {
1902                 my $url = $self->metadata_url;
1903                 remove_username($url);
1904                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
1905                 $log_entry{metadata} = "$url\@$rev " . $uuid;
1906                 $email ||= "$author\@" . $uuid;
1907                 $commit_email ||= "$author\@" . $uuid;
1908         }
1909         $log_entry{name} = $name;
1910         $log_entry{email} = $email;
1911         $log_entry{commit_name} = $commit_name;
1912         $log_entry{commit_email} = $commit_email;
1913         \%log_entry;
1914 }
1915
1916 sub fetch {
1917         my ($self, $min_rev, $max_rev, @parents) = @_;
1918         my ($last_rev, $last_commit) = $self->last_rev_commit;
1919         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1920         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1921 }
1922
1923 sub set_tree_cb {
1924         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1925         $self->{inject_parents} = { $rev => $tree };
1926         $self->fetch(undef, undef);
1927 }
1928
1929 sub set_tree {
1930         my ($self, $tree) = (shift, shift);
1931         my $log_entry = ::get_commit_entry($tree);
1932         unless ($self->{last_rev}) {
1933                 fatal("Must have an existing revision to commit");
1934         }
1935         my %ed_opts = ( r => $self->{last_rev},
1936                         log => $log_entry->{log},
1937                         ra => $self->ra,
1938                         tree_a => $self->{last_commit},
1939                         tree_b => $tree,
1940                         editor_cb => sub {
1941                                $self->set_tree_cb($log_entry, $tree, @_) },
1942                         svn_path => $self->path );
1943         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1944                 print "No changes\nr$self->{last_rev} = $tree\n";
1945         }
1946 }
1947
1948 sub rebuild_from_rev_db {
1949         my ($self, $path) = @_;
1950         my $r = -1;
1951         open my $fh, '<', $path or croak "open: $!";
1952         binmode $fh or croak "binmode: $!";
1953         while (<$fh>) {
1954                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
1955                 chomp($_);
1956                 ++$r;
1957                 next if $_ eq ('0' x 40);
1958                 $self->rev_map_set($r, $_);
1959                 print "r$r = $_\n";
1960         }
1961         close $fh or croak "close: $!";
1962         unlink $path or croak "unlink: $!";
1963 }
1964
1965 sub rebuild {
1966         my ($self) = @_;
1967         my $map_path = $self->map_path;
1968         my $partial = (-e $map_path && ! -z $map_path);
1969         return unless ::verify_ref($self->refname.'^0');
1970         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
1971                 my $rev_db = $self->rev_db_path;
1972                 $self->rebuild_from_rev_db($rev_db);
1973                 if ($self->use_svm_props) {
1974                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
1975                         $self->rebuild_from_rev_db($svm_rev_db);
1976                 }
1977                 $self->unlink_rev_db_symlink;
1978                 return;
1979         }
1980         print "Rebuilding $map_path ...\n" if (!$partial);
1981         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
1982                 (undef, undef));
1983         my ($log, $ctx) =
1984             command_output_pipe(qw/rev-list --pretty=raw --reverse/,
1985                                 ($head ? "$head.." : "") . $self->refname,
1986                                 '--');
1987         my $metadata_url = $self->metadata_url;
1988         remove_username($metadata_url);
1989         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
1990         my $c;
1991         while (<$log>) {
1992                 if ( m{^commit ($::sha1)$} ) {
1993                         $c = $1;
1994                         next;
1995                 }
1996                 next unless s{^\s*(git-svn-id:)}{$1};
1997                 my ($url, $rev, $uuid) = ::extract_metadata($_);
1998                 remove_username($url);
1999
2000                 # ignore merges (from set-tree)
2001                 next if (!defined $rev || !$uuid);
2002
2003                 # if we merged or otherwise started elsewhere, this is
2004                 # how we break out of it
2005                 if (($uuid ne $svn_uuid) ||
2006                     ($metadata_url && $url && ($url ne $metadata_url))) {
2007                         next;
2008                 }
2009                 if ($partial && $head) {
2010                         print "Partial-rebuilding $map_path ...\n";
2011                         print "Currently at $base_rev = $head\n";
2012                         $head = undef;
2013                 }
2014
2015                 $self->rev_map_set($rev, $c);
2016                 print "r$rev = $c\n";
2017         }
2018         command_close_pipe($log, $ctx);
2019         print "Done rebuilding $map_path\n" if (!$partial || !$head);
2020         my $rev_db_path = $self->rev_db_path;
2021         if (-f $self->rev_db_path) {
2022                 unlink $self->rev_db_path or croak "unlink: $!";
2023         }
2024         $self->unlink_rev_db_symlink;
2025 }
2026
2027 # rev_map:
2028 # Tie::File seems to be prone to offset errors if revisions get sparse,
2029 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2030 # one of my favorite modules is out :<  Next up would be one of the DBM
2031 # modules, but I'm not sure which is most portable...
2032 #
2033 # This is the replacement for the rev_db format, which was too big
2034 # and inefficient for large repositories with a lot of sparse history
2035 # (mainly tags)
2036 #
2037 # The format is this:
2038 #   - 24 bytes for every record,
2039 #     * 4 bytes for the integer representing an SVN revision number
2040 #     * 20 bytes representing the sha1 of a git commit
2041 #   - No empty padding records like the old format
2042 #     (except the last record, which can be overwritten)
2043 #   - new records are written append-only since SVN revision numbers
2044 #     increase monotonically
2045 #   - lookups on SVN revision number are done via a binary search
2046 #   - Piping the file to xxd -c24 is a good way of dumping it for
2047 #     viewing or editing (piped back through xxd -r), should the need
2048 #     ever arise.
2049 #   - The last record can be padding revision with an all-zero sha1
2050 #     This is used to optimize fetch performance when using multiple
2051 #     "fetch" directives in .git/config
2052 #
2053 # These files are disposable unless noMetadata or useSvmProps is set
2054
2055 sub _rev_map_set {
2056         my ($fh, $rev, $commit) = @_;
2057
2058         binmode $fh or croak "binmode: $!";
2059         my $size = (stat($fh))[7];
2060         ($size % 24) == 0 or croak "inconsistent size: $size";
2061
2062         my $wr_offset = 0;
2063         if ($size > 0) {
2064                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2065                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2066                 $read == 24 or croak "read only $read bytes (!= 24)";
2067                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2068                 if ($last_commit eq ('0' x40)) {
2069                         if ($size >= 48) {
2070                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2071                                 $read = sysread($fh, $buf, 24) or
2072                                     croak "read: $!";
2073                                 $read == 24 or
2074                                     croak "read only $read bytes (!= 24)";
2075                                 ($last_rev, $last_commit) =
2076                                     unpack(rev_map_fmt, $buf);
2077                                 if ($last_commit eq ('0' x40)) {
2078                                         croak "inconsistent .rev_map\n";
2079                                 }
2080                         }
2081                         if ($last_rev >= $rev) {
2082                                 croak "last_rev is higher!: $last_rev >= $rev";
2083                         }
2084                         $wr_offset = -24;
2085                 }
2086         }
2087         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2088         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2089           croak "write: $!";
2090 }
2091
2092 sub _rev_map_reset {
2093         my ($fh, $rev, $commit) = @_;
2094         my $c = _rev_map_get($fh, $rev);
2095         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
2096         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
2097         truncate $fh, $offset or croak "truncate: $!";
2098 }
2099
2100 sub mkfile {
2101         my ($path) = @_;
2102         unless (-e $path) {
2103                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2104                 mkpath([$dir]) unless -d $dir;
2105                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2106                 close $fh or die "Couldn't close (create) $path: $!\n";
2107         }
2108 }
2109
2110 sub rev_map_set {
2111         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2112         defined $commit or die "missing arg3\n";
2113         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2114         my $db = $self->map_path($uuid);
2115         my $db_lock = "$db.lock";
2116         my $sigmask;
2117         $update_ref ||= 0;
2118         if ($update_ref) {
2119                 $sigmask = POSIX::SigSet->new();
2120                 my $signew = POSIX::SigSet->new(SIGINT, SIGHUP, SIGTERM,
2121                         SIGALRM, SIGUSR1, SIGUSR2);
2122                 sigprocmask(SIG_BLOCK, $signew, $sigmask) or
2123                         croak "Can't block signals: $!";
2124         }
2125         mkfile($db);
2126
2127         $LOCKFILES{$db_lock} = 1;
2128         my $sync;
2129         # both of these options make our .rev_db file very, very important
2130         # and we can't afford to lose it because rebuild() won't work
2131         if ($self->use_svm_props || $self->no_metadata) {
2132                 $sync = 1;
2133                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2134                                            "Failed to copy: ",
2135                                            "$db => $db_lock ($!)\n";
2136         } else {
2137                 rename $db, $db_lock or die "rev_map_set(@_): ",
2138                                             "Failed to rename: ",
2139                                             "$db => $db_lock ($!)\n";
2140         }
2141
2142         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2143              or croak "Couldn't open $db_lock: $!\n";
2144         if ($update_ref eq 'reset') {
2145                 clear_memoized_mergeinfo_caches();
2146                 _rev_map_reset($fh, $rev, $commit);
2147         } else {
2148                 _rev_map_set($fh, $rev, $commit);
2149         }
2150
2151         if ($sync) {
2152                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2153                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2154         }
2155         close $fh or croak $!;
2156         if ($update_ref) {
2157                 $_head = $self;
2158                 my $note = "";
2159                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
2160                 command_noisy('update-ref', '-m', "r$rev$note",
2161                               $self->refname, $commit);
2162         }
2163         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2164                                     "$db_lock => $db ($!)\n";
2165         delete $LOCKFILES{$db_lock};
2166         if ($update_ref) {
2167                 sigprocmask(SIG_SETMASK, $sigmask) or
2168                         croak "Can't restore signal mask: $!";
2169         }
2170 }
2171
2172 # If want_commit, this will return an array of (rev, commit) where
2173 # commit _must_ be a valid commit in the archive.
2174 # Otherwise, it'll return the max revision (whether or not the
2175 # commit is valid or just a 0x40 placeholder).
2176 sub rev_map_max {
2177         my ($self, $want_commit) = @_;
2178         $self->rebuild;
2179         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2180         $want_commit ? ($r, $c) : $r;
2181 }
2182
2183 sub rev_map_max_norebuild {
2184         my ($self, $want_commit) = @_;
2185         my $map_path = $self->map_path;
2186         stat $map_path or return $want_commit ? (0, undef) : 0;
2187         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2188         binmode $fh or croak "binmode: $!";
2189         my $size = (stat($fh))[7];
2190         ($size % 24) == 0 or croak "inconsistent size: $size";
2191
2192         if ($size == 0) {
2193                 close $fh or croak "close: $!";
2194                 return $want_commit ? (0, undef) : 0;
2195         }
2196
2197         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2198         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2199         my ($r, $c) = unpack(rev_map_fmt, $buf);
2200         if ($want_commit && $c eq ('0' x40)) {
2201                 if ($size < 48) {
2202                         return $want_commit ? (0, undef) : 0;
2203                 }
2204                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2205                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2206                 ($r, $c) = unpack(rev_map_fmt, $buf);
2207                 if ($c eq ('0'x40)) {
2208                         croak "Penultimate record is all-zeroes in $map_path";
2209                 }
2210         }
2211         close $fh or croak "close: $!";
2212         $want_commit ? ($r, $c) : $r;
2213 }
2214
2215 sub rev_map_get {
2216         my ($self, $rev, $uuid) = @_;
2217         my $map_path = $self->map_path($uuid);
2218         return undef unless -e $map_path;
2219
2220         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2221         my $c = _rev_map_get($fh, $rev);
2222         close($fh) or croak "close: $!";
2223         $c
2224 }
2225
2226 sub _rev_map_get {
2227         my ($fh, $rev) = @_;
2228
2229         binmode $fh or croak "binmode: $!";
2230         my $size = (stat($fh))[7];
2231         ($size % 24) == 0 or croak "inconsistent size: $size";
2232
2233         if ($size == 0) {
2234                 return undef;
2235         }
2236
2237         my ($l, $u) = (0, $size - 24);
2238         my ($r, $c, $buf);
2239
2240         while ($l <= $u) {
2241                 my $i = int(($l/24 + $u/24) / 2) * 24;
2242                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2243                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2244                 my ($r, $c) = unpack(rev_map_fmt, $buf);
2245
2246                 if ($r < $rev) {
2247                         $l = $i + 24;
2248                 } elsif ($r > $rev) {
2249                         $u = $i - 24;
2250                 } else { # $r == $rev
2251                         return $c eq ('0' x 40) ? undef : $c;
2252                 }
2253         }
2254         undef;
2255 }
2256
2257 # Finds the first svn revision that exists on (if $eq_ok is true) or
2258 # before $rev for the current branch.  It will not search any lower
2259 # than $min_rev.  Returns the git commit hash and svn revision number
2260 # if found, else (undef, undef).
2261 sub find_rev_before {
2262         my ($self, $rev, $eq_ok, $min_rev) = @_;
2263         --$rev unless $eq_ok;
2264         $min_rev ||= 1;
2265         my $max_rev = $self->rev_map_max;
2266         $rev = $max_rev if ($rev > $max_rev);
2267         while ($rev >= $min_rev) {
2268                 if (my $c = $self->rev_map_get($rev)) {
2269                         return ($rev, $c);
2270                 }
2271                 --$rev;
2272         }
2273         return (undef, undef);
2274 }
2275
2276 # Finds the first svn revision that exists on (if $eq_ok is true) or
2277 # after $rev for the current branch.  It will not search any higher
2278 # than $max_rev.  Returns the git commit hash and svn revision number
2279 # if found, else (undef, undef).
2280 sub find_rev_after {
2281         my ($self, $rev, $eq_ok, $max_rev) = @_;
2282         ++$rev unless $eq_ok;
2283         $max_rev ||= $self->rev_map_max;
2284         while ($rev <= $max_rev) {
2285                 if (my $c = $self->rev_map_get($rev)) {
2286                         return ($rev, $c);
2287                 }
2288                 ++$rev;
2289         }
2290         return (undef, undef);
2291 }
2292
2293 sub _new {
2294         my ($class, $repo_id, $ref_id, $path) = @_;
2295         unless (defined $repo_id && length $repo_id) {
2296                 $repo_id = $default_repo_id;
2297         }
2298         unless (defined $ref_id && length $ref_id) {
2299                 # Access the prefix option from the git-svn main program if it's loaded.
2300                 my $prefix = defined &::opt_prefix ? ::opt_prefix() : "";
2301                 $_[2] = $ref_id =
2302                              "refs/remotes/$prefix$default_ref_id";
2303         }
2304         $_[1] = $repo_id;
2305         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2306
2307         # Older repos imported by us used $GIT_DIR/svn/foo instead of
2308         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
2309         if ($ref_id =~ m{^refs/remotes/(.*)}) {
2310                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
2311                 if (-d $old_dir && ! -d $dir) {
2312                         $dir = $old_dir;
2313                 }
2314         }
2315
2316         $_[3] = $path = '' unless (defined $path);
2317         mkpath([$dir]);
2318         my $obj = bless {
2319                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2320                 config => "$ENV{GIT_DIR}/svn/config",
2321                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2322
2323         # Ensure it gets canonicalized
2324         $obj->path($path);
2325
2326         return $obj;
2327 }
2328
2329 sub path {
2330         my $self = shift;
2331
2332         if (@_) {
2333                 my $path = shift;
2334                 $self->{_path} = canonicalize_path($path);
2335                 return;
2336         }
2337
2338         return $self->{_path};
2339 }
2340
2341 sub url {
2342         my $self = shift;
2343
2344         if (@_) {
2345                 my $url = shift;
2346                 $self->{url} = canonicalize_url($url);
2347                 return;
2348         }
2349
2350         return $self->{url};
2351 }
2352
2353 # for read-only access of old .rev_db formats
2354 sub unlink_rev_db_symlink {
2355         my ($self) = @_;
2356         my $link = $self->rev_db_path;
2357         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2358         if (-l $link) {
2359                 unlink $link or croak "unlink: $link failed!";
2360         }
2361 }
2362
2363 sub rev_db_path {
2364         my ($self, $uuid) = @_;
2365         my $db_path = $self->map_path($uuid);
2366         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2367             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2368         $db_path;
2369 }
2370
2371 # the new replacement for .rev_db
2372 sub map_path {
2373         my ($self, $uuid) = @_;
2374         $uuid ||= $self->ra_uuid;
2375         "$self->{map_root}.$uuid";
2376 }
2377
2378 sub uri_encode {
2379         my ($f) = @_;
2380         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2381         $f
2382 }
2383
2384 sub uri_decode {
2385         my ($f) = @_;
2386         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
2387         $f
2388 }
2389
2390 sub remove_username {
2391         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2392 }
2393
2394 1;