git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 $ENV{GIT_DIR} ||= '.git';
  13 $Git::SVN::default_repo_id = 'git-svn';
  14 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  15
  16 $Git::SVN::Log::TZ = $ENV{TZ};
  17 $ENV{TZ} = 'UTC';
  18 $| = 1; # unbuffer STDOUT
  19
  20 sub fatal (@) { print STDERR @_; exit 1 }
  21 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  22 require SVN::Ra;
  23 require SVN::Delta;
  24 if ($SVN::Core::VERSION lt '1.1.0') {
  25         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  26 }
  27 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  28 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  29 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  30 use Carp qw/croak/;
  31 use IO::File qw//;
  32 use File::Basename qw/dirname basename/;
  33 use File::Path qw/mkpath/;
  34 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  35 use IPC::Open3;
  36 use Git;
  37
  38 BEGIN {
  39         my $s;
  40         foreach (qw/command command_oneline command_noisy command_output_pipe
  41                     command_input_pipe command_close_pipe/) {
  42                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  43                       "*Git::SVN::Migration::$_ = ".
  44                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  45         }
  46         eval $s;
  47 }
  48
  49 my ($SVN);
  50
  51 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  52 $sha1 = qr/[a-f\d]{40}/;
  53 $sha1_short = qr/[a-f\d]{4,40}/;
  54 my ($_stdin, $_help, $_edit,
  55         $_repack, $_repack_nr, $_repack_flags,
  56         $_message, $_file,
  57         $_template, $_shared,
  58         $_version,
  59         $_merge, $_strategy, $_dry_run,
  60         $_prefix);
  61
  62 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  63                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  64                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  65 my %fc_opts = ( 'follow-parent|follow' => \$Git::SVN::_follow_parent,
  66                 'authors-file|A=s' => \$_authors,
  67                 'repack:i' => \$_repack,
  68                 'no-metadata' => \$Git::SVN::_no_metadata,
  69                 'quiet|q' => \$_q,
  70                 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
  71                 %remote_opts );
  72
  73 my ($_trunk, $_tags, $_branches);
  74 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  75                 'tags|t=s' => \$_tags,
  76                 'branches|b=s' => \$_branches );
  77 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  78 my %cmt_opts = ( 'edit|e' => \$_edit,
  79                 'rmdir' => \$SVN::Git::Editor::_rmdir,
  80                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
  81                 'l=i' => \$SVN::Git::Editor::_rename_limit,
  82                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
  83 );
  84
  85 my %cmd = (
  86         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  87                         { 'revision|r=s' => \$_revision, %fc_opts } ],
  88         init => [ \&cmd_init, "Initialize a repo for tracking" .
  89                           " (requires URL argument)",
  90                           \%init_opts ],
  91         dcommit => [ \&cmd_dcommit,
  92                      'Commit several diffs to merge with upstream',
  93                         { 'merge|m|M' => \$_merge,
  94                           'strategy|s=s' => \$_strategy,
  95                           'dry-run|n' => \$_dry_run,
  96                         %cmt_opts, %fc_opts } ],
  97         'set-tree' => [ \&cmd_set_tree,
  98                         "Set an SVN repository to a git tree-ish",
  99                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 100         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 101                         { 'revision|r=i' => \$_revision } ],
 102         'multi-init' => [ \&cmd_multi_init,
 103                         'Initialize multiple trees (like git-svnimport)',
 104                         { %multi_opts, %init_opts, %remote_opts,
 105                          'revision|r=i' => \$_revision,
 106                          'prefix=s' => \$_prefix,
 107                         } ],
 108         'multi-fetch' => [ \&cmd_multi_fetch,
 109                         'Fetch multiple trees (like git-svnimport)',
 110                         \%fc_opts ],
 111         'migrate' => [ sub { },
 112                        # no-op, we automatically run this anyways,
 113                        'Migrate configuration/metadata/layout from
 114                         previous versions of git-svn',
 115                         \%remote_opts ],
 116         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 117                         { 'limit=i' => \$Git::SVN::Log::limit,
 118                           'revision|r=s' => \$_revision,
 119                           'verbose|v' => \$Git::SVN::Log::verbose,
 120                           'incremental' => \$Git::SVN::Log::incremental,
 121                           'oneline' => \$Git::SVN::Log::oneline,
 122                           'show-commit' => \$Git::SVN::Log::show_commit,
 123                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 124                           'authors-file|A=s' => \$_authors,
 125                           'color' => \$Git::SVN::Log::color,
 126                           'pager=s' => \$Git::SVN::Log::pager,
 127                         } ],
 128         'commit-diff' => [ \&cmd_commit_diff,
 129                            'Commit a diff between two trees',
 130                         { 'message|m=s' => \$_message,
 131                           'file|F=s' => \$_file,
 132                           'revision|r=s' => \$_revision,
 133                         %cmt_opts } ],
 134 );
 135
 136 my $cmd;
 137 for (my $i = 0; $i < @ARGV; $i++) {
 138         if (defined $cmd{$ARGV[$i]}) {
 139                 $cmd = $ARGV[$i];
 140                 splice @ARGV, $i, 1;
 141                 last;
 142         }
 143 };
 144
 145 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 146
 147 read_repo_config(\%opts);
 148 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 149                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 150                     'id|i=s' => \$Git::SVN::default_ref_id,
 151                     'svn-remote|remote|R=s' => \$Git::SVN::default_repo_id);
 152 exit 1 if (!$rv && $cmd ne 'log');
 153
 154 usage(0) if $_help;
 155 version() if $_version;
 156 usage(1) unless defined $cmd;
 157 load_authors() if $_authors;
 158 unless ($cmd =~ /^(?:init|multi-init|commit-diff)$/) {
 159         Git::SVN::Migration::migration_check();
 160 }
 161 eval {
 162         Git::SVN::verify_remotes_sanity();
 163         $cmd{$cmd}->[0]->(@ARGV);
 164 };
 165 fatal $@ if $@;
 166 exit 0;
 167
 168 ####################### primary functions ######################
 169 sub usage {
 170         my $exit = shift || 0;
 171         my $fd = $exit ? \*STDERR : \*STDOUT;
 172         print $fd <<"";
 173 git-svn - bidirectional operations between a single Subversion tree and git
 174 Usage: $0 <command> [options] [arguments]\n
 175
 176         print $fd "Available commands:\n" unless $cmd;
 177
 178         foreach (sort keys %cmd) {
 179                 next if $cmd && $cmd ne $_;
 180                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 181                 foreach (keys %{$cmd{$_}->[2]}) {
 182                         # prints out arguments as they should be passed:
 183                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 184                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 185                                                         "--$_" : "-$_" }
 186                                                 split /\|/,$_)," $x\n";
 187                 }
 188         }
 189         print $fd <<"";
 190 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 191 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 192 one git repository and want to keep them separate.  See git-svn(1) for more
 193 information.
 194
 195         exit $exit;
 196 }
 197
 198 sub version {
 199         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 200         exit 0;
 201 }
 202
 203 sub do_git_init_db {
 204         unless (-d $ENV{GIT_DIR}) {
 205                 my @init_db = ('init');
 206                 push @init_db, "--template=$_template" if defined $_template;
 207                 push @init_db, "--shared" if defined $_shared;
 208                 command_noisy(@init_db);
 209         }
 210 }
 211
 212 sub cmd_init {
 213         my $url = shift or die "SVN repository location required " .
 214                                 "as a command-line argument\n";
 215         if (my $repo_path = shift) {
 216                 unless (-d $repo_path) {
 217                         mkpath([$repo_path]);
 218                 }
 219                 chdir $repo_path or croak $!;
 220                 $ENV{GIT_DIR} = $repo_path . "/.git";
 221         }
 222         do_git_init_db();
 223
 224         Git::SVN->init($url);
 225 }
 226
 227 sub cmd_fetch {
 228         if (@_) {
 229                 die "Additional fetch arguments are no longer supported.\n",
 230                     "Use --follow-parent if you have moved/copied directories
 231                     instead.\n";
 232         }
 233         my $gs = Git::SVN->new;
 234         $gs->fetch(parse_revision_argument());
 235         if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
 236                 command_noisy(qw(update-ref refs/heads/master),
 237                               $gs->{last_commit});
 238         }
 239 }
 240
 241 sub cmd_set_tree {
 242         my (@commits) = @_;
 243         if ($_stdin || !@commits) {
 244                 print "Reading from stdin...\n";
 245                 @commits = ();
 246                 while (<STDIN>) {
 247                         if (/\b($sha1_short)\b/o) {
 248                                 unshift @commits, $1;
 249                         }
 250                 }
 251         }
 252         my @revs;
 253         foreach my $c (@commits) {
 254                 my @tmp = command('rev-parse',$c);
 255                 if (scalar @tmp == 1) {
 256                         push @revs, $tmp[0];
 257                 } elsif (scalar @tmp > 1) {
 258                         push @revs, reverse(command('rev-list',@tmp));
 259                 } else {
 260                         fatal "Failed to rev-parse $c\n";
 261                 }
 262         }
 263         my $gs = Git::SVN->new;
 264         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 265         $gs->fetch;
 266         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 267                 fatal "There are new revisions that were fetched ",
 268                       "and need to be merged (or acknowledged) ",
 269                       "before committing.\nlast rev: $r_last\n",
 270                       " current: $gs->{last_rev}\n";
 271         }
 272         $gs->set_tree($_) foreach @revs;
 273         print "Done committing ",scalar @revs," revisions to SVN\n";
 274 }
 275
 276 sub cmd_dcommit {
 277         my $head = shift;
 278         my $gs = Git::SVN->new;
 279         $head ||= 'HEAD';
 280         my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
 281         my $last_rev;
 282         foreach my $d (reverse @refs) {
 283                 if (!verify_ref("$d~1")) {
 284                         fatal "Commit $d\n",
 285                               "has no parent commit, and therefore ",
 286                               "nothing to diff against.\n",
 287                               "You should be working from a repository ",
 288                               "originally created by git-svn\n";
 289                 }
 290                 unless (defined $last_rev) {
 291                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 292                         unless (defined $last_rev) {
 293                                 fatal "Unable to extract revision information ",
 294                                       "from commit $d~1\n";
 295                         }
 296                 }
 297                 if ($_dry_run) {
 298                         print "diff-tree $d~1 $d\n";
 299                 } else {
 300                         my %ed_opts = ( r => $last_rev,
 301                                         log => get_commit_entry($d)->{log},
 302                                         ra => $gs->ra,
 303                                         tree_a => "$d~1",
 304                                         tree_b => $d,
 305                                         editor_cb => sub {
 306                                                print "Committed r$_[0]\n";
 307                                                $last_rev = $_[0]; },
 308                                         svn_path => $gs->{path} );
 309                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 310                                 print "No changes\n$d~1 == $d\n";
 311                         }
 312                 }
 313         }
 314         return if $_dry_run;
 315         $gs->fetch;
 316         # we always want to rebase against the current HEAD, not any
 317         # head that was passed to us
 318         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 319         my @finish;
 320         if (@diff) {
 321                 @finish = qw/rebase/;
 322                 push @finish, qw/--merge/ if $_merge;
 323                 push @finish, "--strategy=$_strategy" if $_strategy;
 324                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 325                              "using @finish:\n", "@diff";
 326         } else {
 327                 print "No changes between current HEAD and ",
 328                       $gs->refname, "\nResetting to the latest ",
 329                       $gs->refname, "\n";
 330                 @finish = qw/reset --mixed/;
 331         }
 332         command_noisy(@finish, $gs->refname);
 333 }
 334
 335 sub cmd_show_ignore {
 336         my $gs = Git::SVN->new;
 337         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 338         $gs->traverse_ignore(\*STDOUT, '', $r);
 339 }
 340
 341 sub cmd_multi_init {
 342         my $url = shift;
 343         unless (defined $_trunk || defined $_branches || defined $_tags) {
 344                 usage(1);
 345         }
 346         do_git_init_db();
 347         $_prefix = '' unless defined $_prefix;
 348         $url =~ s#/+$## if defined $url;
 349         if (defined $_trunk) {
 350                 my $trunk_ref = $_prefix . 'trunk';
 351                 # try both old-style and new-style lookups:
 352                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 353                 unless ($gs_trunk) {
 354                         my ($trunk_url, $trunk_path) =
 355                                               complete_svn_url($url, $_trunk);
 356                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 357                                                    undef, $trunk_ref);
 358                 }
 359         }
 360         return unless defined $_branches || defined $_tags;
 361         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 362         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 363         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 364 }
 365
 366 sub cmd_multi_fetch {
 367         my $remotes = Git::SVN::read_all_remotes();
 368         foreach my $repo_id (sort keys %$remotes) {
 369                 my $url = $remotes->{$repo_id}->{url} or next;
 370                 my $fetch = $remotes->{$repo_id}->{fetch} or next;
 371                 Git::SVN::fetch_all($repo_id, $url, $fetch);
 372         }
 373 }
 374
 375 # this command is special because it requires no metadata
 376 sub cmd_commit_diff {
 377         my ($ta, $tb, $url) = @_;
 378         my $usage = "Usage: $0 commit-diff -r<revision> ".
 379                     "<tree-ish> <tree-ish> [<URL>]\n";
 380         fatal($usage) if (!defined $ta || !defined $tb);
 381         my $svn_path;
 382         if (!defined $url) {
 383                 my $gs = eval { Git::SVN->new };
 384                 if (!$gs) {
 385                         fatal("Needed URL or usable git-svn --id in ",
 386                               "the command-line\n", $usage);
 387                 }
 388                 $url = $gs->{url};
 389                 $svn_path = $gs->{path};
 390         }
 391         unless (defined $_revision) {
 392                 fatal("-r|--revision is a required argument\n", $usage);
 393         }
 394         if (defined $_message && defined $_file) {
 395                 fatal("Both --message/-m and --file/-F specified ",
 396                       "for the commit message.\n",
 397                       "I have no idea what you mean\n");
 398         }
 399         if (defined $_file) {
 400                 $_message = file_to_s($_file);
 401         } else {
 402                 $_message ||= get_commit_entry($tb)->{log};
 403         }
 404         my $ra ||= Git::SVN::Ra->new($url);
 405         $svn_path ||= $ra->{svn_path};
 406         my $r = $_revision;
 407         if ($r eq 'HEAD') {
 408                 $r = $ra->get_latest_revnum;
 409         } elsif ($r !~ /^\d+$/) {
 410                 die "revision argument: $r not understood by git-svn\n";
 411         }
 412         my %ed_opts = ( r => $r,
 413                         log => $_message,
 414                         ra => $ra,
 415                         tree_a => $ta,
 416                         tree_b => $tb,
 417                         editor_cb => sub { print "Committed r$_[0]\n" },
 418                         svn_path => $svn_path );
 419         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 420                 print "No changes\n$ta == $tb\n";
 421         }
 422 }
 423
 424 ########################### utility functions #########################
 425
 426 sub parse_revision_argument {
 427         if (!defined $_revision || $_revision eq 'BASE:HEAD') {
 428                 return (undef, undef);
 429         }
 430         return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
 431         return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
 432         return (undef, $1) if ($_revision =~ /^BASE:(\d+)$/);
 433         return ($1, undef) if ($_revision =~ /^(\d+):HEAD$/);
 434         die "revision argument: $_revision not understood by git-svn\n",
 435             "Try using the command-line svn client instead\n";
 436 }
 437
 438 sub complete_svn_url {
 439         my ($url, $path) = @_;
 440         $path =~ s#/+$##;
 441         if ($path !~ m#^[a-z\+]+://#) {
 442                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 443                         fatal("E: '$path' is not a complete URL ",
 444                               "and a separate URL is not specified\n");
 445                 }
 446                 return ($url, $path);
 447         }
 448         return ($path, '');
 449 }
 450
 451 sub complete_url_ls_init {
 452         my ($ra, $repo_path, $switch, $pfx) = @_;
 453         unless ($repo_path) {
 454                 print STDERR "W: $switch not specified\n";
 455                 return;
 456         }
 457         $repo_path =~ s#/+$##;
 458         if ($repo_path =~ m#^[a-z\+]+://#) {
 459                 $ra = Git::SVN::Ra->new($repo_path);
 460                 $repo_path = '';
 461         } else {
 462                 $repo_path =~ s#^/+##;
 463                 unless ($ra) {
 464                         fatal("E: '$repo_path' is not a complete URL ",
 465                               "and a separate URL is not specified\n");
 466                 }
 467         }
 468         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
 469         my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
 470         my $url = $ra->{url};
 471         foreach my $d (sort keys %$dirent) {
 472                 next if ($dirent->{$d}->kind != $SVN::Node::dir);
 473                 my $path =  "$repo_path/$d";
 474                 my $ref = "$pfx$d";
 475                 my $gs = eval { Git::SVN->new($ref) };
 476                 # don't try to init already existing refs
 477                 unless ($gs) {
 478                         print "init $url/$path => $ref\n";
 479                         Git::SVN->init($url, $path, undef, $ref);
 480                 }
 481         }
 482 }
 483
 484 sub verify_ref {
 485         my ($ref) = @_;
 486         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 487                                { STDERR => 0 }); };
 488 }
 489
 490 sub get_tree_from_treeish {
 491         my ($treeish) = @_;
 492         # $treeish can be a symbolic ref, too:
 493         my $type = command_oneline(qw/cat-file -t/, $treeish);
 494         my $expected;
 495         while ($type eq 'tag') {
 496                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 497         }
 498         if ($type eq 'commit') {
 499                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 500                                                     $treeish))[0];
 501                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 502                 die "Unable to get tree from $treeish\n" unless $expected;
 503         } elsif ($type eq 'tree') {
 504                 $expected = $treeish;
 505         } else {
 506                 die "$treeish is a $type, expected tree, tag or commit\n";
 507         }
 508         return $expected;
 509 }
 510
 511 sub get_commit_entry {
 512         my ($treeish) = shift;
 513         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 514         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 515         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 516         open my $log_fh, '>', $commit_editmsg or croak $!;
 517
 518         my $type = command_oneline(qw/cat-file -t/, $treeish);
 519         if ($type eq 'commit' || $type eq 'tag') {
 520                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 521                                                          $type, $treeish);
 522                 my $in_msg = 0;
 523                 while (<$msg_fh>) {
 524                         if (!$in_msg) {
 525                                 $in_msg = 1 if (/^\s*$/);
 526                         } elsif (/^git-svn-id: /) {
 527                                 # skip this for now, we regenerate the
 528                                 # correct one on re-fetch anyways
 529                                 # TODO: set *:merge properties or like...
 530                         } else {
 531                                 print $log_fh $_ or croak $!;
 532                         }
 533                 }
 534                 command_close_pipe($msg_fh, $ctx);
 535         }
 536         close $log_fh or croak $!;
 537
 538         if ($_edit || ($type eq 'tree')) {
 539                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 540                 # TODO: strip out spaces, comments, like git-commit.sh
 541                 system($editor, $commit_editmsg);
 542         }
 543         rename $commit_editmsg, $commit_msg or croak $!;
 544         open $log_fh, '<', $commit_msg or croak $!;
 545         { local $/; chomp($log_entry{log} = <$log_fh>); }
 546         close $log_fh or croak $!;
 547         unlink $commit_msg;
 548         \%log_entry;
 549 }
 550
 551 sub s_to_file {
 552         my ($str, $file, $mode) = @_;
 553         open my $fd,'>',$file or croak $!;
 554         print $fd $str,"\n" or croak $!;
 555         close $fd or croak $!;
 556         chmod ($mode &~ umask, $file) if (defined $mode);
 557 }
 558
 559 sub file_to_s {
 560         my $file = shift;
 561         open my $fd,'<',$file or croak "$!: file: $file\n";
 562         local $/;
 563         my $ret = <$fd>;
 564         close $fd or croak $!;
 565         $ret =~ s/\s*$//s;
 566         return $ret;
 567 }
 568
 569 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 570 sub load_authors {
 571         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 572         my $log = $cmd eq 'log';
 573         while (<$authors>) {
 574                 chomp;
 575                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 576                 my ($user, $name, $email) = ($1, $2, $3);
 577                 if ($log) {
 578                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 579                 } else {
 580                         $users{$user} = [$name, $email];
 581                 }
 582         }
 583         close $authors or croak $!;
 584 }
 585
 586 # convert GetOpt::Long specs for use by git-config
 587 sub read_repo_config {
 588         return unless -d $ENV{GIT_DIR};
 589         my $opts = shift;
 590         foreach my $o (keys %$opts) {
 591                 my $v = $opts->{$o};
 592                 my ($key) = ($o =~ /^([a-z\-]+)/);
 593                 $key =~ s/-//g;
 594                 my $arg = 'git-config';
 595                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 596                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 597                 if (ref $v eq 'ARRAY') {
 598                         chomp(my @tmp = `$arg --get-all svn.$key`);
 599                         @$v = @tmp if @tmp;
 600                 } else {
 601                         chomp(my $tmp = `$arg --get svn.$key`);
 602                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 603                                 $$v = $tmp;
 604                         }
 605                 }
 606         }
 607 }
 608
 609 sub extract_metadata {
 610         my $id = shift or return (undef, undef, undef);
 611         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 612                                                         \s([a-f\d\-]+)$/x);
 613         if (!defined $rev || !$uuid || !$url) {
 614                 # some of the original repositories I made had
 615                 # identifiers like this:
 616                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 617         }
 618         return ($url, $rev, $uuid);
 619 }
 620
 621 sub cmt_metadata {
 622         return extract_metadata((grep(/^git-svn-id: /,
 623                 command(qw/cat-file commit/, shift)))[-1]);
 624 }
 625
 626 package Git::SVN;
 627 use strict;
 628 use warnings;
 629 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent/;
 630 use Carp qw/croak/;
 631 use File::Path qw/mkpath/;
 632 use IPC::Open3;
 633
 634 # properties that we do not log:
 635 my %SKIP_PROP;
 636 BEGIN {
 637         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 638                                         svn:special svn:executable
 639                                         svn:entry:committed-rev
 640                                         svn:entry:last-author
 641                                         svn:entry:uuid
 642                                         svn:entry:committed-date/;
 643 }
 644
 645 sub fetch_all {
 646         my ($repo_id, $url, $fetch) = @_;
 647         my @gs;
 648         my $ra = Git::SVN::Ra->new($url);
 649         my $head = $ra->get_latest_revnum;
 650         my $base = $head;
 651         my $new_remote;
 652         foreach my $p (sort keys %$fetch) {
 653                 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 654                 my $lr = $gs->last_rev;
 655                 if (defined $lr) {
 656                         $base = $lr if ($lr < $base);
 657                 } else {
 658                         $new_remote = 1;
 659                 }
 660                 push @gs, $gs;
 661         }
 662         $base = 0 if $new_remote;
 663         return if (++$base > $head);
 664         $ra->gs_fetch_loop_common($base, $head, @gs);
 665 }
 666
 667 sub read_all_remotes {
 668         my $r = {};
 669         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 670                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 671                         $r->{$1}->{fetch}->{$2} = $3;
 672                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 673                         $r->{$1}->{url} = $2;
 674                 }
 675         }
 676         $r;
 677 }
 678
 679 sub verify_remotes_sanity {
 680         return unless -d $ENV{GIT_DIR};
 681         my %seen;
 682         foreach (command(qw/config -l/)) {
 683                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 684                         if ($seen{$1}) {
 685                                 die "Remote ref refs/remote/$1 is tracked by",
 686                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 687                                     "Please resolve this ambiguity in ",
 688                                     "your git configuration file before ",
 689                                     "continuing\n";
 690                         }
 691                         $seen{$1} = $_;
 692                 }
 693         }
 694 }
 695
 696 # we allow more chars than remotes2config.sh...
 697 sub sanitize_remote_name {
 698         my ($name) = @_;
 699         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 700         $name;
 701 }
 702
 703 sub find_existing_remote {
 704         my ($url, $remotes) = @_;
 705         my $existing;
 706         foreach my $repo_id (keys %$remotes) {
 707                 my $u = $remotes->{$repo_id}->{url} or next;
 708                 next if $u ne $url;
 709                 $existing = $repo_id;
 710                 last;
 711         }
 712         $existing;
 713 }
 714
 715 sub init_remote_config {
 716         my ($self, $url) = @_;
 717         $url =~ s!/+$!!; # strip trailing slash
 718         my $r = read_all_remotes();
 719         my $existing = find_existing_remote($url, $r);
 720         if ($existing) {
 721                 print STDERR "Using existing ",
 722                              "[svn-remote \"$existing\"]\n";
 723                 $self->{repo_id} = $existing;
 724         } else {
 725                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 726                 $existing = find_existing_remote($min_url, $r);
 727                 if ($existing) {
 728                         print STDERR "Using existing ",
 729                                      "[svn-remote \"$existing\"]\n";
 730                         $self->{repo_id} = $existing;
 731                 }
 732                 if ($min_url ne $url) {
 733                         print STDERR "Using higher level of URL: ",
 734                                      "$url => $min_url\n";
 735                         my $old_path = $self->{path};
 736                         $self->{path} = $url;
 737                         $self->{path} =~ s!^\Q$min_url\E/*!!;
 738                         if (length $old_path) {
 739                                 $self->{path} .= "/$old_path";
 740                         }
 741                         $url = $min_url;
 742                 }
 743         }
 744         my $orig_url;
 745         if (!$existing) {
 746                 # verify that we aren't overwriting anything:
 747                 $orig_url = eval {
 748                         command_oneline('config', '--get',
 749                                         "svn-remote.$self->{repo_id}.url")
 750                 };
 751                 if ($orig_url && ($orig_url ne $url)) {
 752                         die "svn-remote.$self->{repo_id}.url already set: ",
 753                             "$orig_url\nwanted to set to: $url\n";
 754                 }
 755         }
 756         my ($xrepo_id, $xpath) = find_ref($self->refname);
 757         if (defined $xpath) {
 758                 die "svn-remote.$xrepo_id.fetch already set to track ",
 759                     "$xpath:refs/remotes/", $self->refname, "\n";
 760         }
 761         command_noisy('config',
 762                       "svn-remote.$self->{repo_id}.url", $url);
 763         command_noisy('config', '--add',
 764                       "svn-remote.$self->{repo_id}.fetch",
 765                       "$self->{path}:".$self->refname);
 766         $self->{url} = $url;
 767 }
 768
 769 sub init {
 770         my ($class, $url, $path, $repo_id, $ref_id) = @_;
 771         my $self = _new($class, $repo_id, $ref_id, $path);
 772         if (defined $url) {
 773                 $self->init_remote_config($url);
 774         }
 775         $self;
 776 }
 777
 778 sub find_ref {
 779         my ($ref_id) = @_;
 780         foreach (command(qw/config -l/)) {
 781                 next unless m!^svn-remote\.(.+)\.fetch=
 782                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 783                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 784                 if ($ref eq $ref_id) {
 785                         $path = '' if ($path =~ m#^\./?#);
 786                         return ($repo_id, $path);
 787                 }
 788         }
 789         (undef, undef, undef);
 790 }
 791
 792 sub new {
 793         my ($class, $ref_id, $repo_id, $path) = @_;
 794         if (defined $ref_id && !defined $repo_id && !defined $path) {
 795                 ($repo_id, $path) = find_ref($ref_id);
 796                 if (!defined $repo_id) {
 797                         die "Could not find a \"svn-remote.*.fetch\" key ",
 798                             "in the repository configuration matching: ",
 799                             "refs/remotes/$ref_id\n";
 800                 }
 801         }
 802         my $self = _new($class, $repo_id, $ref_id, $path);
 803         if (!defined $self->{path} || !length $self->{path}) {
 804                 my $fetch = command_oneline('config', '--get',
 805                                             "svn-remote.$repo_id.fetch",
 806                                             ":refs/remotes/$ref_id\$") or
 807                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 808                          "\":refs/remotes/$ref_id\$\" in config\n";
 809                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
 810         }
 811         $self->{url} = command_oneline('config', '--get',
 812                                        "svn-remote.$repo_id.url") or
 813                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 814         if (-z $self->{db_path} && ::verify_ref($self->refname.'^0')) {
 815                 $self->rebuild;
 816         }
 817         $self;
 818 }
 819
 820 sub refname { "refs/remotes/$_[0]->{ref_id}" }
 821
 822 sub ra {
 823         my ($self) = shift;
 824         Git::SVN::Ra->new($self->{url});
 825 }
 826
 827 sub rel_path {
 828         my ($self) = @_;
 829         my $repos_root = $self->ra->{repos_root};
 830         return $self->{path} if ($self->{url} eq $repos_root);
 831         my $url = $self->{url} .
 832                   (length $self->{path} ? "/$self->{path}" : $self->{path});
 833         $url =~ s!^\Q$repos_root\E/*!!g;
 834         $url;
 835 }
 836
 837 sub traverse_ignore {
 838         my ($self, $fh, $path, $r) = @_;
 839         $path =~ s#^/+##g;
 840         my $ra = $self->ra;
 841         my ($dirent, undef, $props) = $ra->get_dir($path, $r);
 842         my $p = $path;
 843         $p =~ s#^\Q$ra->{svn_path}\E/##;
 844         print $fh length $p ? "\n# $p\n" : "\n# /\n";
 845         if (my $s = $props->{'svn:ignore'}) {
 846                 $s =~ s/[\r\n]+/\n/g;
 847                 chomp $s;
 848                 if (length $p == 0) {
 849                         $s =~ s#\n#\n/$p#g;
 850                         print $fh "/$s\n";
 851                 } else {
 852                         $s =~ s#\n#\n/$p/#g;
 853                         print $fh "/$p/$s\n";
 854                 }
 855         }
 856         foreach (sort keys %$dirent) {
 857                 next if $dirent->{$_}->kind != $SVN::Node::dir;
 858                 $self->traverse_ignore($fh, "$path/$_", $r);
 859         }
 860 }
 861
 862 sub last_rev { ($_[0]->last_rev_commit)[0] }
 863 sub last_commit { ($_[0]->last_rev_commit)[1] }
 864
 865 # returns the newest SVN revision number and newest commit SHA1
 866 sub last_rev_commit {
 867         my ($self) = @_;
 868         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 869                 return ($self->{last_rev}, $self->{last_commit});
 870         }
 871         my $c = ::verify_ref($self->refname.'^0');
 872         if ($c) {
 873                 my $rev = (::cmt_metadata($c))[1];
 874                 if (defined $rev) {
 875                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 876                         return ($rev, $c);
 877                 }
 878         }
 879         my $offset = -41; # from tail
 880         my $rl;
 881         open my $fh, '<', $self->{db_path} or
 882                                  croak "$self->{db_path} not readable: $!\n";
 883         seek $fh, $offset, 2;
 884         $rl = readline $fh;
 885         defined $rl or return (undef, undef);
 886         chomp $rl;
 887         while ($c ne $rl && tell $fh != 0) {
 888                 $offset -= 41;
 889                 seek $fh, $offset, 2;
 890                 $rl = readline $fh;
 891                 defined $rl or return (undef, undef);
 892                 chomp $rl;
 893         }
 894         my $rev = tell $fh;
 895         croak $! if ($rev < 0);
 896         $rev =  ($rev - 41) / 41;
 897         close $fh or croak $!;
 898         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 899         return ($rev, $c);
 900 }
 901
 902 sub get_fetch_range {
 903         my ($self, $min, $max) = @_;
 904         $max ||= $self->ra->get_latest_revnum;
 905         $min ||= $self->last_rev || 0;
 906         (++$min, $max);
 907 }
 908
 909 sub tmp_index_do {
 910         my ($self, $sub) = @_;
 911         my $old_index = $ENV{GIT_INDEX_FILE};
 912         $ENV{GIT_INDEX_FILE} = $self->{index};
 913         my @ret = &$sub;
 914         if ($old_index) {
 915                 $ENV{GIT_INDEX_FILE} = $old_index;
 916         } else {
 917                 delete $ENV{GIT_INDEX_FILE};
 918         }
 919         wantarray ? @ret : $ret[0];
 920 }
 921
 922 sub assert_index_clean {
 923         my ($self, $treeish) = @_;
 924
 925         $self->tmp_index_do(sub {
 926                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 927                 my $x = command_oneline('write-tree');
 928                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 929                            /^tree ($::sha1)/mo);
 930                 if ($y ne $x) {
 931                         unlink $self->{index} or croak $!;
 932                         command_noisy('read-tree', $treeish);
 933                 }
 934                 $x = command_oneline('write-tree');
 935                 if ($y ne $x) {
 936                         ::fatal "trees ($treeish) $y != $x\n",
 937                                 "Something is seriously wrong...\n";
 938                 }
 939         });
 940 }
 941
 942 sub get_commit_parents {
 943         my ($self, $log_entry) = @_;
 944         my (%seen, @ret, @tmp);
 945         # legacy support for 'set-tree'; this is only used by set_tree_cb:
 946         if (my $ip = $self->{inject_parents}) {
 947                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
 948                         push @tmp, $commit;
 949                 }
 950         }
 951         if (my $cur = ::verify_ref($self->refname.'^0')) {
 952                 push @tmp, $cur;
 953         }
 954         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
 955         while (my $p = shift @tmp) {
 956                 next if $seen{$p};
 957                 $seen{$p} = 1;
 958                 push @ret, $p;
 959                 # MAXPARENT is defined to 16 in commit-tree.c:
 960                 last if @ret >= 16;
 961         }
 962         if (@tmp) {
 963                 die "r$log_entry->{revision}: No room for parents:\n\t",
 964                     join("\n\t", @tmp), "\n";
 965         }
 966         @ret;
 967 }
 968
 969 sub full_url {
 970         my ($self) = @_;
 971         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
 972 }
 973
 974 sub do_git_commit {
 975         my ($self, $log_entry) = @_;
 976         my $lr = $self->last_rev;
 977         if (defined $lr && $lr >= $log_entry->{revision}) {
 978                 die "Last fetched revision of ", $self->refname,
 979                     " was r$lr, but we are about to fetch: ",
 980                     "r$log_entry->{revision}!\n";
 981         }
 982         if (my $c = $self->rev_db_get($log_entry->{revision})) {
 983                 croak "$log_entry->{revision} = $c already exists! ",
 984                       "Why are we refetching it?\n";
 985         }
 986         my $author = $log_entry->{author};
 987         my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
 988                            : ($author, "$author\@".$self->ra->uuid));
 989         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
 990         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
 991         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
 992
 993         my $tree = $log_entry->{tree};
 994         if (!defined $tree) {
 995                 $tree = $self->tmp_index_do(sub {
 996                                             command_oneline('write-tree') });
 997         }
 998         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
 999
1000         my @exec = ('git-commit-tree', $tree);
1001         foreach ($self->get_commit_parents($log_entry)) {
1002                 push @exec, '-p', $_;
1003         }
1004         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1005                                                                    or croak $!;
1006         print $msg_fh $log_entry->{log} or croak $!;
1007         unless ($_no_metadata) {
1008                 print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1009                               $log_entry->{revision}, ' ',
1010                               $self->ra->uuid, "\n" or croak $!;
1011         }
1012         $msg_fh->flush == 0 or croak $!;
1013         close $msg_fh or croak $!;
1014         chomp(my $commit = do { local $/; <$out_fh> });
1015         close $out_fh or croak $!;
1016         waitpid $pid, 0;
1017         croak $? if $?;
1018         if ($commit !~ /^$::sha1$/o) {
1019                 die "Failed to commit, invalid sha1: $commit\n";
1020         }
1021
1022         command_noisy('update-ref',$self->refname, $commit);
1023         $self->rev_db_set($log_entry->{revision}, $commit);
1024
1025         $self->{last_rev} = $log_entry->{revision};
1026         $self->{last_commit} = $commit;
1027         print "r$log_entry->{revision} = $commit ($self->{ref_id})\n";
1028         return $commit;
1029 }
1030
1031 sub revisions_eq {
1032         my ($self, $r0, $r1) = @_;
1033         return 1 if $r0 == $r1;
1034         my $nr = 0;
1035         $self->ra->get_log([$self->{path}], $r0, $r1,
1036                            0, 0, 1, sub { $nr++ });
1037         return 0 if ($nr > 1);
1038         return 1;
1039 }
1040
1041 sub find_parent_branch {
1042         my ($self, $paths, $rev) = @_;
1043         return undef unless $_follow_parent;
1044         unless (defined $paths) {
1045                 my $err_handler = $SVN::Error::handler;
1046                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1047                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1048                                    $paths =
1049                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
1050                 $SVN::Error::handler = $err_handler;
1051         }
1052         return undef unless defined $paths;
1053
1054         # look for a parent from another branch:
1055         my @b_path_components = split m#/#, $self->rel_path;
1056         my @a_path_components;
1057         my $i;
1058         while (@b_path_components) {
1059                 $i = $paths->{'/'.join('/', @b_path_components)};
1060                 last if $i;
1061                 unshift(@a_path_components, pop(@b_path_components));
1062         }
1063         goto not_found unless defined $i;
1064         my $branch_from = $i->{copyfrom_path} or goto not_found;
1065         if (@a_path_components) {
1066                 print STDERR "branch_from: $branch_from => ";
1067                 $branch_from .= '/'.join('/', @a_path_components);
1068                 print STDERR $branch_from, "\n";
1069         }
1070         my $r = $i->{copyfrom_rev};
1071         my $repos_root = $self->ra->{repos_root};
1072         my $url = $self->ra->{url};
1073         my $new_url = $repos_root . $branch_from;
1074         print STDERR  "Found possible branch point: ",
1075                       "$new_url => ", $self->full_url, ", $r\n";
1076         $branch_from =~ s#^/##;
1077         my $remotes = read_all_remotes();
1078         my $gs;
1079         foreach my $repo_id (keys %$remotes) {
1080                 my $u = $remotes->{$repo_id}->{url} or next;
1081                 next if $url ne $u;
1082                 my $fetch = $remotes->{$repo_id}->{fetch};
1083                 foreach my $f (keys %$fetch) {
1084                         next if $f ne $branch_from;
1085                         $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1086                         last;
1087                 }
1088                 last if $gs;
1089         }
1090         unless ($gs) {
1091                 my $ref_id = $self->{ref_id};
1092                 $ref_id =~ s/\@\d+$//;
1093                 $ref_id .= "\@$r";
1094                 # just grow a tail if we're not unique enough :x
1095                 $ref_id .= '-' while find_ref($ref_id);
1096                 print STDERR "Initializing parent: $ref_id\n";
1097                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1098         }
1099         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1100         if ($_follow_parent && (!defined $r0 || !defined $parent)) {
1101                 $gs->fetch(0, $r);
1102                 ($r0, $parent) = $gs->last_rev_commit;
1103         }
1104         if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1105                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1106                 $self->assert_index_clean($parent);
1107                 my $ed;
1108                 if ($self->ra->can_do_switch) {
1109                         print STDERR "Following parent with do_switch\n";
1110                         # do_switch works with svn/trunk >= r22312, but that
1111                         # is not included with SVN 1.4.3 (the latest version
1112                         # at the moment), so we can't rely on it
1113                         $self->{last_commit} = $parent;
1114                         $ed = SVN::Git::Fetcher->new($self);
1115                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1116                                               $self->full_url, $ed)
1117                           or die "SVN connection failed somewhere...\n";
1118                 } else {
1119                         print STDERR "Following parent with do_update\n";
1120                         $ed = SVN::Git::Fetcher->new($self);
1121                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1122                           or die "SVN connection failed somewhere...\n";
1123                 }
1124                 print STDERR "Successfully followed parent\n";
1125                 return $self->make_log_entry($rev, [$parent], $ed);
1126         }
1127 not_found:
1128         print STDERR "Branch parent for path: '/",
1129                      $self->rel_path, "' @ r$rev not found:\n";
1130         return undef unless $paths;
1131         print STDERR "Changed paths:\n";
1132         foreach my $x (sort keys %$paths) {
1133                 my $p = $paths->{$x};
1134                 print STDERR "\t$p->{action}\t$x";
1135                 if ($p->{copyfrom_path}) {
1136                         print STDERR "(from $p->{copyfrom_path}: ",
1137                                      "$p->{copyfrom_rev})";
1138                 }
1139                 print STDERR "\n";
1140         }
1141         print STDERR '-'x72, "\n";
1142         return undef;
1143 }
1144
1145 sub do_fetch {
1146         my ($self, $paths, $rev) = @_;
1147         my $ed;
1148         my ($last_rev, @parents);
1149         if ($self->{last_commit}) {
1150                 $ed = SVN::Git::Fetcher->new($self);
1151                 $last_rev = $self->{last_rev};
1152                 $ed->{c} = $self->{last_commit};
1153                 @parents = ($self->{last_commit});
1154         } else {
1155                 $last_rev = $rev;
1156                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1157                         return $log_entry;
1158                 }
1159                 $ed = SVN::Git::Fetcher->new($self);
1160         }
1161         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1162                 die "SVN connection failed somewhere...\n";
1163         }
1164         $self->make_log_entry($rev, \@parents, $ed);
1165 }
1166
1167 sub get_untracked {
1168         my ($self, $ed) = @_;
1169         my @out;
1170         my $h = $ed->{empty};
1171         foreach (sort keys %$h) {
1172                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1173                 push @out, "  $act: " . uri_encode($_);
1174                 warn "W: $act: $_\n";
1175         }
1176         foreach my $t (qw/dir_prop file_prop/) {
1177                 $h = $ed->{$t} or next;
1178                 foreach my $path (sort keys %$h) {
1179                         my $ppath = $path eq '' ? '.' : $path;
1180                         foreach my $prop (sort keys %{$h->{$path}}) {
1181                                 next if $SKIP_PROP{$prop};
1182                                 my $v = $h->{$path}->{$prop};
1183                                 my $t_ppath_prop = "$t: " .
1184                                                     uri_encode($ppath) . ' ' .
1185                                                     uri_encode($prop);
1186                                 if (defined $v) {
1187                                         push @out, "  +$t_ppath_prop " .
1188                                                    uri_encode($v);
1189                                 } else {
1190                                         push @out, "  -$t_ppath_prop";
1191                                 }
1192                         }
1193                 }
1194         }
1195         foreach my $t (qw/absent_file absent_directory/) {
1196                 $h = $ed->{$t} or next;
1197                 foreach my $parent (sort keys %$h) {
1198                         foreach my $path (sort @{$h->{$parent}}) {
1199                                 push @out, "  $t: " .
1200                                            uri_encode("$parent/$path");
1201                                 warn "W: $t: $parent/$path ",
1202                                      "Insufficient permissions?\n";
1203                         }
1204                 }
1205         }
1206         \@out;
1207 }
1208
1209 sub parse_svn_date {
1210         my $date = shift || return '+0000 1970-01-01 00:00:00';
1211         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1212                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1213                                          croak "Unable to parse date: $date\n";
1214         "+0000 $Y-$m-$d $H:$M:$S";
1215 }
1216
1217 sub check_author {
1218         my ($author) = @_;
1219         if (!defined $author || length $author == 0) {
1220                 $author = '(no author)';
1221         }
1222         if (defined $::_authors && ! defined $::users{$author}) {
1223                 die "Author: $author not defined in $::_authors file\n";
1224         }
1225         $author;
1226 }
1227
1228 sub make_log_entry {
1229         my ($self, $rev, $parents, $ed) = @_;
1230         my $untracked = $self->get_untracked($ed);
1231
1232         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1233         print $un "r$rev\n" or croak $!;
1234         print $un $_, "\n" foreach @$untracked;
1235         my %log_entry = ( parents => $parents || [], revision => $rev,
1236                           log => '');
1237         my $rp = $self->ra->rev_proplist($rev);
1238         foreach (sort keys %$rp) {
1239                 my $v = $rp->{$_};
1240                 if (/^svn:(author|date|log)$/) {
1241                         $log_entry{$1} = $v;
1242                 } else {
1243                         print $un "  rev_prop: ", uri_encode($_), ' ',
1244                                   uri_encode($v), "\n";
1245                 }
1246         }
1247         close $un or croak $!;
1248
1249         $log_entry{date} = parse_svn_date($log_entry{date});
1250         $log_entry{author} = check_author($log_entry{author});
1251         $log_entry{log} .= "\n";
1252         \%log_entry;
1253 }
1254
1255 sub fetch {
1256         my ($self, $min_rev, $max_rev, @parents) = @_;
1257         my ($last_rev, $last_commit) = $self->last_rev_commit;
1258         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1259         return if ($base > $head);
1260         $self->ra->gs_fetch_loop_common($base, $head, $self);
1261 }
1262
1263 sub set_tree_cb {
1264         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1265         # TODO: enable and test optimized commits:
1266         if (0 && $rev == ($self->{last_rev} + 1)) {
1267                 $log_entry->{revision} = $rev;
1268                 $log_entry->{author} = $author;
1269                 $self->do_git_commit($log_entry, "$rev=$tree");
1270         } else {
1271                 $self->{inject_parents} = { $rev => $tree };
1272                 $self->fetch(undef, undef);
1273         }
1274 }
1275
1276 sub set_tree {
1277         my ($self, $tree) = (shift, shift);
1278         my $log_entry = ::get_commit_entry($tree);
1279         unless ($self->{last_rev}) {
1280                 fatal("Must have an existing revision to commit\n");
1281         }
1282         my %ed_opts = ( r => $self->{last_rev},
1283                         log => $log_entry->{log},
1284                         ra => $self->ra,
1285                         tree_a => $self->{last_commit},
1286                         tree_b => $tree,
1287                         editor_cb => sub {
1288                                $self->set_tree_cb($log_entry, $tree, @_) },
1289                         svn_path => $self->{path} );
1290         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1291                 print "No changes\nr$self->{last_rev} = $tree\n";
1292         }
1293 }
1294
1295 sub rebuild {
1296         my ($self) = @_;
1297         print "Rebuilding $self->{db_path} ...\n";
1298         my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1299         my $latest;
1300         my $full_url = $self->full_url;
1301         my $svn_uuid;
1302         while (<$rev_list>) {
1303                 chomp;
1304                 my $c = $_;
1305                 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1306                 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1307
1308                 # ignore merges (from set-tree)
1309                 next if (!defined $rev || !$uuid);
1310
1311                 # if we merged or otherwise started elsewhere, this is
1312                 # how we break out of it
1313                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1314                     ($full_url && $url && ($url ne $full_url))) {
1315                         next;
1316                 }
1317                 $latest ||= $rev;
1318                 $svn_uuid ||= $uuid;
1319
1320                 $self->rev_db_set($rev, $c);
1321                 print "r$rev = $c\n";
1322         }
1323         command_close_pipe($rev_list, $ctx);
1324         print "Done rebuilding $self->{db_path}\n";
1325 }
1326
1327 # rev_db:
1328 # Tie::File seems to be prone to offset errors if revisions get sparse,
1329 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1330 # one of my favorite modules is out :<  Next up would be one of the DBM
1331 # modules, but I'm not sure which is most portable...  So I'll just
1332 # go with something that's plain-text, but still capable of
1333 # being randomly accessed.  So here's my ultra-simple fixed-width
1334 # database.  All records are 40 characters + "\n", so it's easy to seek
1335 # to a revision: (41 * rev) is the byte offset.
1336 # A record of 40 0s denotes an empty revision.
1337 # And yes, it's still pretty fast (faster than Tie::File).
1338
1339 sub rev_db_set {
1340         my ($self, $rev, $commit) = @_;
1341         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1342         open my $fh, '+<', $self->{db_path} or croak $!;
1343         my $offset = $rev * 41;
1344         # assume that append is the common case:
1345         seek $fh, 0, 2 or croak $!;
1346         my $pos = tell $fh;
1347         if ($pos < $offset) {
1348                 for (1 .. (($offset - $pos) / 41)) {
1349                         print $fh (('0' x 40),"\n") or croak $!;
1350                 }
1351         }
1352         seek $fh, $offset, 0 or croak $!;
1353         print $fh $commit,"\n" or croak $!;
1354         close $fh or croak $!;
1355 }
1356
1357 sub rev_db_get {
1358         my ($self, $rev) = @_;
1359         my $ret;
1360         my $offset = $rev * 41;
1361         open my $fh, '<', $self->{db_path} or croak $!;
1362         if (seek $fh, $offset, 0) {
1363                 $ret = readline $fh;
1364                 if (defined $ret) {
1365                         chomp $ret;
1366                         $ret = undef if ($ret =~ /^0{40}$/);
1367                 }
1368         }
1369         close $fh or croak $!;
1370         $ret;
1371 }
1372
1373 sub find_rev_before {
1374         my ($self, $rev, $eq_ok) = @_;
1375         --$rev unless $eq_ok;
1376         while ($rev > 0) {
1377                 if (my $c = $self->rev_db_get($rev)) {
1378                         return ($rev, $c);
1379                 }
1380                 --$rev;
1381         }
1382         return (undef, undef);
1383 }
1384
1385 sub _new {
1386         my ($class, $repo_id, $ref_id, $path) = @_;
1387         unless (defined $repo_id && length $repo_id) {
1388                 $repo_id = $Git::SVN::default_repo_id;
1389         }
1390         unless (defined $ref_id && length $ref_id) {
1391                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1392         }
1393         $_[1] = $repo_id = sanitize_remote_name($repo_id);
1394         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1395         $_[3] = $path = '' unless (defined $path);
1396         mkpath([$dir]);
1397         unless (-f "$dir/.rev_db") {
1398                 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1399                 close $fh or croak $!;
1400         }
1401         bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1402                 path => $path,
1403                 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1404 }
1405
1406 sub uri_encode {
1407         my ($f) = @_;
1408         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1409         $f
1410 }
1411
1412 package Git::SVN::Prompt;
1413 use strict;
1414 use warnings;
1415 require SVN::Core;
1416 use vars qw/$_no_auth_cache $_username/;
1417
1418 sub simple {
1419         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1420         $may_save = undef if $_no_auth_cache;
1421         $default_username = $_username if defined $_username;
1422         if (defined $default_username && length $default_username) {
1423                 if (defined $realm && length $realm) {
1424                         print STDERR "Authentication realm: $realm\n";
1425                         STDERR->flush;
1426                 }
1427                 $cred->username($default_username);
1428         } else {
1429                 username($cred, $realm, $may_save, $pool);
1430         }
1431         $cred->password(_read_password("Password for '" .
1432                                        $cred->username . "': ", $realm));
1433         $cred->may_save($may_save);
1434         $SVN::_Core::SVN_NO_ERROR;
1435 }
1436
1437 sub ssl_server_trust {
1438         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1439         $may_save = undef if $_no_auth_cache;
1440         print STDERR "Error validating server certificate for '$realm':\n";
1441         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1442                 print STDERR " - The certificate is not issued by a trusted ",
1443                       "authority. Use the\n",
1444                       "   fingerprint to validate the certificate manually!\n";
1445         }
1446         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1447                 print STDERR " - The certificate hostname does not match.\n";
1448         }
1449         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1450                 print STDERR " - The certificate is not yet valid.\n";
1451         }
1452         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1453                 print STDERR " - The certificate has expired.\n";
1454         }
1455         if ($failures & $SVN::Auth::SSL::OTHER) {
1456                 print STDERR " - The certificate has an unknown error.\n";
1457         }
1458         printf STDERR
1459                 "Certificate information:\n".
1460                 " - Hostname: %s\n".
1461                 " - Valid: from %s until %s\n".
1462                 " - Issuer: %s\n".
1463                 " - Fingerprint: %s\n",
1464                 map $cert_info->$_, qw(hostname valid_from valid_until
1465                                        issuer_dname fingerprint);
1466         my $choice;
1467 prompt:
1468         print STDERR $may_save ?
1469               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1470               "(R)eject or accept (t)emporarily? ";
1471         STDERR->flush;
1472         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1473         if ($choice =~ /^t$/i) {
1474                 $cred->may_save(undef);
1475         } elsif ($choice =~ /^r$/i) {
1476                 return -1;
1477         } elsif ($may_save && $choice =~ /^p$/i) {
1478                 $cred->may_save($may_save);
1479         } else {
1480                 goto prompt;
1481         }
1482         $cred->accepted_failures($failures);
1483         $SVN::_Core::SVN_NO_ERROR;
1484 }
1485
1486 sub ssl_client_cert {
1487         my ($cred, $realm, $may_save, $pool) = @_;
1488         $may_save = undef if $_no_auth_cache;
1489         print STDERR "Client certificate filename: ";
1490         STDERR->flush;
1491         chomp(my $filename = <STDIN>);
1492         $cred->cert_file($filename);
1493         $cred->may_save($may_save);
1494         $SVN::_Core::SVN_NO_ERROR;
1495 }
1496
1497 sub ssl_client_cert_pw {
1498         my ($cred, $realm, $may_save, $pool) = @_;
1499         $may_save = undef if $_no_auth_cache;
1500         $cred->password(_read_password("Password: ", $realm));
1501         $cred->may_save($may_save);
1502         $SVN::_Core::SVN_NO_ERROR;
1503 }
1504
1505 sub username {
1506         my ($cred, $realm, $may_save, $pool) = @_;
1507         $may_save = undef if $_no_auth_cache;
1508         if (defined $realm && length $realm) {
1509                 print STDERR "Authentication realm: $realm\n";
1510         }
1511         my $username;
1512         if (defined $_username) {
1513                 $username = $_username;
1514         } else {
1515                 print STDERR "Username: ";
1516                 STDERR->flush;
1517                 chomp($username = <STDIN>);
1518         }
1519         $cred->username($username);
1520         $cred->may_save($may_save);
1521         $SVN::_Core::SVN_NO_ERROR;
1522 }
1523
1524 sub _read_password {
1525         my ($prompt, $realm) = @_;
1526         print STDERR $prompt;
1527         STDERR->flush;
1528         require Term::ReadKey;
1529         Term::ReadKey::ReadMode('noecho');
1530         my $password = '';
1531         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1532                 last if $key =~ /[\012\015]/; # \n\r
1533                 $password .= $key;
1534         }
1535         Term::ReadKey::ReadMode('restore');
1536         print STDERR "\n";
1537         STDERR->flush;
1538         $password;
1539 }
1540
1541 package main;
1542
1543 {
1544         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1545                                 $SVN::Node::dir.$SVN::Node::unknown.
1546                                 $SVN::Node::none.$SVN::Node::file.
1547                                 $SVN::Node::dir.$SVN::Node::unknown.
1548                                 $SVN::Auth::SSL::CNMISMATCH.
1549                                 $SVN::Auth::SSL::NOTYETVALID.
1550                                 $SVN::Auth::SSL::EXPIRED.
1551                                 $SVN::Auth::SSL::UNKNOWNCA.
1552                                 $SVN::Auth::SSL::OTHER;
1553 }
1554
1555 package SVN::Git::Fetcher;
1556 use vars qw/@ISA/;
1557 use strict;
1558 use warnings;
1559 use Carp qw/croak/;
1560 use IO::File qw//;
1561 use Digest::MD5;
1562
1563 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1564 sub new {
1565         my ($class, $git_svn) = @_;
1566         my $self = SVN::Delta::Editor->new;
1567         bless $self, $class;
1568         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1569         $self->{empty} = {};
1570         $self->{dir_prop} = {};
1571         $self->{file_prop} = {};
1572         $self->{absent_dir} = {};
1573         $self->{absent_file} = {};
1574         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1575         $self;
1576 }
1577
1578 sub set_path_strip {
1579         my ($self, $path) = @_;
1580         $self->{path_strip} = qr/^\Q$path\E\/?/;
1581 }
1582
1583 sub open_root {
1584         { path => '' };
1585 }
1586
1587 sub open_directory {
1588         my ($self, $path, $pb, $rev) = @_;
1589         { path => $path };
1590 }
1591
1592 sub git_path {
1593         my ($self, $path) = @_;
1594         if ($self->{path_strip}) {
1595                 $path =~ s!$self->{path_strip}!! or
1596                   die "Failed to strip path '$path' ($self->{path_strip})\n";
1597         }
1598         $path;
1599 }
1600
1601 sub delete_entry {
1602         my ($self, $path, $rev, $pb) = @_;
1603
1604         my $gpath = $self->git_path($path);
1605         return undef if ($gpath eq '');
1606
1607         # remove entire directories.
1608         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1609                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1610                                                      -r --name-only -z/,
1611                                                      $self->{c}, '--', $gpath);
1612                 local $/ = "\0";
1613                 while (<$ls>) {
1614                         chomp;
1615                         $self->{gii}->remove($_);
1616                         print "\tD\t$_\n" unless $self->{q};
1617                 }
1618                 print "\tD\t$gpath/\n" unless $self->{q};
1619                 command_close_pipe($ls, $ctx);
1620                 $self->{empty}->{$path} = 0
1621         } else {
1622                 $self->{gii}->remove($gpath);
1623                 print "\tD\t$gpath\n" unless $self->{q};
1624         }
1625         undef;
1626 }
1627
1628 sub open_file {
1629         my ($self, $path, $pb, $rev) = @_;
1630         my $gpath = $self->git_path($path);
1631         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1632                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1633         unless (defined $mode && defined $blob) {
1634                 die "$path was not found in commit $self->{c} (r$rev)\n";
1635         }
1636         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1637           pool => SVN::Pool->new, action => 'M' };
1638 }
1639
1640 sub add_file {
1641         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1642         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1643         delete $self->{empty}->{$dir};
1644         { path => $path, mode_a => 100644, mode_b => 100644,
1645           pool => SVN::Pool->new, action => 'A' };
1646 }
1647
1648 sub add_directory {
1649         my ($self, $path, $cp_path, $cp_rev) = @_;
1650         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1651         delete $self->{empty}->{$dir};
1652         $self->{empty}->{$path} = 1;
1653         { path => $path };
1654 }
1655
1656 sub change_dir_prop {
1657         my ($self, $db, $prop, $value) = @_;
1658         $self->{dir_prop}->{$db->{path}} ||= {};
1659         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1660         undef;
1661 }
1662
1663 sub absent_directory {
1664         my ($self, $path, $pb) = @_;
1665         $self->{absent_dir}->{$pb->{path}} ||= [];
1666         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1667         undef;
1668 }
1669
1670 sub absent_file {
1671         my ($self, $path, $pb) = @_;
1672         $self->{absent_file}->{$pb->{path}} ||= [];
1673         push @{$self->{absent_file}->{$pb->{path}}}, $path;
1674         undef;
1675 }
1676
1677 sub change_file_prop {
1678         my ($self, $fb, $prop, $value) = @_;
1679         if ($prop eq 'svn:executable') {
1680                 if ($fb->{mode_b} != 120000) {
1681                         $fb->{mode_b} = defined $value ? 100755 : 100644;
1682                 }
1683         } elsif ($prop eq 'svn:special') {
1684                 $fb->{mode_b} = defined $value ? 120000 : 100644;
1685         } else {
1686                 $self->{file_prop}->{$fb->{path}} ||= {};
1687                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1688         }
1689         undef;
1690 }
1691
1692 sub apply_textdelta {
1693         my ($self, $fb, $exp) = @_;
1694         my $fh = IO::File->new_tmpfile;
1695         $fh->autoflush(1);
1696         # $fh gets auto-closed() by SVN::TxDelta::apply(),
1697         # (but $base does not,) so dup() it for reading in close_file
1698         open my $dup, '<&', $fh or croak $!;
1699         my $base = IO::File->new_tmpfile;
1700         $base->autoflush(1);
1701         if ($fb->{blob}) {
1702                 defined (my $pid = fork) or croak $!;
1703                 if (!$pid) {
1704                         open STDOUT, '>&', $base or croak $!;
1705                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1706                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1707                 }
1708                 waitpid $pid, 0;
1709                 croak $? if $?;
1710
1711                 if (defined $exp) {
1712                         seek $base, 0, 0 or croak $!;
1713                         my $md5 = Digest::MD5->new;
1714                         $md5->addfile($base);
1715                         my $got = $md5->hexdigest;
1716                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1717                             "expected: $exp\n",
1718                             "     got: $got\n" if ($got ne $exp);
1719                 }
1720         }
1721         seek $base, 0, 0 or croak $!;
1722         $fb->{fh} = $dup;
1723         $fb->{base} = $base;
1724         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1725 }
1726
1727 sub close_file {
1728         my ($self, $fb, $exp) = @_;
1729         my $hash;
1730         my $path = $self->git_path($fb->{path});
1731         if (my $fh = $fb->{fh}) {
1732                 seek($fh, 0, 0) or croak $!;
1733                 my $md5 = Digest::MD5->new;
1734                 $md5->addfile($fh);
1735                 my $got = $md5->hexdigest;
1736                 die "Checksum mismatch: $path\n",
1737                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
1738                 seek($fh, 0, 0) or croak $!;
1739                 if ($fb->{mode_b} == 120000) {
1740                         read($fh, my $buf, 5) == 5 or croak $!;
1741                         $buf eq 'link ' or die "$path has mode 120000",
1742                                                "but is not a link\n";
1743                 }
1744                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1745                 if (!$pid) {
1746                         open STDIN, '<&', $fh or croak $!;
1747                         exec qw/git-hash-object -w --stdin/ or croak $!;
1748                 }
1749                 chomp($hash = do { local $/; <$out> });
1750                 close $out or croak $!;
1751                 close $fh or croak $!;
1752                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1753                 close $fb->{base} or croak $!;
1754         } else {
1755                 $hash = $fb->{blob} or die "no blob information\n";
1756         }
1757         $fb->{pool}->clear;
1758         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1759         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1760         undef;
1761 }
1762
1763 sub abort_edit {
1764         my $self = shift;
1765         $self->{nr} = $self->{gii}->{nr};
1766         delete $self->{gii};
1767         $self->SUPER::abort_edit(@_);
1768 }
1769
1770 sub close_edit {
1771         my $self = shift;
1772         $self->{git_commit_ok} = 1;
1773         $self->{nr} = $self->{gii}->{nr};
1774         delete $self->{gii};
1775         $self->SUPER::close_edit(@_);
1776 }
1777
1778 package SVN::Git::Editor;
1779 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
1780 use strict;
1781 use warnings;
1782 use Carp qw/croak/;
1783 use IO::File;
1784 use Digest::MD5;
1785
1786 sub new {
1787         my ($class, $opts) = @_;
1788         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
1789                 die "$_ required!\n" unless (defined $opts->{$_});
1790         }
1791
1792         my $pool = SVN::Pool->new;
1793         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
1794         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
1795                                      $opts->{r}, $mods);
1796
1797         # $opts->{ra} functions should not be used after this:
1798         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
1799                                                 $opts->{editor_cb}, $pool);
1800         my $self = SVN::Delta::Editor->new(@ce, $pool);
1801         bless $self, $class;
1802         foreach (qw/svn_path r tree_a tree_b/) {
1803                 $self->{$_} = $opts->{$_};
1804         }
1805         $self->{url} = $opts->{ra}->{url};
1806         $self->{mods} = $mods;
1807         $self->{types} = $types;
1808         $self->{pool} = $pool;
1809         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1810         $self->{rm} = { };
1811         $self->{path_prefix} = length $self->{svn_path} ?
1812                                "$self->{svn_path}/" : '';
1813         return $self;
1814 }
1815
1816 sub generate_diff {
1817         my ($tree_a, $tree_b) = @_;
1818         my @diff_tree = qw(diff-tree -z -r);
1819         if ($_cp_similarity) {
1820                 push @diff_tree, "-C$_cp_similarity";
1821         } else {
1822                 push @diff_tree, '-C';
1823         }
1824         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
1825         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
1826         push @diff_tree, $tree_a, $tree_b;
1827         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1828         local $/ = "\0";
1829         my $state = 'meta';
1830         my @mods;
1831         while (<$diff_fh>) {
1832                 chomp $_; # this gets rid of the trailing "\0"
1833                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1834                                         $::sha1\s($::sha1)\s
1835                                         ([MTCRAD])\d*$/xo) {
1836                         push @mods, {   mode_a => $1, mode_b => $2,
1837                                         sha1_b => $3, chg => $4 };
1838                         if ($4 =~ /^(?:C|R)$/) {
1839                                 $state = 'file_a';
1840                         } else {
1841                                 $state = 'file_b';
1842                         }
1843                 } elsif ($state eq 'file_a') {
1844                         my $x = $mods[$#mods] or croak "Empty array\n";
1845                         if ($x->{chg} !~ /^(?:C|R)$/) {
1846                                 croak "Error parsing $_, $x->{chg}\n";
1847                         }
1848                         $x->{file_a} = $_;
1849                         $state = 'file_b';
1850                 } elsif ($state eq 'file_b') {
1851                         my $x = $mods[$#mods] or croak "Empty array\n";
1852                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1853                                 croak "Error parsing $_, $x->{chg}\n";
1854                         }
1855                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1856                                 croak "Error parsing $_, $x->{chg}\n";
1857                         }
1858                         $x->{file_b} = $_;
1859                         $state = 'meta';
1860                 } else {
1861                         croak "Error parsing $_\n";
1862                 }
1863         }
1864         command_close_pipe($diff_fh, $ctx);
1865         \@mods;
1866 }
1867
1868 sub check_diff_paths {
1869         my ($ra, $pfx, $rev, $mods) = @_;
1870         my %types;
1871         $pfx .= '/' if length $pfx;
1872
1873         sub type_diff_paths {
1874                 my ($ra, $types, $path, $rev) = @_;
1875                 my @p = split m#/+#, $path;
1876                 my $c = shift @p;
1877                 unless (defined $types->{$c}) {
1878                         $types->{$c} = $ra->check_path($c, $rev);
1879                 }
1880                 while (@p) {
1881                         $c .= '/' . shift @p;
1882                         next if defined $types->{$c};
1883                         $types->{$c} = $ra->check_path($c, $rev);
1884                 }
1885         }
1886
1887         foreach my $m (@$mods) {
1888                 foreach my $f (qw/file_a file_b/) {
1889                         next unless defined $m->{$f};
1890                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
1891                         if (length $pfx.$dir && ! defined $types{$dir}) {
1892                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
1893                         }
1894                 }
1895         }
1896         \%types;
1897 }
1898
1899 sub split_path {
1900         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1901 }
1902
1903 sub repo_path {
1904         my ($self, $path) = @_;
1905         $self->{path_prefix}.(defined $path ? $path : '');
1906 }
1907
1908 sub url_path {
1909         my ($self, $path) = @_;
1910         $self->{url} . '/' . $self->repo_path($path);
1911 }
1912
1913 sub rmdirs {
1914         my ($self) = @_;
1915         my $rm = $self->{rm};
1916         delete $rm->{''}; # we never delete the url we're tracking
1917         return unless %$rm;
1918
1919         foreach (keys %$rm) {
1920                 my @d = split m#/#, $_;
1921                 my $c = shift @d;
1922                 $rm->{$c} = 1;
1923                 while (@d) {
1924                         $c .= '/' . shift @d;
1925                         $rm->{$c} = 1;
1926                 }
1927         }
1928         delete $rm->{$self->{svn_path}};
1929         delete $rm->{''}; # we never delete the url we're tracking
1930         return unless %$rm;
1931
1932         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
1933                                              $self->{tree_b});
1934         local $/ = "\0";
1935         while (<$fh>) {
1936                 chomp;
1937                 my @dn = split m#/#, $_;
1938                 while (pop @dn) {
1939                         delete $rm->{join '/', @dn};
1940                 }
1941                 unless (%$rm) {
1942                         close $fh;
1943                         return;
1944                 }
1945         }
1946         command_close_pipe($fh, $ctx);
1947
1948         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1949         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1950                 $self->close_directory($bat->{$d}, $p);
1951                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1952                 print "\tD+\t$d/\n" unless $::_q;
1953                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1954                 delete $bat->{$d};
1955         }
1956 }
1957
1958 sub open_or_add_dir {
1959         my ($self, $full_path, $baton) = @_;
1960         my $t = $self->{types}->{$full_path};
1961         if (!defined $t) {
1962                 die "$full_path not known in r$self->{r} or we have a bug!\n";
1963         }
1964         if ($t == $SVN::Node::none) {
1965                 return $self->add_directory($full_path, $baton,
1966                                                 undef, -1, $self->{pool});
1967         } elsif ($t == $SVN::Node::dir) {
1968                 return $self->open_directory($full_path, $baton,
1969                                                 $self->{r}, $self->{pool});
1970         }
1971         print STDERR "$full_path already exists in repository at ",
1972                 "r$self->{r} and it is not a directory (",
1973                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
1974         exit 1;
1975 }
1976
1977 sub ensure_path {
1978         my ($self, $path) = @_;
1979         my $bat = $self->{bat};
1980         my $repo_path = $self->repo_path($path);
1981         return $bat->{''} unless (length $repo_path);
1982         my @p = split m#/+#, $repo_path;
1983         my $c = shift @p;
1984         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
1985         while (@p) {
1986                 my $c0 = $c;
1987                 $c .= '/' . shift @p;
1988                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
1989         }
1990         return $bat->{$c};
1991 }
1992
1993 sub A {
1994         my ($self, $m) = @_;
1995         my ($dir, $file) = split_path($m->{file_b});
1996         my $pbat = $self->ensure_path($dir);
1997         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1998                                         undef, -1);
1999         print "\tA\t$m->{file_b}\n" unless $::_q;
2000         $self->chg_file($fbat, $m);
2001         $self->close_file($fbat,undef,$self->{pool});
2002 }
2003
2004 sub C {
2005         my ($self, $m) = @_;
2006         my ($dir, $file) = split_path($m->{file_b});
2007         my $pbat = $self->ensure_path($dir);
2008         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2009                                 $self->url_path($m->{file_a}), $self->{r});
2010         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2011         $self->chg_file($fbat, $m);
2012         $self->close_file($fbat,undef,$self->{pool});
2013 }
2014
2015 sub delete_entry {
2016         my ($self, $path, $pbat) = @_;
2017         my $rpath = $self->repo_path($path);
2018         my ($dir, $file) = split_path($rpath);
2019         $self->{rm}->{$dir} = 1;
2020         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2021 }
2022
2023 sub R {
2024         my ($self, $m) = @_;
2025         my ($dir, $file) = split_path($m->{file_b});
2026         my $pbat = $self->ensure_path($dir);
2027         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2028                                 $self->url_path($m->{file_a}), $self->{r});
2029         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2030         $self->chg_file($fbat, $m);
2031         $self->close_file($fbat,undef,$self->{pool});
2032
2033         ($dir, $file) = split_path($m->{file_a});
2034         $pbat = $self->ensure_path($dir);
2035         $self->delete_entry($m->{file_a}, $pbat);
2036 }
2037
2038 sub M {
2039         my ($self, $m) = @_;
2040         my ($dir, $file) = split_path($m->{file_b});
2041         my $pbat = $self->ensure_path($dir);
2042         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2043                                 $pbat,$self->{r},$self->{pool});
2044         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2045         $self->chg_file($fbat, $m);
2046         $self->close_file($fbat,undef,$self->{pool});
2047 }
2048
2049 sub T { shift->M(@_) }
2050
2051 sub change_file_prop {
2052         my ($self, $fbat, $pname, $pval) = @_;
2053         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2054 }
2055
2056 sub chg_file {
2057         my ($self, $fbat, $m) = @_;
2058         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2059                 $self->change_file_prop($fbat,'svn:executable','*');
2060         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2061                 $self->change_file_prop($fbat,'svn:executable',undef);
2062         }
2063         my $fh = IO::File->new_tmpfile or croak $!;
2064         if ($m->{mode_b} =~ /^120/) {
2065                 print $fh 'link ' or croak $!;
2066                 $self->change_file_prop($fbat,'svn:special','*');
2067         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2068                 $self->change_file_prop($fbat,'svn:special',undef);
2069         }
2070         defined(my $pid = fork) or croak $!;
2071         if (!$pid) {
2072                 open STDOUT, '>&', $fh or croak $!;
2073                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2074         }
2075         waitpid $pid, 0;
2076         croak $? if $?;
2077         $fh->flush == 0 or croak $!;
2078         seek $fh, 0, 0 or croak $!;
2079
2080         my $md5 = Digest::MD5->new;
2081         $md5->addfile($fh) or croak $!;
2082         seek $fh, 0, 0 or croak $!;
2083
2084         my $exp = $md5->hexdigest;
2085         my $pool = SVN::Pool->new;
2086         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2087         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2088         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2089         $pool->clear;
2090
2091         close $fh or croak $!;
2092 }
2093
2094 sub D {
2095         my ($self, $m) = @_;
2096         my ($dir, $file) = split_path($m->{file_b});
2097         my $pbat = $self->ensure_path($dir);
2098         print "\tD\t$m->{file_b}\n" unless $::_q;
2099         $self->delete_entry($m->{file_b}, $pbat);
2100 }
2101
2102 sub close_edit {
2103         my ($self) = @_;
2104         my ($p,$bat) = ($self->{pool}, $self->{bat});
2105         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2106                 $self->close_directory($bat->{$_}, $p);
2107         }
2108         $self->SUPER::close_edit($p);
2109         $p->clear;
2110 }
2111
2112 sub abort_edit {
2113         my ($self) = @_;
2114         $self->SUPER::abort_edit($self->{pool});
2115 }
2116
2117 sub DESTROY {
2118         my $self = shift;
2119         $self->SUPER::DESTROY(@_);
2120         $self->{pool}->clear;
2121 }
2122
2123 # this drives the editor
2124 sub apply_diff {
2125         my ($self) = @_;
2126         my $mods = $self->{mods};
2127         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2128         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2129                 my $f = $m->{chg};
2130                 if (defined $o{$f}) {
2131                         $self->$f($m);
2132                 } else {
2133                         fatal("Invalid change type: $f\n");
2134                 }
2135         }
2136         $self->rmdirs if $_rmdir;
2137         if (@$mods == 0) {
2138                 $self->abort_edit;
2139         } else {
2140                 $self->close_edit;
2141         }
2142         return scalar @$mods;
2143 }
2144
2145 package Git::SVN::Ra;
2146 use vars qw/@ISA $config_dir/;
2147 use strict;
2148 use warnings;
2149 my ($can_do_switch);
2150 my $RA;
2151
2152 BEGIN {
2153         # enforce temporary pool usage for some simple functions
2154         my $e;
2155         foreach (qw/get_latest_revnum rev_proplist get_file
2156                     check_path get_dir get_uuid get_repos_root/) {
2157                 $e .= "sub $_ {
2158                         my \$self = shift;
2159                         my \$pool = SVN::Pool->new;
2160                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2161                         \$pool->clear;
2162                         wantarray ? \@ret : \$ret[0]; }\n";
2163         }
2164         eval $e;
2165 }
2166
2167 sub new {
2168         my ($class, $url) = @_;
2169         $url =~ s!/+$!!;
2170         return $RA if ($RA && $RA->{url} eq $url);
2171
2172         SVN::_Core::svn_config_ensure($config_dir, undef);
2173         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2174             SVN::Client::get_simple_provider(),
2175             SVN::Client::get_ssl_server_trust_file_provider(),
2176             SVN::Client::get_simple_prompt_provider(
2177               \&Git::SVN::Prompt::simple, 2),
2178             SVN::Client::get_ssl_client_cert_prompt_provider(
2179               \&Git::SVN::Prompt::ssl_client_cert, 2),
2180             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2181               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2182             SVN::Client::get_username_provider(),
2183             SVN::Client::get_ssl_server_trust_prompt_provider(
2184               \&Git::SVN::Prompt::ssl_server_trust),
2185             SVN::Client::get_username_prompt_provider(
2186               \&Git::SVN::Prompt::username, 2),
2187           ]);
2188         my $config = SVN::Core::config_get_config($config_dir);
2189         my $self = SVN::Ra->new(url => $url, auth => $baton,
2190                               config => $config,
2191                               pool => SVN::Pool->new,
2192                               auth_provider_callbacks => $callbacks);
2193         $self->{svn_path} = $url;
2194         $self->{repos_root} = $self->get_repos_root;
2195         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2196         $RA = bless $self, $class;
2197 }
2198
2199 sub DESTROY {
2200         # do not call the real DESTROY since we store ourselves in $RA
2201 }
2202
2203 sub get_log {
2204         my ($self, @args) = @_;
2205         my $pool = SVN::Pool->new;
2206         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2207         my $ret = $self->SUPER::get_log(@args, $pool);
2208         $pool->clear;
2209         $ret;
2210 }
2211
2212 sub get_commit_editor {
2213         my ($self, $log, $cb, $pool) = @_;
2214         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2215         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2216 }
2217
2218 sub uuid {
2219         my ($self) = @_;
2220         $self->{uuid} ||= $self->get_uuid;
2221 }
2222
2223 sub gs_do_update {
2224         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
2225         my $new = ($rev_a == $rev_b);
2226         my $path = $gs->{path};
2227
2228         my $ta = $self->check_path($path, $rev_a);
2229         my $tb = $new ? $ta : $self->check_path($path, $rev_b);
2230         return 1 if ($tb != $SVN::Node::dir && $ta != $SVN::Node::dir);
2231         if ($ta == $SVN::Node::none) {
2232                 $rev_a = $rev_b;
2233                 $new = 1;
2234         }
2235
2236         my $pool = SVN::Pool->new;
2237         $editor->set_path_strip($path);
2238         my (@pc) = split m#/#, $path;
2239         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2240                                         1, $editor, $pool);
2241         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2242
2243         # Since we can't rely on svn_ra_reparent being available, we'll
2244         # just have to do some magic with set_path to make it so
2245         # we only want a partial path.
2246         my $sp = '';
2247         my $final = join('/', @pc);
2248         while (@pc) {
2249                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2250                 $sp .= '/' if length $sp;
2251                 $sp .= shift @pc;
2252         }
2253         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2254
2255         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2256
2257         $reporter->finish_report($pool);
2258         $pool->clear;
2259         $editor->{git_commit_ok};
2260 }
2261
2262 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2263 # svn_ra_reparent didn't work before 1.4)
2264 sub gs_do_switch {
2265         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
2266         my $path = $gs->{path};
2267         my $pool = SVN::Pool->new;
2268
2269         my $full_url = $self->{url};
2270         my $old_url = $full_url;
2271         $full_url .= "/$path" if length $path;
2272         my ($ra, $reparented);
2273         if ($old_url ne $full_url) {
2274                 if ($old_url !~ m#^svn(\+ssh)?://#) {
2275                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
2276                                                   $pool);
2277                         $self->{url} = $full_url;
2278                         $reparented = 1;
2279                 } else {
2280                         $ra = Git::SVN::Ra->new($full_url);
2281                 }
2282         }
2283         $ra ||= $self;
2284         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
2285         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2286         $reporter->set_path('', $rev_a, 0, @lock, $pool);
2287         $reporter->finish_report($pool);
2288
2289         if ($reparented) {
2290                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
2291                 $self->{url} = $old_url;
2292         }
2293
2294         $pool->clear;
2295         $editor->{git_commit_ok};
2296 }
2297
2298 sub gs_fetch_loop_common {
2299         my ($self, $base, $head, @gs) = @_;
2300         my $inc = 1000;
2301         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
2302         foreach my $gs (@gs) {
2303                 if (my $last_commit = $gs->last_commit) {
2304                         $gs->assert_index_clean($last_commit);
2305                 }
2306         }
2307         while (1) {
2308                 my %revs;
2309                 my $err;
2310                 my $err_handler = $SVN::Error::handler;
2311                 $SVN::Error::handler = sub {
2312                         ($err) = @_;
2313                         skip_unknown_revs($err);
2314                 };
2315                 foreach my $gs (@gs) {
2316                         $self->get_log([$gs->{path}], $min, $max, 0, 1, 1, sub
2317                                        { my ($paths, $rev) = @_;
2318                                          push @{$revs{$rev}},
2319                                               [ $gs,
2320                                                 dup_changed_paths($paths) ] });
2321
2322                         next unless ($err && $max >= $head);
2323
2324                         print STDERR "Path '$gs->{path}' ",
2325                                      "was probably deleted:\n",
2326                                      $err->expanded_message,
2327                                      "\nWill attempt to follow ",
2328                                      "revisions r$min .. r$max ",
2329                                      "committed before the deletion\n";
2330                         my $hi = $max;
2331                         while (--$hi >= $min) {
2332                                 my $ok;
2333                                 $self->get_log([$gs->{path}], $min, $hi,
2334                                                0, 1, 1, sub {
2335                                         my ($paths, $rev) = @_;
2336                                         $ok = $rev;
2337                                         push @{$revs{$rev}}, [ $gs,
2338                                            dup_changed_paths($_[0])]});
2339                                 if ($ok) {
2340                                         print STDERR "r$min .. r$ok OK\n";
2341                                         last;
2342                                 }
2343                         }
2344                 }
2345                 $SVN::Error::handler = $err_handler;
2346                 foreach my $r (sort {$a <=> $b} keys %revs) {
2347                         foreach (@{$revs{$r}}) {
2348                                 my ($gs, $paths) = @$_;
2349                                 my $lr = $gs->last_rev;
2350                                 next if defined $lr && $lr >= $r;
2351                                 next if defined $gs->rev_db_get($r);
2352                                 if (my $log_entry = $gs->do_fetch($paths, $r)) {
2353                                         $gs->do_git_commit($log_entry);
2354                                 }
2355                         }
2356                 }
2357                 last if $max >= $head;
2358                 $min = $max + 1;
2359                 $max += $inc;
2360                 $max = $head if ($max > $head);
2361         }
2362 }
2363
2364 sub minimize_url {
2365         my ($self) = @_;
2366         return $self->{url} if ($self->{url} eq $self->{repos_root});
2367         my $url = $self->{repos_root};
2368         my @components = split(m!/!, $self->{svn_path});
2369         my $c = '';
2370         do {
2371                 $url .= "/$c" if length $c;
2372                 eval { (ref $self)->new($url)->get_latest_revnum };
2373         } while ($@ && ($c = shift @components));
2374         $url;
2375 }
2376
2377 sub can_do_switch {
2378         my $self = shift;
2379         unless (defined $can_do_switch) {
2380                 my $pool = SVN::Pool->new;
2381                 my $rep = eval {
2382                         $self->do_switch(1, '', 0, $self->{url},
2383                                          SVN::Delta::Editor->new, $pool);
2384                 };
2385                 if ($@) {
2386                         $can_do_switch = 0;
2387                 } else {
2388                         $rep->abort_report($pool);
2389                         $can_do_switch = 1;
2390                 }
2391                 $pool->clear;
2392         }
2393         $can_do_switch;
2394 }
2395
2396 sub skip_unknown_revs {
2397         my ($err) = @_;
2398         my $errno = $err->apr_err();
2399         # Maybe the branch we're tracking didn't
2400         # exist when the repo started, so it's
2401         # not an error if it doesn't, just continue
2402         #
2403         # Wonderfully consistent library, eh?
2404         # 160013 - svn:// and file://
2405         # 175002 - http(s)://
2406         # 175007 - http(s):// (this repo required authorization, too...)
2407         #   More codes may be discovered later...
2408         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2409                 return;
2410         }
2411         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2412 }
2413
2414 # svn_log_changed_path_t objects passed to get_log are likely to be
2415 # overwritten even if only the refs are copied to an external variable,
2416 # so we should dup the structures in their entirety.  Using an externally
2417 # passed pool (instead of our temporary and quickly cleared pool in
2418 # Git::SVN::Ra) does not help matters at all...
2419 sub dup_changed_paths {
2420         my ($paths) = @_;
2421         return undef unless $paths;
2422         my %ret;
2423         foreach my $p (keys %$paths) {
2424                 my $i = $paths->{$p};
2425                 my %s = map { $_ => $i->$_ }
2426                               qw/copyfrom_path copyfrom_rev action/;
2427                 $ret{$p} = \%s;
2428         }
2429         \%ret;
2430 }
2431
2432 package Git::SVN::Log;
2433 use strict;
2434 use warnings;
2435 use POSIX qw/strftime/;
2436 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2437             %rusers $show_commit $incremental/;
2438 my $l_fmt;
2439
2440 sub cmt_showable {
2441         my ($c) = @_;
2442         return 1 if defined $c->{r};
2443         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2444                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2445                 my @log = command(qw/cat-file commit/, $c->{c});
2446                 shift @log while ($log[0] ne "\n");
2447                 shift @log;
2448                 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2449
2450                 (undef, $c->{r}, undef) = ::extract_metadata(
2451                                 (grep(/^git-svn-id: /, @log))[-1]);
2452         }
2453         return defined $c->{r};
2454 }
2455
2456 sub log_use_color {
2457         return 1 if $color;
2458         my ($dc, $dcvar);
2459         $dcvar = 'color.diff';
2460         $dc = `git-config --get $dcvar`;
2461         if ($dc eq '') {
2462                 # nothing at all; fallback to "diff.color"
2463                 $dcvar = 'diff.color';
2464                 $dc = `git-config --get $dcvar`;
2465         }
2466         chomp($dc);
2467         if ($dc eq 'auto') {
2468                 my $pc;
2469                 $pc = `git-config --get color.pager`;
2470                 if ($pc eq '') {
2471                         # does not have it -- fallback to pager.color
2472                         $pc = `git-config --bool --get pager.color`;
2473                 }
2474                 else {
2475                         $pc = `git-config --bool --get color.pager`;
2476                         if ($?) {
2477                                 $pc = 'false';
2478                         }
2479                 }
2480                 chomp($pc);
2481                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2482                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2483                 }
2484                 return 0;
2485         }
2486         return 0 if $dc eq 'never';
2487         return 1 if $dc eq 'always';
2488         chomp($dc = `git-config --bool --get $dcvar`);
2489         return ($dc eq 'true');
2490 }
2491
2492 sub git_svn_log_cmd {
2493         my ($r_min, $r_max) = @_;
2494         my $gs = Git::SVN->_new;
2495         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2496                    $gs->refname);
2497         push @cmd, '-r' unless $non_recursive;
2498         push @cmd, qw/--raw --name-status/ if $verbose;
2499         push @cmd, '--color' if log_use_color();
2500         return @cmd unless defined $r_max;
2501         if ($r_max == $r_min) {
2502                 push @cmd, '--max-count=1';
2503                 if (my $c = $gs->rev_db_get($r_max)) {
2504                         push @cmd, $c;
2505                 }
2506         } else {
2507                 my ($c_min, $c_max);
2508                 $c_max = $gs->rev_db_get($r_max);
2509                 $c_min = $gs->rev_db_get($r_min);
2510                 if (defined $c_min && defined $c_max) {
2511                         if ($r_max > $r_max) {
2512                                 push @cmd, "$c_min..$c_max";
2513                         } else {
2514                                 push @cmd, "$c_max..$c_min";
2515                         }
2516                 } elsif ($r_max > $r_min) {
2517                         push @cmd, $c_max;
2518                 } else {
2519                         push @cmd, $c_min;
2520                 }
2521         }
2522         return @cmd;
2523 }
2524
2525 # adapted from pager.c
2526 sub config_pager {
2527         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2528         if (!defined $pager) {
2529                 $pager = 'less';
2530         } elsif (length $pager == 0 || $pager eq 'cat') {
2531                 $pager = undef;
2532         }
2533 }
2534
2535 sub run_pager {
2536         return unless -t *STDOUT;
2537         pipe my $rfd, my $wfd or return;
2538         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2539         if (!$pid) {
2540                 open STDOUT, '>&', $wfd or
2541                                      ::fatal "Can't redirect to stdout: $!\n";
2542                 return;
2543         }
2544         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2545         $ENV{LESS} ||= 'FRSX';
2546         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2547 }
2548
2549 sub tz_to_s_offset {
2550         my ($tz) = @_;
2551         $tz =~ s/(\d\d)$//;
2552         return ($1 * 60) + ($tz * 3600);
2553 }
2554
2555 sub get_author_info {
2556         my ($dest, $author, $t, $tz) = @_;
2557         $author =~ s/(?:^\s*|\s*$)//g;
2558         $dest->{a_raw} = $author;
2559         my $au;
2560         if ($::_authors) {
2561                 $au = $rusers{$author} || undef;
2562         }
2563         if (!$au) {
2564                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2565         }
2566         $dest->{t} = $t;
2567         $dest->{tz} = $tz;
2568         $dest->{a} = $au;
2569         # Date::Parse isn't in the standard Perl distro :(
2570         if ($tz =~ s/^\+//) {
2571                 $t += tz_to_s_offset($tz);
2572         } elsif ($tz =~ s/^\-//) {
2573                 $t -= tz_to_s_offset($tz);
2574         }
2575         $dest->{t_utc} = $t;
2576 }
2577
2578 sub process_commit {
2579         my ($c, $r_min, $r_max, $defer) = @_;
2580         if (defined $r_min && defined $r_max) {
2581                 if ($r_min == $c->{r} && $r_min == $r_max) {
2582                         show_commit($c);
2583                         return 0;
2584                 }
2585                 return 1 if $r_min == $r_max;
2586                 if ($r_min < $r_max) {
2587                         # we need to reverse the print order
2588                         return 0 if (defined $limit && --$limit < 0);
2589                         push @$defer, $c;
2590                         return 1;
2591                 }
2592                 if ($r_min != $r_max) {
2593                         return 1 if ($r_min < $c->{r});
2594                         return 1 if ($r_max > $c->{r});
2595                 }
2596         }
2597         return 0 if (defined $limit && --$limit < 0);
2598         show_commit($c);
2599         return 1;
2600 }
2601
2602 sub show_commit {
2603         my $c = shift;
2604         if ($oneline) {
2605                 my $x = "\n";
2606                 if (my $l = $c->{l}) {
2607                         while ($l->[0] =~ /^\s*$/) { shift @$l }
2608                         $x = $l->[0];
2609                 }
2610                 $l_fmt ||= 'A' . length($c->{r});
2611                 print 'r',pack($l_fmt, $c->{r}),' | ';
2612                 print "$c->{c} | " if $show_commit;
2613                 print $x;
2614         } else {
2615                 show_commit_normal($c);
2616         }
2617 }
2618
2619 sub show_commit_changed_paths {
2620         my ($c) = @_;
2621         return unless $c->{changed};
2622         print "Changed paths:\n", @{$c->{changed}};
2623 }
2624
2625 sub show_commit_normal {
2626         my ($c) = @_;
2627         print '-' x72, "\nr$c->{r} | ";
2628         print "$c->{c} | " if $show_commit;
2629         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2630                                  localtime($c->{t_utc})), ' | ';
2631         my $nr_line = 0;
2632
2633         if (my $l = $c->{l}) {
2634                 while ($l->[$#$l] eq "\n" && $#$l > 0
2635                                           && $l->[($#$l - 1)] eq "\n") {
2636                         pop @$l;
2637                 }
2638                 $nr_line = scalar @$l;
2639                 if (!$nr_line) {
2640                         print "1 line\n\n\n";
2641                 } else {
2642                         if ($nr_line == 1) {
2643                                 $nr_line = '1 line';
2644                         } else {
2645                                 $nr_line .= ' lines';
2646                         }
2647                         print $nr_line, "\n";
2648                         show_commit_changed_paths($c);
2649                         print "\n";
2650                         print $_ foreach @$l;
2651                 }
2652         } else {
2653                 print "1 line\n";
2654                 show_commit_changed_paths($c);
2655                 print "\n";
2656
2657         }
2658         foreach my $x (qw/raw diff/) {
2659                 if ($c->{$x}) {
2660                         print "\n";
2661                         print $_ foreach @{$c->{$x}}
2662                 }
2663         }
2664 }
2665
2666 sub cmd_show_log {
2667         my (@args) = @_;
2668         my ($r_min, $r_max);
2669         my $r_last = -1; # prevent dupes
2670         if (defined $TZ) {
2671                 $ENV{TZ} = $TZ;
2672         } else {
2673                 delete $ENV{TZ};
2674         }
2675         if (defined $::_revision) {
2676                 if ($::_revision =~ /^(\d+):(\d+)$/) {
2677                         ($r_min, $r_max) = ($1, $2);
2678                 } elsif ($::_revision =~ /^\d+$/) {
2679                         $r_min = $r_max = $::_revision;
2680                 } else {
2681                         ::fatal "-r$::_revision is not supported, use ",
2682                                 "standard \'git log\' arguments instead\n";
2683                 }
2684         }
2685
2686         config_pager();
2687         @args = (git_svn_log_cmd($r_min, $r_max), @args);
2688         my $log = command_output_pipe(@args);
2689         run_pager();
2690         my (@k, $c, $d);
2691         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2692         while (<$log>) {
2693                 if (/^${esc_color}commit ($::sha1_short)/o) {
2694                         my $cmt = $1;
2695                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2696                                 $r_last = $c->{r};
2697                                 process_commit($c, $r_min, $r_max, \@k) or
2698                                                                 goto out;
2699                         }
2700                         $d = undef;
2701                         $c = { c => $cmt };
2702                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2703                         get_author_info($c, $1, $2, $3);
2704                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2705                         # ignore
2706                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2707                         push @{$c->{raw}}, $_;
2708                 } elsif (/^${esc_color}[ACRMDT]\t/) {
2709                         # we could add $SVN->{svn_path} here, but that requires
2710                         # remote access at the moment (repo_path_split)...
2711                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
2712                         push @{$c->{changed}}, $_;
2713                 } elsif (/^${esc_color}diff /o) {
2714                         $d = 1;
2715                         push @{$c->{diff}}, $_;
2716                 } elsif ($d) {
2717                         push @{$c->{diff}}, $_;
2718                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
2719                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2720                 } elsif (s/^${esc_color}    //o) {
2721                         push @{$c->{l}}, $_;
2722                 }
2723         }
2724         if ($c && defined $c->{r} && $c->{r} != $r_last) {
2725                 $r_last = $c->{r};
2726                 process_commit($c, $r_min, $r_max, \@k);
2727         }
2728         if (@k) {
2729                 my $swap = $r_max;
2730                 $r_max = $r_min;
2731                 $r_min = $swap;
2732                 process_commit($_, $r_min, $r_max) foreach reverse @k;
2733         }
2734 out:
2735         close $log;
2736         print '-' x72,"\n" unless $incremental || $oneline;
2737 }
2738
2739 package Git::SVN::Migration;
2740 # these version numbers do NOT correspond to actual version numbers
2741 # of git nor git-svn.  They are just relative.
2742 #
2743 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2744 #
2745 # v1 layout: .git/$id/info/url, refs/remotes/$id
2746 #
2747 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2748 #
2749 # v3 layout: .git/svn/$id, refs/remotes/$id
2750 #            - info/url may remain for backwards compatibility
2751 #            - this is what we migrate up to this layout automatically,
2752 #            - this will be used by git svn init on single branches
2753 #
2754 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2755 #            - this is only created for newly multi-init-ed
2756 #              repositories.  Similar in spirit to the
2757 #              --use-separate-remotes option in git-clone (now default)
2758 #            - we do not automatically migrate to this (following
2759 #              the example set by core git)
2760 use strict;
2761 use warnings;
2762 use Carp qw/croak/;
2763 use File::Path qw/mkpath/;
2764 use File::Basename qw/dirname basename/;
2765 use vars qw/$_minimize/;
2766
2767 sub migrate_from_v0 {
2768         my $git_dir = $ENV{GIT_DIR};
2769         return undef unless -d $git_dir;
2770         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2771         my $migrated = 0;
2772         while (<$fh>) {
2773                 chomp;
2774                 my ($id, $orig_ref) = ($_, $_);
2775                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2776                 next unless -f "$git_dir/$id/info/url";
2777                 my $new_ref = "refs/remotes/$id";
2778                 if (::verify_ref("$new_ref^0")) {
2779                         print STDERR "W: $orig_ref is probably an old ",
2780                                      "branch used by an ancient version of ",
2781                                      "git-svn.\n",
2782                                      "However, $new_ref also exists.\n",
2783                                      "We will not be able ",
2784                                      "to use this branch until this ",
2785                                      "ambiguity is resolved.\n";
2786                         next;
2787                 }
2788                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2789                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2790                 command_noisy('update-ref', $new_ref, $orig_ref);
2791                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2792                 $migrated++;
2793         }
2794         command_close_pipe($fh, $ctx);
2795         print STDERR "Done migrating from v0 layout...\n" if $migrated;
2796         $migrated;
2797 }
2798
2799 sub migrate_from_v1 {
2800         my $git_dir = $ENV{GIT_DIR};
2801         my $migrated = 0;
2802         return $migrated unless -d $git_dir;
2803         my $svn_dir = "$git_dir/svn";
2804
2805         # just in case somebody used 'svn' as their $id at some point...
2806         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2807
2808         print STDERR "Migrating from a git-svn v1 layout...\n";
2809         mkpath([$svn_dir]);
2810         print STDERR "Data from a previous version of git-svn exists, but\n\t",
2811                      "$svn_dir\n\t(required for this version ",
2812                      "($::VERSION) of git-svn) does not. exist\n";
2813         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2814         while (<$fh>) {
2815                 my $x = $_;
2816                 next unless $x =~ s#^refs/remotes/##;
2817                 chomp $x;
2818                 next unless -f "$git_dir/$x/info/url";
2819                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2820                 next unless $u;
2821                 my $dn = dirname("$git_dir/svn/$x");
2822                 mkpath([$dn]) unless -d $dn;
2823                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2824                         mkpath(["$git_dir/svn/svn"]);
2825                         print STDERR " - $git_dir/$x/info => ",
2826                                         "$git_dir/svn/$x/info\n";
2827                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2828                                croak "$!: $x";
2829                         # don't worry too much about these, they probably
2830                         # don't exist with repos this old (save for index,
2831                         # and we can easily regenerate that)
2832                         foreach my $f (qw/unhandled.log index .rev_db/) {
2833                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2834                         }
2835                 } else {
2836                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2837                         rename "$git_dir/$x", "$git_dir/svn/$x" or
2838                                croak "$!: $x";
2839                 }
2840                 $migrated++;
2841         }
2842         command_close_pipe($fh, $ctx);
2843         print STDERR "Done migrating from a git-svn v1 layout\n";
2844         $migrated;
2845 }
2846
2847 sub read_old_urls {
2848         my ($l_map, $pfx, $path) = @_;
2849         my @dir;
2850         foreach (<$path/*>) {
2851                 if (-r "$_/info/url") {
2852                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2853                         my $ref_id = $pfx . basename $_;
2854                         my $url = ::file_to_s("$_/info/url");
2855                         $l_map->{$ref_id} = $url;
2856                 } elsif (-d $_) {
2857                         push @dir, $_;
2858                 }
2859         }
2860         foreach (@dir) {
2861                 my $x = $_;
2862                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2863                 read_old_urls($l_map, $x, $_);
2864         }
2865 }
2866
2867 sub migrate_from_v2 {
2868         my @cfg = command(qw/config -l/);
2869         return if grep /^svn-remote\..+\.url=/, @cfg;
2870         my %l_map;
2871         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2872         my $migrated = 0;
2873
2874         foreach my $ref_id (sort keys %l_map) {
2875                 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2876                 $migrated++;
2877         }
2878         $migrated;
2879 }
2880
2881 sub minimize_connections {
2882         my $r = Git::SVN::read_all_remotes();
2883         my $new_urls = {};
2884         my $root_repos = {};
2885         foreach my $repo_id (keys %$r) {
2886                 my $url = $r->{$repo_id}->{url} or next;
2887                 my $fetch = $r->{$repo_id}->{fetch} or next;
2888                 my $ra = Git::SVN::Ra->new($url);
2889
2890                 # skip existing cases where we already connect to the root
2891                 if (($ra->{url} eq $ra->{repos_root}) ||
2892                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2893                      $repo_id)) {
2894                         $root_repos->{$ra->{url}} = $repo_id;
2895                         next;
2896                 }
2897
2898                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2899                 my $root_path = $ra->{url};
2900                 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2901                 foreach my $path (keys %$fetch) {
2902                         my $ref_id = $fetch->{$path};
2903                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2904
2905                         # make sure we can read when connecting to
2906                         # a higher level of a repository
2907                         my ($last_rev, undef) = $gs->last_rev_commit;
2908                         if (!defined $last_rev) {
2909                                 $last_rev = eval {
2910                                         $root_ra->get_latest_revnum;
2911                                 };
2912                                 next if $@;
2913                         }
2914                         my $new = $root_path;
2915                         $new .= length $path ? "/$path" : '';
2916                         eval {
2917                                 $root_ra->get_log([$new], $last_rev, $last_rev,
2918                                                   0, 0, 1, sub { });
2919                         };
2920                         next if $@;
2921                         $new_urls->{$ra->{repos_root}}->{$new} =
2922                                 { ref_id => $ref_id,
2923                                   old_repo_id => $repo_id,
2924                                   old_path => $path };
2925                 }
2926         }
2927
2928         my @emptied;
2929         foreach my $url (keys %$new_urls) {
2930                 # see if we can re-use an existing [svn-remote "repo_id"]
2931                 # instead of creating a(n ugly) new section:
2932                 my $repo_id = $root_repos->{$url} ||
2933                               Git::SVN::sanitize_remote_name($url);
2934
2935                 my $fetch = $new_urls->{$url};
2936                 foreach my $path (keys %$fetch) {
2937                         my $x = $fetch->{$path};
2938                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2939                         my $pfx = "svn-remote.$x->{old_repo_id}";
2940
2941                         my $old_fetch = quotemeta("$x->{old_path}:".
2942                                                   "refs/remotes/$x->{ref_id}");
2943                         command_noisy(qw/config --unset/,
2944                                       "$pfx.fetch", '^'. $old_fetch . '$');
2945                         delete $r->{$x->{old_repo_id}}->
2946                                {fetch}->{$x->{old_path}};
2947                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2948                                 command_noisy(qw/config --unset/,
2949                                               "$pfx.url");
2950                                 push @emptied, $x->{old_repo_id}
2951                         }
2952                 }
2953         }
2954         if (@emptied) {
2955                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2956                            "$ENV{GIT_DIR}/config";
2957                 print STDERR <<EOF;
2958 The following [svn-remote] sections in your config file ($file) are empty
2959 and can be safely removed:
2960 EOF
2961                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2962         }
2963 }
2964
2965 sub migration_check {
2966         migrate_from_v0();
2967         migrate_from_v1();
2968         migrate_from_v2();
2969         minimize_connections() if $_minimize;
2970 }
2971
2972 package Git::IndexInfo;
2973 use strict;
2974 use warnings;
2975 use Git qw/command_input_pipe command_close_pipe/;
2976
2977 sub new {
2978         my ($class) = @_;
2979         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2980         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2981 }
2982
2983 sub remove {
2984         my ($self, $path) = @_;
2985         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2986                 return ++$self->{nr};
2987         }
2988         undef;
2989 }
2990
2991 sub update {
2992         my ($self, $mode, $hash, $path) = @_;
2993         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2994                 return ++$self->{nr};
2995         }
2996         undef;
2997 }
2998
2999 sub DESTROY {
3000         my ($self) = @_;
3001         command_close_pipe($self->{gui}, $self->{ctx});
3002 }
3003
3004 __END__
3005
3006 Data structures:
3007
3008 $log_entry hashref as returned by libsvn_log_entry()
3009 {
3010         log => 'whitespace-formatted log entry
3011 ',                                              # trailing newline is preserved
3012         revision => '8',                        # integer
3013         date => '2004-02-24T17:01:44.108345Z',  # commit date
3014         author => 'committer name'
3015 };
3016
3017
3018 # this is generated by generate_diff();
3019 @mods = array of diff-index line hashes, each element represents one line
3020         of diff-index output
3021
3022 diff-index line ($m hash)
3023 {
3024         mode_a => first column of diff-index output, no leading ':',
3025         mode_b => second column of diff-index output,
3026         sha1_b => sha1sum of the final blob,
3027         chg => change type [MCRADT],
3028         file_a => original file name of a file (iff chg is 'C' or 'R')
3029         file_b => new/current file name of a file (any chg)
3030 }
3031 ;
3032
3033 # retval of read_url_paths{,_all}();
3034 $l_map = {
3035         # repository root url
3036         'https://svn.musicpd.org' => {
3037                 # repository path               # GIT_SVN_ID
3038                 'mpd/trunk'             =>      'trunk',
3039                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
3040         },
3041 }
3042
3043 Notes:
3044         I don't trust the each() function on unless I created %hash myself
3045         because the internal iterator may not have started at base.