git.oblomov.eu Git - git/blob - contrib/completion/git-completion.zsh

   1 #compdef git gitk
   2
   3 # zsh completion wrapper for git
   4 #
   5 # Copyright (c) 2012-2013 Felipe Contreras <felipe.contreras@gmail.com>
   6 #
   7 # The recommended way to install this script is to make a copy of it as a
   8 # file named '_git' inside any directory in your fpath.
   9 #
  10 # For example, create a directory '~/.zsh/', copy this file to '~/.zsh/_git',
  11 # and then add the following to your ~/.zshrc file:
  12 #
  13 #  fpath=(~/.zsh $fpath)
  14 #
  15 # You need git's bash completion script installed. By default bash-completion's
  16 # location will be used (e.g. pkg-config --variable=completionsdir bash-completion).
  17 #
  18 # If your bash completion script is somewhere else, you can specify the
  19 # location in your ~/.zshrc:
  20 #
  21 #  zstyle ':completion:*:*:git:*' script ~/.git-completion.bash
  22 #
  23
  24 zstyle -T ':completion:*:*:git:*' tag-order && \
  25         zstyle ':completion:*:*:git:*' tag-order 'common-commands'
  26
  27 zstyle -s ":completion:*:*:git:*" script script
  28 if [ -z "$script" ]; then
  29         local -a locations
  30         local e bash_completion
  31
  32         bash_completion=$(pkg-config --variable=completionsdir bash-completion 2>/dev/null) ||
  33                 bash_completion='/usr/share/bash-completion/completions/'
  34
  35         locations=(
  36                 "$(dirname ${funcsourcetrace[1]%:*})"/git-completion.bash
  37                 "$HOME/.local/share/bash-completion/completions/git"
  38                 "$bash_completion/git"
  39                 '/etc/bash_completion.d/git' # old debian
  40                 )
  41         for e in $locations; do
  42                 test -f $e && script="$e" && break
  43         done
  44 fi
  45
  46 local old_complete="$functions[complete]"
  47 functions[complete]=:
  48 GIT_SOURCING_ZSH_COMPLETION=y . "$script"
  49 functions[complete]="$old_complete"
  50
  51 __gitcomp ()
  52 {
  53         emulate -L zsh
  54
  55         local cur_="${3-$cur}"
  56
  57         case "$cur_" in
  58         --*=)
  59                 ;;
  60         --no-*)
  61                 local c IFS=$' \t\n'
  62                 local -a array
  63                 for c in ${=1}; do
  64                         if [[ $c == "--" ]]; then
  65                                 continue
  66                         fi
  67                         c="$c${4-}"
  68                         case $c in
  69                         --*=|*.) ;;
  70                         *) c="$c " ;;
  71                         esac
  72                         array+=("$c")
  73                 done
  74                 compset -P '*[=:]'
  75                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  76                 ;;
  77         *)
  78                 local c IFS=$' \t\n'
  79                 local -a array
  80                 for c in ${=1}; do
  81                         if [[ $c == "--" ]]; then
  82                                 c="--no-...${4-}"
  83                                 array+=("$c ")
  84                                 break
  85                         fi
  86                         c="$c${4-}"
  87                         case $c in
  88                         --*=*|*.) ;;
  89                         *) c="$c " ;;
  90                         esac
  91                         array+=("$c")
  92                 done
  93                 compset -P '*[=:]'
  94                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  95                 ;;
  96         esac
  97 }
  98
  99 __gitcomp_direct ()
 100 {
 101         emulate -L zsh
 102
 103         compset -P '*[=:]'
 104         compadd -Q -S '' -- ${(f)1} && _ret=0
 105 }
 106
 107 __gitcomp_nl ()
 108 {
 109         emulate -L zsh
 110
 111         compset -P '*[=:]'
 112         compadd -Q -S "${4- }" -p "${2-}" -- ${(f)1} && _ret=0
 113 }
 114
 115 __gitcomp_file ()
 116 {
 117         emulate -L zsh
 118
 119         compadd -f -p "${2-}" -- ${(f)1} && _ret=0
 120 }
 121
 122 __gitcomp_direct_append ()
 123 {
 124         __gitcomp_direct "$@"
 125 }
 126
 127 __gitcomp_nl_append ()
 128 {
 129         __gitcomp_nl "$@"
 130 }
 131
 132 __gitcomp_file_direct ()
 133 {
 134         __gitcomp_file "$1" ""
 135 }
 136
 137 __git_zsh_bash_func ()
 138 {
 139         emulate -L ksh
 140
 141         local command=$1
 142
 143         local completion_func="_git_${command//-/_}"
 144         declare -f $completion_func >/dev/null && $completion_func && return
 145
 146         local expansion=$(__git_aliased_command "$command")
 147         if [ -n "$expansion" ]; then
 148                 words[1]=$expansion
 149                 completion_func="_git_${expansion//-/_}"
 150                 declare -f $completion_func >/dev/null && $completion_func
 151         fi
 152 }
 153
 154 __git_zsh_cmd_common ()
 155 {
 156         local -a list
 157         list=(
 158         add:'add file contents to the index'
 159         bisect:'find by binary search the change that introduced a bug'
 160         branch:'list, create, or delete branches'
 161         checkout:'checkout a branch or paths to the working tree'
 162         clone:'clone a repository into a new directory'
 163         commit:'record changes to the repository'
 164         diff:'show changes between commits, commit and working tree, etc'
 165         fetch:'download objects and refs from another repository'
 166         grep:'print lines matching a pattern'
 167         init:'create an empty Git repository or reinitialize an existing one'
 168         log:'show commit logs'
 169         merge:'join two or more development histories together'
 170         mv:'move or rename a file, a directory, or a symlink'
 171         pull:'fetch from and merge with another repository or a local branch'
 172         push:'update remote refs along with associated objects'
 173         rebase:'forward-port local commits to the updated upstream head'
 174         reset:'reset current HEAD to the specified state'
 175         restore:'restore working tree files'
 176         rm:'remove files from the working tree and from the index'
 177         show:'show various types of objects'
 178         status:'show the working tree status'
 179         switch:'switch branches'
 180         tag:'create, list, delete or verify a tag object signed with GPG')
 181         _describe -t common-commands 'common commands' list && _ret=0
 182 }
 183
 184 __git_zsh_cmd_alias ()
 185 {
 186         local -a list
 187         list=(${${${(0)"$(git config -z --get-regexp '^alias\.')"}#alias.}%$'\n'*})
 188         _describe -t alias-commands 'aliases' list $* && _ret=0
 189 }
 190
 191 __git_zsh_cmd_all ()
 192 {
 193         local -a list
 194         emulate ksh -c __git_compute_all_commands
 195         list=( ${=__git_all_commands} )
 196         _describe -t all-commands 'all commands' list && _ret=0
 197 }
 198
 199 __git_zsh_main ()
 200 {
 201         local curcontext="$curcontext" state state_descr line
 202         typeset -A opt_args
 203         local -a orig_words
 204
 205         orig_words=( ${words[@]} )
 206
 207         _arguments -C \
 208                 '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \
 209                 '(-p --paginate)--no-pager[do not pipe git output into a pager]' \
 210                 '--git-dir=-[set the path to the repository]: :_directories' \
 211                 '--bare[treat the repository as a bare repository]' \
 212                 '(- :)--version[prints the git suite version]' \
 213                 '--exec-path=-[path to where your core git programs are installed]:: :_directories' \
 214                 '--html-path[print the path where git''s HTML documentation is installed]' \
 215                 '--info-path[print the path where the Info files are installed]' \
 216                 '--man-path[print the manpath (see `man(1)`) for the man pages]' \
 217                 '--work-tree=-[set the path to the working tree]: :_directories' \
 218                 '--namespace=-[set the git namespace]' \
 219                 '--no-replace-objects[do not use replacement refs to replace git objects]' \
 220                 '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \
 221                 '(-): :->command' \
 222                 '(-)*:: :->arg' && return
 223
 224         case $state in
 225         (command)
 226                 _alternative \
 227                          'alias-commands:alias:__git_zsh_cmd_alias' \
 228                          'common-commands:common:__git_zsh_cmd_common' \
 229                          'all-commands:all:__git_zsh_cmd_all' && _ret=0
 230                 ;;
 231         (arg)
 232                 local command="${words[1]}" __git_dir
 233
 234                 if (( $+opt_args[--bare] )); then
 235                         __git_dir='.'
 236                 else
 237                         __git_dir=${opt_args[--git-dir]}
 238                 fi
 239
 240                 (( $+opt_args[--help] )) && command='help'
 241
 242                 words=( ${orig_words[@]} )
 243
 244                 __git_zsh_bash_func $command
 245                 ;;
 246         esac
 247 }
 248
 249 _git ()
 250 {
 251         local _ret=1
 252         local cur cword prev
 253
 254         cur=${words[CURRENT]}
 255         prev=${words[CURRENT-1]}
 256         let cword=CURRENT-1
 257
 258         if (( $+functions[__${service}_zsh_main] )); then
 259                 __${service}_zsh_main
 260         elif (( $+functions[__${service}_main] )); then
 261                 emulate ksh -c __${service}_main
 262         elif (( $+functions[_${service}] )); then
 263                 emulate ksh -c _${service}
 264         elif (( $+functions[_${service//-/_}] )); then
 265                 emulate ksh -c _${service//-/_}
 266         fi
 267
 268         let _ret && _default && _ret=0
 269         return _ret
 270 }
 271
 272 _git