git.oblomov.eu Git - git/blob - contrib/completion/git-completion.tcsh

   1 #!tcsh
   2 #
   3 # tcsh completion support for core Git.
   4 #
   5 # Copyright (C) 2012 Marc Khouzam <marc.khouzam@gmail.com>
   6 # Distributed under the GNU General Public License, version 2.0.
   7 #
   8 # When sourced, this script will generate a new script that uses
   9 # the git-completion.bash script provided by core Git.  This new
  10 # script can be used by tcsh to perform git completion.
  11 # The current script also issues the necessary tcsh 'complete'
  12 # commands.
  13 #
  14 # To use this completion script:
  15 #
  16 #    0) You need tcsh 6.16.00 or newer.
  17 #    1) Copy both this file and the bash completion script to ${HOME}.
  18 #       You _must_ use the name ${HOME}/.git-completion.bash for the
  19 #       bash script.
  20 #       (e.g. ~/.git-completion.tcsh and ~/.git-completion.bash).
  21 #    2) Add the following line to your .tcshrc/.cshrc:
  22 #        source ~/.git-completion.tcsh
  23 #    3) For completion similar to bash, it is recommended to also
  24 #       add the following line to your .tcshrc/.cshrc:
  25 #        set autolist=ambiguous
  26 #       It will tell tcsh to list the possible completion choices.
  27
  28 set __git_tcsh_completion_version = `\echo ${tcsh} | \sed 's/\./ /g'`
  29 if ( ${__git_tcsh_completion_version[1]} < 6 || \
  30      ( ${__git_tcsh_completion_version[1]} == 6 && \
  31        ${__git_tcsh_completion_version[2]} < 16 ) ) then
  32         echo "git-completion.tcsh: Your version of tcsh is too old, you need version 6.16.00 or newer.  Git completion will not work."
  33         exit
  34 endif
  35 unset __git_tcsh_completion_version
  36
  37 set __git_tcsh_completion_original_script = ${HOME}/.git-completion.bash
  38 set __git_tcsh_completion_script = ${HOME}/.git-completion.tcsh.bash
  39
  40 # Check that the user put the script in the right place
  41 if ( ! -e ${__git_tcsh_completion_original_script} ) then
  42         echo "git-completion.tcsh: Cannot find: ${__git_tcsh_completion_original_script}.  Git completion will not work."
  43         exit
  44 endif
  45
  46 cat << EOF > ${__git_tcsh_completion_script}
  47 #!bash
  48 #
  49 # This script is GENERATED and will be overwritten automatically.
  50 # Do not modify it directly.  Instead, modify git-completion.tcsh
  51 # and source it again.
  52
  53 source ${__git_tcsh_completion_original_script}
  54
  55 # Set COMP_WORDS in a way that can be handled by the bash script.
  56 COMP_WORDS=(\$2)
  57
  58 # The cursor is at the end of parameter #1.
  59 # We must check for a space as the last character which will
  60 # tell us that the previous word is complete and the cursor
  61 # is on the next word.
  62 if [ "\${2: -1}" == " " ]; then
  63         # The last character is a space, so our location is at the end
  64         # of the command-line array
  65         COMP_CWORD=\${#COMP_WORDS[@]}
  66 else
  67         # The last character is not a space, so our location is on the
  68         # last word of the command-line array, so we must decrement the
  69         # count by 1
  70         COMP_CWORD=\$((\${#COMP_WORDS[@]}-1))
  71 fi
  72
  73 # Call _git() or _gitk() of the bash script, based on the first argument
  74 _\${1}
  75
  76 IFS=\$'\n'
  77 if [ \${#COMPREPLY[*]} -eq 0 ]; then
  78         # No completions suggested.  In this case, we want tcsh to perform
  79         # standard file completion.  However, there does not seem to be way
  80         # to tell tcsh to do that.  To help the user, we try to simulate
  81         # file completion directly in this script.
  82         #
  83         # Known issues:
  84         #     - Possible completions are shown with their directory prefix.
  85         #     - Completions containing shell variables are not handled.
  86         #     - Completions with ~ as the first character are not handled.
  87
  88         # No file completion should be done unless we are completing beyond
  89         # the git sub-command.  An improvement on the bash completion :)
  90         if [ \${COMP_CWORD} -gt 1 ]; then
  91                 TO_COMPLETE="\${COMP_WORDS[\${COMP_CWORD}]}"
  92
  93                 # We don't support ~ expansion: too tricky.
  94                 if [ "\${TO_COMPLETE:0:1}" != "~" ]; then
  95                         # Use ls so as to add the '/' at the end of directories.
  96                         COMPREPLY=(\`ls -dp \${TO_COMPLETE}* 2> /dev/null\`)
  97                 fi
  98         fi
  99 fi
 100
 101 # tcsh does not automatically remove duplicates, so we do it ourselves
 102 echo "\${COMPREPLY[*]}" | sort | uniq
 103
 104 # If there is a single completion and it is a directory, we output it
 105 # a second time to trick tcsh into not adding a space after it.
 106 if [ \${#COMPREPLY[*]} -eq 1 ] && [ "\${COMPREPLY[0]: -1}" == "/" ]; then
 107         echo "\${COMPREPLY[*]}"
 108 fi
 109
 110 EOF
 111
 112 # Don't need this variable anymore, so don't pollute the users environment
 113 unset __git_tcsh_completion_original_script
 114
 115 complete git  'p,*,`bash ${__git_tcsh_completion_script} git "${COMMAND_LINE}"`,'
 116 complete gitk 'p,*,`bash ${__git_tcsh_completion_script} gitk "${COMMAND_LINE}"`,'