git.oblomov.eu Git - git/blob - git-cvsexportcommit.perl

   1 #!/usr/bin/perl -w
   2
   3 # Known limitations:
   4 # - does not propagate permissions
   5 # - error handling has not been extensively tested
   6 #
   7
   8 use strict;
   9 use Getopt::Std;
  10 use File::Temp qw(tempdir);
  11 use Data::Dumper;
  12 use File::Basename qw(basename dirname);
  13
  14 unless ($ENV{GIT_DIR} && -r $ENV{GIT_DIR}){
  15     die "GIT_DIR is not defined or is unreadable";
  16 }
  17
  18 our ($opt_h, $opt_P, $opt_p, $opt_v, $opt_c, $opt_f, $opt_a, $opt_m, $opt_d);
  19
  20 getopts('hPpvcfam:d:');
  21
  22 $opt_h && usage();
  23
  24 die "Need at least one commit identifier!" unless @ARGV;
  25
  26 my @cvs;
  27 if ($opt_d) {
  28         @cvs = ('cvs', '-d', $opt_d);
  29 } else {
  30         @cvs = ('cvs');
  31 }
  32
  33 # setup a tempdir
  34 our ($tmpdir, $tmpdirname) = tempdir('git-cvsapplycommit-XXXXXX',
  35                                      TMPDIR => 1,
  36                                      CLEANUP => 1);
  37
  38 # resolve target commit
  39 my $commit;
  40 $commit = pop @ARGV;
  41 $commit = safe_pipe_capture('git-rev-parse', '--verify', "$commit^0");
  42 chomp $commit;
  43 if ($?) {
  44     die "The commit reference $commit did not resolve!";
  45 }
  46
  47 # resolve what parent we want
  48 my $parent;
  49 if (@ARGV) {
  50     $parent = pop @ARGV;
  51     $parent =  safe_pipe_capture('git-rev-parse', '--verify', "$parent^0");
  52     chomp $parent;
  53     if ($?) {
  54         die "The parent reference did not resolve!";
  55     }
  56 }
  57
  58 # find parents from the commit itself
  59 my @commit  = safe_pipe_capture('git-cat-file', 'commit', $commit);
  60 my @parents;
  61 my $committer;
  62 my $author;
  63 my $stage = 'headers'; # headers, msg
  64 my $title;
  65 my $msg = '';
  66
  67 foreach my $line (@commit) {
  68     chomp $line;
  69     if ($stage eq 'headers' && $line eq '') {
  70         $stage = 'msg';
  71         next;
  72     }
  73
  74     if ($stage eq 'headers') {
  75         if ($line =~ m/^parent (\w{40})$/) { # found a parent
  76             push @parents, $1;
  77         } elsif ($line =~ m/^author (.+) \d+ [-+]\d+$/) {
  78             $author = $1;
  79         } elsif ($line =~ m/^committer (.+) \d+ [-+]\d+$/) {
  80             $committer = $1;
  81         }
  82     } else {
  83         $msg .= $line . "\n";
  84         unless ($title) {
  85             $title = $line;
  86         }
  87     }
  88 }
  89
  90 if ($parent) {
  91     my $found;
  92     # double check that it's a valid parent
  93     foreach my $p (@parents) {
  94         if ($p eq $parent) {
  95             $found = 1;
  96             last;
  97         }; # found it
  98     }
  99     die "Did not find $parent in the parents for this commit!" if !$found and !$opt_P;
 100 } else { # we don't have a parent from the cmdline...
 101     if (@parents == 1) { # it's safe to get it from the commit
 102         $parent = $parents[0];
 103     } else { # or perhaps not!
 104         die "This commit has more than one parent -- please name the parent you want to use explicitly";
 105     }
 106 }
 107
 108 $opt_v && print "Applying to CVS commit $commit from parent $parent\n";
 109
 110 # grab the commit message
 111 open(MSG, ">.msg") or die "Cannot open .msg for writing";
 112 if ($opt_m) {
 113     print MSG $opt_m;
 114 }
 115 print MSG $msg;
 116 if ($opt_a) {
 117     print MSG "\n\nAuthor: $author\n";
 118     if ($author ne $committer) {
 119         print MSG "Committer: $committer\n";
 120     }
 121 }
 122 close MSG;
 123
 124 `git-diff-tree --binary -p $parent $commit >.cvsexportcommit.diff`;# || die "Cannot diff";
 125
 126 ## apply non-binary changes
 127 my $fuzz = $opt_p ? 0 : 2;
 128
 129 print "Checking if patch will apply\n";
 130
 131 my @stat;
 132 open APPLY, "GIT_DIR= git-apply -C$fuzz --binary --summary --numstat<.cvsexportcommit.diff|" || die "cannot patch";
 133 @stat=<APPLY>;
 134 close APPLY || die "Cannot patch";
 135 my (@bfiles,@files,@afiles,@dfiles);
 136 chomp @stat;
 137 foreach (@stat) {
 138         push (@bfiles,$1) if m/^-\t-\t(.*)$/;
 139         push (@files, $1) if m/^-\t-\t(.*)$/;
 140         push (@files, $1) if m/^\d+\t\d+\t(.*)$/;
 141         push (@afiles,$1) if m/^ create mode [0-7]+ (.*)$/;
 142         push (@dfiles,$1) if m/^ delete mode [0-7]+ (.*)$/;
 143 }
 144 map { s/^"(.*)"$/$1/g } @bfiles,@files;
 145 map { s/\\([0-7]{3})/sprintf('%c',oct $1)/eg } @bfiles,@files;
 146
 147 # check that the files are clean and up to date according to cvs
 148 my $dirty;
 149 my @dirs;
 150 foreach my $p (@afiles) {
 151     my $path = dirname $p;
 152     while (!-d $path and ! grep { $_ eq $path } @dirs) {
 153         unshift @dirs, $path;
 154         $path = dirname $path;
 155     }
 156 }
 157
 158 foreach my $d (@dirs) {
 159     if (-e $d) {
 160         $dirty = 1;
 161         warn "$d exists and is not a directory!\n";
 162     }
 163 }
 164 foreach my $f (@afiles) {
 165     # This should return only one value
 166     if ($f =~ m,(.*)/[^/]*$,) {
 167         my $p = $1;
 168         next if (grep { $_ eq $p } @dirs);
 169     }
 170     my @status = grep(m/^File/,  safe_pipe_capture(@cvs, '-q', 'status' ,$f));
 171     if (@status > 1) { warn 'Strange! cvs status returned more than one line?'};
 172     if (-d dirname $f and $status[0] !~ m/Status: Unknown$/
 173         and $status[0] !~ m/^File: no file /) {
 174         $dirty = 1;
 175         warn "File $f is already known in your CVS checkout -- perhaps it has been added by another user. Or this may indicate that it exists on a different branch. If this is the case, use -f to force the merge.\n";
 176         warn "Status was: $status[0]\n";
 177     }
 178 }
 179
 180 foreach my $f (@files) {
 181     next if grep { $_ eq $f } @afiles;
 182     # TODO:we need to handle removed in cvs
 183     my @status = grep(m/^File/,  safe_pipe_capture(@cvs, '-q', 'status' ,$f));
 184     if (@status > 1) { warn 'Strange! cvs status returned more than one line?'};
 185     unless ($status[0] =~ m/Status: Up-to-date$/) {
 186         $dirty = 1;
 187         warn "File $f not up to date in your CVS checkout!\n";
 188     }
 189 }
 190 if ($dirty) {
 191     if ($opt_f) {       warn "The tree is not clean -- forced merge\n";
 192         $dirty = 0;
 193     } else {
 194         die "Exiting: your CVS tree is not clean for this merge.";
 195     }
 196 }
 197
 198 print "Applying\n";
 199 `GIT_DIR= git-apply -C$fuzz --binary --summary --numstat --apply <.cvsexportcommit.diff` || die "cannot patch";
 200
 201 print "Patch applied successfully. Adding new files and directories to CVS\n";
 202 my $dirtypatch = 0;
 203 foreach my $d (@dirs) {
 204     if (system(@cvs,'add',$d)) {
 205         $dirtypatch = 1;
 206         warn "Failed to cvs add directory $d -- you may need to do it manually";
 207     }
 208 }
 209
 210 foreach my $f (@afiles) {
 211     if (grep { $_ eq $f } @bfiles) {
 212       system(@cvs, 'add','-kb',$f);
 213     } else {
 214       system(@cvs, 'add', $f);
 215     }
 216     if ($?) {
 217         $dirtypatch = 1;
 218         warn "Failed to cvs add $f -- you may need to do it manually";
 219     }
 220 }
 221
 222 foreach my $f (@dfiles) {
 223     system(@cvs, 'rm', '-f', $f);
 224     if ($?) {
 225         $dirtypatch = 1;
 226         warn "Failed to cvs rm -f $f -- you may need to do it manually";
 227     }
 228 }
 229
 230 print "Commit to CVS\n";
 231 print "Patch title (first comment line): $title\n";
 232 my @commitfiles = map { unless (m/\s/) { '\''.$_.'\''; } else { $_; }; } (@files);
 233 my $cmd = join(' ', @cvs)." commit -F .msg @commitfiles";
 234
 235 if ($dirtypatch) {
 236     print "NOTE: One or more hunks failed to apply cleanly.\n";
 237     print "You'll need to apply the patch in .cvsexportcommit.diff manually\n";
 238     print "using a patch program. After applying the patch and resolving the\n";
 239     print "problems you may commit using:";
 240     print "\n    $cmd\n\n";
 241     exit(1);
 242 }
 243
 244 if ($opt_c) {
 245     print "Autocommit\n  $cmd\n";
 246     print safe_pipe_capture(@cvs, 'commit', '-F', '.msg', @files);
 247     if ($?) {
 248         die "Exiting: The commit did not succeed";
 249     }
 250     print "Committed successfully to CVS\n";
 251 } else {
 252     print "Ready for you to commit, just run:\n\n   $cmd\n";
 253 }
 254
 255 # clean up
 256 unlink(".cvsexportcommit.diff");
 257 unlink(".msg");
 258
 259 sub usage {
 260         print STDERR <<END;
 261 Usage: GIT_DIR=/path/to/.git ${\basename $0} [-h] [-p] [-v] [-c] [-f] [-m msgprefix] [ parent ] commit
 262 END
 263         exit(1);
 264 }
 265
 266 # An alternative to `command` that allows input to be passed as an array
 267 # to work around shell problems with weird characters in arguments
 268 # if the exec returns non-zero we die
 269 sub safe_pipe_capture {
 270     my @output;
 271     if (my $pid = open my $child, '-|') {
 272         @output = (<$child>);
 273         close $child or die join(' ',@_).": $! $?";
 274     } else {
 275         exec(@_) or die "$! $?"; # exec() can fail the executable can't be found
 276     }
 277     return wantarray ? @output : join('',@output);
 278 }
 279
 280 sub safe_pipe_capture_blob {
 281     my $output;
 282     if (my $pid = open my $child, '-|') {
 283         local $/;
 284         undef $/;
 285         $output = (<$child>);
 286         close $child or die join(' ',@_).": $! $?";
 287     } else {
 288         exec(@_) or die "$! $?"; # exec() can fail the executable can't be found
 289     }
 290     return $output;
 291 }