git.oblomov.eu Git - git/blob - git-add--interactive.perl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Git;
   5
   6 binmode(STDOUT, ":raw");
   7
   8 my $repo = Git->repository();
   9
  10 my $menu_use_color = $repo->get_colorbool('color.interactive');
  11 my ($prompt_color, $header_color, $help_color) =
  12         $menu_use_color ? (
  13                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  14                 $repo->get_color('color.interactive.header', 'bold'),
  15                 $repo->get_color('color.interactive.help', 'red bold'),
  16         ) : ();
  17 my $error_color = ();
  18 if ($menu_use_color) {
  19         my $help_color_spec = ($repo->config('color.interactive.help') or
  20                                 'red bold');
  21         $error_color = $repo->get_color('color.interactive.error',
  22                                         $help_color_spec);
  23 }
  24
  25 my $diff_use_color = $repo->get_colorbool('color.diff');
  26 my ($fraginfo_color) =
  27         $diff_use_color ? (
  28                 $repo->get_color('color.diff.frag', 'cyan'),
  29         ) : ();
  30 my ($diff_plain_color) =
  31         $diff_use_color ? (
  32                 $repo->get_color('color.diff.plain', ''),
  33         ) : ();
  34 my ($diff_old_color) =
  35         $diff_use_color ? (
  36                 $repo->get_color('color.diff.old', 'red'),
  37         ) : ();
  38 my ($diff_new_color) =
  39         $diff_use_color ? (
  40                 $repo->get_color('color.diff.new', 'green'),
  41         ) : ();
  42
  43 my $normal_color = $repo->get_color("", "reset");
  44
  45 my $use_readkey = 0;
  46 sub ReadMode;
  47 sub ReadKey;
  48 if ($repo->config_bool("interactive.singlekey")) {
  49         eval {
  50                 require Term::ReadKey;
  51                 Term::ReadKey->import;
  52                 $use_readkey = 1;
  53         };
  54 }
  55
  56 sub colored {
  57         my $color = shift;
  58         my $string = join("", @_);
  59
  60         if (defined $color) {
  61                 # Put a color code at the beginning of each line, a reset at the end
  62                 # color after newlines that are not at the end of the string
  63                 $string =~ s/(\n+)(.)/$1$color$2/g;
  64                 # reset before newlines
  65                 $string =~ s/(\n+)/$normal_color$1/g;
  66                 # codes at beginning and end (if necessary):
  67                 $string =~ s/^/$color/;
  68                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  69         }
  70         return $string;
  71 }
  72
  73 # command line options
  74 my $patch_mode;
  75
  76 sub run_cmd_pipe {
  77         if ($^O eq 'MSWin32' || $^O eq 'msys') {
  78                 my @invalid = grep {m/[":*]/} @_;
  79                 die "$^O does not support: @invalid\n" if @invalid;
  80                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
  81                 return qx{@args};
  82         } else {
  83                 my $fh = undef;
  84                 open($fh, '-|', @_) or die;
  85                 return <$fh>;
  86         }
  87 }
  88
  89 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
  90
  91 if (!defined $GIT_DIR) {
  92         exit(1); # rev-parse would have already said "not a git repo"
  93 }
  94 chomp($GIT_DIR);
  95
  96 my %cquote_map = (
  97  "b" => chr(8),
  98  "t" => chr(9),
  99  "n" => chr(10),
 100  "v" => chr(11),
 101  "f" => chr(12),
 102  "r" => chr(13),
 103  "\\" => "\\",
 104  "\042" => "\042",
 105 );
 106
 107 sub unquote_path {
 108         local ($_) = @_;
 109         my ($retval, $remainder);
 110         if (!/^\042(.*)\042$/) {
 111                 return $_;
 112         }
 113         ($_, $retval) = ($1, "");
 114         while (/^([^\\]*)\\(.*)$/) {
 115                 $remainder = $2;
 116                 $retval .= $1;
 117                 for ($remainder) {
 118                         if (/^([0-3][0-7][0-7])(.*)$/) {
 119                                 $retval .= chr(oct($1));
 120                                 $_ = $2;
 121                                 last;
 122                         }
 123                         if (/^([\\\042btnvfr])(.*)$/) {
 124                                 $retval .= $cquote_map{$1};
 125                                 $_ = $2;
 126                                 last;
 127                         }
 128                         # This is malformed -- just return it as-is for now.
 129                         return $_[0];
 130                 }
 131                 $_ = $remainder;
 132         }
 133         $retval .= $_;
 134         return $retval;
 135 }
 136
 137 sub refresh {
 138         my $fh;
 139         open $fh, 'git update-index --refresh |'
 140             or die;
 141         while (<$fh>) {
 142                 ;# ignore 'needs update'
 143         }
 144         close $fh;
 145 }
 146
 147 sub list_untracked {
 148         map {
 149                 chomp $_;
 150                 unquote_path($_);
 151         }
 152         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 153 }
 154
 155 my $status_fmt = '%12s %12s %s';
 156 my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
 157
 158 {
 159         my $initial;
 160         sub is_initial_commit {
 161                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 162                         unless defined $initial;
 163                 return $initial;
 164         }
 165 }
 166
 167 sub get_empty_tree {
 168         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 169 }
 170
 171 # Returns list of hashes, contents of each of which are:
 172 # VALUE:        pathname
 173 # BINARY:       is a binary path
 174 # INDEX:        is index different from HEAD?
 175 # FILE:         is file different from index?
 176 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 177 # FILE_ADDDEL:  is it add/delete between index and file?
 178
 179 sub list_modified {
 180         my ($only) = @_;
 181         my (%data, @return);
 182         my ($add, $del, $adddel, $file);
 183         my @tracked = ();
 184
 185         if (@ARGV) {
 186                 @tracked = map {
 187                         chomp $_;
 188                         unquote_path($_);
 189                 } run_cmd_pipe(qw(git ls-files --exclude-standard --), @ARGV);
 190                 return if (!@tracked);
 191         }
 192
 193         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
 194         for (run_cmd_pipe(qw(git diff-index --cached
 195                              --numstat --summary), $reference,
 196                              '--', @tracked)) {
 197                 if (($add, $del, $file) =
 198                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 199                         my ($change, $bin);
 200                         $file = unquote_path($file);
 201                         if ($add eq '-' && $del eq '-') {
 202                                 $change = 'binary';
 203                                 $bin = 1;
 204                         }
 205                         else {
 206                                 $change = "+$add/-$del";
 207                         }
 208                         $data{$file} = {
 209                                 INDEX => $change,
 210                                 BINARY => $bin,
 211                                 FILE => 'nothing',
 212                         }
 213                 }
 214                 elsif (($adddel, $file) =
 215                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 216                         $file = unquote_path($file);
 217                         $data{$file}{INDEX_ADDDEL} = $adddel;
 218                 }
 219         }
 220
 221         for (run_cmd_pipe(qw(git diff-files --numstat --summary --), @tracked)) {
 222                 if (($add, $del, $file) =
 223                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 224                         $file = unquote_path($file);
 225                         if (!exists $data{$file}) {
 226                                 $data{$file} = +{
 227                                         INDEX => 'unchanged',
 228                                         BINARY => 0,
 229                                 };
 230                         }
 231                         my ($change, $bin);
 232                         if ($add eq '-' && $del eq '-') {
 233                                 $change = 'binary';
 234                                 $bin = 1;
 235                         }
 236                         else {
 237                                 $change = "+$add/-$del";
 238                         }
 239                         $data{$file}{FILE} = $change;
 240                         if ($bin) {
 241                                 $data{$file}{BINARY} = 1;
 242                         }
 243                 }
 244                 elsif (($adddel, $file) =
 245                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 246                         $file = unquote_path($file);
 247                         $data{$file}{FILE_ADDDEL} = $adddel;
 248                 }
 249         }
 250
 251         for (sort keys %data) {
 252                 my $it = $data{$_};
 253
 254                 if ($only) {
 255                         if ($only eq 'index-only') {
 256                                 next if ($it->{INDEX} eq 'unchanged');
 257                         }
 258                         if ($only eq 'file-only') {
 259                                 next if ($it->{FILE} eq 'nothing');
 260                         }
 261                 }
 262                 push @return, +{
 263                         VALUE => $_,
 264                         %$it,
 265                 };
 266         }
 267         return @return;
 268 }
 269
 270 sub find_unique {
 271         my ($string, @stuff) = @_;
 272         my $found = undef;
 273         for (my $i = 0; $i < @stuff; $i++) {
 274                 my $it = $stuff[$i];
 275                 my $hit = undef;
 276                 if (ref $it) {
 277                         if ((ref $it) eq 'ARRAY') {
 278                                 $it = $it->[0];
 279                         }
 280                         else {
 281                                 $it = $it->{VALUE};
 282                         }
 283                 }
 284                 eval {
 285                         if ($it =~ /^$string/) {
 286                                 $hit = 1;
 287                         };
 288                 };
 289                 if (defined $hit && defined $found) {
 290                         return undef;
 291                 }
 292                 if ($hit) {
 293                         $found = $i + 1;
 294                 }
 295         }
 296         return $found;
 297 }
 298
 299 # inserts string into trie and updates count for each character
 300 sub update_trie {
 301         my ($trie, $string) = @_;
 302         foreach (split //, $string) {
 303                 $trie = $trie->{$_} ||= {COUNT => 0};
 304                 $trie->{COUNT}++;
 305         }
 306 }
 307
 308 # returns an array of tuples (prefix, remainder)
 309 sub find_unique_prefixes {
 310         my @stuff = @_;
 311         my @return = ();
 312
 313         # any single prefix exceeding the soft limit is omitted
 314         # if any prefix exceeds the hard limit all are omitted
 315         # 0 indicates no limit
 316         my $soft_limit = 0;
 317         my $hard_limit = 3;
 318
 319         # build a trie modelling all possible options
 320         my %trie;
 321         foreach my $print (@stuff) {
 322                 if ((ref $print) eq 'ARRAY') {
 323                         $print = $print->[0];
 324                 }
 325                 elsif ((ref $print) eq 'HASH') {
 326                         $print = $print->{VALUE};
 327                 }
 328                 update_trie(\%trie, $print);
 329                 push @return, $print;
 330         }
 331
 332         # use the trie to find the unique prefixes
 333         for (my $i = 0; $i < @return; $i++) {
 334                 my $ret = $return[$i];
 335                 my @letters = split //, $ret;
 336                 my %search = %trie;
 337                 my ($prefix, $remainder);
 338                 my $j;
 339                 for ($j = 0; $j < @letters; $j++) {
 340                         my $letter = $letters[$j];
 341                         if ($search{$letter}{COUNT} == 1) {
 342                                 $prefix = substr $ret, 0, $j + 1;
 343                                 $remainder = substr $ret, $j + 1;
 344                                 last;
 345                         }
 346                         else {
 347                                 my $prefix = substr $ret, 0, $j;
 348                                 return ()
 349                                     if ($hard_limit && $j + 1 > $hard_limit);
 350                         }
 351                         %search = %{$search{$letter}};
 352                 }
 353                 if (ord($letters[0]) > 127 ||
 354                     ($soft_limit && $j + 1 > $soft_limit)) {
 355                         $prefix = undef;
 356                         $remainder = $ret;
 357                 }
 358                 $return[$i] = [$prefix, $remainder];
 359         }
 360         return @return;
 361 }
 362
 363 # filters out prefixes which have special meaning to list_and_choose()
 364 sub is_valid_prefix {
 365         my $prefix = shift;
 366         return (defined $prefix) &&
 367             !($prefix =~ /[\s,]/) && # separators
 368             !($prefix =~ /^-/) &&    # deselection
 369             !($prefix =~ /^\d+/) &&  # selection
 370             ($prefix ne '*') &&      # "all" wildcard
 371             ($prefix ne '?');        # prompt help
 372 }
 373
 374 # given a prefix/remainder tuple return a string with the prefix highlighted
 375 # for now use square brackets; later might use ANSI colors (underline, bold)
 376 sub highlight_prefix {
 377         my $prefix = shift;
 378         my $remainder = shift;
 379
 380         if (!defined $prefix) {
 381                 return $remainder;
 382         }
 383
 384         if (!is_valid_prefix($prefix)) {
 385                 return "$prefix$remainder";
 386         }
 387
 388         if (!$menu_use_color) {
 389                 return "[$prefix]$remainder";
 390         }
 391
 392         return "$prompt_color$prefix$normal_color$remainder";
 393 }
 394
 395 sub error_msg {
 396         print STDERR colored $error_color, @_;
 397 }
 398
 399 sub list_and_choose {
 400         my ($opts, @stuff) = @_;
 401         my (@chosen, @return);
 402         my $i;
 403         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 404
 405       TOPLOOP:
 406         while (1) {
 407                 my $last_lf = 0;
 408
 409                 if ($opts->{HEADER}) {
 410                         if (!$opts->{LIST_FLAT}) {
 411                                 print "     ";
 412                         }
 413                         print colored $header_color, "$opts->{HEADER}\n";
 414                 }
 415                 for ($i = 0; $i < @stuff; $i++) {
 416                         my $chosen = $chosen[$i] ? '*' : ' ';
 417                         my $print = $stuff[$i];
 418                         my $ref = ref $print;
 419                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 420                             if @prefixes;
 421                         if ($ref eq 'ARRAY') {
 422                                 $print = $highlighted || $print->[0];
 423                         }
 424                         elsif ($ref eq 'HASH') {
 425                                 my $value = $highlighted || $print->{VALUE};
 426                                 $print = sprintf($status_fmt,
 427                                     $print->{INDEX},
 428                                     $print->{FILE},
 429                                     $value);
 430                         }
 431                         else {
 432                                 $print = $highlighted || $print;
 433                         }
 434                         printf("%s%2d: %s", $chosen, $i+1, $print);
 435                         if (($opts->{LIST_FLAT}) &&
 436                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 437                                 print "\t";
 438                                 $last_lf = 0;
 439                         }
 440                         else {
 441                                 print "\n";
 442                                 $last_lf = 1;
 443                         }
 444                 }
 445                 if (!$last_lf) {
 446                         print "\n";
 447                 }
 448
 449                 return if ($opts->{LIST_ONLY});
 450
 451                 print colored $prompt_color, $opts->{PROMPT};
 452                 if ($opts->{SINGLETON}) {
 453                         print "> ";
 454                 }
 455                 else {
 456                         print ">> ";
 457                 }
 458                 my $line = <STDIN>;
 459                 if (!$line) {
 460                         print "\n";
 461                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 462                         last;
 463                 }
 464                 chomp $line;
 465                 last if $line eq '';
 466                 if ($line eq '?') {
 467                         $opts->{SINGLETON} ?
 468                             singleton_prompt_help_cmd() :
 469                             prompt_help_cmd();
 470                         next TOPLOOP;
 471                 }
 472                 for my $choice (split(/[\s,]+/, $line)) {
 473                         my $choose = 1;
 474                         my ($bottom, $top);
 475
 476                         # Input that begins with '-'; unchoose
 477                         if ($choice =~ s/^-//) {
 478                                 $choose = 0;
 479                         }
 480                         # A range can be specified like 5-7 or 5-.
 481                         if ($choice =~ /^(\d+)-(\d*)$/) {
 482                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 483                         }
 484                         elsif ($choice =~ /^\d+$/) {
 485                                 $bottom = $top = $choice;
 486                         }
 487                         elsif ($choice eq '*') {
 488                                 $bottom = 1;
 489                                 $top = 1 + @stuff;
 490                         }
 491                         else {
 492                                 $bottom = $top = find_unique($choice, @stuff);
 493                                 if (!defined $bottom) {
 494                                         error_msg "Huh ($choice)?\n";
 495                                         next TOPLOOP;
 496                                 }
 497                         }
 498                         if ($opts->{SINGLETON} && $bottom != $top) {
 499                                 error_msg "Huh ($choice)?\n";
 500                                 next TOPLOOP;
 501                         }
 502                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 503                                 next if (@stuff <= $i || $i < 0);
 504                                 $chosen[$i] = $choose;
 505                         }
 506                 }
 507                 last if ($opts->{IMMEDIATE} || $line eq '*');
 508         }
 509         for ($i = 0; $i < @stuff; $i++) {
 510                 if ($chosen[$i]) {
 511                         push @return, $stuff[$i];
 512                 }
 513         }
 514         return @return;
 515 }
 516
 517 sub singleton_prompt_help_cmd {
 518         print colored $help_color, <<\EOF ;
 519 Prompt help:
 520 1          - select a numbered item
 521 foo        - select item based on unique prefix
 522            - (empty) select nothing
 523 EOF
 524 }
 525
 526 sub prompt_help_cmd {
 527         print colored $help_color, <<\EOF ;
 528 Prompt help:
 529 1          - select a single item
 530 3-5        - select a range of items
 531 2-3,6-9    - select multiple ranges
 532 foo        - select item based on unique prefix
 533 -...       - unselect specified items
 534 *          - choose all items
 535            - (empty) finish selecting
 536 EOF
 537 }
 538
 539 sub status_cmd {
 540         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 541                         list_modified());
 542         print "\n";
 543 }
 544
 545 sub say_n_paths {
 546         my $did = shift @_;
 547         my $cnt = scalar @_;
 548         print "$did ";
 549         if (1 < $cnt) {
 550                 print "$cnt paths\n";
 551         }
 552         else {
 553                 print "one path\n";
 554         }
 555 }
 556
 557 sub update_cmd {
 558         my @mods = list_modified('file-only');
 559         return if (!@mods);
 560
 561         my @update = list_and_choose({ PROMPT => 'Update',
 562                                        HEADER => $status_head, },
 563                                      @mods);
 564         if (@update) {
 565                 system(qw(git update-index --add --remove --),
 566                        map { $_->{VALUE} } @update);
 567                 say_n_paths('updated', @update);
 568         }
 569         print "\n";
 570 }
 571
 572 sub revert_cmd {
 573         my @update = list_and_choose({ PROMPT => 'Revert',
 574                                        HEADER => $status_head, },
 575                                      list_modified());
 576         if (@update) {
 577                 if (is_initial_commit()) {
 578                         system(qw(git rm --cached),
 579                                 map { $_->{VALUE} } @update);
 580                 }
 581                 else {
 582                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 583                                                  map { $_->{VALUE} } @update);
 584                         my $fh;
 585                         open $fh, '| git update-index --index-info'
 586                             or die;
 587                         for (@lines) {
 588                                 print $fh $_;
 589                         }
 590                         close($fh);
 591                         for (@update) {
 592                                 if ($_->{INDEX_ADDDEL} &&
 593                                     $_->{INDEX_ADDDEL} eq 'create') {
 594                                         system(qw(git update-index --force-remove --),
 595                                                $_->{VALUE});
 596                                         print "note: $_->{VALUE} is untracked now.\n";
 597                                 }
 598                         }
 599                 }
 600                 refresh();
 601                 say_n_paths('reverted', @update);
 602         }
 603         print "\n";
 604 }
 605
 606 sub add_untracked_cmd {
 607         my @add = list_and_choose({ PROMPT => 'Add untracked' },
 608                                   list_untracked());
 609         if (@add) {
 610                 system(qw(git update-index --add --), @add);
 611                 say_n_paths('added', @add);
 612         }
 613         print "\n";
 614 }
 615
 616 sub parse_diff {
 617         my ($path) = @_;
 618         my @diff = run_cmd_pipe(qw(git diff-files -p --), $path);
 619         my @colored = ();
 620         if ($diff_use_color) {
 621                 @colored = run_cmd_pipe(qw(git diff-files -p --color --), $path);
 622         }
 623         my (@hunk) = { TEXT => [], DISPLAY => [] };
 624
 625         for (my $i = 0; $i < @diff; $i++) {
 626                 if ($diff[$i] =~ /^@@ /) {
 627                         push @hunk, { TEXT => [], DISPLAY => [] };
 628                 }
 629                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 630                 push @{$hunk[-1]{DISPLAY}},
 631                         ($diff_use_color ? $colored[$i] : $diff[$i]);
 632         }
 633         return @hunk;
 634 }
 635
 636 sub parse_diff_header {
 637         my $src = shift;
 638
 639         my $head = { TEXT => [], DISPLAY => [] };
 640         my $mode = { TEXT => [], DISPLAY => [] };
 641
 642         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 643                 my $dest = $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ?
 644                         $mode : $head;
 645                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 646                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 647         }
 648         return ($head, $mode);
 649 }
 650
 651 sub hunk_splittable {
 652         my ($text) = @_;
 653
 654         my @s = split_hunk($text);
 655         return (1 < @s);
 656 }
 657
 658 sub parse_hunk_header {
 659         my ($line) = @_;
 660         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 661             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
 662         $o_cnt = 1 unless defined $o_cnt;
 663         $n_cnt = 1 unless defined $n_cnt;
 664         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 665 }
 666
 667 sub split_hunk {
 668         my ($text, $display) = @_;
 669         my @split = ();
 670         if (!defined $display) {
 671                 $display = $text;
 672         }
 673         # If there are context lines in the middle of a hunk,
 674         # it can be split, but we would need to take care of
 675         # overlaps later.
 676
 677         my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
 678         my $hunk_start = 1;
 679
 680       OUTER:
 681         while (1) {
 682                 my $next_hunk_start = undef;
 683                 my $i = $hunk_start - 1;
 684                 my $this = +{
 685                         TEXT => [],
 686                         DISPLAY => [],
 687                         OLD => $o_ofs,
 688                         NEW => $n_ofs,
 689                         OCNT => 0,
 690                         NCNT => 0,
 691                         ADDDEL => 0,
 692                         POSTCTX => 0,
 693                         USE => undef,
 694                 };
 695
 696                 while (++$i < @$text) {
 697                         my $line = $text->[$i];
 698                         my $display = $display->[$i];
 699                         if ($line =~ /^ /) {
 700                                 if ($this->{ADDDEL} &&
 701                                     !defined $next_hunk_start) {
 702                                         # We have seen leading context and
 703                                         # adds/dels and then here is another
 704                                         # context, which is trailing for this
 705                                         # split hunk and leading for the next
 706                                         # one.
 707                                         $next_hunk_start = $i;
 708                                 }
 709                                 push @{$this->{TEXT}}, $line;
 710                                 push @{$this->{DISPLAY}}, $display;
 711                                 $this->{OCNT}++;
 712                                 $this->{NCNT}++;
 713                                 if (defined $next_hunk_start) {
 714                                         $this->{POSTCTX}++;
 715                                 }
 716                                 next;
 717                         }
 718
 719                         # add/del
 720                         if (defined $next_hunk_start) {
 721                                 # We are done with the current hunk and
 722                                 # this is the first real change for the
 723                                 # next split one.
 724                                 $hunk_start = $next_hunk_start;
 725                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 726                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 727                                 $o_ofs -= $this->{POSTCTX};
 728                                 $n_ofs -= $this->{POSTCTX};
 729                                 push @split, $this;
 730                                 redo OUTER;
 731                         }
 732                         push @{$this->{TEXT}}, $line;
 733                         push @{$this->{DISPLAY}}, $display;
 734                         $this->{ADDDEL}++;
 735                         if ($line =~ /^-/) {
 736                                 $this->{OCNT}++;
 737                         }
 738                         else {
 739                                 $this->{NCNT}++;
 740                         }
 741                 }
 742
 743                 push @split, $this;
 744                 last;
 745         }
 746
 747         for my $hunk (@split) {
 748                 $o_ofs = $hunk->{OLD};
 749                 $n_ofs = $hunk->{NEW};
 750                 my $o_cnt = $hunk->{OCNT};
 751                 my $n_cnt = $hunk->{NCNT};
 752
 753                 my $head = ("@@ -$o_ofs" .
 754                             (($o_cnt != 1) ? ",$o_cnt" : '') .
 755                             " +$n_ofs" .
 756                             (($n_cnt != 1) ? ",$n_cnt" : '') .
 757                             " @@\n");
 758                 my $display_head = $head;
 759                 unshift @{$hunk->{TEXT}}, $head;
 760                 if ($diff_use_color) {
 761                         $display_head = colored($fraginfo_color, $head);
 762                 }
 763                 unshift @{$hunk->{DISPLAY}}, $display_head;
 764         }
 765         return @split;
 766 }
 767
 768
 769 sub color_diff {
 770         return map {
 771                 colored((/^@/  ? $fraginfo_color :
 772                          /^\+/ ? $diff_new_color :
 773                          /^-/  ? $diff_old_color :
 774                          $diff_plain_color),
 775                         $_);
 776         } @_;
 777 }
 778
 779 sub edit_hunk_manually {
 780         my ($oldtext) = @_;
 781
 782         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
 783         my $fh;
 784         open $fh, '>', $hunkfile
 785                 or die "failed to open hunk edit file for writing: " . $!;
 786         print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
 787         print $fh @$oldtext;
 788         print $fh <<EOF;
 789 # ---
 790 # To remove '-' lines, make them ' ' lines (context).
 791 # To remove '+' lines, delete them.
 792 # Lines starting with # will be removed.
 793 #
 794 # If the patch applies cleanly, the edited hunk will immediately be
 795 # marked for staging. If it does not apply cleanly, you will be given
 796 # an opportunity to edit again. If all lines of the hunk are removed,
 797 # then the edit is aborted and the hunk is left unchanged.
 798 EOF
 799         close $fh;
 800
 801         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor")
 802                 || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 803         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
 804
 805         if ($? != 0) {
 806                 return undef;
 807         }
 808
 809         open $fh, '<', $hunkfile
 810                 or die "failed to open hunk edit file for reading: " . $!;
 811         my @newtext = grep { !/^#/ } <$fh>;
 812         close $fh;
 813         unlink $hunkfile;
 814
 815         # Abort if nothing remains
 816         if (!grep { /\S/ } @newtext) {
 817                 return undef;
 818         }
 819
 820         # Reinsert the first hunk header if the user accidentally deleted it
 821         if ($newtext[0] !~ /^@/) {
 822                 unshift @newtext, $oldtext->[0];
 823         }
 824         return \@newtext;
 825 }
 826
 827 sub diff_applies {
 828         my $fh;
 829         open $fh, '| git apply --recount --cached --check';
 830         for my $h (@_) {
 831                 print $fh @{$h->{TEXT}};
 832         }
 833         return close $fh;
 834 }
 835
 836 sub _restore_terminal_and_die {
 837         ReadMode 'restore';
 838         print "\n";
 839         exit 1;
 840 }
 841
 842 sub prompt_single_character {
 843         if ($use_readkey) {
 844                 local $SIG{TERM} = \&_restore_terminal_and_die;
 845                 local $SIG{INT} = \&_restore_terminal_and_die;
 846                 ReadMode 'cbreak';
 847                 my $key = ReadKey 0;
 848                 ReadMode 'restore';
 849                 print "$key" if defined $key;
 850                 print "\n";
 851                 return $key;
 852         } else {
 853                 return <STDIN>;
 854         }
 855 }
 856
 857 sub prompt_yesno {
 858         my ($prompt) = @_;
 859         while (1) {
 860                 print colored $prompt_color, $prompt;
 861                 my $line = prompt_single_character;
 862                 return 0 if $line =~ /^n/i;
 863                 return 1 if $line =~ /^y/i;
 864         }
 865 }
 866
 867 sub edit_hunk_loop {
 868         my ($head, $hunk, $ix) = @_;
 869         my $text = $hunk->[$ix]->{TEXT};
 870
 871         while (1) {
 872                 $text = edit_hunk_manually($text);
 873                 if (!defined $text) {
 874                         return undef;
 875                 }
 876                 my $newhunk = { TEXT => $text, USE => 1 };
 877                 if (diff_applies($head,
 878                                  @{$hunk}[0..$ix-1],
 879                                  $newhunk,
 880                                  @{$hunk}[$ix+1..$#{$hunk}])) {
 881                         $newhunk->{DISPLAY} = [color_diff(@{$text})];
 882                         return $newhunk;
 883                 }
 884                 else {
 885                         prompt_yesno(
 886                                 'Your edited hunk does not apply. Edit again '
 887                                 . '(saying "no" discards!) [y/n]? '
 888                                 ) or return undef;
 889                 }
 890         }
 891 }
 892
 893 sub help_patch_cmd {
 894         print colored $help_color, <<\EOF ;
 895 y - stage this hunk
 896 n - do not stage this hunk
 897 a - stage this and all the remaining hunks in the file
 898 d - do not stage this hunk nor any of the remaining hunks in the file
 899 g - select a hunk to go to
 900 / - search for a hunk matching the given regex
 901 j - leave this hunk undecided, see next undecided hunk
 902 J - leave this hunk undecided, see next hunk
 903 k - leave this hunk undecided, see previous undecided hunk
 904 K - leave this hunk undecided, see previous hunk
 905 s - split the current hunk into smaller hunks
 906 e - manually edit the current hunk
 907 ? - print help
 908 EOF
 909 }
 910
 911 sub patch_update_cmd {
 912         my @all_mods = list_modified('file-only');
 913         my @mods = grep { !($_->{BINARY}) } @all_mods;
 914         my @them;
 915
 916         if (!@mods) {
 917                 if (@all_mods) {
 918                         print STDERR "Only binary files changed.\n";
 919                 } else {
 920                         print STDERR "No changes.\n";
 921                 }
 922                 return 0;
 923         }
 924         if ($patch_mode) {
 925                 @them = @mods;
 926         }
 927         else {
 928                 @them = list_and_choose({ PROMPT => 'Patch update',
 929                                           HEADER => $status_head, },
 930                                         @mods);
 931         }
 932         for (@them) {
 933                 patch_update_file($_->{VALUE});
 934         }
 935 }
 936
 937 # Generate a one line summary of a hunk.
 938 sub summarize_hunk {
 939         my $rhunk = shift;
 940         my $summary = $rhunk->{TEXT}[0];
 941
 942         # Keep the line numbers, discard extra context.
 943         $summary =~ s/@@(.*?)@@.*/$1 /s;
 944         $summary .= " " x (20 - length $summary);
 945
 946         # Add some user context.
 947         for my $line (@{$rhunk->{TEXT}}) {
 948                 if ($line =~ m/^[+-].*\w/) {
 949                         $summary .= $line;
 950                         last;
 951                 }
 952         }
 953
 954         chomp $summary;
 955         return substr($summary, 0, 80) . "\n";
 956 }
 957
 958
 959 # Print a one-line summary of each hunk in the array ref in
 960 # the first argument, starting wih the index in the 2nd.
 961 sub display_hunks {
 962         my ($hunks, $i) = @_;
 963         my $ctr = 0;
 964         $i ||= 0;
 965         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
 966                 my $status = " ";
 967                 if (defined $hunks->[$i]{USE}) {
 968                         $status = $hunks->[$i]{USE} ? "+" : "-";
 969                 }
 970                 printf "%s%2d: %s",
 971                         $status,
 972                         $i + 1,
 973                         summarize_hunk($hunks->[$i]);
 974         }
 975         return $i;
 976 }
 977
 978 sub patch_update_file {
 979         my ($ix, $num);
 980         my $path = shift;
 981         my ($head, @hunk) = parse_diff($path);
 982         ($head, my $mode) = parse_diff_header($head);
 983         for (@{$head->{DISPLAY}}) {
 984                 print;
 985         }
 986
 987         if (@{$mode->{TEXT}}) {
 988                 while (1) {
 989                         print @{$mode->{DISPLAY}};
 990                         print colored $prompt_color,
 991                                 "Stage mode change [y/n/a/d/?]? ";
 992                         my $line = prompt_single_character;
 993                         if ($line =~ /^y/i) {
 994                                 $mode->{USE} = 1;
 995                                 last;
 996                         }
 997                         elsif ($line =~ /^n/i) {
 998                                 $mode->{USE} = 0;
 999                                 last;
1000                         }
1001                         elsif ($line =~ /^a/i) {
1002                                 $_->{USE} = 1 foreach ($mode, @hunk);
1003                                 last;
1004                         }
1005                         elsif ($line =~ /^d/i) {
1006                                 $_->{USE} = 0 foreach ($mode, @hunk);
1007                                 last;
1008                         }
1009                         else {
1010                                 help_patch_cmd('');
1011                                 next;
1012                         }
1013                 }
1014         }
1015
1016         $num = scalar @hunk;
1017         $ix = 0;
1018
1019         while (1) {
1020                 my ($prev, $next, $other, $undecided, $i);
1021                 $other = '';
1022
1023                 if ($num <= $ix) {
1024                         $ix = 0;
1025                 }
1026                 for ($i = 0; $i < $ix; $i++) {
1027                         if (!defined $hunk[$i]{USE}) {
1028                                 $prev = 1;
1029                                 $other .= ',k';
1030                                 last;
1031                         }
1032                 }
1033                 if ($ix) {
1034                         $other .= ',K';
1035                 }
1036                 for ($i = $ix + 1; $i < $num; $i++) {
1037                         if (!defined $hunk[$i]{USE}) {
1038                                 $next = 1;
1039                                 $other .= ',j';
1040                                 last;
1041                         }
1042                 }
1043                 if ($ix < $num - 1) {
1044                         $other .= ',J';
1045                 }
1046                 if ($num > 1) {
1047                         $other .= ',g';
1048                 }
1049                 for ($i = 0; $i < $num; $i++) {
1050                         if (!defined $hunk[$i]{USE}) {
1051                                 $undecided = 1;
1052                                 last;
1053                         }
1054                 }
1055                 last if (!$undecided);
1056
1057                 if (hunk_splittable($hunk[$ix]{TEXT})) {
1058                         $other .= ',s';
1059                 }
1060                 $other .= ',e';
1061                 for (@{$hunk[$ix]{DISPLAY}}) {
1062                         print;
1063                 }
1064                 print colored $prompt_color, "Stage this hunk [y,n,a,d,/$other,?]? ";
1065                 my $line = prompt_single_character;
1066                 if ($line) {
1067                         if ($line =~ /^y/i) {
1068                                 $hunk[$ix]{USE} = 1;
1069                         }
1070                         elsif ($line =~ /^n/i) {
1071                                 $hunk[$ix]{USE} = 0;
1072                         }
1073                         elsif ($line =~ /^a/i) {
1074                                 while ($ix < $num) {
1075                                         if (!defined $hunk[$ix]{USE}) {
1076                                                 $hunk[$ix]{USE} = 1;
1077                                         }
1078                                         $ix++;
1079                                 }
1080                                 next;
1081                         }
1082                         elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1083                                 my $response = $1;
1084                                 my $no = $ix > 10 ? $ix - 10 : 0;
1085                                 while ($response eq '') {
1086                                         my $extra = "";
1087                                         $no = display_hunks(\@hunk, $no);
1088                                         if ($no < $num) {
1089                                                 $extra = " (<ret> to see more)";
1090                                         }
1091                                         print "go to which hunk$extra? ";
1092                                         $response = <STDIN>;
1093                                         if (!defined $response) {
1094                                                 $response = '';
1095                                         }
1096                                         chomp $response;
1097                                 }
1098                                 if ($response !~ /^\s*\d+\s*$/) {
1099                                         error_msg "Invalid number: '$response'\n";
1100                                 } elsif (0 < $response && $response <= $num) {
1101                                         $ix = $response - 1;
1102                                 } else {
1103                                         error_msg "Sorry, only $num hunks available.\n";
1104                                 }
1105                                 next;
1106                         }
1107                         elsif ($line =~ /^d/i) {
1108                                 while ($ix < $num) {
1109                                         if (!defined $hunk[$ix]{USE}) {
1110                                                 $hunk[$ix]{USE} = 0;
1111                                         }
1112                                         $ix++;
1113                                 }
1114                                 next;
1115                         }
1116                         elsif ($line =~ m|^/(.*)|) {
1117                                 my $regex = $1;
1118                                 if ($1 eq "") {
1119                                         print colored $prompt_color, "search for regex? ";
1120                                         $regex = <STDIN>;
1121                                         if (defined $regex) {
1122                                                 chomp $regex;
1123                                         }
1124                                 }
1125                                 my $search_string;
1126                                 eval {
1127                                         $search_string = qr{$regex}m;
1128                                 };
1129                                 if ($@) {
1130                                         my ($err,$exp) = ($@, $1);
1131                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1132                                         error_msg "Malformed search regexp $exp: $err\n";
1133                                         next;
1134                                 }
1135                                 my $iy = $ix;
1136                                 while (1) {
1137                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1138                                         last if ($text =~ $search_string);
1139                                         $iy++;
1140                                         $iy = 0 if ($iy >= $num);
1141                                         if ($ix == $iy) {
1142                                                 error_msg "No hunk matches the given pattern\n";
1143                                                 last;
1144                                         }
1145                                 }
1146                                 $ix = $iy;
1147                                 next;
1148                         }
1149                         elsif ($line =~ /^K/) {
1150                                 if ($other =~ /K/) {
1151                                         $ix--;
1152                                 }
1153                                 else {
1154                                         error_msg "No previous hunk\n";
1155                                 }
1156                                 next;
1157                         }
1158                         elsif ($line =~ /^J/) {
1159                                 if ($other =~ /J/) {
1160                                         $ix++;
1161                                 }
1162                                 else {
1163                                         error_msg "No next hunk\n";
1164                                 }
1165                                 next;
1166                         }
1167                         elsif ($line =~ /^k/) {
1168                                 if ($other =~ /k/) {
1169                                         while (1) {
1170                                                 $ix--;
1171                                                 last if (!$ix ||
1172                                                          !defined $hunk[$ix]{USE});
1173                                         }
1174                                 }
1175                                 else {
1176                                         error_msg "No previous hunk\n";
1177                                 }
1178                                 next;
1179                         }
1180                         elsif ($line =~ /^j/) {
1181                                 if ($other !~ /j/) {
1182                                         error_msg "No next hunk\n";
1183                                         next;
1184                                 }
1185                         }
1186                         elsif ($other =~ /s/ && $line =~ /^s/) {
1187                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1188                                 if (1 < @split) {
1189                                         print colored $header_color, "Split into ",
1190                                         scalar(@split), " hunks.\n";
1191                                 }
1192                                 splice (@hunk, $ix, 1, @split);
1193                                 $num = scalar @hunk;
1194                                 next;
1195                         }
1196                         elsif ($line =~ /^e/) {
1197                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1198                                 if (defined $newhunk) {
1199                                         splice @hunk, $ix, 1, $newhunk;
1200                                 }
1201                         }
1202                         else {
1203                                 help_patch_cmd($other);
1204                                 next;
1205                         }
1206                         # soft increment
1207                         while (1) {
1208                                 $ix++;
1209                                 last if ($ix >= $num ||
1210                                          !defined $hunk[$ix]{USE});
1211                         }
1212                 }
1213         }
1214
1215         my $n_lofs = 0;
1216         my @result = ();
1217         if ($mode->{USE}) {
1218                 push @result, @{$mode->{TEXT}};
1219         }
1220         for (@hunk) {
1221                 if ($_->{USE}) {
1222                         push @result, @{$_->{TEXT}};
1223                 }
1224         }
1225
1226         if (@result) {
1227                 my $fh;
1228
1229                 open $fh, '| git apply --cached --recount';
1230                 for (@{$head->{TEXT}}, @result) {
1231                         print $fh $_;
1232                 }
1233                 if (!close $fh) {
1234                         for (@{$head->{TEXT}}, @result) {
1235                                 print STDERR $_;
1236                         }
1237                 }
1238                 refresh();
1239         }
1240
1241         print "\n";
1242 }
1243
1244 sub diff_cmd {
1245         my @mods = list_modified('index-only');
1246         @mods = grep { !($_->{BINARY}) } @mods;
1247         return if (!@mods);
1248         my (@them) = list_and_choose({ PROMPT => 'Review diff',
1249                                      IMMEDIATE => 1,
1250                                      HEADER => $status_head, },
1251                                    @mods);
1252         return if (!@them);
1253         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1254         system(qw(git diff -p --cached), $reference, '--',
1255                 map { $_->{VALUE} } @them);
1256 }
1257
1258 sub quit_cmd {
1259         print "Bye.\n";
1260         exit(0);
1261 }
1262
1263 sub help_cmd {
1264         print colored $help_color, <<\EOF ;
1265 status        - show paths with changes
1266 update        - add working tree state to the staged set of changes
1267 revert        - revert staged set of changes back to the HEAD version
1268 patch         - pick hunks and update selectively
1269 diff          - view diff between HEAD and index
1270 add untracked - add contents of untracked files to the staged set of changes
1271 EOF
1272 }
1273
1274 sub process_args {
1275         return unless @ARGV;
1276         my $arg = shift @ARGV;
1277         if ($arg eq "--patch") {
1278                 $patch_mode = 1;
1279                 $arg = shift @ARGV or die "missing --";
1280                 die "invalid argument $arg, expecting --"
1281                     unless $arg eq "--";
1282         }
1283         elsif ($arg ne "--") {
1284                 die "invalid argument $arg, expecting --";
1285         }
1286 }
1287
1288 sub main_loop {
1289         my @cmd = ([ 'status', \&status_cmd, ],
1290                    [ 'update', \&update_cmd, ],
1291                    [ 'revert', \&revert_cmd, ],
1292                    [ 'add untracked', \&add_untracked_cmd, ],
1293                    [ 'patch', \&patch_update_cmd, ],
1294                    [ 'diff', \&diff_cmd, ],
1295                    [ 'quit', \&quit_cmd, ],
1296                    [ 'help', \&help_cmd, ],
1297         );
1298         while (1) {
1299                 my ($it) = list_and_choose({ PROMPT => 'What now',
1300                                              SINGLETON => 1,
1301                                              LIST_FLAT => 4,
1302                                              HEADER => '*** Commands ***',
1303                                              ON_EOF => \&quit_cmd,
1304                                              IMMEDIATE => 1 }, @cmd);
1305                 if ($it) {
1306                         eval {
1307                                 $it->[1]->();
1308                         };
1309                         if ($@) {
1310                                 print "$@";
1311                         }
1312                 }
1313         }
1314 }
1315
1316 process_args();
1317 refresh();
1318 if ($patch_mode) {
1319         patch_update_cmd();
1320 }
1321 else {
1322         status_cmd();
1323         main_loop();
1324 }