git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Define ZLIB_PATH to provide path to zlib.
  79 GIT_ARG_SET_PATH(zlib)
  80 #
  81 # Declare the with-tcltk/without-tcltk options.
  82 AC_ARG_WITH(tcltk,
  83 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  84 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  85 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  86 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  87 GIT_PARSE_WITH(tcltk))
  88 #
  89
  90
  91 ## Checks for programs.
  92 AC_MSG_NOTICE([CHECKS for programs])
  93 #
  94 AC_PROG_CC([cc gcc])
  95 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  96 AC_CHECK_TOOL(AR, ar, :)
  97 AC_CHECK_PROGS(TAR, [gtar tar])
  98 # TCLTK_PATH will be set to some value if we want Tcl/Tk
  99 # or will be empty otherwise.
 100 if test -z "$NO_TCLTK"; then
 101   if test "$with_tcltk" = ""; then
 102   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 103     TCLTK_PATH=wish
 104     AC_SUBST(TCLTK_PATH)
 105   elif test "$with_tcltk" = "yes"; then
 106   # Tcl/Tk check requested.
 107     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 108   else
 109     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 110     TCLTK_PATH="$with_tcltk"
 111     AC_SUBST(TCLTK_PATH)
 112   fi
 113 fi
 114
 115 ## Checks for libraries.
 116 AC_MSG_NOTICE([CHECKS for libraries])
 117 #
 118 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 119 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 120 AC_CHECK_LIB([crypto], [SHA1_Init],
 121 [NEEDS_SSL_WITH_CRYPTO=],
 122 [AC_CHECK_LIB([ssl], [SHA1_Init],
 123  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 124   NEEDS_SSL_WITH_CRYPTO=],
 125  [NO_OPENSSL=YesPlease])])
 126 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 127 AC_SUBST(NO_OPENSSL)
 128 #
 129 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 130 # git-http-push are not built, and you cannot use http:// and https://
 131 # transports.
 132 AC_CHECK_LIB([curl], [curl_global_init],
 133 [NO_CURL=],
 134 [NO_CURL=YesPlease])
 135 AC_SUBST(NO_CURL)
 136 #
 137 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 138 # not built, and you cannot push using http:// and https:// transports.
 139 AC_CHECK_LIB([expat], [XML_ParserCreate],
 140 [NO_EXPAT=],
 141 [NO_EXPAT=YesPlease])
 142 AC_SUBST(NO_EXPAT)
 143 #
 144 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 145 # some Solaris installations).
 146 # Define NO_ICONV if neither libc nor libiconv support iconv.
 147 AC_DEFUN([ICONVTEST_SRC], [
 148 #include <iconv.h>
 149
 150 int main(void)
 151 {
 152         iconv_open("", "");
 153         return 0;
 154 }
 155 ])
 156 AC_MSG_CHECKING([for iconv in -lc])
 157 AC_LINK_IFELSE(ICONVTEST_SRC,
 158         [AC_MSG_RESULT([yes])
 159         NEEDS_LIBICONV=],
 160         [AC_MSG_RESULT([no])
 161         old_LIBS="$LIBS"
 162         LIBS="$LIBS -liconv"
 163         AC_MSG_CHECKING([for iconv in -liconv])
 164         AC_LINK_IFELSE(ICONVTEST_SRC,
 165                 [AC_MSG_RESULT([yes])
 166                 NEEDS_LIBICONV=YesPlease],
 167                 [AC_MSG_RESULT([no])
 168                 NO_ICONV=YesPlease])
 169         LIBS="$old_LIBS"])
 170 AC_SUBST(NEEDS_LIBICONV)
 171 AC_SUBST(NO_ICONV)
 172 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 173 #
 174 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 175 # Patrick Mauritz).
 176 AC_CHECK_LIB([c], [socket],
 177 [NEEDS_SOCKET=],
 178 [NEEDS_SOCKET=YesPlease])
 179 AC_SUBST(NEEDS_SOCKET)
 180 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 181
 182
 183 ## Checks for header files.
 184
 185
 186 ## Checks for typedefs, structures, and compiler characteristics.
 187 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 188 #
 189 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 190 AC_CHECK_MEMBER(struct dirent.d_ino,
 191 [NO_D_INO_IN_DIRENT=],
 192 [NO_D_INO_IN_DIRENT=YesPlease],
 193 [#include <dirent.h>])
 194 AC_SUBST(NO_D_INO_IN_DIRENT)
 195 #
 196 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 197 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 198 AC_CHECK_MEMBER(struct dirent.d_type,
 199 [NO_D_TYPE_IN_DIRENT=],
 200 [NO_D_TYPE_IN_DIRENT=YesPlease],
 201 [#include <dirent.h>])
 202 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 203 #
 204 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 205 # sockaddr_storage.
 206 AC_CHECK_TYPE(struct sockaddr_storage,
 207 [NO_SOCKADDR_STORAGE=],
 208 [NO_SOCKADDR_STORAGE=YesPlease],[
 209 #include <sys/types.h>
 210 #include <sys/socket.h>
 211 ])
 212 AC_SUBST(NO_SOCKADDR_STORAGE)
 213 #
 214 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 215 AC_CHECK_TYPE([struct addrinfo],[
 216  AC_CHECK_FUNC([getaddrinfo],
 217   [NO_IPV6=],
 218   [NO_IPV6=YesPlease])
 219 ],[NO_IPV6=YesPlease],[
 220 #include <sys/types.h>
 221 #include <sys/socket.h>
 222 #include <netdb.h>
 223 ])
 224 AC_SUBST(NO_IPV6)
 225 #
 226 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 227 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 228 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 229 # some C compilers supported these specifiers prior to C99 as an extension.
 230 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 231  [ac_cv_c_c99_format],
 232 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 233 AC_RUN_IFELSE(
 234         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 235                 [[char buf[64];
 236                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 237                   exit(1);
 238                 else if (strcmp(buf, "12345"))
 239                   exit(2);]])],
 240         [ac_cv_c_c99_format=yes],
 241         [ac_cv_c_c99_format=no])
 242 ])
 243 if test $ac_cv_c_c99_format = no; then
 244         NO_C99_FORMAT=YesPlease
 245 else
 246         NO_C99_FORMAT=
 247 fi
 248 AC_SUBST(NO_C99_FORMAT)
 249
 250
 251 ## Checks for library functions.
 252 ## (in default C library and libraries checked by AC_CHECK_LIB)
 253 AC_MSG_NOTICE([CHECKS for library functions])
 254 #
 255 # Define NO_STRCASESTR if you don't have strcasestr.
 256 AC_CHECK_FUNC(strcasestr,
 257 [NO_STRCASESTR=],
 258 [NO_STRCASESTR=YesPlease])
 259 AC_SUBST(NO_STRCASESTR)
 260 #
 261 # Define NO_STRLCPY if you don't have strlcpy.
 262 AC_CHECK_FUNC(strlcpy,
 263 [NO_STRLCPY=],
 264 [NO_STRLCPY=YesPlease])
 265 AC_SUBST(NO_STRLCPY)
 266 #
 267 # Define NO_SETENV if you don't have setenv in the C library.
 268 AC_CHECK_FUNC(setenv,
 269 [NO_SETENV=],
 270 [NO_SETENV=YesPlease])
 271 AC_SUBST(NO_SETENV)
 272 #
 273 # Define NO_MMAP if you want to avoid mmap.
 274 #
 275 # Define NO_ICONV if your libc does not properly support iconv.
 276
 277
 278 ## Other checks.
 279 # Define USE_PIC if you need the main git objects to be built with -fPIC
 280 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 281 #
 282 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 283 # Enable it on Windows.  By default, symrefs are still used.
 284
 285 ## Site configuration (override autodetection)
 286 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 287 AC_MSG_NOTICE([CHECKS for site configuration])
 288 #
 289 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 290 # tests.  These tests take up a significant amount of the total test time
 291 # but are not needed unless you plan to talk to SVN repos.
 292 #
 293 # Define MOZILLA_SHA1 environment variable when running make to make use of
 294 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 295 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 296 # choice) has very fast version optimized for i586.
 297 #
 298 # Define PPC_SHA1 environment variable when running make to make use of
 299 # a bundled SHA1 routine optimized for PowerPC.
 300 #
 301 # Define ARM_SHA1 environment variable when running make to make use of
 302 # a bundled SHA1 routine optimized for ARM.
 303 #
 304 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 305 # This also implies MOZILLA_SHA1.
 306 #
 307 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 308 # /foo/bar/include and /foo/bar/lib directories.
 309 AC_ARG_WITH(openssl,
 310 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 311 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 312 GIT_PARSE_WITH(openssl))
 313 #
 314 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 315 # git-http-push are not built, and you cannot use http:// and https://
 316 # transports.
 317 #
 318 # Define CURLDIR=/foo/bar if your curl header and library files are in
 319 # /foo/bar/include and /foo/bar/lib directories.
 320 AC_ARG_WITH(curl,
 321 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 322 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 323 GIT_PARSE_WITH(curl))
 324 #
 325 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 326 # not built, and you cannot push using http:// and https:// transports.
 327 #
 328 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 329 # /foo/bar/include and /foo/bar/lib directories.
 330 AC_ARG_WITH(expat,
 331 AS_HELP_STRING([--with-expat],
 332 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 333 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 334 GIT_PARSE_WITH(expat))
 335 #
 336 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 337 # installed in /sw, but don't want GIT to link against any libraries
 338 # installed there.  If defined you may specify your own (or Fink's)
 339 # include directories and library directories by defining CFLAGS
 340 # and LDFLAGS appropriately.
 341 #
 342 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 343 # have DarwinPorts installed in /opt/local, but don't want GIT to
 344 # link against any libraries installed there.  If defined you may
 345 # specify your own (or DarwinPort's) include directories and
 346 # library directories by defining CFLAGS and LDFLAGS appropriately.
 347 #
 348 # Define NO_MMAP if you want to avoid mmap.
 349 #
 350 # Define NO_ICONV if your libc does not properly support iconv.
 351 AC_ARG_WITH(iconv,
 352 AS_HELP_STRING([--without-iconv],
 353 [if your architecture doesn't properly support iconv])
 354 AS_HELP_STRING([--with-iconv=PATH],
 355 [PATH is prefix for libiconv library and headers])
 356 AS_HELP_STRING([],
 357 [used only if you need linking with libiconv]),
 358 GIT_PARSE_WITH(iconv))
 359
 360 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 361 #
 362 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 363 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 364 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 365 # randomly break unless your underlying filesystem supports those sub-second
 366 # times (my ext3 doesn't).
 367 #
 368 # Define USE_STDEV below if you want git to care about the underlying device
 369 # change being considered an inode change from the update-cache perspective.
 370
 371
 372 ## Output files
 373 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 374 AC_OUTPUT
 375
 376
 377 ## Cleanup
 378 rm -f "${config_append}"