git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use Digest::MD5;
  15 use IO::File qw//;
  16 use File::Basename qw/dirname basename/;
  17 use File::Path qw/mkpath/;
  18 use File::Spec;
  19 use File::Find;
  20 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21 use IPC::Open3;
  22 use Memoize;
  23
  24 use Git::SVN;
  25 use Git::SVN::Editor;
  26 use Git::SVN::Fetcher;
  27 use Git::SVN::Ra;
  28 use Git::SVN::Prompt;
  29 use Git::SVN::Log;
  30 use Git::SVN::Migration;
  31
  32 use Git::SVN::Utils qw(
  33         fatal
  34         can_compress
  35         canonicalize_path
  36         canonicalize_url
  37         join_paths
  38         add_path_to_url
  39         join_paths
  40 );
  41
  42 use Git qw(
  43         git_cmd_try
  44         command
  45         command_oneline
  46         command_noisy
  47         command_output_pipe
  48         command_close_pipe
  49         command_bidi_pipe
  50         command_close_bidi_pipe
  51 );
  52
  53 BEGIN {
  54         Memoize::memoize 'Git::config';
  55         Memoize::memoize 'Git::config_bool';
  56 }
  57
  58
  59 # From which subdir have we been invoked?
  60 my $cmd_dir_prefix = eval {
  61         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  62 } || '';
  63
  64 $Git::SVN::Ra::_log_window_size = 100;
  65
  66 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  67         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  68 }
  69
  70 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  71         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  72         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  73 }
  74
  75 $Git::SVN::Log::TZ = $ENV{TZ};
  76 $ENV{TZ} = 'UTC';
  77 $| = 1; # unbuffer STDOUT
  78
  79 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  80 # repository decides to close the connection which we expect to be kept alive.
  81 $SIG{PIPE} = 'IGNORE';
  82
  83 # Given a dot separated version number, "subtract" it from
  84 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  85 # is at least at the version the caller asked for.
  86 sub compare_svn_version {
  87         my (@ours) = split(/\./, $SVN::Core::VERSION);
  88         my (@theirs) = split(/\./, $_[0]);
  89         my ($i, $diff);
  90
  91         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  92                 $diff = $ours[$i] - $theirs[$i];
  93                 return $diff if ($diff);
  94         }
  95         return 1 if ($i < @ours);
  96         return -1 if ($i < @theirs);
  97         return 0;
  98 }
  99
 100 sub _req_svn {
 101         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 102         require SVN::Ra;
 103         require SVN::Delta;
 104         if (::compare_svn_version('1.1.0') < 0) {
 105                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 106         }
 107 }
 108
 109 $sha1 = qr/[a-f\d]{40}/;
 110 $sha1_short = qr/[a-f\d]{4,40}/;
 111 my ($_stdin, $_help, $_edit,
 112         $_message, $_file, $_branch_dest,
 113         $_template, $_shared,
 114         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 115         $_before, $_after,
 116         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
 117         $_prefix, $_no_checkout, $_url, $_verbose,
 118         $_commit_url, $_tag, $_merge_info, $_interactive);
 119
 120 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 121 sub opt_prefix { return $_prefix || '' }
 122
 123 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 124 $_q ||= 0;
 125 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 126                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 127                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 128                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 129                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 130                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 131 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 132                 'authors-file|A=s' => \$_authors,
 133                 'authors-prog=s' => \$_authors_prog,
 134                 'repack:i' => \$Git::SVN::_repack,
 135                 'noMetadata' => \$Git::SVN::_no_metadata,
 136                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 137                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 138                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 139                 'no-checkout' => \$_no_checkout,
 140                 'quiet|q+' => \$_q,
 141                 'repack-flags|repack-args|repack-opts=s' =>
 142                    \$Git::SVN::_repack_flags,
 143                 'use-log-author' => \$Git::SVN::_use_log_author,
 144                 'add-author-from' => \$Git::SVN::_add_author_from,
 145                 'localtime' => \$Git::SVN::_localtime,
 146                 %remote_opts );
 147
 148 my ($_trunk, @_tags, @_branches, $_stdlayout);
 149 my %icv;
 150 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 151                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 152                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 153                   'stdlayout|s' => \$_stdlayout,
 154                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 155                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 156                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 157                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 158                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 159                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 160                   %remote_opts );
 161 my %cmt_opts = ( 'edit|e' => \$_edit,
 162                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 163                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 164                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 165                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 166 );
 167
 168 my %cmd = (
 169         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 170                         { 'revision|r=s' => \$_revision,
 171                           'fetch-all|all' => \$_fetch_all,
 172                           'parent|p' => \$_fetch_parent,
 173                            %fc_opts } ],
 174         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 175                         { 'revision|r=s' => \$_revision,
 176                           'preserve-empty-dirs' =>
 177                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 178                           'placeholder-filename=s' =>
 179                                 \$Git::SVN::Fetcher::_placeholder_filename,
 180                            %fc_opts, %init_opts } ],
 181         init => [ \&cmd_init, "Initialize a repo for tracking" .
 182                           " (requires URL argument)",
 183                           \%init_opts ],
 184         'multi-init' => [ \&cmd_multi_init,
 185                           "Deprecated alias for ".
 186                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 187                           \%init_opts ],
 188         dcommit => [ \&cmd_dcommit,
 189                      'Commit several diffs to merge with upstream',
 190                         { 'merge|m|M' => \$_merge,
 191                           'strategy|s=s' => \$_strategy,
 192                           'verbose|v' => \$_verbose,
 193                           'dry-run|n' => \$_dry_run,
 194                           'fetch-all|all' => \$_fetch_all,
 195                           'commit-url=s' => \$_commit_url,
 196                           'revision|r=i' => \$_revision,
 197                           'no-rebase' => \$_no_rebase,
 198                           'mergeinfo=s' => \$_merge_info,
 199                           'interactive|i' => \$_interactive,
 200                         %cmt_opts, %fc_opts } ],
 201         branch => [ \&cmd_branch,
 202                     'Create a branch in the SVN repository',
 203                     { 'message|m=s' => \$_message,
 204                       'destination|d=s' => \$_branch_dest,
 205                       'dry-run|n' => \$_dry_run,
 206                       'parents' => \$_parents,
 207                       'tag|t' => \$_tag,
 208                       'username=s' => \$Git::SVN::Prompt::_username,
 209                       'commit-url=s' => \$_commit_url } ],
 210         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 211                  'Create a tag in the SVN repository',
 212                  { 'message|m=s' => \$_message,
 213                    'destination|d=s' => \$_branch_dest,
 214                    'dry-run|n' => \$_dry_run,
 215                    'parents' => \$_parents,
 216                    'username=s' => \$Git::SVN::Prompt::_username,
 217                    'commit-url=s' => \$_commit_url } ],
 218         'set-tree' => [ \&cmd_set_tree,
 219                         "Set an SVN repository to a git tree-ish",
 220                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 221         'create-ignore' => [ \&cmd_create_ignore,
 222                              'Create a .gitignore per svn:ignore',
 223                              { 'revision|r=i' => \$_revision
 224                              } ],
 225         'mkdirs' => [ \&cmd_mkdirs ,
 226                       "recreate empty directories after a checkout",
 227                       { 'revision|r=i' => \$_revision } ],
 228         'propget' => [ \&cmd_propget,
 229                        'Print the value of a property on a file or directory',
 230                        { 'revision|r=i' => \$_revision } ],
 231         'proplist' => [ \&cmd_proplist,
 232                        'List all properties of a file or directory',
 233                        { 'revision|r=i' => \$_revision } ],
 234         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 235                         { 'revision|r=i' => \$_revision
 236                         } ],
 237         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 238                         { 'revision|r=i' => \$_revision
 239                         } ],
 240         'multi-fetch' => [ \&cmd_multi_fetch,
 241                            "Deprecated alias for $0 fetch --all",
 242                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 243         'migrate' => [ sub { },
 244                        # no-op, we automatically run this anyways,
 245                        'Migrate configuration/metadata/layout from
 246                         previous versions of git-svn',
 247                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 248                          %remote_opts } ],
 249         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 250                         { 'limit=i' => \$Git::SVN::Log::limit,
 251                           'revision|r=s' => \$_revision,
 252                           'verbose|v' => \$Git::SVN::Log::verbose,
 253                           'incremental' => \$Git::SVN::Log::incremental,
 254                           'oneline' => \$Git::SVN::Log::oneline,
 255                           'show-commit' => \$Git::SVN::Log::show_commit,
 256                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 257                           'authors-file|A=s' => \$_authors,
 258                           'color' => \$Git::SVN::Log::color,
 259                           'pager=s' => \$Git::SVN::Log::pager
 260                         } ],
 261         'find-rev' => [ \&cmd_find_rev,
 262                         "Translate between SVN revision numbers and tree-ish",
 263                         { 'before' => \$_before,
 264                           'after' => \$_after } ],
 265         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 266                         { 'merge|m|M' => \$_merge,
 267                           'verbose|v' => \$_verbose,
 268                           'strategy|s=s' => \$_strategy,
 269                           'local|l' => \$_local,
 270                           'fetch-all|all' => \$_fetch_all,
 271                           'dry-run|n' => \$_dry_run,
 272                           'preserve-merges|p' => \$_preserve_merges,
 273                           %fc_opts } ],
 274         'commit-diff' => [ \&cmd_commit_diff,
 275                            'Commit a diff between two trees',
 276                         { 'message|m=s' => \$_message,
 277                           'file|F=s' => \$_file,
 278                           'revision|r=s' => \$_revision,
 279                         %cmt_opts } ],
 280         'info' => [ \&cmd_info,
 281                     "Show info about the latest SVN revision
 282                      on the current branch",
 283                     { 'url' => \$_url, } ],
 284         'blame' => [ \&Git::SVN::Log::cmd_blame,
 285                     "Show what revision and author last modified each line of a file",
 286                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 287         'reset' => [ \&cmd_reset,
 288                      "Undo fetches back to the specified SVN revision",
 289                      { 'revision|r=s' => \$_revision,
 290                        'parent|p' => \$_fetch_parent } ],
 291         'gc' => [ \&cmd_gc,
 292                   "Compress unhandled.log files in .git/svn and remove " .
 293                   "index files in .git/svn",
 294                 {} ],
 295 );
 296
 297 use Term::ReadLine;
 298 package FakeTerm;
 299 sub new {
 300         my ($class, $reason) = @_;
 301         return bless \$reason, shift;
 302 }
 303 sub readline {
 304         my $self = shift;
 305         die "Cannot use readline on FakeTerm: $$self";
 306 }
 307 package main;
 308
 309 my $term = eval {
 310         $ENV{"GIT_SVN_NOTTY"}
 311                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 312                 : new Term::ReadLine 'git-svn';
 313 };
 314 if ($@) {
 315         $term = new FakeTerm "$@: going non-interactive";
 316 }
 317
 318 my $cmd;
 319 for (my $i = 0; $i < @ARGV; $i++) {
 320         if (defined $cmd{$ARGV[$i]}) {
 321                 $cmd = $ARGV[$i];
 322                 splice @ARGV, $i, 1;
 323                 last;
 324         } elsif ($ARGV[$i] eq 'help') {
 325                 $cmd = $ARGV[$i+1];
 326                 usage(0);
 327         }
 328 };
 329
 330 # make sure we're always running at the top-level working directory
 331 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 332         $ENV{GIT_DIR} ||= ".git";
 333 } else {
 334         my ($git_dir, $cdup);
 335         git_cmd_try {
 336                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 337         } "Unable to find .git directory\n";
 338         git_cmd_try {
 339                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 340                 chomp $cdup if ($cdup);
 341                 $cdup = "." unless ($cdup && length $cdup);
 342         } "Already at toplevel, but $git_dir not found\n";
 343         $ENV{GIT_DIR} = $git_dir;
 344         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 345         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 346 }
 347
 348 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 349
 350 read_git_config(\%opts);
 351 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 352         Getopt::Long::Configure('pass_through');
 353 }
 354 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 355                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 356                     'id|i=s' => \$Git::SVN::default_ref_id,
 357                     'svn-remote|remote|R=s' => sub {
 358                        $Git::SVN::no_reuse_existing = 1;
 359                        $Git::SVN::default_repo_id = $_[1] });
 360 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 361
 362 usage(0) if $_help;
 363 version() if $_version;
 364 usage(1) unless defined $cmd;
 365 load_authors() if $_authors;
 366 if (defined $_authors_prog) {
 367         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 368 }
 369
 370 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 371         Git::SVN::Migration::migration_check();
 372 }
 373 Git::SVN::init_vars();
 374 eval {
 375         Git::SVN::verify_remotes_sanity();
 376         $cmd{$cmd}->[0]->(@ARGV);
 377         post_fetch_checkout();
 378 };
 379 fatal $@ if $@;
 380 exit 0;
 381
 382 ####################### primary functions ######################
 383 sub usage {
 384         my $exit = shift || 0;
 385         my $fd = $exit ? \*STDERR : \*STDOUT;
 386         print $fd <<"";
 387 git-svn - bidirectional operations between a single Subversion tree and git
 388 usage: git svn <command> [options] [arguments]\n
 389
 390         print $fd "Available commands:\n" unless $cmd;
 391
 392         foreach (sort keys %cmd) {
 393                 next if $cmd && $cmd ne $_;
 394                 next if /^multi-/; # don't show deprecated commands
 395                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 396                 foreach (sort keys %{$cmd{$_}->[2]}) {
 397                         # mixed-case options are for .git/config only
 398                         next if /[A-Z]/ && /^[a-z]+$/i;
 399                         # prints out arguments as they should be passed:
 400                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 401                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 402                                                         "--$_" : "-$_" }
 403                                                 split /\|/,$_)," $x\n";
 404                 }
 405         }
 406         print $fd <<"";
 407 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 408 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 409 one git repository and want to keep them separate.  See git-svn(1) for more
 410 information.
 411
 412         exit $exit;
 413 }
 414
 415 sub version {
 416         ::_req_svn();
 417         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 418         exit 0;
 419 }
 420
 421 sub ask {
 422         my ($prompt, %arg) = @_;
 423         my $valid_re = $arg{valid_re};
 424         my $default = $arg{default};
 425         my $resp;
 426         my $i = 0;
 427
 428         if ( !( defined($term->IN)
 429             && defined( fileno($term->IN) )
 430             && defined( $term->OUT )
 431             && defined( fileno($term->OUT) ) ) ){
 432                 return defined($default) ? $default : undef;
 433         }
 434
 435         while ($i++ < 10) {
 436                 $resp = $term->readline($prompt);
 437                 if (!defined $resp) { # EOF
 438                         print "\n";
 439                         return defined $default ? $default : undef;
 440                 }
 441                 if ($resp eq '' and defined $default) {
 442                         return $default;
 443                 }
 444                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 445                         return $resp;
 446                 }
 447         }
 448         return undef;
 449 }
 450
 451 sub do_git_init_db {
 452         unless (-d $ENV{GIT_DIR}) {
 453                 my @init_db = ('init');
 454                 push @init_db, "--template=$_template" if defined $_template;
 455                 if (defined $_shared) {
 456                         if ($_shared =~ /[a-z]/) {
 457                                 push @init_db, "--shared=$_shared";
 458                         } else {
 459                                 push @init_db, "--shared";
 460                         }
 461                 }
 462                 command_noisy(@init_db);
 463                 $_repository = Git->repository(Repository => ".git");
 464         }
 465         my $set;
 466         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 467         foreach my $i (keys %icv) {
 468                 die "'$set' and '$i' cannot both be set\n" if $set;
 469                 next unless defined $icv{$i};
 470                 command_noisy('config', "$pfx.$i", $icv{$i});
 471                 $set = $i;
 472         }
 473         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 474         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 475                 if defined $$ignore_paths_regex;
 476         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 477         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 478                 if defined $$include_paths_regex;
 479         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 480         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 481                 if defined $$ignore_refs_regex;
 482
 483         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 484                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 485                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 486                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 487         }
 488 }
 489
 490 sub init_subdir {
 491         my $repo_path = shift or return;
 492         mkpath([$repo_path]) unless -d $repo_path;
 493         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 494         $ENV{GIT_DIR} = '.git';
 495         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 496 }
 497
 498 sub cmd_clone {
 499         my ($url, $path) = @_;
 500         if (!defined $path &&
 501             (defined $_trunk || @_branches || @_tags ||
 502              defined $_stdlayout) &&
 503             $url !~ m#^[a-z\+]+://#) {
 504                 $path = $url;
 505         }
 506         $path = basename($url) if !defined $path || !length $path;
 507         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 508         cmd_init($url, $path);
 509         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 510             if $_authors;
 511         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 512 }
 513
 514 sub cmd_init {
 515         if (defined $_stdlayout) {
 516                 $_trunk = 'trunk' if (!defined $_trunk);
 517                 @_tags = 'tags' if (! @_tags);
 518                 @_branches = 'branches' if (! @_branches);
 519         }
 520         if (defined $_trunk || @_branches || @_tags) {
 521                 return cmd_multi_init(@_);
 522         }
 523         my $url = shift or die "SVN repository location required ",
 524                                "as a command-line argument\n";
 525         $url = canonicalize_url($url);
 526         init_subdir(@_);
 527         do_git_init_db();
 528
 529         if ($Git::SVN::_minimize_url eq 'unset') {
 530                 $Git::SVN::_minimize_url = 0;
 531         }
 532
 533         Git::SVN->init($url);
 534 }
 535
 536 sub cmd_fetch {
 537         if (grep /^\d+=./, @_) {
 538                 die "'<rev>=<commit>' fetch arguments are ",
 539                     "no longer supported.\n";
 540         }
 541         my ($remote) = @_;
 542         if (@_ > 1) {
 543                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 544         }
 545         $Git::SVN::no_reuse_existing = undef;
 546         if ($_fetch_parent) {
 547                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 548                 unless ($gs) {
 549                         die "Unable to determine upstream SVN information from ",
 550                             "working tree history\n";
 551                 }
 552                 # just fetch, don't checkout.
 553                 $_no_checkout = 'true';
 554                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 555         } elsif ($_fetch_all) {
 556                 cmd_multi_fetch();
 557         } else {
 558                 $remote ||= $Git::SVN::default_repo_id;
 559                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 560         }
 561 }
 562
 563 sub cmd_set_tree {
 564         my (@commits) = @_;
 565         if ($_stdin || !@commits) {
 566                 print "Reading from stdin...\n";
 567                 @commits = ();
 568                 while (<STDIN>) {
 569                         if (/\b($sha1_short)\b/o) {
 570                                 unshift @commits, $1;
 571                         }
 572                 }
 573         }
 574         my @revs;
 575         foreach my $c (@commits) {
 576                 my @tmp = command('rev-parse',$c);
 577                 if (scalar @tmp == 1) {
 578                         push @revs, $tmp[0];
 579                 } elsif (scalar @tmp > 1) {
 580                         push @revs, reverse(command('rev-list',@tmp));
 581                 } else {
 582                         fatal "Failed to rev-parse $c";
 583                 }
 584         }
 585         my $gs = Git::SVN->new;
 586         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 587         $gs->fetch;
 588         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 589                 fatal "There are new revisions that were fetched ",
 590                       "and need to be merged (or acknowledged) ",
 591                       "before committing.\nlast rev: $r_last\n",
 592                       " current: $gs->{last_rev}";
 593         }
 594         $gs->set_tree($_) foreach @revs;
 595         print "Done committing ",scalar @revs," revisions to SVN\n";
 596         unlink $gs->{index};
 597 }
 598
 599 sub split_merge_info_range {
 600         my ($range) = @_;
 601         if ($range =~ /(\d+)-(\d+)/) {
 602                 return (int($1), int($2));
 603         } else {
 604                 return (int($range), int($range));
 605         }
 606 }
 607
 608 sub combine_ranges {
 609         my ($in) = @_;
 610
 611         my @fnums = ();
 612         my @arr = split(/,/, $in);
 613         for my $element (@arr) {
 614                 my ($start, $end) = split_merge_info_range($element);
 615                 push @fnums, $start;
 616         }
 617
 618         my @sorted = @arr [ sort {
 619                 $fnums[$a] <=> $fnums[$b]
 620         } 0..$#arr ];
 621
 622         my @return = ();
 623         my $last = -1;
 624         my $first = -1;
 625         for my $element (@sorted) {
 626                 my ($start, $end) = split_merge_info_range($element);
 627
 628                 if ($last == -1) {
 629                         $first = $start;
 630                         $last = $end;
 631                         next;
 632                 }
 633                 if ($start <= $last+1) {
 634                         if ($end > $last) {
 635                                 $last = $end;
 636                         }
 637                         next;
 638                 }
 639                 if ($first == $last) {
 640                         push @return, "$first";
 641                 } else {
 642                         push @return, "$first-$last";
 643                 }
 644                 $first = $start;
 645                 $last = $end;
 646         }
 647
 648         if ($first != -1) {
 649                 if ($first == $last) {
 650                         push @return, "$first";
 651                 } else {
 652                         push @return, "$first-$last";
 653                 }
 654         }
 655
 656         return join(',', @return);
 657 }
 658
 659 sub merge_revs_into_hash {
 660         my ($hash, $minfo) = @_;
 661         my @lines = split(' ', $minfo);
 662
 663         for my $line (@lines) {
 664                 my ($branchpath, $revs) = split(/:/, $line);
 665
 666                 if (exists($hash->{$branchpath})) {
 667                         # Merge the two revision sets
 668                         my $combined = "$hash->{$branchpath},$revs";
 669                         $hash->{$branchpath} = combine_ranges($combined);
 670                 } else {
 671                         # Just do range combining for consolidation
 672                         $hash->{$branchpath} = combine_ranges($revs);
 673                 }
 674         }
 675 }
 676
 677 sub merge_merge_info {
 678         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 679         my %result_hash = ();
 680
 681         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 682         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 683
 684         delete $result_hash{$ignore_branch} if $ignore_branch;
 685
 686         my $result = '';
 687         # Sort below is for consistency's sake
 688         for my $branchname (sort keys(%result_hash)) {
 689                 my $revlist = $result_hash{$branchname};
 690                 $result .= "$branchname:$revlist\n"
 691         }
 692         return $result;
 693 }
 694
 695 sub populate_merge_info {
 696         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 697
 698         my %parentshash;
 699         read_commit_parents(\%parentshash, $d);
 700         my @parents = @{$parentshash{$d}};
 701         if ($#parents > 0) {
 702                 # Merge commit
 703                 my $all_parents_ok = 1;
 704                 my $aggregate_mergeinfo = '';
 705                 my $rooturl = $gs->repos_root;
 706                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 707
 708                 if (defined($rewritten_parent)) {
 709                         # Replace first parent with newly-rewritten version
 710                         shift @parents;
 711                         unshift @parents, $rewritten_parent;
 712                 }
 713
 714                 foreach my $parent (@parents) {
 715                         my ($branchurl, $svnrev, $paruuid) =
 716                                 cmt_metadata($parent);
 717
 718                         unless (defined($svnrev)) {
 719                                 # Should have been caught be preflight check
 720                                 fatal "merge commit $d has ancestor $parent, but that change "
 721                      ."does not have git-svn metadata!";
 722                         }
 723                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 724                                 fatal "commit $parent git-svn metadata changed mid-run!";
 725                         }
 726                         my $branchpath = $1;
 727
 728                         my $ra = Git::SVN::Ra->new($branchurl);
 729                         my (undef, undef, $props) =
 730                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 731                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 732                         unless (defined $par_mergeinfo) {
 733                                 $par_mergeinfo = '';
 734                         }
 735                         # Merge previous mergeinfo values
 736                         $aggregate_mergeinfo =
 737                                 merge_merge_info($aggregate_mergeinfo,
 738                                                                 $par_mergeinfo,
 739                                                                 $target_branch);
 740
 741                         next if $parent eq $parents[0]; # Skip first parent
 742                         # Add new changes being placed in tree by merge
 743                         my @cmd = (qw/rev-list --reverse/,
 744                                            $parent, qw/--not/);
 745                         foreach my $par (@parents) {
 746                                 unless ($par eq $parent) {
 747                                         push @cmd, $par;
 748                                 }
 749                         }
 750                         my @revsin = ();
 751                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 752                         while (<$revlist>) {
 753                                 my $irev = $_;
 754                                 chomp $irev;
 755                                 my (undef, $csvnrev, undef) =
 756                                         cmt_metadata($irev);
 757                                 unless (defined $csvnrev) {
 758                                         # A child is missing SVN annotations...
 759                                         # this might be OK, or might not be.
 760                                         warn "W:child $irev is merged into revision "
 761                                                  ."$d but does not have git-svn metadata. "
 762                                                  ."This means git-svn cannot determine the "
 763                                                  ."svn revision numbers to place into the "
 764                                                  ."svn:mergeinfo property. You must ensure "
 765                                                  ."a branch is entirely committed to "
 766                                                  ."SVN before merging it in order for "
 767                                                  ."svn:mergeinfo population to function "
 768                                                  ."properly";
 769                                 }
 770                                 push @revsin, $csvnrev;
 771                         }
 772                         command_close_pipe($revlist, $ctx);
 773
 774                         last unless $all_parents_ok;
 775
 776                         # We now have a list of all SVN revnos which are
 777                         # merged by this particular parent. Integrate them.
 778                         next if $#revsin == -1;
 779                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 780                         $aggregate_mergeinfo =
 781                                 merge_merge_info($aggregate_mergeinfo,
 782                                                                 $newmergeinfo,
 783                                                                 $target_branch);
 784                 }
 785                 if ($all_parents_ok and $aggregate_mergeinfo) {
 786                         return $aggregate_mergeinfo;
 787                 }
 788         }
 789
 790         return undef;
 791 }
 792
 793 sub dcommit_rebase {
 794         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 795         my @diff;
 796
 797         if ($svn_error) {
 798                 print STDERR "\nERROR from SVN:\n",
 799                                 $svn_error->expanded_message, "\n";
 800         }
 801         unless ($_no_rebase) {
 802                 # we always want to rebase against the current HEAD,
 803                 # not any head that was passed to us
 804                 @diff = command('diff-tree', $current,
 805                            $fetched_ref, '--');
 806                 my @finish;
 807                 if (@diff) {
 808                         @finish = rebase_cmd();
 809                         print STDERR "W: $current and ", $fetched_ref,
 810                                      " differ, using @finish:\n",
 811                                      join("\n", @diff), "\n";
 812                 } elsif ($is_last) {
 813                         print "No changes between ", $current, " and ",
 814                               $fetched_ref,
 815                               "\nResetting to the latest ",
 816                               $fetched_ref, "\n";
 817                         @finish = qw/reset --mixed/;
 818                 }
 819                 command_noisy(@finish, $fetched_ref) if @finish;
 820         }
 821         if ($svn_error) {
 822                 die "ERROR: Not all changes have been committed into SVN"
 823                         .($_no_rebase ? ".\n" : ", however the committed\n"
 824                         ."ones (if any) seem to be successfully integrated "
 825                         ."into the working tree.\n")
 826                         ."Please see the above messages for details.\n";
 827         }
 828         return @diff;
 829 }
 830
 831 sub cmd_dcommit {
 832         my $head = shift;
 833         command_noisy(qw/update-index --refresh/);
 834         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 835                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 836                 . "or stash them with `git stash'.\n";
 837         $head ||= 'HEAD';
 838
 839         my $old_head;
 840         if ($head ne 'HEAD') {
 841                 $old_head = eval {
 842                         command_oneline([qw/symbolic-ref -q HEAD/])
 843                 };
 844                 if ($old_head) {
 845                         $old_head =~ s{^refs/heads/}{};
 846                 } else {
 847                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 848                 }
 849                 command(['checkout', $head], STDERR => 0);
 850         }
 851
 852         my @refs;
 853         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 854         unless ($gs) {
 855                 die "Unable to determine upstream SVN information from ",
 856                     "$head history.\nPerhaps the repository is empty.";
 857         }
 858
 859         if (defined $_commit_url) {
 860                 $url = $_commit_url;
 861         } else {
 862                 $url = eval { command_oneline('config', '--get',
 863                               "svn-remote.$gs->{repo_id}.commiturl") };
 864                 if (!$url) {
 865                         $url = $gs->full_pushurl
 866                 }
 867         }
 868
 869         my $last_rev = $_revision if defined $_revision;
 870         if ($url) {
 871                 print "Committing to $url ...\n";
 872         }
 873         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 874         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 875                 warn "Attempting to commit more than one change while ",
 876                      "--no-rebase is enabled.\n",
 877                      "If these changes depend on each other, re-running ",
 878                      "without --no-rebase may be required."
 879         }
 880
 881         if (defined $_interactive){
 882                 my $ask_default = "y";
 883                 foreach my $d (@$linear_refs){
 884                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 885                         while (<$fh>){
 886                                 print $_;
 887                         }
 888                         command_close_pipe($fh, $ctx);
 889                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 890                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 891                                  default => $ask_default);
 892                         die "Commit this patch reply required" unless defined $_;
 893                         if (/^[nq]/i) {
 894                                 exit(0);
 895                         } elsif (/^a/i) {
 896                                 last;
 897                         }
 898                 }
 899         }
 900
 901         my $expect_url = $url;
 902
 903         my $push_merge_info = eval {
 904                 command_oneline(qw/config --get svn.pushmergeinfo/)
 905                 };
 906         if (not defined($push_merge_info)
 907                         or $push_merge_info eq "false"
 908                         or $push_merge_info eq "no"
 909                         or $push_merge_info eq "never") {
 910                 $push_merge_info = 0;
 911         }
 912
 913         unless (defined($_merge_info) || ! $push_merge_info) {
 914                 # Preflight check of changes to ensure no issues with mergeinfo
 915                 # This includes check for uncommitted-to-SVN parents
 916                 # (other than the first parent, which we will handle),
 917                 # information from different SVN repos, and paths
 918                 # which are not underneath this repository root.
 919                 my $rooturl = $gs->repos_root;
 920                 foreach my $d (@$linear_refs) {
 921                         my %parentshash;
 922                         read_commit_parents(\%parentshash, $d);
 923                         my @realparents = @{$parentshash{$d}};
 924                         if ($#realparents > 0) {
 925                                 # Merge commit
 926                                 shift @realparents; # Remove/ignore first parent
 927                                 foreach my $parent (@realparents) {
 928                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 929                                         unless (defined $paruuid) {
 930                                                 # A parent is missing SVN annotations...
 931                                                 # abort the whole operation.
 932                                                 fatal "$parent is merged into revision $d, "
 933                                                          ."but does not have git-svn metadata. "
 934                                                          ."Either dcommit the branch or use a "
 935                                                          ."local cherry-pick, FF merge, or rebase "
 936                                                          ."instead of an explicit merge commit.";
 937                                         }
 938
 939                                         unless ($paruuid eq $uuid) {
 940                                                 # Parent has SVN metadata from different repository
 941                                                 fatal "merge parent $parent for change $d has "
 942                                                          ."git-svn uuid $paruuid, while current change "
 943                                                          ."has uuid $uuid!";
 944                                         }
 945
 946                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 947                                                 # This branch is very strange indeed.
 948                                                 fatal "merge parent $parent for $d is on branch "
 949                                                          ."$branchurl, which is not under the "
 950                                                          ."git-svn root $rooturl!";
 951                                         }
 952                                 }
 953                         }
 954                 }
 955         }
 956
 957         my $rewritten_parent;
 958         my $current_head = command_oneline(qw/rev-parse HEAD/);
 959         Git::SVN::remove_username($expect_url);
 960         if (defined($_merge_info)) {
 961                 $_merge_info =~ tr{ }{\n};
 962         }
 963         while (1) {
 964                 my $d = shift @$linear_refs or last;
 965                 unless (defined $last_rev) {
 966                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 967                         unless (defined $last_rev) {
 968                                 fatal "Unable to extract revision information ",
 969                                       "from commit $d~1";
 970                         }
 971                 }
 972                 if ($_dry_run) {
 973                         print "diff-tree $d~1 $d\n";
 974                 } else {
 975                         my $cmt_rev;
 976
 977                         unless (defined($_merge_info) || ! $push_merge_info) {
 978                                 $_merge_info = populate_merge_info($d, $gs,
 979                                                              $uuid,
 980                                                              $linear_refs,
 981                                                              $rewritten_parent);
 982                         }
 983
 984                         my %ed_opts = ( r => $last_rev,
 985                                         log => get_commit_entry($d)->{log},
 986                                         ra => Git::SVN::Ra->new($url),
 987                                         config => SVN::Core::config_get_config(
 988                                                 $Git::SVN::Ra::config_dir
 989                                         ),
 990                                         tree_a => "$d~1",
 991                                         tree_b => $d,
 992                                         editor_cb => sub {
 993                                                print "Committed r$_[0]\n";
 994                                                $cmt_rev = $_[0];
 995                                         },
 996                                         mergeinfo => $_merge_info,
 997                                         svn_path => '');
 998
 999                         my $err_handler = $SVN::Error::handler;
1000                         $SVN::Error::handler = sub {
1001                                 my $err = shift;
1002                                 dcommit_rebase(1, $current_head, $gs->refname,
1003                                         $err);
1004                         };
1005
1006                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1007                                 print "No changes\n$d~1 == $d\n";
1008                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1009                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1010                                                                $parents->{$d};
1011                         }
1012                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1013                         $SVN::Error::handler = $err_handler;
1014                         $last_rev = $cmt_rev;
1015                         next if $_no_rebase;
1016
1017                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1018                                                 $gs->refname, undef);
1019
1020                         $rewritten_parent = command_oneline(qw/rev-parse/,
1021                                                         $gs->refname);
1022
1023                         if (@diff) {
1024                                 $current_head = command_oneline(qw/rev-parse
1025                                                                 HEAD/);
1026                                 @refs = ();
1027                                 my ($url_, $rev_, $uuid_, $gs_) =
1028                                               working_head_info('HEAD', \@refs);
1029                                 my ($linear_refs_, $parents_) =
1030                                               linearize_history($gs_, \@refs);
1031                                 if (scalar(@$linear_refs) !=
1032                                     scalar(@$linear_refs_)) {
1033                                         fatal "# of revisions changed ",
1034                                           "\nbefore:\n",
1035                                           join("\n", @$linear_refs),
1036                                           "\n\nafter:\n",
1037                                           join("\n", @$linear_refs_), "\n",
1038                                           'If you are attempting to commit ',
1039                                           "merges, try running:\n\t",
1040                                           'git rebase --interactive',
1041                                           '--preserve-merges ',
1042                                           $gs->refname,
1043                                           "\nBefore dcommitting";
1044                                 }
1045                                 if ($url_ ne $expect_url) {
1046                                         if ($url_ eq $gs->metadata_url) {
1047                                                 print
1048                                                   "Accepting rewritten URL:",
1049                                                   " $url_\n";
1050                                         } else {
1051                                                 fatal
1052                                                   "URL mismatch after rebase:",
1053                                                   " $url_ != $expect_url";
1054                                         }
1055                                 }
1056                                 if ($uuid_ ne $uuid) {
1057                                         fatal "uuid mismatch after rebase: ",
1058                                               "$uuid_ != $uuid";
1059                                 }
1060                                 # remap parents
1061                                 my (%p, @l, $i);
1062                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1063                                         my $new = $linear_refs_->[$i] or next;
1064                                         $p{$new} =
1065                                                 $parents->{$linear_refs->[$i]};
1066                                         push @l, $new;
1067                                 }
1068                                 $parents = \%p;
1069                                 $linear_refs = \@l;
1070                                 undef $last_rev;
1071                         }
1072                 }
1073         }
1074
1075         if ($old_head) {
1076                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1077                 my $new_is_symbolic = eval {
1078                         command_oneline(qw/symbolic-ref -q HEAD/);
1079                 };
1080                 if ($new_is_symbolic) {
1081                         print "dcommitted the branch ", $head, "\n";
1082                 } else {
1083                         print "dcommitted on a detached HEAD because you gave ",
1084                               "a revision argument.\n",
1085                               "The rewritten commit is: ", $new_head, "\n";
1086                 }
1087                 command(['checkout', $old_head], STDERR => 0);
1088         }
1089
1090         unlink $gs->{index};
1091 }
1092
1093 sub cmd_branch {
1094         my ($branch_name, $head) = @_;
1095
1096         unless (defined $branch_name && length $branch_name) {
1097                 die(($_tag ? "tag" : "branch") . " name required\n");
1098         }
1099         $head ||= 'HEAD';
1100
1101         my (undef, $rev, undef, $gs) = working_head_info($head);
1102         my $src = $gs->full_pushurl;
1103
1104         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1105         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1106         my $glob;
1107         if ($#{$allglobs} == 0) {
1108                 $glob = $allglobs->[0];
1109         } else {
1110                 unless(defined $_branch_dest) {
1111                         die "Multiple ",
1112                             $_tag ? "tag" : "branch",
1113                             " paths defined for Subversion repository.\n",
1114                             "You must specify where you want to create the ",
1115                             $_tag ? "tag" : "branch",
1116                             " with the --destination argument.\n";
1117                 }
1118                 foreach my $g (@{$allglobs}) {
1119                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1120                         if ($_branch_dest =~ /$re/) {
1121                                 $glob = $g;
1122                                 last;
1123                         }
1124                 }
1125                 unless (defined $glob) {
1126                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1127                         foreach my $g (@{$allglobs}) {
1128                                 $g->{path}->{left} =~ /$dest_re/ or next;
1129                                 if (defined $glob) {
1130                                         die "Ambiguous destination: ",
1131                                             $_branch_dest, "\nmatches both '",
1132                                             $glob->{path}->{left}, "' and '",
1133                                             $g->{path}->{left}, "'\n";
1134                                 }
1135                                 $glob = $g;
1136                         }
1137                         unless (defined $glob) {
1138                                 die "Unknown ",
1139                                     $_tag ? "tag" : "branch",
1140                                     " destination $_branch_dest\n";
1141                         }
1142                 }
1143         }
1144         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1145         my $url;
1146         if (defined $_commit_url) {
1147                 $url = $_commit_url;
1148         } else {
1149                 $url = eval { command_oneline('config', '--get',
1150                         "svn-remote.$gs->{repo_id}.commiturl") };
1151                 if (!$url) {
1152                         $url = $remote->{pushurl} || $remote->{url};
1153                 }
1154         }
1155         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1156
1157         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1158                 $src=~s/^http:/https:/;
1159         }
1160
1161         ::_req_svn();
1162
1163         my $ctx = SVN::Client->new(
1164                 auth    => Git::SVN::Ra::_auth_providers(),
1165                 log_msg => sub {
1166                         ${ $_[0] } = defined $_message
1167                                 ? $_message
1168                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1169                                 . $branch_name;
1170                 },
1171         );
1172
1173         eval {
1174                 $ctx->ls($dst, 'HEAD', 0);
1175         } and die "branch ${branch_name} already exists\n";
1176
1177         if ($_parents) {
1178                 mk_parent_dirs($ctx, $dst);
1179         }
1180
1181         print "Copying ${src} at r${rev} to ${dst}...\n";
1182         $ctx->copy($src, $rev, $dst)
1183                 unless $_dry_run;
1184
1185         $gs->fetch_all;
1186 }
1187
1188 sub mk_parent_dirs {
1189         my ($ctx, $parent) = @_;
1190         $parent =~ s{/[^/]*$}{};
1191
1192         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1193                 mk_parent_dirs($ctx, $parent);
1194                 print "Creating parent folder ${parent} ...\n";
1195                 $ctx->mkdir($parent) unless $_dry_run;
1196         }
1197 }
1198
1199 sub cmd_find_rev {
1200         my $revision_or_hash = shift or die "SVN or git revision required ",
1201                                             "as a command-line argument\n";
1202         my $result;
1203         if ($revision_or_hash =~ /^r\d+$/) {
1204                 my $head = shift;
1205                 $head ||= 'HEAD';
1206                 my @refs;
1207                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1208                 unless ($gs) {
1209                         die "Unable to determine upstream SVN information from ",
1210                             "$head history\n";
1211                 }
1212                 my $desired_revision = substr($revision_or_hash, 1);
1213                 if ($_before) {
1214                         $result = $gs->find_rev_before($desired_revision, 1);
1215                 } elsif ($_after) {
1216                         $result = $gs->find_rev_after($desired_revision, 1);
1217                 } else {
1218                         $result = $gs->rev_map_get($desired_revision, $uuid);
1219                 }
1220         } else {
1221                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1222                 $result = $rev;
1223         }
1224         print "$result\n" if $result;
1225 }
1226
1227 sub auto_create_empty_directories {
1228         my ($gs) = @_;
1229         my $var = eval { command_oneline('config', '--get', '--bool',
1230                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1231         # By default, create empty directories by consulting the unhandled log,
1232         # but allow setting it to 'false' to skip it.
1233         return !($var && $var eq 'false');
1234 }
1235
1236 sub cmd_rebase {
1237         command_noisy(qw/update-index --refresh/);
1238         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1239         unless ($gs) {
1240                 die "Unable to determine upstream SVN information from ",
1241                     "working tree history\n";
1242         }
1243         if ($_dry_run) {
1244                 print "Remote Branch: " . $gs->refname . "\n";
1245                 print "SVN URL: " . $url . "\n";
1246                 return;
1247         }
1248         if (command(qw/diff-index HEAD --/)) {
1249                 print STDERR "Cannot rebase with uncommitted changes:\n";
1250                 command_noisy('status');
1251                 exit 1;
1252         }
1253         unless ($_local) {
1254                 # rebase will checkout for us, so no need to do it explicitly
1255                 $_no_checkout = 'true';
1256                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1257         }
1258         command_noisy(rebase_cmd(), $gs->refname);
1259         if (auto_create_empty_directories($gs)) {
1260                 $gs->mkemptydirs;
1261         }
1262 }
1263
1264 sub cmd_show_ignore {
1265         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1266         $gs ||= Git::SVN->new;
1267         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1268         $gs->prop_walk($gs->path, $r, sub {
1269                 my ($gs, $path, $props) = @_;
1270                 print STDOUT "\n# $path\n";
1271                 my $s = $props->{'svn:ignore'} or return;
1272                 $s =~ s/[\r\n]+/\n/g;
1273                 $s =~ s/^\n+//;
1274                 chomp $s;
1275                 $s =~ s#^#$path#gm;
1276                 print STDOUT "$s\n";
1277         });
1278 }
1279
1280 sub cmd_show_externals {
1281         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1282         $gs ||= Git::SVN->new;
1283         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1284         $gs->prop_walk($gs->path, $r, sub {
1285                 my ($gs, $path, $props) = @_;
1286                 print STDOUT "\n# $path\n";
1287                 my $s = $props->{'svn:externals'} or return;
1288                 $s =~ s/[\r\n]+/\n/g;
1289                 chomp $s;
1290                 $s =~ s#^#$path#gm;
1291                 print STDOUT "$s\n";
1292         });
1293 }
1294
1295 sub cmd_create_ignore {
1296         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1297         $gs ||= Git::SVN->new;
1298         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1299         $gs->prop_walk($gs->path, $r, sub {
1300                 my ($gs, $path, $props) = @_;
1301                 # $path is of the form /path/to/dir/
1302                 $path = '.' . $path;
1303                 # SVN can have attributes on empty directories,
1304                 # which git won't track
1305                 mkpath([$path]) unless -d $path;
1306                 my $ignore = $path . '.gitignore';
1307                 my $s = $props->{'svn:ignore'} or return;
1308                 open(GITIGNORE, '>', $ignore)
1309                   or fatal("Failed to open `$ignore' for writing: $!");
1310                 $s =~ s/[\r\n]+/\n/g;
1311                 $s =~ s/^\n+//;
1312                 chomp $s;
1313                 # Prefix all patterns so that the ignore doesn't apply
1314                 # to sub-directories.
1315                 $s =~ s#^#/#gm;
1316                 print GITIGNORE "$s\n";
1317                 close(GITIGNORE)
1318                   or fatal("Failed to close `$ignore': $!");
1319                 command_noisy('add', '-f', $ignore);
1320         });
1321 }
1322
1323 sub cmd_mkdirs {
1324         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1325         $gs ||= Git::SVN->new;
1326         $gs->mkemptydirs($_revision);
1327 }
1328
1329 # get_svnprops(PATH)
1330 # ------------------
1331 # Helper for cmd_propget and cmd_proplist below.
1332 sub get_svnprops {
1333         my $path = shift;
1334         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1335         $gs ||= Git::SVN->new;
1336
1337         # prefix THE PATH by the sub-directory from which the user
1338         # invoked us.
1339         $path = $cmd_dir_prefix . $path;
1340         fatal("No such file or directory: $path") unless -e $path;
1341         my $is_dir = -d $path ? 1 : 0;
1342         $path = join_paths($gs->path, $path);
1343
1344         # canonicalize the path (otherwise libsvn will abort or fail to
1345         # find the file)
1346         $path = canonicalize_path($path);
1347
1348         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1349         my $props;
1350         if ($is_dir) {
1351                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1352         }
1353         else {
1354                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1355         }
1356         return $props;
1357 }
1358
1359 # cmd_propget (PROP, PATH)
1360 # ------------------------
1361 # Print the SVN property PROP for PATH.
1362 sub cmd_propget {
1363         my ($prop, $path) = @_;
1364         $path = '.' if not defined $path;
1365         usage(1) if not defined $prop;
1366         my $props = get_svnprops($path);
1367         if (not defined $props->{$prop}) {
1368                 fatal("`$path' does not have a `$prop' SVN property.");
1369         }
1370         print $props->{$prop} . "\n";
1371 }
1372
1373 # cmd_proplist (PATH)
1374 # -------------------
1375 # Print the list of SVN properties for PATH.
1376 sub cmd_proplist {
1377         my $path = shift;
1378         $path = '.' if not defined $path;
1379         my $props = get_svnprops($path);
1380         print "Properties on '$path':\n";
1381         foreach (sort keys %{$props}) {
1382                 print "  $_\n";
1383         }
1384 }
1385
1386 sub cmd_multi_init {
1387         my $url = shift;
1388         unless (defined $_trunk || @_branches || @_tags) {
1389                 usage(1);
1390         }
1391
1392         $_prefix = 'origin/' unless defined $_prefix;
1393         if (defined $url) {
1394                 $url = canonicalize_url($url);
1395                 init_subdir(@_);
1396         }
1397         do_git_init_db();
1398         if (defined $_trunk) {
1399                 $_trunk =~ s#^/+##;
1400                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1401                 # try both old-style and new-style lookups:
1402                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1403                 unless ($gs_trunk) {
1404                         my ($trunk_url, $trunk_path) =
1405                                               complete_svn_url($url, $_trunk);
1406                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1407                                                    undef, $trunk_ref);
1408                 }
1409         }
1410         return unless @_branches || @_tags;
1411         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1412         foreach my $path (@_branches) {
1413                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1414         }
1415         foreach my $path (@_tags) {
1416                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1417         }
1418 }
1419
1420 sub cmd_multi_fetch {
1421         $Git::SVN::no_reuse_existing = undef;
1422         my $remotes = Git::SVN::read_all_remotes();
1423         foreach my $repo_id (sort keys %$remotes) {
1424                 if ($remotes->{$repo_id}->{url}) {
1425                         Git::SVN::fetch_all($repo_id, $remotes);
1426                 }
1427         }
1428 }
1429
1430 # this command is special because it requires no metadata
1431 sub cmd_commit_diff {
1432         my ($ta, $tb, $url) = @_;
1433         my $usage = "usage: $0 commit-diff -r<revision> ".
1434                     "<tree-ish> <tree-ish> [<URL>]";
1435         fatal($usage) if (!defined $ta || !defined $tb);
1436         my $svn_path = '';
1437         if (!defined $url) {
1438                 my $gs = eval { Git::SVN->new };
1439                 if (!$gs) {
1440                         fatal("Needed URL or usable git-svn --id in ",
1441                               "the command-line\n", $usage);
1442                 }
1443                 $url = $gs->url;
1444                 $svn_path = $gs->path;
1445         }
1446         unless (defined $_revision) {
1447                 fatal("-r|--revision is a required argument\n", $usage);
1448         }
1449         if (defined $_message && defined $_file) {
1450                 fatal("Both --message/-m and --file/-F specified ",
1451                       "for the commit message.\n",
1452                       "I have no idea what you mean");
1453         }
1454         if (defined $_file) {
1455                 $_message = file_to_s($_file);
1456         } else {
1457                 $_message ||= get_commit_entry($tb)->{log};
1458         }
1459         my $ra ||= Git::SVN::Ra->new($url);
1460         my $r = $_revision;
1461         if ($r eq 'HEAD') {
1462                 $r = $ra->get_latest_revnum;
1463         } elsif ($r !~ /^\d+$/) {
1464                 die "revision argument: $r not understood by git-svn\n";
1465         }
1466         my %ed_opts = ( r => $r,
1467                         log => $_message,
1468                         ra => $ra,
1469                         tree_a => $ta,
1470                         tree_b => $tb,
1471                         editor_cb => sub { print "Committed r$_[0]\n" },
1472                         svn_path => $svn_path );
1473         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1474                 print "No changes\n$ta == $tb\n";
1475         }
1476 }
1477
1478
1479 sub cmd_info {
1480         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1481         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1482         if (exists $_[1]) {
1483                 die "Too many arguments specified\n";
1484         }
1485
1486         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1487
1488         if (!$file_type && !$diff_status) {
1489                 print STDERR "svn: '$path' is not under version control\n";
1490                 exit 1;
1491         }
1492
1493         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1494         unless ($gs) {
1495                 die "Unable to determine upstream SVN information from ",
1496                     "working tree history\n";
1497         }
1498
1499         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1500         $path = "." if $path eq "";
1501
1502         my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1503
1504         if ($_url) {
1505                 print "$full_url\n";
1506                 return;
1507         }
1508
1509         my $result = "Path: $path\n";
1510         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1511         $result .= "URL: $full_url\n";
1512
1513         eval {
1514                 my $repos_root = $gs->repos_root;
1515                 Git::SVN::remove_username($repos_root);
1516                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1517         };
1518         if ($@) {
1519                 $result .= "Repository Root: (offline)\n";
1520         }
1521         ::_req_svn();
1522         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1523                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1524         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1525
1526         $result .= "Node Kind: " .
1527                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1528
1529         my $schedule = $diff_status eq "A"
1530                        ? "add"
1531                        : ($diff_status eq "D" ? "delete" : "normal");
1532         $result .= "Schedule: $schedule\n";
1533
1534         if ($diff_status eq "A") {
1535                 print $result, "\n";
1536                 return;
1537         }
1538
1539         my ($lc_author, $lc_rev, $lc_date_utc);
1540         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1541         my $log = command_output_pipe(@args);
1542         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1543         while (<$log>) {
1544                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1545                         $lc_author = $1;
1546                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1547                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1548                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1549                 }
1550         }
1551         close $log;
1552
1553         Git::SVN::Log::set_local_timezone();
1554
1555         $result .= "Last Changed Author: $lc_author\n";
1556         $result .= "Last Changed Rev: $lc_rev\n";
1557         $result .= "Last Changed Date: " .
1558                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1559
1560         if ($file_type ne "dir") {
1561                 my $text_last_updated_date =
1562                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1563                 $result .=
1564                     "Text Last Updated: " .
1565                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1566                     "\n";
1567                 my $checksum;
1568                 if ($diff_status eq "D") {
1569                         my ($fh, $ctx) =
1570                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1571                         if ($file_type eq "link") {
1572                                 my $file_name = <$fh>;
1573                                 $checksum = md5sum("link $file_name");
1574                         } else {
1575                                 $checksum = md5sum($fh);
1576                         }
1577                         command_close_pipe($fh, $ctx);
1578                 } elsif ($file_type eq "link") {
1579                         my $file_name =
1580                             command(qw(cat-file blob), "HEAD:$path");
1581                         $checksum =
1582                             md5sum("link " . $file_name);
1583                 } else {
1584                         open FILE, "<", $path or die $!;
1585                         $checksum = md5sum(\*FILE);
1586                         close FILE or die $!;
1587                 }
1588                 $result .= "Checksum: " . $checksum . "\n";
1589         }
1590
1591         print $result, "\n";
1592 }
1593
1594 sub cmd_reset {
1595         my $target = shift || $_revision or die "SVN revision required\n";
1596         $target = $1 if $target =~ /^r(\d+)$/;
1597         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1598         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1599         unless ($gs) {
1600                 die "Unable to determine upstream SVN information from ".
1601                     "history\n";
1602         }
1603         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1604         die "Cannot find SVN revision $target\n" unless defined($c);
1605         $gs->rev_map_set($r, $c, 'reset', $uuid);
1606         print "r$r = $c ($gs->{ref_id})\n";
1607 }
1608
1609 sub cmd_gc {
1610         if (!can_compress()) {
1611                 warn "Compress::Zlib could not be found; unhandled.log " .
1612                      "files will not be compressed.\n";
1613         }
1614         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1615 }
1616
1617 ########################### utility functions #########################
1618
1619 sub rebase_cmd {
1620         my @cmd = qw/rebase/;
1621         push @cmd, '-v' if $_verbose;
1622         push @cmd, qw/--merge/ if $_merge;
1623         push @cmd, "--strategy=$_strategy" if $_strategy;
1624         push @cmd, "--preserve-merges" if $_preserve_merges;
1625         @cmd;
1626 }
1627
1628 sub post_fetch_checkout {
1629         return if $_no_checkout;
1630         return if verify_ref('HEAD^0');
1631         my $gs = $Git::SVN::_head or return;
1632
1633         # look for "trunk" ref if it exists
1634         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1635         my $fetch = $remote->{fetch};
1636         if ($fetch) {
1637                 foreach my $p (keys %$fetch) {
1638                         basename($fetch->{$p}) eq 'trunk' or next;
1639                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1640                         last;
1641                 }
1642         }
1643
1644         command_noisy(qw(update-ref HEAD), $gs->refname);
1645         return unless verify_ref('HEAD^0');
1646
1647         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1648         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1649         return if -f $index;
1650
1651         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1652         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1653         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1654         print STDERR "Checked out HEAD:\n  ",
1655                      $gs->full_url, " r", $gs->last_rev, "\n";
1656         if (auto_create_empty_directories($gs)) {
1657                 $gs->mkemptydirs($gs->last_rev);
1658         }
1659 }
1660
1661 sub complete_svn_url {
1662         my ($url, $path) = @_;
1663         $path = canonicalize_path($path);
1664
1665         # If the path is not a URL...
1666         if ($path !~ m#^[a-z\+]+://#) {
1667                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1668                         fatal("E: '$path' is not a complete URL ",
1669                               "and a separate URL is not specified");
1670                 }
1671                 return ($url, $path);
1672         }
1673         return ($path, '');
1674 }
1675
1676 sub complete_url_ls_init {
1677         my ($ra, $repo_path, $switch, $pfx) = @_;
1678         unless ($repo_path) {
1679                 print STDERR "W: $switch not specified\n";
1680                 return;
1681         }
1682         $repo_path = canonicalize_path($repo_path);
1683         if ($repo_path =~ m#^[a-z\+]+://#) {
1684                 $ra = Git::SVN::Ra->new($repo_path);
1685                 $repo_path = '';
1686         } else {
1687                 $repo_path =~ s#^/+##;
1688                 unless ($ra) {
1689                         fatal("E: '$repo_path' is not a complete URL ",
1690                               "and a separate URL is not specified");
1691                 }
1692         }
1693         my $url = $ra->url;
1694         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1695         my $k = "svn-remote.$gs->{repo_id}.url";
1696         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1697         if ($orig_url && ($orig_url ne $gs->url)) {
1698                 die "$k already set: $orig_url\n",
1699                     "wanted to set to: $gs->url\n";
1700         }
1701         command_oneline('config', $k, $gs->url) unless $orig_url;
1702
1703         my $remote_path = join_paths( $gs->path, $repo_path );
1704         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1705         $remote_path =~ s#^/##g;
1706         $remote_path .= "/*" if $remote_path !~ /\*/;
1707         my ($n) = ($switch =~ /^--(\w+)/);
1708         if (length $pfx && $pfx !~ m#/$#) {
1709                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1710         }
1711         command_noisy('config',
1712                       '--add',
1713                       "svn-remote.$gs->{repo_id}.$n",
1714                       "$remote_path:refs/remotes/$pfx*" .
1715                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1716 }
1717
1718 sub verify_ref {
1719         my ($ref) = @_;
1720         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1721                                { STDERR => 0 }); };
1722 }
1723
1724 sub get_tree_from_treeish {
1725         my ($treeish) = @_;
1726         # $treeish can be a symbolic ref, too:
1727         my $type = command_oneline(qw/cat-file -t/, $treeish);
1728         my $expected;
1729         while ($type eq 'tag') {
1730                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1731         }
1732         if ($type eq 'commit') {
1733                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1734                                                     $treeish))[0];
1735                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1736                 die "Unable to get tree from $treeish\n" unless $expected;
1737         } elsif ($type eq 'tree') {
1738                 $expected = $treeish;
1739         } else {
1740                 die "$treeish is a $type, expected tree, tag or commit\n";
1741         }
1742         return $expected;
1743 }
1744
1745 sub get_commit_entry {
1746         my ($treeish) = shift;
1747         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1748         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1749         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1750         open my $log_fh, '>', $commit_editmsg or croak $!;
1751
1752         my $type = command_oneline(qw/cat-file -t/, $treeish);
1753         if ($type eq 'commit' || $type eq 'tag') {
1754                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1755                                                          $type, $treeish);
1756                 my $in_msg = 0;
1757                 my $author;
1758                 my $saw_from = 0;
1759                 my $msgbuf = "";
1760                 while (<$msg_fh>) {
1761                         if (!$in_msg) {
1762                                 $in_msg = 1 if (/^$/);
1763                                 $author = $1 if (/^author (.*>)/);
1764                         } elsif (/^git-svn-id: /) {
1765                                 # skip this for now, we regenerate the
1766                                 # correct one on re-fetch anyways
1767                                 # TODO: set *:merge properties or like...
1768                         } else {
1769                                 if (/^From:/ || /^Signed-off-by:/) {
1770                                         $saw_from = 1;
1771                                 }
1772                                 $msgbuf .= $_;
1773                         }
1774                 }
1775                 $msgbuf =~ s/\s+$//s;
1776                 if ($Git::SVN::_add_author_from && defined($author)
1777                     && !$saw_from) {
1778                         $msgbuf .= "\n\nFrom: $author";
1779                 }
1780                 print $log_fh $msgbuf or croak $!;
1781                 command_close_pipe($msg_fh, $ctx);
1782         }
1783         close $log_fh or croak $!;
1784
1785         if ($_edit || ($type eq 'tree')) {
1786                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1787                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1788         }
1789         rename $commit_editmsg, $commit_msg or croak $!;
1790         {
1791                 require Encode;
1792                 # SVN requires messages to be UTF-8 when entering the repo
1793                 local $/;
1794                 open $log_fh, '<', $commit_msg or croak $!;
1795                 binmode $log_fh;
1796                 chomp($log_entry{log} = <$log_fh>);
1797
1798                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1799                 my $msg = $log_entry{log};
1800
1801                 eval { $msg = Encode::decode($enc, $msg, 1) };
1802                 if ($@) {
1803                         die "Could not decode as $enc:\n", $msg,
1804                             "\nPerhaps you need to set i18n.commitencoding\n";
1805                 }
1806
1807                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1808                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1809
1810                 $log_entry{log} = $msg;
1811
1812                 close $log_fh or croak $!;
1813         }
1814         unlink $commit_msg;
1815         \%log_entry;
1816 }
1817
1818 sub s_to_file {
1819         my ($str, $file, $mode) = @_;
1820         open my $fd,'>',$file or croak $!;
1821         print $fd $str,"\n" or croak $!;
1822         close $fd or croak $!;
1823         chmod ($mode &~ umask, $file) if (defined $mode);
1824 }
1825
1826 sub file_to_s {
1827         my $file = shift;
1828         open my $fd,'<',$file or croak "$!: file: $file\n";
1829         local $/;
1830         my $ret = <$fd>;
1831         close $fd or croak $!;
1832         $ret =~ s/\s*$//s;
1833         return $ret;
1834 }
1835
1836 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1837 sub load_authors {
1838         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1839         my $log = $cmd eq 'log';
1840         while (<$authors>) {
1841                 chomp;
1842                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1843                 my ($user, $name, $email) = ($1, $2, $3);
1844                 if ($log) {
1845                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1846                 } else {
1847                         $users{$user} = [$name, $email];
1848                 }
1849         }
1850         close $authors or croak $!;
1851 }
1852
1853 # convert GetOpt::Long specs for use by git-config
1854 sub read_git_config {
1855         my $opts = shift;
1856         my @config_only;
1857         foreach my $o (keys %$opts) {
1858                 # if we have mixedCase and a long option-only, then
1859                 # it's a config-only variable that we don't need for
1860                 # the command-line.
1861                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1862                 my $v = $opts->{$o};
1863                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1864                 $key =~ s/-//g;
1865                 my $arg = 'git config';
1866                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1867                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1868                 if (ref $v eq 'ARRAY') {
1869                         chomp(my @tmp = `$arg --get-all svn.$key`);
1870                         @$v = @tmp if @tmp;
1871                 } else {
1872                         chomp(my $tmp = `$arg --get svn.$key`);
1873                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1874                                 $$v = $tmp;
1875                         }
1876                 }
1877         }
1878         delete @$opts{@config_only} if @config_only;
1879 }
1880
1881 sub extract_metadata {
1882         my $id = shift or return (undef, undef, undef);
1883         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1884                                                         \s([a-f\d\-]+)$/ix);
1885         if (!defined $rev || !$uuid || !$url) {
1886                 # some of the original repositories I made had
1887                 # identifiers like this:
1888                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1889         }
1890         return ($url, $rev, $uuid);
1891 }
1892
1893 sub cmt_metadata {
1894         return extract_metadata((grep(/^git-svn-id: /,
1895                 command(qw/cat-file commit/, shift)))[-1]);
1896 }
1897
1898 sub cmt_sha2rev_batch {
1899         my %s2r;
1900         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1901         my $list = shift;
1902
1903         foreach my $sha (@{$list}) {
1904                 my $first = 1;
1905                 my $size = 0;
1906                 print $out $sha, "\n";
1907
1908                 while (my $line = <$in>) {
1909                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1910                                 last;
1911                         } elsif ($first &&
1912                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1913                                 $first = 0;
1914                                 $size = $1;
1915                                 next;
1916                         } elsif ($line =~ /^(git-svn-id: )/) {
1917                                 my (undef, $rev, undef) =
1918                                                       extract_metadata($line);
1919                                 $s2r{$sha} = $rev;
1920                         }
1921
1922                         $size -= length($line);
1923                         last if ($size == 0);
1924                 }
1925         }
1926
1927         command_close_bidi_pipe($pid, $in, $out, $ctx);
1928
1929         return \%s2r;
1930 }
1931
1932 sub working_head_info {
1933         my ($head, $refs) = @_;
1934         my @args = qw/rev-list --first-parent --pretty=medium/;
1935         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
1936         my $hash;
1937         my %max;
1938         while (<$fh>) {
1939                 if ( m{^commit ($::sha1)$} ) {
1940                         unshift @$refs, $hash if $hash and $refs;
1941                         $hash = $1;
1942                         next;
1943                 }
1944                 next unless s{^\s*(git-svn-id:)}{$1};
1945                 my ($url, $rev, $uuid) = extract_metadata($_);
1946                 if (defined $url && defined $rev) {
1947                         next if $max{$url} and $max{$url} < $rev;
1948                         if (my $gs = Git::SVN->find_by_url($url)) {
1949                                 my $c = $gs->rev_map_get($rev, $uuid);
1950                                 if ($c && $c eq $hash) {
1951                                         close $fh; # break the pipe
1952                                         return ($url, $rev, $uuid, $gs);
1953                                 } else {
1954                                         $max{$url} ||= $gs->rev_map_max;
1955                                 }
1956                         }
1957                 }
1958         }
1959         command_close_pipe($fh, $ctx);
1960         (undef, undef, undef, undef);
1961 }
1962
1963 sub read_commit_parents {
1964         my ($parents, $c) = @_;
1965         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1966         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1967         @{$parents->{$c}} = split(/ /, $p);
1968 }
1969
1970 sub linearize_history {
1971         my ($gs, $refs) = @_;
1972         my %parents;
1973         foreach my $c (@$refs) {
1974                 read_commit_parents(\%parents, $c);
1975         }
1976
1977         my @linear_refs;
1978         my %skip = ();
1979         my $last_svn_commit = $gs->last_commit;
1980         foreach my $c (reverse @$refs) {
1981                 next if $c eq $last_svn_commit;
1982                 last if $skip{$c};
1983
1984                 unshift @linear_refs, $c;
1985                 $skip{$c} = 1;
1986
1987                 # we only want the first parent to diff against for linear
1988                 # history, we save the rest to inject when we finalize the
1989                 # svn commit
1990                 my $fp_a = verify_ref("$c~1");
1991                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1992                 if (!$fp_a || !$fp_b) {
1993                         die "Commit $c\n",
1994                             "has no parent commit, and therefore ",
1995                             "nothing to diff against.\n",
1996                             "You should be working from a repository ",
1997                             "originally created by git-svn\n";
1998                 }
1999                 if ($fp_a ne $fp_b) {
2000                         die "$c~1 = $fp_a, however parsing commit $c ",
2001                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2002                 }
2003
2004                 foreach my $p (@{$parents{$c}}) {
2005                         $skip{$p} = 1;
2006                 }
2007         }
2008         (\@linear_refs, \%parents);
2009 }
2010
2011 sub find_file_type_and_diff_status {
2012         my ($path) = @_;
2013         return ('dir', '') if $path eq '';
2014
2015         my $diff_output =
2016             command_oneline(qw(diff --cached --name-status --), $path) || "";
2017         my $diff_status = (split(' ', $diff_output))[0] || "";
2018
2019         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2020
2021         return (undef, undef) if !$diff_status && !$ls_tree;
2022
2023         if ($diff_status eq "A") {
2024                 return ("link", $diff_status) if -l $path;
2025                 return ("dir", $diff_status) if -d $path;
2026                 return ("file", $diff_status);
2027         }
2028
2029         my $mode = (split(' ', $ls_tree))[0] || "";
2030
2031         return ("link", $diff_status) if $mode eq "120000";
2032         return ("dir", $diff_status) if $mode eq "040000";
2033         return ("file", $diff_status);
2034 }
2035
2036 sub md5sum {
2037         my $arg = shift;
2038         my $ref = ref $arg;
2039         my $md5 = Digest::MD5->new();
2040         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2041                 $md5->addfile($arg) or croak $!;
2042         } elsif ($ref eq 'SCALAR') {
2043                 $md5->add($$arg) or croak $!;
2044         } elsif (!$ref) {
2045                 $md5->add($arg) or croak $!;
2046         } else {
2047                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2048         }
2049         return $md5->hexdigest();
2050 }
2051
2052 sub gc_directory {
2053         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2054                 my $out_filename = $_ . ".gz";
2055                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2056                 binmode $in_fh;
2057                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2058                                 die "Unable to open $out_filename: $!\n";
2059
2060                 my $res;
2061                 while ($res = sysread($in_fh, my $str, 1024)) {
2062                         $gz->gzwrite($str) or
2063                                 die "Unable to write: ".$gz->gzerror()."!\n";
2064                 }
2065                 unlink $_ or die "unlink $File::Find::name: $!\n";
2066         } elsif (-f $_ && basename($_) eq "index") {
2067                 unlink $_ or die "unlink $_: $!\n";
2068         }
2069 }
2070
2071 __END__
2072
2073 Data structures:
2074
2075
2076 $remotes = { # returned by read_all_remotes()
2077         'svn' => {
2078                 # svn-remote.svn.url=https://svn.musicpd.org
2079                 url => 'https://svn.musicpd.org',
2080                 # svn-remote.svn.fetch=mpd/trunk:trunk
2081                 fetch => {
2082                         'mpd/trunk' => 'trunk',
2083                 },
2084                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2085                 tags => {
2086                         path => {
2087                                 left => 'mpd/tags',
2088                                 right => '',
2089                                 regex => qr!mpd/tags/([^/]+)$!,
2090                                 glob => 'tags/*',
2091                         },
2092                         ref => {
2093                                 left => 'tags',
2094                                 right => '',
2095                                 regex => qr!tags/([^/]+)$!,
2096                                 glob => 'tags/*',
2097                         },
2098                 }
2099         }
2100 };
2101
2102 $log_entry hashref as returned by libsvn_log_entry()
2103 {
2104         log => 'whitespace-formatted log entry
2105 ',                                              # trailing newline is preserved
2106         revision => '8',                        # integer
2107         date => '2004-02-24T17:01:44.108345Z',  # commit date
2108         author => 'committer name'
2109 };
2110
2111
2112 # this is generated by generate_diff();
2113 @mods = array of diff-index line hashes, each element represents one line
2114         of diff-index output
2115
2116 diff-index line ($m hash)
2117 {
2118         mode_a => first column of diff-index output, no leading ':',
2119         mode_b => second column of diff-index output,
2120         sha1_b => sha1sum of the final blob,
2121         chg => change type [MCRADT],
2122         file_a => original file name of a file (iff chg is 'C' or 'R')
2123         file_b => new/current file name of a file (any chg)
2124 }
2125 ;
2126
2127 # retval of read_url_paths{,_all}();
2128 $l_map = {
2129         # repository root url
2130         'https://svn.musicpd.org' => {
2131                 # repository path               # GIT_SVN_ID
2132                 'mpd/trunk'             =>      'trunk',
2133                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2134         },
2135 }
2136
2137 Notes:
2138         I don't trust the each() function on unless I created %hash myself
2139         because the internal iterator may not have started at base.