git.oblomov.eu Git - git/blob - git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a, $opt_r);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage(;$) {
  36         my $msg = shift;
  37         print(STDERR "Error: $msg\n") if $msg;
  38         print STDERR <<END;
  39 Usage: ${\basename $0}     # fetch/update GIT from CVS
  40        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  41        [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
  42        [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
  43        [-r remote] [CVS_module]
  44 END
  45         exit(1);
  46 }
  47
  48 sub read_author_info($) {
  49         my ($file) = @_;
  50         my $user;
  51         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  52
  53         while (<$f>) {
  54                 # Expected format is this:
  55                 #   exon=Andreas Ericsson <ae@op5.se>
  56                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  57                         $user = $1;
  58                         $conv_author_name{$user} = $2;
  59                         $conv_author_email{$user} = $3;
  60                 }
  61                 # However, we also read from CVSROOT/users format
  62                 # to ease migration.
  63                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  64                         my $mapped;
  65                         ($user, $mapped) = ($1, $3);
  66                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  67                                 $conv_author_name{$user} = $1;
  68                                 $conv_author_email{$user} = $2;
  69                         }
  70                         elsif ($mapped =~ /^<?(.*)>?$/) {
  71                                 $conv_author_name{$user} = $user;
  72                                 $conv_author_email{$user} = $1;
  73                         }
  74                 }
  75                 # NEEDSWORK: Maybe warn on unrecognized lines?
  76         }
  77         close ($f);
  78 }
  79
  80 sub write_author_info($) {
  81         my ($file) = @_;
  82         open my $f, '>', $file or
  83           die("Failed to open $file for writing: $!");
  84
  85         foreach (keys %conv_author_name) {
  86                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  87         }
  88         close ($f);
  89 }
  90
  91 # convert getopts specs for use by git config
  92 sub read_repo_config {
  93     # Split the string between characters, unless there is a ':'
  94     # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
  95         my @opts = split(/ *(?!:)/, shift);
  96         foreach my $o (@opts) {
  97                 my $key = $o;
  98                 $key =~ s/://g;
  99                 my $arg = 'git config';
 100                 $arg .= ' --bool' if ($o !~ /:$/);
 101
 102         chomp(my $tmp = `$arg --get cvsimport.$key`);
 103                 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
 104             no strict 'refs';
 105             my $opt_name = "opt_" . $key;
 106             if (!$$opt_name) {
 107                 $$opt_name = $tmp;
 108             }
 109                 }
 110         }
 111 }
 112
 113 my $opts = "haivmkuo:d:p:r:C:z:s:M:P:A:S:L:";
 114 read_repo_config($opts);
 115 getopts($opts) or usage();
 116 usage if $opt_h;
 117
 118 if (@ARGV == 0) {
 119                 chomp(my $module = `git config --get cvsimport.module`);
 120                 push(@ARGV, $module) if $? == 0;
 121 }
 122 @ARGV <= 1 or usage("You can't specify more than one CVS module");
 123
 124 if ($opt_d) {
 125         $ENV{"CVSROOT"} = $opt_d;
 126 } elsif (-f 'CVS/Root') {
 127         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
 128         $opt_d = <$f>;
 129         chomp $opt_d;
 130         close $f;
 131         $ENV{"CVSROOT"} = $opt_d;
 132 } elsif ($ENV{"CVSROOT"}) {
 133         $opt_d = $ENV{"CVSROOT"};
 134 } else {
 135         usage("CVSROOT needs to be set");
 136 }
 137 $opt_s ||= "-";
 138 $opt_a ||= 0;
 139
 140 my $git_tree = $opt_C;
 141 $git_tree ||= ".";
 142
 143 my $remote;
 144 if (defined $opt_r) {
 145         $remote = 'refs/remotes/' . $opt_r;
 146         $opt_o ||= "master";
 147 } else {
 148         $opt_o ||= "origin";
 149         $remote = 'refs/heads';
 150 }
 151
 152 my $cvs_tree;
 153 if ($#ARGV == 0) {
 154         $cvs_tree = $ARGV[0];
 155 } elsif (-f 'CVS/Repository') {
 156         open my $f, '<', 'CVS/Repository' or
 157             die 'Failed to open CVS/Repository';
 158         $cvs_tree = <$f>;
 159         chomp $cvs_tree;
 160         close $f;
 161 } else {
 162         usage("CVS module has to be specified");
 163 }
 164
 165 our @mergerx = ();
 166 if ($opt_m) {
 167         @mergerx = ( qr/\b(?:from|of|merge|merging|merged) (\w+)/i );
 168 }
 169 if ($opt_M) {
 170         push (@mergerx, qr/$opt_M/);
 171 }
 172
 173 # Remember UTC of our starting time
 174 # we'll want to avoid importing commits
 175 # that are too recent
 176 our $starttime = time();
 177
 178 select(STDERR); $|=1; select(STDOUT);
 179
 180
 181 package CVSconn;
 182 # Basic CVS dialog.
 183 # We're only interested in connecting and downloading, so ...
 184
 185 use File::Spec;
 186 use File::Temp qw(tempfile);
 187 use POSIX qw(strftime dup2);
 188
 189 sub new {
 190         my ($what,$repo,$subdir) = @_;
 191         $what=ref($what) if ref($what);
 192
 193         my $self = {};
 194         $self->{'buffer'} = "";
 195         bless($self,$what);
 196
 197         $repo =~ s#/+$##;
 198         $self->{'fullrep'} = $repo;
 199         $self->conn();
 200
 201         $self->{'subdir'} = $subdir;
 202         $self->{'lines'} = undef;
 203
 204         return $self;
 205 }
 206
 207 sub conn {
 208         my $self = shift;
 209         my $repo = $self->{'fullrep'};
 210         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 211                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 212
 213                 my ($proxyhost,$proxyport);
 214                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 215                         $proxyhost = $1;
 216                         # Default proxyport, if not specified, is 8080.
 217                         $proxyport = 8080;
 218                         if ($ENV{"CVS_PROXY_PORT"}) {
 219                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 220                         }
 221                         if ($param =~ m/proxyport=([^;]+)/) {
 222                                 $proxyport = $1;
 223                         }
 224                 }
 225
 226                 # if username is not explicit in CVSROOT, then use current user, as cvs would
 227                 $user=(getlogin() || $ENV{'LOGNAME'} || $ENV{'USER'} || "anonymous") unless $user;
 228                 my $rr2 = "-";
 229                 unless ($port) {
 230                         $rr2 = ":pserver:$user\@$serv:$repo";
 231                         $port=2401;
 232                 }
 233                 my $rr = ":pserver:$user\@$serv:$port$repo";
 234
 235                 unless ($pass) {
 236                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 237                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 238                                 while (<H>) {
 239                                         chomp;
 240                                         s/^\/\d+\s+//;
 241                                         my ($w,$p) = split(/\s/,$_,2);
 242                                         if ($w eq $rr or $w eq $rr2) {
 243                                                 $pass = $p;
 244                                                 last;
 245                                         }
 246                                 }
 247                         };
 248                 }
 249                 $pass="A" unless $pass;
 250
 251                 my ($s, $rep);
 252                 if ($proxyhost) {
 253
 254                         # Use a HTTP Proxy. Only works for HTTP proxies that
 255                         # don't require user authentication
 256                         #
 257                         # See: http://www.ietf.org/rfc/rfc2817.txt
 258
 259                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 260                         die "Socket to $proxyhost: $!\n" unless defined $s;
 261                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 262                                 or die "Write to $proxyhost: $!\n";
 263                         $s->flush();
 264
 265                         $rep = <$s>;
 266
 267                         # The answer should look like 'HTTP/1.x 2yy ....'
 268                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 269                                 die "Proxy connect: $rep\n";
 270                         }
 271                         # Skip up to the empty line of the proxy server output
 272                         # including the response headers.
 273                         while ($rep = <$s>) {
 274                                 last if (!defined $rep ||
 275                                          $rep eq "\n" ||
 276                                          $rep eq "\r\n");
 277                         }
 278                 } else {
 279                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 280                         die "Socket to $serv: $!\n" unless defined $s;
 281                 }
 282
 283                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 284                         or die "Write to $serv: $!\n";
 285                 $s->flush();
 286
 287                 $rep = <$s>;
 288
 289                 if ($rep ne "I LOVE YOU\n") {
 290                         $rep="<unknown>" unless $rep;
 291                         die "AuthReply: $rep\n";
 292                 }
 293                 $self->{'socketo'} = $s;
 294                 $self->{'socketi'} = $s;
 295         } else { # local or ext: Fork off our own cvs server.
 296                 my $pr = IO::Pipe->new();
 297                 my $pw = IO::Pipe->new();
 298                 my $pid = fork();
 299                 die "Fork: $!\n" unless defined $pid;
 300                 my $cvs = 'cvs';
 301                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 302                 my $rsh = 'rsh';
 303                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 304
 305                 my @cvs = ($cvs, 'server');
 306                 my ($local, $user, $host);
 307                 $local = $repo =~ s/:local://;
 308                 if (!$local) {
 309                     $repo =~ s/:ext://;
 310                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 311                     ($user, $host) = ($1, $2);
 312                 }
 313                 if (!$local) {
 314                     if ($user) {
 315                         unshift @cvs, $rsh, '-l', $user, $host;
 316                     } else {
 317                         unshift @cvs, $rsh, $host;
 318                     }
 319                 }
 320
 321                 unless ($pid) {
 322                         $pr->writer();
 323                         $pw->reader();
 324                         dup2($pw->fileno(),0);
 325                         dup2($pr->fileno(),1);
 326                         $pr->close();
 327                         $pw->close();
 328                         exec(@cvs);
 329                 }
 330                 $pw->writer();
 331                 $pr->reader();
 332                 $self->{'socketo'} = $pw;
 333                 $self->{'socketi'} = $pr;
 334         }
 335         $self->{'socketo'}->write("Root $repo\n");
 336
 337         # Trial and error says that this probably is the minimum set
 338         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 339
 340         $self->{'socketo'}->write("valid-requests\n");
 341         $self->{'socketo'}->flush();
 342
 343         chomp(my $rep=$self->readline());
 344         if ($rep !~ s/^Valid-requests\s*//) {
 345                 $rep="<unknown>" unless $rep;
 346                 die "Expected Valid-requests from server, but got: $rep\n";
 347         }
 348         chomp(my $res=$self->readline());
 349         die "validReply: $res\n" if $res ne "ok";
 350
 351         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 352         $self->{'repo'} = $repo;
 353 }
 354
 355 sub readline {
 356         my ($self) = @_;
 357         return $self->{'socketi'}->getline();
 358 }
 359
 360 sub _file {
 361         # Request a file with a given revision.
 362         # Trial and error says this is a good way to do it. :-/
 363         my ($self,$fn,$rev) = @_;
 364         $self->{'socketo'}->write("Argument -N\n") or return undef;
 365         $self->{'socketo'}->write("Argument -P\n") or return undef;
 366         # -kk: Linus' version doesn't use it - defaults to off
 367         if ($opt_k) {
 368             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 369         }
 370         $self->{'socketo'}->write("Argument -r\n") or return undef;
 371         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 372         $self->{'socketo'}->write("Argument --\n") or return undef;
 373         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 374         $self->{'socketo'}->write("Directory .\n") or return undef;
 375         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 376         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 377         $self->{'socketo'}->write("co\n") or return undef;
 378         $self->{'socketo'}->flush() or return undef;
 379         $self->{'lines'} = 0;
 380         return 1;
 381 }
 382 sub _line {
 383         # Read a line from the server.
 384         # ... except that 'line' may be an entire file. ;-)
 385         my ($self, $fh) = @_;
 386         die "Not in lines" unless defined $self->{'lines'};
 387
 388         my $line;
 389         my $res=0;
 390         while (defined($line = $self->readline())) {
 391                 # M U gnupg-cvs-rep/AUTHORS
 392                 # Updated gnupg-cvs-rep/
 393                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 394                 # /AUTHORS/1.1///T1.1
 395                 # u=rw,g=rw,o=rw
 396                 # 0
 397                 # ok
 398
 399                 if ($line =~ s/^(?:Created|Updated) //) {
 400                         $line = $self->readline(); # path
 401                         $line = $self->readline(); # Entries line
 402                         my $mode = $self->readline(); chomp $mode;
 403                         $self->{'mode'} = $mode;
 404                         defined (my $cnt = $self->readline())
 405                                 or die "EOF from server after 'Changed'\n";
 406                         chomp $cnt;
 407                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 408                         $line="";
 409                         $res = $self->_fetchfile($fh, $cnt);
 410                 } elsif ($line =~ s/^ //) {
 411                         print $fh $line;
 412                         $res += length($line);
 413                 } elsif ($line =~ /^M\b/) {
 414                         # output, do nothing
 415                 } elsif ($line =~ /^Mbinary\b/) {
 416                         my $cnt;
 417                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 418                         chomp $cnt;
 419                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 420                         $line="";
 421                         $res += $self->_fetchfile($fh, $cnt);
 422                 } else {
 423                         chomp $line;
 424                         if ($line eq "ok") {
 425                                 # print STDERR "S: ok (".length($res).")\n";
 426                                 return $res;
 427                         } elsif ($line =~ s/^E //) {
 428                                 # print STDERR "S: $line\n";
 429                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 430                                 $line = $self->readline(); # filename
 431                                 $line = $self->readline(); # OK
 432                                 chomp $line;
 433                                 die "Unknown: $line" if $line ne "ok";
 434                                 return -1;
 435                         } else {
 436                                 die "Unknown: $line\n";
 437                         }
 438                 }
 439         }
 440         return undef;
 441 }
 442 sub file {
 443         my ($self,$fn,$rev) = @_;
 444         my $res;
 445
 446         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 447                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 448
 449         $self->_file($fn,$rev) and $res = $self->_line($fh);
 450
 451         if (!defined $res) {
 452             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 453             truncate $fh, 0;
 454             $self->conn();
 455             $self->_file($fn,$rev) or die "No file command send";
 456             $res = $self->_line($fh);
 457             die "Retry failed" unless defined $res;
 458         }
 459         close ($fh);
 460
 461         return ($name, $res);
 462 }
 463 sub _fetchfile {
 464         my ($self, $fh, $cnt) = @_;
 465         my $res = 0;
 466         my $bufsize = 1024 * 1024;
 467         while ($cnt) {
 468             if ($bufsize > $cnt) {
 469                 $bufsize = $cnt;
 470             }
 471             my $buf;
 472             my $num = $self->{'socketi'}->read($buf,$bufsize);
 473             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 474             print $fh $buf;
 475             $res += $num;
 476             $cnt -= $num;
 477         }
 478         return $res;
 479 }
 480
 481
 482 package main;
 483
 484 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 485
 486
 487 sub pdate($) {
 488         my ($d) = @_;
 489         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 490                 or die "Unparseable date: $d\n";
 491         my $y=$1; $y-=1900 if $y>1900;
 492         return timegm($6||0,$5,$4,$3,$2-1,$y);
 493 }
 494
 495 sub pmode($) {
 496         my ($mode) = @_;
 497         my $m = 0;
 498         my $mm = 0;
 499         my $um = 0;
 500         for my $x(split(//,$mode)) {
 501                 if ($x eq ",") {
 502                         $m |= $mm&$um;
 503                         $mm = 0;
 504                         $um = 0;
 505                 } elsif ($x eq "u") { $um |= 0700;
 506                 } elsif ($x eq "g") { $um |= 0070;
 507                 } elsif ($x eq "o") { $um |= 0007;
 508                 } elsif ($x eq "r") { $mm |= 0444;
 509                 } elsif ($x eq "w") { $mm |= 0222;
 510                 } elsif ($x eq "x") { $mm |= 0111;
 511                 } elsif ($x eq "=") { # do nothing
 512                 } else { die "Unknown mode: $mode\n";
 513                 }
 514         }
 515         $m |= $mm&$um;
 516         return $m;
 517 }
 518
 519 sub getwd() {
 520         my $pwd = `pwd`;
 521         chomp $pwd;
 522         return $pwd;
 523 }
 524
 525 sub is_sha1 {
 526         my $s = shift;
 527         return $s =~ /^[a-f0-9]{40}$/;
 528 }
 529
 530 sub get_headref ($) {
 531         my $name = shift;
 532         my $r = `git rev-parse --verify '$name' 2>/dev/null`;
 533         return undef unless $? == 0;
 534         chomp $r;
 535         return $r;
 536 }
 537
 538 -d $git_tree
 539         or mkdir($git_tree,0777)
 540         or die "Could not create $git_tree: $!";
 541 chdir($git_tree);
 542
 543 my $last_branch = "";
 544 my $orig_branch = "";
 545 my %branch_date;
 546 my $tip_at_start = undef;
 547
 548 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 549 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 550 $ENV{"GIT_DIR"} = $git_dir;
 551 my $orig_git_index;
 552 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 553
 554 my %index; # holds filenames of one index per branch
 555
 556 unless (-d $git_dir) {
 557         system("git-init");
 558         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 559         system("git-read-tree");
 560         die "Cannot init an empty tree: $?\n" if $?;
 561
 562         $last_branch = $opt_o;
 563         $orig_branch = "";
 564 } else {
 565         open(F, "git-symbolic-ref HEAD |") or
 566                 die "Cannot run git-symbolic-ref: $!\n";
 567         chomp ($last_branch = <F>);
 568         $last_branch = basename($last_branch);
 569         close(F);
 570         unless ($last_branch) {
 571                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 572                 $last_branch = "master";
 573         }
 574         $orig_branch = $last_branch;
 575         $tip_at_start = `git-rev-parse --verify HEAD`;
 576
 577         # Get the last import timestamps
 578         my $fmt = '($ref, $author) = (%(refname), %(author));';
 579         open(H, "git-for-each-ref --perl --format='$fmt' $remote |") or
 580                 die "Cannot run git-for-each-ref: $!\n";
 581         while (defined(my $entry = <H>)) {
 582                 my ($ref, $author);
 583                 eval($entry) || die "cannot eval refs list: $@";
 584                 my ($head) = ($ref =~ m|^$remote/(.*)|);
 585                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 586                 $branch_date{$head} = $1;
 587         }
 588         close(H);
 589         if (!exists $branch_date{$opt_o}) {
 590                 die "Branch '$opt_o' does not exist.\n".
 591                        "Either use the correct '-o branch' option,\n".
 592                        "or import to a new repository.\n";
 593         }
 594 }
 595
 596 -d $git_dir
 597         or die "Could not create git subdir ($git_dir).\n";
 598
 599 # now we read (and possibly save) author-info as well
 600 -f "$git_dir/cvs-authors" and
 601   read_author_info("$git_dir/cvs-authors");
 602 if ($opt_A) {
 603         read_author_info($opt_A);
 604         write_author_info("$git_dir/cvs-authors");
 605 }
 606
 607
 608 #
 609 # run cvsps into a file unless we are getting
 610 # it passed as a file via $opt_P
 611 #
 612 my $cvspsfile;
 613 unless ($opt_P) {
 614         print "Running cvsps...\n" if $opt_v;
 615         my $pid = open(CVSPS,"-|");
 616         my $cvspsfh;
 617         die "Cannot fork: $!\n" unless defined $pid;
 618         unless ($pid) {
 619                 my @opt;
 620                 @opt = split(/,/,$opt_p) if defined $opt_p;
 621                 unshift @opt, '-z', $opt_z if defined $opt_z;
 622                 unshift @opt, '-q'         unless defined $opt_v;
 623                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 624                         push @opt, '--cvs-direct';
 625                 }
 626                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 627                 die "Could not start cvsps: $!\n";
 628         }
 629         ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 630                                           DIR => File::Spec->tmpdir());
 631         while (<CVSPS>) {
 632             print $cvspsfh $_;
 633         }
 634         close CVSPS;
 635         $? == 0 or die "git-cvsimport: fatal: cvsps reported error\n";
 636         close $cvspsfh;
 637 } else {
 638         $cvspsfile = $opt_P;
 639 }
 640
 641 open(CVS, "<$cvspsfile") or die $!;
 642
 643 ## cvsps output:
 644 #---------------------
 645 #PatchSet 314
 646 #Date: 1999/09/18 13:03:59
 647 #Author: wkoch
 648 #Branch: STABLE-BRANCH-1-0
 649 #Ancestor branch: HEAD
 650 #Tag: (none)
 651 #Log:
 652 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 653 #Members:
 654 #       README:1.57->1.57.2.1
 655 #       VERSION:1.96->1.96.2.1
 656 #
 657 #---------------------
 658
 659 my $state = 0;
 660
 661 sub update_index (\@\@) {
 662         my $old = shift;
 663         my $new = shift;
 664         open(my $fh, '|-', qw(git-update-index -z --index-info))
 665                 or die "unable to open git-update-index: $!";
 666         print $fh
 667                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 668                         @$old),
 669                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 670                         @$new)
 671                 or die "unable to write to git-update-index: $!";
 672         close $fh
 673                 or die "unable to write to git-update-index: $!";
 674         $? and die "git-update-index reported error: $?";
 675 }
 676
 677 sub write_tree () {
 678         open(my $fh, '-|', qw(git-write-tree))
 679                 or die "unable to open git-write-tree: $!";
 680         chomp(my $tree = <$fh>);
 681         is_sha1($tree)
 682                 or die "Cannot get tree id ($tree): $!";
 683         close($fh)
 684                 or die "Error running git-write-tree: $?\n";
 685         print "Tree ID $tree\n" if $opt_v;
 686         return $tree;
 687 }
 688
 689 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 690 my (@old,@new,@skipped,%ignorebranch);
 691
 692 # commits that cvsps cannot place anywhere...
 693 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 694
 695 sub commit {
 696         if ($branch eq $opt_o && !$index{branch} &&
 697                 !get_headref("$remote/$branch")) {
 698             # looks like an initial commit
 699             # use the index primed by git-init
 700             $ENV{GIT_INDEX_FILE} = "$git_dir/index";
 701             $index{$branch} = "$git_dir/index";
 702         } else {
 703             # use an index per branch to speed up
 704             # imports of projects with many branches
 705             unless ($index{$branch}) {
 706                 $index{$branch} = tmpnam();
 707                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 708                 if ($ancestor) {
 709                     system("git-read-tree", "$remote/$ancestor");
 710                 } else {
 711                     system("git-read-tree", "$remote/$branch");
 712                 }
 713                 die "read-tree failed: $?\n" if $?;
 714             }
 715         }
 716         $ENV{GIT_INDEX_FILE} = $index{$branch};
 717
 718         update_index(@old, @new);
 719         @old = @new = ();
 720         my $tree = write_tree();
 721         my $parent = get_headref("$remote/$last_branch");
 722         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 723
 724         my @commit_args;
 725         push @commit_args, ("-p", $parent) if $parent;
 726
 727         # loose detection of merges
 728         # based on the commit msg
 729         foreach my $rx (@mergerx) {
 730                 next unless $logmsg =~ $rx && $1;
 731                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 732                 if (my $sha1 = get_headref("$remote/$mparent")) {
 733                         push @commit_args, '-p', $mparent;
 734                         print "Merge parent branch: $mparent\n" if $opt_v;
 735                 }
 736         }
 737
 738         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 739         $ENV{GIT_AUTHOR_NAME} = $author_name;
 740         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 741         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 742         $ENV{GIT_COMMITTER_NAME} = $author_name;
 743         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 744         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 745         my $pid = open2(my $commit_read, my $commit_write,
 746                 'git-commit-tree', $tree, @commit_args);
 747
 748         # compatibility with git2cvs
 749         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 750         $logmsg =~ s/[\s\n]+\z//;
 751
 752         if (@skipped) {
 753             $logmsg .= "\n\n\nSKIPPED:\n\t";
 754             $logmsg .= join("\n\t", @skipped) . "\n";
 755             @skipped = ();
 756         }
 757
 758         print($commit_write "$logmsg\n") && close($commit_write)
 759                 or die "Error writing to git-commit-tree: $!\n";
 760
 761         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 762         chomp(my $cid = <$commit_read>);
 763         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 764         print "Commit ID $cid\n" if $opt_v;
 765         close($commit_read);
 766
 767         waitpid($pid,0);
 768         die "Error running git-commit-tree: $?\n" if $?;
 769
 770         system("git-update-ref $remote/$branch $cid") == 0
 771                 or die "Cannot write branch $branch for update: $!\n";
 772
 773         if ($tag) {
 774                 my ($xtag) = $tag;
 775                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 776                 $xtag =~ tr/_/\./ if ( $opt_u );
 777                 $xtag =~ s/[\/]/$opt_s/g;
 778
 779                 system('git-tag', '-f', $xtag, $cid) == 0
 780                         or die "Cannot create tag $xtag: $!\n";
 781
 782                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 783         }
 784 };
 785
 786 my $commitcount = 1;
 787 while (<CVS>) {
 788         chomp;
 789         if ($state == 0 and /^-+$/) {
 790                 $state = 1;
 791         } elsif ($state == 0) {
 792                 $state = 1;
 793                 redo;
 794         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 795                 $patchset = 0+$_;
 796                 $state=2;
 797         } elsif ($state == 2 and s/^Date:\s+//) {
 798                 $date = pdate($_);
 799                 unless ($date) {
 800                         print STDERR "Could not parse date: $_\n";
 801                         $state=0;
 802                         next;
 803                 }
 804                 $state=3;
 805         } elsif ($state == 3 and s/^Author:\s+//) {
 806                 s/\s+$//;
 807                 if (/^(.*?)\s+<(.*)>/) {
 808                     ($author_name, $author_email) = ($1, $2);
 809                 } elsif ($conv_author_name{$_}) {
 810                         $author_name = $conv_author_name{$_};
 811                         $author_email = $conv_author_email{$_};
 812                 } else {
 813                     $author_name = $author_email = $_;
 814                 }
 815                 $state = 4;
 816         } elsif ($state == 4 and s/^Branch:\s+//) {
 817                 s/\s+$//;
 818                 tr/_/\./ if ( $opt_u );
 819                 s/[\/]/$opt_s/g;
 820                 $branch = $_;
 821                 $state = 5;
 822         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 823                 s/\s+$//;
 824                 $ancestor = $_;
 825                 $ancestor = $opt_o if $ancestor eq "HEAD";
 826                 $state = 6;
 827         } elsif ($state == 5) {
 828                 $ancestor = undef;
 829                 $state = 6;
 830                 redo;
 831         } elsif ($state == 6 and s/^Tag:\s+//) {
 832                 s/\s+$//;
 833                 if ($_ eq "(none)") {
 834                         $tag = undef;
 835                 } else {
 836                         $tag = $_;
 837                 }
 838                 $state = 7;
 839         } elsif ($state == 7 and /^Log:/) {
 840                 $logmsg = "";
 841                 $state = 8;
 842         } elsif ($state == 8 and /^Members:/) {
 843                 $branch = $opt_o if $branch eq "HEAD";
 844                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 845                         # skip
 846                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 847                         $state = 11;
 848                         next;
 849                 }
 850                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 851                         # skip if the commit is too recent
 852                         # given that the cvsps default fuzz is 300s, we give ourselves another
 853                         # 300s just in case -- this also prevents skipping commits
 854                         # due to server clock drift
 855                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 856                         $state = 11;
 857                         next;
 858                 }
 859                 if (exists $ignorebranch{$branch}) {
 860                         print STDERR "Skipping $branch\n";
 861                         $state = 11;
 862                         next;
 863                 }
 864                 if ($ancestor) {
 865                         if ($ancestor eq $branch) {
 866                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 867                                 $ancestor = $opt_o;
 868                         }
 869                         if (defined get_headref("$remote/$branch")) {
 870                                 print STDERR "Branch $branch already exists!\n";
 871                                 $state=11;
 872                                 next;
 873                         }
 874                         my $id = get_headref("$remote/$ancestor");
 875                         if (!$id) {
 876                                 print STDERR "Branch $ancestor does not exist!\n";
 877                                 $ignorebranch{$branch} = 1;
 878                                 $state=11;
 879                                 next;
 880                         }
 881
 882                         system(qw(git update-ref -m cvsimport),
 883                                 "$remote/$branch", $id);
 884                         if($? != 0) {
 885                                 print STDERR "Could not create branch $branch\n";
 886                                 $ignorebranch{$branch} = 1;
 887                                 $state=11;
 888                                 next;
 889                         }
 890                 }
 891                 $last_branch = $branch if $branch ne $last_branch;
 892                 $state = 9;
 893         } elsif ($state == 8) {
 894                 $logmsg .= "$_\n";
 895         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 896 #       VERSION:1.96->1.96.2.1
 897                 my $init = ($2 eq "INITIAL");
 898                 my $fn = $1;
 899                 my $rev = $3;
 900                 $fn =~ s#^/+##;
 901                 if ($opt_S && $fn =~ m/$opt_S/) {
 902                     print "SKIPPING $fn v $rev\n";
 903                     push(@skipped, $fn);
 904                     next;
 905                 }
 906                 print "Fetching $fn   v $rev\n" if $opt_v;
 907                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 908                 if ($size == -1) {
 909                         push(@old,$fn);
 910                         print "Drop $fn\n" if $opt_v;
 911                 } else {
 912                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 913                         my $pid = open(my $F, '-|');
 914                         die $! unless defined $pid;
 915                         if (!$pid) {
 916                             exec("git-hash-object", "-w", $tmpname)
 917                                 or die "Cannot create object: $!\n";
 918                         }
 919                         my $sha = <$F>;
 920                         chomp $sha;
 921                         close $F;
 922                         my $mode = pmode($cvs->{'mode'});
 923                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 924                 }
 925                 unlink($tmpname);
 926         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 927                 my $fn = $1;
 928                 $fn =~ s#^/+##;
 929                 push(@old,$fn);
 930                 print "Delete $fn\n" if $opt_v;
 931         } elsif ($state == 9 and /^\s*$/) {
 932                 $state = 10;
 933         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 934                 $commitcount++;
 935                 if ($opt_L && $commitcount > $opt_L) {
 936                         last;
 937                 }
 938                 commit();
 939                 if (($commitcount & 1023) == 0) {
 940                         system("git repack -a -d");
 941                 }
 942                 $state = 1;
 943         } elsif ($state == 11 and /^-+$/) {
 944                 $state = 1;
 945         } elsif (/^-+$/) { # end of unknown-line processing
 946                 $state = 1;
 947         } elsif ($state != 11) { # ignore stuff when skipping
 948                 print "* UNKNOWN LINE * $_\n";
 949         }
 950 }
 951 commit() if $branch and $state != 11;
 952
 953 unless ($opt_P) {
 954         unlink($cvspsfile);
 955 }
 956
 957 # The heuristic of repacking every 1024 commits can leave a
 958 # lot of unpacked data.  If there is more than 1MB worth of
 959 # not-packed objects, repack once more.
 960 my $line = `git-count-objects`;
 961 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 962   my ($n_objects, $kb) = ($1, $2);
 963   1024 < $kb
 964     and system("git repack -a -d");
 965 }
 966
 967 foreach my $git_index (values %index) {
 968     if ($git_index ne "$git_dir/index") {
 969         unlink($git_index);
 970     }
 971 }
 972
 973 if (defined $orig_git_index) {
 974         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 975 } else {
 976         delete $ENV{GIT_INDEX_FILE};
 977 }
 978
 979 # Now switch back to the branch we were in before all of this happened
 980 if ($orig_branch) {
 981         print "DONE.\n" if $opt_v;
 982         if ($opt_i) {
 983                 exit 0;
 984         }
 985         my $tip_at_end = `git-rev-parse --verify HEAD`;
 986         if ($tip_at_start ne $tip_at_end) {
 987                 for ($tip_at_start, $tip_at_end) { chomp; }
 988                 print "Fetched into the current branch.\n" if $opt_v;
 989                 system(qw(git-read-tree -u -m),
 990                        $tip_at_start, $tip_at_end);
 991                 die "Fast-forward update failed: $?\n" if $?;
 992         }
 993         else {
 994                 system(qw(git-merge cvsimport HEAD), "$remote/$opt_o");
 995                 die "Could not merge $opt_o into the current branch.\n" if $?;
 996         }
 997 } else {
 998         $orig_branch = "master";
 999         print "DONE; creating $orig_branch branch\n" if $opt_v;
1000         system("git-update-ref", "refs/heads/master", "$remote/$opt_o")
1001                 unless defined get_headref('refs/heads/master');
1002         system("git-symbolic-ref", "$remote/HEAD", "$remote/$opt_o")
1003                 if ($opt_r && $opt_o ne 'HEAD');
1004         system('git-update-ref', 'HEAD', "$orig_branch");
1005         unless ($opt_i) {
1006                 system('git checkout -f');
1007                 die "checkout failed: $?\n" if $?;
1008         }
1009 }