git.oblomov.eu Git - git/blob - contrib/mw-to-git/git-remote-mediawiki.perl

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 # Documentation & bugtracker: https://github.com/Git-Mediawiki/Git-Mediawiki
  13
  14 use strict;
  15 use MediaWiki::API;
  16 use Git;
  17 use Git::Mediawiki qw(clean_filename smudge_filename connect_maybe
  18                                         EMPTY HTTP_CODE_OK);
  19 use DateTime::Format::ISO8601;
  20 use warnings;
  21
  22 # By default, use UTF-8 to communicate with Git and the user
  23 binmode STDERR, ':encoding(UTF-8)';
  24 binmode STDOUT, ':encoding(UTF-8)';
  25
  26 use URI::Escape;
  27
  28 # It's not always possible to delete pages (may require some
  29 # privileges). Deleted pages are replaced with this content.
  30 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  31
  32 # It's not possible to create empty pages. New empty files in Git are
  33 # sent with this content instead.
  34 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  35
  36 # used to reflect file creation or deletion in diff.
  37 use constant NULL_SHA1 => '0000000000000000000000000000000000000000';
  38
  39 # Used on Git's side to reflect empty edit messages on the wiki
  40 use constant EMPTY_MESSAGE => '*Empty MediaWiki Message*';
  41
  42 # Number of pages taken into account at once in submodule get_mw_page_list
  43 use constant SLICE_SIZE => 50;
  44
  45 # Number of linked mediafile to get at once in get_linked_mediafiles
  46 # The query is split in small batches because of the MW API limit of
  47 # the number of links to be returned (500 links max).
  48 use constant BATCH_SIZE => 10;
  49
  50 if (@ARGV != 2) {
  51         exit_error_usage();
  52 }
  53
  54 my $remotename = $ARGV[0];
  55 my $url = $ARGV[1];
  56
  57 # Accept both space-separated and multiple keys in config file.
  58 # Spaces should be written as _ anyway because we'll use chomp.
  59 my @tracked_pages = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.pages"]));
  60 chomp(@tracked_pages);
  61
  62 # Just like @tracked_pages, but for MediaWiki categories.
  63 my @tracked_categories = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.categories"]));
  64 chomp(@tracked_categories);
  65
  66 # Just like @tracked_categories, but for MediaWiki namespaces.
  67 my @tracked_namespaces = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.namespaces"]));
  68 for (@tracked_namespaces) { s/_/ /g; }
  69 chomp(@tracked_namespaces);
  70
  71 # Import media files on pull
  72 my $import_media = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.mediaimport"]);
  73 chomp($import_media);
  74 $import_media = ($import_media eq 'true');
  75
  76 # Export media files on push
  77 my $export_media = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.mediaexport"]);
  78 chomp($export_media);
  79 $export_media = !($export_media eq 'false');
  80
  81 my $wiki_login = run_git_quoted(["config", "--get", "remote.${remotename}.mwLogin"]);
  82 # Note: mwPassword is discouraged. Use the credential system instead.
  83 my $wiki_passwd = run_git_quoted(["config", "--get", "remote.${remotename}.mwPassword"]);
  84 my $wiki_domain = run_git_quoted(["config", "--get", "remote.${remotename}.mwDomain"]);
  85 chomp($wiki_login);
  86 chomp($wiki_passwd);
  87 chomp($wiki_domain);
  88
  89 # Import only last revisions (both for clone and fetch)
  90 my $shallow_import = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.shallow"]);
  91 chomp($shallow_import);
  92 $shallow_import = ($shallow_import eq 'true');
  93
  94 # Fetch (clone and pull) by revisions instead of by pages. This behavior
  95 # is more efficient when we have a wiki with lots of pages and we fetch
  96 # the revisions quite often so that they concern only few pages.
  97 # Possible values:
  98 # - by_rev: perform one query per new revision on the remote wiki
  99 # - by_page: query each tracked page for new revision
 100 my $fetch_strategy = run_git_quoted(["config", "--get", "remote.${remotename}.fetchStrategy"]);
 101 if (!$fetch_strategy) {
 102         $fetch_strategy = run_git_quoted(["config", "--get", "mediawiki.fetchStrategy"]);
 103 }
 104 chomp($fetch_strategy);
 105 if (!$fetch_strategy) {
 106         $fetch_strategy = 'by_page';
 107 }
 108
 109 # Remember the timestamp corresponding to a revision id.
 110 my %basetimestamps;
 111
 112 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
 113 #
 114 # Configurable with mediawiki.dumbPush, or per-remote with
 115 # remote.<remotename>.dumbPush.
 116 #
 117 # This means the user will have to re-import the just-pushed
 118 # revisions. On the other hand, this means that the Git revisions
 119 # corresponding to MediaWiki revisions are all imported from the wiki,
 120 # regardless of whether they were initially created in Git or from the
 121 # web interface, hence all users will get the same history (i.e. if
 122 # the push from Git to MediaWiki loses some information, everybody
 123 # will get the history with information lost). If the import is
 124 # deterministic, this means everybody gets the same sha1 for each
 125 # MediaWiki revision.
 126 my $dumb_push = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.dumbPush"]);
 127 if (!$dumb_push) {
 128         $dumb_push = run_git_quoted(["config", "--get", "--bool", "mediawiki.dumbPush"]);
 129 }
 130 chomp($dumb_push);
 131 $dumb_push = ($dumb_push eq 'true');
 132
 133 my $wiki_name = $url;
 134 $wiki_name =~ s{[^/]*://}{};
 135 # If URL is like http://user:password@example.com/, we clearly don't
 136 # want the password in $wiki_name. While we're there, also remove user
 137 # and '@' sign, to avoid author like MWUser@HTTPUser@host.com
 138 $wiki_name =~ s/^.*@//;
 139
 140 # Commands parser
 141 while (<STDIN>) {
 142         chomp;
 143
 144         if (!parse_command($_)) {
 145                 last;
 146         }
 147
 148         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 149                          # command is fully processed.
 150 }
 151
 152 ########################## Functions ##############################
 153
 154 ## error handling
 155 sub exit_error_usage {
 156         die "ERROR: git-remote-mediawiki module was not called with a correct number of\n" .
 157             "parameters\n" .
 158             "You may obtain this error because you attempted to run the git-remote-mediawiki\n" .
 159             "module directly.\n" .
 160             "This module can be used the following way:\n" .
 161             "\tgit clone mediawiki://<address of a mediawiki>\n" .
 162             "Then, use git commit, push and pull as with every normal git repository.\n";
 163 }
 164
 165 sub parse_command {
 166         my ($line) = @_;
 167         my @cmd = split(/ /, $line);
 168         if (!defined $cmd[0]) {
 169                 return 0;
 170         }
 171         if ($cmd[0] eq 'capabilities') {
 172                 die("Too many arguments for capabilities\n")
 173                     if (defined($cmd[1]));
 174                 mw_capabilities();
 175         } elsif ($cmd[0] eq 'list') {
 176                 die("Too many arguments for list\n") if (defined($cmd[2]));
 177                 mw_list($cmd[1]);
 178         } elsif ($cmd[0] eq 'import') {
 179                 die("Invalid argument for import\n")
 180                     if ($cmd[1] eq EMPTY);
 181                 die("Too many arguments for import\n")
 182                     if (defined($cmd[2]));
 183                 mw_import($cmd[1]);
 184         } elsif ($cmd[0] eq 'option') {
 185                 die("Invalid arguments for option\n")
 186                     if ($cmd[1] eq EMPTY || $cmd[2] eq EMPTY);
 187                 die("Too many arguments for option\n")
 188                     if (defined($cmd[3]));
 189                 mw_option($cmd[1],$cmd[2]);
 190         } elsif ($cmd[0] eq 'push') {
 191                 mw_push($cmd[1]);
 192         } else {
 193                 print {*STDERR} "Unknown command. Aborting...\n";
 194                 return 0;
 195         }
 196         return 1;
 197 }
 198
 199 # MediaWiki API instance, created lazily.
 200 my $mediawiki;
 201
 202 sub fatal_mw_error {
 203         my $action = shift;
 204         print STDERR "fatal: could not $action.\n";
 205         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 206         if ($url =~ /^https/) {
 207                 print STDERR "fatal: make sure '$url/api.php' is a valid page\n";
 208                 print STDERR "fatal: and the SSL certificate is correct.\n";
 209         } else {
 210                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 211         }
 212         print STDERR "fatal: (error " .
 213             $mediawiki->{error}->{code} . ': ' .
 214             $mediawiki->{error}->{details} . ")\n";
 215         exit 1;
 216 }
 217
 218 ## Functions for listing pages on the remote wiki
 219 sub get_mw_tracked_pages {
 220         my $pages = shift;
 221         get_mw_page_list(\@tracked_pages, $pages);
 222         return;
 223 }
 224
 225 sub get_mw_page_list {
 226         my $page_list = shift;
 227         my $pages = shift;
 228         my @some_pages = @{$page_list};
 229         while (@some_pages) {
 230                 my $last_page = SLICE_SIZE;
 231                 if ($#some_pages < $last_page) {
 232                         $last_page = $#some_pages;
 233                 }
 234                 my @slice = @some_pages[0..$last_page];
 235                 get_mw_first_pages(\@slice, $pages);
 236                 @some_pages = @some_pages[(SLICE_SIZE + 1)..$#some_pages];
 237         }
 238         return;
 239 }
 240
 241 sub get_mw_tracked_categories {
 242         my $pages = shift;
 243         foreach my $category (@tracked_categories) {
 244                 if (index($category, ':') < 0) {
 245                         # Mediawiki requires the Category
 246                         # prefix, but let's not force the user
 247                         # to specify it.
 248                         $category = "Category:${category}";
 249                 }
 250                 my $mw_pages = $mediawiki->list( {
 251                         action => 'query',
 252                         list => 'categorymembers',
 253                         cmtitle => $category,
 254                         cmlimit => 'max' } )
 255                         || die $mediawiki->{error}->{code} . ': '
 256                                 . $mediawiki->{error}->{details} . "\n";
 257                 foreach my $page (@{$mw_pages}) {
 258                         $pages->{$page->{title}} = $page;
 259                 }
 260         }
 261         return;
 262 }
 263
 264 sub get_mw_tracked_namespaces {
 265     my $pages = shift;
 266     foreach my $local_namespace (sort @tracked_namespaces) {
 267         my $namespace_id;
 268         if ($local_namespace eq "(Main)") {
 269             $namespace_id = 0;
 270         } else {
 271             $namespace_id = get_mw_namespace_id($local_namespace);
 272         }
 273         # virtual namespaces don't support allpages
 274         next if !defined($namespace_id) || $namespace_id < 0;
 275         my $mw_pages = $mediawiki->list( {
 276             action => 'query',
 277             list => 'allpages',
 278             apnamespace => $namespace_id,
 279             aplimit => 'max' } )
 280             || die $mediawiki->{error}->{code} . ': '
 281                 . $mediawiki->{error}->{details} . "\n";
 282         print {*STDERR} "$#{$mw_pages} found in namespace $local_namespace ($namespace_id)\n";
 283         foreach my $page (@{$mw_pages}) {
 284             $pages->{$page->{title}} = $page;
 285         }
 286     }
 287     return;
 288 }
 289
 290 sub get_mw_all_pages {
 291         my $pages = shift;
 292         # No user-provided list, get the list of pages from the API.
 293         my $mw_pages = $mediawiki->list({
 294                 action => 'query',
 295                 list => 'allpages',
 296                 aplimit => 'max'
 297         });
 298         if (!defined($mw_pages)) {
 299                 fatal_mw_error("get the list of wiki pages");
 300         }
 301         foreach my $page (@{$mw_pages}) {
 302                 $pages->{$page->{title}} = $page;
 303         }
 304         return;
 305 }
 306
 307 # queries the wiki for a set of pages. Meant to be used within a loop
 308 # querying the wiki for slices of page list.
 309 sub get_mw_first_pages {
 310         my $some_pages = shift;
 311         my @some_pages = @{$some_pages};
 312
 313         my $pages = shift;
 314
 315         # pattern 'page1|page2|...' required by the API
 316         my $titles = join('|', @some_pages);
 317
 318         my $mw_pages = $mediawiki->api({
 319                 action => 'query',
 320                 titles => $titles,
 321         });
 322         if (!defined($mw_pages)) {
 323                 fatal_mw_error("query the list of wiki pages");
 324         }
 325         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 326                 if ($id < 0) {
 327                         print {*STDERR} "Warning: page $page->{title} not found on wiki\n";
 328                 } else {
 329                         $pages->{$page->{title}} = $page;
 330                 }
 331         }
 332         return;
 333 }
 334
 335 # Get the list of pages to be fetched according to configuration.
 336 sub get_mw_pages {
 337         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 338
 339         print {*STDERR} "Listing pages on remote wiki...\n";
 340
 341         my %pages; # hash on page titles to avoid duplicates
 342         my $user_defined;
 343         if (@tracked_pages) {
 344                 $user_defined = 1;
 345                 # The user provided a list of pages titles, but we
 346                 # still need to query the API to get the page IDs.
 347                 get_mw_tracked_pages(\%pages);
 348         }
 349         if (@tracked_categories) {
 350                 $user_defined = 1;
 351                 get_mw_tracked_categories(\%pages);
 352         }
 353         if (@tracked_namespaces) {
 354                 $user_defined = 1;
 355                 get_mw_tracked_namespaces(\%pages);
 356         }
 357         if (!$user_defined) {
 358                 get_mw_all_pages(\%pages);
 359         }
 360         if ($import_media) {
 361                 print {*STDERR} "Getting media files for selected pages...\n";
 362                 if ($user_defined) {
 363                         get_linked_mediafiles(\%pages);
 364                 } else {
 365                         get_all_mediafiles(\%pages);
 366                 }
 367         }
 368         print {*STDERR} (scalar keys %pages) . " pages found.\n";
 369         return %pages;
 370 }
 371
 372 # usage: $out = run_git_quoted(["command", "args", ...]);
 373 #        $out = run_git_quoted(["command", "args", ...], "raw"); # don't interpret output as UTF-8.
 374 #        $out = run_git_unquoted(["command args"); # don't quote arguments
 375 #        $out = run_git_unquoted(["command args", "raw"); # ditto but raw instead of UTF-8 as above
 376 sub _run_git {
 377         my $args = shift;
 378         my $encoding = (shift || 'encoding(UTF-8)');
 379         open(my $git, "-|:${encoding}", @$args)
 380             or die "Unable to fork: $!\n";
 381         my $res = do {
 382                 local $/ = undef;
 383                 <$git>
 384         };
 385         close($git);
 386
 387         return $res;
 388 }
 389
 390 sub run_git_quoted {
 391     _run_git(["git", @{$_[0]}], $_[1]);
 392 }
 393
 394 sub run_git_unquoted {
 395     _run_git(["git $_[0]"], $_[1]);
 396 }
 397
 398 BEGIN { *run_git = \&run_git_unquoted }
 399
 400 sub get_all_mediafiles {
 401         my $pages = shift;
 402         # Attach list of all pages for media files from the API,
 403         # they are in a different namespace, only one namespace
 404         # can be queried at the same moment
 405         my $mw_pages = $mediawiki->list({
 406                 action => 'query',
 407                 list => 'allpages',
 408                 apnamespace => get_mw_namespace_id('File'),
 409                 aplimit => 'max'
 410         });
 411         if (!defined($mw_pages)) {
 412                 print {*STDERR} "fatal: could not get the list of pages for media files.\n";
 413                 print {*STDERR} "fatal: '$url' does not appear to be a mediawiki\n";
 414                 print {*STDERR} "fatal: make sure '$url/api.php' is a valid page.\n";
 415                 exit 1;
 416         }
 417         foreach my $page (@{$mw_pages}) {
 418                 $pages->{$page->{title}} = $page;
 419         }
 420         return;
 421 }
 422
 423 sub get_linked_mediafiles {
 424         my $pages = shift;
 425         my @titles = map { $_->{title} } values(%{$pages});
 426
 427         my $batch = BATCH_SIZE;
 428         while (@titles) {
 429                 if ($#titles < $batch) {
 430                         $batch = $#titles;
 431                 }
 432                 my @slice = @titles[0..$batch];
 433
 434                 # pattern 'page1|page2|...' required by the API
 435                 my $mw_titles = join('|', @slice);
 436
 437                 # Media files could be included or linked from
 438                 # a page, get all related
 439                 my $query = {
 440                         action => 'query',
 441                         prop => 'links|images',
 442                         titles => $mw_titles,
 443                         plnamespace => get_mw_namespace_id('File'),
 444                         pllimit => 'max'
 445                 };
 446                 my $result = $mediawiki->api($query);
 447
 448                 while (my ($id, $page) = each(%{$result->{query}->{pages}})) {
 449                         my @media_titles;
 450                         if (defined($page->{links})) {
 451                                 my @link_titles
 452                                     = map { $_->{title} } @{$page->{links}};
 453                                 push(@media_titles, @link_titles);
 454                         }
 455                         if (defined($page->{images})) {
 456                                 my @image_titles
 457                                     = map { $_->{title} } @{$page->{images}};
 458                                 push(@media_titles, @image_titles);
 459                         }
 460                         if (@media_titles) {
 461                                 get_mw_page_list(\@media_titles, $pages);
 462                         }
 463                 }
 464
 465                 @titles = @titles[($batch+1)..$#titles];
 466         }
 467         return;
 468 }
 469
 470 sub get_mw_mediafile_for_page_revision {
 471         # Name of the file on Wiki, with the prefix.
 472         my $filename = shift;
 473         my $timestamp = shift;
 474         my %mediafile;
 475
 476         # Search if on a media file with given timestamp exists on
 477         # MediaWiki. In that case download the file.
 478         my $query = {
 479                 action => 'query',
 480                 prop => 'imageinfo',
 481                 titles => "File:${filename}",
 482                 iistart => $timestamp,
 483                 iiend => $timestamp,
 484                 iiprop => 'timestamp|archivename|url',
 485                 iilimit => 1
 486         };
 487         my $result = $mediawiki->api($query);
 488
 489         my ($fileid, $file) = each( %{$result->{query}->{pages}} );
 490         # If not defined it means there is no revision of the file for
 491         # given timestamp.
 492         if (defined($file->{imageinfo})) {
 493                 $mediafile{title} = $filename;
 494
 495                 my $fileinfo = pop(@{$file->{imageinfo}});
 496                 $mediafile{timestamp} = $fileinfo->{timestamp};
 497                 # Mediawiki::API's download function doesn't support https URLs
 498                 # and can't download old versions of files.
 499                 print {*STDERR} "\tDownloading file $mediafile{title}, version $mediafile{timestamp}\n";
 500                 $mediafile{content} = download_mw_mediafile($fileinfo->{url});
 501         }
 502         return %mediafile;
 503 }
 504
 505 sub download_mw_mediafile {
 506         my $download_url = shift;
 507
 508         my $response = $mediawiki->{ua}->get($download_url);
 509         if ($response->code == HTTP_CODE_OK) {
 510                 # It is tempting to return
 511                 # $response->decoded_content({charset => "none"}), but
 512                 # when doing so, utf8::downgrade($content) fails with
 513                 # "Wide character in subroutine entry".
 514                 $response->decode();
 515                 return $response->content();
 516         } else {
 517                 print {*STDERR} "Error downloading mediafile from :\n";
 518                 print {*STDERR} "URL: ${download_url}\n";
 519                 print {*STDERR} 'Server response: ' . $response->code . q{ } . $response->message . "\n";
 520                 exit 1;
 521         }
 522 }
 523
 524 sub get_last_local_revision {
 525         # Get note regarding last mediawiki revision
 526         my $note = run_git("notes --ref=${remotename}/mediawiki show refs/mediawiki/${remotename}/master 2>/dev/null");
 527         my @note_info = split(/ /, $note);
 528
 529         my $lastrevision_number;
 530         if (!(defined($note_info[0]) && $note_info[0] eq 'mediawiki_revision:')) {
 531                 print {*STDERR} 'No previous mediawiki revision found';
 532                 $lastrevision_number = 0;
 533         } else {
 534                 # Notes are formatted : mediawiki_revision: #number
 535                 $lastrevision_number = $note_info[1];
 536                 chomp($lastrevision_number);
 537                 print {*STDERR} "Last local mediawiki revision found is ${lastrevision_number}";
 538         }
 539         return $lastrevision_number;
 540 }
 541
 542 # Get the last remote revision without taking in account which pages are
 543 # tracked or not. This function makes a single request to the wiki thus
 544 # avoid a loop onto all tracked pages. This is useful for the fetch-by-rev
 545 # option.
 546 sub get_last_global_remote_rev {
 547         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 548
 549         my $query = {
 550                 action => 'query',
 551                 list => 'recentchanges',
 552                 prop => 'revisions',
 553                 rclimit => '1',
 554                 rcdir => 'older',
 555         };
 556         my $result = $mediawiki->api($query);
 557         return $result->{query}->{recentchanges}[0]->{revid};
 558 }
 559
 560 # Get the last remote revision concerning the tracked pages and the tracked
 561 # categories.
 562 sub get_last_remote_revision {
 563         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 564
 565         my %pages_hash = get_mw_pages();
 566         my @pages = values(%pages_hash);
 567
 568         my $max_rev_num = 0;
 569
 570         print {*STDERR} "Getting last revision id on tracked pages...\n";
 571
 572         foreach my $page (@pages) {
 573                 my $id = $page->{pageid};
 574
 575                 my $query = {
 576                         action => 'query',
 577                         prop => 'revisions',
 578                         rvprop => 'ids|timestamp',
 579                         pageids => $id,
 580                 };
 581
 582                 my $result = $mediawiki->api($query);
 583
 584                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 585
 586                 $basetimestamps{$lastrev->{revid}} = $lastrev->{timestamp};
 587
 588                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 589         }
 590
 591         print {*STDERR} "Last remote revision found is $max_rev_num.\n";
 592         return $max_rev_num;
 593 }
 594
 595 # Clean content before sending it to MediaWiki
 596 sub mediawiki_clean {
 597         my $string = shift;
 598         my $page_created = shift;
 599         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 600         # This function right trims a string and adds a \n at the end to follow this rule
 601         $string =~ s/\s+$//;
 602         if ($string eq EMPTY && $page_created) {
 603                 # Creating empty pages is forbidden.
 604                 $string = EMPTY_CONTENT;
 605         }
 606         return $string."\n";
 607 }
 608
 609 # Filter applied on MediaWiki data before adding them to Git
 610 sub mediawiki_smudge {
 611         my $string = shift;
 612         if ($string eq EMPTY_CONTENT) {
 613                 $string = EMPTY;
 614         }
 615         # This \n is important. This is due to mediawiki's way to handle end of files.
 616         return "${string}\n";
 617 }
 618
 619 sub literal_data {
 620         my ($content) = @_;
 621         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 622         return;
 623 }
 624
 625 sub literal_data_raw {
 626         # Output possibly binary content.
 627         my ($content) = @_;
 628         # Avoid confusion between size in bytes and in characters
 629         utf8::downgrade($content);
 630         binmode STDOUT, ':raw';
 631         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 632         binmode STDOUT, ':encoding(UTF-8)';
 633         return;
 634 }
 635
 636 sub mw_capabilities {
 637         # Revisions are imported to the private namespace
 638         # refs/mediawiki/$remotename/ by the helper and fetched into
 639         # refs/remotes/$remotename later by fetch.
 640         print {*STDOUT} "refspec refs/heads/*:refs/mediawiki/${remotename}/*\n";
 641         print {*STDOUT} "import\n";
 642         print {*STDOUT} "list\n";
 643         print {*STDOUT} "push\n";
 644         if ($dumb_push) {
 645                 print {*STDOUT} "no-private-update\n";
 646         }
 647         print {*STDOUT} "\n";
 648         return;
 649 }
 650
 651 sub mw_list {
 652         # MediaWiki do not have branches, we consider one branch arbitrarily
 653         # called master, and HEAD pointing to it.
 654         print {*STDOUT} "? refs/heads/master\n";
 655         print {*STDOUT} "\@refs/heads/master HEAD\n";
 656         print {*STDOUT} "\n";
 657         return;
 658 }
 659
 660 sub mw_option {
 661         print {*STDERR} "remote-helper command 'option $_[0]' not yet implemented\n";
 662         print {*STDOUT} "unsupported\n";
 663         return;
 664 }
 665
 666 sub fetch_mw_revisions_for_page {
 667         my $page = shift;
 668         my $id = shift;
 669         my $fetch_from = shift;
 670         my @page_revs = ();
 671         my $query = {
 672                 action => 'query',
 673                 prop => 'revisions',
 674                 rvprop => 'ids',
 675                 rvdir => 'newer',
 676                 rvstartid => $fetch_from,
 677                 rvlimit => 500,
 678                 pageids => $id,
 679
 680                 # Let MediaWiki know that we support the latest API.
 681                 continue => '',
 682         };
 683
 684         my $revnum = 0;
 685         # Get 500 revisions at a time due to the mediawiki api limit
 686         while (1) {
 687                 my $result = $mediawiki->api($query);
 688
 689                 # Parse each of those 500 revisions
 690                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 691                         my $page_rev_ids;
 692                         $page_rev_ids->{pageid} = $page->{pageid};
 693                         $page_rev_ids->{revid} = $revision->{revid};
 694                         push(@page_revs, $page_rev_ids);
 695                         $revnum++;
 696                 }
 697
 698                 if ($result->{'query-continue'}) { # For legacy APIs
 699                         $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 700                 } elsif ($result->{continue}) { # For newer APIs
 701                         $query->{rvstartid} = $result->{continue}->{rvcontinue};
 702                         $query->{continue} = $result->{continue}->{continue};
 703                 } else {
 704                         last;
 705                 }
 706         }
 707         if ($shallow_import && @page_revs) {
 708                 print {*STDERR} "  Found 1 revision (shallow import).\n";
 709                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 710                 return $page_revs[0];
 711         }
 712         print {*STDERR} "  Found ${revnum} revision(s).\n";
 713         return @page_revs;
 714 }
 715
 716 sub fetch_mw_revisions {
 717         my $pages = shift; my @pages = @{$pages};
 718         my $fetch_from = shift;
 719
 720         my @revisions = ();
 721         my $n = 1;
 722         foreach my $page (@pages) {
 723                 my $id = $page->{pageid};
 724                 print {*STDERR} "page ${n}/", scalar(@pages), ': ', $page->{title}, "\n";
 725                 $n++;
 726                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 727                 @revisions = (@page_revs, @revisions);
 728         }
 729
 730         return ($n, @revisions);
 731 }
 732
 733 sub fe_escape_path {
 734     my $path = shift;
 735     $path =~ s/\\/\\\\/g;
 736     $path =~ s/"/\\"/g;
 737     $path =~ s/\n/\\n/g;
 738     return qq("${path}");
 739 }
 740
 741 sub import_file_revision {
 742         my $commit = shift;
 743         my %commit = %{$commit};
 744         my $full_import = shift;
 745         my $n = shift;
 746         my $mediafile = shift;
 747         my %mediafile;
 748         if ($mediafile) {
 749                 %mediafile = %{$mediafile};
 750         }
 751
 752         my $title = $commit{title};
 753         my $comment = $commit{comment};
 754         my $content = $commit{content};
 755         my $author = $commit{author};
 756         my $date = $commit{date};
 757
 758         print {*STDOUT} "commit refs/mediawiki/${remotename}/master\n";
 759         print {*STDOUT} "mark :${n}\n";
 760         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 761         literal_data($comment);
 762
 763         # If it's not a clone, we need to know where to start from
 764         if (!$full_import && $n == 1) {
 765                 print {*STDOUT} "from refs/mediawiki/${remotename}/master^0\n";
 766         }
 767         if ($content ne DELETED_CONTENT) {
 768                 print {*STDOUT} 'M 644 inline ' .
 769                     fe_escape_path("${title}.mw") . "\n";
 770                 literal_data($content);
 771                 if (%mediafile) {
 772                         print {*STDOUT} 'M 644 inline '
 773                             . fe_escape_path($mediafile{title}) . "\n";
 774                         literal_data_raw($mediafile{content});
 775                 }
 776                 print {*STDOUT} "\n\n";
 777         } else {
 778                 print {*STDOUT} 'D ' . fe_escape_path("${title}.mw") . "\n";
 779         }
 780
 781         # mediawiki revision number in the git note
 782         if ($full_import && $n == 1) {
 783                 print {*STDOUT} "reset refs/notes/${remotename}/mediawiki\n";
 784         }
 785         print {*STDOUT} "commit refs/notes/${remotename}/mediawiki\n";
 786         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 787         literal_data('Note added by git-mediawiki during import');
 788         if (!$full_import && $n == 1) {
 789                 print {*STDOUT} "from refs/notes/${remotename}/mediawiki^0\n";
 790         }
 791         print {*STDOUT} "N inline :${n}\n";
 792         literal_data("mediawiki_revision: $commit{mw_revision}");
 793         print {*STDOUT} "\n\n";
 794         return;
 795 }
 796
 797 # parse a sequence of
 798 # <cmd> <arg1>
 799 # <cmd> <arg2>
 800 # \n
 801 # (like batch sequence of import and sequence of push statements)
 802 sub get_more_refs {
 803         my $cmd = shift;
 804         my @refs;
 805         while (1) {
 806                 my $line = <STDIN>;
 807                 if ($line =~ /^$cmd (.*)$/) {
 808                         push(@refs, $1);
 809                 } elsif ($line eq "\n") {
 810                         return @refs;
 811                 } else {
 812                         die("Invalid command in a '$cmd' batch: $_\n");
 813                 }
 814         }
 815         return;
 816 }
 817
 818 sub mw_import {
 819         # multiple import commands can follow each other.
 820         my @refs = (shift, get_more_refs('import'));
 821         my $processedRefs;
 822         foreach my $ref (@refs) {
 823                 next if $processedRefs->{$ref}; # skip duplicates: "import refs/heads/master" being issued twice; TODO: why?
 824                 $processedRefs->{$ref} = 1;
 825                 mw_import_ref($ref);
 826         }
 827         print {*STDOUT} "done\n";
 828         return;
 829 }
 830
 831 sub mw_import_ref {
 832         my $ref = shift;
 833         # The remote helper will call "import HEAD" and
 834         # "import refs/heads/master".
 835         # Since HEAD is a symbolic ref to master (by convention,
 836         # followed by the output of the command "list" that we gave),
 837         # we don't need to do anything in this case.
 838         if ($ref eq 'HEAD') {
 839                 return;
 840         }
 841
 842         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 843
 844         print {*STDERR} "Searching revisions...\n";
 845         my $last_local = get_last_local_revision();
 846         my $fetch_from = $last_local + 1;
 847         if ($fetch_from == 1) {
 848                 print {*STDERR} ", fetching from beginning.\n";
 849         } else {
 850                 print {*STDERR} ", fetching from here.\n";
 851         }
 852
 853         my $n = 0;
 854         if ($fetch_strategy eq 'by_rev') {
 855                 print {*STDERR} "Fetching & writing export data by revs...\n";
 856                 $n = mw_import_ref_by_revs($fetch_from);
 857         } elsif ($fetch_strategy eq 'by_page') {
 858                 print {*STDERR} "Fetching & writing export data by pages...\n";
 859                 $n = mw_import_ref_by_pages($fetch_from);
 860         } else {
 861                 print {*STDERR} qq(fatal: invalid fetch strategy "${fetch_strategy}".\n);
 862                 print {*STDERR} "Check your configuration variables remote.${remotename}.fetchStrategy and mediawiki.fetchStrategy\n";
 863                 exit 1;
 864         }
 865
 866         if ($fetch_from == 1 && $n == 0) {
 867                 print {*STDERR} "You appear to have cloned an empty MediaWiki.\n";
 868                 # Something has to be done remote-helper side. If nothing is done, an error is
 869                 # thrown saying that HEAD is referring to unknown object 0000000000000000000
 870                 # and the clone fails.
 871         }
 872         return;
 873 }
 874
 875 sub mw_import_ref_by_pages {
 876
 877         my $fetch_from = shift;
 878         my %pages_hash = get_mw_pages();
 879         my @pages = values(%pages_hash);
 880
 881         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 882
 883         @revisions = sort {$a->{revid} <=> $b->{revid}} @revisions;
 884         my @revision_ids = map { $_->{revid} } @revisions;
 885
 886         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 887 }
 888
 889 sub mw_import_ref_by_revs {
 890
 891         my $fetch_from = shift;
 892         my %pages_hash = get_mw_pages();
 893
 894         my $last_remote = get_last_global_remote_rev();
 895         my @revision_ids = $fetch_from..$last_remote;
 896         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 897 }
 898
 899 # Import revisions given in second argument (array of integers).
 900 # Only pages appearing in the third argument (hash indexed by page titles)
 901 # will be imported.
 902 sub mw_import_revids {
 903         my $fetch_from = shift;
 904         my $revision_ids = shift;
 905         my $pages = shift;
 906
 907         my $n = 0;
 908         my $n_actual = 0;
 909         my $last_timestamp = 0; # Placeholder in case $rev->timestamp is undefined
 910
 911         foreach my $pagerevid (@{$revision_ids}) {
 912                 # Count page even if we skip it, since we display
 913                 # $n/$total and $total includes skipped pages.
 914                 $n++;
 915
 916                 # fetch the content of the pages
 917                 my $query = {
 918                         action => 'query',
 919                         prop => 'revisions',
 920                         rvprop => 'content|timestamp|comment|user|ids',
 921                         revids => $pagerevid,
 922                 };
 923
 924                 my $result = $mediawiki->api($query);
 925
 926                 if (!$result) {
 927                         die "Failed to retrieve modified page for revision $pagerevid\n";
 928                 }
 929
 930                 if (defined($result->{query}->{badrevids}->{$pagerevid})) {
 931                         # The revision id does not exist on the remote wiki.
 932                         next;
 933                 }
 934
 935                 if (!defined($result->{query}->{pages})) {
 936                         die "Invalid revision ${pagerevid}.\n";
 937                 }
 938
 939                 my @result_pages = values(%{$result->{query}->{pages}});
 940                 my $result_page = $result_pages[0];
 941                 my $rev = $result_pages[0]->{revisions}->[0];
 942
 943                 my $page_title = $result_page->{title};
 944
 945                 if (!exists($pages->{$page_title})) {
 946                         print {*STDERR} "${n}/", scalar(@{$revision_ids}),
 947                                 ": Skipping revision #$rev->{revid} of ${page_title}\n";
 948                         next;
 949                 }
 950
 951                 $n_actual++;
 952
 953                 my %commit;
 954                 $commit{author} = $rev->{user} || 'Anonymous';
 955                 $commit{comment} = $rev->{comment} || EMPTY_MESSAGE;
 956                 $commit{title} = smudge_filename($page_title);
 957                 $commit{mw_revision} = $rev->{revid};
 958                 $commit{content} = mediawiki_smudge($rev->{'*'});
 959
 960                 if (!defined($rev->{timestamp})) {
 961                         $last_timestamp++;
 962                 } else {
 963                         $last_timestamp = $rev->{timestamp};
 964                 }
 965                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 966
 967                 # Differentiates classic pages and media files.
 968                 my ($namespace, $filename) = $page_title =~ /^([^:]*):(.*)$/;
 969                 my %mediafile;
 970                 if ($namespace) {
 971                         my $id = get_mw_namespace_id($namespace);
 972                         if ($id && $id == get_mw_namespace_id('File')) {
 973                                 %mediafile = get_mw_mediafile_for_page_revision($filename, $rev->{timestamp});
 974                         }
 975                 }
 976                 # If this is a revision of the media page for new version
 977                 # of a file do one common commit for both file and media page.
 978                 # Else do commit only for that page.
 979                 print {*STDERR} "${n}/", scalar(@{$revision_ids}), ": Revision #$rev->{revid} of $commit{title}\n";
 980                 import_file_revision(\%commit, ($fetch_from == 1), $n_actual, \%mediafile);
 981         }
 982
 983         return $n_actual;
 984 }
 985
 986 sub error_non_fast_forward {
 987         my $advice = run_git_quoted(["config", "--bool", "advice.pushNonFastForward"]);
 988         chomp($advice);
 989         if ($advice ne 'false') {
 990                 # Native git-push would show this after the summary.
 991                 # We can't ask it to display it cleanly, so print it
 992                 # ourselves before.
 993                 print {*STDERR} "To prevent you from losing history, non-fast-forward updates were rejected\n";
 994                 print {*STDERR} "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 995                 print {*STDERR} "'Note about fast-forwards' section of 'git push --help' for details.\n";
 996         }
 997         print {*STDOUT} qq(error $_[0] "non-fast-forward"\n);
 998         return 0;
 999 }
1000
1001 sub mw_upload_file {
1002         my $complete_file_name = shift;
1003         my $new_sha1 = shift;
1004         my $extension = shift;
1005         my $file_deleted = shift;
1006         my $summary = shift;
1007         my $newrevid;
1008         my $path = "File:${complete_file_name}";
1009         my %hashFiles = get_allowed_file_extensions();
1010         if (!exists($hashFiles{$extension})) {
1011                 print {*STDERR} "${complete_file_name} is not a permitted file on this wiki.\n";
1012                 print {*STDERR} "Check the configuration of file uploads in your mediawiki.\n";
1013                 return $newrevid;
1014         }
1015         # Deleting and uploading a file requires a privileged user
1016         if ($file_deleted) {
1017                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1018                 my $query = {
1019                         action => 'delete',
1020                         title => $path,
1021                         reason => $summary
1022                 };
1023                 if (!$mediawiki->edit($query)) {
1024                         print {*STDERR} "Failed to delete file on remote wiki\n";
1025                         print {*STDERR} "Check your permissions on the remote site. Error code:\n";
1026                         print {*STDERR} $mediawiki->{error}->{code} . ':' . $mediawiki->{error}->{details};
1027                         exit 1;
1028                 }
1029         } else {
1030                 # Don't let perl try to interpret file content as UTF-8 => use "raw"
1031                 my $content = run_git_quoted(["cat-file", "blob", $new_sha1], 'raw');
1032                 if ($content ne EMPTY) {
1033                         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1034                         $mediawiki->{config}->{upload_url} =
1035                                 "${url}/index.php/Special:Upload";
1036                         $mediawiki->edit({
1037                                 action => 'upload',
1038                                 filename => $complete_file_name,
1039                                 comment => $summary,
1040                                 file => [undef,
1041                                          $complete_file_name,
1042                                          Content => $content],
1043                                 ignorewarnings => 1,
1044                         }, {
1045                                 skip_encoding => 1
1046                         } ) || die $mediawiki->{error}->{code} . ':'
1047                                  . $mediawiki->{error}->{details} . "\n";
1048                         my $last_file_page = $mediawiki->get_page({title => $path});
1049                         $newrevid = $last_file_page->{revid};
1050                         print {*STDERR} "Pushed file: ${new_sha1} - ${complete_file_name}.\n";
1051                 } else {
1052                         print {*STDERR} "Empty file ${complete_file_name} not pushed.\n";
1053                 }
1054         }
1055         return $newrevid;
1056 }
1057
1058 sub mw_push_file {
1059         my $diff_info = shift;
1060         # $diff_info contains a string in this format:
1061         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
1062         my @diff_info_split = split(/[ \t]/, $diff_info);
1063
1064         # Filename, including .mw extension
1065         my $complete_file_name = shift;
1066         # Commit message
1067         my $summary = shift;
1068         # MediaWiki revision number. Keep the previous one by default,
1069         # in case there's no edit to perform.
1070         my $oldrevid = shift;
1071         my $newrevid;
1072
1073         if ($summary eq EMPTY_MESSAGE) {
1074                 $summary = EMPTY;
1075         }
1076
1077         my $new_sha1 = $diff_info_split[3];
1078         my $old_sha1 = $diff_info_split[2];
1079         my $page_created = ($old_sha1 eq NULL_SHA1);
1080         my $page_deleted = ($new_sha1 eq NULL_SHA1);
1081         $complete_file_name = clean_filename($complete_file_name);
1082
1083         my ($title, $extension) = $complete_file_name =~ /^(.*)\.([^\.]*)$/;
1084         if (!defined($extension)) {
1085                 $extension = EMPTY;
1086         }
1087         if ($extension eq 'mw') {
1088                 my $ns = get_mw_namespace_id_for_page($complete_file_name);
1089                 if ($ns && $ns == get_mw_namespace_id('File') && (!$export_media)) {
1090                         print {*STDERR} "Ignoring media file related page: ${complete_file_name}\n";
1091                         return ($oldrevid, 'ok');
1092                 }
1093                 my $file_content;
1094                 if ($page_deleted) {
1095                         # Deleting a page usually requires
1096                         # special privileges. A common
1097                         # convention is to replace the page
1098                         # with this content instead:
1099                         $file_content = DELETED_CONTENT;
1100                 } else {
1101                         $file_content = run_git_quoted(["cat-file", "blob", $new_sha1]);
1102                 }
1103
1104                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1105
1106                 my $result = $mediawiki->edit( {
1107                         action => 'edit',
1108                         summary => $summary,
1109                         title => $title,
1110                         basetimestamp => $basetimestamps{$oldrevid},
1111                         text => mediawiki_clean($file_content, $page_created),
1112                                   }, {
1113                                           skip_encoding => 1 # Helps with names with accentuated characters
1114                                   });
1115                 if (!$result) {
1116                         if ($mediawiki->{error}->{code} == 3) {
1117                                 # edit conflicts, considered as non-fast-forward
1118                                 print {*STDERR} 'Warning: Error ' .
1119                                     $mediawiki->{error}->{code} .
1120                                     ' from mediawiki: ' . $mediawiki->{error}->{details} .
1121                                     ".\n";
1122                                 return ($oldrevid, 'non-fast-forward');
1123                         } else {
1124                                 # Other errors. Shouldn't happen => just die()
1125                                 die 'Fatal: Error ' .
1126                                     $mediawiki->{error}->{code} .
1127                                     ' from mediawiki: ' . $mediawiki->{error}->{details} . "\n";
1128                         }
1129                 }
1130                 $newrevid = $result->{edit}->{newrevid};
1131                 print {*STDERR} "Pushed file: ${new_sha1} - ${title}\n";
1132         } elsif ($export_media) {
1133                 $newrevid = mw_upload_file($complete_file_name, $new_sha1,
1134                                            $extension, $page_deleted,
1135                                            $summary);
1136         } else {
1137                 print {*STDERR} "Ignoring media file ${title}\n";
1138         }
1139         $newrevid = ($newrevid or $oldrevid);
1140         return ($newrevid, 'ok');
1141 }
1142
1143 sub mw_push {
1144         # multiple push statements can follow each other
1145         my @refsspecs = (shift, get_more_refs('push'));
1146         my $pushed;
1147         for my $refspec (@refsspecs) {
1148                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
1149                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>\n");
1150                 if ($force) {
1151                         print {*STDERR} "Warning: forced push not allowed on a MediaWiki.\n";
1152                 }
1153                 if ($local eq EMPTY) {
1154                         print {*STDERR} "Cannot delete remote branch on a MediaWiki\n";
1155                         print {*STDOUT} "error ${remote} cannot delete\n";
1156                         next;
1157                 }
1158                 if ($remote ne 'refs/heads/master') {
1159                         print {*STDERR} "Only push to the branch 'master' is supported on a MediaWiki\n";
1160                         print {*STDOUT} "error ${remote} only master allowed\n";
1161                         next;
1162                 }
1163                 if (mw_push_revision($local, $remote)) {
1164                         $pushed = 1;
1165                 }
1166         }
1167
1168         # Notify Git that the push is done
1169         print {*STDOUT} "\n";
1170
1171         if ($pushed && $dumb_push) {
1172                 print {*STDERR} "Just pushed some revisions to MediaWiki.\n";
1173                 print {*STDERR} "The pushed revisions now have to be re-imported, and your current branch\n";
1174                 print {*STDERR} "needs to be updated with these re-imported commits. You can do this with\n";
1175                 print {*STDERR} "\n";
1176                 print {*STDERR} "  git pull --rebase\n";
1177                 print {*STDERR} "\n";
1178         }
1179         return;
1180 }
1181
1182 sub mw_push_revision {
1183         my $local = shift;
1184         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
1185         my $last_local_revid = get_last_local_revision();
1186         print {*STDERR} ".\n"; # Finish sentence started by get_last_local_revision()
1187         my $last_remote_revid = get_last_remote_revision();
1188         my $mw_revision = $last_remote_revid;
1189
1190         # Get sha1 of commit pointed by local HEAD
1191         my $HEAD_sha1 = run_git("rev-parse ${local} 2>/dev/null");
1192         chomp($HEAD_sha1);
1193         # Get sha1 of commit pointed by remotes/$remotename/master
1194         my $remoteorigin_sha1 = run_git("rev-parse refs/remotes/${remotename}/master 2>/dev/null");
1195         chomp($remoteorigin_sha1);
1196
1197         if ($last_local_revid > 0 &&
1198             $last_local_revid < $last_remote_revid) {
1199                 return error_non_fast_forward($remote);
1200         }
1201
1202         if ($HEAD_sha1 eq $remoteorigin_sha1) {
1203                 # nothing to push
1204                 return 0;
1205         }
1206
1207         # Get every commit in between HEAD and refs/remotes/origin/master,
1208         # including HEAD and refs/remotes/origin/master
1209         my @commit_pairs = ();
1210         if ($last_local_revid > 0) {
1211                 my $parsed_sha1 = $remoteorigin_sha1;
1212                 # Find a path from last MediaWiki commit to pushed commit
1213                 print {*STDERR} "Computing path from local to remote ...\n";
1214                 my @local_ancestry = split(/\n/, run_git_quoted(["rev-list", "--boundary", "--parents", $local, "^${parsed_sha1}"]));
1215                 my %local_ancestry;
1216                 foreach my $line (@local_ancestry) {
1217                         if (my ($child, $parents) = $line =~ /^-?([a-f0-9]+) ([a-f0-9 ]+)/) {
1218                                 foreach my $parent (split(/ /, $parents)) {
1219                                         $local_ancestry{$parent} = $child;
1220                                 }
1221                         } elsif (!$line =~ /^([a-f0-9]+)/) {
1222                                 die "Unexpected output from git rev-list: ${line}\n";
1223                         }
1224                 }
1225                 while ($parsed_sha1 ne $HEAD_sha1) {
1226                         my $child = $local_ancestry{$parsed_sha1};
1227                         if (!$child) {
1228                                 print {*STDERR} "Cannot find a path in history from remote commit to last commit\n";
1229                                 return error_non_fast_forward($remote);
1230                         }
1231                         push(@commit_pairs, [$parsed_sha1, $child]);
1232                         $parsed_sha1 = $child;
1233                 }
1234         } else {
1235                 # No remote mediawiki revision. Export the whole
1236                 # history (linearized with --first-parent)
1237                 print {*STDERR} "Warning: no common ancestor, pushing complete history\n";
1238                 my $history = run_git_quoted(["rev-list", "--first-parent", "--children", $local]);
1239                 my @history = split(/\n/, $history);
1240                 @history = @history[1..$#history];
1241                 foreach my $line (reverse @history) {
1242                         my @commit_info_split = split(/[ \n]/, $line);
1243                         push(@commit_pairs, \@commit_info_split);
1244                 }
1245         }
1246
1247         foreach my $commit_info_split (@commit_pairs) {
1248                 my $sha1_child = @{$commit_info_split}[0];
1249                 my $sha1_commit = @{$commit_info_split}[1];
1250                 my $diff_infos = run_git_quoted(["diff-tree", "-r", "--raw", "-z", $sha1_child, $sha1_commit]);
1251                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
1252                 # TODO: for now, it's just a delete+add
1253                 my @diff_info_list = split(/\0/, $diff_infos);
1254                 # Keep the subject line of the commit message as mediawiki comment for the revision
1255                 my $commit_msg = run_git_quoted(["log", "--no-walk", '--format="%s"', $sha1_commit]);
1256                 chomp($commit_msg);
1257                 # Push every blob
1258                 while (@diff_info_list) {
1259                         my $status;
1260                         # git diff-tree -z gives an output like
1261                         # <metadata>\0<filename1>\0
1262                         # <metadata>\0<filename2>\0
1263                         # and we've split on \0.
1264                         my $info = shift(@diff_info_list);
1265                         my $file = shift(@diff_info_list);
1266                         ($mw_revision, $status) = mw_push_file($info, $file, $commit_msg, $mw_revision);
1267                         if ($status eq 'non-fast-forward') {
1268                                 # we may already have sent part of the
1269                                 # commit to MediaWiki, but it's too
1270                                 # late to cancel it. Stop the push in
1271                                 # the middle, but still give an
1272                                 # accurate error message.
1273                                 return error_non_fast_forward($remote);
1274                         }
1275                         if ($status ne 'ok') {
1276                                 die("Unknown error from mw_push_file()\n");
1277                         }
1278                 }
1279                 if (!$dumb_push) {
1280                         run_git_quoted(["notes", "--ref=${remotename}/mediawiki",
1281                                         "add", "-f", "-m",
1282                                         "mediawiki_revision: ${mw_revision}",
1283                                         $sha1_commit]);
1284                 }
1285         }
1286
1287         print {*STDOUT} "ok ${remote}\n";
1288         return 1;
1289 }
1290
1291 sub get_allowed_file_extensions {
1292         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1293
1294         my $query = {
1295                 action => 'query',
1296                 meta => 'siteinfo',
1297                 siprop => 'fileextensions'
1298                 };
1299         my $result = $mediawiki->api($query);
1300         my @file_extensions = map { $_->{ext}} @{$result->{query}->{fileextensions}};
1301         my %hashFile = map { $_ => 1 } @file_extensions;
1302
1303         return %hashFile;
1304 }
1305
1306 # In memory cache for MediaWiki namespace ids.
1307 my %namespace_id;
1308
1309 # Namespaces whose id is cached in the configuration file
1310 # (to avoid duplicates)
1311 my %cached_mw_namespace_id;
1312
1313 # Return MediaWiki id for a canonical namespace name.
1314 # Ex.: "File", "Project".
1315 sub get_mw_namespace_id {
1316         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1317         my $name = shift;
1318
1319         if (!exists $namespace_id{$name}) {
1320                 # Look at configuration file, if the record for that namespace is
1321                 # already cached. Namespaces are stored in form:
1322                 # "Name_of_namespace:Id_namespace", ex.: "File:6".
1323                 my @temp = split(/\n/,
1324                                  run_git_quoted(["config", "--get-all", "remote.${remotename}.namespaceCache"]));
1325                 chomp(@temp);
1326                 foreach my $ns (@temp) {
1327                         my ($n, $id) = split(/:/, $ns);
1328                         if ($id eq 'notANameSpace') {
1329                                 $namespace_id{$n} = {is_namespace => 0};
1330                         } else {
1331                                 $namespace_id{$n} = {is_namespace => 1, id => $id};
1332                         }
1333                         $cached_mw_namespace_id{$n} = 1;
1334                 }
1335         }
1336
1337         if (!exists $namespace_id{$name}) {
1338                 print {*STDERR} "Namespace ${name} not found in cache, querying the wiki ...\n";
1339                 # NS not found => get namespace id from MW and store it in
1340                 # configuration file.
1341                 my $query = {
1342                         action => 'query',
1343                         meta => 'siteinfo',
1344                         siprop => 'namespaces'
1345                 };
1346                 my $result = $mediawiki->api($query);
1347
1348                 while (my ($id, $ns) = each(%{$result->{query}->{namespaces}})) {
1349                         if (defined($ns->{id}) && defined($ns->{canonical})) {
1350                                 $namespace_id{$ns->{canonical}} = {is_namespace => 1, id => $ns->{id}};
1351                                 if ($ns->{'*'}) {
1352                                         # alias (e.g. french Fichier: as alias for canonical File:)
1353                                         $namespace_id{$ns->{'*'}} = {is_namespace => 1, id => $ns->{id}};
1354                                 }
1355                         }
1356                 }
1357         }
1358
1359         my $ns = $namespace_id{$name};
1360         my $id;
1361
1362         if (!defined $ns) {
1363                 my @namespaces = map { s/ /_/g; $_; } sort keys %namespace_id;
1364                 print {*STDERR} "No such namespace ${name} on MediaWiki, known namespaces: @namespaces\n";
1365                 $ns = {is_namespace => 0};
1366                 $namespace_id{$name} = $ns;
1367         }
1368
1369         if ($ns->{is_namespace}) {
1370                 $id = $ns->{id};
1371         }
1372
1373         # Store "notANameSpace" as special value for inexisting namespaces
1374         my $store_id = ($id || 'notANameSpace');
1375
1376         # Store explicitly requested namespaces on disk
1377         if (!exists $cached_mw_namespace_id{$name}) {
1378                 run_git_quoted(["config", "--add", "remote.${remotename}.namespaceCache", "${name}:${store_id}"]);
1379                 $cached_mw_namespace_id{$name} = 1;
1380         }
1381         return $id;
1382 }
1383
1384 sub get_mw_namespace_id_for_page {
1385         my $namespace = shift;
1386         if ($namespace =~ /^([^:]*):/) {
1387                 return get_mw_namespace_id($namespace);
1388         } else {
1389                 return;
1390         }
1391 }